A Definition is a statement that changes the schema of the database, like a createTable, dropTable, or alterTable command. Definitions may be composed using the >>> operator.

Left-to-right composition

createTable adds a table to the schema.

>>> :set -XOverloadedLabels
>>> :{
renderDefinition $
  createTable #tab (int `As` #a :* real `As` #b :* Nil) Nil
:}
"CREATE TABLE \"tab\" (\"a\" int, \"b\" real);"

createTableIfNotExists creates a table if it doesn't exist, but does not add it to the schema. Instead, the schema already has the table so if the table did not yet exist, the schema was wrong. createTableIfNotExists fixes this. Interestingly, this property makes it an idempotent in the Category Definition.

>>> :set -XOverloadedLabels -XTypeApplications
>>> type Table = '[] :=> '["a" ::: 'NoDef :=> 'Null 'PGint4, "b" ::: 'NoDef :=> 'Null 'PGfloat4]
>>> type Schema = '["tab" ::: Table]
>>> :{
renderDefinition
  (createTableIfNotExists #tab (int `As` #a :* real `As` #b :* Nil) Nil :: Definition Schema Schema)
:}
"CREATE TABLE IF NOT EXISTS \"tab\" (\"a\" int, \"b\" real);"

Data types are a way to limit the kind of data that can be stored in a table. For many applications, however, the constraint they provide is too coarse. For example, a column containing a product price should probably only accept positive values. But there is no standard data type that accepts only positive numbers. Another issue is that you might want to constrain column data with respect to other columns or rows. For example, in a table containing product information, there should be only one row for each product number. TableConstraints give you as much control over the data in your tables as you wish. If a user attempts to store data in a column that would violate a constraint, an error is raised. This applies even if the value came from the default value definition.

Column columns column is a witness that column is in columns.

A check constraint is the most generic TableConstraint type. It allows you to specify that the value in a certain column must satisfy a Boolean (truth-value) expression.

>>> :{
renderDefinition $
  createTable #tab
    ( (int & notNull) `As` #a :*
      (int & notNull) `As` #b :* Nil )
    ( check (Column #a :* Column #b :* Nil) (#a .> #b) `As` #inequality :* Nil )
:}
"CREATE TABLE \"tab\" (\"a\" int NOT NULL, \"b\" int NOT NULL, CONSTRAINT \"inequality\" CHECK ((\"a\" > \"b\")));"

A unique constraint ensure that the data contained in a column, or a group of columns, is unique among all the rows in the table.

>>> :{
renderDefinition $
  createTable #tab
    ( int `As` #a :*
      int `As` #b :* Nil )
    ( unique (Column #a :* Column #b :* Nil) `As` #uq_a_b :* Nil )
:}
"CREATE TABLE \"tab\" (\"a\" int, \"b\" int, CONSTRAINT \"uq_a_b\" UNIQUE (\"a\", \"b\"));"

A primaryKey constraint indicates that a column, or group of columns, can be used as a unique identifier for rows in the table. This requires that the values be both unique and not null.

>>> :{
renderDefinition $
  createTable #tab
    ( serial `As` #id :*
      (text & notNull) `As` #name :* Nil )
    ( primaryKey (Column #id :* Nil) `As` #pk_id :* Nil )
:}
"CREATE TABLE \"tab\" (\"id\" serial, \"name\" text NOT NULL, CONSTRAINT \"pk_id\" PRIMARY KEY (\"id\"));"

A foreignKey specifies that the values in a column (or a group of columns) must match the values appearing in some row of another table. We say this maintains the referential integrity between two related tables.

>>> :{
type Schema =
  '[ "users" :::
       '[ "pk_users" ::: 'PrimaryKey '["id"] ] :=>
       '[ "id" ::: 'Def :=> 'NotNull 'PGint4
        , "name" ::: 'NoDef :=> 'NotNull 'PGtext
        ]
   , "emails" :::
       '[  "pk_emails" ::: 'PrimaryKey '["id"]
        , "fk_user_id" ::: 'ForeignKey '["user_id"] "users" '["id"]
        ] :=>
       '[ "id" ::: 'Def :=> 'NotNull 'PGint4
        , "user_id" ::: 'NoDef :=> 'NotNull 'PGint4
        , "email" ::: 'NoDef :=> 'Null 'PGtext
        ]
   ]
:}

>>> :{
let
  setup :: Definition '[] Schema
  setup = 
   createTable #users
     ( serial `As` #id :*
       (text & notNull) `As` #name :* Nil )
     ( primaryKey (Column #id :* Nil) `As` #pk_users :* Nil ) >>>
   createTable #emails
     ( serial `As` #id :*
       (int & notNull) `As` #user_id :*
       text `As` #email :* Nil )
     ( primaryKey (Column #id :* Nil) `As` #pk_emails :*
       foreignKey (Column #user_id :* Nil) #users (Column #id :* Nil)
         OnDeleteCascade OnUpdateCascade `As` #fk_user_id :* Nil )
in renderDefinition setup
:}
"CREATE TABLE \"users\" (\"id\" serial, \"name\" text NOT NULL, CONSTRAINT \"pk_users\" PRIMARY KEY (\"id\")); CREATE TABLE \"emails\" (\"id\" serial, \"user_id\" int NOT NULL, \"email\" text, CONSTRAINT \"pk_emails\" PRIMARY KEY (\"id\"), CONSTRAINT \"fk_user_id\" FOREIGN KEY (\"user_id\") REFERENCES \"users\" (\"id\") ON DELETE CASCADE ON UPDATE CASCADE);"

A type synonym for constraints on a table with a foreign key.

OnDeleteClause indicates what to do with rows that reference a deleted row.

Render OnDeleteClause.

Analagous to OnDeleteClause there is also OnUpdateClause which is invoked when a referenced column is changed (updated).

Render OnUpdateClause.

dropTable removes a table from the schema.

>>> renderDefinition $ dropTable #muh_table
"DROP TABLE \"muh_table\";"

alterTable changes the definition of a table from the schema.

alterTableRename changes the name of a table from the schema.

>>> renderDefinition $ alterTableRename #foo #bar
"ALTER TABLE \"foo\" RENAME TO \"bar\";"

An AlterTable describes the alteration to perform on the columns of a table.

An addConstraint adds a table constraint.

>>> :{
let
  definition :: Definition
    '["tab" ::: '[] :=> '["col" ::: 'NoDef :=> 'NotNull 'PGint4]]
    '["tab" ::: '["positive" ::: Check '["col"]] :=> '["col" ::: 'NoDef :=> 'NotNull 'PGint4]]
  definition = alterTable #tab (addConstraint #positive (check (Column #col :* Nil) (#col .> 0)))
in renderDefinition definition
:}
"ALTER TABLE \"tab\" ADD CONSTRAINT \"positive\" CHECK ((\"col\" > 0));"

A dropConstraint drops a table constraint.

>>> :{
let
  definition :: Definition
    '["tab" ::: '["positive" ::: Check '["col"]] :=> '["col" ::: 'NoDef :=> 'NotNull 'PGint4]]
    '["tab" ::: '[] :=> '["col" ::: 'NoDef :=> 'NotNull 'PGint4]]
  definition = alterTable #tab (dropConstraint #positive)
in renderDefinition definition
:}
"ALTER TABLE \"tab\" DROP CONSTRAINT \"positive\";"

An AddColumn is either NULL or has DEFAULT.

A dropColumn removes a column. Whatever data was in the column disappears. Table constraints involving the column are dropped, too. However, if the column is referenced by a foreign key constraint of another table, PostgreSQL will not silently drop that constraint.

>>> :{
let
  definition :: Definition
    '["tab" ::: '[] :=>
       '[ "col1" ::: 'NoDef :=> 'Null 'PGint4
        , "col2" ::: 'NoDef :=> 'Null 'PGtext ]]
    '["tab" ::: '[] :=> '["col1" ::: 'NoDef :=> 'Null 'PGint4]]
  definition = alterTable #tab (dropColumn #col2)
in renderDefinition definition
:}
"ALTER TABLE \"tab\" DROP COLUMN \"col2\";"

A renameColumn renames a column.

>>> :{
let
  definition :: Definition
    '["tab" ::: '[] :=> '["foo" ::: 'NoDef :=> 'Null 'PGint4]]
    '["tab" ::: '[] :=> '["bar" ::: 'NoDef :=> 'Null 'PGint4]]
  definition = alterTable #tab (renameColumn #foo #bar)
in renderDefinition definition
:}
"ALTER TABLE \"tab\" RENAME COLUMN \"foo\" TO \"bar\";"

An alterColumn alters a single column.

An AlterColumn describes the alteration to perform on a single column.

A setDefault sets a new default for a column. Note that this doesn't affect any existing rows in the table, it just changes the default for future insert and update commands.

>>> :{
let
  definition :: Definition
    '["tab" ::: '[] :=> '["col" ::: 'NoDef :=> 'Null 'PGint4]]
    '["tab" ::: '[] :=> '["col" ::: 'Def :=> 'Null 'PGint4]]
  definition = alterTable #tab (alterColumn #col (setDefault 5))
in renderDefinition definition
:}
"ALTER TABLE \"tab\" ALTER COLUMN \"col\" SET DEFAULT 5;"

A dropDefault removes any default value for a column.

>>> :{
let
  definition :: Definition
    '["tab" ::: '[] :=> '["col" ::: 'Def :=> 'Null 'PGint4]]
    '["tab" ::: '[] :=> '["col" ::: 'NoDef :=> 'Null 'PGint4]]
  definition = alterTable #tab (alterColumn #col dropDefault)
