The Tcpdump Group git mirrors - tcpdump/blob - configure.ac

   1 dnl Copyright (c) 1994, 1995, 1996, 1997
   2 dnl     The Regents of the University of California.  All rights reserved.
   3 dnl
   4 dnl Process this file with autoconf to produce a configure script.
   5 dnl
   6
   7 #
   8 # See
   9 #
  10 #       https://ftp.gnu.org/gnu/config/README
  11 #
  12 # for the URLs to use to fetch new versions of config.guess and
  13 # config.sub.
  14 #
  15
  16 AC_PREREQ([2.69])
  17 AC_INIT(
  18         [tcpdump],
  19         [m4_esyscmd_s(cat VERSION)],
  20         [https://github.com/the-tcpdump-group/tcpdump/issues],
  21         [tcpdump],
  22         [https://www.tcpdump.org/])
  23 AC_CONFIG_SRCDIR(tcpdump.c)
  24
  25 AC_CANONICAL_HOST
  26
  27 AC_LBL_C_INIT_BEFORE_CC(V_INCLS)
  28 #
  29 # Try to enable as many C99 features as we can.
  30 # At minimum, we want C++/C99-style // comments.
  31 #
  32 AC_PROG_CC_C99
  33 if test "$ac_cv_prog_cc_c99" = "no"; then
  34         AC_MSG_WARN([The C compiler does not support C99; there may be compiler errors])
  35 fi
  36 AC_LBL_C_INIT(V_CCOPT, V_INCLS)
  37
  38 #
  39 # Test for ONC RPC headers.
  40 #
  41 # XXX - we should supply copies of these, as I think Sun released them
  42 # under a sufficiently permissive license, and that would be one less
  43 # place where we rely on OS headers, rather than our own headers, for
  44 # a protocol that is specified independent of any particular OS.
  45 #
  46 AC_CHECK_HEADERS(rpc/rpc.h rpc/rpcent.h)
  47
  48 # On Linux, if Autoconf version >= 2.72 and GNU C Library version >= 2.34,
  49 # uncomment AC_SYS_YEAR2038_RECOMMENDED to ensure time_t is Y2038-safe.
  50 # (Can be done by autogen.sh)
  51 # AC_SYS_YEAR2038_RECOMMENDED
  52 #
  53 # Get the size of a void *, to know whether this is a 32-bit or 64-bit build.
  54 #
  55 AC_CHECK_SIZEOF([void *])
  56
  57 #
  58 # Get the size of a time_t, to know whether it's 32-bit or 64-bit.
  59 #
  60 AC_CHECK_SIZEOF([time_t],,[#include <time.h>])
  61
  62 case "$host_os" in
  63
  64 darwin*)
  65         AC_ARG_ENABLE(universal,
  66         AS_HELP_STRING([--disable-universal],[don't build universal on macOS]))
  67         if test "$enable_universal" != "no"; then
  68                 case "$host_os" in
  69
  70                 darwin9.*)
  71                         #
  72                         # Leopard.  Build for x86 and 32-bit PowerPC, with
  73                         # x86 first.  (That's what Apple does.)
  74                         #
  75                         V_CCOPT="$V_CCOPT -arch i386 -arch ppc"
  76                         LDFLAGS="$LDFLAGS -arch i386 -arch ppc"
  77                         ;;
  78
  79                 darwin10.*)
  80                         #
  81                         # Snow Leopard.  Build for x86-64 and x86, with
  82                         # x86-64 first.  (That's what Apple does.)
  83                         #
  84                         V_CCOPT="$V_CCOPT -arch x86_64 -arch i386"
  85                         LDFLAGS="$LDFLAGS -arch x86_64 -arch i386"
  86                         ;;
  87                 esac
  88         fi
  89         ;;
  90 esac
  91
  92 #
  93 # Do we have pkg-config?
  94 #
  95 PKG_PROG_PKG_CONFIG
  96
  97 #
  98 # Do we have the brew command from Homebrew?
  99 #
 100 case "$host_os" in
 101 darwin*|linux*)
 102         AC_PATH_PROG([BREW], [brew])
 103         ;;
 104 esac
 105
 106 AC_ARG_WITH([smi],
 107    [AS_HELP_STRING([--with-smi],
 108      [link with libsmi (allows to load MIBs on the fly to decode SNMP packets) [default=yes, if available]])],
 109    [],
 110    [with_smi=yes])
 111
 112 if test "x$with_smi" != "xno" ; then
 113         AC_CHECK_HEADER(smi.h,
 114         [
 115                 #
 116                 # OK, we found smi.h.  Do we have libsmi with smiInit?
 117                 #
 118                 AC_CHECK_LIB(smi, smiInit,
 119                 [
 120                         #
 121                         # OK, we have libsmi with smiInit.  Can we use it?
 122                         #
 123                         AC_MSG_CHECKING([whether to enable libsmi])
 124                         savedlibs="$LIBS"
 125                         LIBS="-lsmi $LIBS"
 126                         AC_RUN_IFELSE([AC_LANG_SOURCE([[
 127 /* libsmi available check */
 128 #include <stdio.h>
 129 #include <stdlib.h>
 130 #include <string.h>
 131 #include <smi.h>
 132 int main()
 133 {
 134   int current, revision, age, n;
 135   const int required = 2;
 136   if (smiInit(""))
 137     exit(1);
 138   if (strcmp(SMI_LIBRARY_VERSION, smi_library_version))
 139     exit(2);
 140   n = sscanf(smi_library_version, "%d:%d:%d", &current, &revision, &age);
 141   if (n != 3)
 142     exit(3);
 143   if (required < current - age || required > current)
 144     exit(4);
 145   exit(0);
 146 }
 147                                 ]])
 148                                 ],
 149                                 [
 150                                         AC_MSG_RESULT(yes)
 151                                         AC_DEFINE(USE_LIBSMI, 1,
 152                                             [Define if you enable support for libsmi])
 153                                 ],
 154                                 [
 155                                         dnl autoconf documentation says that
 156                                         dnl $? contains the exit value.
 157                                         dnl reality is that it does not.
 158                                         dnl We leave this in just in case
 159                                         dnl autoconf ever comes back to
 160                                         dnl match the documentation.
 161                                         case $? in
 162                                           1) AC_MSG_RESULT(no - smiInit failed) ;;
 163                                           2) AC_MSG_RESULT(no - header/library version mismatch) ;;
 164                                           3) AC_MSG_RESULT(no - can't determine library version) ;;
 165                                           4) AC_MSG_RESULT(no - too old) ;;
 166                                           *) AC_MSG_RESULT(no) ;;
 167                                         esac
 168                                         LIBS="$savedlibs"
 169                                 ],
 170                                 [
 171                                         AC_MSG_RESULT(not when cross-compiling)
 172                                         LIBS="$savedlibs"
 173                                 ]
 174                         )
 175                 ])
 176         ])
 177 fi
 178
 179 AC_MSG_CHECKING([whether to enable the instrument functions code])
 180 AC_ARG_ENABLE([instrument-functions],
 181    [AS_HELP_STRING([--enable-instrument-functions],
 182      [enable instrument functions code [default=no]])],
 183    [],
 184    [enableval=no])
 185 case "$enableval" in
 186 yes)    AC_MSG_RESULT(yes)
 187         AC_CHECK_LIB([bfd], [bfd_init],
 188             [true],
 189             [AC_MSG_ERROR(
 190                [--enable-instrument-functions was given, but test for library libbfd failed. Please install the 'binutils-dev' package.])],
 191             [])
 192         AC_DEFINE(ENABLE_INSTRUMENT_FUNCTIONS, 1,
 193             [define if you want to build the instrument functions code])
 194         LOCALSRC="$LOCALSRC instrument-functions.c"
 195         # Add '-finstrument-functions' instrumentation option to generate
 196         # instrumentation calls for entry and exit to functions.
 197         # Try to avoid Address Space Layout Randomization (ALSR).
 198         CFLAGS="$CFLAGS -O0 -ggdb -finstrument-functions -fno-stack-protector -fno-pic"
 199         LDFLAGS="$LDFLAGS -O0 -ggdb -fno-stack-protector -no-pie"
 200         LIBS="$LIBS -lbfd"
 201         ;;
 202 *)      AC_MSG_RESULT(no)
 203         ;;
 204 esac
 205
 206 AC_MSG_CHECKING([whether to enable the possibly-buggy SMB printer])
 207 AC_ARG_ENABLE([smb],
 208    [AS_HELP_STRING([--enable-smb],
 209      [enable possibly-buggy SMB printer [default=no]])],
 210    [],
 211    [enableval=no])
 212 case "$enableval" in
 213 yes)    AC_MSG_RESULT(yes)
 214         AC_DEFINE(ENABLE_SMB, 1,
 215             [define if you want to build the possibly-buggy SMB printer])
 216         LOCALSRC="print-smb.c smbutil.c $LOCALSRC"
 217         ;;
 218 *)      AC_MSG_RESULT(no)
 219         ;;
 220 esac
 221
 222 AC_MSG_CHECKING([whether to drop root privileges by default])
 223 AC_ARG_WITH(
 224         [user],
 225         [AS_HELP_STRING([--with-user=USERNAME],
 226                 [drop privileges by default to USERNAME]
 227         )],
 228         [],
 229         [withval=no])
 230 AS_CASE(["$withval"],
 231         [no], [AC_MSG_RESULT(no)],
 232         [''|yes], [AC_MSG_ERROR([--with-user requires a username])],
 233         [
 234                 AC_DEFINE_UNQUOTED(WITH_USER, "$withval",
 235                     [define if should drop privileges by default])
 236                 AC_MSG_RESULT([yes, to user "$withval"])
 237         ]
 238 )
 239
 240 AC_MSG_CHECKING([whether to chroot])
 241 AC_ARG_WITH(
 242         [chroot],
 243         [AS_HELP_STRING([--with-chroot=DIRECTORY],
 244                 [when dropping privileges, chroot to DIRECTORY]
 245         )],
 246         [],
 247         [withval=no]
 248 )
 249 AS_CASE(["$withval"],
 250         [no], [AC_MSG_RESULT(no)],
 251         [''|yes], [AC_MSG_ERROR([--with-chroot requires a directory])],
 252         [
 253                 AC_DEFINE_UNQUOTED(WITH_CHROOT, "$withval",
 254                     [define if should chroot when dropping privileges])
 255                 AC_MSG_RESULT([yes, to directory "$withval"])
 256         ]
 257 )
 258
 259 AC_ARG_WITH(sandbox-capsicum,
 260         AS_HELP_STRING([--with-sandbox-capsicum],
 261                        [use Capsicum security functions @<:@default=yes, if available@:>@]))
 262
 263 # Capsicum is available on FreeBSD only.
 264 expr "$host_os" : freebsd >/dev/null || with_sandbox_capsicum=no
 265
 266 #
 267 # Check whether various functions are available.  If any are, set
 268 # ac_lbl_capsicum_function_seen to yes; if any are not, set
 269 # ac_lbl_capsicum_function_not_seen to yes.
 270 #
 271 # We don't check cap_rights_init(), as it's a macro, wrapping another
 272 # function, in at least some versions of FreeBSD, and AC_CHECK_FUNCS()
 273 # doesn't handle that.
 274 #
 275 # All of the ones we check for must be available in order to enable
 276 # capsicum sandboxing.
 277 #
 278 # XXX - do we need to check for all of them, or are there some that, if
 279 # present, imply others are present?
 280 #
 281 if test -z "$with_sandbox_capsicum" || test "$with_sandbox_capsicum" != "no" ; then
 282         #
 283         # First, make sure we have the required header.
 284         #
 285         AC_CHECK_HEADER(sys/capsicum.h,
 286         [
 287                 #
 288                 # We do; now make sure we have the required functions.
 289                 #
 290                 AC_CHECK_FUNCS(cap_enter cap_rights_limit cap_ioctls_limit openat,
 291                     ac_lbl_capsicum_function_seen=yes,
 292                     ac_lbl_capsicum_function_not_seen=yes)
 293         ])
 294         AC_CHECK_LIB(casper, cap_init, LIBS="$LIBS -lcasper")
 295         AC_CHECK_LIB(cap_dns, cap_gethostbyaddr, LIBS="$LIBS -lcap_dns")
 296 fi
 297 AC_MSG_CHECKING([whether to sandbox using capsicum])
 298 if test "x$ac_lbl_capsicum_function_seen" = "xyes" -a "x$ac_lbl_capsicum_function_not_seen" != "xyes"; then
 299         AC_DEFINE(HAVE_CAPSICUM, 1, [capsicum support available])
 300         AC_MSG_RESULT(yes)
 301 else
 302         AC_MSG_RESULT(no)
 303 fi
 304 AC_MSG_CHECKING([whether to sandbox using Casper library])
 305 if test "x$ac_cv_lib_casper_cap_init" = "xyes" -a "x$ac_cv_lib_cap_dns_cap_gethostbyaddr" = "xyes"; then
 306         AC_DEFINE(HAVE_CASPER, 1, [Casper support available])
 307         AC_MSG_RESULT(yes)
 308 else
 309         AC_MSG_RESULT(no)
 310 fi
 311
 312 #
 313 # XXX - we used to check this before checking whether to check the OS's
 314 # IPv6, support because, on some platforms (such as SunOS 5.x), the test
 315 # program requires the extra networking libraries.  We no longer
 316 # test for IPv6 support, we just assume it's present with the
 317 # standard API, so perhaps this can be moved.
 318 #
 319 AC_LBL_LIBRARY_NET
 320
 321 AC_REPLACE_FUNCS(strlcat strlcpy strsep getservent getopt_long)
 322 AC_CHECK_FUNCS(fork vfork)
 323
 324 #
 325 # It became apparent at some point that using a suitable C99 compiler does not
 326 # automatically mean snprintf(3) implementation in the libc supports all the
 327 # modifiers and specifiers used in the project, so let's test that before the
 328 # build, not after.
 329 #
 330 # Testing the sizeof_t length modifier takes making an snprintf() call and
 331 # comparing the actual result with the expected result.  If this fails, it will
 332 # most likely happen at run time, not compile time.
 333 #
 334 # Testing the 64-bit conversion specifiers in addition to that requires the
 335 # <inttypes.h> header to be present and the macros to be defined, so if this
 336 # fails, it will more likely happen at compile time.
 337 #
 338 AC_MSG_CHECKING([whether snprintf is suitable])
 339 AC_RUN_IFELSE(
 340     [
 341         AC_LANG_SOURCE([[
 342 #include <stdio.h>
 343 #include <string.h>
 344 #include <inttypes.h>
 345 #include <sys/types.h>
 346
 347 #if defined(_WIN32) && !defined(_SSIZE_T_DEFINED)
 348 /*
 349  * On UN*Xes, this is a signed integer type of the same size as size_t.
 350  *
 351  * It's not defined by Visual Studio; we assume that ptrdiff_t will
 352  * be a type that is a signed integer type of the same size as size_t.
 353  */
 354 typedef ptrdiff_t ssize_t;
 355 #endif
 356
 357 /*
 358  * Avoid trying to cast negative values to unsigned types, or doing
 359  * shifts of signed types, in order not to have the test program fail
 360  * if we're building with undefined-behavior sanitizers enabled.
 361  */
 362 int main()
 363 {
 364   char buf[100];
 365   unsigned int ui = sizeof(buf);
 366   int i = sizeof(buf);
 367   int64_t i64 = INT64_C(0x100000000);
 368   uint64_t ui64 = UINT64_C(0x100000000);
 369
 370   snprintf(buf, sizeof(buf), "%zu", (size_t)ui);
 371   if (strncmp(buf, "100", sizeof(buf)))
 372     return 1;
 373
 374   snprintf(buf, sizeof(buf), "%zd", (ssize_t)(-i));
 375   if (strncmp(buf, "-100", sizeof(buf)))
 376     return 2;
 377
 378   snprintf(buf, sizeof(buf), "%" PRId64, -i64);
 379   if (strncmp(buf, "-4294967296", sizeof(buf)))
 380     return 3;
 381
 382   snprintf(buf, sizeof(buf), "0o%" PRIo64, ui64);
 383   if (strncmp(buf, "0o40000000000", sizeof(buf)))
 384     return 4;
 385
 386   snprintf(buf, sizeof(buf), "0x%" PRIx64, ui64);
 387   if (strncmp(buf, "0x100000000", sizeof(buf)))
 388     return 5;
 389
 390   snprintf(buf, sizeof(buf), "%" PRIu64, ui64);
 391   if (strncmp(buf, "4294967296", sizeof(buf)))
 392     return 6;
 393
 394   return 0;
 395 }
 396         ]])
 397     ],
 398     [
 399         AC_MSG_RESULT(yes)
 400     ],
 401     [
 402         AC_MSG_RESULT(no)
 403         AC_MSG_ERROR(
 404 [The snprintf(3) implementation in this libc is not suitable,
 405 tcpdump would not work correctly even if it managed to compile.])
 406     ],
 407     [
 408         AC_MSG_RESULT(not while cross-compiling)
 409     ]
 410 )
 411
 412 AC_CHECK_LIB(rpc, main)         dnl It's unclear why we might need -lrpc
 413
 414 dnl Some platforms may need -lnsl for getrpcbynumber.
 415 AC_SEARCH_LIBS(getrpcbynumber, nsl,
 416     AC_DEFINE(HAVE_GETRPCBYNUMBER, 1, [define if you have getrpcbynumber()]))
 417
 418 AC_LBL_LIBPCAP(V_PCAPDEP, V_INCLS)
 419
 420 #
 421 # Check for these after AC_LBL_LIBPCAP, so we link with the appropriate
 422 # libraries (e.g., "-lsocket -lnsl" on Solaris).
 423 #
 424 # You are in a twisty little maze of UN*Xes, all different.
 425 # Some might not have ether_ntohost().
 426 # Some might have it and declare it in <net/ethernet.h>.
 427 # Some might have it and declare it in <netinet/ether.h>
 428 # Some might have it and declare it in <sys/ethernet.h>.
 429 # Some might have it and declare it in <arpa/inet.h>.
 430 # Some might have it and declare it in <netinet/if_ether.h>.
 431 # Some might have it and not declare it in any header file.
 432 #
 433 # Before you is a C compiler.
 434 #
 435 AC_CHECK_FUNCS(ether_ntohost, [
 436         #
 437         # OK, we have ether_ntohost().  Is it declared in <net/ethernet.h>?
 438         #
 439         # This test fails if we don't have <net/ethernet.h> or if we do
 440         # but it doesn't declare ether_ntohost().
 441         #
 442         AC_CHECK_DECL(ether_ntohost,
 443             [
 444                 AC_DEFINE(NET_ETHERNET_H_DECLARES_ETHER_NTOHOST,1,
 445                     [Define to 1 if net/ethernet.h declares `ether_ntohost'])
 446             ],,
 447             [
 448 #include <net/ethernet.h>
 449             ])
 450         #
 451         # Did that succeed?
 452         #
 453         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 454                 #
 455                 # No, how about <netinet/ether.h>, as on Linux?
 456                 #
 457                 # This test fails if we don't have <netinet/ether.h>
 458                 # or if we do but it doesn't declare ether_ntohost().
 459                 #
 460                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 461                 # treat the previous failure as a cached value and
 462                 # suppress the next test.
 463                 #
 464                 unset ac_cv_have_decl_ether_ntohost
 465                 AC_CHECK_DECL(ether_ntohost,
 466                     [
 467                         AC_DEFINE(NETINET_ETHER_H_DECLARES_ETHER_NTOHOST,1,
 468                             [Define to 1 if netinet/ether.h declares `ether_ntohost'])
 469                     ],,
 470                     [
 471 #include <netinet/ether.h>
 472                     ])
 473         fi
 474         #
 475         # Did that succeed?
 476         #
 477         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 478                 #
 479                 # No, how about <sys/ethernet.h>, as on Solaris 10
 480                 # and later?
 481                 #
 482                 # This test fails if we don't have <sys/ethernet.h>
 483                 # or if we do but it doesn't declare ether_ntohost().
 484                 #
 485                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 486                 # treat the previous failure as a cached value and
 487                 # suppress the next test.
 488                 #
 489                 unset ac_cv_have_decl_ether_ntohost
 490                 AC_CHECK_DECL(ether_ntohost,
 491                     [
 492                         AC_DEFINE(SYS_ETHERNET_H_DECLARES_ETHER_NTOHOST,1,
 493                             [Define to 1 if sys/ethernet.h declares `ether_ntohost'])
 494                     ],,
 495                     [
 496 #include <sys/ethernet.h>
 497                     ])
 498         fi
 499         #
 500         # Did that succeed?
 501         #
 502         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 503                 #
 504                 # No, how about <arpa/inet.h>, as in AIX?
 505                 #
 506                 # This test fails if we don't have <arpa/inet.h>
 507                 # (if we have ether_ntohost(), we should have
 508                 # networking, and if we have networking, we should
 509                 # have <arpa/inet.h>) or if we do but it doesn't
 510                 # declare ether_ntohost().
 511                 #
 512                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 513                 # treat the previous failure as a cached value and
 514                 # suppress the next test.
 515                 #
 516                 unset ac_cv_have_decl_ether_ntohost
 517                 AC_CHECK_DECL(ether_ntohost,
 518                     [
 519                         AC_DEFINE(ARPA_INET_H_DECLARES_ETHER_NTOHOST,1,
 520                             [Define to 1 if arpa/inet.h declares `ether_ntohost'])
 521                     ],,
 522                     [
 523 #include <arpa/inet.h>
 524                     ])
 525         fi
 526         #
 527         # Did that succeed?
 528         #
 529         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 530                 #
 531                 # No, how about <netinet/if_ether.h>?
 532                 # On some platforms, it requires <net/if.h> and
 533                 # <netinet/in.h>, and we always include it with
 534                 # both of them, so test it with both of them.
 535                 #
 536                 # This test fails if we don't have <netinet/if_ether.h>
 537                 # and the headers we include before it, or if we do but
 538                 # <netinet/if_ether.h> doesn't declare ether_hostton().
 539                 #
 540                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 541                 # treat the previous failure as a cached value and
 542                 # suppress the next test.
 543                 #
 544                 unset ac_cv_have_decl_ether_ntohost
 545                 AC_CHECK_DECL(ether_ntohost,
 546                     [
 547                         AC_DEFINE(NETINET_IF_ETHER_H_DECLARES_ETHER_NTOHOST,1,
 548                             [Define to 1 if netinet/if_ether.h declares `ether_ntohost'])
 549                     ],,
 550                     [
 551 #include <sys/types.h>
 552 #include <sys/socket.h>
 553 #include <net/if.h>
 554 #include <netinet/in.h>
 555 #include <netinet/if_ether.h>
 556                     ])
 557         fi
 558         #
 559         # After all that, is ether_ntohost() declared?
 560         #
 561         if test "$ac_cv_have_decl_ether_ntohost" = yes; then
 562                 #
 563                 # Yes.
 564                 #
 565                 AC_DEFINE(HAVE_DECL_ETHER_NTOHOST, 1,
 566                     [Define to 1 if you have the declaration of `ether_ntohost'])
 567         else
 568                 #
 569                 # No, we'll have to declare it ourselves.
 570                 # Do we have "struct ether_addr" if we include
 571                 # <netinet/if_ether.h>?
 572                 #
 573                 AC_CHECK_TYPES(struct ether_addr,,,
 574                     [
 575                         #include <sys/types.h>
 576                         #include <sys/socket.h>
 577                         #include <net/if.h>
 578                         #include <netinet/in.h>
 579                         #include <netinet/if_ether.h>
 580                     ])
 581         fi
 582     AC_CACHE_CHECK(for buggy ether_ntohost, ac_cv_buggy_ether_ntohost, [
 583         AC_RUN_IFELSE([AC_LANG_SOURCE([[
 584   #include <netdb.h>
 585   #if defined(NET_ETHERNET_H_DECLARES_ETHER_NTOHOST)
 586     /*
 587      * OK, just include <net/ethernet.h>.
 588      */
 589     #include <net/ethernet.h>
 590   #elif defined(NETINET_ETHER_H_DECLARES_ETHER_NTOHOST)
 591     /*
 592      * OK, just include <netinet/ether.h>
 593      */
 594     #include <netinet/ether.h>
 595   #elif defined(SYS_ETHERNET_H_DECLARES_ETHER_NTOHOST)
 596     /*
 597      * OK, just include <sys/ethernet.h>
 598      */
 599     #include <sys/ethernet.h>
 600   #elif defined(ARPA_INET_H_DECLARES_ETHER_NTOHOST)
 601     /*
 602      * OK, just include <arpa/inet.h>
 603      */
 604     #include <arpa/inet.h>
 605   #elif defined(NETINET_IF_ETHER_H_DECLARES_ETHER_NTOHOST)
 606     /*
 607      * OK, include <netinet/if_ether.h>, after all the other stuff we
 608      * need to include or define for its benefit.
 609      */
 610     #define NEED_NETINET_IF_ETHER_H
 611   #else
 612     /*
 613      * We'll have to declare it ourselves.
 614      * If <netinet/if_ether.h> defines struct ether_addr, include
 615      * it.  Otherwise, define it ourselves.
 616      */
 617     #ifdef HAVE_STRUCT_ETHER_ADDR
 618       #define NEED_NETINET_IF_ETHER_H
 619     #else /* HAVE_STRUCT_ETHER_ADDR */
 620         struct ether_addr {
 621                 /* Beware FreeBSD calls this "octet". */
 622                 unsigned char ether_addr_octet[MAC_ADDR_LEN];
 623         };
 624     #endif /* HAVE_STRUCT_ETHER_ADDR */
 625   #endif /* what declares ether_ntohost() */
 626
 627   #ifdef NEED_NETINET_IF_ETHER_H
 628     /*
 629      * Include diag-control.h before <net/if.h>, which too defines a macro
 630      * named ND_UNREACHABLE.
 631      */
 632     #include "diag-control.h"
 633     #include <net/if.h>         /* Needed on some platforms */
 634     #include <netinet/in.h>     /* Needed on some platforms */
 635     #include <netinet/if_ether.h>
 636   #endif /* NEED_NETINET_IF_ETHER_H */
 637
 638   #ifndef HAVE_DECL_ETHER_NTOHOST
 639     /*
 640      * No header declares it, so declare it ourselves.
 641      */
 642     extern int ether_ntohost(char *, const struct ether_addr *);
 643   #endif /* !defined(HAVE_DECL_ETHER_NTOHOST) */
 644   #include <stdlib.h>
 645   #include <sys/types.h>
 646   #include <sys/param.h>
 647   #include <sys/socket.h>
 648
 649   int
 650   main(int argc, char **argv)
 651   {
 652     u_char ea[6] = { 0xff, 0xff, 0xff, 0xff, 0xff };
 653     char name[MAXHOSTNAMELEN];
 654
 655     ether_ntohost(name, (struct ether_addr *)ea);
 656     exit(0);
 657   }
 658         ]])
 659         ], [ac_cv_buggy_ether_ntohost=no],
 660            [ac_cv_buggy_ether_ntohost=yes],
 661            [ac_cv_buggy_ether_ntohost="not while cross-compiling"])])
 662     if test "$ac_cv_buggy_ether_ntohost" = "no"; then
 663         AC_DEFINE(USE_ETHER_NTOHOST, 1,
 664             [define if you have ether_ntohost() and it works])
 665     fi
 666 ])
 667
 668 #
 669 # Do we have the new open API?  Check for pcap_create, and assume that,
 670 # if we do, we also have pcap_activate() and the other new routines
 671 # introduced in libpcap 1.0.
 672 #
 673 # We require those routines, so fail if we don't find it.
 674 #
 675 AC_CHECK_FUNC(pcap_create,,
 676     [AC_MSG_ERROR([libpcap is too old; 1.0 or later is required])])
 677
 678 #
 679 # OK, do we have pcap_set_tstamp_type?  If so, assume we have
 680 # pcap_list_tstamp_types and pcap_free_tstamp_types as well.
 681 #
 682 AC_CHECK_FUNCS(pcap_set_tstamp_type)
 683 #
 684 # And do we have pcap_set_tstamp_precision?  If so, we assume
 685 # we also have pcap_open_offline_with_tstamp_precision.
 686 #
 687 AC_CHECK_FUNCS(pcap_set_tstamp_precision)
 688
 689 #
 690 # Check for a miscellaneous collection of functions which we use
 691 # if we have them.
 692 #
 693 AC_CHECK_FUNCS(pcap_set_immediate_mode pcap_dump_ftell64)
 694 #
 695 # See the comment in AC_LBL_LIBPCAP in aclocal.m4 for the reason
 696 # why we don't check for remote-capture APIs if we're building
 697 # with the system libpcap on macOS.
 698 #
 699 if test "$_dont_check_for_remote_apis" != "yes"; then
 700         AC_CHECK_FUNCS(pcap_open pcap_findalldevs_ex)
 701 fi
 702
 703 #
 704 # Check for special debugging functions
 705 #
 706 AC_CHECK_FUNCS(pcap_set_parser_debug)
 707 if test "$ac_cv_func_pcap_set_parser_debug" = "no" ; then
 708         #
 709         # OK, we don't have pcap_set_parser_debug() to set the libpcap
 710         # filter expression parser debug flag; can we directly set the
 711         # flag?
 712         AC_MSG_CHECKING(whether pcap_debug is defined by libpcap)
 713         AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
 714                 extern int pcap_debug;
 715
 716                 return pcap_debug;
 717            ]])
 718            ],
 719            [ac_lbl_cv_pcap_debug_defined=yes],
 720            [ac_lbl_cv_pcap_debug_defined=no])
 721         if test "$ac_lbl_cv_pcap_debug_defined" = yes ; then
 722                 AC_MSG_RESULT(yes)
 723                 AC_DEFINE(HAVE_PCAP_DEBUG, 1, [define if libpcap has pcap_debug])
 724         else
 725                 AC_MSG_RESULT(no)
 726                 #
 727                 # OK, what about "yydebug"?
 728                 #
 729                 AC_MSG_CHECKING(whether yydebug is defined by libpcap)
 730                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
 731                         extern int yydebug;
 732
 733                         return yydebug;
 734                    ]])
 735                    ],
 736                    [ac_lbl_cv_yydebug_defined=yes],
 737                    [ac_lbl_cv_yydebug_defined=no])
 738                 if test "$ac_lbl_cv_yydebug_defined" = yes ; then
 739                         AC_MSG_RESULT(yes)
 740                         AC_DEFINE(HAVE_YYDEBUG, 1, [define if libpcap has yydebug])
 741                 else
 742                         AC_MSG_RESULT(no)
 743                 fi
 744         fi
 745 fi
 746 AC_CHECK_FUNCS(pcap_set_optimizer_debug)
 747
 748 #
 749 # bpf_dump() moved from tcpdump to libpcap in libpcap 0.6, but some
 750 # versions of libpcap didn't pick that change up; the OpenBSD libpcap
 751 # picked up most of the new APIs from versions up to 1.0, but didn't
 752 # pick up bpf_dump(), so we need to provide it if it's absent.
 753 #
 754 AC_REPLACE_FUNCS(bpf_dump)      dnl moved to libpcap in 0.6
 755
 756 #
 757 # Assume V7/BSD convention for man pages (file formats in section 5,
 758 # miscellaneous info in section 7).
 759 #
 760 MAN_FILE_FORMATS=5
 761 MAN_MISC_INFO=7
 762 case "$host_os" in
 763
 764 hpux*)
 765         #
 766         # Use System V conventions for man pages.
 767         #
 768         MAN_FILE_FORMATS=4
 769         MAN_MISC_INFO=5
 770         ;;
 771
 772 solaris*)
 773         #
 774         # Use System V conventions for man pages.
 775         #
 776         MAN_FILE_FORMATS=4
 777         MAN_MISC_INFO=5
 778         ;;
 779 esac
 780
 781 savedcppflags="$CPPFLAGS"
 782 CPPFLAGS="$CPPFLAGS $V_INCLS"
 783
 784 #
 785 # Check whether we have pcap/pcap-inttypes.h.
 786 # If we do, we use that to get the C99 types defined.
 787 #
 788 AC_CHECK_HEADERS(pcap/pcap-inttypes.h)
 789
 790 CPPFLAGS="$savedcppflags"
 791
 792 #
 793 # Define the old BSD specified-width types in terms of the C99 types;
 794 # we may need them with libpcap include files.
 795 #
 796 AC_CHECK_TYPE([u_int8_t], ,
 797         [AC_DEFINE([u_int8_t], [uint8_t],
 798         [Define to `uint8_t' if u_int8_t not defined.])],
 799         [AC_INCLUDES_DEFAULT
 800 #include <sys/types.h>
 801 ])
 802 AC_CHECK_TYPE([u_int16_t], ,
 803         [AC_DEFINE([u_int16_t], [uint16_t],
 804         [Define to `uint16_t' if u_int16_t not defined.])],
 805         [AC_INCLUDES_DEFAULT
 806 #include <sys/types.h>
 807 ])
 808 AC_CHECK_TYPE([u_int32_t], ,
 809         [AC_DEFINE([u_int32_t], [uint32_t],
 810         [Define to `uint32_t' if u_int32_t not defined.])],
 811         [AC_INCLUDES_DEFAULT
 812 #include <sys/types.h>
 813 ])
 814 AC_CHECK_TYPE([u_int64_t], ,
 815         [AC_DEFINE([u_int64_t], [uint64_t],
 816         [Define to `uint64_t' if u_int64_t not defined.])],
 817         [AC_INCLUDES_DEFAULT
 818 #include <sys/types.h>
 819 ])
 820
 821 AC_PROG_RANLIB
 822 AC_CHECK_TOOL([AR], [ar])
 823
 824 AC_LBL_DEVEL(V_CCOPT)
 825
 826 # Check for OpenSSL/libressl libcrypto
 827 AC_MSG_CHECKING(whether to use OpenSSL/libressl libcrypto)
 828 # Specify location for both includes and libraries.
 829 want_libcrypto=ifavailable
 830 AC_ARG_WITH(crypto,
 831     AS_HELP_STRING([--with-crypto]@<:@=DIR@:>@,
 832                    [use OpenSSL/libressl libcrypto (located in directory DIR, if specified) @<:@default=yes, if available@:>@]),
 833 [
 834         if test $withval = no
 835         then
 836                 # User doesn't want to link with libcrypto.
 837                 want_libcrypto=no
 838                 AC_MSG_RESULT(no)
 839         elif test $withval = yes
 840         then
 841                 # User wants to link with libcrypto but hasn't specified
 842                 # a directory.
 843                 want_libcrypto=yes
 844                 AC_MSG_RESULT(yes)
 845         else
 846                 # User wants to link with libcrypto and has specified
 847                 # a directory, so use the provided value.
 848                 want_libcrypto=yes
 849                 libcrypto_root=$withval
 850                 AC_MSG_RESULT([yes, using the version installed in $withval])
 851         fi
 852 ],[
 853         #
 854         # Use libcrypto if it's present, otherwise don't; no directory
 855         # was specified.
 856         #
 857         want_libcrypto=ifavailable
 858         AC_MSG_RESULT([yes, if available])
 859 ])
 860 if test "$want_libcrypto" != "no"; then
 861         #
 862         # Were we told where to look for libcrypto?
 863         #
 864         if test -z "$libcrypto_root"; then
 865                 #
 866                 # No.
 867                 #
 868                 # First, try looking for it with pkg-config, if we have it.
 869                 #
 870                 # Homebrew's pkg-config does not, by default, look for
 871                 # pkg-config files for packages it has installed.
 872                 # Furthermore, at least for OpenSSL, they appear to be
 873                 # dumped in package-specific directories whose paths are
 874                 # not only package-specific but package-version-specific.
 875                 #
 876                 # So the only way to find openssl is to get the value of
 877                 # PKG_CONFIG_PATH from "brew --env openssl" and add that
 878                 # to PKG_CONFIG_PATH.  (No, we can't just assume it's under
 879                 # /usr/local; Homebrew have conveniently chosen to put it
 880                 # under /opt/homebrew on ARM.)
 881                 #
 882                 # That's the nice thing about Homebrew - it makes things easier!
 883                 # Thanks!
 884                 #
 885                 save_PKG_CONFIG_PATH="$PKG_CONFIG_PATH"
 886                 if test -n "$BREW"; then
 887                         openssl_pkgconfig_dir=`$BREW --env --plain openssl | sed -n 's/PKG_CONFIG_PATH: //p'`
 888                         PKG_CONFIG_PATH="$openssl_pkgconfig_dir:$PKG_CONFIG_PATH"
 889                 fi
 890                 PKG_CHECK_MODULE(LIBCRYPTO, libcrypto,
 891                     [
 892                         #
 893                         # We found OpenSSL/libressl libcrypto.
 894                         #
 895                         HAVE_LIBCRYPTO=yes
 896                     ])
 897                 PKG_CONFIG_PATH="$save_PKG_CONFIG_PATH"
 898
 899                 #
 900                 # If it wasn't found, and we have Homebrew installed, see
 901                 # if it's in Homebrew.
 902                 #
 903                 if test "x$HAVE_LIBCRYPTO" != "xyes" -a -n "$BREW"; then
 904                         AC_MSG_CHECKING(for openssl in Homebrew)
 905                         #
 906                         # The brew man page lies when it speaks of
 907                         # $BREW --prefix --installed <formula>
 908                         # outputting nothing.  In Homebrew 3.3.16,
 909                         # it produces output regardless of whether
 910                         # the formula is installed or not, so we
 911                         # send the standard output and error to
 912                         # the bit bucket.
 913                         #
 914                         # libcrypto isn't a formula, openssl is a formula.
 915                         #
 916                         if $BREW --prefix --installed openssl >/dev/null 2>&1; then
 917                                 #
 918                                 # Yes.  Get the include directory and library
 919                                 # directory.  (No, we can't just assume it's
 920                                 # under /usr/local; Homebrew have conveniently
 921                                 # chosen to put it under /opt/homebrew on ARM.)
 922                                 #
 923                                 AC_MSG_RESULT(yes)
 924                                 HAVE_LIBCRYPTO=yes
 925                                 openssl_path=`$BREW --prefix openssl`
 926                                 LIBCRYPTO_CFLAGS="-I$openssl_path/include"
 927                                 LIBCRYPTO_LIBS="-L$openssl_path/lib -lcrypto"
 928                         else
 929                                 AC_MSG_RESULT(no)
 930                         fi
 931                 fi
 932
 933                 #
 934                 # If it wasn't found, and /usr/local/include and /usr/local/lib
 935                 # exist, check if it's in /usr/local.  (We check whether they
 936                 # exist because, if they don't exist, the compiler will warn
 937                 # about that and then ignore the argument, so they test
 938                 # using just the system header files and libraries.)
 939                 #
 940                 # We include the standard include file to 1) make sure that
 941                 # it's installed (if it's just a shared library for the
 942                 # benefit of existing programs, that's not useful) and 2)
 943                 # because SSL_library_init() is a library routine in some
 944                 # versions and a #defined wrapper around OPENSSL_init_ssl()
 945                 # in others.
 946                 #
 947                 if test "x$HAVE_LIBCRYPTO" != "xyes" -a -d "/usr/local/include" -a -d "/usr/local/lib"; then
 948                         AC_LBL_SAVE_CHECK_STATE
 949                         CFLAGS="$CFLAGS -I/usr/local/include"
 950                         LIBS="$LIBS -L/usr/local/lib -lcrypto"
 951                         AC_MSG_CHECKING(whether we have an OpenSSL/libressl libcrypto in /usr/local that we can use)
 952                         AC_LINK_IFELSE([AC_LANG_PROGRAM(
 953                             [[
 954 #include <openssl/evp.h>
 955                             ]],
 956                             [[
 957 EVP_CIPHER_CTX_block_size((EVP_CIPHER_CTX *)0);
 958 return 0;
 959                             ]])],
 960                             [
 961                                 AC_MSG_RESULT(yes)
 962                                 HAVE_LIBCRYPTO=yes
 963                                 LIBCRYPTO_CFLAGS="-I/usr/local/include"
 964                                 LIBCRYPTO_LIBS="-L/usr/local/lib -lcrypto"
 965                             ],
 966                             AC_MSG_RESULT(no))
 967                         AC_LBL_RESTORE_CHECK_STATE
 968                 fi
 969
 970                 #
 971                 # If it wasn't found, check if it's a system library.
 972                 #
 973                 # We include the standard include file to 1) make sure that
 974                 # it's installed (if it's just a shared library for the
 975                 # benefit of existing programs, that's not useful) and 2)
 976                 # make sure this isn't a newer macOS that provides libcrypto
 977                 # as a shared library but doesn't provide headers - Apple,
 978                 # bless their pointy little heads, apparently ship libcrypto
 979                 # as a library, but not the header files, in El Capitan and
 980                 # later, probably because they don't want you writing nasty
 981                 # portable code that could run on other UN*Xes, they want you
 982                 # writing code that uses their Shiny New Crypto Library and
 983                 # that thus only runs on macOS.
 984                 #
 985                 if test "x$HAVE_LIBCRYPTO" != "xyes"; then
 986                         AC_LBL_SAVE_CHECK_STATE
 987                         LIBS="$LIBS -lcrypto"
 988                         AC_MSG_CHECKING(whether we have a system OpenSSL/libressl that we can use)
 989                         AC_LINK_IFELSE([AC_LANG_PROGRAM(
 990                             [[
 991 #include <openssl/evp.h>
 992                             ]],
 993                             [[
 994 EVP_CIPHER_CTX_block_size((EVP_CIPHER_CTX *)0);
 995 return 0;
 996                             ]])],
 997                             [
 998                                 AC_MSG_RESULT(yes)
 999                                 HAVE_LIBCRYPTO=yes
1000                                 LIBCRYPTO_LIBS="-lcrypto"
1001                             ],
1002                             AC_MSG_RESULT(no))
1003                         AC_LBL_RESTORE_CHECK_STATE
1004                 fi
1005         else
1006                 #
1007                 # Yes.
1008                 #
1009                 # Look for it there.
1010                 #
1011                 AC_LBL_SAVE_CHECK_STATE
1012                 CFLAGS="$CFLAGS -I$libcrypto_root/include"
1013                 LIBS="$LIBS -L$libcrypto_root/lib -lcrypto"
1014                 AC_MSG_CHECKING(whether we have a system OpenSSL/libressl that we can use)
1015                 AC_LINK_IFELSE([AC_LANG_PROGRAM(
1016                     [[
1017 #include <openssl/evp.h>
1018                     ]],
1019                     [[
1020 EVP_CIPHER_CTX_block_size((EVP_CIPHER_CTX *)0);
1021 return 0;
1022                     ]])],
1023                     [
1024                         AC_MSG_RESULT(yes)
1025                         HAVE_LIBCRYPTO=yes
1026                         LIBCRYPTO_CFLAGS="-I$libcrypto_root/include"
1027                         LIBCRYPTO_LIBS="-L$libcrypto_root/lib -lcrypto"
1028                     ],
1029                     AC_MSG_RESULT(no))
1030                 AC_LBL_RESTORE_CHECK_STATE
1031         fi
1032
1033         #
1034         # OK, did we find it?
1035         #
1036         if test "x$HAVE_LIBCRYPTO" = "xyes"; then
1037                 AC_DEFINE([HAVE_LIBCRYPTO], [1], [Define to 1 if you have a usable `crypto' library (-lcrypto).])
1038
1039                 #
1040                 # Put the subdirectories of the libcrypto root directory
1041                 # at the end of the header and library search path, to
1042                 # make sure they come after any -I or -L flags for
1043                 # a local libpcap - those must take precedence of any
1044                 # directory that might contain an installed version of
1045                 # libpcap.
1046                 #
1047                 V_INCLS="$V_INCLS $LIBCRYPTO_CFLAGS"
1048                 LIBS="$LIBS $LIBCRYPTO_LIBS"
1049
1050                 #
1051                 # OK, then:
1052                 #
1053                 # 1) do we have EVP_CIPHER_CTX_new?
1054                 # If so, we use it to allocate an EVP_CIPHER_CTX, as
1055                 # EVP_CIPHER_CTX may be opaque; otherwise, we allocate it
1056                 # ourselves.
1057                 #
1058                 # 2) do we have EVP_DecryptInit_ex()?
1059                 # If so, we use it, because we need to be able to make
1060                 # two "initialize the cipher" calls, one with the cipher
1061                 # and key, and one with the IV, and, as of OpenSSL 1.1,
1062                 # You Can't Do That with EVP_DecryptInit(), because a
1063                 # call to EVP_DecryptInit() will unconditionally clear
1064                 # the context, and if you don't supply a cipher, it'll
1065                 # clear the cipher, rendering the context unusable and
1066                 # causing a crash.
1067                 #
1068                 AC_CHECK_FUNCS(EVP_CIPHER_CTX_new EVP_DecryptInit_ex)
1069         else
1070                 AC_MSG_NOTICE(OpenSSL/libressl libcrypto not found)
1071         fi
1072 fi
1073
1074 # Check for libcap-ng
1075 AC_MSG_CHECKING(whether to use libcap-ng)
1076 # Specify location for both includes and libraries.
1077 AC_ARG_WITH(cap_ng,
1078     AS_HELP_STRING([--with-cap-ng],
1079                    [use libcap-ng @<:@default=yes, if available@:>@]),
1080 [
1081         if test $withval = no
1082         then
1083                 want_libcap_ng=no
1084                 AC_MSG_RESULT(no)
1085         elif test $withval = yes
1086         then
1087                 want_libcap_ng=yes
1088                 AC_MSG_RESULT(yes)
1089         fi
1090 ],[
1091         #
1092         # Use libcap-ng if it's present, otherwise don't.
1093         #
1094         want_libcap_ng=ifavailable
1095         AC_MSG_RESULT([yes, if available])
1096 ])
1097
1098 # libcap-ng is available on Linux only.
1099 expr "$host_os" : linux >/dev/null || want_libcap_ng=no
1100
1101 if test "$want_libcap_ng" != "no"; then
1102         AC_CHECK_LIB(cap-ng, capng_change_id)
1103         AC_CHECK_HEADERS(cap-ng.h)
1104 fi
1105
1106 dnl
1107 dnl set additional include path if necessary
1108 if test "$missing_includes" = "yes"; then
1109         CPPFLAGS="$CPPFLAGS -I$srcdir/missing"
1110         V_INCLS="$V_INCLS -I$srcdir/missing"
1111 fi
1112
1113 AC_SUBST(V_CCOPT)
1114 AC_SUBST(V_DEFS)
1115 AC_SUBST(V_INCLS)
1116 AC_SUBST(V_PCAPDEP)
1117 AC_SUBST(LOCALSRC)
1118 AC_SUBST(MAN_FILE_FORMATS)
1119 AC_SUBST(MAN_MISC_INFO)
1120
1121 AC_PROG_INSTALL
1122
1123 AC_CONFIG_HEADERS([config.h])
1124 AH_TOP([
1125 #ifndef TCPDUMP_CONFIG_H_
1126 #define TCPDUMP_CONFIG_H_
1127 ])
1128 AH_BOTTOM([
1129 #endif // TCPDUMP_CONFIG_H_
1130 ])
1131
1132 AC_CONFIG_COMMANDS([.devel],[[if test -f .devel; then
1133         echo timestamp > stamp-h
1134         cat $srcdir/Makefile-devel-adds >> Makefile
1135         make depend || exit 1
1136 fi]])
1137 AC_CONFIG_FILES([Makefile tcpdump.1])
1138 AC_OUTPUT
1139 exit 0