The basic Logic monad, for performing backtracking computations returning values (e.g. Logic a will return values of type a).

It's important to remember that Logic on its own is just a lawful list monad, behaving exactly as instance Monad []. One should explicitly use methods of MonadLogic such as (>>-) and interleave to get fair conjunction / disjunction. Note that usual lists have an instance of MonadLogic, so maybe you don't need Logic at all.

Technical perspective. Logic is a Boehm-Berarducci encoding of lists. Speaking plainly, its type is identical (up to Identity wrappers) to foldr applied to a given list. And this list itself can be reconstructed by supplying (:) and [].

import Data.Functor.Identity

fromList :: [a] -> Logic a
fromList xs = LogicT $ \cons nil -> foldr cons nil xs

toList :: Logic a -> [a]
toList (LogicT fld) = runIdentity $ fld (\x (Identity xs) -> Identity (x : xs)) (Identity [])

Here is a systematic derivation of the isomorphism. We start with observing that [a] is isomorphic to a fix point of a non-recursive base algebra Fix (ListF a):

newtype Fix f = Fix (f (Fix f))
data ListF a r = ConsF a r | NilF deriving (Functor)

cata :: Functor f => (f r -> r) -> Fix f -> r
cata f = go where go (Fix x) = f (fmap go x)

from :: [a] -> Fix (ListF a)
from = foldr (\a acc -> Fix (ConsF a acc)) (Fix NilF)

to :: Fix (ListF a) -> [a]
to = cata (\case ConsF a r -> a : r; NilF -> [])

Further, Fix (ListF a) is isomorphic to Boehm-Berarducci encoding ListC a:

newtype ListC a = ListC (forall r. (ListF a r -> r) -> r)

from :: Fix (ListF a) -> ListC a
from xs = ListC (\f -> cata f xs)

to :: ListC a -> Fix (ListF a)
to (ListC f) = f Fix

Finally, ListF a r → r is isomorphic to a pair (a → r → r, r), so ListC is isomorphic to the Logic type modulo Identity wrappers:

newtype Logic a = Logic (forall r. (a -> r -> r) -> r -> r)

And wrapping every occurence of r into m gives us LogicT:

newtype LogicT m a = Logic (forall r. (a -> m r -> m r) -> m r -> m r)

Since: 0.5.0

A smart constructor for Logic computations.

Since: 0.5.0

Runs a Logic computation with the specified initial success and failure continuations.

>>> runLogic empty (+) 0
0

>>> runLogic (pure 5 <|> pure 3 <|> empty) (+) 0
8

When invoked with (:) and [] as arguments, reveals a half of the isomorphism between Logic and lists. See description of observeAll for the other half.

Since: 0.2

Extracts the first result from a Logic computation, failing if there are no results.

>>> observe (pure 5 <|> pure 3 <|> empty)
5

>>> observe empty
*** Exception: No answer.

Since Logic is isomorphic to a list, observe is analogous to head.

Since: 0.2

Extracts up to a given number of results from a Logic computation.

>>> let nats = pure 0 <|> fmap (+ 1) nats
>>> observeMany 5 nats
[0,1,2,3,4]

Since Logic is isomorphic to a list, observeMany is analogous to take.

Since: 0.2

Extracts all results from a Logic computation.

>>> observeAll (pure 5 <|> empty <|> empty <|> pure 3 <|> empty)
[5,3]

observeAll reveals a half of the isomorphism between Logic and lists. See description of runLogic for the other half.

Since: 0.2

A monad transformer for performing backtracking computations layered over another monad m.

When m is Identity, LogicT m becomes isomorphic to a list (see Logic). Thus LogicT m for non-trivial m can be imagined as a list, pattern matching on which causes monadic effects.

It's important to remember that LogicT on its own is just a lawful list monad transformer, adding a nondeterministic effect, and its Monad instance behaves just as instance Monad []:

>>> :set -XOverloadedLists
>>> observeMany 9 $ do {x <- [100,200] :: Logic Int; fmap (+x) [1..]}
[101,102,103,104,105,106,107,108,109]
>>> observeMany 9 $ do {[100,200] >>= \x -> fmap (+x) [1..] :: Logic Int}
[101,102,103,104,105,106,107,108,109]

One should explicitly use methods of MonadLogic such as (>>-) and interleave to get fair conjunction / disjunction:

>>> observeMany 9 $ do {[100,200] >>- \x -> fmap (+x) [1..] :: Logic Int}
[101,201,102,202,103,203,104,204,105]

Since: 0.2

Runs a LogicT computation with the specified initial success and failure continuations.

The second argument ("success continuation") takes one result of the LogicT computation and the monad to run for any subsequent matches.

The third argument ("failure continuation") is called when the LogicT cannot produce any more results.

For example:

>>> yieldWords = foldr ((<|>) . pure) empty
>>> showEach wrd nxt = putStrLn wrd >> nxt
>>> runLogicT (yieldWords ["foo", "bar"]) showEach (putStrLn "none!")
foo
bar
none!
>>> runLogicT (yieldWords []) showEach (putStrLn "none!")
none!
>>> showFirst wrd _ = putStrLn wrd
>>> runLogicT (yieldWords ["foo", "bar"]) showFirst (putStrLn "none!")
foo

Since: 0.2

Extracts the first result from a LogicT computation, failing if there are no results at all.

Since: 0.2

Extracts up to a given number of results from a LogicT computation.

Since: 0.2

Extracts all results from a LogicT computation, unless blocked by the underlying monad.

For example, given

>>> let nats = pure 0 <|> fmap (+ 1) nats

some monads (like Identity, Reader, Writer, and State) will be productive:

>>> take 5 $ runIdentity (observeAllT nats)
[0,1,2,3,4]

but others (like ExceptT, and ContT) will not:

>>> take 20 <$> runExcept (observeAllT nats)

In general, if the underlying monad manages control flow then observeAllT may be unproductive under infinite branching, and observeManyT should be used instead.

Since: 0.2

Convert from LogicT to an arbitrary logic-like monad transformer, such as list-t or logict-sequence

For example, to show a representation of the structure of a LogicT computation, l, over a data-like Monad (such as [], Data.Sequence.Seq, etc.), you could write

import ListT (ListT)

show $ fromLogicT @ListT l

Since: 0.8.0.0

Convert from LogicT m to an arbitrary logic-like monad, such as [].

Examples:

fromLogicT = fromLogicTWith d
hoistLogicT f = fromLogicTWith (lift . f)
embedLogicT f = fromLogicTWith f

The first argument should be a monad morphism. to produce sensible results.

Since: 0.8.0.0

Convert a LogicT computation from one underlying monad to another. For example,

hoistLogicT lift :: LogicT m a -> LogicT (StateT m) a

The first argument should be a monad morphism. to produce sensible results.

Since: 0.8.0.0

Convert a LogicT computation from one underlying monad to another.

The first argument should be a monad morphism. to produce sensible results.

Since: 0.8.0.0