]> The Tcpdump Group git mirrors - tcpdump/blob - configure.ac
projects / tcpdump / blob


ffe0f97ed8d9b21b27f3f8205b0ae3e4df4f8fd0
[tcpdump] / configure.ac
1 dnl Copyright (c) 1994, 1995, 1996, 1997
2 dnl The Regents of the University of California. All rights reserved.
3 dnl
4 dnl Process this file with autoconf to produce a configure script.
5 dnl
6
7 #
8 # See
9 #
10 # https://ftp.gnu.org/gnu/config/README
11 #
12 # for the URLs to use to fetch new versions of config.guess and
13 # config.sub.
14 #
15
16 AC_PREREQ([2.69])
17 AC_INIT([tcpdump],[m4_esyscmd_s(cat VERSION)])
18 AC_CONFIG_SRCDIR(tcpdump.c)
19
20 AC_CANONICAL_HOST
21
22 AC_LBL_C_INIT_BEFORE_CC(V_INCLS)
23 #
24 # Try to enable as many C99 features as we can.
25 # At minimum, we want C++/C99-style // comments.
26 #
27 AC_PROG_CC_C99
28 if test "$ac_cv_prog_cc_c99" = "no"; then
29 AC_MSG_WARN([The C compiler does not support C99; there may be compiler errors])
30 fi
31 AC_LBL_C_INIT(V_CCOPT, V_INCLS)
32 AC_C_INLINE
33
34 AC_CHECK_HEADERS(fcntl.h rpc/rpc.h rpc/rpcent.h net/if.h)
35
36 #
37 # Assorted platform checks.
38 #
39 case "$host_os" in
40
41 darwin*)
42 AC_ARG_ENABLE(universal,
43 AS_HELP_STRING([--disable-universal],[don't build universal on macOS]))
44 if test "$enable_universal" != "no"; then
45 case "$host_os" in
46
47 darwin9.*)
48 #
49 # Leopard. Build for x86 and 32-bit PowerPC, with
50 # x86 first. (That's what Apple does.)
51 #
52 V_CCOPT="$V_CCOPT -arch i386 -arch ppc"
53 LDFLAGS="$LDFLAGS -arch i386 -arch ppc"
54 ;;
55
56 darwin10.*)
57 #
58 # Snow Leopard. Build for x86-64 and x86, with
59 # x86-64 first. (That's what Apple does.)
60 #
61 V_CCOPT="$V_CCOPT -arch x86_64 -arch i386"
62 LDFLAGS="$LDFLAGS -arch x86_64 -arch i386"
63 ;;
64 esac
65 fi
66 ;;
67
68 haiku*)
69 #
70 # On Haiku, all executables are built as shared objects,
71 # and must have their code build as PIC.
72 #
73 # At least some versions of Haiku's GCC default to PIC,
74 # with a -fno-pic option for cases where that's not desired.
75 #
76 # Clang hasn't been modified in that fashion, so Clang
77 # builds of tcpdump fail.
78 #
79 # Force the use of -fPIC (even for GCC; adding -fPIC for GCC
80 # won't break anything).
81 #
82 CFLAGS="$CFLAGS -fPIC"
83 ;;
84 esac
85
86 AC_ARG_WITH([smi],
87 [AS_HELP_STRING([--with-smi],
88 [link with libsmi (allows to load MIBs on the fly to decode SNMP packets) [default=yes, if available]])],
89 [],
90 [with_smi=yes])
91
92 if test "x$with_smi" != "xno" ; then
93 AC_CHECK_HEADER(smi.h,
94 [
95 #
96 # OK, we found smi.h. Do we have libsmi with smiInit?
97 #
98 AC_CHECK_LIB(smi, smiInit,
99 [
100 #
101 # OK, we have libsmi with smiInit. Can we use it?
102 #
103 AC_MSG_CHECKING([whether to enable libsmi])
104 savedlibs="$LIBS"
105 LIBS="-lsmi $LIBS"
106 AC_RUN_IFELSE([AC_LANG_SOURCE([[
107 /* libsmi available check */
108 #include <stdio.h>
109 #include <stdlib.h>
110 #include <string.h>
111 #include <smi.h>
112 int main()
113 {
114 int current, revision, age, n;
115 const int required = 2;
116 if (smiInit(""))
117 exit(1);
118 if (strcmp(SMI_LIBRARY_VERSION, smi_library_version))
119 exit(2);
120 n = sscanf(smi_library_version, "%d:%d:%d", &current, &revision, &age);
121 if (n != 3)
122 exit(3);
123 if (required < current - age || required > current)
124 exit(4);
125 exit(0);
126 }
127 ]])
128 ],
129 [
130 AC_MSG_RESULT(yes)
131 AC_DEFINE(USE_LIBSMI, 1,
132 [Define if you enable support for libsmi])
133 ],
134 [
135 dnl autoconf documentation says that
136 dnl $? contains the exit value.
137 dnl reality is that it does not.
138 dnl We leave this in just in case
139 dnl autoconf ever comes back to
140 dnl match the documentation.
141 case $? in
142 1) AC_MSG_RESULT(no - smiInit failed) ;;
143 2) AC_MSG_RESULT(no - header/library version mismatch) ;;
144 3) AC_MSG_RESULT(no - can't determine library version) ;;
145 4) AC_MSG_RESULT(no - too old) ;;
146 *) AC_MSG_RESULT(no) ;;
147 esac
148 LIBS="$savedlibs"
149 ],
150 [
151 AC_MSG_RESULT(not when cross-compiling)
152 LIBS="$savedlibs"
153 ]
154 )
155 ])
156 ])
157 fi
158
159 AC_MSG_CHECKING([whether to enable the instrument functions code])
160 AC_ARG_ENABLE([instrument-functions],
161 [AS_HELP_STRING([--enable-instrument-functions],
162 [enable instrument functions code [default=no]])],
163 [],
164 [enableval=no])
165 case "$enableval" in
166 yes) AC_MSG_RESULT(yes)
167 AC_CHECK_LIB([bfd], [bfd_init],
168 [true],
169 [AC_MSG_ERROR(
170 [--enable-instrument-functions was given, but test for library libbfd failed. Please install the 'binutils-dev' package.])],
171 [])
172 AC_DEFINE(ENABLE_INSTRUMENT_FUNCTIONS, 1,
173 [define if you want to build the instrument functions code])
174 LOCALSRC="$LOCALSRC instrument-functions.c"
175 # Add '-finstrument-functions' instrumentation option to generate
176 # instrumentation calls for entry and exit to functions.
177 # Try to avoid Address Space Layout Randomization (ALSR).
178 CFLAGS="$CFLAGS -O0 -ggdb -finstrument-functions -fno-stack-protector -fno-pic"
179 LDFLAGS="$LDFLAGS -O0 -ggdb -fno-stack-protector -no-pie"
180 LIBS="$LIBS -lbfd"
181 ;;
182 *) AC_MSG_RESULT(no)
183 ;;
184 esac
185
186 AC_MSG_CHECKING([whether to enable the possibly-buggy SMB printer])
187 AC_ARG_ENABLE([smb],
188 [AS_HELP_STRING([--enable-smb],
189 [enable possibly-buggy SMB printer [default=no]])],
190 [],
191 [enableval=no])
192 case "$enableval" in
193 yes) AC_MSG_RESULT(yes)
194 AC_DEFINE(ENABLE_SMB, 1,
195 [define if you want to build the possibly-buggy SMB printer])
196 LOCALSRC="print-smb.c smbutil.c $LOCALSRC"
197 ;;
198 *) AC_MSG_RESULT(no)
199 ;;
200 esac
201
202 AC_ARG_WITH(user, [ --with-user=USERNAME drop privileges by default to USERNAME])
203 AC_MSG_CHECKING([whether to drop root privileges by default])
204 if test ! -z "$withval" && test "$withval" != "no" ; then
205 if test "$withval" = "yes" ; then
206 AC_MSG_ERROR([--with-user requires a username])
207 fi
208 AC_DEFINE_UNQUOTED(WITH_USER, "$withval",
209 [define if should drop privileges by default])
210 AC_MSG_RESULT([yes, to user "$withval"])
211 else
212 AC_MSG_RESULT(no)
213 fi
214
215 AC_ARG_WITH(chroot, [ --with-chroot=DIRECTORY when dropping privileges, chroot to DIRECTORY])
216 AC_MSG_CHECKING([whether to chroot])
217 if test ! -z "$withval" && test "$withval" != "no" ; then
218 if test "$withval" = "yes" ; then
219 AC_MSG_ERROR([--with-chroot requires a directory])
220 fi
221 AC_DEFINE_UNQUOTED(WITH_CHROOT, "$withval",
222 [define if should chroot when dropping privileges])
223 AC_MSG_RESULT([yes, to directory "$withval"])
224 else
225 AC_MSG_RESULT(no)
226 fi
227
228 AC_ARG_WITH(sandbox-capsicum,
229 AS_HELP_STRING([--with-sandbox-capsicum],
230 [use Capsicum security functions @<:@default=yes, if available@:>@]))
231 #
232 # Check whether various functions are available. If any are, set
233 # ac_lbl_capsicum_function_seen to yes; if any are not, set
234 # ac_lbl_capsicum_function_not_seen to yes.
235 #
236 # We don't check cap_rights_init(), as it's a macro, wrapping another
237 # function, in at least some versions of FreeBSD, and AC_CHECK_FUNCS()
238 # doesn't handle that.
239 #
240 # All of the ones we check for must be available in order to enable
241 # capsicum sandboxing.
242 #
243 # XXX - do we need to check for all of them, or are there some that, if
244 # present, imply others are present?
245 #
246 if test -z "$with_sandbox_capsicum" || test "$with_sandbox_capsicum" != "no" ; then
247 #
248 # First, make sure we have the required header.
249 #
250 AC_CHECK_HEADER(sys/capsicum.h,
251 [
252 #
253 # We do; now make sure we have the required functions.
254 #
255 AC_CHECK_FUNCS(cap_enter cap_rights_limit cap_ioctls_limit openat,
256 ac_lbl_capsicum_function_seen=yes,
257 ac_lbl_capsicum_function_not_seen=yes)
258 ])
259 AC_CHECK_LIB(casper, cap_init, LIBS="$LIBS -lcasper")
260 AC_CHECK_LIB(cap_dns, cap_gethostbyaddr, LIBS="$LIBS -lcap_dns")
261 fi
262 AC_MSG_CHECKING([whether to sandbox using capsicum])
263 if test "x$ac_lbl_capsicum_function_seen" = "xyes" -a "x$ac_lbl_capsicum_function_not_seen" != "xyes"; then
264 AC_DEFINE(HAVE_CAPSICUM, 1, [capsicum support available])
265 AC_MSG_RESULT(yes)
266 else
267 AC_MSG_RESULT(no)
268 fi
269 AC_MSG_CHECKING([whether to sandbox using Casper library])
270 if test "x$ac_cv_lib_casper_cap_init" = "xyes" -a "x$ac_cv_lib_cap_dns_cap_gethostbyaddr" = "xyes"; then
271 AC_DEFINE(HAVE_CASPER, 1, [Casper support available])
272 AC_MSG_RESULT(yes)
273 else
274 AC_MSG_RESULT(no)
275 fi
276
277 #
278 # We must check this before checking whether to check the OS's IPv6,
279 # support because, on some platforms (such as SunOS 5.x), the test
280 # program requires the extra networking libraries.
281 #
282 AC_LBL_LIBRARY_NET
283
284 #
285 # Check whether AF_INET6 and struct in6_addr are defined.
286 # If they aren't both defined, we don't have sufficient OS
287 # support for IPv6, so we don't look for IPv6 support libraries,
288 # and we define AF_INET6 and struct in6_addr ourselves.
289 #
290 AC_MSG_CHECKING([whether the operating system supports IPv6])
291 AC_COMPILE_IFELSE(
292 [
293 AC_LANG_SOURCE(
294 [[
295 #include <string.h>
296 /* AF_INET6 available check */
297 #include <sys/types.h>
298 #ifdef _WIN32
299 #include <ws2tcpip.h>
300 #else
301 #include <sys/socket.h>
302 #include <netinet/in.h>
303 #endif
304 #ifdef AF_INET6
305 void
306 foo(struct in6_addr *addr)
307 {
308 memset(addr, 0, sizeof (struct in6_addr));
309 }
310 #else
311 #error "AF_INET6 not defined"
312 #endif
313 ]])
314 ],
315 [
316 AC_MSG_RESULT(yes)
317 AC_DEFINE(HAVE_OS_IPV6_SUPPORT, 1,
318 [define if the OS provides AF_INET6 and struct in6_addr])
319 ipv6=yes
320 ],
321 [
322 AC_MSG_RESULT(no)
323 ipv6=no
324 ]
325 )
326
327 ipv6type=unknown
328 ipv6lib=none
329 ipv6trylibc=no
330
331 if test "$ipv6" = "yes"; then
332 # Apparently, only on Linux by this point the configure script knows
333 # what the C preprocessor and the extended regexp grep commands are.
334 # On other OSes the first call to AC_EGREP_CPP() induces a search for
335 # these tools, which prints three lines in the middle of the IPv6
336 # detection message and distorts it. Resolve these dependencies
337 # beforehand to prevent that.
338 AC_PROG_CPP
339 AC_PROG_EGREP
340
341 AC_MSG_CHECKING([ipv6 stack type])
342 for i in inria kame linux-glibc linux-libinet6 toshiba v6d zeta; do
343 case $i in
344 inria)
345 dnl http://www.kame.net/
346 AC_EGREP_CPP(yes,
347 [#include <netinet/in.h>
348 #ifdef IPV6_INRIA_VERSION
349 yes
350 #endif],
351 [ipv6type=$i])
352 ;;
353 kame)
354 dnl http://www.kame.net/
355 AC_EGREP_CPP(yes,
356 [#include <netinet/in.h>
357 #ifdef __KAME__
358 yes
359 #endif],
360 [ipv6type=$i;
361 ipv6lib=inet6;
362 ipv6libdir=/usr/local/v6/lib;
363 ipv6trylibc=yes])
364 ;;
365 linux-glibc)
366 dnl http://www.v6.linux.or.jp/
367 AC_EGREP_CPP(yes,
368 [#include <features.h>
369 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
370 yes
371 #endif],
372 [ipv6type=$i])
373 ;;
374 linux-libinet6)
375 dnl http://www.v6.linux.or.jp/
376 dnl
377 dnl This also matches Solaris 8 and Tru64 UNIX 5.1,
378 dnl and possibly other versions of those OSes
379 dnl
380 if test -d /usr/inet6 -o -f /usr/include/netinet/ip6.h; then
381 ipv6type=$i
382 ipv6lib=inet6
383 ipv6libdir=/usr/inet6/lib
384 ipv6trylibc=yes;
385 CFLAGS="-I/usr/inet6/include $CFLAGS"
386 fi
387 ;;
388 toshiba)
389 AC_EGREP_CPP(yes,
390 [#include <sys/param.h>
391 #ifdef _TOSHIBA_INET6
392 yes
393 #endif],
394 [ipv6type=$i;
395 ipv6lib=inet6;
396 ipv6libdir=/usr/local/v6/lib])
397 ;;
398 v6d)
399 AC_EGREP_CPP(yes,
400 [#include </usr/local/v6/include/sys/v6config.h>
401 #ifdef __V6D__
402 yes
403 #endif],
404 [ipv6type=$i;
405 ipv6lib=v6;
406 ipv6libdir=/usr/local/v6/lib;
407 CFLAGS="-I/usr/local/v6/include $CFLAGS"])
408 ;;
409 zeta)
410 AC_EGREP_CPP(yes,
411 [#include <sys/param.h>
412 #ifdef _ZETA_MINAMI_INET6
413 yes
414 #endif],
415 [ipv6type=$i;
416 ipv6lib=inet6;
417 ipv6libdir=/usr/local/v6/lib])
418 ;;
419 esac
420 if test "$ipv6type" != "unknown"; then
421 break
422 fi
423 done
424 AC_MSG_RESULT($ipv6type)
425 fi
426
427 if test "$ipv6" = "yes" -a "$ipv6lib" != "none"; then
428 if test -d $ipv6libdir -a -f $ipv6libdir/lib$ipv6lib.a; then
429 LIBS="-L$ipv6libdir -l$ipv6lib $LIBS"
430 echo "You have $ipv6lib library, using it"
431 else
432 if test "$ipv6trylibc" = "yes"; then
433 echo "You do not have $ipv6lib library, using libc"
434 else
435 echo 'Fatal: no $ipv6lib library found. cannot continue.'
436 echo "You need to fetch lib$ipv6lib.a from appropriate"
437 echo 'ipv6 kit and compile beforehand.'
438 exit 1
439 fi
440 fi
441 fi
442
443 AC_REPLACE_FUNCS(strlcat strlcpy strdup strsep getservent getopt_long)
444 AC_CHECK_FUNCS(fork vfork)
445 AC_CHECK_FUNCS(setlinebuf)
446
447 #
448 # Make sure we have vsnprintf() and snprintf(); we require them.
449 #
450 AC_CHECK_FUNC(vsnprintf,,
451 AC_MSG_ERROR([vsnprintf() is required but wasn't found]))
452 AC_CHECK_FUNC(snprintf,,
453 AC_MSG_ERROR([snprintf() is required but wasn't found]))
454
455 #
456 # Define HAVE_NO_PRINTF_Z to make it possible to disable test cases that
457 # depend on %zu.
458 #
459 AC_MSG_CHECKING([whether printf(3) supports the z length modifier])
460 AC_RUN_IFELSE(
461 [
462 AC_LANG_SOURCE([[
463 #include <stdio.h>
464 #include <string.h>
465
466 int main()
467 {
468 char buf[100];
469 snprintf(buf, sizeof(buf), "%zu", sizeof(buf));
470 return strncmp(buf, "100", sizeof(buf)) ? 1 : 0;
471 }
472 ]])
473 ],
474 [
475 AC_MSG_RESULT(yes)
476 ],
477 [
478 AC_MSG_RESULT(no)
479 AC_DEFINE(HAVE_NO_PRINTF_Z, 1,
480 [Define to 1 if printf(3) does not support the z length modifier.])
481 ],
482 [
483 AC_MSG_RESULT(not while cross-compiling)
484 ]
485 )
486
487 AC_CHECK_LIB(rpc, main) dnl It's unclear why we might need -lrpc
488
489 dnl Some platforms may need -lnsl for getrpcbynumber.
490 AC_SEARCH_LIBS(getrpcbynumber, nsl,
491 AC_DEFINE(HAVE_GETRPCBYNUMBER, 1, [define if you have getrpcbynumber()]))
492
493 AC_LBL_LIBPCAP(V_PCAPDEP, V_INCLS)
494
495 #
496 # Check for these after AC_LBL_LIBPCAP, so we link with the appropriate
497 # libraries (e.g., "-lsocket -lnsl" on Solaris).
498 #
499 # You are in a twisty little maze of UN*Xes, all different.
500 # Some might not have ether_ntohost().
501 # Some might have it and declare it in <net/ethernet.h>.
502 # Some might have it and declare it in <netinet/ether.h>
503 # Some might have it and declare it in <sys/ethernet.h>.
504 # Some might have it and declare it in <arpa/inet.h>.
505 # Some might have it and declare it in <netinet/if_ether.h>.
506 # Some might have it and not declare it in any header file.
507 #
508 # Before you is a C compiler.
509 #
510 AC_CHECK_FUNCS(ether_ntohost, [
511 AC_CACHE_CHECK(for buggy ether_ntohost, ac_cv_buggy_ether_ntohost, [
512 AC_RUN_IFELSE([AC_LANG_SOURCE([[
513 #include <netdb.h>
514 #include <netinet/ether.h>
515 #include <stdlib.h>
516 #include <sys/types.h>
517 #include <sys/param.h>
518 #include <sys/socket.h>
519
520 int
521 main(int argc, char **argv)
522 {
523 u_char ea[6] = { 0xff, 0xff, 0xff, 0xff, 0xff };
524 char name[MAXHOSTNAMELEN];
525
526 ether_ntohost(name, (struct ether_addr *)ea);
527 exit(0);
528 }
529 ]])
530 ], [ac_cv_buggy_ether_ntohost=no],
531 [ac_cv_buggy_ether_ntohost=yes],
532 [ac_cv_buggy_ether_ntohost="not while cross-compiling"])])
533 if test "$ac_cv_buggy_ether_ntohost" = "no"; then
534 AC_DEFINE(USE_ETHER_NTOHOST, 1,
535 [define if you have ether_ntohost() and it works])
536 fi
537 ])
538 if test "$ac_cv_func_ether_ntohost" = yes -a \
539 "$ac_cv_buggy_ether_ntohost" = "no"; then
540 #
541 # OK, we have ether_ntohost(). Is it declared in <net/ethernet.h>?
542 #
543 # This test fails if we don't have <net/ethernet.h> or if we do
544 # but it doesn't declare ether_ntohost().
545 #
546 AC_CHECK_DECL(ether_ntohost,
547 [
548 AC_DEFINE(NET_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
549 [Define to 1 if net/ethernet.h declares `ether_ntohost'])
550 ],,
551 [
552 #include <net/ethernet.h>
553 ])
554 #
555 # Did that succeed?
556 #
557 if test "$ac_cv_have_decl_ether_ntohost" != yes; then
558 #
559 # No, how about <netinet/ether.h>, as on Linux?
560 #
561 # This test fails if we don't have <netinet/ether.h>
562 # or if we do but it doesn't declare ether_ntohost().
563 #
564 # Unset ac_cv_have_decl_ether_ntohost so we don't
565 # treat the previous failure as a cached value and
566 # suppress the next test.
567 #
568 unset ac_cv_have_decl_ether_ntohost
569 AC_CHECK_DECL(ether_ntohost,
570 [
571 AC_DEFINE(NETINET_ETHER_H_DECLARES_ETHER_NTOHOST,,
572 [Define to 1 if netinet/ether.h declares `ether_ntohost'])
573 ],,
574 [
575 #include <netinet/ether.h>
576 ])
577 fi
578 #
579 # Did that succeed?
580 #
581 if test "$ac_cv_have_decl_ether_ntohost" != yes; then
582 #
583 # No, how about <sys/ethernet.h>, as on Solaris 10
584 # and later?
585 #
586 # This test fails if we don't have <sys/ethernet.h>
587 # or if we do but it doesn't declare ether_ntohost().
588 #
589 # Unset ac_cv_have_decl_ether_ntohost so we don't
590 # treat the previous failure as a cached value and
591 # suppress the next test.
592 #
593 unset ac_cv_have_decl_ether_ntohost
594 AC_CHECK_DECL(ether_ntohost,
595 [
596 AC_DEFINE(SYS_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
597 [Define to 1 if sys/ethernet.h declares `ether_ntohost'])
598 ],,
599 [
600 #include <sys/ethernet.h>
601 ])
602 fi
603 #
604 # Did that succeed?
605 #
606 if test "$ac_cv_have_decl_ether_ntohost" != yes; then
607 #
608 # No, how about <arpa/inet.h>, as in AIX?
609 #
610 # This test fails if we don't have <arpa/inet.h>
611 # (if we have ether_ntohost(), we should have
612 # networking, and if we have networking, we should
613 # have <arpa/inet.h>) or if we do but it doesn't
614 # declare ether_ntohost().
615 #
616 # Unset ac_cv_have_decl_ether_ntohost so we don't
617 # treat the previous failure as a cached value and
618 # suppress the next test.
619 #
620 unset ac_cv_have_decl_ether_ntohost
621 AC_CHECK_DECL(ether_ntohost,
622 [
623 AC_DEFINE(ARPA_INET_H_DECLARES_ETHER_NTOHOST,,
624 [Define to 1 if arpa/inet.h declares `ether_ntohost'])
625 ],,
626 [
627 #include <arpa/inet.h>
628 ])
629 fi
630 #
631 # Did that succeed?
632 #
633 if test "$ac_cv_have_decl_ether_ntohost" != yes; then
634 #
635 # No, how about <netinet/if_ether.h>?
636 # On some platforms, it requires <net/if.h> and
637 # <netinet/in.h>, and we always include it with
638 # both of them, so test it with both of them.
639 #
640 # This test fails if we don't have <netinet/if_ether.h>
641 # and the headers we include before it, or if we do but
642 # <netinet/if_ether.h> doesn't declare ether_hostton().
643 #
644 # Unset ac_cv_have_decl_ether_ntohost so we don't
645 # treat the previous failure as a cached value and
646 # suppress the next test.
647 #
648 unset ac_cv_have_decl_ether_ntohost
649 AC_CHECK_DECL(ether_ntohost,
650 [
651 AC_DEFINE(NETINET_IF_ETHER_H_DECLARES_ETHER_NTOHOST,,
652 [Define to 1 if netinet/if_ether.h declares `ether_ntohost'])
653 ],,
654 [
655 #include <sys/types.h>
656 #include <sys/socket.h>
657 #include <net/if.h>
658 #include <netinet/in.h>
659 #include <netinet/if_ether.h>
660 ])
661 fi
662 #
663 # After all that, is ether_ntohost() declared?
664 #
665 if test "$ac_cv_have_decl_ether_ntohost" = yes; then
666 #
667 # Yes.
668 #
669 AC_DEFINE(HAVE_DECL_ETHER_NTOHOST, 1,
670 [Define to 1 if you have the declaration of `ether_ntohost'])
671 else
672 #
673 # No, we'll have to declare it ourselves.
674 # Do we have "struct ether_addr" if we include
675 # <netinet/if_ether.h>?
676 #
677 AC_CHECK_TYPES(struct ether_addr,,,
678 [
679 #include <sys/types.h>
680 #include <sys/socket.h>
681 #include <net/if.h>
682 #include <netinet/in.h>
683 #include <netinet/if_ether.h>
684 ])
685 fi
686 fi
687
688 dnl
689 dnl Check for "pcap_list_datalinks()" and use a substitute version if
690 dnl it's not present. If it is present, check for "pcap_free_datalinks()";
691 dnl if it's not present, we don't replace it for now. (We could do so
692 dnl on UN*X, but not on Windows, where hilarity ensues if a program
693 dnl built with one version of the MSVC support library tries to free
694 dnl something allocated by a library built with another version of
695 dnl the MSVC support library.)
696 dnl
697 AC_CHECK_FUNC(pcap_list_datalinks,
698 [
699 AC_DEFINE(HAVE_PCAP_LIST_DATALINKS, 1,
700 [define if libpcap has pcap_list_datalinks()])
701 AC_CHECK_FUNCS(pcap_free_datalinks)
702 ],
703 [
704 AC_LIBOBJ(datalinks)
705 ])
706
707 dnl
708 dnl Check for "pcap_datalink_name_to_val()", and use a substitute
709 dnl version if it's not present. If it is present, check for
710 dnl "pcap_datalink_val_to_description()", and if we don't have it,
711 dnl use a substitute version.
712 dnl
713 AC_CHECK_FUNC(pcap_datalink_name_to_val,
714 [
715 AC_DEFINE(HAVE_PCAP_DATALINK_NAME_TO_VAL, 1,
716 [define if libpcap has pcap_datalink_name_to_val()])
717 AC_CHECK_FUNC(pcap_datalink_val_to_description,
718 AC_DEFINE(HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION, 1,
719 [define if libpcap has pcap_datalink_val_to_description()]),
720 [
721 AC_LIBOBJ(dlnames)
722 ])
723 ],
724 [
725 AC_LIBOBJ(dlnames)
726 ])
727
728 dnl
729 dnl Check for "pcap_set_datalink()"; you can't substitute for it if
730 dnl it's absent (it has hooks into libpcap), so just define the
731 dnl HAVE_ value if it's there.
732 dnl
733 AC_CHECK_FUNCS(pcap_set_datalink)
734
735 dnl
736 dnl Check for "pcap_breakloop()"; you can't substitute for it if
737 dnl it's absent (it has hooks into the live capture routines),
738 dnl so just define the HAVE_ value if it's there.
739 dnl
740 AC_CHECK_FUNCS(pcap_breakloop)
741
742 #
743 # Do we have the new open API? Check for pcap_create, and assume that,
744 # if we do, we also have pcap_activate() and the other new routines
745 # introduced in libpcap 1.0.0.
746 #
747 AC_CHECK_FUNCS(pcap_create)
748 if test $ac_cv_func_pcap_create = "yes" ; then
749 #
750 # OK, do we have pcap_set_tstamp_type? If so, assume we have
751 # pcap_list_tstamp_types and pcap_free_tstamp_types as well.
752 #
753 AC_CHECK_FUNCS(pcap_set_tstamp_type)
754 #
755 # And do we have pcap_set_tstamp_precision? If so, we assume
756 # we also have pcap_open_offline_with_tstamp_precision.
757 #
758 AC_CHECK_FUNCS(pcap_set_tstamp_precision)
759 fi
760
761 #
762 # Check for a miscellaneous collection of functions which we use
763 # if we have them.
764 #
765 AC_CHECK_FUNCS(pcap_findalldevs)
766 if test $ac_cv_func_pcap_findalldevs = "yes" ; then
767 dnl Check for libpcap having pcap_findalldevs() but the pcap.h header
768 dnl not having pcap_if_t; some versions of Mac OS X shipped with pcap.h
769 dnl from 0.6 and libpcap 0.8, so that libpcap had pcap_findalldevs but
770 dnl pcap.h didn't have pcap_if_t.
771 savedcppflags="$CPPFLAGS"
772 CPPFLAGS="$CPPFLAGS $V_INCLS"
773 AC_CHECK_TYPES(pcap_if_t, , , [#include <pcap.h>])
774 CPPFLAGS="$savedcppflags"
775 fi
776 AC_CHECK_FUNCS(pcap_dump_flush pcap_lib_version)
777 if test $ac_cv_func_pcap_lib_version = "no" ; then
778 AC_MSG_CHECKING(whether pcap_version is defined by libpcap)
779 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
780 extern char pcap_version[];
781
782 return (int)pcap_version;
783 ]])
784 ],
785 [ac_lbl_cv_pcap_version_defined=yes],
786 [ac_lbl_cv_pcap_version_defined=no])
787 if test "$ac_lbl_cv_pcap_version_defined" = yes ; then
788 AC_MSG_RESULT(yes)
789 AC_DEFINE(HAVE_PCAP_VERSION, 1, [define if libpcap has pcap_version])
790 else
791 AC_MSG_RESULT(no)
792 fi
793 fi
794 AC_CHECK_FUNCS(pcap_setdirection pcap_set_immediate_mode pcap_dump_ftell64)
795 AC_CHECK_FUNCS(pcap_open pcap_findalldevs_ex)
796 AC_REPLACE_FUNCS(pcap_dump_ftell)
797
798 #
799 # Check for special debugging functions
800 #
801 AC_CHECK_FUNCS(pcap_set_parser_debug)
802 if test "$ac_cv_func_pcap_set_parser_debug" = "no" ; then
803 #
804 # OK, we don't have pcap_set_parser_debug() to set the libpcap
805 # filter expression parser debug flag; can we directly set the
806 # flag?
807 AC_MSG_CHECKING(whether pcap_debug is defined by libpcap)
808 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
809 extern int pcap_debug;
810
811 return pcap_debug;
812 ]])
813 ],
814 [ac_lbl_cv_pcap_debug_defined=yes],
815 [ac_lbl_cv_pcap_debug_defined=no])
816 if test "$ac_lbl_cv_pcap_debug_defined" = yes ; then
817 AC_MSG_RESULT(yes)
818 AC_DEFINE(HAVE_PCAP_DEBUG, 1, [define if libpcap has pcap_debug])
819 else
820 AC_MSG_RESULT(no)
821 #
822 # OK, what about "yydebug"?
823 #
824 AC_MSG_CHECKING(whether yydebug is defined by libpcap)
825 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
826 extern int yydebug;
827
828 return yydebug;
829 ]])
830 ],
831 [ac_lbl_cv_yydebug_defined=yes],
832 [ac_lbl_cv_yydebug_defined=no])
833 if test "$ac_lbl_cv_yydebug_defined" = yes ; then
834 AC_MSG_RESULT(yes)
835 AC_DEFINE(HAVE_YYDEBUG, 1, [define if libpcap has yydebug])
836 else
837 AC_MSG_RESULT(no)
838 fi
839 fi
840 fi
841 AC_CHECK_FUNCS(pcap_set_optimizer_debug)
842 AC_REPLACE_FUNCS(bpf_dump) dnl moved to libpcap in 0.6
843
844 V_GROUP=0
845 if test -f /etc/group -a ! -z "`grep '^wheel:' /etc/group`" ; then
846 V_GROUP=wheel
847 fi
848 #
849 # Assume V7/BSD convention for man pages (file formats in section 5,
850 # miscellaneous info in section 7).
851 #
852 MAN_FILE_FORMATS=5
853 MAN_MISC_INFO=7
854 case "$host_os" in
855
856 aix*)
857 dnl Workaround to enable certain features
858 AC_DEFINE(_SUN,1,[define on AIX to get certain functions])
859 ;;
860
861 hpux*)
862 #
863 # Use System V conventions for man pages.
864 #
865 MAN_FILE_FORMATS=4
866 MAN_MISC_INFO=5
867 ;;
868
869 irix*)
870 V_GROUP=sys
871
872 #
873 # Use System V conventions for man pages.
874 #
875 MAN_FILE_FORMATS=4
876 MAN_MISC_INFO=5
877 ;;
878
879 osf*)
880 V_GROUP=system
881
882 #
883 # Use System V conventions for man pages.
884 #
885 MAN_FILE_FORMATS=4
886 MAN_MISC_INFO=5
887 ;;
888
889 solaris*)
890 V_GROUP=sys
891
892 #
893 # Use System V conventions for man pages.
894 #
895 MAN_FILE_FORMATS=4
896 MAN_MISC_INFO=5
897 ;;
898 esac
899
900 if test -f /dev/bpf0 ; then
901 V_GROUP=bpf
902 fi
903
904 #
905 # Make sure we have a definition for C99's uintptr_t (regardless of
906 # whether the environment is a C99 environment or not).
907 #
908 AC_TYPE_UINTPTR_T
909
910 #
911 # Check whether we have pcap/pcap-inttypes.h.
912 # If we do, we use that to get the C99 types defined.
913 #
914 savedcppflags="$CPPFLAGS"
915 CPPFLAGS="$CPPFLAGS $V_INCLS"
916 AC_CHECK_HEADERS(pcap/pcap-inttypes.h)
917 CPPFLAGS="$savedcppflags"
918
919 #
920 # Define the old BSD specified-width types in terms of the C99 types;
921 # we may need them with libpcap include files.
922 #
923 AC_CHECK_TYPE([u_int8_t], ,
924 [AC_DEFINE([u_int8_t], [uint8_t],
925 [Define to `uint8_t' if u_int8_t not defined.])],
926 [AC_INCLUDES_DEFAULT
927 #include <sys/types.h>
928 ])
929 AC_CHECK_TYPE([u_int16_t], ,
930 [AC_DEFINE([u_int16_t], [uint16_t],
931 [Define to `uint16_t' if u_int16_t not defined.])],
932 [AC_INCLUDES_DEFAULT
933 #include <sys/types.h>
934 ])
935 AC_CHECK_TYPE([u_int32_t], ,
936 [AC_DEFINE([u_int32_t], [uint32_t],
937 [Define to `uint32_t' if u_int32_t not defined.])],
938 [AC_INCLUDES_DEFAULT
939 #include <sys/types.h>
940 ])
941 AC_CHECK_TYPE([u_int64_t], ,
942 [AC_DEFINE([u_int64_t], [uint64_t],
943 [Define to `uint64_t' if u_int64_t not defined.])],
944 [AC_INCLUDES_DEFAULT
945 #include <sys/types.h>
946 ])
947
948 AC_PROG_RANLIB
949 AC_CHECK_TOOL([AR], [ar])
950
951 AC_LBL_DEVEL(V_CCOPT)
952
953 # Check for OpenSSL/libressl libcrypto
954 AC_MSG_CHECKING(whether to use OpenSSL/libressl libcrypto)
955 # Specify location for both includes and libraries.
956 want_libcrypto=ifavailable
957 AC_ARG_WITH(crypto,
958 AS_HELP_STRING([--with-crypto]@<:@=DIR@:>@,
959 [use OpenSSL/libressl libcrypto (located in directory DIR, if specified) @<:@default=yes, if available@:>@]),
960 [
961 if test $withval = no
962 then
963 # User doesn't want to link with libcrypto.
964 want_libcrypto=no
965 AC_MSG_RESULT(no)
966 elif test $withval = yes
967 then
968 # User wants to link with libcrypto but hasn't specified
969 # a directory.
970 want_libcrypto=yes
971 AC_MSG_RESULT(yes)
972 else
973 # User wants to link with libcrypto and has specified
974 # a directory, so use the provided value.
975 want_libcrypto=yes
976 libcrypto_root=$withval
977 AC_MSG_RESULT([yes, using the version installed in $withval])
978
979 #
980 # Put the subdirectories of the libcrypto root directory
981 # at the front of the header and library search path.
982 #
983 CFLAGS="-I$withval/include $CFLAGS"
984 LIBS="-L$withval/lib $LIBS"
985 fi
986 ],[
987 #
988 # Use libcrypto if it's present, otherwise don't; no directory
989 # was specified.
990 #
991 want_libcrypto=ifavailable
992 AC_MSG_RESULT([yes, if available])
993 ])
994 if test "$want_libcrypto" != "no"; then
995 #
996 # Don't check for libcrypto unless we have its headers;
997 # Apple, bless their pointy little heads, apparently ship
998 # libcrypto as a library, but not the header files, in
999 # El Capitan, probably because they don't want you writing
1000 # nasty portable code that could run on other UN*Xes, they
1001 # want you writing code that uses their Shiny New Crypto
1002 # Library and that only runs on macOS.
1003 #
1004 AC_CHECK_HEADER(openssl/crypto.h,
1005 [
1006 AC_CHECK_LIB(crypto, DES_cbc_encrypt)
1007 if test "$ac_cv_lib_crypto_DES_cbc_encrypt" = "yes"; then
1008 AC_CHECK_HEADERS(openssl/evp.h)
1009 #
1010 # OK, then:
1011 #
1012 # 1) do we have EVP_CIPHER_CTX_new?
1013 # If so, we use it to allocate an
1014 # EVP_CIPHER_CTX, as EVP_CIPHER_CTX may be
1015 # opaque; otherwise, we allocate it ourselves.
1016 #
1017 # 2) do we have EVP_DecryptInit_ex()?
1018 # If so, we use it, because we need to be
1019 # able to make two "initialize the cipher"
1020 # calls, one with the cipher and key, and
1021 # one with the IV, and, as of OpenSSL 1.1,
1022 # You Can't Do That with EVP_DecryptInit(),
1023 # because a call to EVP_DecryptInit() will
1024 # unconditionally clear the context, and
1025 # if you don't supply a cipher, it'll
1026 # clear the cipher, rendering the context
1027 # unusable and causing a crash.
1028 #
1029 AC_CHECK_FUNCS(EVP_CIPHER_CTX_new EVP_DecryptInit_ex)
1030 fi
1031 ])
1032 fi
1033
1034 # Check for libcap-ng
1035 AC_MSG_CHECKING(whether to use libcap-ng)
1036 # Specify location for both includes and libraries.
1037 want_libcap_ng=ifavailable
1038 AC_ARG_WITH(cap_ng,
1039 AS_HELP_STRING([--with-cap-ng],
1040 [use libcap-ng @<:@default=yes, if available@:>@]),
1041 [
1042 if test $withval = no
1043 then
1044 want_libcap_ng=no
1045 AC_MSG_RESULT(no)
1046 elif test $withval = yes
1047 then
1048 want_libcap_ng=yes
1049 AC_MSG_RESULT(yes)
1050 fi
1051 ],[
1052 #
1053 # Use libcap-ng if it's present, otherwise don't.
1054 #
1055 want_libcap_ng=ifavailable
1056 AC_MSG_RESULT([yes, if available])
1057 ])
1058 if test "$want_libcap_ng" != "no"; then
1059 AC_CHECK_LIB(cap-ng, capng_change_id)
1060 AC_CHECK_HEADERS(cap-ng.h)
1061 fi
1062
1063 dnl
1064 dnl set additional include path if necessary
1065 if test "$missing_includes" = "yes"; then
1066 CPPFLAGS="$CPPFLAGS -I$srcdir/missing"
1067 V_INCLS="$V_INCLS -I$srcdir/missing"
1068 fi
1069
1070 AC_SUBST(V_CCOPT)
1071 AC_SUBST(V_DEFS)
1072 AC_SUBST(V_GROUP)
1073 AC_SUBST(V_INCLS)
1074 AC_SUBST(V_PCAPDEP)
1075 AC_SUBST(LOCALSRC)
1076 AC_SUBST(MAN_FILE_FORMATS)
1077 AC_SUBST(MAN_MISC_INFO)
1078
1079 AC_PROG_INSTALL
1080
1081 AC_CONFIG_HEADERS([config.h])
1082
1083 AC_CONFIG_COMMANDS([.devel],[[if test -f .devel; then
1084 echo timestamp > stamp-h
1085 cat $srcdir/Makefile-devel-adds >> Makefile
1086 make depend || exit 1
1087 fi]])
1088 AC_CONFIG_FILES([Makefile tcpdump.1])
1089 AC_OUTPUT
1090 exit 0
[mirror] the TCPdump network dissector