The Tcpdump Group git mirrors - tcpdump/blob - configure.ac

   1 dnl Copyright (c) 1994, 1995, 1996, 1997
   2 dnl     The Regents of the University of California.  All rights reserved.
   3 dnl
   4 dnl Process this file with autoconf to produce a configure script.
   5 dnl
   6
   7 #
   8 # See
   9 #
  10 #       https://ftp.gnu.org/gnu/config/README
  11 #
  12 # for the URLs to use to fetch new versions of config.guess and
  13 # config.sub.
  14 #
  15
  16 AC_PREREQ(2.64)
  17 AC_INIT(tcpdump, m4_esyscmd_s([cat VERSION]))
  18 AC_CONFIG_SRCDIR(tcpdump.c)
  19
  20 AC_CANONICAL_HOST
  21
  22 AC_LBL_C_INIT_BEFORE_CC(V_INCLS)
  23 #
  24 # Try to enable as many C99 features as we can.
  25 # At minimum, we want C++/C99-style // comments.
  26 #
  27 AC_PROG_CC_C99
  28 if test "$ac_cv_prog_cc_c99" = "no"; then
  29         AC_MSG_WARN([The C compiler does not support C99; there may be compiler errors])
  30 fi
  31 AC_LBL_C_INIT(V_CCOPT, V_INCLS)
  32 AC_LBL_C_INLINE
  33
  34 AC_CHECK_HEADERS(fcntl.h rpc/rpc.h rpc/rpcent.h net/if.h)
  35 AC_CHECK_HEADERS(net/pfvar.h, , , [#include <sys/types.h>
  36 #include <sys/socket.h>
  37 #include <net/if.h>])
  38 if test "$ac_cv_header_net_pfvar_h" = yes; then
  39         AC_CHECK_HEADERS(net/if_pflog.h, , , [#include <sys/types.h>
  40         #include <sys/socket.h>
  41         #include <net/if.h>
  42         #include <net/pfvar.h>])
  43         if test "$ac_cv_header_net_if_pflog_h" = yes; then
  44                 LOCALSRC="print-pflog.c $LOCALSRC"
  45         fi
  46 fi
  47
  48 case "$host_os" in
  49
  50 darwin*)
  51         AC_ARG_ENABLE(universal,
  52         AC_HELP_STRING([--disable-universal],[don't build universal on macOS]))
  53         if test "$enable_universal" != "no"; then
  54                 case "$host_os" in
  55
  56                 darwin9.*)
  57                         #
  58                         # Leopard.  Build for x86 and 32-bit PowerPC, with
  59                         # x86 first.  (That's what Apple does.)
  60                         #
  61                         V_CCOPT="$V_CCOPT -arch i386 -arch ppc"
  62                         LDFLAGS="$LDFLAGS -arch i386 -arch ppc"
  63                         ;;
  64
  65                 darwin10.*)
  66                         #
  67                         # Snow Leopard.  Build for x86-64 and x86, with
  68                         # x86-64 first.  (That's what Apple does.)
  69                         #
  70                         V_CCOPT="$V_CCOPT -arch x86_64 -arch i386"
  71                         LDFLAGS="$LDFLAGS -arch x86_64 -arch i386"
  72                         ;;
  73                 esac
  74         fi
  75         ;;
  76 esac
  77
  78
  79 AC_ARG_WITH(smi,
  80 [  --with-smi              link with libsmi (allows to load MIBs on the fly to decode SNMP packets. [default=yes]
  81   --without-smi           don't link with libsmi],,
  82    with_smi=yes)
  83
  84 if test "x$with_smi" != "xno" ; then
  85         AC_CHECK_HEADER(smi.h,
  86         [
  87                 #
  88                 # OK, we found smi.h.  Do we have libsmi with smiInit?
  89                 #
  90                 AC_CHECK_LIB(smi, smiInit,
  91                 [
  92                         #
  93                         # OK, we have libsmi with smiInit.  Can we use it?
  94                         #
  95                         AC_MSG_CHECKING([whether to enable libsmi])
  96                         savedlibs="$LIBS"
  97                         LIBS="-lsmi $LIBS"
  98                         AC_TRY_RUN(
  99                                 [
 100 /* libsmi available check */
 101 #include <smi.h>
 102 main()
 103 {
 104   int current, revision, age, n;
 105   const int required = 2;
 106   if (smiInit(""))
 107     exit(1);
 108   if (strcmp(SMI_LIBRARY_VERSION, smi_library_version))
 109     exit(2);
 110   n = sscanf(smi_library_version, "%d:%d:%d", &current, &revision, &age);
 111   if (n != 3)
 112     exit(3);
 113   if (required < current - age || required > current)
 114     exit(4);
 115   exit(0);
 116 }
 117                                 ],
 118                                 [
 119                                         AC_MSG_RESULT(yes)
 120                                         AC_DEFINE(USE_LIBSMI, 1,
 121                                             [Define if you enable support for libsmi])
 122                                 ],
 123                                 [
 124                                         dnl autoconf documentation says that
 125                                         dnl $? contains the exit value.
 126                                         dnl reality is that it does not.
 127                                         dnl We leave this in just in case
 128                                         dnl autoconf ever comes back to
 129                                         dnl match the documentation.
 130                                         case $? in
 131                                           1) AC_MSG_RESULT(no - smiInit failed) ;;
 132                                           2) AC_MSG_RESULT(no - header/library version mismatch) ;;
 133                                           3) AC_MSG_RESULT(no - can't determine library version) ;;
 134                                           4) AC_MSG_RESULT(no - too old) ;;
 135                                           *) AC_MSG_RESULT(no) ;;
 136                                         esac
 137                                         LIBS="$savedlibs"
 138                                 ],
 139                                 [
 140                                         AC_MSG_RESULT(not when cross-compiling)
 141                                         LIBS="$savedlibs"
 142                                 ]
 143                         )
 144                 ])
 145         ])
 146 fi
 147
 148 AC_MSG_CHECKING([whether to enable the possibly-buggy SMB printer])
 149 AC_ARG_ENABLE(smb,
 150 [  --enable-smb            enable possibly-buggy SMB printer [default=yes]
 151   --disable-smb           disable possibly-buggy SMB printer],,
 152    enableval=yes)
 153 case "$enableval" in
 154 yes)    AC_MSG_RESULT(yes)
 155         AC_DEFINE(ENABLE_SMB, 1,
 156             [define if you want to build the possibly-buggy SMB printer])
 157         LOCALSRC="print-smb.c smbutil.c $LOCALSRC"
 158         ;;
 159 *)      AC_MSG_RESULT(no)
 160         ;;
 161 esac
 162
 163 AC_ARG_WITH(user, [  --with-user=USERNAME    drop privileges by default to USERNAME])
 164 AC_MSG_CHECKING([whether to drop root privileges by default])
 165 if test ! -z "$with_user" ; then
 166        AC_DEFINE_UNQUOTED(WITH_USER, "$withval",
 167            [define if should drop privileges by default])
 168        AC_MSG_RESULT(to \"$withval\")
 169 else
 170        AC_MSG_RESULT(no)
 171 fi
 172
 173 AC_ARG_WITH(chroot, [  --with-chroot=DIRECTORY when dropping privileges, chroot to DIRECTORY])
 174 AC_MSG_CHECKING([whether to chroot])
 175 if test ! -z "$with_chroot" && test "$with_chroot" != "no" ; then
 176        AC_DEFINE_UNQUOTED(WITH_CHROOT, "$withval",
 177            [define if should chroot when dropping privileges])
 178        AC_MSG_RESULT(to \"$withval\")
 179 else
 180        AC_MSG_RESULT(no)
 181 fi
 182
 183 AC_ARG_WITH(sandbox-capsicum,
 184         AS_HELP_STRING([--with-sandbox-capsicum],
 185                        [use Capsicum security functions @<:@default=yes, if available@:>@]))
 186 #
 187 # Check whether various functions are available.  If any are, set
 188 # ac_lbl_capsicum_function_seen to yes; if any are not, set
 189 # ac_lbl_capsicum_function_not_seen to yes.
 190 #
 191 # We don't check cap_rights_init(), as it's a macro, wrapping another
 192 # function, in at least some versions of FreeBSD, and AC_CHECK_FUNCS()
 193 # doesn't handle that.
 194 #
 195 # All of the ones we check for must be available in order to enable
 196 # capsicum sandboxing.
 197 #
 198 # XXX - do we need to check for all of them, or are there some that, if
 199 # present, imply others are present?
 200 #
 201 if test ! -z "$with_sandbox_capsicum" && test "$with_sandbox_capsicum" != "no" ; then
 202         #
 203         # First, make sure we have the required header.
 204         #
 205         AC_CHECK_HEADER(sys/capsicum.h,
 206         [
 207                 #
 208                 # We do; now make sure we have the required functions.
 209                 #
 210                 AC_CHECK_FUNCS(cap_enter cap_rights_limit cap_ioctls_limit openat,
 211                     ac_lbl_capsicum_function_seen=yes,
 212                     ac_lbl_capsicum_function_not_seen=yes)
 213         ])
 214         AC_CHECK_LIB(casper, cap_init, LIBS="$LIBS -lcasper")
 215         AC_CHECK_LIB(cap_dns, cap_gethostbyaddr, LIBS="$LIBS -lcap_dns")
 216 fi
 217 AC_MSG_CHECKING([whether to sandbox using capsicum])
 218 if test "x$ac_lbl_capsicum_function_seen" = "xyes" -a "x$ac_lbl_capsicum_function_not_seen" != "xyes"; then
 219         AC_DEFINE(HAVE_CAPSICUM, 1, [capsicum support available])
 220         AC_MSG_RESULT(yes)
 221 else
 222         AC_MSG_RESULT(no)
 223 fi
 224 AC_MSG_CHECKING([whether to sandbox using Casper library])
 225 if test "x$ac_cv_lib_casper_cap_init" = "xyes" -a "x$ac_cv_lib_cap_dns_cap_gethostbyaddr" = "xyes"; then
 226         AC_DEFINE(HAVE_CASPER, 1, [Casper support available])
 227         AC_MSG_RESULT(yes)
 228 else
 229         AC_MSG_RESULT(no)
 230 fi
 231
 232 #
 233 # We must check this before checking whether to check the OS's IPv6,
 234 # support because, on some platforms (such as SunOS 5.x), the test
 235 # program requires the extra networking libraries.
 236 #
 237 AC_LBL_LIBRARY_NET
 238
 239 #
 240 # Check whether AF_INET6 and struct in6_addr are defined.
 241 # If they aren't both defined, we don't have sufficient OS
 242 # support for IPv6, so we don't look for IPv6 support libraries,
 243 # and we define AF_INET6 and struct in6_addr ourselves.
 244 #
 245 AC_MSG_CHECKING([whether the operating system supports IPv6])
 246 AC_COMPILE_IFELSE(
 247     [
 248       AC_LANG_SOURCE(
 249         [[
 250 /* AF_INET6 available check */
 251 #include <sys/types.h>
 252 #ifdef _WIN32
 253 #include <ws2tcpip.h>
 254 #else
 255 #include <sys/socket.h>
 256 #include <netinet/in.h>
 257 #endif
 258 #ifdef AF_INET6
 259 void
 260 foo(struct in6_addr *addr)
 261 {
 262  memset(addr, 0, sizeof (struct in6_addr));
 263 }
 264 #else
 265 #error "AF_INET6 not defined"
 266 #endif
 267         ]])
 268     ],
 269     [
 270         AC_MSG_RESULT(yes)
 271         AC_DEFINE(HAVE_OS_IPV6_SUPPORT, 1,
 272             [define if the OS provides AF_INET6 and struct in6_addr])
 273         ipv6=yes
 274     ],
 275     [
 276         AC_MSG_RESULT(no)
 277         ipv6=no
 278     ]
 279 )
 280
 281 ipv6type=unknown
 282 ipv6lib=none
 283 ipv6trylibc=no
 284
 285 if test "$ipv6" = "yes"; then
 286         AC_MSG_CHECKING([ipv6 stack type])
 287         for i in inria kame linux-glibc linux-libinet6 toshiba v6d zeta; do
 288                 case $i in
 289                 inria)
 290                         dnl http://www.kame.net/
 291                         AC_EGREP_CPP(yes,
 292 [#include <netinet/in.h>
 293 #ifdef IPV6_INRIA_VERSION
 294 yes
 295 #endif],
 296                                 [ipv6type=$i])
 297                         ;;
 298                 kame)
 299                         dnl http://www.kame.net/
 300                         AC_EGREP_CPP(yes,
 301 [#include <netinet/in.h>
 302 #ifdef __KAME__
 303 yes
 304 #endif],
 305                                 [ipv6type=$i;
 306                                 ipv6lib=inet6;
 307                                 ipv6libdir=/usr/local/v6/lib;
 308                                 ipv6trylibc=yes])
 309                         ;;
 310                 linux-glibc)
 311                         dnl http://www.v6.linux.or.jp/
 312                         AC_EGREP_CPP(yes,
 313 [#include <features.h>
 314 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 315 yes
 316 #endif],
 317                                 [ipv6type=$i])
 318                         ;;
 319                 linux-libinet6)
 320                         dnl http://www.v6.linux.or.jp/
 321                         dnl
 322                         dnl This also matches Solaris 8 and Tru64 UNIX 5.1,
 323                         dnl and possibly other versions of those OSes
 324                         dnl
 325                         if test -d /usr/inet6 -o -f /usr/include/netinet/ip6.h; then
 326                                 ipv6type=$i
 327                                 ipv6lib=inet6
 328                                 ipv6libdir=/usr/inet6/lib
 329                                 ipv6trylibc=yes;
 330                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 331                         fi
 332                         ;;
 333                 toshiba)
 334                         AC_EGREP_CPP(yes,
 335 [#include <sys/param.h>
 336 #ifdef _TOSHIBA_INET6
 337 yes
 338 #endif],
 339                                 [ipv6type=$i;
 340                                 ipv6lib=inet6;
 341                                 ipv6libdir=/usr/local/v6/lib])
 342                         ;;
 343                 v6d)
 344                         AC_EGREP_CPP(yes,
 345 [#include </usr/local/v6/include/sys/v6config.h>
 346 #ifdef __V6D__
 347 yes
 348 #endif],
 349                                 [ipv6type=$i;
 350                                 ipv6lib=v6;
 351                                 ipv6libdir=/usr/local/v6/lib;
 352                                 CFLAGS="-I/usr/local/v6/include $CFLAGS"])
 353                         ;;
 354                 zeta)
 355                         AC_EGREP_CPP(yes,
 356 [#include <sys/param.h>
 357 #ifdef _ZETA_MINAMI_INET6
 358 yes
 359 #endif],
 360                                 [ipv6type=$i;
 361                                 ipv6lib=inet6;
 362                                 ipv6libdir=/usr/local/v6/lib])
 363                         ;;
 364                 esac
 365                 if test "$ipv6type" != "unknown"; then
 366                         break
 367                 fi
 368         done
 369         AC_MSG_RESULT($ipv6type)
 370 fi
 371
 372 if test "$ipv6" = "yes" -a "$ipv6lib" != "none"; then
 373         if test -d $ipv6libdir -a -f $ipv6libdir/lib$ipv6lib.a; then
 374                 LIBS="-L$ipv6libdir -l$ipv6lib $LIBS"
 375                 echo "You have $ipv6lib library, using it"
 376         else
 377                 if test "$ipv6trylibc" = "yes"; then
 378                         echo "You do not have $ipv6lib library, using libc"
 379                 else
 380                         echo 'Fatal: no $ipv6lib library found.  cannot continue.'
 381                         echo "You need to fetch lib$ipv6lib.a from appropriate"
 382                         echo 'ipv6 kit and compile beforehand.'
 383                         exit 1
 384                 fi
 385         fi
 386 fi
 387
 388 AC_REPLACE_FUNCS(strlcat strlcpy strdup strsep getservent getopt_long)
 389 AC_CHECK_FUNCS(fork vfork strftime)
 390 AC_CHECK_FUNCS(setlinebuf)
 391
 392 #
 393 # Make sure we have vsnprintf() and snprintf(); we require them.
 394 #
 395 AC_CHECK_FUNC(vsnprintf,,
 396     AC_MSG_ERROR([vsnprintf() is required but wasn't found]))
 397 AC_CHECK_FUNC(snprintf,,
 398     AC_MSG_ERROR([snprintf() is required but wasn't found]))
 399
 400 AC_CHECK_LIB(rpc, main)         dnl It's unclear why we might need -lrpc
 401
 402 dnl Some platforms may need -lnsl for getrpcbynumber.
 403 AC_SEARCH_LIBS(getrpcbynumber, nsl,
 404     AC_DEFINE(HAVE_GETRPCBYNUMBER, 1, [define if you have getrpcbynumber()]))
 405
 406 AC_LBL_LIBPCAP(V_PCAPDEP, V_INCLS)
 407
 408 #
 409 # Check for these after AC_LBL_LIBPCAP, so we link with the appropriate
 410 # libraries (e.g., "-lsocket -lnsl" on Solaris).
 411 #
 412 # You are in a twisty little maze of UN*Xes, all different.
 413 # Some might not have ether_ntohost().
 414 # Some might have it and declare it in <net/ethernet.h>.
 415 # Some might have it and declare it in <netinet/ether.h>
 416 # Some might have it and declare it in <sys/ethernet.h>.
 417 # Some might have it and declare it in <arpa/inet.h>.
 418 # Some might have it and declare it in <netinet/if_ether.h>.
 419 # Some might have it and not declare it in any header file.
 420 #
 421 # Before you is a C compiler.
 422 #
 423 AC_CHECK_FUNCS(ether_ntohost, [
 424     AC_CACHE_CHECK(for buggy ether_ntohost, ac_cv_buggy_ether_ntohost, [
 425         AC_TRY_RUN([
 426                 #include <netdb.h>
 427                 #include <sys/types.h>
 428                 #include <sys/param.h>
 429                 #include <sys/socket.h>
 430
 431                 int
 432                 main(int argc, char **argv)
 433                 {
 434                         u_char ea[6] = { 0xff, 0xff, 0xff, 0xff, 0xff };
 435                         char name[MAXHOSTNAMELEN];
 436
 437                         ether_ntohost(name, (struct ether_addr *)ea);
 438                         exit(0);
 439                 }
 440         ], [ac_cv_buggy_ether_ntohost=no],
 441            [ac_cv_buggy_ether_ntohost=yes],
 442            [ac_cv_buggy_ether_ntohost="not while cross-compiling"])])
 443     if test "$ac_cv_buggy_ether_ntohost" = "no"; then
 444         AC_DEFINE(USE_ETHER_NTOHOST, 1,
 445             [define if you have ether_ntohost() and it works])
 446     fi
 447 ])
 448 if test "$ac_cv_func_ether_ntohost" = yes -a \
 449     "$ac_cv_buggy_ether_ntohost" = "no"; then
 450         #
 451         # OK, we have ether_ntohost().  Is it declared in <net/ethernet.h>?
 452         #
 453         # This test fails if we don't have <net/ethernet.h> or if we do
 454         # but it doesn't declare ether_ntohost().
 455         #
 456         AC_CHECK_DECL(ether_ntohost,
 457             [
 458                 AC_DEFINE(NET_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
 459                     [Define to 1 if net/ethernet.h declares `ether_ntohost'])
 460             ],,
 461             [
 462 #include <net/ethernet.h>
 463             ])
 464         #
 465         # Did that succeed?
 466         #
 467         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 468                 #
 469                 # No, how about <netinet/ether.h>, as on Linux?
 470                 #
 471                 # This test fails if we don't have <netinet/ether.h>
 472                 # or if we do but it doesn't declare ether_ntohost().
 473                 #
 474                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 475                 # treat the previous failure as a cached value and
 476                 # suppress the next test.
 477                 #
 478                 unset ac_cv_have_decl_ether_ntohost
 479                 AC_CHECK_DECL(ether_ntohost,
 480                     [
 481                         AC_DEFINE(NETINET_ETHER_H_DECLARES_ETHER_NTOHOST,,
 482                             [Define to 1 if netinet/ether.h declares `ether_ntohost'])
 483                     ],,
 484                     [
 485 #include <netinet/ether.h>
 486                     ])
 487         fi
 488         #
 489         # Did that succeed?
 490         #
 491         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 492                 #
 493                 # No, how about <sys/ethernet.h>, as on Solaris 10
 494                 # and later?
 495                 #
 496                 # This test fails if we don't have <sys/ethernet.h>
 497                 # or if we do but it doesn't declare ether_ntohost().
 498                 #
 499                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 500                 # treat the previous failure as a cached value and
 501                 # suppress the next test.
 502                 #
 503                 unset ac_cv_have_decl_ether_ntohost
 504                 AC_CHECK_DECL(ether_ntohost,
 505                     [
 506                         AC_DEFINE(SYS_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
 507                             [Define to 1 if sys/ethernet.h declares `ether_ntohost'])
 508                     ],,
 509                     [
 510 #include <sys/ethernet.h>
 511                     ])
 512         fi
 513         #
 514         # Did that succeed?
 515         #
 516         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 517                 #
 518                 # No, how about <arpa/inet.h>, as in AIX?
 519                 #
 520                 # This test fails if we don't have <arpa/inet.h>
 521                 # (if we have ether_ntohost(), we should have
 522                 # networking, and if we have networking, we should
 523                 # have <arpa/inet.h>) or if we do but it doesn't
 524                 # declare ether_ntohost().
 525                 #
 526                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 527                 # treat the previous failure as a cached value and
 528                 # suppress the next test.
 529                 #
 530                 unset ac_cv_have_decl_ether_ntohost
 531                 AC_CHECK_DECL(ether_ntohost,
 532                     [
 533                         AC_DEFINE(ARPA_INET_H_DECLARES_ETHER_NTOHOST,,
 534                             [Define to 1 if arpa/inet.h declares `ether_ntohost'])
 535                     ],,
 536                     [
 537 #include <arpa/inet.h>
 538                     ])
 539         fi
 540         #
 541         # Did that succeed?
 542         #
 543         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 544                 #
 545                 # No, how about <netinet/if_ether.h>?
 546                 # On some platforms, it requires <net/if.h> and
 547                 # <netinet/in.h>, and we always include it with
 548                 # both of them, so test it with both of them.
 549                 #
 550                 # This test fails if we don't have <netinet/if_ether.h>
 551                 # and the headers we include before it, or if we do but
 552                 # <netinet/if_ether.h> doesn't declare ether_hostton().
 553                 #
 554                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 555                 # treat the previous failure as a cached value and
 556                 # suppress the next test.
 557                 #
 558                 unset ac_cv_have_decl_ether_ntohost
 559                 AC_CHECK_DECL(ether_ntohost,
 560                     [
 561                         AC_DEFINE(NETINET_IF_ETHER_H_DECLARES_ETHER_NTOHOST,,
 562                             [Define to 1 if netinet/if_ether.h declares `ether_ntohost'])
 563                     ],,
 564                     [
 565 #include <sys/types.h>
 566 #include <sys/socket.h>
 567 #include <net/if.h>
 568 #include <netinet/in.h>
 569 #include <netinet/if_ether.h>
 570                     ])
 571         fi
 572         #
 573         # After all that, is ether_ntohost() declared?
 574         #
 575         if test "$ac_cv_have_decl_ether_ntohost" = yes; then
 576                 #
 577                 # Yes.
 578                 #
 579                 AC_DEFINE(HAVE_DECL_ETHER_NTOHOST, 1,
 580                     [Define to 1 if you have the declaration of `ether_ntohost'])
 581         else
 582                 #
 583                 # No, we'll have to declare it ourselves.
 584                 # Do we have "struct ether_addr" if we include
 585                 # <netinet/if_ether.h>?
 586                 #
 587                 AC_CHECK_TYPES(struct ether_addr,,,
 588                     [
 589                         #include <sys/types.h>
 590                         #include <sys/socket.h>
 591                         #include <net/if.h>
 592                         #include <netinet/in.h>
 593                         #include <netinet/if_ether.h>
 594                     ])
 595         fi
 596 fi
 597
 598 dnl
 599 dnl Check for "pcap_list_datalinks()" and use a substitute version if
 600 dnl it's not present.  If it is present, check for "pcap_free_datalinks()";
 601 dnl if it's not present, we don't replace it for now.  (We could do so
 602 dnl on UN*X, but not on Windows, where hilarity ensues if a program
 603 dnl built with one version of the MSVC support library tries to free
 604 dnl something allocated by a library built with another version of
 605 dnl the MSVC support library.)
 606 dnl
 607 AC_CHECK_FUNC(pcap_list_datalinks,
 608         [
 609             AC_DEFINE(HAVE_PCAP_LIST_DATALINKS, 1,
 610                 [define if libpcap has pcap_list_datalinks()])
 611             AC_CHECK_FUNCS(pcap_free_datalinks)
 612         ],
 613         [
 614             AC_LIBOBJ(datalinks)
 615         ])
 616
 617 dnl
 618 dnl Check for "pcap_datalink_name_to_val()", and use a substitute
 619 dnl version if it's not present.  If it is present, check for
 620 dnl "pcap_datalink_val_to_description()", and if we don't have it,
 621 dnl use a substitute version.
 622 dnl
 623 AC_CHECK_FUNC(pcap_datalink_name_to_val,
 624         [
 625             AC_DEFINE(HAVE_PCAP_DATALINK_NAME_TO_VAL, 1,
 626                 [define if libpcap has pcap_datalink_name_to_val()])
 627             AC_CHECK_FUNC(pcap_datalink_val_to_description,
 628                 AC_DEFINE(HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION, 1,
 629                     [define if libpcap has pcap_datalink_val_to_description()]),
 630                 [
 631                     AC_LIBOBJ(dlnames)
 632                 ])
 633         ],
 634         [
 635             AC_LIBOBJ(dlnames)
 636         ])
 637
 638 dnl
 639 dnl Check for "pcap_set_datalink()"; you can't substitute for it if
 640 dnl it's absent (it has hooks into libpcap), so just define the
 641 dnl HAVE_ value if it's there.
 642 dnl
 643 AC_CHECK_FUNCS(pcap_set_datalink)
 644
 645 dnl
 646 dnl Check for "pcap_breakloop()"; you can't substitute for it if
 647 dnl it's absent (it has hooks into the live capture routines),
 648 dnl so just define the HAVE_ value if it's there.
 649 dnl
 650 AC_CHECK_FUNCS(pcap_breakloop)
 651
 652 #
 653 # Do we have the new open API?  Check for pcap_create, and assume that,
 654 # if we do, we also have pcap_activate() and the other new routines
 655 # introduced in libpcap 1.0.0.
 656 #
 657 AC_CHECK_FUNCS(pcap_create)
 658 if test $ac_cv_func_pcap_create = "yes" ; then
 659         #
 660         # OK, do we have pcap_set_tstamp_type?  If so, assume we have
 661         # pcap_list_tstamp_types and pcap_free_tstamp_types as well.
 662         #
 663         AC_CHECK_FUNCS(pcap_set_tstamp_type)
 664         #
 665         # And do we have pcap_set_tstamp_precision?  If so, we assume
 666         # we also have pcap_open_offline_with_tstamp_precision.
 667         #
 668         AC_CHECK_FUNCS(pcap_set_tstamp_precision)
 669 fi
 670
 671 #
 672 # Check for a miscellaneous collection of functions which we use
 673 # if we have them.
 674 #
 675 AC_CHECK_FUNCS(pcap_findalldevs)
 676 if test $ac_cv_func_pcap_findalldevs = "yes" ; then
 677 dnl Check for libpcap having pcap_findalldevs() but the pcap.h header
 678 dnl not having pcap_if_t; some versions of Mac OS X shipped with pcap.h
 679 dnl from 0.6 and libpcap 0.8, so that libpcap had pcap_findalldevs but
 680 dnl pcap.h didn't have pcap_if_t.
 681     savedcppflags="$CPPFLAGS"
 682     CPPFLAGS="$CPPFLAGS $V_INCLS"
 683     AC_CHECK_TYPES(pcap_if_t, , , [#include <pcap.h>])
 684     CPPFLAGS="$savedcppflags"
 685 fi
 686 AC_CHECK_FUNCS(pcap_dump_flush pcap_lib_version)
 687 if test $ac_cv_func_pcap_lib_version = "no" ; then
 688     AC_MSG_CHECKING(whether pcap_version is defined by libpcap)
 689     AC_TRY_LINK([],
 690        [
 691         extern char pcap_version[];
 692
 693         return (int)pcap_version;
 694        ],
 695        ac_lbl_cv_pcap_version_defined=yes,
 696        ac_lbl_cv_pcap_version_defined=no)
 697     if test "$ac_lbl_cv_pcap_version_defined" = yes ; then
 698         AC_MSG_RESULT(yes)
 699         AC_DEFINE(HAVE_PCAP_VERSION, 1, [define if libpcap has pcap_version])
 700     else
 701         AC_MSG_RESULT(no)
 702     fi
 703 fi
 704 AC_CHECK_FUNCS(pcap_setdirection pcap_set_immediate_mode pcap_dump_ftell64)
 705 AC_CHECK_FUNCS(pcap_open pcap_findalldevs_ex)
 706 AC_REPLACE_FUNCS(pcap_dump_ftell)
 707
 708 #
 709 # Check for special debugging functions
 710 #
 711 AC_CHECK_FUNCS(pcap_set_parser_debug)
 712 if test "$ac_cv_func_pcap_set_parser_debug" = "no" ; then
 713         #
 714         # OK, we don't have pcap_set_parser_debug() to set the libpcap
 715         # filter expression parser debug flag; can we directly set the
 716         # flag?
 717         AC_MSG_CHECKING(whether pcap_debug is defined by libpcap)
 718         AC_TRY_LINK([],
 719            [
 720                 extern int pcap_debug;
 721
 722                 return pcap_debug;
 723            ],
 724            ac_lbl_cv_pcap_debug_defined=yes,
 725            ac_lbl_cv_pcap_debug_defined=no)
 726         if test "$ac_lbl_cv_pcap_debug_defined" = yes ; then
 727                 AC_MSG_RESULT(yes)
 728                 AC_DEFINE(HAVE_PCAP_DEBUG, 1, [define if libpcap has pcap_debug])
 729         else
 730                 AC_MSG_RESULT(no)
 731                 #
 732                 # OK, what about "yydebug"?
 733                 #
 734                 AC_MSG_CHECKING(whether yydebug is defined by libpcap)
 735                 AC_TRY_LINK([],
 736                    [
 737                         extern int yydebug;
 738
 739                         return yydebug;
 740                    ],
 741                    ac_lbl_cv_yydebug_defined=yes,
 742                    ac_lbl_cv_yydebug_defined=no)
 743                 if test "$ac_lbl_cv_yydebug_defined" = yes ; then
 744                         AC_MSG_RESULT(yes)
 745                         AC_DEFINE(HAVE_YYDEBUG, 1, [define if libpcap has yydebug])
 746                 else
 747                         AC_MSG_RESULT(no)
 748                 fi
 749         fi
 750 fi
 751 AC_CHECK_FUNCS(pcap_set_optimizer_debug)
 752 AC_REPLACE_FUNCS(bpf_dump)      dnl moved to libpcap in 0.6
 753
 754 V_GROUP=0
 755 if test -f /etc/group -a ! -z "`grep '^wheel:' /etc/group`" ; then
 756         V_GROUP=wheel
 757 fi
 758 #
 759 # Assume V7/BSD convention for man pages (file formats in section 5,
 760 # miscellaneous info in section 7).
 761 #
 762 MAN_FILE_FORMATS=5
 763 MAN_MISC_INFO=7
 764 case "$host_os" in
 765
 766 aix*)
 767         dnl Workaround to enable certain features
 768         AC_DEFINE(_SUN,1,[define on AIX to get certain functions])
 769         ;;
 770
 771 hpux*)
 772         #
 773         # Use System V conventions for man pages.
 774         #
 775         MAN_FILE_FORMATS=4
 776         MAN_MISC_INFO=5
 777         ;;
 778
 779 irix*)
 780         V_GROUP=sys
 781
 782         #
 783         # Use System V conventions for man pages.
 784         #
 785         MAN_FILE_FORMATS=4
 786         MAN_MISC_INFO=5
 787         ;;
 788
 789 osf*)
 790         V_GROUP=system
 791
 792         #
 793         # Use System V conventions for man pages.
 794         #
 795         MAN_FILE_FORMATS=4
 796         MAN_MISC_INFO=5
 797         ;;
 798
 799 solaris*)
 800         V_GROUP=sys
 801
 802         #
 803         # Use System V conventions for man pages.
 804         #
 805         MAN_FILE_FORMATS=4
 806         MAN_MISC_INFO=5
 807         ;;
 808 esac
 809
 810 if test -f /dev/bpf0 ; then
 811         V_GROUP=bpf
 812 fi
 813
 814 #
 815 # Make sure we have a definition for C99's uintptr_t (regardless of
 816 # whether the environment is a C99 environment or not).
 817 #
 818 AC_TYPE_UINTPTR_T
 819
 820 #
 821 # Check whether we have pcap/pcap-inttypes.h.
 822 # If we do, we use that to get the C99 types defined.
 823 #
 824 savedcppflags="$CPPFLAGS"
 825 CPPFLAGS="$CPPFLAGS $V_INCLS"
 826 AC_CHECK_HEADERS(pcap/pcap-inttypes.h)
 827 CPPFLAGS="$savedcppflags"
 828
 829 #
 830 # Define the old BSD specified-width types in terms of the C99 types;
 831 # we may need them with libpcap include files.
 832 #
 833 AC_CHECK_TYPE([u_int8_t], ,
 834         [AC_DEFINE([u_int8_t], [uint8_t],
 835         [Define to `uint8_t' if u_int8_t not defined.])],
 836         [AC_INCLUDES_DEFAULT
 837 #include <sys/types.h>
 838 ])
 839 AC_CHECK_TYPE([u_int16_t], ,
 840         [AC_DEFINE([u_int16_t], [uint16_t],
 841         [Define to `uint16_t' if u_int16_t not defined.])],
 842         [AC_INCLUDES_DEFAULT
 843 #include <sys/types.h>
 844 ])
 845 AC_CHECK_TYPE([u_int32_t], ,
 846         [AC_DEFINE([u_int32_t], [uint32_t],
 847         [Define to `uint32_t' if u_int32_t not defined.])],
 848         [AC_INCLUDES_DEFAULT
 849 #include <sys/types.h>
 850 ])
 851 AC_CHECK_TYPE([u_int64_t], ,
 852         [AC_DEFINE([u_int64_t], [uint64_t],
 853         [Define to `uint64_t' if u_int64_t not defined.])],
 854         [AC_INCLUDES_DEFAULT
 855 #include <sys/types.h>
 856 ])
 857
 858 AC_PROG_RANLIB
 859 AC_CHECK_TOOL([AR], [ar])
 860
 861 AC_LBL_DEVEL(V_CCOPT)
 862
 863 # Check for OpenSSL/libressl libcrypto
 864 AC_MSG_CHECKING(whether to use OpenSSL/libressl libcrypto)
 865 # Specify location for both includes and libraries.
 866 want_libcrypto=ifavailable
 867 AC_ARG_WITH(crypto,
 868     AS_HELP_STRING([--with-crypto]@<:@=DIR@:>@,
 869                    [use OpenSSL/libressl libcrypto (located in directory DIR, if specified) @<:@default=yes, if available@:>@]),
 870 [
 871         if test $withval = no
 872         then
 873                 # User doesn't want to link with libcrypto.
 874                 want_libcrypto=no
 875                 AC_MSG_RESULT(no)
 876         elif test $withval = yes
 877         then
 878                 # User wants to link with libcrypto but hasn't specified
 879                 # a directory.
 880                 want_libcrypto=yes
 881                 AC_MSG_RESULT(yes)
 882         else
 883                 # User wants to link with libcrypto and has specified
 884                 # a directory, so use the provided value.
 885                 want_libcrypto=yes
 886                 libcrypto_root=$withval
 887                 AC_MSG_RESULT([yes, using the version installed in $withval])
 888
 889                 #
 890                 # Put the subdirectories of the libcrypto root directory
 891                 # at the front of the header and library search path.
 892                 #
 893                 CFLAGS="-I$withval/include $CFLAGS"
 894                 LIBS="-L$withval/lib $LIBS"
 895         fi
 896 ],[
 897         #
 898         # Use libcrypto if it's present, otherwise don't; no directory
 899         # was specified.
 900         #
 901         want_libcrypto=ifavailable
 902         AC_MSG_RESULT([yes, if available])
 903 ])
 904 if test "$want_libcrypto" != "no"; then
 905         #
 906         # Don't check for libcrypto unless we have its headers;
 907         # Apple, bless their pointy little heads, apparently ship
 908         # libcrypto as a library, but not the header files, in
 909         # El Capitan, probably because they don't want you writing
 910         # nasty portable code that could run on other UN*Xes, they
 911         # want you writing code that uses their Shiny New Crypto
 912         # Library and that only runs on macOS.
 913         #
 914         AC_CHECK_HEADER(openssl/crypto.h,
 915         [
 916                 AC_CHECK_LIB(crypto, DES_cbc_encrypt)
 917                 if test "$ac_cv_lib_crypto_DES_cbc_encrypt" = "yes"; then
 918                         AC_CHECK_HEADERS(openssl/evp.h)
 919                         #
 920                         # OK, then:
 921                         #
 922                         # 1) do we have EVP_CIPHER_CTX_new?
 923                         # If so, we use it to allocate an
 924                         # EVP_CIPHER_CTX, as EVP_CIPHER_CTX may be
 925                         # opaque; otherwise, we allocate it ourselves.
 926                         #
 927                         # 2) do we have EVP_DecryptInit_ex()?
 928                         # If so, we use it, because we need to be
 929                         # able to make two "initialize the cipher"
 930                         # calls, one with the cipher and key, and
 931                         # one with the IV, and, as of OpenSSL 1.1,
 932                         # You Can't Do That with EVP_DecryptInit(),
 933                         # because a call to EVP_DecryptInit() will
 934                         # unconditionally clear the context, and
 935                         # if you don't supply a cipher, it'll
 936                         # clear the cipher, rendering the context
 937                         # unusable and causing a crash.
 938                         #
 939                         AC_CHECK_FUNCS(EVP_CIPHER_CTX_new EVP_DecryptInit_ex)
 940                 fi
 941         ])
 942 fi
 943
 944 # Check for libcap-ng
 945 AC_MSG_CHECKING(whether to use libcap-ng)
 946 # Specify location for both includes and libraries.
 947 want_libcap_ng=ifavailable
 948 AC_ARG_WITH(cap_ng,
 949     AS_HELP_STRING([--with-cap-ng],
 950                    [use libcap-ng @<:@default=yes, if available@:>@]),
 951 [
 952         if test $withval = no
 953         then
 954                 want_libcap_ng=no
 955                 AC_MSG_RESULT(no)
 956         elif test $withval = yes
 957         then
 958                 want_libcap_ng=yes
 959                 AC_MSG_RESULT(yes)
 960         fi
 961 ],[
 962         #
 963         # Use libcap-ng if it's present, otherwise don't.
 964         #
 965         want_libcap_ng=ifavailable
 966         AC_MSG_RESULT([yes, if available])
 967 ])
 968 if test "$want_libcap_ng" != "no"; then
 969         AC_CHECK_LIB(cap-ng, capng_change_id)
 970         AC_CHECK_HEADERS(cap-ng.h)
 971 fi
 972
 973 dnl
 974 dnl set additional include path if necessary
 975 if test "$missing_includes" = "yes"; then
 976         CPPFLAGS="$CPPFLAGS -I$srcdir/missing"
 977         V_INCLS="$V_INCLS -I$srcdir/missing"
 978 fi
 979
 980 AC_SUBST(V_CCOPT)
 981 AC_SUBST(V_DEFS)
 982 AC_SUBST(V_GROUP)
 983 AC_SUBST(V_INCLS)
 984 AC_SUBST(V_PCAPDEP)
 985 AC_SUBST(LOCALSRC)
 986 AC_SUBST(MAN_FILE_FORMATS)
 987 AC_SUBST(MAN_MISC_INFO)
 988
 989 AC_PROG_INSTALL
 990
 991 AC_CONFIG_HEADER(config.h)
 992
 993 AC_OUTPUT_COMMANDS([if test -f .devel; then
 994         echo timestamp > stamp-h
 995         cat $srcdir/Makefile-devel-adds >> Makefile
 996         make depend
 997 fi])
 998 AC_OUTPUT(Makefile tcpdump.1)
 999 exit 0