!#!

Info Example: Prestressed bridge

!#!Info Keyword: prestress; tendon

!#!Info Program: TENDON

!#!Info Version: SOFiSTiK 25

!#!Info Date: 24.04.2009

+PROG AQUA URS:1

HEAD Materials

echo mat full ; echo sect no

NORM DIN 'fb102-2009' CAT C $ DIN FACHBERICHT 102 vgl. Beispiel DIN_FB_SOFiSTiK.pdf

$ DIN Special report German 102 campare example DIN_FB_SOFiSTiK.pdf

CONC 1 C 40 $ = C40/50

STEE 2 BST 500SA

STEE 7 S 235

STEE 11 PST 1570S

$ STEE 11 Y 1770 $ for EUROCODE see csm.dat\..\mode\csm31_design_ec2.dat

END

+PROG AQUA URS:2

HEAD Template section with axis-variables

CTRL REST 0 $ alte Querschnitte löschen - delete old sections

echo pict no

STO#WIDTH 8.00 $ Total width $ these two variables will change in

STO#HEIGHT 1.50 $ Total height $ axis development -> see SOFIMSHC - axis variables

SECT 1 MNO 1 MRF 2 TITL 'cross1'

SPT TOPP Y 0 Z0 MNO 1 $ MNR 1 = for AQB-output material 1

SPT BOTT Y 0 Z '=#HEIGHT' MNO 1 $

SPT TOPR Y '=+#WIDTH*0.5' Z 0 MNO 0 $ MNR 0 = only construction

SPT TOPL Y '=-#WIDTH*0.5' Z 0 MNO 0 $ point - not used for AQB-output

VERT 11 Y 0 Z 0 REFP TOPR

12 Y 0 Z .2 REFP TOPR

13 Y 2.0 Z .4

14 Y 1.5 Z 0 REFP BOTT

114 Y -1.5 Z 0 REFP BOTT

113 Y -2.0 Z .4

112 Y 0 Z .2 REFP TOPL

111 Y 0 Z 0 REFP TOPL exp 0.50 $ Belüftung nur über Asphalt $ aeration only over asphalt

$ Torsionsbox: *---------------------> y

$ TOPL=111--------------------------------------------11=TOPR

$ 112--- TL----------|----------TR ----12

$ ----113 | | | 13---

$ | | | | |

$ | | | | |

$ | | | | |

$ | BL----------|----------BR |

$ 114-------------------------14

let#c 0.07 $ m distance to surface - torsion box reinforcement

SPT TL REFP 113 Y #c Z -0.40+#c MNO 0

SPT TR REFP 13 Y -#c Z -0.40+#c MNO 0

SPT BL REFP 114 Y #c Z -#c MNO 0

SPT BR REFP 14 Y -#c Z -#c MNO 0

LRF 1 0 0 0 0 REFA TL REFE BL AS 0.1 LAY 0 TORS ACTI D 12

LRF 2 0 0 0 0 REFA BL REFE BR AS 0.1 LAY 0 TORS ACTI D 12

LRF 3 0 0 0 0 REFA BR REFE TR AS 0.1 LAY 0 TORS ACTI D 12

LRF 4 0 0 0 0 REFA TR REFE TL AS 0.1 LAY 0 TORS ACTI D 12

let#d 0.09 $ m distance to surface - main reinforcement bars

LRF 5 #d #d -#d #d REFA TOPL REFE TOPR AS - LAY 1 TORS PASS D 20 $ unten $ below
LRF 5 #d -#d -#d -#d REFA 114 REFE 14 AS - LAY 2 TORS PASS D 20 $ oben $ above

CUT 1 ZB 0.41 MNO 1 LAY 1

CUT 2 ZB S MNO 1 LAY 1

CUT 3 YB 1.50 MNO 1 LAY 3 TYPE FLAN

$ Sections for cross girders and piers:

SREC 7 H 1.8 B 1.2 REF UM $ Querträger - cross girder

SREC 9 H 1.5 B 4 $ Pfeiler - piers

END

+PROG SOFIMSHC URS:3 $ Definition of the main axis, spans, main beam and axis variables

HEAD CABD - Parametric haunched prestressed bridge

SYST SPAC GDIV 1000 POSZ

$ ------------------------------------- axis : ------------------------------

GAX 'AX_1'

GAXA S 0 X 0 0 0 SX 1 0 0 $ first starting point with starting direction

GAXA L 10 RA 0 RE 80

