STARTING WITH CAST3M

THERMOMECHANICAL CALCULATIONS
AVAILABLE ON: HTTP://WWW-CAST3M.CEA.FR/INDEX.PHP?XML=FORMATIONS

François DI PAOLA, Caroline GUERIN,

Thibault LINDECKER, Clément BERTHINIER

LAST CHANGES: FEBRUARY 27 2020

 SUMMARY

Introduction to Cast3M

Gibiane language

Tutorial class
thermo-mechanical behavior of a plate with a hole

Complements

Objects in Gibiane

PAGE 2
INTRODUCTION TO CAST3M
 WHAT IS CAST3M?

A finite element software for structural and fluid

mechanics

Partial differential equations solved thanks to the finite element

method
Objet-oriented programming language: Gibiane

Many basic functions

Complete software: solver, pre-processing and post-processing,
visualization

PAGE 4
 HISTORY

AQUAMODE
1970 CEASEMT: package of dedicated software:
COCO (mesh), ESPACE, TEMPS, VISU (post-processing), TRICO INCA
SANSON (eq. properties) COCO
TEDEL (beams, pipes), TRICO (shells), BILBO (solids) ESPACE SANSON
PASTEL (2D, plasticity)  INCA TEMPS VISU

DELPHINE (thermal), AQUAMODE (modal analysis) TEDEL BILBO

1981 Start of GIBI (meshing software) DELPHINE

1983 Initiation of Castem 2000 (based on GIBI)

1986 Official release of Castem2000
Procedures, introduction of fluid physics and other physics
1990 Development of dedicated applications (Toutatis, Esus, …)
2000 Castem 2000  Cast3M
Platforms for dev. of dedicated applications (Pléiades, Alliance, …)
New dedicated applications (Brasero, Gerboise, Rotor, …)

PAGE 5
 MODELLING OF NUMEROUS PHYSICAL PHENOMENA

Structural mechanics
Quasi-static (non-linear materials, geometries, boundary conditions )
Contact/friction
Buckling
Dynamics (temporal, modal, fluid/structure interaction)
Fracture mechanics (XFEM, dynamic propagation, cohesive zone model)
Thermal calculations
Conduction, convection, radiation, phase change
Fluid mechanics

Magneto statics
Multi species diffusion (Fick’s Law)
Thermo-hydro-mechanical coupling

PAGE 6
 GENERAL COMMENTS (1/2)

How to download Cast3M?

http://www-cast3m.cea.fr/index.php?page=dlcastem
For which OS Cast3M is available?
 Windows (32 and 64 bits)
 Linux (32 and 64 bits)
 Mac OS X (64 bits)
Which versions of Cast3M are available?
User Version: source code cannot be modified
Developer Version: source code can be modified ;-)
Does it exist a graphical user interface for CAST3M?
No, Cast3M has a command line interface. GIBIANE’s statements
can be written in a text file with the .dgibi extension
Is Cast3M free?
Yes, free license for education and research
No, paid license for enterprise use

PAGE 7
 GENERAL COMMENTS (2/2)

Is Cast3M an open source software?

Not all sources available, but the user is free to modify and adapt
Cast3M to his needs
 Access to source code (Esope language, a Fortran 77 extension)

 Esope compiler + linker included

 Collaborative development
Everyone can propose developments/bug fixes to be integrated to the
Cast3M standard version

Is it possible to alert the Cast3M support in case of anomaly?

Yes (highly recommended), contact Cast3M support, via the web site:
http://www-cast3m.cea.fr/index.php?page=mailsupport

PAGE 8
 HOW TO LAUNCH CAST3M?

Write a Gibiane script in a text file (ex: hello.dgibi)

and save it in a working directory

Open a terminal
Go to the working directory
here are some basic Linux commands:
ls list present files
cd foo/bar change directory
pwd print the name of the current working directory

Launch Cast3M on this file

castem19 hello.dgibi

You can also use (interactive mode):

castem19 PAGE 9
 THE CAST3M WEB SITE

The Cast3M web site: "the place to be"

http://www-cast3m.cea.fr

 Cast3M presentation

 Training courses and video tutorials

 Documentation (manual pages, source code, examples)

 Anomaly and development reports

 Downloads

 Contact: Cast3M support

 Community: mailing list, Cast3M club

PAGE 10
GIBIANE: THE USER LANGAGE
 INTRODUCTION TO GIBIANE

Language dedicated to FE calculation but also a

programming language
Classical objects (integer, floating-point, string, logical , tables…)
Flow control statements
Loops and iterations
Subroutines
Recursion

Interpreted language
You can run the program as soon as you make changes to the file
You can run it in a interactive mode
Object-oriented language
Everything in the program is treated as an object
No need to declare variables or to specify the type of a variable
French key words
Easy to learn, easy to read PAGE 12
 GIBIANE: SYNTAX

Statements lines
500 characters max per statement
A statement can be written on several lines
End with a semicolon ;
The assignment operator is the equals sign =
Older versions (< 2018): 72 characters by line!!!

Case insensitive
TOTO = 3.14 ;
A = 2. * tOTo ; variable A has the value of 6.28
excepted characters strings 'blabla' ≠ 'BLABLA'
enclosed by single quotes mot1 = 'Hello bro' ;

Program ends
with statement FIN ;  Cast3M stop
empty line or EOF  interactive mode
A * in the first column means that the rest of the line is a comment

Empty lines accepted PAGE 13

 GIBIANE: SYNTAX

No precedence in operators (from left to rigth)

1+2*3 = 9  use parentheses
1+(2*3) = 7

Prohibitions
No tab key  incomprehensible error message
No double quotes "

Guidelines
No special characters (é, ç, ~, œ …)
Use line indentation
Adjust the text editor
syntax highlighting, switch tabulations by spaces,…

Common traps
Semicolon ; forgotten at the end of the statement
 the statement is not ended
Introduce a single quote in a string
 indicates the string end
PAGE 14
 GIBIANE: OBJECTS

Definition
Any data/result with a defined type (possibly a sub-type) and name

Objects Names
User Defined
Limited to 8 characters chosen in:
letters a to z or A to Z, digits (0 to 9) and underscore ( _ )
Traps
more than 8 characters: additional characters ignored
dash sign –  not allowed
letters with accents: é, è  not allowed

Objects types
There are more than 40 types of objects
A detailed list of the most often used objects is given at the end of the
presentation (link)

PAGE 15
 GIBIANE: OBJECTS

Examples (non exhaustive)

OBJ1 = 3 ; type: ENTIER (integer)
OBJ2 = 3.14 ; type: FLOTTANT (floating)
OBJ3 = 'How are you?' ; type: MOT (string)
OBJ4 = VRAI ; type: LOGIQUE (logical)
poin1 = POIN 0. 0. ; type: POINT
poin2 = POIN 1. 3. ; type: POINT
OBJ5 = DROI 8 poin1 poin2 ; type: MAILLAGE (mesh)
LIST OBJ5 ;
MAILLAGE 3520406 : 8 élément(S) de type SEG2
0 sous-référence(s)
1ère ligne numéro élément : 2ème couleur : 3ème... noeud(s)
1 2 3 4 5 6 7 8
DEFA DEFA DEFA DEFA DEFA DEFA DEFA DEFA
1 3 4 5 6 7 8 9
3 4 5 6 7 8 9 2

PAGE 16
 GIBIANE: OPERATORS

Definition
Any processing with a name (Gibiane instruction) that creates new
object(s) from pre-existing object(s)

Operators Names
Pre-defined
These are Gibiane instructions
Case insensitive
Only the four first characters are necessary and taken into account
(DROITE = DROI)
Excepted abbreviations
DROIT  D (or d)
CERCLE  C (or c)

PAGE 17
 GIBIANE: OPERATORS

Examples of operator call

Common cases (single object on the left of the equals sign)
obj1 = OPER obj2 ;
obj3 = OPER obj4 obj5 ;
obj6 = obj7 OPER obj8 obj9 ;

Unusual cases (multiple objects on the left of the equals sign)

obj1 obj2 obj3 = OPER obj4 obj5 ;

The "no name" operator: POINTS creation

in 2 dimensions Point1 = 0. 0. ;
in 3 dimensions Point1 = 0. 0. 0. ;

PAGE 18
 GIBIANE: OPERATORS

Arguments order
do not matters if arguments have different types
(with a few exceptions pointed in the manual)
matters if same type arguments

Overwriting an object
Always possible, the overwritten object does not exists any longer
A = ‘Hello' ;  A has type MOT
B = 28 ;
C = 3 ;
A = B**C ;  A has type ENTIER, its value is 21952

Traps
Object name = operator name  operator cannot be called
excepted if you call it with quotes
A = 'OPER' B C ;
in upper case!
Objet name c, C, d or D ! PAGE 19
 GIBIANE: DIRECTIVES

Definition
Statement without assignment operator =
Does not create a new object
Examples
OPTI 'DIME' 3 'ELEM' 'CUB8' ;
OPTI 'TITR' 'Meshing of the structure' ;
DEPL mail1 'PLUS' (28. -0.3 20.03) ;

OPTI is often the first statement of a Gibiane program

It defines Cast3M general options

Examples:
space dimension (1 to 3), elements type, mesh size,
output file name, axial symmetry hypothesis, and others…

PAGE 20
 GIBIANE: PROCEDURES

Definition
Set of Gibiane statements having a name with input and output
arguments
Similar to Fortran subroutine or a C function

Procedures names
As other objects (a procedure is an object with PROCEDUR type)

Declaration
DEBP my_proc arg_e1*entier arg_e2*flottant ... arg_en*mchaml ;
statement 1 ;
statement 2 ;
...
statement k ;
FINP arg_s1 arg_s2 ... arg_sm ;

PAGE 21
 GIBIANE: PROCEDURES

Calling
As an operator or directive
obj1 obj2 ... objm = my_proc ent1 flot2 ... champn ;

Pre-existing procedures in Cast3M

List in: http://www-cast3m.cea.fr/index.php?page=notices
The @blabla, with @ prefix are general interest procedures
PASAPAS  non-linear calculations
FLAMBAGE  buckling calculations
DYNAMIC  dynamics calculations
THERMIC  thermal calculations
…
other procedures to discover in the manual pages

PAGE 22
 GIBIANE: PROCEDURES

Traps
FINP missing
 Cast3M stops, error message that can be misunderstood
FINP existing but missing ;
 Cast3M stops, error message that can be misunderstood
Procedure called before it is declared
 Cast3M stops, error message in the = operator difficult to
interpret

PAGE 23
 GIBIANE: SOME USEFUL STATEMENTS

Debugging
INFO OPER ; OPTI 'LANG' 'ANGL' ;
 print the manual page of a operator/directive/procedure
