flake.nix

   1 # SPDX-FileCopyrightText: 2023 Frank Doepper
   2 #
   3 # SPDX-License-Identifier: GPL-3.0-only
   4
   5 # thank https://magnus.therning.org/2022-03-13-simple-nix-flake-for-haskell-development.html !
   6 {
   7   inputs = {
   8     nixpkgs.url = "nixpkgs/nixos-unstable";
   9     flake-utils.url = "flake-utils";
  10   };
  11
  12   outputs = { self, nixpkgs, flake-utils }:
  13     flake-utils.lib.eachDefaultSystem (system:
  14       let
  15         pkgs = nixpkgs.legacyPackages.${system};
  16         t = pkgs.lib.trivial;
  17         hl = pkgs.haskell.lib;
  18         hp = pkgs.haskell.packages.ghc96;
  19         project = { withEnv ? false }:
  20           hp.developPackage {
  21             root = ./.;
  22             name = "amqp-utils";
  23             returnShellEnv = withEnv;
  24             withHoogle = false;
  25             overrides = self: super: rec {
  26               amqp = hl.dontCheck super.amqp_0_22_2;
  27               tls = super.tls_1_7_0;
  28               crypton-connection = super.crypton-connection.override { inherit tls; };
  29             };
  30             modifier = (t.flip t.pipe) [
  31               hl.dontHaddock
  32               hl.enableStaticLibraries
  33               hl.justStaticExecutables
  34               hl.disableLibraryProfiling
  35               hl.disableExecutableProfiling
  36             ];
  37           };
  38       in {
  39         packages.default = project { };
  40         devShells.default = project { withEnv = true; };
  41         apps = builtins.listToAttrs (builtins.map (x: {
  42           name = x;
  43           value = {
  44             type = "app";
  45             program = "${project { }}/bin/${x}";
  46           };
  47         }) [ "agitprop" "konsum" "plane" "arbeite" ]);
  48       });
  49 }