The Tcpdump Group git mirrors - tcpdump/blob

1 if(WIN32)

2 #

3 # We need 3.12 or later, so that we can set policy CMP0074; see

4 # below.

5 cmake_minimum_required(VERSION 3.12)

6 else(WIN32)

7 #

8 # For now, require only 2.8.12, just in case somebody is

9 # configuring with CMake on a "long-term support" version

10 # of some OS and that version supplies an older version of

11 # CMake.

12 #

13 # If this is ever updated to CMake 3.1 or later, remove the

14 # stuff in cmake/Modules/FindPCAP.cmake that appends subdirectories

15 # of directories from CMAKE_PREFIX_PATH to the PKG_CONFIG_PATH

16 # environment variable when running pkg-config, to make sure

17 # it finds any .pc file from there.

18 #

19 cmake_minimum_required(VERSION 2.8.12)

20 endif(WIN32)

22 #

23 # We want find_path() and find_library() to honor {packagename}_ROOT,

24 # as that appears to be the standard way to say "hey, look here for

25 # this package" from the command line.

26 #

27 if(POLICY CMP0074)

28 cmake_policy(SET CMP0074 NEW)

29 endif()

31 #

32 # OK, this is a pain.

33 #

34 # When building on NetBSD, with a libpcap installed from pkgsrc,

35 # a -Wl,-rpath,/usr/pkg/lib option is added to the options when

36 # linking tcpdump. This puts /usr/pkg/lib into the run-time path.

37 #

38 # However, by default, CMake adds a rule to the install CMake script

39 # a CMake command (using an undocumented subcommand of file()) that

40 # strips /usr/pkg/lib *out* of the run-time path; the message in the

41 # output for the "install" target is

42 #

43 # -- Set runtime path of "{target-directory}/tcpdump" to ""

44 #

45 # I am not certain what the rationale is for doing this, but a

46 # *consequence* of this is that, when you run the installed tcpdump,

47 # it fails to find libpcap.so:

48 #

49 # $ {target-directory}/tcpdump -h

50 # {target-directory}/tcpdump: Shared object "libpcap.so.0" not found

51 #

52 # It also appears to be the case that, on Ubuntu 22.04, FreeBSD 12,

53 # DragonFly BSD 5.8, OpenBSD 6.6, and Solaris 11.4,

54 #

55 # On Ubuntu and Solaris, even if you have a libpcap in /usr/local, you

56 # have to provide not only -I/usr/local/include and -L/usr/local/lib,

57 # you also must provide -Wl,-rpath,/usr/local/lib in order to have

58 # the run-time linker look in /usr/local/lib for libpcap. If it's not

59 # specified, then, if the shared library major version number of the

60 # libpcap in /usr/lib is the same as the shared major version number

61 # of the libpcap in /usr/local/lib, the run-time linker will find the

62 # libpcap in /usr/lib; if the versions are different, the run-time

63 # linker will fail to find the libpcap in /usr/lib, so the program will

64 # fail to run.

65 #

66 # We suppress this by setting CMAKE_INSTALL_RPATH_USE_LINK_PATH to TRUE;

67 # as the documentation for that variable says:

68 #

69 # Add paths to linker search and installed rpath.

70 #

71 # CMAKE_INSTALL_RPATH_USE_LINK_PATH is a boolean that if set to True

72 # will append to the runtime search path (rpath) of installed

73 # binaries any directories outside the project that are in the linker

74 # search path or contain linked library files. The directories are

75 # appended after the value of the INSTALL_RPATH target property.

76 #

77 # If, for whatever reason, directories in which we search for external

78 # libraries, other than the standard system library directories, are

79 # added to the executable's rpath in the build process, we most

80 # defintely want them in the installed image's rpath if they are

81 # necessary in order to find the libraries at run time.

82 #

83 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)

85 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/Modules)

87 #

88 # OK, this is a royal pain.

89 #

90 # CMake will try to determine the sizes of some data types, including

91 # void *, early in the process of configuration; apparently, it's done

92 # as part of processing the project() command.

93 #

94 # At least as of CMake 2.8.6, it does so by checking the size of

95 # "void *" in C, setting CMAKE_C_SIZEOF_DATA_PTR based on that,

96 # setting CMAKE_SIZEOF_VOID_P to that, and then checking the size

97 # of "void *" in C++, setting CMAKE_CXX_SIZEOF_DATA_PTR based on

98 # that, and then setting CMAKE_SIZEOF_VOID_P to *that*.

99 #

100 # The compile tests include whatever C flags may have been provided

101 # to CMake in the CFLAGS and CXXFLAGS environment variables.

102 #

103 # If you set an architecture flag such as -m32 or -m64 in CFLAGS

104 # but *not* in CXXFLAGS, the size for C++ will win, and hilarity

105 # will ensue.

106 #

107 # Or if, at least on Solaris, you have a newer version of GCC

108 # installed, but *not* a newer version of G++, and you have Oracle

109 # Studio installed, it will find GCC, which will default to building

110 # 64-bit, and Oracle Studio's C++ compiler, which will default to

111 # building 32-bit, the size for C++ will win, and, again, hilarity

112 # will ensue.

113 #

114 # So we *explicitly* state that only C is used; there is currently no

115 # C++ code in tcpdump.

116 #

117 project(tcpdump C)

118

119 #

120 # For checking if a compiler flag works and adding it if it does.

121 #

122 include(CheckCCompilerFlag)

123 macro(check_and_add_compiler_option _option)

124 message(STATUS "Checking C compiler flag ${_option}")

125 string(REPLACE "=" "-" _temp_option_variable ${_option})

126 string(REGEX REPLACE "^-" "" _option_variable ${_temp_option_variable})

127 check_c_compiler_flag("${_option}" ${_option_variable})

128 if(${${_option_variable}})

129 set(C_ADDITIONAL_FLAGS "${C_ADDITIONAL_FLAGS} ${_option}")

130 endif()

131 endmacro()

132

133 #

134 # If we're building with Visual Studio, we require Visual Studio 2015,

135 # in order to get sufficient C99 compatibility. Check for that.

136 #

137 # If not, try the appropriate flag for the compiler to enable C99

138 # features.

139 #

140 set(C_ADDITIONAL_FLAGS "")

141 if(MSVC)

142 if(MSVC_VERSION LESS 1900)

143 message(FATAL_ERROR "Visual Studio 2015 or later is required")

144 endif()

145

146 #

147 # Treat source files as being in UTF-8 with MSVC if it's not using

148 # the Clang front end.

149 # We assume that UTF-8 source is OK with other compilers and with

150 # MSVC if it's using the Clang front end.

151 #

152 if(NOT ${CMAKE_C_COMPILER} MATCHES "clang*")

153 set(C_ADDITIONAL_FLAGS "${C_ADDITIONAL_FLAGS} /utf-8")

154 endif(NOT ${CMAKE_C_COMPILER} MATCHES "clang*")

155 else(MSVC)

156 #

157 # Try to enable as many C99 features as we can.

158 # At minimum, we want C++/C99-style // comments.

159 #

160 # Newer versions of compilers might default to supporting C99, but

161 # older versions may require a special flag.

162 #

163 # Prior to CMake 3.1, setting CMAKE_C_STANDARD will not have any effect,

164 # so, unless and until we require CMake 3.1 or later, we have to do it

165 # ourselves on pre-3.1 CMake, so we just do it ourselves on all versions

166 # of CMake.

167 #

168 # Note: with CMake 3.1 through 3.5, the only compilers for which CMake

169 # handles CMAKE_C_STANDARD are GCC and Clang. 3.6 adds support only