OPTI 'DONN' 5 ;
 stop to run the file .dgibi
 run from scream: interactive prompt
OPTI 'DONN' 3 ;
 return to run the file .dgibi (from where it stops previously)
LIST OBJ1 ;
 print information about the object OBJ1
LIST 'RESU' OBJ1 ;
 printing is reduced to the headings
OPTI 'DEBU' 1 ;
 stop on a error inside a procedure
TRAC OBJ1 (OBJ2) ;
 plot an object (mesh, iso-values of fields, deformed mesh, …)
MESS 'Here I am!' ;
 print a message

PAGE 24
 DOCUMENTATION

Manual pages of operators/directives/procedures

1) The INFO directive, example: INFO EXTR ;
2) Local html page: in the installation directory
example on a Linux system: /home/john_doe/CAST3M_2019/doc/index.html

example on a Windows system: C:\Cast3M\PCW_19\doc\index.html

3) The web site: http://www-cast3m.cea.fr/index.php?page=notices

dedicated to the up to date version !
Users manual
On the web site, see the "Documentation" tab

PAGE 25
TUTORIAL CLASSES

MODELING OF THE THERMO-MECHANICAL

BEHAVIOR OF A PLATE WITH A HOLE
 PROBLEM DESCRIPTION AND BOUNDARY CONDITIONS

Thermal
Uniform strength Radiation
Mechanical

Prescribed Convection
heat flux

Prescribed
temperature

Blocking (symmetry) PAGE 27

 REMINDER

Method to perform finite element calculations (4 main steps)

1) Geometry description and meshing
a) Description of points, lines, surfaces, volumes
b) Discretization
2) Mathematical model definition
a) Definition of the model data (type of analyze, formulation, material behavior, types of elements)
b) Definition of the material properties (Young’s modulus, density, …)
c) Definition of the geometrical properties (shell thickness, moments of inertia for beams, …)
d) Definition of the boundary conditions and loadings
f) Definition of the initial values
3) Solving the discretized model
a) Elementary stiffness matrix and elementary mass matrix calculation
b) Global matrix calculation
c) Introduction of the loadings and boundary conditions
e) Solving the system of equations
4) Analysis et post-processing
a) Local quantities (strains, stresses, displacements, …)
b) Global quantities (maximal strains, strain energy, …)

PAGE 28
 SOLUTION FILES

The solution files of this tutorial are in the examples base

Download them from the web site:
http://www-cast3m.cea.fr/index.php?page=exemples

Three files will be used:

 formation_debutant_1_maillage.dgibi
 formation_debutant_2_thermique.dgibi
 formation_debutant_3_mecanique.dgibi

PAGE 29
 CHAP. 1: GEOMETRY AND MESH

Objective: to create a parametered mesh of the plate with the hole

1. locate the main points

2. mesh the closed border
3. mesh the internal surface
Y nlong

nhaut
haut

nbasg nbasd
X
O PAGE 30
long
 CHAP. 1: MESHING AND GENERAL STATEMENTS

General options and parameters

* GENERAL OPTIONS AND TYPE OF FINITE ELEMENTS
OPTI 'DIME' 2 'ELEM' 'QUA8' ;

* LENGTHS AND MESH DENSITY DEFINITIONS

LONG = 24.E-1 ;
Y
HAUT = 10.E-1 ; nlong
RAYON = 2.E-1 ;

NLONG = 24 ;
NHAUT = 4 ;

nhaut
NBASG = 10 ;
haut

NBASD = 10 ;
NQCG = 8 ;
NQCD = 8 ;
nbasg nbasd
O X
long
PAGE 31
New objects ENTIER, FLOTTANT, MOT
 CHAP. 1: MESHING AND GENERAL STATEMENTS

Points creation
* CREATION OF POINTS SUPPORTING THE MESH
PA = 0. 0. ; PG PF
PB = ((0.5 * LONG) – RAYON) 0. ;
PC = (0.5 * LONG) RAYON ;
PD = ((0.5 * LONG) + RAYON) 0. ;
PE = LONG 0. ;
PF = LONG HAUT ;
PG = 0. HAUT ; PC
PCEN = (0.5 * LONG) 0. ;

PCEN
PA PB PD PE

PAGE 32
new object POINT
 CHAP. 1: MESHING AND GENERAL STATEMENTS

Lines and closed contour

* STRAIGHT LINES CONSTRUCTION (DROI or D)

LIAB = DROI NBASG PA PB ;

LIDE = DROI NBASD PD PE ;
LIEF = D NHAUT PE PF ;
LIFG = D NLONG PF PG ;
LIGA = D NHAUT PG PA ;

* CONSTRUCTION OF CIRCLES (CERC or C)

(It’s up to you: see the manual pages)

* CLOSED CONTOUR OBTAINED FROM THE ELEMENTARY LINES ASSEMBLY

CO = LIAB ET CE ET LIDE ET LIEF ET LIFG ET LIGA ;

PAGE 33
new object MAILLAGE
 CHAP. 1: MESHING AND GENERAL STATEMENTS

Lines and closed contour

* STRAIGHT LINES CONSTRUCTION (DROI or D)

LIAB = DROI NBASG PA PB ; LIFG

LIDE = DROI NBASD PD PE ;
LIEF = D NHAUT PE PF ;
LIFG = D NLONG PF PG ;
LIGA = D NHAUT PG PA ;

LIEF
LIGA
* CONSTRUCTION OF CIRCLES (CERC or C)
CE

CE1 = CERC NQCG PB PCEN PC ; LIAB LIDE

CE = C NQCD CE1 PCEN PD ;

* CLOSED CONTOUR OBTAINED FROM THE ELEMENTARY LINES ASSEMBLY

CO = LIAB ET CE ET LIDE ET LIEF ET LIFG ET LIGA ;

PAGE 34
 CHAP. 1: MESHING AND GENERAL STATEMENTS

Surface meshing (free meshing inside the closed contour)

SU = SURF CO ;
TRAC SU ;

PAGE 35
 CHAP. 1: MESHING AND GENERAL STATEMENTS

Objective: to create a regular mesh of the half-plate with a hole

- contains only quadrangle,

- controlled elements size,
- takes into account geometrical
symmetry.

PAGE 36
 CHAP. 1: MESHING AND GENERAL STATEMENTS

Objective: to create a regular mesh of the half-plate with a hole

regular mesh, symmetry, variable elements size

PG PH PF
nhaut

PC

variable density PCEN

PA 0.1 – 0.05
PB PD PE
PAGE 37
 CHAP. 1: MESHING AND GENERAL STATEMENTS

Surface meshing (regular mesh surface relative to two lines)

NHAUT = 10 ;
NQCG = 20 ;
PH = (locate point PH  POIN)
LIHG = (define line HG  DROI)
LIGA = (define line GA  DROI)
CE1 = (define quarter-circle CE1  CERC)
SU1 = (mesh the surface SU1  REGL)
SU2 = (using symmetry mesh the surface SU2  SYME)
SU = (group the two meshes SU1 and SU2  ET)

PAGE 38
 CHAP. 1: MESHING AND GENERAL STATEMENTS

Surface meshing (regular mesh surface relative to two lines)

NHAUT = 10 ;
NQCG = 20 ;
PH = (0.5 * LONG) HAUT ;
LIHG = DROI (NQCG - NHAUT) PH PG ;
LIGA = DROI NHAUT PG PA ;
CE1 = CERC NQCG PB PCEN PC ;
SU1 = REGL 'DINI' 0.05 'DFIN' 0.1 (INVE CE1) (LIHG ET LIGA) ;
SU2 = SU1 SYME 'DROI' PCEN PH ;
SU = SU1 ET SU2 ;

TRAC SU ;

PAGE 39
 CHAP. 1: MESHING AND GENERAL STATEMENTS

Elimination of double nodes, directive ELIM

ELIM SU 1.E-9 ;
TRAC SU ;

 all SU nodes distant less than 10-9 m are merged in single one
 does not change the element type
 directive to use carefully !

See also REGE operator

 regeneration of elements with merged nodes
 change the element type if necessary
PAGE 40
 CHAP. 1: MESHING AND GENERAL STATEMENTS

Meshed zones recovery

* HALF-CIRCLE MESH, UPPER AND LINES MESHES RETRIEVAL WITH 'POIN' ET 'ELEM'

CSU = CONT SU ; (Contour of SU mesh recovery)

PCE = SU POIN 'SPHE' PCEN PC 1.E-9 ; (Points of SU located on sphere

recovery)
CE = CSU ELEM 'APPU' 'STRI' PCE ; (Elements containing points of CE
recovery)
PLHAUT = (It’s up to you); (Points of line PF PG recovery)

LHAUT = (It’s up to you); (Elements containing points of

PLHAUT recovery)
PLBAS = (It’s up to you); (Points of line PA PE recovery)

LBAS = (It’s up to you); (Elements containing points of

PLBAS recovery)

PAGE 41
 CHAP. 1: MESHING AND GENERAL STATEMENTS

Meshed zones recovery

* HALF-CIRCLE MESH, UPPER AND LINES MESHES RETRIEVAL WITH 'POIN' ET 'ELEM'

CSU = CONT SU ;

PCE = SU POIN 'SPHE' PCEN PC 1.E-9 ;

CE = CSU ELEM 'APPU' 'STRI' PCE ;

PLHAUT = SU POIN 'DROI' PF PG 1.E-9 ;

LHAUT = CSU ELEM 'APPU' 'STRI' PLHAUT ;

PLBAS = SU POIN 'DROI' PE PCEN 1.E-9 ;

LBAS = CSU ELEM 'APPU' 'STRI' PLBAS ;

PAGE 42
 [BONUS] 3D MESHING

Volume meshing (complement)

* CHANGE TO DIMENSION 3
OPTI 'DIME' 3 'ELEM' 'CU20' ;

* VOLUME FROM EXTRUSION

VO = SU VOLU 6 'TRAN' (0. 0. 2.) ;

* VOLUME FROM ROTATION

VO = SU VOLU 10 'ROTA' 90. (0. -1. 0.) (1. -1. 0.) ;

* DISPLAYING
TRAC VO ;
TRAC 'CACH' VO ;
OPTI 'TRAC' 'OPEN' ;
TRAC 'CACH' VO ;

* BACK TO DIMENSON 2
OPTI 'DIME' 2 ;

PAGE 43
 CHAP. 1: MESHING AND GENERAL STATEMENTS

Saving data and end of program

* NAME OF THE OUTPUT FILE
OPTI 'SAUV' 'formation_debutant_1_maillage.sauv' ;

* WRITTING THE FILE

SAUV ;

* END OF THE GIBI PROGRAM

FIN ;

All of the objects are saved in the output file

