The Tcpdump Group git mirrors - tcpdump/blob - configure.in

   1 dnl @(#) $Header: /tcpdump/master/tcpdump/configure.in,v 1.169.2.5 2004-08-27 07:19:56 guy Exp $ (LBL)
   2 dnl
   3 dnl Copyright (c) 1994, 1995, 1996, 1997
   4 dnl     The Regents of the University of California.  All rights reserved.
   5 dnl
   6 dnl Process this file with autoconf to produce a configure script.
   7 dnl
   8
   9 AC_REVISION($Revision: 1.169.2.5 $)
  10 AC_PREREQ(2.50)
  11 AC_INIT(tcpdump.c)
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_LBL_C_INIT(V_CCOPT, V_INCLS)
  16 AC_LBL_C_INLINE
  17 AC_C___ATTRIBUTE__
  18
  19 AC_CHECK_HEADERS(fcntl.h rpc/rpcent.h netdnet/dnetdb.h netinet/ether.h)
  20 AC_CHECK_HEADERS(netinet/if_ether.h, , , [#include <sys/types.h>
  21 #include <sys/socket.h>])
  22 AC_HEADER_TIME
  23
  24 case "$host_os" in
  25
  26 linux*)
  27         AC_MSG_CHECKING(Linux kernel version)
  28         if test "$cross_compiling" = yes; then
  29                 AC_CACHE_VAL(ac_cv_linux_vers,
  30                     ac_cv_linux_vers=unknown)
  31         else
  32                 AC_CACHE_VAL(ac_cv_linux_vers,
  33                     ac_cv_linux_vers=`uname -r 2>&1 | \
  34                         sed -n -e '$s/.* //' -e '$s/\..*//p'`)
  35         fi
  36         AC_MSG_RESULT($ac_cv_linux_vers)
  37         if test $ac_cv_linux_vers = unknown ; then
  38                 AC_MSG_ERROR(cannot determine linux version when cross-compiling)
  39         fi
  40         if test $ac_cv_linux_vers -lt 2 ; then
  41                 AC_MSG_ERROR(version 2 or higher required; see the INSTALL doc for more info)
  42         fi
  43         ;;
  44
  45 *)
  46         ;;
  47 esac
  48
  49
  50 AC_CHECK_HEADERS(smi.h)
  51 AC_CHECK_LIB(smi, smiInit)
  52 if test "$ac_cv_header_smi_h" = yes -a "$ac_cv_lib_smi_smiInit" = yes
  53 then
  54 AC_MSG_CHECKING([whether to enable libsmi])
  55         AC_TRY_RUN([ /* libsmi available check */
  56 #include <smi.h>
  57 main()
  58 {
  59   int current, revision, age, n;
  60   const int required = 2;
  61   if (smiInit(""))
  62     exit(1);
  63   if (strcmp(SMI_LIBRARY_VERSION, smi_library_version))
  64     exit(2);
  65   n = sscanf(smi_library_version, "%d:%d:%d", &current, &revision, &age);
  66   if (n != 3)
  67     exit(3);
  68   if (required < current - age || required > current)
  69     exit(4);
  70   exit(0);
  71 }
  72 ],
  73 [ AC_MSG_RESULT(yes)
  74   AC_DEFINE(LIBSMI)
  75   libsmi=yes],
  76 dnl autoconf documentation says that $? contains the exit value.
  77 dnl reality is that it does not.  We leave this in just in case
  78 dnl autoconf ever comes back to match the documentation.
  79 [ case $? in
  80   1) AC_MSG_RESULT(no - smiInit failed) ;;
  81   2) AC_MSG_RESULT(no - header/library version mismatch) ;;
  82   3) AC_MSG_RESULT(no - can't determine library version) ;;
  83   4) AC_MSG_RESULT(no - too old) ;;
  84   *) AC_MSG_RESULT(no) ;;
  85   esac
  86   libsmi=no],
  87 [ AC_MSG_RESULT(not when cross-compiling)
  88   libsmi=no]
  89 )
  90 fi
  91
  92 AC_MSG_CHECKING([whether to enable the possibly-buggy SMB printer])
  93 AC_ARG_ENABLE(smb,
  94 [  --enable-smb            enable possibly-buggy SMB printer [default=yes]
  95   --disable-smb           disable possibly-buggy SMB printer],,
  96    enableval=yes)
  97 case "$enableval" in
  98 yes)    AC_MSG_RESULT(yes)
  99         AC_WARN([The SMB printer may have exploitable buffer overflows!!!])
 100         AC_DEFINE(TCPDUMP_DO_SMB)
 101         LOCALSRC="print-smb.c smbutil.c $LOCALSRC"
 102         ;;
 103 *)      AC_MSG_RESULT(no)
 104         ;;
 105 esac
 106
 107 AC_MSG_CHECKING([whether to enable ipv6])
 108 AC_ARG_ENABLE(ipv6,
 109 [  --enable-ipv6           enable ipv6 (with ipv4) support
 110   --disable-ipv6          disable ipv6 support],
 111 [ case "$enableval" in
 112 yes)   AC_MSG_RESULT(yes)
 113        LOCALSRC="print-ip6.c print-ip6opts.c print-mobility.c print-ripng.c print-icmp6.c print-frag6.c print-rt6.c print-ospf6.c print-dhcp6.c $LOCALSRC"
 114        AC_DEFINE(INET6)
 115        ipv6=yes
 116        ;;
 117 *)
 118        AC_MSG_RESULT(no)
 119        ipv6=no
 120        ;;
 121   esac ],
 122
 123   AC_TRY_RUN([ /* AF_INET6 available check */
 124 #include <sys/types.h>
 125 #include <sys/socket.h>
 126 main()
 127 {
 128  if (socket(AF_INET6, SOCK_STREAM, 0) < 0)
 129    exit(1);
 130  else
 131    exit(0);
 132 }
 133 ],
 134 [ AC_MSG_RESULT(yes)
 135   LOCALSRC="print-ip6.c print-ip6opts.c print-mobility.c print-ripng.c print-icmp6.c print-frag6.c print-rt6.c print-ospf6.c print-dhcp6.c $LOCALSRC"
 136   AC_DEFINE(INET6)
 137   ipv6=yes],
 138 [ AC_MSG_RESULT(no)
 139   ipv6=no],
 140 [ AC_MSG_RESULT(no)
 141   ipv6=no]
 142 ))
 143
 144 ipv6type=unknown
 145 ipv6lib=none
 146 ipv6trylibc=no
 147
 148 if test "$ipv6" = "yes"; then
 149         AC_MSG_CHECKING([ipv6 stack type])
 150         for i in inria kame linux-glibc linux-libinet6 toshiba v6d zeta; do
 151                 case $i in
 152                 inria)
 153                         dnl http://www.kame.net/
 154                         AC_EGREP_CPP(yes,
 155 [#include <netinet/in.h>
 156 #ifdef IPV6_INRIA_VERSION
 157 yes
 158 #endif],
 159                                 [ipv6type=$i;
 160                                 CFLAGS="-DINET6 $CFLAGS"])
 161                         ;;
 162                 kame)
 163                         dnl http://www.kame.net/
 164                         AC_EGREP_CPP(yes,
 165 [#include <netinet/in.h>
 166 #ifdef __KAME__
 167 yes
 168 #endif],
 169                                 [ipv6type=$i;
 170                                 ipv6lib=inet6;
 171                                 ipv6libdir=/usr/local/v6/lib;
 172                                 ipv6trylibc=yes;
 173                                 CFLAGS="-DINET6 $CFLAGS"])
 174                         ;;
 175                 linux-glibc)
 176                         dnl http://www.v6.linux.or.jp/
 177                         AC_EGREP_CPP(yes,
 178 [#include <features.h>
 179 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 180 yes
 181 #endif],
 182                                 [ipv6type=$i;
 183                                 CFLAGS="-DINET6 $CFLAGS"])
 184                         ;;
 185                 linux-libinet6)
 186                         dnl http://www.v6.linux.or.jp/
 187                         dnl
 188                         dnl This also matches Solaris 8 and Tru64 UNIX 5.1,
 189                         dnl and possibly other versions of those OSes
 190                         dnl
 191                         if test -d /usr/inet6 -o -f /usr/include/netinet/ip6.h; then
 192                                 ipv6type=$i
 193                                 ipv6lib=inet6
 194                                 ipv6libdir=/usr/inet6/lib
 195                                 ipv6trylibc=yes;
 196                                 CFLAGS="-DINET6 -I/usr/inet6/include $CFLAGS"
 197                         fi
 198                         ;;
 199                 toshiba)
 200                         AC_EGREP_CPP(yes,
 201 [#include <sys/param.h>
 202 #ifdef _TOSHIBA_INET6
 203 yes
 204 #endif],
 205                                 [ipv6type=$i;
 206                                 ipv6lib=inet6;
 207                                 ipv6libdir=/usr/local/v6/lib;
 208                                 CFLAGS="-DINET6 $CFLAGS"])
 209                         ;;
 210                 v6d)
 211                         AC_EGREP_CPP(yes,
 212 [#include </usr/local/v6/include/sys/v6config.h>
 213 #ifdef __V6D__
 214 yes
 215 #endif],
 216                                 [ipv6type=$i;
 217                                 ipv6lib=v6;
 218                                 ipv6libdir=/usr/local/v6/lib;
 219                                 CFLAGS="-I/usr/local/v6/include $CFLAGS"])
 220                         ;;
 221                 zeta)
 222                         AC_EGREP_CPP(yes,
 223 [#include <sys/param.h>
 224 #ifdef _ZETA_MINAMI_INET6
 225 yes
 226 #endif],
 227                                 [ipv6type=$i;
 228                                 ipv6lib=inet6;
 229                                 ipv6libdir=/usr/local/v6/lib;
 230                                 CFLAGS="-DINET6 $CFLAGS"])
 231                         ;;
 232                 esac
 233                 if test "$ipv6type" != "unknown"; then
 234                         break
 235                 fi
 236         done
 237         AC_MSG_RESULT($ipv6type)
 238 fi
 239
 240 if test "$ipv6" = "yes" -a "$ipv6lib" != "none"; then
 241         if test -d $ipv6libdir -a -f $ipv6libdir/lib$ipv6lib.a; then
 242                 LIBS="-L$ipv6libdir -l$ipv6lib $LIBS"
 243                 echo "You have $ipv6lib library, using it"
 244         else
 245                 if test "$ipv6trylibc" = "yes"; then
 246                         echo "You do not have $ipv6lib library, using libc"
 247                 else
 248                         echo 'Fatal: no $ipv6lib library found.  cannot continue.'
 249                         echo "You need to fetch lib$ipv6lib.a from appropriate"
 250                         echo 'ipv6 kit and compile beforehand.'
 251                         exit 1
 252                 fi
 253         fi
 254 fi
 255
 256
 257 if test "$ipv6" = "yes"; then
 258         #
 259         # XXX - on Tru64 UNIX 5.1, there is no "getaddrinfo()"
 260         # function in libc; there are "ngetaddrinfo()" and
 261         # "ogetaddrinfo()" functions, and <netdb.h> #defines
 262         # "getaddrinfo" to be either "ngetaddrinfo" or
 263         # "ogetaddrinfo", depending on whether _SOCKADDR_LEN
 264         # or _XOPEN_SOURCE_EXTENDED are defined or not.
 265         #
 266         # So this test doesn't work on Tru64 5.1, and possibly
 267         # on other 5.x releases.  This causes the configure
 268         # script to become confused, and results in libpcap
 269         # being unbuildable.
 270         #
 271         AC_SEARCH_LIBS(getaddrinfo, socket, [dnl
 272         AC_MSG_CHECKING(getaddrinfo bug)
 273         AC_CACHE_VAL(td_cv_buggygetaddrinfo, [AC_TRY_RUN([
 274 #include <sys/types.h>
 275 #include <netdb.h>
 276 #include <string.h>
 277 #include <sys/socket.h>
 278 #include <netinet/in.h>
 279
 280 main()
 281 {
 282   int passive, gaierr, inet4 = 0, inet6 = 0;
 283   struct addrinfo hints, *ai, *aitop;
 284   char straddr[INET6_ADDRSTRLEN], strport[16];
 285
 286   for (passive = 0; passive <= 1; passive++) {
 287     memset(&hints, 0, sizeof(hints));
 288     hints.ai_family = AF_UNSPEC;
 289     hints.ai_flags = passive ? AI_PASSIVE : 0;
 290     hints.ai_socktype = SOCK_STREAM;
 291     hints.ai_protocol = IPPROTO_TCP;
 292     if ((gaierr = getaddrinfo(NULL, "54321", &hints, &aitop)) != 0) {
 293       (void)gai_strerror(gaierr);
 294       goto bad;
 295     }
 296     for (ai = aitop; ai; ai = ai->ai_next) {
 297       if (ai->ai_addr == NULL ||
 298           ai->ai_addrlen == 0 ||
 299           getnameinfo(ai->ai_addr, ai->ai_addrlen,
 300                       straddr, sizeof(straddr), strport, sizeof(strport),
 301                       NI_NUMERICHOST|NI_NUMERICSERV) != 0) {
 302         goto bad;
 303       }
 304       switch (ai->ai_family) {
 305       case AF_INET:
 306         if (strcmp(strport, "54321") != 0) {
 307           goto bad;
 308         }
 309         if (passive) {
 310           if (strcmp(straddr, "0.0.0.0") != 0) {
 311             goto bad;
 312           }
 313         } else {
 314           if (strcmp(straddr, "127.0.0.1") != 0) {
 315             goto bad;
 316           }
 317         }
 318         inet4++;
 319         break;
 320       case AF_INET6:
 321         if (strcmp(strport, "54321") != 0) {
 322           goto bad;
 323         }
 324         if (passive) {
 325           if (strcmp(straddr, "::") != 0) {
 326             goto bad;
 327           }
 328         } else {
 329           if (strcmp(straddr, "::1") != 0) {
 330             goto bad;
 331           }
 332         }
 333         inet6++;
 334         break;
 335       case AF_UNSPEC:
 336         goto bad;
 337         break;
 338 #ifdef AF_UNIX
 339       case AF_UNIX:
 340 #else
 341 #ifdef AF_LOCAL
 342       case AF_LOCAL:
 343 #endif
 344 #endif
 345       default:
 346         /* another family support? */
 347         break;
 348       }
 349     }
 350   }
 351
 352   /* supported family should be 2, unsupported family should be 0 */
 353   if (!(inet4 == 0 || inet4 == 2))
 354     goto bad;
 355   if (!(inet6 == 0 || inet6 == 2))
 356     goto bad;
 357
 358   if (aitop)
 359     freeaddrinfo(aitop);
 360   exit(0);
 361
 362  bad:
 363   if (aitop)
 364     freeaddrinfo(aitop);
 365   exit(1);
 366 }
 367 ],
 368         td_cv_buggygetaddrinfo=no,
 369         td_cv_buggygetaddrinfo=yes,
 370         td_cv_buggygetaddrinfo=yes)])
 371         if test "$td_cv_buggygetaddrinfo" = no; then
 372                 AC_MSG_RESULT(good)
 373         else
 374                 AC_MSG_RESULT(buggy)
 375         fi
 376
 377         if test "$td_cv_buggygetaddrinfo" = "yes"; then
 378                 #
 379                 # XXX - it doesn't appear that "ipv6type" can ever be
 380                 # set to "linux".  Should this be testing for
 381                 # "linux-glibc", or for that *or* "linux-libinet6"?
 382                 # If the latter, note that "linux-libinet6" is also
 383                 # the type given to some non-Linux OSes.
 384                 #
 385                 if test "$ipv6type" != "linux"; then
 386                         echo 'Fatal: You must get working getaddrinfo() function.'
 387                         echo '       or you can specify "--disable-ipv6"'.
 388                         exit 1
 389                 else
 390                         echo 'Warning: getaddrinfo() implementation on your system seems be buggy.'
 391                         echo '         Better upgrade your system library to newest version'
 392                         echo '         of GNU C library (aka glibc).'
 393                 fi
 394         fi
 395         ])
 396         AC_REPLACE_FUNCS(getaddrinfo getnameinfo)
 397 fi
 398
 399 AC_CACHE_CHECK([for dnet_htoa declaration in netdnet/dnetdb.h],
 400 [td_cv_decl_netdnet_dnetdb_h_dnet_htoa],
 401 [AC_EGREP_HEADER(dnet_htoa, netdnet/dnetdb.h,
 402         td_cv_decl_netdnet_dnetdb_h_dnet_htoa=yes,
 403         td_cv_decl_netdnet_dnetdb_h_dnet_htoa=no)])
 404 if test "$td_cv_decl_netdnet_dnetdb_h_dnet_htoa" = yes; then
 405         AC_DEFINE(HAVE_NETDNET_DNETDB_H_DNET_HTOA)
 406 fi
 407
 408 dnl
 409 dnl check sizeof basic types.
 410 dnl They're very likely to be wrong for cross-compiling.
 411 AC_CHECK_SIZEOF(char, 1)
 412 AC_CHECK_SIZEOF(short, 2)
 413 AC_CHECK_SIZEOF(int, 4)
 414 AC_CHECK_SIZEOF(long, 4)
 415
 416 dnl
 417 dnl Checks for u_intXX_t
 418 dnl AC_CHECK_BITTYPES(ac_cv_bittypes)
 419 dnl if test "$ac_cv_bittypes" = no; then
 420 dnl     missing_includes=yes
 421 dnl fi
 422
 423 dnl
 424 dnl Checks for addrinfo structure
 425 AC_STRUCT_ADDRINFO(ac_cv_addrinfo)
 426 if test "$ac_cv_addrinfo" = no; then
 427         missing_includes=yes
 428 fi
 429
 430 dnl
 431 dnl Checks for NI_MAXSERV
 432 AC_NI_MAXSERV(ac_cv_maxserv)
 433 if test "$ac_cv_maxserv" = no; then
 434         missing_includes=yes
 435 fi
 436
 437 dnl
 438 dnl Checks for NI_NAMEREQD
 439 AC_NI_NAMEREQD(ac_cv_namereqd)
 440 if test "$ac_cv_namereqd" = no; then
 441         missing_includes=yes
 442 fi
 443
 444 dnl
 445 dnl Checks for sockaddr_storage structure
 446 AC_STRUCT_SA_STORAGE(ac_cv_sa_storage)
 447 if test "$ac_cv_sa_storage" = no; then
 448         missing_includes=yes
 449 fi
 450
 451 dnl
 452 dnl Checks for IN[6]ADDRSZ
 453 AC_CHECK_ADDRSZ(ac_cv_addrsz)
 454 if test "$ac_cv_addrsz" = no; then
 455         missing_includes=yes
 456 fi
 457
 458 dnl
 459 dnl Checks for RES_USE_INET6
 460 AC_CHECK_RES_USE_INET6(ac_cv_res_inet6)
 461 if test "$ac_cv_res_inet6" = no; then
 462         missing_includes=yes
 463 fi
 464
 465 dnl
 466 dnl Checks for res_state_ext structure
 467 AC_STRUCT_RES_STATE_EXT(ac_cv_res_state_ext)
 468 if test "$ac_cv_res_state_ext" = no; then
 469         missing_includes=yes
 470 fi
 471
 472 dnl
 473 dnl Checks if res_state structure has nsort member.
 474 AC_STRUCT_RES_STATE(ac_cv_res_state)
 475
 476 dnl
 477 dnl set additional include path if necessary
 478 if test "$missing_includes" = "yes"; then
 479         CPPFLAGS="$CPPFLAGS -I\$(srcdir)/missing"
 480         V_INCLS="$V_INCLS -I\$(srcdir)/missing"
 481 fi
 482
 483
 484 AC_REPLACE_FUNCS(vfprintf strcasecmp strlcat strlcpy strdup strsep)
 485 AC_CHECK_FUNCS(strftime)
 486 AC_CHECK_FUNCS(ether_ntohost, [
 487     AC_CACHE_CHECK(for buggy ether_ntohost, ac_cv_buggy_ether_ntohost, [
 488         AC_TRY_RUN([
 489                 #include <netdb.h>
 490                 #include <sys/types.h>
 491                 #include <sys/param.h>
 492                 #include <sys/socket.h>
 493
 494                 int
 495                 main(int argc, char **argv)
 496                 {
 497                         u_char ea[6] = { 0xff, 0xff, 0xff, 0xff, 0xff };
 498                         char name[MAXHOSTNAMELEN];
 499
 500                         ether_ntohost(name, (struct ether_addr *)ea);
 501                         exit(0);
 502                 }
 503         ], [ac_cv_buggy_ether_ntohost=no],
 504            [ac_cv_buggy_ether_ntohost=yes],
 505            [ac_cv_buggy_ether_ntohost="not while cross-compiling"])])
 506     if test "$ac_cv_buggy_ether_ntohost" = "no"; then
 507         AC_DEFINE(USE_ETHER_NTOHOST)
 508     fi
 509 ])
 510 AC_CHECK_FUNCS(setlinebuf)
 511
 512 needsnprintf=no
 513 AC_CHECK_FUNCS(vsnprintf snprintf,,
 514         [needsnprintf=yes])
 515 if test $needsnprintf = yes; then
 516         AC_LIBOBJ(snprintf)
 517 fi
 518
 519 AC_LBL_TYPE_SIGNAL
 520
 521 AC_SEARCH_LIBS(dnet_htoa, dnet, AC_DEFINE(HAVE_DNET_HTOA))
 522
 523 AC_CHECK_LIB(rpc, main)         dnl It's unclear why we might need -lrpc
 524
 525 dnl HP/UX may need -lnsl for getrpcbynumber.
 526 AC_SEARCH_LIBS(getrpcbynumber, nsl)
 527
 528 dnl AC_CHECK_LIB(z, uncompress)
 529 dnl AC_CHECK_HEADERS(zlib.h)
 530
 531 AC_LBL_LIBPCAP(V_PCAPDEP, V_INCLS)
 532
 533 #
 534 # Check for these after AC_LBL_LIBPCAP, so we link with the appropriate
 535 # libraries (e.g., "-lsocket -lnsl" on Solaris).
 536 #
 537 # We don't use AC_REPLACE_FUNCS because that uses AC_CHECK_FUNCS which
 538 # use AC_CHECK_FUNC which doesn't let us specify the right #includes
 539 # to make this work on BSD/OS 4.x.  BSD/OS 4.x ships with the BIND8
 540 # resolver, and the way it defines inet_{ntop,pton} is rather strange;
 541 # it does not ship with a libc symbol "inet_ntop()", it ships with
 542 # "_inet_ntop()", and has a #define macro in one of the system headers
 543 # to rename it.
 544 #
 545 dnl AC_TRY_COMPILE(inet_ntop inet_pton inet_aton)
 546 AC_MSG_CHECKING(for inet_ntop)
 547 AC_TRY_LINK([#include <sys/types.h>
 548 #include <sys/socket.h>
 549 #include <netinet/in.h>
 550 #include <arpa/inet.h>], [char src[4], dst[128];
 551 inet_ntop(AF_INET, src, dst, sizeof(dst));],
 552         [AC_MSG_RESULT(yes)], [AC_MSG_RESULT(no)
 553         AC_LIBOBJ(inet_ntop)])
 554 AC_MSG_CHECKING(for inet_pton)
 555 AC_TRY_LINK([#include <sys/types.h>
 556 #include <sys/socket.h>
 557 #include <netinet/in.h>
 558 #include <arpa/inet.h>], [char src[128], dst[4];
 559 inet_pton(AF_INET, src, dst);],
 560         [AC_MSG_RESULT(yes)], [AC_MSG_RESULT(no)
 561         AC_LIBOBJ(inet_pton)])
 562 AC_MSG_CHECKING(for inet_aton)
 563 AC_TRY_LINK([#include <sys/types.h>
 564 #include <netinet/in.h>
 565 #include <arpa/inet.h>], [char src[128];
 566 struct in_addr dst;
 567 inet_aton(src, &dst);],
 568         [AC_MSG_RESULT(yes)], [AC_MSG_RESULT(no)
 569         AC_LIBOBJ(inet_aton)])
 570
 571 dnl portability macros for getaddrinfo/getnameinfo
 572 dnl
 573 dnl Check for sa_len
 574 AC_CHECK_SA_LEN(ac_cv_sockaddr_has_sa_len)
 575 if test "$ac_cv_sockaddr_has_sa_len" = no; then
 576         missing_includes=yes
 577 fi
 578
 579 AC_CHECK_FUNCS(pcap_findalldevs pcap_dump_flush pcap_lib_version)
 580 if test $ac_cv_func_pcap_findalldevs = "yes" ; then
 581 dnl Check for MacOS X, which may ship pcap.h from 0.6 but libpcap may
 582 dnl be 0.8; this means that lib has pcap_findalldevs but header doesn't
 583 dnl have pcap_if_t.
 584     AC_CHECK_TYPES(pcap_if_t, , , [#include <pcap.h>])
 585 fi
 586 if test $ac_cv_func_pcap_lib_version = "no" ; then
 587     AC_MSG_CHECKING(whether pcap_version is defined by libpcap)
 588     AC_TRY_LINK([],
 589        [
 590         extern char pcap_version[];
 591
 592         return (int)pcap_version;
 593        ],
 594        ac_lbl_cv_pcap_version_defined=yes,
 595        ac_lbl_cv_pcap_version_defined=no)
 596     if test "$ac_lbl_cv_pcap_version_defined" = yes ; then
 597         AC_MSG_RESULT(yes)
 598         AC_DEFINE(HAVE_PCAP_VERSION)
 599     else
 600         AC_MSG_RESULT(no)
 601     fi
 602 fi
 603 AC_MSG_CHECKING(whether pcap_debug is defined by libpcap)
 604 AC_TRY_LINK([],
 605    [
 606         extern int pcap_debug;
 607
 608         return pcap_debug;
 609    ],
 610    ac_lbl_cv_pcap_debug_defined=yes,
 611    ac_lbl_cv_pcap_debug_defined=no)
 612 if test "$ac_lbl_cv_pcap_debug_defined" = yes ; then
 613         AC_MSG_RESULT(yes)
 614         AC_DEFINE(HAVE_PCAP_DEBUG)
 615 else
 616         AC_MSG_RESULT(no)
 617         #
 618         # OK, what about "yydebug"?
 619         #
 620         AC_MSG_CHECKING(whether yydebug is defined by libpcap)
 621         AC_TRY_LINK([],
 622            [
 623                 extern int yydebug;
 624
 625                 return yydebug;
 626            ],
 627            ac_lbl_cv_yydebug_defined=yes,
 628            ac_lbl_cv_yydebug_defined=no)
 629         if test "$ac_lbl_cv_yydebug_defined" = yes ; then
 630                 AC_MSG_RESULT(yes)
 631                 AC_DEFINE(HAVE_YYDEBUG)
 632         else
 633                 AC_MSG_RESULT(no)
 634         fi
 635 fi
 636 AC_REPLACE_FUNCS(bpf_dump)      dnl moved to libpcap in 0.6
 637
 638 V_GROUP=0
 639 if test -f /etc/group -a ! -z "`grep '^wheel:' /etc/group`" ; then
 640         V_GROUP=wheel
 641 fi
 642 case "$host_os" in
 643
 644 aix*)
 645         dnl Workaround to enable certain features
 646         AC_DEFINE(_SUN)
 647         ;;
 648
 649 irix*)
 650         V_GROUP=sys
 651         ;;
 652
 653 osf*)
 654         V_GROUP=system
 655         ;;
 656
 657 solaris*)
 658         V_GROUP=sys
 659         ;;
 660 esac
 661
 662 if test -f /dev/bpf0 ; then
 663         V_GROUP=bpf
 664 fi
 665
 666 AC_LBL_CHECK_TYPE(int8_t, signed char)
 667 AC_LBL_CHECK_TYPE(u_int8_t, u_char)
 668 AC_LBL_CHECK_TYPE(int16_t, short)
 669 AC_LBL_CHECK_TYPE(u_int16_t, u_short)
 670 AC_LBL_CHECK_TYPE(int32_t, int)
 671 AC_LBL_CHECK_TYPE(u_int32_t, u_int)
 672
 673 AC_LBL_DEVEL(V_CCOPT)
 674
 675 AC_LBL_SOCKADDR_SA_LEN
 676
 677 AC_LBL_UNALIGNED_ACCESS
 678
 679 AC_VAR_H_ERRNO
 680
 681 AC_ARG_WITH(crypto, [  --without-crypto        disable crypto support],
 682         [], [
 683 AC_MSG_CHECKING(for SSLeay)
 684 ac_cv_ssleay_path=no
 685 incdir=no
 686 for dir in /usr/${host_alias} /usr /usr/local /usr/local/ssl /usr/pkg; do
 687         #
 688         # XXX - is there a better way to check if a given library is
 689         # in a given directory than checking each of the possible
 690         # shared library suffixes?
 691         #
 692         # Are there any other suffixes we need to look for?  Do we have to
 693         # worry about ".so.{version}"?
 694         #
 695         # Or should we just look for "libcrypto.*"?
 696         #
 697         if test -d $dir/lib -a \( -f $dir/lib/libcrypto.a -o \
 698                                   -f $dir/lib/libcrypto.so -o \
 699                                   -f $dir/lib/libcrypto.sl -o \
 700                                   -f $dir/lib/libcrypto.dylib \); then
 701                 ac_cv_ssleay_path=$dir
 702         fi
 703         if test -d $dir/include/openssl -a -f $dir/include/openssl/des.h; then
 704                 incdir="-I$dir/include"
 705         fi
 706         if test "$ac_cv_ssleay_path" != "no" -a "$incdir" != "no"; then
 707                 break;
 708         else
 709                 ac_cv_ssleay_path=no
 710                 incdir=no
 711         fi
 712 done
 713 AC_MSG_RESULT($ac_cv_ssleay_path)
 714 if test "$ac_cv_ssleay_path" != no; then
 715         V_INCLS="$V_INCLS $incdir"
 716         LDFLAGS="-L$dir/lib $LDFLAGS"
 717         if test -f $ac_cv_ssleay_path/lib/libRSAglue.a; then
 718                 LIBS="$LIBS -lRSAglue"
 719         fi
 720         if test -f $ac_cv_ssleay_path/lib/librsaref.a; then
 721                 LIBS="$LIBS -lrsaref"
 722         fi
 723         AC_CHECK_LIB(crypto, des_cbc_encrypt)
 724
 725         CPPFLAGS="$CPPFLAGS $V_INCLS"
 726         AC_CHECK_HEADERS(openssl/evp.h)
 727 fi
 728 ])
 729
 730 AC_SUBST(V_CCOPT)
 731 AC_SUBST(V_DEFS)
 732 AC_SUBST(V_GROUP)
 733 AC_SUBST(V_INCLS)
 734 AC_SUBST(V_PCAPDEP)
 735 AC_SUBST(LOCALSRC)
 736
 737 AC_PROG_INSTALL
 738
 739 AC_CONFIG_HEADER(config.h)
 740
 741 AC_OUTPUT_COMMANDS([if test -f .devel; then
 742         echo timestamp > stamp-h
 743         cat Makefile-devel-adds >> Makefile
 744         make depend
 745 fi])
 746 AC_OUTPUT(Makefile)
 747 exit 0