170 # for Intel C; 3.9 adds support for PGI C, Sun C, and IBM XL C, and

171 # 3.10 adds support for Cray C and IAR C, but no version of CMake has

172 # support for HP C. Therefore, even if we use CMAKE_C_STANDARD with

173 # compilers for which CMake supports it, we may still have to do it

174 # ourselves on other compilers.

175 #

176 # See the CMake documentation for the CMAKE_<LANG>_COMPILER_ID variables

177 # for a list of compiler IDs.

178 #

179 # XXX - this just tests whether the option works and adds it if it does.

180 # We don't test whether it's necessary in order to get the C99 features

181 # that we use; if we ever have a user who tries to compile with a compiler

182 # that can't be made to support those features, we can add a test to make

183 # sure we actually *have* C99 support.

184 #

185 if(CMAKE_C_COMPILER_ID MATCHES "GNU" OR

186 CMAKE_C_COMPILER_ID MATCHES "Clang")

187 check_and_add_compiler_option("-std=gnu99")

188 elseif(CMAKE_C_COMPILER_ID MATCHES "XL")

189 #

190 # We want support for extensions picked up for GNU C compatibility,

191 # so we use -qlanglvl=extc99.

192 #

193 check_and_add_compiler_option("-qlanglvl=extc99")

194 elseif(CMAKE_C_COMPILER_ID MATCHES "HP")

195 check_and_add_compiler_option("-AC99")

196 elseif(CMAKE_C_COMPILER_ID MATCHES "Sun")

197 check_and_add_compiler_option("-xc99")

198 elseif(CMAKE_C_COMPILER_ID MATCHES "Intel")

199 check_and_add_compiler_option("-c99")

200 endif()

201 endif(MSVC)

202

203 set(LIBRARY_NAME netdissect)

204

205 ###################################################################

206 # Parameters

207 ###################################################################

208

209 option(WITH_SMI "Build with libsmi, if available" ON)

210 option(WITH_CRYPTO "Build with OpenSSL/libressl libcrypto, if available" ON)

211 option(WITH_CAPSICUM "Build with Capsicum security functions, if available" ON)

212 option(WITH_CAP_NG "Use libcap-ng, if available" ON)

213 option(ENABLE_SMB "Build with the SMB dissector" OFF)

214

215 #

216 # String parameters. Neither of them are set, initially; only if the

217 # user explicitly configures them are they set.

218 #

219 # WITH_CHROOT is STRING, not PATH, as the directory need not exist

220 # when CMake is run.

221 #

222 set(WITH_CHROOT CACHE STRING

223 "Directory to which to chroot when dropping privileges")

224 set(WITH_USER CACHE STRING

225 "User to whom to set the UID when dropping privileges")

226

227 #

228 # By default, build universal with the appropriate set of architectures

229 # for the OS on which we're doing the build.

230 #

231 if(APPLE AND "${CMAKE_OSX_ARCHITECTURES}" STREQUAL "")

232 #

233 # Get the major version of Darwin.

234 #

235 string(REGEX MATCH "^([0-9]+)" SYSTEM_VERSION_MAJOR "${CMAKE_SYSTEM_VERSION}")

236

237 if(SYSTEM_VERSION_MAJOR EQUAL 9)

238 #

239 # Leopard. Build for x86 and 32-bit PowerPC, with

240 # x86 first. (That's what Apple does.)

241 #

242 set(CMAKE_OSX_ARCHITECTURES "i386;ppc")

243 elseif(SYSTEM_VERSION_MAJOR EQUAL 10)

244 #

245 # Snow Leopard. Build for x86-64 and x86, with

246 # x86-64 first. (That's what Apple does.)

247 #

248 set(CMAKE_OSX_ARCHITECTURES "x86_64;i386")

249 endif()

250 endif()

251

252 ###################################################################

253 # Versioning

254 ###################################################################

255

256 # Get, parse, format and set tcpdump's version string from

257 # [tcpdump_root]/VERSION for later use.

258

259 # Get MAJOR, MINOR, PATCH & SUFFIX

260 file(STRINGS ${tcpdump_SOURCE_DIR}/VERSION

261 PACKAGE_VERSION

262 LIMIT_COUNT 1 # Read only the first line

263 )

264

265 ######################################

266 # Project settings

267 ######################################

268

269 add_definitions(-DHAVE_CONFIG_H)

270

271 include_directories(

272 ${CMAKE_CURRENT_BINARY_DIR}

273 ${tcpdump_SOURCE_DIR}

274 )

275

276 if(MSVC)

277 add_definitions(-D__STDC__)

278 add_definitions(-D_CRT_SECURE_NO_WARNINGS)

279 endif(MSVC)

280

281 if(MSVC)

282 if (USE_STATIC_RT)

283 MESSAGE(STATUS "Use STATIC runtime")

284 set(NAME_RT MT)