The output file is binary (XDR format )
Other formats available (text, …), see the manual page of
OPTI 'SAUV' and SAUV

PAGE 44
 CHAP. 2: STATIONARY LINEAR THERMAL ANALYSIS

Objective: stationary thermal calculation with prescribed temperatures

(time independent)

Linear system: Λ 𝜃 = Φ

1. conductivity matrix calculation Λ (1st member)

2. fixed nodal heat fluxes calculation Φ (2nd member)
3. solving with RESO  temperature 𝜃 (unknown)

-3,5 104 W.m-2

250 °C

PAGE 45
 CHAP. 2: STATIONARY LINEAR THERMAL ANALYSIS

Input data from previous computation (mesh, parameters, …)

* NAME OF THE INPUT FILE (RESTITUTION)
OPTI 'REST' 'formation_debutant_1_maillage.sauv' ;

* LOADING INTO MEMORY

REST ;

All of the objects are loaded into memory

They can be called now

PAGE 46
 CHAP. 2: STATIONARY LINEAR THERMAL ANALYSIS

Mathematical formulation
* MATERIAL PROPERTIES
CONDUMAT = 210. ;
CAPAMAT = 900. ;
RHOMAT = 2700. ;

* THERMAL MODEL (CONDUCTION) UNIFORM AND STATIONARY MATERIAL PROPERTIES

MOT = MODE SU 'THERMIQUE' ;
MAT = MATE MOT 'K' CONDUMAT 'C' CAPAMAT 'RHO' RHOMAT ;

* CONDUCTIVITY MATRIX CALCULATION (FIRST MEMBER)

CON = COND MOT MAT ;

PAGE 47
new objects MMODEL, MCHAML, RIGIDITE
 CHAP. 2: STATIONARY LINEAR THERMAL ANALYSIS

Boundary conditions
* BOUNDARY CONDITIONS: PRESCRIBED TEMPERATURE ON THE HOLE
BLT = BLOQ CE 'T' ;

* NODAL HEAT FLUX (LOADINGS) FOR CONSTRAINTS link

TMAX = 250. ;
FLT1 = DEPI BLT TMAX ;

* PRESCRIBED HEAT FLUX ON THE LEFT SIDE

FLT2 = FLUX MOT LIGA -3.5E4 ;

Linear system solving

* TEMPERATURE FIELD CALCULATION USING 'RESO'
TCON1 = RESO (CON ET BLT) (FLT1 ET FLT2) ;

PAGE 48
new object CHPOINT
 CHAP. 2: STATIONARY LINEAR THERMAL ANALYSIS

Results display
* DISPLAY THE TEMPERATURE FIELD

TRAC TCON1 SU ;

PAGE 49
 CHAP. 2: STATIONARY LINEAR THERMAL ANALYSIS

Results display
* DISPLAY THE TEMPERATURE FIELD

TRAC TCON1 SU CSU ;

PAGE 50
 CHAP. 2: STATIONARY LINEAR THERMAL ANALYSIS

Results display
* DISPLAY THE TEMPERATURE FIELD
LISO1 = PROG 0. 'PAS' (TMAX / 15.) TMAX ;
TRAC TCON1 SU CSU LISO1 ;

new object LISTREEL

PAGE 51
 CHAP. 2: STATIONARY LINEAR THERMAL ANALYSIS

Results display
* DISPLAY THE TEMPERATURE FIELD

TRAC TCON1 SU CSU LISO1 'TITR' '[2] Temperature' ;

PAGE 52
 NOTE: THE NODAL FIELD (CHPOINT)

The CHPOINT type object

Values are located on POINTS (nodes)

Examples:
 scalar temperature field
 vector displacement field (3 components)
 vector coordinates fields
 second member of a linear problem K.U = F, for instance:
 nodal forces
 nodal heat flux
 and others…

Some characteristics:
 only one value per node
 do not depends on the mesh, only on nodes!
 when plotted, the field is continuous on the mesh

PAGE 53
 NOTE: THE ELEMENT FIELD (MCHAML)

The MCHAML type object

Values are located into elements of a mesh

Examples:
 material properties
 stress, strains fields
 internal variables field
 and others…

Some characteristics:
 several support points available:
 integration points for stresses
 integration points for stiffness
 integration points for mass
 center of gravity
 nodes
 interpolation functions depends on the model
 non continuous between elements

PAGE 54
 CHAP. 3: TRANSIENT LINEAR THERMAL ANALYSIS
PASAPAS

Objective: previous thermal calculation

+ transient (initial temperature = 25 °C)

1. time description of loading

2. initial conditions
3. using the PASAPAS solving procedure

-3,5 104 W.m-2

250 °C

PAGE 55
 CHAP. 3: TRANSIENT LINEAR THERMAL ANALYSIS
PASAPAS

Initial conditions
* FINAL TIME OF THE THERMAL CALCULATION
TPSFIN = 5.E4 ;
* INITIAL TEMPERATURE (UNIFORM)
T0 = 25. ;
T_INI = MANU 'CHPO' 1 SU 'T' T0 ;

Loads definition (BC as a function of space and time)

* THERMAL LOAD FOR FIXED TEMPERATURE CONDITION
* FAST RISE THEN KEPT CONSTANT
LIST1 = PROG 0. (0.1 * TPSFIN) TPSFIN ;
LIST2 = PROG (T0 / TMAX) 1. 1. ;
EVT1 = EVOL 'MANU' LIST1 LIST2 ;
CHT1 = CHAR 'TIMP' FLT1 EVT1 ;
* THERMAL LOAD FOR FIXED HEAT FLUX
* WAITING PHASE THEN GRADUAL RISE
LIST3 = PROG 0. (0.2 * TPSFIN) (0.5 * TPSFIN) TPSFIN ;
LIST4 = PROG 0. 0. 1. 1. ;
EVT2 = EVOL 'MANU' LIST3 LIST4 ;
CHT2 = CHAR 'Q' FLT2 EVT2 ;
CHT = CHT1 ET CHT2 ;

PAGE 56
new objects EVOLUTIOn and CHARGEMEnt
 CHAP. 3: TRANSIENT LINEAR THERMAL ANALYSIS
PASAPAS

Construction of TAB1: table for procedure PASAPAS

* TABLE OF ARGUMENTS NECESSARY AS ENTRIES FOR THE PASAPAS PROCEDURE

TAB1 = TABL ;
TAB1 . 'MODELE' = MOT ;
TAB1 . 'CARACTERISTIQUES' = MAT ;
TAB1 . 'BLOCAGES_THERMIQUES' = BLT ;
TAB1 . 'CHARGEMENT' = CHT ;
TAB1 . 'TEMPS_CALCULES' = PROG 0. 'PAS' (0.02 * TPSFIN) TPSFIN ;
TAB1 . 'TEMPERATURES' = TABL ;
TAB1 . 'TEMPERATURES' . 0 = T_INI ;

Solving with PASAPAS procedure

* PASAPAS CALL
PASAPAS TAB1 ;

PAGE 57
new object TABLE
 CHAP. 3: TRANSIENT LINEAR THERMAL ANALYSIS
PASAPAS

Post processing: evolution curves, field plot

* VARIATION OF TEMPERATURE AT TWO POINTS AS A FUNCTION OF TIME
* IN ORDER TO VERIFY STEADY STATE IS REACHED
PMIL = SU POIN 'PROC' ((0.5 * LONG) (0.5 * HAUT)) ;
EV1 = EVOL 'ROUG' 'TEMP' TAB1 'TEMPERATURES' 'T' PMIL ;
EV2 = EVOL 'BLEU' 'TEMP' TAB1 'TEMPERATURES' 'T' PG ;

DESS (EV1 ET EV2) 'TITR' '[3] Temperature at test points vs Time' ;

PAGE 58
 CHAP. 3: TRANSIENT LINEAR THERMAL ANALYSIS
PASAPAS

Post processing: iterative loop for plotting

* LOOP ON EACH TIME STEP AND PLOT OF TEMPERATURE FIELD
N1 = DIME (TAB1 . 'TEMPERATURES') ; Loop counter
REPE B1 N1 ; 1, 2, 3, … , N1
T_I = TAB1 . 'TEMPERATURES' . (&B1 - 1) ;
TPS_I = TAB1 . 'TEMPS' . (&B1 - 1) ;
MOT_I = CHAI '[3] Temperatures at time ' TPS_I ;
TRAC T_I SU CSU 'TITR' MOT_I LISO1 ;
FIN B1 ;

PAGE 59
 CHAP. 3: TRANSIENT LINEAR THERMAL ANALYSIS
PASAPAS

Procedure writing (heat flux vector calculation)

* HEAT FLUX VECTOR ==> PROCEDURE WRITING
DEBP VECFLU CHP1*'CHPOINT' MOD1*'MMODEL' MAT1*'MCHAML' ;
* GRADIENT CALCULATION AND CHANGE OF ITS TYPE
G1 = GRAD CHP1 MOD1 ;
G2 = CHAN 'TYPE' G1 'CARACTERISTIQUES' ;
* MULTIPLICATION
Q = MAT1 * G2 (MOTS 'K' 'K') (MOTS 'T,X' 'T,Y') (MOTS 'QX' 'QY') ;
Q = -1. * Q ;
* VECTOR OBJECT CREATION
VEC1 = VECT Q MOD1 (MOTS 'QX' 'QY') 2.E-6 ;
FINP VEC1 ;

PAGE 60
new objects PROCEDURe, LISTMOTS, VECTEUR
 CHAP. 3: TRANSIENT LINEAR THERMAL ANALYSIS
PASAPAS

Procedure writing (heat flux vector calculation)

* HEAT FLUX VECTOR ==> PROCEDURE WRITING
DEBP VECFLU CHP1*'CHPOINT' MOD1*'MMODEL' MAT1*'MCHAML' MOT1/'MOT' ;
* GRADIENT CALCULATION AND CHANGE OF ITS TYPE
G1 = GRAD CHP1 MOD1 ;
G2 = CHAN 'TYPE' G1 'CARACTERISTIQUES' ;
* MULTIPLICATION
Q = MAT1 * G2 (MOTS 'K' 'K') (MOTS 'T,X' 'T,Y') (MOTS 'QX' 'QY') ;
Q = -1. * Q ;
* VECTOR OBJECT CREATION
SI (EGA (TYPE MOT1) 'MOT') ;
SI (EGA MOT1 'COUL') ;
QP = CHAN 'CHPO' Q MOD1 ;
VEC1 = @VECOUL QP 2.E-6 ;
SINON ;
ERRE '--> ERROR in the VECFLU procedure, the expected keyword is COUL <--' ;
FINSI ;
SINON ;
VEC1 = VECT Q MOD1 (MOTS 'QX' 'QY') 2.E-6 ;
FINSI ;
FINP VEC1 ;