in renderDefinition definition
:}
"ALTER TABLE \"tab\" ALTER COLUMN \"col\" DROP DEFAULT;"

A setNotNull adds a NOT NULL constraint to a column. The constraint will be checked immediately, so the table data must satisfy the constraint before it can be added.

>>> :{
let
  definition :: Definition
    '["tab" ::: '[] :=> '["col" ::: 'NoDef :=> 'Null 'PGint4]]
    '["tab" ::: '[] :=> '["col" ::: 'NoDef :=> 'NotNull 'PGint4]]
  definition = alterTable #tab (alterColumn #col setNotNull)
in renderDefinition definition
:}
"ALTER TABLE \"tab\" ALTER COLUMN \"col\" SET NOT NULL;"

A dropNotNull drops a NOT NULL constraint from a column.

>>> :{
let
  definition :: Definition
    '["tab" ::: '[] :=> '["col" ::: 'NoDef :=> 'NotNull 'PGint4]]
    '["tab" ::: '[] :=> '["col" ::: 'NoDef :=> 'Null 'PGint4]]
  definition = alterTable #tab (alterColumn #col dropNotNull)
in renderDefinition definition
:}
"ALTER TABLE \"tab\" ALTER COLUMN \"col\" DROP NOT NULL;"

An alterType converts a column to a different data type. This will succeed only if each existing entry in the column can be converted to the new type by an implicit cast.

>>> :{
let
  definition :: Definition
    '["tab" ::: '[] :=> '["col" ::: 'NoDef :=> 'NotNull 'PGint4]]
    '["tab" ::: '[] :=> '["col" ::: 'NoDef :=> 'NotNull 'PGnumeric]]
  definition =
    alterTable #tab (alterColumn #col (alterType (numeric & notNull)))
in renderDefinition definition
:}
"ALTER TABLE \"tab\" ALTER COLUMN \"col\" TYPE numeric NOT NULL;"