285 set (CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /MT")

286 set (CMAKE_CXX_FLAGS_RELWITHDEBINFO "${CMAKE_CXX_FLAGS_RELWITHDEBINFO} /MT")

287 set (CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} /MT")

288 set (CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} /MTd")

289

290 set (CMAKE_C_FLAGS_MINSIZEREL "${CMAKE_C_FLAGS_MINSIZEREL} /MT")

291 set (CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS_RELWITHDEBINFO} /MT")

292 set (CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} /MT")

293 set (CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /MTd")

294 else (USE_STATIC_RT)

295 MESSAGE(STATUS "Use DYNAMIC runtime")

296 set(NAME_RT MD)

297 set (CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /MD")

298 set (CMAKE_CXX_FLAGS_RELWITHDEBINFO "${CMAKE_CXX_FLAGS_RELWITHDEBINFO} /MD")

299 set (CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} /MD")

300 set (CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} /MDd")

301

302 set (CMAKE_C_FLAGS_MINSIZEREL "${CMAKE_C_FLAGS_MINSIZEREL} /MD")

303 set (CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS_RELWITHDEBINFO} /MD")

304 set (CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} /MD")

305 set (CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /MDd")

306 endif (USE_STATIC_RT)

307 endif(MSVC)

308

309 ###################################################################

310 # Detect available platform features

311 ###################################################################

312

313 include(CMakePushCheckState)

314 include(CheckIncludeFile)

315 include(CheckIncludeFiles)

316 include(CheckFunctionExists)

317 include(CheckLibraryExists)

318 include(CheckSymbolExists)

319 include(CheckStructHasMember)

320 include(CheckVariableExists)

321 include(CheckTypeSize)

322

323 #

324 # Header files.

325 #

326 check_include_file(fcntl.h HAVE_FCNTL_H)

327 check_include_file(rpc/rpc.h HAVE_RPC_RPC_H)

328 check_include_file(net/if.h HAVE_NET_IF_H)

329 if(HAVE_RPC_RPC_H)

330 check_include_files("rpc/rpc.h;rpc/rpcent.h" HAVE_RPC_RPCENT_H)

331 endif(HAVE_RPC_RPC_H)

332

333 #

334 # Functions.

335 #

336 check_function_exists(strlcat HAVE_STRLCAT)

337 check_function_exists(strlcpy HAVE_STRLCPY)

338 check_function_exists(strdup HAVE_STRDUP)

339 check_function_exists(strsep HAVE_STRSEP)

340

341 #

342 # Find library needed for gethostbyaddr.

343 # NOTE: if you hand check_library_exists as its last argument a variable

344 # that's been set, it skips the test, so we need different variables.

345 #

346 set(TCPDUMP_LINK_LIBRARIES "")

347 if(WIN32)

348 #

349 # We need winsock2.h and ws2tcpip.h.

350 #

351 cmake_push_check_state()

352 set(CMAKE_REQUIRED_LIBRARIES ws2_32)

353 check_symbol_exists(gethostbyaddr "winsock2.h;ws2tcpip.h" LIBWS2_32_HAS_GETHOSTBYADDR)

354 cmake_pop_check_state()

355 if(LIBWS2_32_HAS_GETHOSTBYADDR)

356 set(TCPDUMP_LINK_LIBRARIES ws2_32 ${TCPDUMP_LINK_LIBRARIES})

357 else(LIBWS2_32_HAS_GETHOSTBYADDR)

358 message(FATAL_ERROR "gethostbyaddr is required, but wasn't found")

359 endif(LIBWS2_32_HAS_GETHOSTBYADDR)

360 else(WIN32)

361 check_function_exists(gethostbyaddr STDLIBS_HAVE_GETHOSTBYADDR)

362 if(NOT STDLIBS_HAVE_GETHOSTBYADDR)

363 check_library_exists(socket gethostbyaddr "" LIBSOCKET_HAS_GETHOSTBYADDR)

364 if(LIBSOCKET_HAS_GETHOSTBYADDR)

365 set(TCPDUMP_LINK_LIBRARIES ${TCPDUMP_LINK_LIBRARIES} socket)

366 else(LIBSOCKET_HAS_GETHOSTBYADDR)

367 check_library_exists(nsl gethostbyaddr "" LIBNSL_HAS_GETHOSTBYADDR)

368 if(LIBNSL_HAS_GETHOSTBYADDR)

369 set(TCPDUMP_LINK_LIBRARIES ${TCPDUMP_LINK_LIBRARIES} nsl)

370 else(LIBNSL_HAS_GETHOSTBYADDR)

371 check_library_exists(network gethostbyaddr "" LIBNETWORK_HAS_GETHOSTBYADDR)

372 if(LIBNETWORK_HAS_GETHOSTBYADDR)

373 set(TCPDUMP_LINK_LIBRARIES ${TCPDUMP_LINK_LIBRARIES} network)

374 else(LIBNETWORK_HAS_GETHOSTBYADDR)

375 message(FATAL_ERROR "gethostbyaddr is required, but wasn't found")

376 endif(LIBNETWORK_HAS_GETHOSTBYADDR)

377 endif(LIBNSL_HAS_GETHOSTBYADDR)

378 endif(LIBSOCKET_HAS_GETHOSTBYADDR)

379 endif(NOT STDLIBS_HAVE_GETHOSTBYADDR)

380 endif(WIN32)

381

382 #

383 # This may require additional libraries.

384 #

385 cmake_push_check_state()

386 set(CMAKE_REQUIRED_LIBRARIES ${TCPDUMP_LINK_LIBRARIES})

387 check_function_exists(getservent STDLIBS_HAVE_GETSERVENT)

388 if(STDLIBS_HAVE_GETSERVENT)

389 set(HAVE_GETSERVENT TRUE)

390 else(STDLIBS_HAVE_GETSERVENT)

391 #

392 # Some platforms may need -lsocket for getservent.

393 #

394 set(CMAKE_REQUIRED_LIBRARIES socket ${TCPDUMP_LINK_LIBRARIES})

395 check_function_exists(getservent LIBSOCKET_HAS_GETSERVENT)

396 if(LIBSOCKET_HAS_GETSERVENT)

397 set(HAVE_GETSERVENT TRUE)

398 set(TCPDUMP_LINK_LIBRARIES socket ${TCPDUMP_LINK_LIBRARIES})

399 endif(LIBSOCKET_HAS_GETSERVENT)

400 endif(STDLIBS_HAVE_GETSERVENT)

401 cmake_pop_check_state()

402

403 #

404 # Make sure we have vsnprintf() and snprintf(); we require them.

405 # We use check_symbol_exists(), as they aren't necessarily external

406 # functions - in Visual Studio, for example, they're inline functions

407 # calling a common external function.

408 #

409 check_symbol_exists(vsnprintf "stdio.h" HAVE_VSNPRINTF)

410 if(NOT HAVE_VSNPRINTF)

411 message(FATAL_ERROR "vsnprintf() is required but wasn't found")

412 endif(NOT HAVE_VSNPRINTF)

413 check_symbol_exists(snprintf "stdio.h" HAVE_SNPRINTF)

414 if(NOT HAVE_SNPRINTF)

415 message(FATAL_ERROR "snprintf() is required but wasn't found")

416 endif()

417

418 check_function_exists(getopt_long HAVE_GETOPT_LONG)

419 check_function_exists(setlinebuf HAVE_SETLINEBUF)

420 #

421 # For Windows, don't need to waste time checking for fork() or vfork().

422 #

423 if(NOT WIN32)

424 check_function_exists(fork HAVE_FORK)

425 check_function_exists(vfork HAVE_VFORK)

426 endif(NOT WIN32)

427

428 #

429 # Some platforms may need -lnsl for getrpcbynumber.

430 #

431 cmake_push_check_state()

432 set(CMAKE_REQUIRED_LIBRARIES ${TCPDUMP_LINK_LIBRARIES})

433 check_function_exists(getrpcbynumber STDLIBS_HAVE_GETRPCBYNUMBER)

434 if(STDLIBS_HAVE_GETRPCBYNUMBER)

435 set(HAVE_GETRPCBYNUMBER TRUE)

436 else(STDLIBS_HAVE_GETRPCBYNUMBER)

437 set(CMAKE_REQUIRED_LIBRARIES ${TCPDUMP_LINK_LIBRARIES} nsl)

438 check_function_exists(getrpcbynumber LIBNSL_HAS_GETRPCBYNUMBER)

439 if(LIBNSL_HAS_GETRPCBYNUMBER)

440 set(HAVE_GETRPCBYNUMBER TRUE)

441 set(TCPDUMP_LINK_LIBRARIES ${TCPDUMP_LINK_LIBRARIES} nsl)

442 endif(LIBNSL_HAS_GETRPCBYNUMBER)

443 endif(STDLIBS_HAVE_GETRPCBYNUMBER)

444 cmake_pop_check_state()

445

446 #

447 # This requires the libraries we require, as ether_ntohost might be

448 # in one of those libraries. That means we have to do this after

449 # we check for those libraries.

450 #

451 # You are in a twisty little maze of UN*Xes, all different.

452 # Some might not have ether_ntohost().

453 # Some might have it and declare it in <net/ethernet.h>.

454 # Some might have it and declare it in <netinet/ether.h>

455 # Some might have it and declare it in <sys/ethernet.h>.

456 # Some might have it and declare it in <arpa/inet.h>.

457 # Some might have it and declare it in <netinet/if_ether.h>.

458 # Some might have it and not declare it in any header file.

459 #

460 # Before you is a C compiler.

461 #

462 cmake_push_check_state()

463 set(CMAKE_REQUIRED_LIBRARIES ${TCPDUMP_LINK_LIBRARIES})

464 check_function_exists(ether_ntohost HAVE_ETHER_NTOHOST)

465 if(HAVE_ETHER_NTOHOST)

466 #

467 # OK, we have ether_ntohost(). We don't check whether it's buggy,

468 # as we assume any system that has CMake is likely to be new enough

469 # that, if it has ether_ntohost(), whatever bug is checked for in

470 # autotools is fixed; we just decide to use it.

471 #

472 set(USE_ETHER_NTOHOST TRUE)

473

474 #

475 # Is it declared in <net/ethernet.h>?

476 #

477 # This test fails if we don't have <net/ethernet.h> or if we do

478 # but it doesn't declare ether_ntohost().

479 #

480 check_symbol_exists(ether_ntohost net/ethernet.h NET_ETHERNET_H_DECLARES_ETHER_NTOHOST)

481 if(NET_ETHERNET_H_DECLARES_ETHER_NTOHOST)

482 #

483 # Yes - we have it declared.

484 #

485 set(HAVE_DECL_ETHER_NTOHOST TRUE)

486 endif()

487 #

488 # Did that succeed?

489 #

490 if(NOT HAVE_DECL_ETHER_NTOHOST)

491 #

492 # No - how about <netinet/ether.h>, as on Linux?

493 #

494 # This test fails if we don't have <netinet/ether.h>

495 # or if we do but it doesn't declare ether_ntohost().

496 #

497 check_symbol_exists(ether_ntohost netinet/ether.h NETINET_ETHER_H_DECLARES_ETHER_NTOHOST)

498 if(NETINET_ETHER_H_DECLARES_ETHER_NTOHOST)

499 #

500 # Yes - we have it declared.

501 #

502 set(HAVE_DECL_ETHER_NTOHOST TRUE)

503 endif()

504 endif()

505 #

506 # Did that succeed?

507 #

508 if(NOT HAVE_DECL_ETHER_NTOHOST)

509 #

510 # No - how about <sys/ethernet.h>, as on Solaris 10 and later?

511 #

512 # This test fails if we don't have <sys/ethernet.h>

513 # or if we do but it doesn't declare ether_ntohost().

514 #

515 check_symbol_exists(ether_ntohost sys/ethernet.h SYS_ETHERNET_H_DECLARES_ETHER_NTOHOST)

516 if(SYS_ETHERNET_H_DECLARES_ETHER_NTOHOST)

517 #

518 # Yes - we have it declared.

519 #

520 set(HAVE_DECL_ETHER_NTOHOST TRUE)

521 endif()

522 endif()

523 #

524 # Did that succeed?

525 #

526 if(NOT HAVE_DECL_ETHER_NTOHOST)

527 #

528 # No, how about <arpa/inet.h>, as on AIX?

529 #

530 # This test fails if we don't have <arpa/inet.h>

531 # or if we do but it doesn't declare ether_ntohost().

532 #

533 check_symbol_exists(ether_ntohost arpa/inet.h ARPA_INET_H_DECLARES_ETHER_NTOHOST)

534 if(ARPA_INET_H_DECLARES_ETHER_NTOHOST)

535 #

536 # Yes - we have it declared.

537 #

538 set(HAVE_DECL_ETHER_NTOHOST TRUE)

539 endif()

540 endif()

541 #

542 # Did that succeed?

543 #

544 if(NOT HAVE_DECL_ETHER_NTOHOST)

545 #

546 # No, how about <netinet/if_ether.h>?

547 # On some platforms, it requires <net/if.h> and

548 # <netinet/in.h>, and we always include it with

549 # both of them, so test it with both of them.

550 #

551 # This test fails if we don't have <netinet/if_ether.h>

552 # and the headers we include before it, or if we do but

553 # <netinet/if_ether.h> doesn't declare ether_ntohost().

554 #

555 check_symbol_exists(ether_ntohost "sys/types.h;sys/socket.h;net/if.h;netinet/in.h;netinet/if_ether.h" NETINET_IF_ETHER_H_DECLARES_ETHER_NTOHOST)

556 if(NETINET_IF_ETHER_H_DECLARES_ETHER_NTOHOST)

557 #

558 # Yes - we have it declared.

559 #

560 set(HAVE_DECL_ETHER_NTOHOST TRUE)

561 endif()

562 endif()

563 #

564 # After all that, is ether_ntohost() declared?

565 #

566 if(NOT HAVE_DECL_ETHER_NTOHOST)

567 #

568 # No, we'll have to declare it ourselves.

569 # Do we have "struct ether_addr" if we include<netinet/if_ether.h>?

570 #

571 check_struct_has_member("struct ether_addr" octet "sys/types.h;sys/socket.h;net/if.h;netinet/in.h;netinet/if_ether.h" HAVE_STRUCT_ETHER_ADDR)

572 endif()

573 endif()

574 cmake_pop_check_state()

575

576 #

577 # Data types.

578 #

579 # XXX - there's no check_struct() macro that's like check_struct_has_member()

580 # except that it only checks for the existence of the structure type,

581 # so we use check_struct_has_member() and look for ss_family.

582 #

583

584 #

585 # Check for IPv6 support.

586 # We just check for AF_INET6 and struct in6_addr.

587 #

588 cmake_push_check_state()

589 if(WIN32)

590 set(CMAKE_EXTRA_INCLUDE_FILES sys/types.h ws2tcpip.h)

591 check_symbol_exists(AF_INET6 "sys/types.h;ws2tcpip.h" HAVE_AF_INET6)

592 else(WIN32)

593 set(CMAKE_EXTRA_INCLUDE_FILES sys/types.h sys/socket.h netinet/in.h)

594 check_symbol_exists(AF_INET6 "sys/types.h;sys/socket.h;netinet/in.h" HAVE_AF_INET6)

595 endif(WIN32)

596 check_type_size("struct in6_addr" HAVE_STRUCT_IN6_ADDR)

597 cmake_pop_check_state()

598 if(HAVE_AF_INET6 AND HAVE_STRUCT_IN6_ADDR)

599 set(HAVE_OS_IPV6_SUPPORT TRUE)

600 endif(HAVE_AF_INET6 AND HAVE_STRUCT_IN6_ADDR)

601

602 ######################################

603 # External dependencies

604 ######################################

605

606 #

607 # libpcap/WinPcap/Npcap.

608 # First, find it.

609 #

610 find_package(PCAP REQUIRED)

611 include_directories(${PCAP_INCLUDE_DIRS})

612

613 cmake_push_check_state()

614

615 #

616 # Now check headers.

617 #

618 set(CMAKE_REQUIRED_INCLUDES ${PCAP_INCLUDE_DIRS})

619

620 #

621 # Check whether we have pcap/pcap-inttypes.h.

622 # If we do, we use that to get the C99 types defined.

623 #

624 check_include_file(pcap/pcap-inttypes.h HAVE_PCAP_PCAP_INTTYPES_H)

625

626 #

627 # Check for various functions in libpcap/WinPcap/Npcap.

628 #

629 cmake_push_check_state()

630 set(CMAKE_REQUIRED_LIBRARIES ${PCAP_LIBRARIES})

631

632 #

633 # Check for "pcap_list_datalinks()" and use a substitute version if

634 # it's not present. If it is present, check for "pcap_free_datalinks()";

635 # if it's not present, we don't replace it for now. (We could do so

636 # on UN*X, but not on Windows, where hilarity ensues if a program

637 # built with one version of the MSVC support library tries to free

638 # something allocated by a library built with another version of

639 # the MSVC support library.)

640 #

641 check_function_exists(pcap_list_datalinks HAVE_PCAP_LIST_DATALINKS)

642 if(HAVE_PCAP_LIST_DATALINKS)

643 check_function_exists(pcap_free_datalinks HAVE_PCAP_FREE_DATALINKS)

644 endif(HAVE_PCAP_LIST_DATALINKS)

645

646 #

647 # Check for "pcap_datalink_name_to_val()", and use a substitute

648 # version if it's not present. If it is present, check for

649 # "pcap_datalink_val_to_description()", and if we don't have it,

650 # use a substitute version.

651 #

652 check_function_exists(pcap_datalink_name_to_val HAVE_PCAP_DATALINK_NAME_TO_VAL)

653 if(HAVE_PCAP_DATALINK_NAME_TO_VAL)

654 check_function_exists(pcap_datalink_val_to_description HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION)

655 endif(HAVE_PCAP_DATALINK_NAME_TO_VAL)

656

657 #

658 # Check for "pcap_set_datalink()"; you can't substitute for it if

659 # it's absent (it has hooks into libpcap), so just define the

660 # HAVE_ value if it's there.

661 #

662 check_function_exists(pcap_set_datalink HAVE_PCAP_SET_DATALINK)

663

664 #

665 # Check for "pcap_breakloop()"; you can't substitute for it if

666 # it's absent (it has hooks into the live capture routines),

667 # so just define the HAVE_ value if it's there.

668 #

669 check_function_exists(pcap_breakloop HAVE_PCAP_BREAKLOOP)

670

671 #

672 # Check for "pcap_dump_ftell()"; we use a substitute version

673 # if it's not present.

674 #

675 check_function_exists(pcap_dump_ftell HAVE_PCAP_DUMP_FTELL)

676

677 #

678 # Do we have the new open API? Check for pcap_create() and for

679 # pcap_statustostr(), and assume that, if we have both of them,

680 # we also have pcap_activate() and the other new routines

681 # introduced in libpcap 1.0.0. (We check for pcap_statustostr()

682 # as well, because WinPcap 4.1.3 screwed up and exported pcap_create()

683 # but not other routines such as pcap_statustostr(), even though it

684 # defined them and even though you really want pcap_statustostr() to

685 # get strings corresponding to some of the status returns from the

686 # new routines.)

687 #

688 check_function_exists(pcap_statustostr HAVE_PCAP_STATUSTOSTR)

689 #

690 # If we don't have pcap_statustostr(), don't check for pcap_create(),

691 # so we pretend we don't have it.

692 #

693 if(HAVE_PCAP_STATUSTOSTR)

694 check_function_exists(pcap_create HAVE_PCAP_CREATE)

695 endif(HAVE_PCAP_STATUSTOSTR)

696 if(HAVE_PCAP_CREATE)

697 #

698 # OK, do we have pcap_set_tstamp_type? If so, assume we have

699 # pcap_list_tstamp_types and pcap_free_tstamp_types as well.

700 #

701 check_function_exists(pcap_set_tstamp_type HAVE_PCAP_SET_TSTAMP_TYPE)

702

703 #

704 # And do we have pcap_set_tstamp_precision? If so, we assume

705 # we also have pcap_open_offline_with_tstamp_precision.

706 #

707 check_function_exists(pcap_set_tstamp_precision HAVE_PCAP_SET_TSTAMP_PRECISION)

708 endif(HAVE_PCAP_CREATE)

709

710 #

711 # Check for a miscellaneous collection of functions which we use

712 # if we have them.

713 #

714 check_function_exists(pcap_findalldevs HAVE_PCAP_FINDALLDEVS)

715 if(HAVE_PCAP_FINDALLDEVS)

716 #

717 # Check for libpcap having pcap_findalldevs() but the pcap.h header

718 # not having pcap_if_t; some versions of Mac OS X shipped with pcap.h

719 # from 0.6 and libpcap 0.8, so that libpcap had pcap_findalldevs but

720 # pcap.h didn't have pcap_if_t.

721 #

722 cmake_push_check_state()

723 set(CMAKE_REQUIRED_INCLUDES ${PCAP_INCLUDE_DIRS})

724 set(CMAKE_EXTRA_INCLUDE_FILES pcap.h)

725 check_type_size(pcap_if_t PCAP_IF_T)

726 cmake_pop_check_state()

727 endif(HAVE_PCAP_FINDALLDEVS)

728 check_function_exists(pcap_dump_flush HAVE_PCAP_DUMP_FLUSH)

729 check_function_exists(pcap_lib_version HAVE_PCAP_LIB_VERSION)

730 if(NOT HAVE_PCAP_LIB_VERSION)

731 # Check for the pcap_version string variable and set HAVE_PCAP_VERSION

732 endif(NOT HAVE_PCAP_LIB_VERSION)

733 check_function_exists(pcap_setdirection HAVE_PCAP_SETDIRECTION)

734 check_function_exists(pcap_set_immediate_mode HAVE_PCAP_SET_IMMEDIATE_MODE)

735 check_function_exists(pcap_dump_ftell64 HAVE_PCAP_DUMP_FTELL64)

736 check_function_exists(pcap_open HAVE_PCAP_OPEN)

737 check_function_exists(pcap_findalldevs_ex HAVE_PCAP_FINDALLDEVS_EX)

738

739 #

740 # On Windows, check for pcap_wsockinit(); if we don't have it, check for

741 # wsockinit().

742 #

743 if(WIN32)

744 check_function_exists(pcap_wsockinit HAVE_PCAP_WSOCKINIT)

745 if(NOT HAVE_PCAP_WSOCKINIT)

746 check_function_exists(wsockinit HAVE_WSOCKINIT)

747 endif(NOT HAVE_PCAP_WSOCKINIT)

748 endif(WIN32)

749

750 #

751 # Check for special debugging functions

752 #

753 check_function_exists(pcap_set_parser_debug HAVE_PCAP_SET_PARSER_DEBUG)

754 if(NOT HAVE_PCAP_SET_PARSER_DEBUG)

755 # Check whether libpcap defines pcap_debug or yydebug

756 check_variable_exists(pcap_debug HAVE_PCAP_DEBUG)

757 if(NOT HAVE_PCAP_DEBUG)

758 check_variable_exists(yydebug HAVE_YYDEBUG)

759 endif(NOT HAVE_PCAP_DEBUG)

760 endif(NOT HAVE_PCAP_SET_PARSER_DEBUG)

761

762 check_function_exists(pcap_set_optimizer_debug HAVE_PCAP_SET_OPTIMIZER_DEBUG)

763 check_function_exists(bpf_dump HAVE_BPF_DUMP)

764

765 cmake_pop_check_state()

766

767 #

768 # We have libpcap.

769 #

770 include_directories(SYSTEM ${PCAP_INCLUDE_DIRS})

771 set(TCPDUMP_LINK_LIBRARIES ${PCAP_LIBRARIES} ${TCPDUMP_LINK_LIBRARIES})

772

773 #

774 # Optional libraries.

775 #

776

777 #

778 # libsmi.

779 #

780 if(WITH_SMI)

781 find_package(SMI)

782 if(SMI_FOUND)

783 include_directories(SYSTEM ${SMI_INCLUDE_DIRS})

784 set(TCPDUMP_LINK_LIBRARIES ${TCPDUMP_LINK_LIBRARIES} ${SMI_LIBRARIES})

785 set(USE_LIBSMI ON)

786 endif(SMI_FOUND)

787 endif(WITH_SMI)

788

789 #

790 # OpenSSL/libressl libcrypto.

791 #

792 if(WITH_CRYPTO)

793 find_package(CRYPTO)

794 if(CRYPTO_FOUND)

795 #

796 # Check for some headers and functions.

797 #

798 check_include_file(openssl/evp.h HAVE_OPENSSL_EVP_H)

799

800 #

801 # 1) do we have EVP_CIPHER_CTX_new?

802 # If so, we use it to allocate an EVP_CIPHER_CTX, as

803 # EVP_CIPHER_CTX may be opaque; otherwise, we allocate

804 # it ourselves.

805 #

806 cmake_push_check_state()

807 set(CMAKE_REQUIRED_LIBRARIES "${CRYPTO_LIBRARIES}")

808

809 check_function_exists(EVP_CIPHER_CTX_new HAVE_EVP_CIPHER_CTX_NEW)

810

811 #

812 # 2) do we have EVP_DecryptInit_ex()?

813 # If so, we use it, because we need to be able to make two

814 # "initialize the cipher" calls, one with the cipher and key,

815 # and one with the IV, and, as of OpenSSL 1.1, You Can't Do That

816 # with EVP_DecryptInit(), because a call to EVP_DecryptInit() will

817 # unconditionally clear the context, and if you don't supply a

818 # cipher, it'll clear the cipher, rendering the context unusable

819 # and causing a crash.

820 #

821 check_function_exists(EVP_DecryptInit_ex HAVE_EVP_DECRYPTINIT_EX)

822

823 cmake_pop_check_state()

824

825 #

826 # We have libcrypto.

827 #

828 include_directories(SYSTEM ${CRYPTO_INCLUDE_DIRS})

829 set(TCPDUMP_LINK_LIBRARIES ${TCPDUMP_LINK_LIBRARIES} ${CRYPTO_LIBRARIES})

830 set(HAVE_LIBCRYPTO ON)

831 endif(CRYPTO_FOUND)

832 endif(WITH_CRYPTO)

833

834 #

835 # Capsicum sandboxing.

836 # Some of this is in the system library, some of it is in other libraries.

837 #

838 if(WITH_CAPSICUM)

839 check_include_files("sys/capsicum.h" HAVE_SYS_CAPSICUM_H)

840 if(HAVE_SYS_CAPSICUM_H)

841 check_function_exists(cap_enter HAVE_CAP_ENTER)

842 check_function_exists(cap_rights_limit HAVE_CAP_RIGHTS_LIMIT)

843 check_function_exists(cap_ioctls_limit HAVE_CAP_IOCTLS_LIMIT)

844 check_function_exists(openat HAVE_OPENAT)

845 if(HAVE_CAP_ENTER AND HAVE_CAP_RIGHTS_LIMIT AND

846 HAVE_CAP_IOCTLS_LIMIT AND HAVE_OPENAT)

847 #

848 # OK, we have the functions we need to support Capsicum.

849 #

850 set(HAVE_CAPSICUM TRUE)

851

852 #

853 # OK, can we use Casper?

854 #

855 check_library_exists(casper cap_init "" HAVE_CAP_INIT)

856 if(HAVE_CAP_INIT)

857 cmake_push_check_state()

858 set(CMAKE_REQUIRED_LIBRARIES casper)

859 check_library_exists(cap_dns cap_gethostbyaddr "" HAVE_CAP_GETHOSTBYADDR)

860 cmake_pop_check_state()

861 if(HAVE_CAP_GETHOSTBYADDR)

862 set(HAVE_CASPER TRUE)

863 set(TCPDUMP_LINK_LIBRARIES ${TCPDUMP_LINK_LIBRARIES} casper cap_dns)

864 endif(HAVE_CAP_GETHOSTBYADDR)

865 endif(HAVE_CAP_INIT)

866 endif(HAVE_CAP_ENTER AND HAVE_CAP_RIGHTS_LIMIT AND

867 HAVE_CAP_IOCTLS_LIMIT AND HAVE_OPENAT)

868 endif(HAVE_SYS_CAPSICUM_H)

869 endif(WITH_CAPSICUM)

870

871 #

872 # libcap-ng.

873 #

874 if(WITH_CAP_NG)

875 check_include_file(cap-ng.h HAVE_CAP_NG_H)

876 check_library_exists(cap-ng capng_change_id "" HAVE_LIBCAP_NG)

877 if(HAVE_LIBCAP_NG)

878 set(TCPDUMP_LINK_LIBRARIES ${TCPDUMP_LINK_LIBRARIES} cap-ng)

879 endif(HAVE_LIBCAP_NG)

880 endif(WITH_CAP_NG)

881

882 ###################################################################

883 # Warning options

884 ###################################################################

885

886 #

887 # Check and add warning options if we have a .devel file.

888 #

889 if(EXISTS ${CMAKE_SOURCE_DIR}/.devel OR EXISTS ${CMAKE_BINARY_DIR}/.devel)

890 #

891 # Warning options.

892 #

893 if(MSVC AND NOT ${CMAKE_C_COMPILER} MATCHES "clang*")

894 #

895 # MSVC, with Microsoft's front end and code generator.

896 # "MSVC" is also set for Microsoft's compiler with a Clang

897 # front end and their code generator ("Clang/C2"), so we

898 # check for clang.exe and treat that differently.

899 #

900 check_and_add_compiler_option(-Wall)

901 #

902 # Disable some pointless warnings that /Wall turns on.

903 #

904 # Unfortunately, MSVC does not appear to have an equivalent

905 # to "__attribute__((unused))" to mark a particular function

906 # parameter as being known to be unused, so that the compiler

907 # won't warn about it (for example, the function might have

908 # that parameter because a pointer to it is being used, and

909 # the signature of that function includes that parameter).

910 # C++ lets you give a parameter a type but no name, but C

911 # doesn't have that.

912 #

913 check_and_add_compiler_option(-wd4100)

914 #

915 # In theory, we care whether somebody uses f() rather than

916 # f(void) to declare a function with no arguments, but, in

917 # practice, there are places in the Windows header files

918 # that appear to do that, so we squelch that warning.

919 #

920 check_and_add_compiler_option(-wd4255)

921 #

922 # Windows FD_SET() generates this, so we suppress it.

923 #

924 check_and_add_compiler_option(-wd4548)

925 #

926 # Perhaps testing something #defined to be 0 with #ifdef is an

927 # error, and it should be tested with #if, but perhaps it's

928 # not, and Microsoft does that in its headers, so we squelch

929 # that warning.

930 #

931 check_and_add_compiler_option(-wd4574)

932 #

933 # The Windows headers also test not-defined values in #if, so

934 # we don't want warnings about that, either.

935 #

936 check_and_add_compiler_option(-wd4668)

937 #

938 # We do *not* care whether some function is, or isn't, going to be

939 # expanded inline.

940 #

941 check_and_add_compiler_option(-wd4710)

942 check_and_add_compiler_option(-wd4711)

943 #

944 # We do *not* care whether we're adding padding bytes after

945 # structure members.

946 #

947 check_and_add_compiler_option(-wd4820)

948 #

949 # We do *not* care about every single place the compiler would

950 # have inserted Spectre mitigation if only we had told it to

951 # do so with /Qspectre. I guess the theory is that it's seeing

952 # bounds checks that would prevent out-of-bounds loads and that

953 # those out-of-bounds loads could be done speculatively and that

954 # the Spectre attack could detect the value of the out-of-bounds

955 # data *if* it's within our address space, but unless I'm

956 # missing something I don't see that as being any form of

957 # security hole.

958 #

959 # XXX - add /Qspectre if that is really worth doing.

960 #

961 check_and_add_compiler_option(-wd5045)

962 #

963 # We do *not* care whether a structure had padding added at

964 # the end because of __declspec(align) - *we* don't use

965 # __declspec(align), because the only structures whose layout

966 # we precisely specify are those that get overlayed on packet

967 # data, and in those every element is an array of octets so

968 # that we have full control over the size and aligmnet, and,

969 # apparently, jmp_buf has such a declaration on x86, meaning

970 # that everything that includes netdissect.h, i.e. almost every

971 # file in tcpdump, gets a warning.

972 #

973 check_and_add_compiler_option(-wd4324)

974 else()

975 #

976 # Other compilers, including MSVC with a Clang front end and

977 # Microsoft's code generator. We currently treat them as if

978 # they might support GCC-style -W options.

979 #

980 check_and_add_compiler_option(-W)

981 check_and_add_compiler_option(-Wall)

982 check_and_add_compiler_option(-Wassign-enum)

983 check_and_add_compiler_option(-Wcast-qual)

984 check_and_add_compiler_option(-Wmissing-prototypes)

985 check_and_add_compiler_option(-Wmissing-variable-declarations)

986 check_and_add_compiler_option(-Wold-style-definition)

987 check_and_add_compiler_option(-Wpedantic)

988 check_and_add_compiler_option(-Wpointer-arith)

989 check_and_add_compiler_option(-Wpointer-sign)

990 check_and_add_compiler_option(-Wshadow)

991 check_and_add_compiler_option(-Wsign-compare)

992 check_and_add_compiler_option(-Wstrict-prototypes)

993 check_and_add_compiler_option(-Wunreachable-code-return)

994 check_and_add_compiler_option(-Wused-but-marked-unused)

995 check_and_add_compiler_option(-Wwrite-strings)

996 endif()

997 endif()

998

999 #

1000 # Extra compiler options for the build matrix scripts to request -Werror or

1001 # its equivalent if required. The CMake variable name cannot be CFLAGS

1002 # because that is already used for a different purpose in CMake. Example

1003 # usage: cmake -DEXTRA_CFLAGS='-Wall -Wextra -Werror' ...

1004 #

1005 if(NOT "${EXTRA_CFLAGS}" STREQUAL "")

1006 foreach(_extra_cflag ${EXTRA_CFLAGS})

1007 check_and_add_compiler_option("${_extra_cflag}")

1008 endforeach(_extra_cflag)

1009 message(STATUS "Added extra compile options (${EXTRA_CFLAGS})")

1010 endif()

1011

1012 ######################################

1013 # Input files

1014 ######################################

1015

1016 if(ENABLE_SMB)

1017 #

1018 # We allow the SMB dissector to be omitted.

1019 #

1020 set(LOCALSRC ${LOCALSRC}

1021 print-smb.c

1022 smbutil.c)

1023 endif(ENABLE_SMB)

1024

1025 set(NETDISSECT_SOURCE_LIST_C

1026 addrtoname.c

1027 addrtostr.c

1028 af.c

1029 ascii_strcasecmp.c

1030 checksum.c

1031 cpack.c

1032 gmpls.c

1033 in_cksum.c

1034 ipproto.c

1035 l2vpn.c

1036 machdep.c

1037 netdissect.c

1038 netdissect-alloc.c

1039 nlpid.c

1040 oui.c

1041 ntp.c

1042 parsenfsfh.c

1043 print.c

1044 print-802_11.c

1045 print-802_15_4.c

1046 print-ah.c

1047 print-ahcp.c

1048 print-aodv.c

1049 print-aoe.c

1050 print-ap1394.c

1051 print-arcnet.c

1052 print-arista.c

1053 print-arp.c

1054 print-ascii.c

1055 print-atalk.c

1056 print-atm.c

1057 print-babel.c

1058 print-bcm-li.c

1059 print-beep.c

1060 print-bfd.c

1061 print-bgp.c

1062 print-bootp.c

1063 print-brcmtag.c

1064 print-bt.c

1065 print-calm-fast.c

1066 print-carp.c

1067 print-cdp.c

1068 print-cfm.c

1069 print-chdlc.c

1070 print-cip.c

1071 print-cnfp.c

1072 print-dccp.c

1073 print-decnet.c

1074 print-dhcp6.c

1075 print-domain.c

1076 print-dsa.c

1077 print-dtp.c

1078 print-dvmrp.c

1079 print-eap.c

1080 print-egp.c

1081 print-eigrp.c

1082 print-enc.c

1083 print-esp.c

1084 print-ether.c

1085 print-fddi.c

1086 print-forces.c

1087 print-fr.c

1088 print-frag6.c

1089 print-ftp.c

1090 print-geneve.c

1091 print-geonet.c

1092 print-gre.c

1093 print-hncp.c

1094 print-hsrp.c

1095 print-http.c

1096 print-icmp.c

1097 print-icmp6.c

1098 print-igmp.c

1099 print-igrp.c

1100 print-ip-demux.c

1101 print-ip.c

1102 print-ip6.c

1103 print-ip6opts.c

1104 print-ipcomp.c

1105 print-ipfc.c

1106 print-ipnet.c

1107 print-ipoib.c

1108 print-ipx.c

1109 print-isakmp.c

1110 print-isoclns.c

1111 print-juniper.c

1112 print-krb.c

1113 print-l2tp.c

1114 print-lane.c

1115 print-ldp.c

1116 print-lisp.c

1117 print-llc.c

1118 print-lldp.c

1119 print-lmp.c

1120 print-loopback.c

1121 print-lspping.c

1122 print-lwapp.c

1123 print-lwres.c

1124 print-m3ua.c

1125 print-macsec.c

1126 print-mobile.c

1127 print-mobility.c

1128 print-mpcp.c

1129 print-mpls.c

1130 print-mptcp.c

1131 print-msdp.c

1132 print-msnlb.c

1133 print-nflog.c

1134 print-nfs.c

1135 print-nsh.c

1136 print-ntp.c

1137 print-null.c

1138 print-olsr.c

1139 print-openflow-1.0.c

1140 print-openflow-1.3.c

1141 print-openflow.c

1142 print-ospf.c

1143 print-ospf6.c

1144 print-otv.c

1145 print-pflog.c

1146 print-pgm.c

1147 print-pim.c

1148 print-pktap.c

1149 print-ppi.c

1150 print-ppp.c

1151 print-pppoe.c

1152 print-pptp.c

1153 print-ptp.c

1154 print-quic.c

1155 print-radius.c

1156 print-raw.c

1157 print-realtek.c

1158 print-resp.c

1159 print-rip.c

1160 print-ripng.c

1161 print-rpki-rtr.c

1162 print-rsvp.c

1163 print-rt6.c

1164 print-rtsp.c

1165 print-rx.c

1166 print-sctp.c

1167 print-sflow.c

1168 print-sip.c

1169 print-sl.c

1170 print-sll.c

1171 print-slow.c

1172 print-smtp.c

1173 print-snmp.c

1174 print-someip.c

1175 print-ssh.c

1176 print-stp.c

1177 print-sunatm.c

1178 print-sunrpc.c

1179 print-symantec.c

1180 print-syslog.c

1181 print-tcp.c

1182 print-telnet.c

1183 print-tftp.c

1184 print-timed.c

1185 print-tipc.c

1186 print-token.c

1187 print-udld.c

1188 print-udp.c

1189 print-unsupported.c

1190 print-usb.c

1191 print-vjc.c

1192 print-vqp.c

1193 print-vrrp.c

1194 print-vsock.c

1195 print-vtp.c

1196 print-vxlan-gpe.c

1197 print-vxlan.c

1198 print-wb.c

1199 print-whois.c

1200 print-zep.c

1201 print-zephyr.c

1202 print-zeromq.c

1203 ${LOCALSRC}

1204 signature.c

1205 strtoaddr.c

1206 util-print.c

1207 )

1208

1209 #

1210 # Replace missing functions

1211 #

1212 foreach(FUNC strlcat strlcpy strdup strsep getservent getopt_long)

1213 string(TOUPPER ${FUNC} FUNC_UPPERCASE)

1214 set(HAVE_FUNC_UPPERCASE HAVE_${FUNC_UPPERCASE})

1215 if(NOT ${HAVE_FUNC_UPPERCASE})

1216 set(NETDISSECT_SOURCE_LIST_C ${NETDISSECT_SOURCE_LIST_C} missing/${FUNC}.c)

1217 endif()

1218 endforeach()

1219

1220 add_library(netdissect STATIC

1221 ${NETDISSECT_SOURCE_LIST_C}

1222 )

1223 if(NOT C_ADDITIONAL_FLAGS STREQUAL "")

1224 set_target_properties(netdissect PROPERTIES COMPILE_FLAGS ${C_ADDITIONAL_FLAGS})

1225 endif()

1226

1227 set(TCPDUMP_SOURCE_LIST_C fptype.c tcpdump.c)

1228

1229 if(NOT HAVE_BPF_DUMP)

1230 set(TCPDUMP_SOURCE_LIST_C ${TCPDUMP_SOURCE_LIST_C} bpf_dump.c)

1231 endif(NOT HAVE_BPF_DUMP)

1232 if(NOT HAVE_PCAP_DUMP_FTELL)

1233 set(TCPDUMP_SOURCE_LIST_C ${TCPDUMP_SOURCE_LIST_C} missing/pcap_dump_ftell.c)

1234 endif(NOT HAVE_PCAP_DUMP_FTELL)

1235

1236 if(NOT HAVE_PCAP_LIST_DATALINKS)

1237 set(TCPDUMP_SOURCE_LIST_C ${TCPDUMP_SOURCE_LIST_C} missing/datalinks.c)

1238 endif(NOT HAVE_PCAP_LIST_DATALINKS)

1239

1240 if((NOT HAVE_PCAP_DATALINK_NAME_TO_VAL) OR (NOT HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION))

1241 set(TCPDUMP_SOURCE_LIST_C ${TCPDUMP_SOURCE_LIST_C} missing/dlnames.c)

1242 endif((NOT HAVE_PCAP_DATALINK_NAME_TO_VAL) OR (NOT HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION))

1243

1244 set(PROJECT_SOURCE_LIST_C ${NETDISSECT_SOURCE_LIST_C} ${TCPDUMP_SOURCE_LIST_C})

1245

1246 file(GLOB PROJECT_SOURCE_LIST_H

1247 *.h

1248 )

1249

1250 #

1251 # Assume, by default, no support for shared libraries and V7/BSD

1252 # convention for man pages (devices in section 4, file formats in

1253 # section 5, miscellaneous info in section 7, administrative commands

1254 # and daemons in section 8). Individual cases can override this.

1255 # Individual cases can override this.

1256 #

1257 set(MAN_FILE_FORMATS 5)

1258 set(MAN_MISC_INFO 7)

1259 if(CMAKE_SYSTEM_NAME STREQUAL "AIX")

1260 # Workaround to enable certain features

1261 set(_SUN TRUE)

1262 elseif(CMAKE_SYSTEM_NAME STREQUAL "HP-UX")

1263 #

1264 # Use System V conventions for man pages.

1265 #

1266 set(MAN_FILE_FORMATS 4)

1267 set(MAN_MISC_INFO 5)

1268 elseif(CMAKE_SYSTEM_NAME STREQUAL "IRIX" OR CMAKE_SYSTEM_NAME STREQUAL "IRIX64")

1269 #

1270 # Use IRIX conventions for man pages; they're the same as the

1271 # System V conventions, except that they use section 8 for

1272 # administrative commands and daemons.

1273 #

1274 set(MAN_FILE_FORMATS 4)

1275 set(MAN_MISC_INFO 5)

1276 elseif(CMAKE_SYSTEM_NAME STREQUAL "OSF1")

1277 #

1278 # DEC OSF/1, a/k/a Digital UNIX, a/k/a Tru64 UNIX.

1279 # Use Tru64 UNIX conventions for man pages; they're the same as the

1280 # System V conventions except that they use section 8 for

1281 # administrative commands and daemons.

1282 #

1283 set(MAN_FILE_FORMATS 4)

1284 set(MAN_MISC_INFO 5)

1285 elseif(CMAKE_SYSTEM_NAME STREQUAL "SunOS" AND CMAKE_SYSTEM_VERSION MATCHES "5[.][0-9.]*")

1286 #

1287 # SunOS 5.x.

1288 #

1289 if(CMAKE_SYSTEM_VERSION STREQUAL "5.12")

1290 else()

1291 #

1292 # Use System V conventions for man pages.

1293 #

1294 set(MAN_FILE_FORMATS 4)

1295 set(MAN_MISC_INFO 5)

1296 endif()

1297 endif()

1298

1299 source_group("Source Files" FILES ${PROJECT_SOURCE_LIST_C})

1300 source_group("Header Files" FILES ${PROJECT_SOURCE_LIST_H})

1301

1302 ######################################

1303 # Register targets

1304 ######################################

1305

1306 add_executable(tcpdump ${TCPDUMP_SOURCE_LIST_C})

1307 if(NOT C_ADDITIONAL_FLAGS STREQUAL "")

1308 set_target_properties(tcpdump PROPERTIES COMPILE_FLAGS ${C_ADDITIONAL_FLAGS})

1309 endif()

1310 target_link_libraries(tcpdump netdissect ${TCPDUMP_LINK_LIBRARIES})

1311

1312 ######################################

1313 # Write out the config.h file

1314 ######################################

1315

1316 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/cmakeconfig.h.in ${CMAKE_CURRENT_BINARY_DIR}/config.h)

1317

1318 ######################################

1319 # Install tcpdump and man pages

1320 ######################################

1321

1322 #

1323 # "Define GNU standard installation directories", which actually

1324 # are also defined, to some degree, by autotools, and at least

1325 # some of which are general UN*X conventions.

1326 #

1327 include(GNUInstallDirs)

1328

1329 set(MAN1_EXPAND tcpdump.1.in)

1330

1331 if(WIN32)

1332 # XXX TODO where to install on Windows?

1333 else(WIN32)

1334 install(TARGETS tcpdump DESTINATION bin)

1335 endif(WIN32)

1336

1337 # On UN*X, and on Windows when not using MSVC, process man pages and

1338 # arrange that they be installed.

1339 if(NOT MSVC)

1340 #

1341 # Man pages.

1342 #

1343 # For each section of the manual for which we have man pages

1344 # that require macro expansion, do the expansion.

1345 #

1346 set(MAN1 "")

1347 foreach(TEMPLATE_MANPAGE ${MAN1_EXPAND})

1348 string(REPLACE ".in" "" MANPAGE ${TEMPLATE_MANPAGE})

1349 configure_file(${CMAKE_SOURCE_DIR}/${TEMPLATE_MANPAGE} ${CMAKE_CURRENT_BINARY_DIR}/${MANPAGE} @ONLY)

1350 set(MAN1 ${MAN1} ${CMAKE_CURRENT_BINARY_DIR}/${MANPAGE})

1351 endforeach(TEMPLATE_MANPAGE)

1352 install(FILES ${MAN1} DESTINATION ${CMAKE_INSTALL_MANDIR}/man1)

1353 endif(NOT MSVC)

1354

1355 # uninstall target

1356 configure_file(

1357 "${CMAKE_CURRENT_SOURCE_DIR}/cmake_uninstall.cmake.in"

1358 "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"

1359 IMMEDIATE @ONLY)

1360

1361 add_custom_target(uninstall

1362 COMMAND ${CMAKE_COMMAND} -P ${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake)

1363

1364 #

1365 # Tcpdump tests

1366 # We try to find the Perl interpreter and, if we do, we have the check

1367 # rule run tests/TESTrun with it, because just trying to run the TESTrun

1368 # script as a command won't work on Windows.

1369 #

1370 find_program(PERL perl)

1371 if(PERL)

1372 message(STATUS "Found perl at ${PERL}")

1373 add_custom_target(check

1374 COMMAND ${PERL} ${CMAKE_SOURCE_DIR}/tests/TESTrun)

1375 else()

1376 message(STATUS "Didn't find perl")

1377 endif()