PAGE 61
new object LOGIQUE
 CHAP. 3: TRANSIENT LINEAR THERMAL ANALYSIS
PASAPAS

Post processing: heat flux vector plot

* LOOP ON EACH TIME STEP AND PLOT OF HEAT FLUX VECTOR
REPE B1 N1 ;
T_I = TAB1 . 'TEMPERATURES' . (&B1 - 1) ;
VF_I = VECFLU T_I MOT MAT 'COUL' ;
TPS_I = TAB1 . 'TEMPS' . (&B1 - 1) ;
MOT_I = CHAI '[3] Heat flux vector at time ' TPS_I ;
TRAC VF_I CSU 'TITR' MOT_I ;
FIN B1 ;

PAGE 62
 CHAP. 3: TRANSIENT LINEAR THERMAL ANALYSIS
PASAPAS

Post processing: plot of heat flux vector and temperature

isovalue lines
* FLUX VECTOR AND TEMPERATURE FIELD AS ISOVALUE LINES
OPTI 'ISOV' 'LIGN' ;
TRAC VF_I T_I SU CSU 15 ;
OPTI 'ISOV' 'SURF' ;

PAGE 63
 CHAP. 4: TRANSIENT NON-LINEAR THERMAL ANALYSIS
CONVECTION, RADIATION, PASAPAS

Objective: previous thermal calculations

+ convection
+ radiation

1. addition of a model and loading for convection

2. addition of a model and loading for radiation

T∞ = 25 °C
ε = 0.8

-3,5 104 W.m-2 T∞ = 25 °C

h = 100 W.K-1.m-2

250 °C
PAGE 64
 CHAP. 4: TRANSIENT NON-LINEAR THERMAL ANALYSIS
CONVECTION, RADIATION, PASAPAS

Thermal model for convection

* RIGHT LINE RECOVERY
X1 = COOR SU 1 ;
PLD = X1 POIN 'EGAL' LONG ;
LD = CSU ELEM 'APPU' 'STRI' PLD ;

* CONVECTION MODEL DEFINITION ON THE RIGHT LINE

MOC = MODE LD 'THERMIQUE' 'CONVECTION' ;

* MATERIAL PROPERTIES DEFINING THE HEAT TRANSFER COEFFICIENT

MAC = MATE MOC 'H' 100. ;

Convection temperature loading

* LOADING FOR CONVECTION: SURROUNDINGS TEMPERATURE
* (SUPPOSED CONSTANT)
CHTC = MANU 'CHPO' LD 1 'T' T0 ;
CHACONV = CHAR 'TECO' CHTC EVT2 ;
PAGE 65
 CHAP. 4: TRANSIENT NON-LINEAR THERMAL ANALYSIS
CONVECTION, RADIATION, PASAPAS

Radiation heat transfer Model

* RADIATION MODEL ON THE UPPER LINE
* AND MATERIAL PROPERTIES DEFINING THE EMISSIVITY
MOR = MODE LHAUT 'THERMIQUE' 'RAYONNEMENT' 'INFINI' ;
MAR = MATE MOR 'EMIS' 0.8 ;

Loading with the surroundings temperature

* RADIATION LOADING IS THE SURROUNDINGS TEMPERATURE

* (SUPPOSED CONSTANT)
CHTR = MANU 'CHPO' LHAUT 1 'T' T0 ;
CHARAYE = CHAR 'TERA' CHTR EVT2 ;

PAGE 66
 CHAP. 4: TRANSIENT NON-LINEAR THERMAL ANALYSIS
CONVECTION, RADIATION, PASAPAS

PASAPAS table building

* RE-DEFINITION OF TABLE TAB1 FOR PASAPAS PROCEDURE
TAB1 = TABL ;
TAB1 . 'MODELE' = (It’s up to you) ;
TAB1 . 'CARACTERISTIQUES' = (It’s up to you) ;
TAB1 . 'BLOCAGES_THERMIQUES' = (It’s up to you) ;
TAB1 . 'CHARGEMENT' = (It’s up to you) ;
TAB1 . 'TEMPS_CALCULES' = (It’s up to you) ;
TAB1 . 'TEMPERATURES' = (It’s up to you) ;
TAB1 . 'TEMPERATURES' . 0 = (It’s up to you) ;
TAB1 . 'CELSIUS' = VRAI ;

Solving with PASAPAS procedure

* PASAPAS CALL
(It’s up to you)

PAGE 67
 CHAP. 4: TRANSIENT NON-LINEAR THERMAL ANALYSIS
CONVECTION, RADIATION, PASAPAS

Post processing
* RE-DEFINITION OF TABLE TAB1 FOR PASAPAS PROCEDURE
TAB1 = TABL ;
TAB1 . 'MODELE' = MOT ET MOC ET MOR ;
TAB1 . 'CARACTERISTIQUES' = MAT ET MAC ET MAR ;
TAB1 . 'BLOCAGES_THERMIQUES' = BLT ;
TAB1 . 'CHARGEMENT' = CHT ET CHACONV ET CHARAYE ;
TAB1 . 'TEMPS_CALCULES' = PROG 0. 'PAS' (0.02 * TPSFIN) TPSFIN ;
TAB1 . 'TEMPERATURES' = TABL ;
TAB1 . 'TEMPERATURES' . 0 = T_INI ;
TAB1 . 'CELSIUS' = VRAI ;

Solving with PASAPAS procedure

* PASAPAS CALL
PASAPAS TAB1 ;

PAGE 68
 CHAP. 4: TRANSIENT NON-LINEAR THERMAL ANALYSIS
CONVECTION, RADIATION, PASAPAS

Post processing
* LOCAL TEMPERATURE A FUNCTION OF TIME

It’s up to you ...

PAGE 69
 CHAP. 4: TRANSIENT NON-LINEAR THERMAL ANALYSIS
CONVECTION, RADIATION, PASAPAS

Post processing
* LOCAL TEMPERATURE AS A FUNCTION OF TIME
EV11 = EVOL 'ROUG' 'TEMP' TAB1 'TEMPERATURES' 'T' PMIL ;
EV22 = EVOL 'BLEU' 'TEMP' TAB1 'TEMPERATURES' 'T' PG ;
TL = TABL ;
TL . 1 = 'TIRR' ;
TL . 2 = 'TIRR' ;
TL . 'TITRE' = TABL ;
TL . 'TITRE' . 1 = 'PMIL cond only' ;
TL . 'TITRE' . 2 = 'PG cond only' ;
TL . 'TITRE' . 3 = 'PMIL cond+conv+rad' ;
TL . 'TITRE' . 4 = 'PG cond+conv+rad' ;
DESS (EV1 ET EV2 ET EV11 ET EV22) 'LEGE' TL ;

PAGE 70
 CHAP. 4: TRANSIENT NON-LINEAR THERMAL ANALYSIS
CONVECTION, RADIATION, PASAPAS

Saving data and end of program

OPTI 'SAUV' 'formation_debutant_2_thermique.sauv' ;
SAUV ;

FIN ;

PAGE 71
 CHAP. 5: ELASTIC MECHANICAL ANALYSIS

Objective: linear elastic calculations

with imposed displacements and pressure

Linear system: 𝐾 𝑢 = 𝐹
1. stiffness matrix calculation 𝐾 (1st member)
2. nodal forces calculation 𝐹 (2nd member)
3. solving with RESO  displacements 𝑢 (unknown)

σ = 100 MPa

Ux = 0 Uy = 0 PAGE 72
 CHAP. 5: ELASTIC MECHANICAL ANALYSIS

Input data from previous computation (mesh, parameters, …)

OPTI 'REST' 'formation_debutant_2_thermique.sauv' ;
REST ;

Plane stress hypothesis

OPTI 'MODE' 'PLAN' 'CONT' ;

Linear elastic isotropic mechanical model

YOUNGMAT = 70.E9 ;
NUMAT = 0.36 ;
ALPHAMAT = 24.E-6 ;
SIGYMAT = 130.E6 ;
MOM1 = MODE SU 'MECANIQUE' 'ELASTIQUE' ;
MAM1 = MATE MOM1 'YOUN' YOUNGMAT 'NU' NUMAT 'ALPH' ALPHAMAT ;

Stiffness matrix (1st member)

RI = RIGI MOM1 MAM1 ;
PAGE 73
 CHAP. 5: ELASTIC MECHANICAL ANALYSIS

Constraints on displacements (1st member)

