The Tcpdump Group git mirrors - tcpslice/blob - configure.ac

   1 dnl Copyright (c) 1995, 1996, 1997, 1999
   2 dnl     The Regents of the University of California.  All rights reserved.
   3 dnl
   4 dnl Process this file with autoconf to produce a configure script.
   5 dnl
   6
   7 #
   8 # See
   9 #
  10 #       https://ftp.gnu.org/gnu/config/README
  11 #
  12 # for the URLs to use to fetch new versions of config.guess and
  13 # config.sub.
  14 #
  15
  16 AC_PREREQ([2.69])
  17 AC_INIT([tcpslice],[m4_esyscmd_s(cat VERSION)])
  18 AC_CONFIG_SRCDIR(tcpslice.c)
  19
  20 AC_CANONICAL_HOST
  21
  22 AC_LBL_C_INIT_BEFORE_CC(V_INCLS)
  23 #
  24 # Try to enable as many C99 features as we can.
  25 # At minimum, we want C++/C99-style // comments.
  26 #
  27 AC_PROG_CC_C99
  28 if test "$ac_cv_prog_cc_c99" = "no"; then
  29         AC_MSG_WARN([The C compiler does not support C99; there may be compiler errors])
  30 fi
  31 AC_LBL_C_INIT(V_CCOPT, V_INCLS)
  32
  33 AC_CHECK_HEADERS(fcntl.h)
  34
  35 #
  36 # Try to arrange for large file support.
  37 #
  38 AC_SYS_LARGEFILE
  39 AC_FUNC_FSEEKO
  40
  41 # OpenBSD, Solaris 9 and Solaris 10 don't have posix_fadvise().
  42 AC_CHECK_FUNCS([posix_fadvise])
  43
  44 AC_LBL_LIBPCAP(V_PCAPDEP, V_INCLS)
  45
  46 AC_MSG_CHECKING([whether to enable the instrument functions code])
  47 AC_ARG_ENABLE([instrument-functions],
  48    [AS_HELP_STRING([--enable-instrument-functions],
  49      [enable instrument functions code [default=no]])],
  50    [],
  51    [enableval=no])
  52 case "$enableval" in
  53 yes)    AC_MSG_RESULT(yes)
  54         AC_CHECK_LIB([bfd], [bfd_init],
  55             [true],
  56             [AC_MSG_ERROR(
  57                [--enable-instrument-functions was given, but test for library libbfd failed. Please install the 'binutils-dev' package.])],
  58             [])
  59         AC_DEFINE(ENABLE_INSTRUMENT_FUNCTIONS, 1,
  60             [define if you want to build the instrument functions code])
  61         LOCALSRC="$LOCALSRC instrument-functions.c"
  62         # Add '-finstrument-functions' instrumentation option to generate
  63         # instrumentation calls for entry and exit to functions.
  64         # Try to avoid Address Space Layout Randomization (ALSR).
  65         CFLAGS="$CFLAGS -O0 -ggdb -finstrument-functions -fno-stack-protector -fno-pic"
  66         LDFLAGS="$LDFLAGS -O0 -ggdb -fno-stack-protector -no-pie"
  67         LIBS="$LIBS -lbfd"
  68         ;;
  69 *)      AC_MSG_RESULT(no)
  70         ;;
  71 esac
  72
  73 AC_ARG_WITH([libnids],
  74             AS_HELP_STRING([--without-libnids], [Do not use libnids even if present]))
  75
  76 AS_IF([test "x$with_libnids" != "xno"],
  77       [AC_CHECK_LIB(nids, nids_pcap_handler,,
  78               AC_MSG_WARN(Libnids not present or too old; tcpslice won't be able to track sessions!)
  79               AC_MSG_WARN(Get the latest version of Libnids at http://libnids.sourceforge.net/)
  80       )])
  81
  82 AC_ARG_WITH([libosipparser2],
  83             AS_HELP_STRING([--without-libosipparser2], [Do not use libosipparser2 even if present]))
  84
  85 AS_IF([test "x$with_libosipparser2" != "xno"],
  86       [AC_CHECK_LIB(osipparser2, osip_message_parse,,
  87               AC_MSG_WARN(Libosip2 not present or too old; tcpslice won't be able to track SIP calls!)
  88               AC_MSG_WARN(Get the latest version of Libosip at https://www.gnu.org/software/osip/)
  89       )])
  90
  91 AC_ARG_WITH([libooh323c],
  92             AS_HELP_STRING([--without-libooh323c], [Do not use libooh323c even if present]))
  93
  94 AS_IF([test "x$with_libooh323c" != "xno"],
  95       [AC_CHECK_LIB(ooh323c, asn1PD_H225RasMessage,,
  96               AC_MSG_WARN(Libooh323c not present or too old; tcpslice won't be able to track H.323 calls!)
  97               AC_MSG_WARN(Get the latest version of Libooh323c at https://sourceforge.net/projects/ooh323c/)
  98       )])
  99
 100 #
 101 # Check whether we have pcap/pcap-inttypes.h.
 102 # If we do, we use that to get the C99 types defined.
 103 #
 104 savedcppflags="$CPPFLAGS"
 105 CPPFLAGS="$CPPFLAGS $V_INCLS"
 106 AC_CHECK_HEADERS(pcap/pcap-inttypes.h)
 107 AC_CHECK_FUNCS(pcap_lib_version)
 108 CPPFLAGS="$savedcppflags"
 109
 110 #
 111 # Define the old BSD specified-width types in terms of the C99 types;
 112 # we may need them with libpcap include files.
 113 #
 114 AC_CHECK_TYPE([u_int8_t], ,
 115         [AC_DEFINE([u_int8_t], [uint8_t],
 116         [Define to `uint8_t' if u_int8_t not defined.])],
 117         [AC_INCLUDES_DEFAULT
 118 #include <sys/types.h>
 119 ])
 120 AC_CHECK_TYPE([u_int16_t], ,
 121         [AC_DEFINE([u_int16_t], [uint16_t],
 122         [Define to `uint16_t' if u_int16_t not defined.])],
 123         [AC_INCLUDES_DEFAULT
 124 #include <sys/types.h>
 125 ])
 126 AC_CHECK_TYPE([u_int32_t], ,
 127         [AC_DEFINE([u_int32_t], [uint32_t],
 128         [Define to `uint32_t' if u_int32_t not defined.])],
 129         [AC_INCLUDES_DEFAULT
 130 #include <sys/types.h>
 131 ])
 132 AC_CHECK_TYPE([u_int64_t], ,
 133         [AC_DEFINE([u_int64_t], [uint64_t],
 134         [Define to `uint64_t' if u_int64_t not defined.])],
 135         [AC_INCLUDES_DEFAULT
 136 #include <sys/types.h>
 137 ])
 138
 139 AC_LBL_DEVEL(V_CCOPT)
 140
 141 if test "${srcdir}" = "." ; then
 142         srcdirprefix=""
 143 else
 144         srcdirprefix="./"
 145 fi
 146
 147 AC_SUBST(V_CCOPT)
 148 AC_SUBST(V_DEFS)
 149 AC_SUBST(V_INCLS)
 150 AC_SUBST(V_PCAPDEP)
 151 AC_SUBST(LOCALSRC)
 152
 153 AC_PROG_INSTALL
 154
 155 AC_CONFIG_HEADERS([config.h])
 156
 157 AC_CONFIG_COMMANDS([.devel],[[if test -f .devel; then
 158         echo timestamp > stamp-h
 159         cat $srcdir/Makefile-devel-adds >> Makefile
 160         make depend || exit 1
 161 fi]],[[]])
 162 AC_CONFIG_FILES([Makefile])
 163 AC_OUTPUT
 164 exit 0