GAXA L 10 R 80

GAXA L 20 RA 80 RE -100

GAXA L 80 R -100

$ a straight bridge with 100 m only requires:

$ GAXB X1 0 0 0 X2 100 0 0 $ create axis from point 1 to point 2 (also with R)

$ other curved bridge -> csm.dat\...\cabd\csm10_...cabd.dat

$ ------------------------------ definition of spans: S_XI table: ----- axis : ------------------------------

$ As this span definition is used often in the file, it is defined once and stored:

STO#S_XI(99) 0 $ allocate table

STO#S_XI(0) 0.00 $ start of bridge at left excess - am linken Überstand

STO#S_XI(1) 1.00 $ first support - erstes Lager

STO#S_XI(2) 31.00 $ 2. support - 2. Lager

STO#S_XI(4) 62.00 $ end of bridge at right excess - am rechten Überstand

$ please always define #X_XI(0) and #X_XI(right excess)

$ also if it is equal to support X_XI(0)=X_XI(1)=0.00

$ now you can access to the table also with interpolation:

$ s at span 2 at local xi=0.6 ->

$ let#s =S_XI(2.6) gives s back with 49.00 m !!

STO#s_end =S_XI(4.0) $ for SOFILOAD - end of bridge

TXB Testprint variable s_end = #(s_end,8.3) $ (8 characters and 3 digits)

$ ------------------------------------- main beam : ------------------------------

CTRL MESH 1 ; CTRL HMIN 1.0 $ meshing of beam elements

$ xi-span definition $ Felddefinition - Lagerachsen

$ and beam element definition on that main axis $ gleichzeitig: Stabzug an der Hauptachse

GAXP 'AX_1' S =S_XI(0) TYPE 'A' GRP 1 NCS 1 SPT 90 $ defines xi=0

GAXP 'AX_1' S =S_XI(1) TYPE 'S' SPT 100 $ defines xi=1

GAXP 'AX_1' S =S_XI(2) TYPE 'S' GRP 2 SPT 200 $ defines xi=2

GAXP 'AX_1' S =S_XI(3) TYPE 'S' SPT 300 $ defines xi=3

GAXP 'AX_1' S =S_XI(4) TYPE 'E' SPT 310 $ defines xi=4

$ ------------------------------------- axis variables : ------------------------------

$ Variable HEIGHT via xi:

GAXV S V TYPE ID='AX_1' NAME='HEIGHT'

=#S_XI(0.0) 1.50 -

=#S_XI(1.4) 1.50 D+ $ at xi=0.4 of span 1 !

=#S_XI(2.0)-1.20 2.80 D+ $ 1.20 m vorm Mittelpfeiler

=#S_XI(2.0)+1.20 2.80 D- $ 1.20 m nach Mittelpfeiler

=#S_XI(2.6) 1.50 D-

=#S_XI(4.0) 1.50 D-
$ Variable WIDTH:

GAXV S V TYPE ID='AX_1' NAME='WIDTH'

=#S_XI(0.0) 8.00 POLY

=#S_XI(2.0)-6.00 9.80 POLY $ 6.00 m vorm Mittelpfeiler

=#S_XI(2.0)-3.00 9.80 POLY $ 3.00 m vorm Mittelpfeiler

=#S_XI(2.0)+3.00 9.80 POLY $ 3.00 m nach Mittelpfeiler

=#S_XI(2.0)+6.00 9.80 POLY $ 6.00 m nach Mittelpfeiler

=#S_XI(4.0) 8.00 POLY

END

END

$ alternatively :

$ Variable HEIGHT via S:

GAXV S V TYPE ID='AX_1' NAME='HEIGHT'

0 1.20 -

20 1.20 D+

30 2.70 D+

32 2.70 D-

42 1.20 D-

+PROG AQUA URS:5

HEAD Create interpolated sections

$ echo pict no

INTE 0

END

+PROG SOFIMSHA URS:6

HEAD Piers and support conditions [SOFIPLUS]

$ Please always run also first SOFIMSHC parallel to this SOFIMSHA !!!

SYST REST ; CTRL REST 2

GRP 9

$ The following block can be used for standard support constructs without changes
 $ Please only change the variables let#node ... below !

$ limitation: #node = node number in superstructure < 1000

#define support01

let#dhspring 0 $ m bearing height

$ bearing springs

let#sy 0.5*#b0

TRAN node #node dy #sy dz #h dno 51000

if #b0 ; tran node #node dy -#sy dz #h dno 53000 ; endif