BLMX = BLOQ PA 'UX' ; (point A locked along x)
BLMY = BLOQ (It's up to you); (lower line locked along y)
RITOT = (It's up to you); (assembly of stiffness)

Nodal forces equivalent to the prescribed pressure (2nd member)

TR = PRES 'MASS' MOM1 LHAUT (-100.E6) ;

Linear system solving

U5 = (It's up to you)

PAGE 74
 CHAP. 5: ELASTIC MECHANICAL ANALYSIS

Constraints on displacements (1st member)

BLMX = BLOQ PA 'UX' ;
BLMY = BLOQ LBAS 'UY' ;
RITOT = RI ET BLMX ET BLMY ;

Nodal forces equivalent to the prescribed pressure (2nd member)

TR = PRES 'MASS' MOM1 LHAUT (-100.E6) ;

Linear system solving

U5 = RESO RITOT TR ;

PAGE 75
 CHAP. 5: ELASTIC MECHANICAL ANALYSIS

Post processing: strains, stresses, deformed mesh

* DEFORMED MESH PLOT
DEF_5 = DEFO SU U5 150. 'ROUG' ;
DEF_INI = DEFO SU U5 0. ;
TRAC (DEF_INI ET DEF_5) ;

* PLOT OF THE DEFORMED MESH BORDER

(It's up to you)

TRAC (DEF_INIC ET DEF_5C) ;

PAGE 76
new object DEFORMEE
 CHAP. 5: ELASTIC MECHANICAL ANALYSIS

Post processing: strains, stresses, deformed mesh

* DEFORMED MESH PLOT
DEF_5 = DEFO SU U5 150. 'ROUG' ;
DEF_INI = DEFO SU U5 0. ;
TRAC (DEF_INI ET DEF_5) ;

* PLOT OF THE DEFORMED MESH BORDER

DEF_5C = DEFO CSU U5 150. 'ROUG' ;
DEF_INIC = DEFO CSU U5 0. ;
TRAC (DEF_INIC ET DEF_5C) ;

PAGE 77
new object DEFORMEE
 CHAP. 5: ELASTIC MECHANICAL ANALYSIS

Post processing: strains, stresses, deformed mesh

With two statements:
ന = 𝐆𝐫𝐚𝐝 𝑢ത
𝐻
* STRAINS CALCULATION 1
DEF = EPSI U5 MOM1 ; 𝜀Ӗ = 𝐻ന+𝐻 ന𝑻 + 𝐻
ന𝑻. 𝐻
ന
2
* STRESSES CALCULATION FROM STRAINS
SIG = ELAS DEF MOM1 MAM1 ; 𝜎ധ = C :𝜀 Ӗ

With one statement:

* STRESSES CALCULATION FROM DISPLACEMENTS
SIG = SIGM U5 MOM1 MAM1 ;

PAGE 78
 CHAP. 5: ELASTIC MECHANICAL ANALYSIS

Post processing: stresses on the deformed mesh

* STRESSES PLOT ON THE INITIAL SHAPE
TRAC (It's up to you) ;

PAGE 79
 CHAP. 5: ELASTIC MECHANICAL ANALYSIS

Post processing: stresses on the deformed mesh

* STRESSES PLOT ON THE INITIAL SHAPE
TRAC SIG MOM1 CSU 15 ;

* STRESSES PLOT ON THE DEFORMED SHAPE

DEF_5B = DEFO SU U5 150. ;
TRAC SIG MOM1 DEF_5B CSU 15 ;

PAGE 80
 CHAP. 5: ELASTIC MECHANICAL ANALYSIS

Post processing: stresses at Gauss points

* STRESS PLOT ON THE MESH
SIGYY = EXCO SIG 'SMYY' ;
MESS 'Mini and Maxi for Sigma YY : ' (MINI SIGYY) (MAXI SIGYY) ;
TRAC SIGYY MOM1 'TITR' '[5] Sig_YY in the mesh' ;

SIGYYG = CHAN 'CHPO' SIGYY MOM1 'SUPP' ;

MPGAUSS = EXTR SIGYYG 'MAIL' ;
TRAC SIGYYG MPGAUSS 'TITR' '[5] Sig_YY at Gauss points' ;

PAGE 81
 CHAP. 5: ELASTIC MECHANICAL ANALYSIS

Post processing: stress concentration evolution curve

(along the lower side)
SIGB = CHAN 'CHPO' SIG MOM1 ;
LBASG = LBAS ELEM 'COMP' PB PA ;
EVSIG = EVOL 'CHPO' SIGB 'SMYY' LBASG ;
EVK = EVSIG / 100.E6 ;
DESS EVK 'TITR' '[5] Stress concentration along LBAS' ;

PAGE 82
 CHAP. 5: ELASTIC MECHANICAL ANALYSIS

Post processing: evolution along any line

OPTI 'ELEM' 'SEG2' ;
LIG1 = DROI 50 (0.1 0.1) (2.3 0.9) COUL 'ORAN' ;
TRAC (CSU ET LIG1) 'TITR' '[5] Random line LIG1' ;

SIGT = CHAN 'NOEUD' MOM1 SIG ;

SIGLBAS = PROI SIGT LIG1 ;
EVSIG2 = EVOL 'ORAN' 'CHPO' SIGLBAS 'SMXY' LIG1 ;
DESS EVSIG2 'TITR' '[5] XY stress along LIG1' ;

PAGE 83
 CHAP. 5: ELASTIC MECHANICAL ANALYSIS

Post processing: force reaction

* SUPPORTS REACTIONS PLOT AS VECTORS
REAC1 = REAC U5 (BLMX ET BLMY) ; (reaction due to a constraint)
VREAC = VECT REAC1 'FORC' 'ROUG' ; (arrows for plotting)

* IDEM FOR APPLIED FORCES

VFIMP = (It's up to you)
TRAC (It's up to you) ;

PAGE 84
 CHAP. 5: ELASTIC MECHANICAL ANALYSIS

Post processing: force reaction

* SUPPORTS REACTIONS PLOT AS VECTORS
REAC1 = REAC U5 (BLMX ET BLMY) ; (reaction due to a constraint)
VREAC = VECT REAC1 'FORC' 'ROUG' ; (arrows for plotting)

* IDEM FOR APPLIED FORCES

VFIMP = VECT TR 'FORC' 'VERT' ;
TRAC (VFIMP ET VREAC) CSU ;

PAGE 85
 CHAP. 5: ELASTIC MECHANICAL ANALYSIS

Bonus: case with prescribed displacements

* STIFFNESS MATRICES (1ST MEMBER) link
BLMY2 = BLOQ LHAUT 'UY' ;
RITOT2 = RI ET BLMX ET BLMY ET BLMY2 ;

* SECOND MEMBER ASSOCIETED TO THE STIFFNESS MATRIX

TR2 = DEPI BLMY2 (8.E-3 * RAYON) ;

* RESOLUTION
U52 = RESO RITOT2 TR2 ;

* POST PROCESSING
DEF_5C2 = DEFO CSU U52 150. 'VERT' ;
TRAC (DEF_INIC ET DEF_5C ET DEF_5C2) ;

PAGE 86
 CHAP. 6: LINEAR ELASTICITY
THERMAL LOADING

Objective: previous mechanical calculation

+ thermal loading

1. thermal strain calculation

2. add the nodal forces equivalent to the thermal strain (link)

PAGE 87
 CHAP. 6: LINEAR ELASTICITY
THERMAL LOADING

Nodal forces resulting from thermal strain (2nd member)

* THERMAL STRAINS FROM TEMPERATURE FIELD CALCULATED
* TAKING INTO ACCOUNT CONVECTION + RADIATION
DELTA_TE = (TAB1 . 'TEMPERATURES' . (N1 - 1)) - T_INI ;
EPT = EPTH DELTA_TE MOM1 MAM1 ; 𝜀 𝑡ℎ
Ӗ = 𝛼∆𝑇
ധ

* PSEUDO STRESS FROM THERMAL STRAINS

SIT = ELAS EPT MOM1 MAM1 ; 𝜎ധ 𝑡ℎ = 𝐂: 𝜀 𝑡ℎ
Ӗ

* NODAL FORCES FROM THIS STRESS

FFT = BSIG SIT MOM1 ; 𝐹 𝑡ℎ = න 𝐵 𝑇 𝜎 𝑡ℎ 𝑑𝑉
𝑉
Linear system solving (additional term to the 2nd member)
* DISPLACEMENTS CALCULATION BY CALLING SOLVER WITH THERMAL PSEUDO FORCES
* ADDED TO THE MECHANICAL ONES
U6 = (It's up to you);

PAGE 88
 CHAP. 6: LINEAR ELASTICITY
THERMAL LOADING

Nodal forces resulting from thermal strain (2nd member)

* THERMAL STRAINS FROM TEMPERATURE FIELD CALCULATED
* TAKING INTO ACCOUNT CONVECTION + RADIATION
DELTA_TE = (TAB1 . 'TEMPERATURES' . (N1 - 1)) - T_INI ;
EPT = EPTH DELTA_TE MOM1 MAM1 ; 𝜀 𝑡ℎ
Ӗ = 𝛼∆𝑇
ധ

* PSEUDO STRESS FROM THERMAL STRAINS

SIT = ELAS EPT MOM1 MAM1 ; 𝜎ധ 𝑡ℎ = 𝐂: 𝜀 𝑡ℎ
Ӗ

* NODAL FORCES FROM THIS STRESS

FFT = BSIG SIT MOM1 ; 𝐹 𝑡ℎ = න 𝐵 𝑇 𝜎 𝑡ℎ 𝑑𝑉
𝑉
Linear system solving (additional term to the 2nd member)
* DISPLACEMENTS CALCULATION BY CALLING SOLVER WITH THERMAL PSEUDO FORCES
* ADDED TO THE MECHANICAL ONES
U6 = RESO RITOT (TR ET FFT) ;

PAGE 89
 CHAP. 6: LINEAR ELASTICITY
THERMAL LOADING

Post processing: deformed mesh, strains, stresses

* THERMOMECANICAL DEFORMED MESH
DEF_6 = (It's up to you)
DEF_6C = (It's up to you)
TRAC (It's up to you) ;

PAGE 90
 CHAP. 6: LINEAR ELASTICITY
THERMAL LOADING

Post processing: deformed mesh, strains, stresses

* THERMOMECANICAL DEFORMED MESH
DEF_6 = DEFO SU U6 150. ;
DEF_6C = DEFO CSU U6 150. 'ORAN' ;
TRAC (DEF_INIC ET DEF_5C ET DEF_6C) ;

PAGE 91
 CHAP. 6: LINEAR ELASTICITY
THERMAL LOADING

Post processing: deformed mesh, strains, stresses

* TOTAL STRAINS
EP = (It's up to you, EPSI operator)

* ELASTIC STRAINS
EPE = (It's up to you)

* STRESSES CALCULATED FROM ELASTIC STRAINS

SIGT = (It's up to you)
TRAC SIGT MOM1 DEF_6 CSU ;

PAGE 92
 CHAP. 6: LINEAR ELASTICITY
THERMAL LOADING

Post processing: deformed mesh, strains, stresses

* TOTAL STRAINS
EP = EPSI U6 MOM1 ;

* ELASTIC STRAINS
EPE = EP - EPT ;

* STRESSES CALCULATED FROM ELASTIC STRAINS

SIGT = ELAS EPE MOM1 MAM1 ;
TRAC SIGT MOM1 DEF_6 CSU ;

PAGE 93
 CHAP. 7: LINEAR ELASTICITY
THERMAL LOADING, NON UNIFORM PROPERTIES

Objective: previous thermo-mechanical calculation

+ thermal expansion α variable in space

1. calculation of the field α(x) (from coordinates)

2. material property described by α(x)
3. updating of the nodal thermal pseudo forces

𝑥 − 𝑥mean
3 α0
α 𝑥 = α0 1+β
𝑥max − 𝑥min

x
xmin xmean xmax
PAGE 94
 CHAP. 7: LINEAR ELASTICITY
THERMAL LOADING, NON UNIFORM PROPERTIES

Non uniform thermal expansion coefficient

XX = COOR SU 1 ;
XMAX = MAXI XX ;
XMIN = MINI XX ;
XMOY = 0.5 * (XMAX + XMIN) ;

BETA = 7. ;
CHP_ALPH = ALPHAMAT * (1. + (BETA * (((XX - XMOY) / (XMAX - XMIN)) ** 3))) ;

Material properties updating

* CONVERSION FROM CHPOINT -> TO MCHAML
CHM_ALPH = CHAN 'CHAM' CHP_ALPH MOM1 ;

* UPDATING OF THE MATERIAL MCHAML WITH THE NON UNIFORM ALPHA

MAM1B = MATE MOM1 'YOUN' YOUNGMAT 'NU' NUMAT 'ALPH' CHM_ALPH ;

PAGE 95
 CHAP. 7: LINEAR ELASTICITY
THERMAL LOADING, NON UNIFORM PROPERTIES

Updating the nodal forces due to thermal strains

(2nd member)
* UPDATING THE PURE THERMAL STRAINS WITH ALPHA VARIABLE
EPT = (It's up to you, EPTH operator)

* UPDATING THE THERMAL PSEUDO STRESSES WITH ALPHA VARIABLE

SIT = (It's up to you, ELAS operator)

* UPDATING THE NODAL FORCES FOR THESE THERMAL STRAINS

FFT = (It's up to you, BSIG operator)

Linear system solving

* DISPLACEMENTS WITH ALPHA VARIABLE
U7 = RESO RITOT (TR ET FFT) ;

PAGE 96
 CHAP. 7: LINEAR ELASTICITY
THERMAL LOADING, NON UNIFORM PROPERTIES

Updating the nodal forces due to thermal strains

(2nd member)
* UPDATING THE PURE THERMAL STRAINS WITH ALPHA VARIABLE
EPT = EPTH DELTA_TE MOM1 MAM1B ;

* UPDATING THE THERMAL PSEUDO STRESSES WITH ALPHA VARIABLE

SIT = ELAS EPT MOM1 MAM1B ;

* UPDATING THE NODAL FORCES FOR THESE THERMAL STRAINS

FFT = BSIG SIT MOM1 ;

Linear system solving

* DISPLACEMENTS WITH ALPHA VARIABLE
U7 = RESO RITOT (TR ET FFT) ;

PAGE 97
 CHAP. 7: LINEAR ELASTICITY
THERMAL LOADING, NON UNIFORM PROPERTIES

Post processing: deformed mesh, strains, stresses

* DEFORMED SHAPE WITH ALPHA VARIABLE
(It's up to you)
(It's up to you)
TRAC (It's up to you) ;

PAGE 98
 CHAP. 7: LINEAR ELASTICITY
THERMAL LOADING, NON UNIFORM PROPERTIES

Post processing: deformed mesh, strains, stresses

* DEFORMED SHAPE WITH ALPHA VARIABLE
DEF_7 = DEFO SU U7 150. ;
DEF_7C = DEFO CSU U7 150. 'ROUG' ;
TRAC (DEF_INIC ET DEF_6C ET DEF_7C) ;

PAGE 99
 CHAP. 7: LINEAR ELASTICITY
THERMAL LOADING, NON UNIFORM PROPERTIES

Post processing: deformed mesh, strains, stresses

* STRAINS WITH ALPHA VARIABLE
EP = EPSI U7 MOM1 ;

* ELASTIC STRAINS WITH ALPHA VARIABLE

EPE = EP - EPT ;

* STRESSES WITH ALPHA VARIABLE

SIGT = ELAS EPE MOM1 MAM1B ;
TRAC SIGT MOM1 DEF_7 CSU ;

PAGE 100
 CHAP. 8: ELASTO-PLASTIC MECHANICAL ANALYSIS
THERMAL LOADING, NON UNIFORM PROPERTIES, PASAPAS

Objective: previous thermo-mechanical calculation

+ perfect elasto-plastic material

1. starting from the previous transient thermal analysis

2. add a non-linear mechanical model
3. temporal description of mechanical loadings
4. solving with the PASAPAS procedure

σ
σY

E
ε PAGE 101
 CHAP. 8: ELASTO-PLASTIC MECHANICAL ANALYSIS
THERMAL LOADING, NON UNIFORM PROPERTIES , PASAPAS

Model and material properties updating

* MECHANICAL MODEL UPDATING
MOM2 = MODE SU 'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE' 'PARFAIT' ;

* MATERIAL PROPERTIES UPDATING (YIELD STRENGTH 'SIGY' ADDED TO PROPERTIES)

MAM2 = MATE MOM2 'YOUN' YOUNGMAT 'NU' NUMAT 'ALPH' CHM_ALPH
'SIGY' SIGYMAT ;

PAGE 102
 CHAP. 8: ELASTO-PLASTIC MECHANICAL ANALYSIS
THERMAL LOADING, NON UNIFORM PROPERTIES , PASAPAS

Incremental mechanical loading

* TEMPORAL MECHANICAL LOAD DESCRIPTION
EVTM = EVOL 'MANU' 'Time' (PROG 0. (0.98 * TPSFIN) TPSFIN)
'Coef' (PROG 0. 0. 1.) ;
CHM = CHAR 'MECA' EVTM TR ;

Building of the table for PASAPAS procedure

* PASAPAS TABLE
TAB2 = TABL ;

………
………
………
(It's up to you)
………
………
………

PASAPAS TAB2 ;

PAGE 103
 CHAP. 8: ELASTO-PLASTIC MECHANICAL ANALYSIS
THERMAL LOADING, NON UNIFORM PROPERTIES , PASAPAS

Incremental mechanical loading

* TEMPORAL MECHANICAL LOAD DESCRIPTION
EVTM = EVOL 'MANU' 'Time' (PROG 0. (0.98 * TPSFIN) TPSFIN)
'Coef' (PROG 0. 0. 1.) ;
CHM = CHAR 'MECA' EVTM TR ;

Building of the table for PASAPAS procedure

* PASAPAS TABLE
TAB2 = TABL ;
TAB2 . 'MODELE' = MOT ET MOC ET MOR ET MOM2 ;
TAB2 . 'CARACTERISTIQUES' = MAT ET MAC ET MAR ET MAM2 ;
TAB2 . 'BLOCAGES_MECANIQUES' = BLMX ET BLMY ;
TAB2 . 'BLOCAGES_THERMIQUES' = BLT ;
TAB2 . 'CHARGEMENT' = CHT ET CHACONV ET CHARAYE ET CHM ;
TAB2 . 'TEMPS_CALCULES' = PROG 0. 'PAS' (0.02 * TPSFIN) (0.98 * TPSFIN)
'PAS' (0.001 * TPSFIN) TPSFIN ;
TAB2 . 'TEMPERATURES' = TABL ;
TAB2 . 'TEMPERATURES' . 0 = T_INI ;
TAB2 . 'CELSIUS' = VRAI ;
PASAPAS TAB2 ;

PAGE 104
 CHAP. 8: ELASTO-PLASTIC MECHANICAL ANALYSIS
THERMAL LOADING, NON UNIFORM PROPERTIES , PASAPAS

Post processing: deformed mesh

* COMPARISON OF THE FINAL DEFORMED MESH WITH PREVIOUS RESULTS
N2 = DIME (TAB2 . 'DEPLACEMENTS') ;
U8 = TAB2 . 'DEPLACEMENTS' . (N2 - 1) ;
DEF_8 = (It's up to you)
DEF_8C = (It's up to you)
TRAC (DEF_INIC ET DEF_7C ET DEF_8C) ;

PAGE 105
 CHAP. 8: ELASTO-PLASTIC MECHANICAL ANALYSIS
THERMAL LOADING, NON UNIFORM PROPERTIES , PASAPAS

Post processing: deformed mesh

* COMPARISON OF THE FINAL DEFORMED MESH WITH PREVIOUS RESULTS
N2 = DIME (TAB2 . 'DEPLACEMENTS') ;
U8 = TAB2 . 'DEPLACEMENTS' . (N2 - 1) ;
DEF_8 = DEFO SU U8 150. ;
DEF_8C = DEFO CSU U8 150. 'VIOL' ;
TRAC (DEF_INIC ET DEF_7C ET DEF_8C) ;

PAGE 106
 CHAP. 8: ELASTO-PLASTIC MECHANICAL ANALYSIS
THERMAL LOADING, NON UNIFORM PROPERTIES , PASAPAS

Post-processing: stresses
* LOOP ON EACH TIME STEP
LISO2 = PROG 0. 'PAS' 10.E6 160.E6 ;
REPE B1 N2 ;
U_I = TAB2 . 'DEPLACEMENTS' . (&B1 - 1) ;
DEF_I = DEFO SU U_I 150. ;
S_I = TAB2 . 'CONTRAINTES' . (&B1 - 1) ;
TRAC S_I MOM2 DEF_I CSU LISO2 ;
FIN B1 ;

PAGE 107
 CHAP. 8: ELASTO-PLASTIC MECHANICAL ANALYSIS
THERMAL LOADING, NON UNIFORM PROPERTIES , PASAPAS

Post-processing: cumulated plastic strains (link)

* LOOP ON EACH TIME STEP
VI = TAB2 . 'VARIABLES_INTERNES' . (N2 - 1) ;
EQ_MAX = MAXI (EXCO 'EPSE' VI) ;
LISO3 = PROG 0. 'PAS' (EQ_MAX / 15.) EQ_MAX ;
REPE B1 N2 ;
U_I = TAB2 . 'DEPLACEMENTS' . (&B1 - 1) ;
DEF_I = DEFO SU U_I 150. ;
V_I = TAB2 . 'VARIABLES_INTERNES' . (&B1 - 1) ;
TRAC V_I MOM2 DEF_I CSU LISO3 ;
FIN B1 ;

PAGE 108
 CHAP. 9: ELASTO-PLASTIC MECHANICAL ANALYSIS
THERMAL LOADING, VARIABLE PROPERTIES (X,T), PASAPAS

Objective: previous thermo-mechanical calculation

+ stress yield depending on temperature

1. variable material property depending on the thermal unknown

σY

300 MPa

100 MPa

T
50 °C 200 °C PAGE 109
 CHAP. 9: ELASTO-PLASTIC MECHANICAL ANALYSIS
THERMAL LOADING, VARIABLE PROPERTIES (X,T), PASAPAS

Updating of material properties

* VARIATION OF YIELD STRESS AS A FUNCTION OF T
EVSIGY = EVOL 'MANU' 'T' (PROG 50. 200.) 'SIGY' (PROG 300.E6 100.E6) ;

* UPDATING OF THE MATERIAL

MAM2 = MATE MOM2 'YOUN' YOUNGMAT 'NU' NUMAT 'ALPH' CHM_ALPH
'SIGY' EVSIGY ;

PASAPAS call
(It's up to you)

PAGE 110
 CHAP. 9: ELASTO-PLASTIC MECHANICAL ANALYSIS
THERMAL LOADING, VARIABLE PROPERTIES (X,T), PASAPAS

Updating of material properties

* VARIATION OF YIELD STRESS AS A FUNCTION OF T
EVSIGY = EVOL 'MANU' 'T' (PROG 50. 200.) 'SIGY' (PROG 300.E6 100.E6) ;

* UPDATING OF THE MATERIAL

MAM2 = MATE MOM2 'YOUN' YOUNGMAT 'NU' NUMAT 'ALPH' CHM_ALPH
'SIGY' EVSIGY ;

PASAPAS call
TAB2 = TABL ;
TAB2 . 'MODELE' = MOT ET MOC ET MOR ET MOM2 ;
TAB2 . 'CARACTERISTIQUES' = MAT ET MAC ET MAR ET MAM2 ;
TAB2 . 'BLOCAGES_MECANIQUES' = BLMX ET BLMY ;
TAB2 . 'BLOCAGES_THERMIQUES' = BLT ;
TAB2 . 'CHARGEMENT' = CHT ET CHACONV ET CHARAYE ET CHM ;
TAB2 . 'TEMPS_CALCULES' = PROG 0. 'PAS' (0.02 * TPSFIN) (0.98 * TPSFIN)
'PAS' (0.001 * TPSFIN) TPSFIN ;
TAB2 . 'TEMPERATURES' = TABL ;
TAB2 . 'TEMPERATURES' . 0 = T_INI ;
TAB2 . 'CELSIUS' = VRAI ;
PASAPAS TAB2 ;
PAGE 111
 CHAP. 9: ELASTO-PLASTIC MECHANICAL ANALYSIS
THERMAL LOADING, VARIABLE PROPERTIES (X,T), PASAPAS

Post processing: deformed mesh

* COMPARISON OF THE FINAL SHAPE WITH THOSE OF THE PREVIOUS CALCULATIONS
N2 = DIME (TAB2 . 'DEPLACEMENTS') ;
U9 = TAB2 . 'DEPLACEMENTS' . (N2 - 1) ;
DEF_9 = DEFO SU U9 150. ;
DEF_9C = DEFO CSU U9 150. 'BLEU' ;
TRAC (DEF_INIC ET DEF_7C ET DEF_8C ET DEF_9C) ;

PAGE 112
 CHAP. 9: ELASTO-PLASTIC MECHANICAL ANALYSIS
THERMAL LOADING, VARIABLE PROPERTIES (X,T), PASAPAS

Post processing: cumulated plastic strains

VI = TAB2 . 'VARIABLES_INTERNES' . (N2 - 1) ;
EQ_MAX = MAXI (EXCO 'EPSE' VI) ;
LISO3 = PROG 0. 'PAS' (EQ_MAX / 15.) EQ_MAX ;
REPE B1 N2 ;
U_I = TAB2 . 'DEPLACEMENTS' . (&B1 - 1) ;
DEF_I = DEFO SU U_I 150. ;
V_I = TAB2 . 'VARIABLES_INTERNES' . (&B1 - 1) ;
TRAC V_I MOM2 DEF_I CSU LISO3 ;
FIN B1 ;

PAGE 113
ADDENDA
 TRUSS, BEAM, SHELL, JOINT … F.E.

The choice of the finite elements is made in MODE

MODP1 = MODE LIG1 'MECANIQUE' 'ELASTIQUE' | 'POUT' | ;
| 'TIMO' |

MODC1 = MODE SUR1 'MECANIQUE' 'ELASTIQUE' | 'DKT' | ;

| 'COQ8' |

You should give the geometrical characteristics

MATP1 = MATE MODP1 'YOUN' 210.E9 'NU ' 0.3
'SECT' 1.E-2 'INRY' 1.E-4 'INRZ' 2.E-4 'TORS' 3.E-4 ;

MATC1 = MATE MODC1 'YOUN' 210.E9 'NU ' 0.3

'EPAI' 1.E-2 ;

Then you can prescribe d.o.f. for displacements and rotation

BL1 = BLOQ P1 'UX' 'UY' 'UZ' 'RX' 'RY' 'RZ' ; PAGE 115
 READING / WRITING DATA

Binary file: backup / recovery

OPTI 'SAUV' 'foo' ; SAUV ;
OPTI 'REST' 'foo' ; REST ;

Also possible by a text file

Run an EXTErnal command

TAB1 = EXTE 'grep –in mechanical foo.dgibi' 'RC' ;
 TAB1 contents the output of the grep command

The ACQUisition command

Read a texte file, line by line
OPTI 'ACQU' 'foo.txt' ;
ACQU N1*'ENTIER' A*'FLOTTANT' ; foo.txt
ACQU N2*'ENTIER' L1*'LISTREEL' 3 ;
1 3.14 X Y
2 25.2 28.3 24.3
PAGE 116
 READING / WRITING DATA

Writing in a text file

 by changing the standard output stream
OPTI 'ECHO' 0 ;
OPTI 'IMPR' 42 'IMPR' 'foo.txt' ;

MESS 'I am writing in a text file!' ;

MESS 4 8 15 16 23 42 ;
foo.txt
MESS ;
I am writing in a text file!
4 8 15 16 23 42
MESS '#iteration Fibonacci' ;
#iteration Fibonacci
FIBO1 = 0 ; 0 0
FIBO2 = 1 ; 1 1
2 1
MESS 0 ' ' FIBO1 ; 3 2
MESS 1 ' ' FIBO2 ; 4 3
5 5
REPE B1 15 ; 6 8
FIBO2B = FIBO2 ; 7 13
8 21
FIBO2 = FIBO1 + FIBO2 ; 9 34
10 55
FIBO1 = FIBO2B ; 11 89
MESS (&B1 + 1) ' ' FIBO2 ; 12 144
13 233
FIN B1 ; 14 377
OPTI 'IMPR' 6 ; 15 610
16 987

PAGE 117
 READING / WRITING DATA

LIRE / SORT reading / writing different file formats

Read/write tabular data (CSV or other)

concerned objects: lists, TABLE
used by text editors, spreadsheet (Excel)
OPTI 'SORT' 'foo.csv' ;
SORT 'EXCE' OBJECT1 ;
TAB1 = 'LIRE' 'CSV' 'foo.csv' ;

The column separator can be changed:

semicolon, comma, space, tab, slash

PAGE 118
 READING / WRITING DATA

LIRE / SORT reading / writing different file formats

Read the UNV format (text file)

concerned objects: MAILLAGE (meshes)
used by Gmsh, Salomé, HyperMesh, …
TAB1 = LIRE 'UNV' 'foo.unv' ;

Read/wrtite the AVS format (text file)

concerned objects: MAILLAGE, CHPOINT, MCHAML
.inp extension used by Abaqus
OPTI 'SORT' 'foo.inp' ;
SORT 'AVS' OBJET1 'TEMPS' 12.3 ;
OPTI 'LECT' 'foo.inp' ;
TAB1 = LIRE 'AVS' ;
PAGE 119
 READING / WRITING DATA

LIRE / SORT reading / writing different file formats

Write the VTK format

concerned objects: MAILLAGE, CHPOINT, MCHAML
used by Paraview
OPTI 'SORT' 'foo.vtk' ;
SORT 'VTK' MAIL1 'SCREW' MAIL2 'NUT'
DEP1 'DISPLACEMENTS' SIG1 'STRESSES' ;

PAGE 120
 READING / WRITING DATA

LIRE / SORT reading / writing different file formats

Read/write the MED format

concerned objects: MAILLAGE, CHPOINT, TABLE (from PASAPAS)
used by Salomé, Europlexus
OPTI 'SORT' 'foo.med' ;
SORT 'MED' OBJET1 ;
TAB1 = LIRE 'MED' 'foo.med' ;

Read the FEM fomat

concerned objetcs: MAILLAGE
used by HyperMesh (Altair)
TAB1 = LIRE 'FEM' 'foo.fem' ;
PAGE 121
 DEVELOPMENT: GIBIANE PROCEDURES

Concatenate all procedures in a text file

with the .procedur extension

Launch castem19 with the –u option

castem19 –u

 Cast3M creates a file named UTILPROC (direct access file)

When Cast3M will be launched all procedures will be available

The UTILPROC file must be present in the working directory

Idem for notices (manual pages) (.notice extension files)

PAGE 122
 DEVELOPMENT: ESOPE SOURCES

The user can modify/correct/add the source code of

operators and directives

Compilation of Esope source files

compilcast19 toto.eso
Compilcast19 tata.eso

Linking
essaicast19
 creation of a binary executable file : cast_64_19
 local version of Cast3M

Can be launched as usual

castem19 mon_fichier.dgibi

PAGE 123
 AND TO COMPLETE

Peruse documentation regularly

~70 instructions reviewed during this course
Around 1400 available instructions!

Subscription to the Cast3M mailing list (see the Cast3M web site)
Send an e-mail at [email protected] with in the message frame:
SUB cast3m-util your_name your_firstname

and nothing more! (no object, no signature, …)

Club Cast3M: annual users seminar

Each year in November in the south of Paris
Presentation of studies performed with Cast3M, developments in the
next release
Free registration!

PAGE 124
 PLANE LINEAR THERMAL ELASTICITY
(1) EQUATIONS

𝜕𝑢
Displacements gradient ന = 𝐆𝐫𝐚𝐝 𝑢ത
𝐻 𝐻𝑖𝑗 = 𝜕𝑥𝑖 = 𝑢𝑖,𝑗
𝑖

1
Total strains (Green Lagrange) ന+𝐻
𝜀Ӗ = 2 𝐻 ന𝑻 + 𝐻
ന𝑻 . 𝐻
ന

Strains partition 𝜀 Ӗ = 𝜀 𝑒Ӗ +𝜀 Ӗ𝑡ℎ

Thermal strains Ӗ = 𝛼∆𝑇 𝛿Ӗ

𝜀 𝑡ℎ
Behavior law 𝜎ധ = C : 𝜀 𝑒Ӗ = C ∶ 𝜀 Ӗ − 𝜀 𝑡ℎ
Ӗ

with: 𝑢ത displacement
𝜀Ӗ total strain 𝜎ധ stress
𝜀 𝑒Ӗ elastic strain 𝜀 Ӗ𝑡ℎ thermal strain
𝛿Ӗ identity tensor
C stiffness tensor (4th order)
𝛼 thermal expansion
∆𝑇 temperature increment
PAGE 125
 PLANE LINEAR THERMAL ELASTICITY
(2) PLANE STRESSES

Plane stresses hypothesis:

𝜎11 𝜎12 0 𝜀11 𝜀12 0
𝜎ധ = 𝜎12 𝜎22 0 𝜀 Ӗ = 𝜀12 𝜀22 0
0 0 0 0 0 𝜀33

Vector notation:
𝜎11 𝜀11 𝜈
with: 𝜀33 = − 𝜀11 + 𝜀22
𝜎 = 𝜎22 𝜀 = 𝜀22 𝐸
3 independent components
𝜎12 2𝜀12

Hooke's law:
𝜎11 1 𝜈 0 𝜀11
𝐸 𝜈 1 0
𝜎22 = 𝜀22
1 − 𝜈2 1−𝜈
𝜎12 0 0 2𝜀12
2
𝜎 = 𝐶 𝜀 𝐶 stiffness matrix

PAGE 126
 PLANE LINEAR THERMAL ELASTICITY
(3) FINITE ELEMENTS
𝑞1𝐵
Interpolation of primal unknowns: 𝑞2𝐵
B

𝑢(𝑥) = 𝑁(𝑥) 𝑞
at each point (𝑥, 𝑦) in the element A
𝑞1𝐴 C 𝑞1𝐶
𝑞 are the displacements of the element nodes
𝑞2𝐴 𝑞2𝐶

Case of a TRI3 element (6 dof): 𝑞1𝐴

𝑞2𝐴
𝑢𝑥 (𝑥) 𝑁 (𝑥) 0 𝑁𝐵 (𝑥) 0 𝑁𝐶 (𝑥) 0 𝑞1𝐵
= 𝐴
𝑢𝑦 (𝑥) 0 𝑁𝐴 (𝑥) 0 𝑁𝐵 (𝑥) 0 𝑁𝐶 (𝑥) 𝑞2𝐵
𝑞1𝐶
𝑞2𝐶
Strains (linearized):
𝑁𝐴,𝑥1 0 𝑁𝐵,𝑥1 0 𝑁𝐶,𝑥1 0
𝜕𝑁𝐴 (𝑥)
𝜀(𝑥) = 0 𝑁𝐴,𝑥2 0 𝑁𝐵,𝑥2 0 𝑁𝐶,𝑥2 𝑞 with 𝑁𝐴,𝑥𝑖 =
𝜕𝑥𝑖
𝑁𝐴,𝑥1 𝑁𝐴,𝑥2 𝑁𝐵,𝑥1 𝑁𝐵,𝑥2 𝑁𝐶,𝑥1 𝑁𝐶,𝑥2

𝐵(𝑥) discrete gradient operator PAGE 127

𝜀(𝑥) = 𝐵(𝑥) 𝑞
 PLANE LINEAR THERMAL ELASTICITY
(4) STIFFNESS MATRIX

Elementary elastic energy:

1
𝑒𝑑𝑒𝑓 = න 𝜎:ധ 𝜀 Ӗ 𝑑𝑉
2 𝑉𝑒
1 𝑇
= න 𝜀 𝜎 𝑑𝑉
2 𝑉𝑒
1 𝑇 𝑇
= න 𝑞 𝐵 𝐶 𝐵 𝑞 𝑑𝑉
2 𝑉𝑒
1 𝑇 𝑇 𝑉𝑒 finite element "volume"
= 𝑞 න 𝐵 𝐶 𝐵 𝑑𝑉 𝑞
2 𝑉𝑒
𝑘𝑒 elementary stiffness matrix
(obtained by numerical computation)
𝑘𝑒

Assembly:
𝑄 nodes displacements (global mesh)
1 𝑇
1 𝑇 The 𝑘𝑒 matrices are extended on all dof
𝐸𝑑𝑒𝑓 = 𝑄 ෍ 𝑘𝑒 𝑄 = 𝑄 𝐾 𝑄
2 2 with null items
𝑒 𝐾 assembly stiffness matrix

PAGE 128
 PLANE LINEAR THERMAL ELASTICITY
(5) PRINCIPLE OF VIRTUAL WORK

Principle of virtual work: 𝑓ഥ𝑣 prescribed volume forces

𝑓ഥ𝑠 prescribed surface forces

ധ 𝛿 𝜀 ∗Ӗ 𝑑𝑉 = න 𝑓ഥ𝑣 𝛿 𝑢ത ∗ 𝑑𝑉 + න 𝑓ഥ𝑠 𝛿 𝑢ത ∗ 𝑑𝑆
න 𝜎:
𝑉𝑒 𝑉𝑒 𝑆𝑒

න 𝛿𝜀 ∗ 𝑇 𝜎 𝑑𝑉 = න 𝛿𝑢∗ 𝑇 𝑓𝑣 𝑑𝑉 + න 𝛿𝑢∗ 𝑇 𝑓𝑠 𝑑𝑆
𝑉𝑒 𝑉𝑒 𝑆𝑒

𝛿𝑞 ∗ 𝑇
න 𝐵 𝑇
𝜎 𝑑𝑉 = 𝛿𝑞 ∗ 𝑇
න 𝑁 𝑇
𝑓𝑣 𝑑𝑉 + න 𝑁 𝑇
𝑓𝑠 𝑑𝑆
𝑉𝑒 𝑉𝑒 𝑆𝑒

𝑇 𝑇 𝑇
න 𝐵 𝐶 𝐵 𝑑𝑉 𝑞 = න 𝑁 𝑓𝑣 𝑑𝑉 + න 𝑁 𝑓𝑠 𝑑𝑆
𝑉𝑒 𝑉𝑒 𝑆𝑒
𝑘𝑒 𝐹𝑒

𝑘𝑒 𝑞 = 𝐹𝑒 𝐹𝑒 nodal equivalent forces

PAGE 129
 PLANE LINEAR THERMAL ELASTICITY
(6) THERMAL LOAD

We add a second member item:

න 𝐵 𝑇 𝜎 𝑑𝑉 = 𝐹𝑒
𝑉𝑒

න 𝐵 𝑇 𝐶 𝜀 − 𝜀 𝑡ℎ 𝑑𝑉 = 𝐹𝑒
𝑉𝑒

න 𝐵 𝑇 𝐶 𝜀 𝑑𝑉 = 𝐹𝑒 + න 𝐵 𝑇 𝐶 𝜀 𝑡ℎ 𝑑𝑉
𝑉𝑒 𝑉𝑒
𝐹𝑡ℎ

𝑘𝑒 𝑞 = 𝐹𝑒 + 𝐹𝑡ℎ

PAGE 130
 STIFFNESS AND LAGRANGE MULTIPLIERS

Mechanics deals with the following constrained problem:

𝑏 constraints matrix
𝐾 𝑄 = 𝐹 𝑄0 imposed values
ቊ
𝑏 𝑄 = 𝑄0
We have to minimize the following function:
1
𝑓 𝑄 = 𝑄 𝑇. 𝐾 . 𝑄 − 𝑄 𝑇. 𝐹
2
with the constrain: 𝑏 𝑄 − 𝑄0 = 0

The Lagrange theorem introduces new unknowns 𝜆 so that:

𝑇
𝐾 𝑄 − 𝐹 +𝑏 𝜆 = 0

We have to solve the following linear system:

𝐾 𝑏𝑇 𝑄 𝐹
=
𝑏 0 𝜆 𝑄0 PAGE 131
 STIFFNESS AND LAGRANGE MULTIPLIERS

Example: one bar element

OPTI 'DIME' 2 'ELEM' 'SEG2' ;

* Mesh
p1 = 0. 0. ;
p2 = 3. 0. ;
l1 = DROI 1 p1 p2 ; 𝑘 0 −𝑘 0 𝑈𝑋1 𝐹𝑋1
𝑈𝑌1 𝐹𝑌1
* Model and properties rig1 = 0 0 0 0
mo = MODE l1 'MECANIQUE' 'BARR' ; −𝑘 0 𝑘 0 𝑈𝑋2 𝐹𝑋2
ma = MATE mo 'YOUN' 210.E9 'NU' 0.3
'SECT' 1.E-2 ;
0 0 0 0 𝑈𝑌2 𝐹𝑌2
* Main stiffness matrix 0 1 𝐿𝑋3 𝐹𝐿𝑋3
bl1 =
rig1 = RIGI mo ma ; 1 0 𝑈𝑋1 𝐹𝑋1
LIST rig1 ;
𝑘+0 0 −𝑘 0 1 𝑈𝑋1 𝐹𝑋1
* Constraint matrix
bl1 = BLOQ 'UX' p1 ; 0 0 0 0 0 𝑈𝑌1 𝐹𝑌1
LIST bl1 ; rig1 ET bl1 = −𝑘 0 𝑘 0 0 𝑈𝑋2 𝐹𝑋2
* Second member 0 0 0 0 0 𝑈𝑌2 𝐹𝑌2
f1 = DEPI bl1 1.2 ; 1 0 0 0 0 𝐿𝑋3 𝐹𝐿𝑋3
LIST f1 ;

PAGE 132
lien 1 lien 2 𝐹𝐿𝑋3 = 1,2
 ACCUMULATED PLASTIC STRAIN

Definition

𝑡
2 ሶ𝑝 ሶ𝑝 2 𝑝 𝑝
𝑝 𝑡 = න 𝑝ሶ 𝜏 𝑑𝜏 𝑝ሶ = 𝜀Ӗ : 𝜀Ӗ = 𝜀ሶ 𝜀ሶ
0 3 3 𝑖𝑗 𝑖𝑗

Meaning

Measure of the length of the flow trajectory in the plastic strain space
𝜺𝒑 (𝒕𝟐 )
𝜀 𝑝 𝐼𝐼𝐼

(link) 𝜺𝒑 (𝒕𝟏 )

𝜀 𝑝 𝐼𝐼
𝜀𝑝 𝐼
PAGE 133
DESCRIPTION OF GIBIANE OBJECTS
 OBJECTS DESCRIPTION

General objects
ENTIER Integer
FLOTTANT Real
MOT Characters string
LOGIQUE Boolean (TRUE and FALSE)
LISTENTI List of integers

LISTREEL List of reals

LISTMOT List of word (restricted to 4 digits)
TABLE Set of objects of various types characterized by
an index of various types
EVOLUTIO Representation of a function,
couple of lists (x ; f(x)) PAGE 135
 OBJECTS DESCRIPTION

Objects for meshing

POINT Coordinates of a point of the space + density
MAILLAGE Region of the discretized space

Objects for calculation

CHPOINT Any data type defined at the mesh nodes

(floating, Boolean, fields, …)

MMODEL Association of a type of finite element

and a material behavior with a mesh
Defines the primal / dual unknowns
ex: displacements / forces temperature / heat flux

PAGE 136
 OBJECTS DESCRIPTION

Objects for calculation (continuation)

MCHAML Any data type defined inside the mesh elements
(floating, Boolean, fields, …).
Various supports
(Gauss points, center of gravity, nodes, …)
RIGIDITE Stiffness, mass, conductivity matrix, …
Coupling the physical unknowns
CHARGEME Loading spatio-temporal description

Objects for post processing

VECTEUR To visualize multi component fields

DEFORMEE To visualize a deformed mesh

PAGE 137
François DI PAOLA DEN/DANS
Commissariat à l'énergie atomique et aux énergies alternatives DM2S
Centre de Saclay | 91191 Gif-sur-Yvette Cedex SEMT

Etablissement public à caractère industriel et commercial | R.C.S Paris B 775 685 019