TRAN node #node dy #sy dz #h dno 52000

if #b0 ; tran node #node dy -#sy dz #h dno 54000 ; endif

$ node on top of pier: node 49000...

tran node #node dz #h dno 49000

node #node+51000 FIX KF #node $ coupling

if #b0 ; node #node+53000 FIX KF #node ; endif $ coupling

node #node+52000 FIX KF #node+49000 $ coupling

if #b0 ; node #node+54000 FIX KF #node+49000 ; endif $ coupling

SPRI #node+0 #node+51000 #node+52000 DZ 1 CP 1E7 $ vertical bearing

if #b0 ; SPRI #node+1 #node+53000 #node+54000 DZ 1 CP 1E7 ; endif

$ transverse bearing springs:

SPRI #node+3 #node+51000 #node+52000 dy 1 CP 1E6 $ transverse

$ longitudinal bearing springs:

let#cp_long 1.0 $ weak - to get bearing displacements

if #logitud ; let#cp_long 1E6 ; endif $ longitudinal fixed bearing

SPRI #node+7 #node+51000 #node+52000 dx 1 CP #cp_long $ longitudinal

if #b0 ; SPRI #node+8 #node+53000 #node+54000 dx 1 CP #cp_long ; endif $ longitudinal

$ node bottom of pier: node 50000...

tran node #node dz #UKpier dno 50000

BEAM #node 50000+#node 49000+#node NCS 9 KR YY

node #node+50000 FIX F $ fixed support

#enddef

$
let#node 100 $ basenumber of node in superstructure

let#h 1.5 $ m cross section height

let#b0 2.6 $ m bearingspread

let#UKpier 7 $ m bottom level pier

let#logitud 0 $ =1 bearing fixed in longitud. direction

#include support01

let#node 200 $ basenumber of node in superstructure

let#h 2.7 $ m cross section height

let#UKpier 13 $ m bottom level pier

let#logitud 1 $ =1 bearing fixed in longitud. direction

#include support01

let#node 300 $ basenumber of node in superstructure

let#h 1.5 $ m cross section height

let#UKpier 7 $ m bottom level pier

let#logitud 0 $ =1 bearing fixed in longitud. direction

#include support01

END

+PROG TENDON urs:9

HEAD Prestressing

SYSP NOPS 19 MAT 11 ZV 3848 AZ 2850 LITZ 19 MINR 6.80 BETA 0.30 MUE 0.21 ECC 0.0 SP 6 DO 97

$ for EUROCODE see csm.dat\..\mode\csm31_design_ec2.dat

$ reference axis and span definition:

AXES NOH 1 TYPE AUTO 90 310

TOPP NOH 1 KIND NODE S 90,100,200,300,310 SP 0,1,2,3,4

$ S=100 = Knoten 100 ist der 1. Hochpunkt $ Node 100 is the 1. upper point
$ tendon geometry definition:

$ NOPS = prestressing system for max-min radius parameters + duct-excentricities

TGEO NOG 1 NOH 1 NOPS 19

$ Definition points of geometry: (TYP=SPAN/FELD station via highpoints)

PTUV S U V DVS RV RL TYPE=SPAN

0 0 0.4 - - -

1.4 - 1.35 0 - -

2 0 0.16 0 14 1.3

2.6 - 1.35 0 - -

4 0 0.4 - - -

$ Additional values: construction stages:

CS ICS1 11 12

$ prestress-procedure $ Anspann-Vorgehen

PSIG RI ANWS 'TS' KAPA 1.5 K3 1220 $ k3 = geschätzte Begrenzung, damit Spannung bei
Verkehrsübergabe nicht zu hoch

$ zul-sigma-Verkehrsübergabe wegen DIN-FB 4.4.1.4 -> 0.65 fpk

$ k3 = estimated limit to reduce stress at traffic opening

$ zul-sigma-traffic opening due to DIN-FB 4.4.1.4 -> 0.65 fpk

$ final tendon definition:

TEND NOT 1 NOG 1 NTEN 8 LC 3

$ tendon plots:

ECHO PLOT full

SCHH h2 0.18 h4 0 h5 0 h6 0

PLOT GEOE NO 0 FACH 5 TYPG DUTE DIA 65 PCS 1 $ 0 = all tendons

PLOT FACT NO 1 FACH 50

end

+PROG ASE urs:10

HEAD

LC 1 DLZ 1
LC 3 TITL prestress

END