]> The Tcpdump Group git mirrors - tcpdump/blob - aclocal.m4
projects / tcpdump / blob
summary | shortlog | log | commit | commitdiff | tree
history | raw | HEAD
Merge remote-tracking branch 'mcrhub/master'
[tcpdump] / aclocal.m4
1 dnl @(#) $Header: /tcpdump/master/tcpdump/aclocal.m4,v 1.116 2008-09-25 21:45:50 guy Exp $ (LBL)
2 dnl
3 dnl Copyright (c) 1995, 1996, 1997, 1998
4 dnl The Regents of the University of California. All rights reserved.
5 dnl
6 dnl Redistribution and use in source and binary forms, with or without
7 dnl modification, are permitted provided that: (1) source code distributions
8 dnl retain the above copyright notice and this paragraph in its entirety, (2)
9 dnl distributions including binary code include the above copyright notice and
10 dnl this paragraph in its entirety in the documentation or other materials
11 dnl provided with the distribution, and (3) all advertising materials mentioning
12 dnl features or use of this software display the following acknowledgement:
13 dnl ``This product includes software developed by the University of California,
14 dnl Lawrence Berkeley Laboratory and its contributors.'' Neither the name of
15 dnl the University nor the names of its contributors may be used to endorse
16 dnl or promote products derived from this software without specific prior
17 dnl written permission.
18 dnl THIS SOFTWARE IS PROVIDED ``AS IS'' AND WITHOUT ANY EXPRESS OR IMPLIED
19 dnl WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED WARRANTIES OF
20 dnl MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE.
21 dnl
22 dnl LBL autoconf macros
23 dnl
24
25 dnl
26 dnl Do whatever AC_LBL_C_INIT work is necessary before using AC_PROG_CC.
27 dnl
28 dnl It appears that newer versions of autoconf (2.64 and later) will,
29 dnl if you use AC_TRY_COMPILE in a macro, stick AC_PROG_CC at the
30 dnl beginning of the macro, even if the macro itself calls AC_PROG_CC.
31 dnl See the "Prerequisite Macros" and "Expanded Before Required" sections
32 dnl in the Autoconf documentation.
33 dnl
34 dnl This causes a steaming heap of fail in our case, as we were, in
35 dnl AC_LBL_C_INIT, doing the tests we now do in AC_LBL_C_INIT_BEFORE_CC,
36 dnl calling AC_PROG_CC, and then doing the tests we now do in
37 dnl AC_LBL_C_INIT. Now, we run AC_LBL_C_INIT_BEFORE_CC, AC_PROG_CC,
38 dnl and AC_LBL_C_INIT at the top level.
39 dnl
40 AC_DEFUN(AC_LBL_C_INIT_BEFORE_CC,
41 [AC_PREREQ(2.50)
42 AC_BEFORE([$0], [AC_LBL_C_INIT])
43 AC_BEFORE([$0], [AC_PROG_CC])
44 AC_BEFORE([$0], [AC_LBL_FIXINCLUDES])
45 AC_BEFORE([$0], [AC_LBL_DEVEL])
46 AC_ARG_WITH(gcc, [ --without-gcc don't use gcc])
47 $1="-O"
48 $2=""
49 if test "${srcdir}" != "." ; then
50 $2="-I$srcdir"
51 fi
52 if test "${CFLAGS+set}" = set; then
53 LBL_CFLAGS="$CFLAGS"
54 fi
55 if test -z "$CC" ; then
56 case "$host_os" in
57
58 bsdi*)
59 AC_CHECK_PROG(SHLICC2, shlicc2, yes, no)
60 if test $SHLICC2 = yes ; then
61 CC=shlicc2
62 export CC
63 fi
64 ;;
65 esac
66 fi
67 if test -z "$CC" -a "$with_gcc" = no ; then
68 CC=cc
69 export CC
70 fi
71 ])
72
73 dnl
74 dnl Determine which compiler we're using (cc or gcc)
75 dnl If using gcc, determine the version number
76 dnl If using cc, require that it support ansi prototypes
77 dnl If using gcc, use -O2 (otherwise use -O)
78 dnl If using cc, explicitly specify /usr/local/include
79 dnl
80 dnl usage:
81 dnl
82 dnl AC_LBL_C_INIT(copt, incls)
83 dnl
84 dnl results:
85 dnl
86 dnl $1 (copt set)
87 dnl $2 (incls set)
88 dnl CC
89 dnl LDFLAGS
90 dnl ac_cv_lbl_gcc_vers
91 dnl LBL_CFLAGS
92 dnl
93 AC_DEFUN(AC_LBL_C_INIT,
94 [AC_PREREQ(2.50)
95 AC_BEFORE([$0], [AC_LBL_FIXINCLUDES])
96 AC_BEFORE([$0], [AC_LBL_DEVEL])
97 AC_BEFORE([$0], [AC_LBL_SHLIBS_INIT])
98 if test "$GCC" = yes ; then
99 if test "$SHLICC2" = yes ; then
100 ac_cv_lbl_gcc_vers=2
101 $1="-O2"
102 else
103 AC_MSG_CHECKING(gcc version)
104 AC_CACHE_VAL(ac_cv_lbl_gcc_vers,
105 ac_cv_lbl_gcc_vers=`$CC -v 2>&1 | \
106 sed -e '/^gcc version /!d' \
107 -e 's/^gcc version //' \
108 -e 's/ .*//' -e 's/^[[[^0-9]]]*//' \
109 -e 's/\..*//'`)
110 AC_MSG_RESULT($ac_cv_lbl_gcc_vers)
111 if test $ac_cv_lbl_gcc_vers -gt 1 ; then
112 $1="-O2"
113 fi
114 fi
115 else
116 $2="$$2 -I/usr/local/include"
117 LDFLAGS="$LDFLAGS -L/usr/local/lib"
118
119 case "$host_os" in
120
121 hpux*)
122 #
123 # HP C, which is what we presume we're using, doesn't
124 # exit with a non-zero exit status if we hand it an
125 # invalid -W flag, can't be forced to do so even with
126 # +We, and doesn't handle GCC-style -W flags, so we
127 # don't want to try using GCC-style -W flags.
128 #
129 ac_lbl_cc_dont_try_gcc_dashW=yes
130 ;;
131
132 irix*)
133 #
134 # MIPS C, which is what we presume we're using, doesn't
135 # necessarily exit with a non-zero exit status if we
136 # hand it an invalid -W flag, can't be forced to do
137 # so, and doesn't handle GCC-style -W flags, so we
138 # don't want to try using GCC-style -W flags.
139 #
140 ac_lbl_cc_dont_try_gcc_dashW=yes
141 $1="$$1 -xansi -signed -O"
142 ;;
143
144 osf*)
145 #
146 # Presumed to be DEC OSF/1, Digital UNIX, or
147 # Tru64 UNIX.
148 #
149 # The DEC C compiler, which is what we presume we're
150 # using, doesn't exit with a non-zero exit status if we
151 # hand it an invalid -W flag, can't be forced to do
152 # so, and doesn't handle GCC-style -W flags, so we
153 # don't want to try using GCC-style -W flags.
154 #
155 ac_lbl_cc_dont_try_gcc_dashW=yes
156 $1="$$1 -O"
157 ;;
158
159 ultrix*)
160 AC_MSG_CHECKING(that Ultrix $CC hacks const in prototypes)
161 AC_CACHE_VAL(ac_cv_lbl_cc_const_proto,
162 AC_TRY_COMPILE(
163 [#include <sys/types.h>],
164 [struct a { int b; };
165 void c(const struct a *)],
166 ac_cv_lbl_cc_const_proto=yes,
167 ac_cv_lbl_cc_const_proto=no))
168 AC_MSG_RESULT($ac_cv_lbl_cc_const_proto)
169 if test $ac_cv_lbl_cc_const_proto = no ; then
170 AC_DEFINE(const,[],
171 [to handle Ultrix compilers that don't support const in prototypes])
172 fi
173 ;;
174 esac
175 fi
176 ])
177
178 dnl
179 dnl Check whether, if you pass an unknown warning option to the
180 dnl compiler, it fails or just prints a warning message and succeeds.
181 dnl Set ac_lbl_unknown_warning_option_error to the appropriate flag
182 dnl to force an error if it would otherwise just print a warning message
183 dnl and succeed.
184 dnl
185 AC_DEFUN(AC_LBL_CHECK_UNKNOWN_WARNING_OPTION_ERROR,
186 [
187 AC_MSG_CHECKING([whether the compiler fails when given an unknown warning option])
188 save_CFLAGS="$CFLAGS"
189 CFLAGS="$CFLAGS -Wxyzzy-this-will-never-succeed-xyzzy"
190 AC_TRY_COMPILE(
191 [],
192 [return 0],
193 [
194 AC_MSG_RESULT([no])
195 #
196 # We're assuming this is clang, where
197 # -Werror=unknown-warning-option is the appropriate
198 # option to force the compiler to fail.
199 #
200 ac_lbl_unknown_warning_option_error="-Werror=unknown-warning-option"
201 ],
202 [
203 AC_MSG_RESULT([yes])
204 ])
205 CFLAGS="$save_CFLAGS"
206 ])
207
208 dnl
209 dnl Check whether the compiler option specified as the second argument
210 dnl is supported by the compiler and, if so, add it to the macro
211 dnl specified as the first argument
212 dnl
213 AC_DEFUN(AC_LBL_CHECK_COMPILER_OPT,
214 [
215 AC_MSG_CHECKING([whether the compiler supports the $2 option])
216 save_CFLAGS="$CFLAGS"
217 CFLAGS="$CFLAGS $ac_lbl_unknown_warning_option_error $2"
218 AC_TRY_COMPILE(
219 [],
220 [return 0],
221 [
222 AC_MSG_RESULT([yes])
223 CFLAGS="$save_CFLAGS"
224 $1="$$1 $2"
225 ],
226 [
227 AC_MSG_RESULT([no])
228 CFLAGS="$save_CFLAGS"
229 ])
230 ])
231
232 dnl
233 dnl Check whether the compiler supports an option to generate
234 dnl Makefile-style dependency lines
235 dnl
236 dnl GCC uses -M for this. Non-GCC compilers that support this
237 dnl use a variety of flags, including but not limited to -M.
238 dnl
239 dnl We test whether the flag in question is supported, as older
240 dnl versions of compilers might not support it.
241 dnl
242 dnl We don't try all the possible flags, just in case some flag means
243 dnl "generate dependencies" on one compiler but means something else
244 dnl on another compiler.
245 dnl
246 dnl Most compilers that support this send the output to the standard
247 dnl output by default. IBM's XLC, however, supports -M but sends
248 dnl the output to {sourcefile-basename}.u, and AIX has no /dev/stdout
249 dnl to work around that, so we don't bother with XLC.
250 dnl
251 AC_DEFUN(AC_LBL_CHECK_DEPENDENCY_GENERATION_OPT,
252 [
253 AC_MSG_CHECKING([whether the compiler supports generating dependencies])
254 if test "$GCC" = yes ; then
255 #
256 # GCC, or a compiler deemed to be GCC by AC_PROG_CC (even
257 # though it's not); we assume that, in this case, the flag
258 # would be -M.
259 #
260 ac_lbl_dependency_flag="-M"
261 else
262 #
263 # Not GCC or a compiler deemed to be GCC; what platform is
264 # this? (We're assuming that if the compiler isn't GCC
265 # it's the compiler from the vendor of the OS; that won't
266 # necessarily be true for x86 platforms, where it might be
267 # the Intel C compiler.)
268 #
269 case "$host_os" in
270
271 irix*|osf*|darwin*)
272 #
273 # MIPS C for IRIX, DEC C, and clang all use -M.
274 #
275 ac_lbl_dependency_flag="-M"
276 ;;
277
278 solaris*)
279 #
280 # Sun C uses -xM.
281 #
282 ac_lbl_dependency_flag="-xM"
283 ;;
284
285 hpux*)
286 #
287 # HP's older C compilers don't support this.
288 # HP's newer C compilers support this with
289 # either +M or +Make; the older compilers
290 # interpret +M as something completely
291 # different, so we use +Make so we don't
292 # think it works with the older compilers.
293 #
294 ac_lbl_dependency_flag="+Make"
295 ;;
296
297 *)
298 #
299 # Not one of the above; assume no support for
300 # generating dependencies.
301 #
302 ac_lbl_dependency_flag=""
303 ;;
304 esac
305 fi
306
307 #
308 # Is ac_lbl_dependency_flag defined and, if so, does the compiler
309 # complain about it?
310 #
311 # Note: clang doesn't seem to exit with an error status when handed
312 # an unknown non-warning error, even if you pass it
313 # -Werror=unknown-warning-option. However, it always supports
314 # -M, so the fact that this test always succeeds with clang
315 # isn't an issue.
316 #
317 if test ! -z "$ac_lbl_dependency_flag"; then
318 AC_LANG_CONFTEST(
319 [AC_LANG_SOURCE([[int main(void) { return 0; }]])])
320 echo "$CC" $ac_lbl_dependency_flag conftest.c >&5
321 if "$CC" $ac_lbl_dependency_flag conftest.c >/dev/null 2>&1; then
322 AC_MSG_RESULT([yes, with $ac_lbl_dependency_flag])
323 DEPENDENCY_CFLAG="$ac_lbl_dependency_flag"
324 MKDEP='${srcdir}/mkdep'
325 else
326 AC_MSG_RESULT([no])
327 #
328 # We can't run mkdep, so have "make depend" do
329 # nothing.
330 #
331 MKDEP=:
332 fi
333 rm -rf conftest*
334 else
335 AC_MSG_RESULT([no])
336 #
337 # We can't run mkdep, so have "make depend" do
338 # nothing.
339 #
340 MKDEP=:
341 fi
342 AC_SUBST(DEPENDENCY_CFLAG)
343 AC_SUBST(MKDEP)
344 ])
345
346 #
347 # Try compiling a sample of the type of code that appears in
348 # gencode.c with "inline", "__inline__", and "__inline".
349 #
350 # Autoconf's AC_C_INLINE, at least in autoconf 2.13, isn't good enough,
351 # as it just tests whether a function returning "int" can be inlined;
352 # at least some versions of HP's C compiler can inline that, but can't
353 # inline a function that returns a struct pointer.
354 #
355 # Make sure we use the V_CCOPT flags, because some of those might
356 # disable inlining.
357 #
358 AC_DEFUN(AC_LBL_C_INLINE,
359 [AC_MSG_CHECKING(for inline)
360 save_CFLAGS="$CFLAGS"
361 CFLAGS="$V_CCOPT"
362 AC_CACHE_VAL(ac_cv_lbl_inline, [
363 ac_cv_lbl_inline=""
364 ac_lbl_cc_inline=no
365 for ac_lbl_inline in inline __inline__ __inline
366 do
367 AC_TRY_COMPILE(
368 [#define inline $ac_lbl_inline
369 static inline struct iltest *foo(void);
370 struct iltest {
371 int iltest1;
372 int iltest2;
373 };
374
375 static inline struct iltest *
376 foo()
377 {
378 static struct iltest xxx;
379
380 return &xxx;
381 }],,ac_lbl_cc_inline=yes,)
382 if test "$ac_lbl_cc_inline" = yes ; then
383 break;
384 fi
385 done
386 if test "$ac_lbl_cc_inline" = yes ; then
387 ac_cv_lbl_inline=$ac_lbl_inline
388 fi])
389 CFLAGS="$save_CFLAGS"
390 if test ! -z "$ac_cv_lbl_inline" ; then
391 AC_MSG_RESULT($ac_cv_lbl_inline)
392 else
393 AC_MSG_RESULT(no)
394 fi
395 AC_DEFINE_UNQUOTED(inline, $ac_cv_lbl_inline, [Define as token for inline if inlining supported])])
396
397 dnl
398 dnl Use pfopen.c if available and pfopen() not in standard libraries
399 dnl Require libpcap
400 dnl Look for libpcap in ..
401 dnl Use the installed libpcap if there is no local version
402 dnl
403 dnl usage:
404 dnl
405 dnl AC_LBL_LIBPCAP(pcapdep, incls)
406 dnl
407 dnl results:
408 dnl
409 dnl $1 (pcapdep set)
410 dnl $2 (incls appended)
411 dnl LIBS
412 dnl LBL_LIBS
413 dnl
414 AC_DEFUN(AC_LBL_LIBPCAP,
415 [AC_REQUIRE([AC_LBL_LIBRARY_NET])
416 dnl
417 dnl save a copy before locating libpcap.a
418 dnl
419 LBL_LIBS="$LIBS"
420 pfopen=/usr/examples/packetfilter/pfopen.c
421 if test -f $pfopen ; then
422 AC_CHECK_FUNCS(pfopen)
423 if test $ac_cv_func_pfopen = "no" ; then
424 AC_MSG_RESULT(Using $pfopen)
425 LIBS="$LIBS $pfopen"
426 fi
427 fi
428 AC_MSG_CHECKING(for local pcap library)
429 libpcap=FAIL
430 lastdir=FAIL
431 places=`ls $srcdir/.. | sed -e 's,/$,,' -e "s,^,$srcdir/../," | \
432 egrep '/libpcap-[[0-9]]+\.[[0-9]]+(\.[[0-9]]*)?([[ab]][[0-9]]*|-PRE-GIT)?$'`
433 for dir in $places $srcdir/../libpcap $srcdir/libpcap ; do
434 basedir=`echo $dir | sed -e 's/[[ab]][[0-9]]*$//' | \
435 sed -e 's/-PRE-GIT$//' `
436 if test $lastdir = $basedir ; then
437 dnl skip alphas when an actual release is present
438 continue;
439 fi
440 lastdir=$dir
441 if test -r $dir/libpcap.a ; then
442 libpcap=$dir/libpcap.a
443 d=$dir
444 dnl continue and select the last one that exists
445 fi
446 done
447 if test $libpcap = FAIL ; then
448 AC_MSG_RESULT(not found)
449
450 #
451 # Look for pcap-config.
452 #
453 AC_PATH_TOOL(PCAP_CONFIG, pcap-config)
454 if test -n "$PCAP_CONFIG" ; then
455 #
456 # Found - use it to get the include flags for
457 # libpcap and the flags to link with libpcap.
458 #
459 # Please read section 11.6 "Shell Substitutions"
460 # in the autoconf manual before doing anything
461 # to this that involves quoting. Especially note
462 # the statement "There is just no portable way to use
463 # double-quoted strings inside double-quoted back-quoted
464 # expressions (pfew!)."
465 #
466 cflags=`"$PCAP_CONFIG" --cflags`
467 $2="$cflags $$2"
468 libpcap=`"$PCAP_CONFIG" --libs`
469 else
470 #
471 # Not found; look for pcap.
472 #
473 AC_CHECK_LIB(pcap, main, libpcap="-lpcap")
474 if test $libpcap = FAIL ; then
475 AC_MSG_ERROR(see the INSTALL doc for more info)
476 fi
477 dnl
478 dnl Some versions of Red Hat Linux put "pcap.h" in
479 dnl "/usr/include/pcap"; had the LBL folks done so,
480 dnl that would have been a good idea, but for
481 dnl the Red Hat folks to do so just breaks source
482 dnl compatibility with other systems.
483 dnl
484 dnl We work around this by assuming that, as we didn't
485 dnl find a local libpcap, libpcap is in /usr/lib or
486 dnl /usr/local/lib and that the corresponding header
487 dnl file is under one of those directories; if we don't
488 dnl find it in either of those directories, we check to
489 dnl see if it's in a "pcap" subdirectory of them and,
490 dnl if so, add that subdirectory to the "-I" list.
491 dnl
492 dnl (We now also put pcap.h in /usr/include/pcap, but we
493 dnl leave behind a /usr/include/pcap.h that includes it,
494 dnl so you can still just include <pcap.h>.)
495 dnl
496 AC_MSG_CHECKING(for extraneous pcap header directories)
497 if test \( ! -r /usr/local/include/pcap.h \) -a \
498 \( ! -r /usr/include/pcap.h \); then
499 if test -r /usr/local/include/pcap/pcap.h; then
500 d="/usr/local/include/pcap"
501 elif test -r /usr/include/pcap/pcap.h; then
502 d="/usr/include/pcap"
503 fi
504 fi
505 if test -z "$d" ; then
506 AC_MSG_RESULT(not found)
507 else
508 $2="-I$d $$2"
509 AC_MSG_RESULT(found -- -I$d added)
510 fi
511 fi
512 else
513 $1=$libpcap
514 places=`ls $srcdir/.. | sed -e 's,/$,,' -e "s,^,$srcdir/../," | \
515 egrep '/libpcap-[[0-9]]*.[[0-9]]*(.[[0-9]]*)?([[ab]][[0-9]]*)?$'`
516 if test -r $d/pcap.h; then
517 $2="-I$d $$2"
518 elif test -r $places/pcap.h; then
519 $2="-I$places $$2"
520 else
521 AC_MSG_ERROR(cannot find pcap.h, see INSTALL)
522 fi
523 AC_MSG_RESULT($libpcap)
524 AC_PATH_PROG(PCAP_CONFIG, pcap-config,, $d)
525 if test -n "$PCAP_CONFIG"; then
526 #
527 # The libpcap directory has a pcap-config script.
528 # Use it to get any additioal libraries needed
529 # to link with the libpcap archive library in
530 # that directory.
531 #
532 # Please read section 11.6 "Shell Substitutions"
533 # in the autoconf manual before doing anything
534 # to this that involves quoting. Especially note
535 # the statement "There is just no portable way to use
536 # double-quoted strings inside double-quoted back-quoted
537 # expressions (pfew!)."
538 #
539 additional_libs=`"$PCAP_CONFIG" --additional-libs --static`
540 libpcap="$libpcap $additional_libs"
541 fi
542 fi
543 LIBS="$libpcap $LIBS"
544 if ! test -n "$PCAP_CONFIG" ; then
545 #
546 # We don't have pcap-config; find out any additional link flags
547 # we need. (If we have pcap-config, we assume it tells us what
548 # we need.)
549 #
550 case "$host_os" in
551
552 aix*)
553 #
554 # If libpcap is DLPI-based, we have to use /lib/pse.exp if
555 # present, as we use the STREAMS routines.
556 #
557 # (XXX - true only if we're linking with a static libpcap?)
558 #
559 pseexe="/lib/pse.exp"
560 AC_MSG_CHECKING(for $pseexe)
561 if test -f $pseexe ; then
562 AC_MSG_RESULT(yes)
563 LIBS="$LIBS -I:$pseexe"
564 fi
565
566 #
567 # If libpcap is BPF-based, we need "-lodm" and "-lcfg", as
568 # we use them to load the BPF module.
569 #
570 # (XXX - true only if we're linking with a static libpcap?)
571 #
572 LIBS="$LIBS -lodm -lcfg"
573 ;;
574 esac
575 fi
576
577 dnl
578 dnl Check for "pcap_loop()", to make sure we found a working
579 dnl libpcap and have all the right other libraries with which
580 dnl to link. (Otherwise, the checks below will fail, not
581 dnl because the routines are missing from the library, but
582 dnl because we aren't linking properly with libpcap, and
583 dnl that will cause confusing errors at build time.)
584 dnl
585 AC_CHECK_FUNC(pcap_loop,,
586 [
587 AC_MSG_ERROR(
588 [Report this to tcpdump-workers@lists.tcpdump.org, and include the
589 config.log file in your report. If you have downloaded libpcap from
590 tcpdump.org, and built it yourself, please also include the config.log
591 file from the libpcap source directory, the Makefile from the libpcap
592 source directory, and the output of the make process for libpcap, as
593 this could be a problem with the libpcap that was built, and we will
594 not be able to determine why this is happening, and thus will not be
595 able to fix it, without that information, as we have not been able to
596 reproduce this problem ourselves.])
597 ])
598
599 dnl
600 dnl Check for "pcap_list_datalinks()", "pcap_set_datalink()",
601 dnl and "pcap_datalink_name_to_val()", and use substitute versions
602 dnl if they're not present.
603 dnl
604 AC_CHECK_FUNC(pcap_list_datalinks,
605 AC_DEFINE(HAVE_PCAP_LIST_DATALINKS, 1,
606 [define if libpcap has pcap_list_datalinks()]),
607 [
608 AC_LIBOBJ(datalinks)
609 ])
610 AC_CHECK_FUNC(pcap_set_datalink,
611 AC_DEFINE(HAVE_PCAP_SET_DATALINK, 1,
612 [define if libpcap has pcap_set_datalink()]))
613 AC_CHECK_FUNC(pcap_datalink_name_to_val,
614 [
615 AC_DEFINE(HAVE_PCAP_DATALINK_NAME_TO_VAL, 1,
616 [define if libpcap has pcap_datalink_name_to_val()])
617 AC_CHECK_FUNC(pcap_datalink_val_to_description,
618 AC_DEFINE(HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION, 1,
619 [define if libpcap has pcap_datalink_val_to_description()]),
620 [
621 AC_LIBOBJ(dlnames)
622 ])
623 ],
624 [
625 AC_LIBOBJ(dlnames)
626 ])
627
628 dnl
629 dnl Check for "pcap_breakloop()"; you can't substitute for it if
630 dnl it's absent (it has hooks into the live capture routines),
631 dnl so just define the HAVE_ value if it's there.
632 dnl
633 AC_CHECK_FUNCS(pcap_breakloop)
634
635 dnl
636 dnl Check for "pcap_dump_ftell()" and use a substitute version
637 dnl if it's not present.
638 AC_CHECK_FUNC(pcap_dump_ftell,
639 AC_DEFINE(HAVE_PCAP_DUMP_FTELL, 1,
640 [define if libpcap has pcap_dump_ftell()]),
641 [
642 AC_LIBOBJ(pcap_dump_ftell)
643 ])
644 ])
645
646 dnl
647 dnl Define RETSIGTYPE and RETSIGVAL
648 dnl
649 dnl usage:
650 dnl
651 dnl AC_LBL_TYPE_SIGNAL
652 dnl
653 dnl results:
654 dnl
655 dnl RETSIGTYPE (defined)
656 dnl RETSIGVAL (defined)
657 dnl
658 AC_DEFUN(AC_LBL_TYPE_SIGNAL,
659 [AC_BEFORE([$0], [AC_LBL_LIBPCAP])
660 AC_TYPE_SIGNAL
661 if test "$ac_cv_type_signal" = void ; then
662 AC_DEFINE(RETSIGVAL,[],[return value of signal handlers])
663 else
664 AC_DEFINE(RETSIGVAL,(0),[return value of signal handlers])
665 fi
666 case "$host_os" in
667
668 irix*)
669 AC_DEFINE(_BSD_SIGNALS,1,[get BSD semantics on Irix])
670 ;;
671
672 *)
673 dnl prefer sigaction() to sigset()
674 AC_CHECK_FUNCS(sigaction)
675 if test $ac_cv_func_sigaction = no ; then
676 AC_CHECK_FUNCS(sigset)
677 fi
678 ;;
679 esac])
680
681 dnl
682 dnl If using gcc, make sure we have ANSI ioctl definitions
683 dnl
684 dnl usage:
685 dnl
686 dnl AC_LBL_FIXINCLUDES
687 dnl
688 AC_DEFUN(AC_LBL_FIXINCLUDES,
689 [if test "$GCC" = yes ; then
690 AC_MSG_CHECKING(for ANSI ioctl definitions)
691 AC_CACHE_VAL(ac_cv_lbl_gcc_fixincludes,
692 AC_TRY_COMPILE(
693 [/*
694 * This generates a "duplicate case value" when fixincludes
695 * has not be run.
696 */
697 # include <sys/types.h>
698 # include <sys/time.h>
699 # include <sys/ioctl.h>
700 # ifdef HAVE_SYS_IOCCOM_H
701 # include <sys/ioccom.h>
702 # endif],
703 [switch (0) {
704 case _IO('A', 1):;
705 case _IO('B', 1):;
706 }],
707 ac_cv_lbl_gcc_fixincludes=yes,
708 ac_cv_lbl_gcc_fixincludes=no))
709 AC_MSG_RESULT($ac_cv_lbl_gcc_fixincludes)
710 if test $ac_cv_lbl_gcc_fixincludes = no ; then
711 # Don't cache failure
712 unset ac_cv_lbl_gcc_fixincludes
713 AC_MSG_ERROR(see the INSTALL for more info)
714 fi
715 fi])
716
717 dnl
718 dnl Checks to see if union wait is used with WEXITSTATUS()
719 dnl
720 dnl usage:
721 dnl
722 dnl AC_LBL_UNION_WAIT
723 dnl
724 dnl results:
725 dnl
726 dnl DECLWAITSTATUS (defined)
727 dnl
728 AC_DEFUN(AC_LBL_UNION_WAIT,
729 [AC_MSG_CHECKING(if union wait is used)
730 AC_CACHE_VAL(ac_cv_lbl_union_wait,
731 AC_TRY_COMPILE([
732 # include <sys/types.h>
733 # include <sys/wait.h>],
734 [int status;
735 u_int i = WEXITSTATUS(status);
736 u_int j = waitpid(0, &status, 0);],
737 ac_cv_lbl_union_wait=no,
738 ac_cv_lbl_union_wait=yes))
739 AC_MSG_RESULT($ac_cv_lbl_union_wait)
740 if test $ac_cv_lbl_union_wait = yes ; then
741 AC_DEFINE(DECLWAITSTATUS,union wait,[type for wait])
742 else
743 AC_DEFINE(DECLWAITSTATUS,int,[type for wait])
744 fi])
745
746 dnl
747 dnl Checks to see if the sockaddr struct has the 4.4 BSD sa_len member
748 dnl
749 dnl usage:
750 dnl
751 dnl AC_LBL_SOCKADDR_SA_LEN
752 dnl
753 dnl results:
754 dnl
755 dnl HAVE_SOCKADDR_SA_LEN (defined)
756 dnl
757 AC_DEFUN(AC_LBL_SOCKADDR_SA_LEN,
758 [AC_MSG_CHECKING(if sockaddr struct has the sa_len member)
759 AC_CACHE_VAL(ac_cv_lbl_sockaddr_has_sa_len,
760 AC_TRY_COMPILE([
761 # include <sys/types.h>
762 # include <sys/socket.h>],
763 [u_int i = sizeof(((struct sockaddr *)0)->sa_len)],
764 ac_cv_lbl_sockaddr_has_sa_len=yes,
765 ac_cv_lbl_sockaddr_has_sa_len=no))
766 AC_MSG_RESULT($ac_cv_lbl_sockaddr_has_sa_len)
767 if test $ac_cv_lbl_sockaddr_has_sa_len = yes ; then
768 AC_DEFINE(HAVE_SOCKADDR_SA_LEN,1,[if struct sockaddr has the sa_len member])
769 fi])
770
771 dnl
772 dnl Checks to see if -R is used
773 dnl
774 dnl usage:
775 dnl
776 dnl AC_LBL_HAVE_RUN_PATH
777 dnl
778 dnl results:
779 dnl
780 dnl ac_cv_lbl_have_run_path (yes or no)
781 dnl
782 AC_DEFUN(AC_LBL_HAVE_RUN_PATH,
783 [AC_MSG_CHECKING(for ${CC-cc} -R)
784 AC_CACHE_VAL(ac_cv_lbl_have_run_path,
785 [echo 'main(){}' > conftest.c
786 ${CC-cc} -o conftest conftest.c -R/a1/b2/c3 >conftest.out 2>&1
787 if test ! -s conftest.out ; then
788 ac_cv_lbl_have_run_path=yes
789 else
790 ac_cv_lbl_have_run_path=no
791 fi
792 rm -f -r conftest*])
793 AC_MSG_RESULT($ac_cv_lbl_have_run_path)
794 ])
795
796 dnl
797 dnl Check whether a given format can be used to print 64-bit integers
798 dnl
799 AC_DEFUN(AC_LBL_CHECK_64BIT_FORMAT,
800 [
801 AC_MSG_CHECKING([whether %$1x can be used to format 64-bit integers])
802 AC_RUN_IFELSE(
803 [
804 AC_LANG_SOURCE(
805 [[
806 # ifdef HAVE_INTTYPES_H
807 #include <inttypes.h>
808 # endif
809 # ifdef HAVE_SYS_BITYPES_H
810 #include <sys/bitypes.h>
811 # endif
812 #include <stdio.h>
813 #include <sys/types.h>
814
815 main()
816 {
817 u_int64_t t = 1;
818 char strbuf[16+1];
819 sprintf(strbuf, "%016$1x", t << 32);
820 if (strcmp(strbuf, "0000000100000000") == 0)
821 exit(0);
822 else
823 exit(1);
824 }
825 ]])
826 ],
827 [
828 AC_DEFINE(PRId64, "$1d", [define if the platform doesn't define PRId64])
829 AC_DEFINE(PRIo64, "$1o", [define if the platform doesn't define PRIo64])
830 AC_DEFINE(PRIx64, "$1x", [define if the platform doesn't define PRIu64])
831 AC_DEFINE(PRIu64, "$1u", [define if the platform doesn't define PRIx64])
832 AC_MSG_RESULT(yes)
833 ],
834 [
835 AC_MSG_RESULT(no)
836 $2
837 ])
838 ])
839
840 dnl
841 dnl Checks to see if unaligned memory accesses fail
842 dnl
843 dnl usage:
844 dnl
845 dnl AC_LBL_UNALIGNED_ACCESS
846 dnl
847 dnl results:
848 dnl
849 dnl LBL_ALIGN (DEFINED)
850 dnl
851 AC_DEFUN(AC_LBL_UNALIGNED_ACCESS,
852 [AC_MSG_CHECKING(if unaligned accesses fail)
853 AC_CACHE_VAL(ac_cv_lbl_unaligned_fail,
854 [case "$host_cpu" in
855
856 #
857 # These are CPU types where:
858 #
859 # the CPU faults on an unaligned access, but at least some
860 # OSes that support that CPU catch the fault and simulate
861 # the unaligned access (e.g., Alpha/{Digital,Tru64} UNIX) -
862 # the simulation is slow, so we don't want to use it;
863 #
864 # the CPU, I infer (from the old
865 #
866 # XXX: should also check that they don't do weird things (like on arm)
867 #
868 # comment) doesn't fault on unaligned accesses, but doesn't
869 # do a normal unaligned fetch, either (e.g., presumably, ARM);
870 #
871 # for whatever reason, the test program doesn't work
872 # (this has been claimed to be the case for several of those
873 # CPUs - I don't know what the problem is; the problem
874 # was reported as "the test program dumps core" for SuperH,
875 # but that's what the test program is *supposed* to do -
876 # it dumps core before it writes anything, so the test
877 # for an empty output file should find an empty output
878 # file and conclude that unaligned accesses don't work).
879 #
880 # This run-time test won't work if you're cross-compiling, so
881 # in order to support cross-compiling for a particular CPU,
882 # we have to wire in the list of CPU types anyway, as far as
883 # I know, so perhaps we should just have a set of CPUs on
884 # which we know it doesn't work, a set of CPUs on which we
885 # know it does work, and have the script just fail on other
886 # cpu types and update it when such a failure occurs.
887 #
888 alpha*|arm*|bfin*|hp*|mips*|sh*|sparc*|ia64|nv1)
889 ac_cv_lbl_unaligned_fail=yes
890 ;;
891
892 *)
893 cat >conftest.c <<EOF
894 # include <sys/types.h>
895 # include <sys/wait.h>
896 # include <stdio.h>
897 unsigned char a[[5]] = { 1, 2, 3, 4, 5 };
898 main() {
899 unsigned int i;
900 pid_t pid;
901 int status;
902 /* avoid "core dumped" message */
903 pid = fork();
904 if (pid < 0)
905 exit(2);
906 if (pid > 0) {
907 /* parent */
908 pid = waitpid(pid, &status, 0);
909 if (pid < 0)
910 exit(3);
911 exit(!WIFEXITED(status));
912 }
913 /* child */
914 i = *(unsigned int *)&a[[1]];
915 printf("%d\n", i);
916 exit(0);
917 }
918 EOF
919 ${CC-cc} -o conftest $CFLAGS $CPPFLAGS $LDFLAGS \
920 conftest.c $LIBS >/dev/null 2>&1
921 if test ! -x conftest ; then
922 dnl failed to compile for some reason
923 ac_cv_lbl_unaligned_fail=yes
924 else
925 ./conftest >conftest.out
926 if test ! -s conftest.out ; then
927 ac_cv_lbl_unaligned_fail=yes
928 else
929 ac_cv_lbl_unaligned_fail=no
930 fi
931 fi
932 rm -f -r conftest* core core.conftest
933 ;;
934 esac])
935 AC_MSG_RESULT($ac_cv_lbl_unaligned_fail)
936 if test $ac_cv_lbl_unaligned_fail = yes ; then
937 AC_DEFINE(LBL_ALIGN,1,[if unaligned access fails])
938 fi])
939
940 dnl
941 dnl If the file .devel exists:
942 dnl Add some warning flags if the compiler supports them
943 dnl If an os prototype include exists, symlink os-proto.h to it
944 dnl If we're using gcc:
945 dnl Compile with -g (if supported)
946 dnl
947 dnl usage:
948 dnl
949 dnl AC_LBL_DEVEL(copt)
950 dnl
951 dnl results:
952 dnl
953 dnl $1 (copt appended)
954 dnl HAVE_OS_PROTO_H (defined)
955 dnl os-proto.h (symlinked)
956 dnl
957 AC_DEFUN(AC_LBL_DEVEL,
958 [rm -f os-proto.h
959 if test "${LBL_CFLAGS+set}" = set; then
960 $1="$$1 ${LBL_CFLAGS}"
961 fi
962 if test -f .devel ; then
963 #
964 # Skip all the warning option stuff on some compilers.
965 #
966 if test "$ac_lbl_cc_dont_try_gcc_dashW" != yes; then
967 AC_LBL_CHECK_UNKNOWN_WARNING_OPTION_ERROR()
968 AC_LBL_CHECK_COMPILER_OPT($1, -Wall)
969 AC_LBL_CHECK_COMPILER_OPT($1, -Wmissing-prototypes)
970 AC_LBL_CHECK_COMPILER_OPT($1, -Wstrict-prototypes)
971 AC_LBL_CHECK_COMPILER_OPT($1, -Wwrite-strings)
972 AC_LBL_CHECK_COMPILER_OPT($1, -Wpointer-arith)
973 AC_LBL_CHECK_COMPILER_OPT($1, -W)
974 fi
975 AC_LBL_CHECK_DEPENDENCY_GENERATION_OPT()
976 if test "$GCC" = yes ; then
977 if test "${LBL_CFLAGS+set}" != set; then
978 if test "$ac_cv_prog_cc_g" = yes ; then
979 $1="-g $$1"
980 fi
981 fi
982 else
983 case "$host_os" in
984
985 irix6*)
986 V_CCOPT="$V_CCOPT -n32"
987 ;;
988
989 *)
990 ;;
991 esac
992 fi
993 os=`echo $host_os | sed -e 's/\([[0-9]][[0-9]]*\)[[^0-9]].*$/\1/'`
994 name="lbl/os-$os.h"
995 if test -f $name ; then
996 ln -s $name os-proto.h
997 AC_DEFINE(HAVE_OS_PROTO_H, 1,
998 [if there's an os_proto.h for this platform, to use additional prototypes])
999 else
1000 AC_MSG_WARN(can't find $name)
1001 fi
1002 fi])
1003
1004 dnl
1005 dnl Improved version of AC_CHECK_LIB
1006 dnl
1007 dnl Thanks to John Hawkinson (jhawk@mit.edu)
1008 dnl
1009 dnl usage:
1010 dnl
1011 dnl AC_LBL_CHECK_LIB(LIBRARY, FUNCTION [, ACTION-IF-FOUND [,
1012 dnl ACTION-IF-NOT-FOUND [, OTHER-LIBRARIES]]])
1013 dnl
1014 dnl results:
1015 dnl
1016 dnl LIBS
1017 dnl
1018 dnl XXX - "AC_LBL_LIBRARY_NET" was redone to use "AC_SEARCH_LIBS"
1019 dnl rather than "AC_LBL_CHECK_LIB", so this isn't used any more.
1020 dnl We keep it around for reference purposes in case it's ever
1021 dnl useful in the future.
1022 dnl
1023
1024 define(AC_LBL_CHECK_LIB,
1025 [AC_MSG_CHECKING([for $2 in -l$1])
1026 dnl Use a cache variable name containing the library, function
1027 dnl name, and extra libraries to link with, because the test really is
1028 dnl for library $1 defining function $2, when linked with potinal
1029 dnl library $5, not just for library $1. Separate tests with the same
1030 dnl $1 and different $2's or $5's may have different results.
1031 ac_lib_var=`echo $1['_']$2['_']$5 | sed 'y%./+- %__p__%'`
1032 AC_CACHE_VAL(ac_cv_lbl_lib_$ac_lib_var,
1033 [ac_save_LIBS="$LIBS"
1034 LIBS="-l$1 $5 $LIBS"
1035 AC_TRY_LINK(dnl
1036 ifelse([$2], [main], , dnl Avoid conflicting decl of main.
1037 [/* Override any gcc2 internal prototype to avoid an error. */
1038 ]ifelse(AC_LANG, CPLUSPLUS, [#ifdef __cplusplus
1039 extern "C"
1040 #endif
1041 ])dnl
1042 [/* We use char because int might match the return type of a gcc2
1043 builtin and then its argument prototype would still apply. */
1044 char $2();
1045 ]),
1046 [$2()],
1047 eval "ac_cv_lbl_lib_$ac_lib_var=yes",
1048 eval "ac_cv_lbl_lib_$ac_lib_var=no")
1049 LIBS="$ac_save_LIBS"
1050 ])dnl
1051 if eval "test \"`echo '$ac_cv_lbl_lib_'$ac_lib_var`\" = yes"; then
1052 AC_MSG_RESULT(yes)
1053 ifelse([$3], ,
1054 [changequote(, )dnl
1055 ac_tr_lib=HAVE_LIB`echo $1 | sed -e 's/[^a-zA-Z0-9_]/_/g' \
1056 -e 'y/abcdefghijklmnopqrstuvwxyz/ABCDEFGHIJKLMNOPQRSTUVWXYZ/'`
1057 changequote([, ])dnl
1058 AC_DEFINE_UNQUOTED($ac_tr_lib)
1059 LIBS="-l$1 $LIBS"
1060 ], [$3])
1061 else
1062 AC_MSG_RESULT(no)
1063 ifelse([$4], , , [$4
1064 ])dnl
1065 fi
1066 ])
1067
1068 dnl
1069 dnl AC_LBL_LIBRARY_NET
1070 dnl
1071 dnl This test is for network applications that need socket() and
1072 dnl gethostbyname() -ish functions. Under Solaris, those applications
1073 dnl need to link with "-lsocket -lnsl". Under IRIX, they need to link
1074 dnl with "-lnsl" but should *not* link with "-lsocket" because
1075 dnl libsocket.a breaks a number of things (for instance:
1076 dnl gethostbyname() under IRIX 5.2, and snoop sockets under most
1077 dnl versions of IRIX).
1078 dnl
1079 dnl Unfortunately, many application developers are not aware of this,
1080 dnl and mistakenly write tests that cause -lsocket to be used under
1081 dnl IRIX. It is also easy to write tests that cause -lnsl to be used
1082 dnl under operating systems where neither are necessary (or useful),
1083 dnl such as SunOS 4.1.4, which uses -lnsl for TLI.
1084 dnl
1085 dnl This test exists so that every application developer does not test
1086 dnl this in a different, and subtly broken fashion.
1087
1088 dnl It has been argued that this test should be broken up into two
1089 dnl seperate tests, one for the resolver libraries, and one for the
1090 dnl libraries necessary for using Sockets API. Unfortunately, the two
1091 dnl are carefully intertwined and allowing the autoconf user to use
1092 dnl them independantly potentially results in unfortunate ordering
1093 dnl dependancies -- as such, such component macros would have to
1094 dnl carefully use indirection and be aware if the other components were
1095 dnl executed. Since other autoconf macros do not go to this trouble,
1096 dnl and almost no applications use sockets without the resolver, this
1097 dnl complexity has not been implemented.
1098 dnl
1099 dnl The check for libresolv is in case you are attempting to link
1100 dnl statically and happen to have a libresolv.a lying around (and no
1101 dnl libnsl.a).
1102 dnl
1103 AC_DEFUN(AC_LBL_LIBRARY_NET, [
1104 # Most operating systems have gethostbyname() in the default searched
1105 # libraries (i.e. libc):
1106 # Some OSes (eg. Solaris) place it in libnsl
1107 # Some strange OSes (SINIX) have it in libsocket:
1108 AC_SEARCH_LIBS(gethostbyname, nsl socket resolv)
1109 # Unfortunately libsocket sometimes depends on libnsl and
1110 # AC_SEARCH_LIBS isn't up to the task of handling dependencies like this.
1111 if test "$ac_cv_search_gethostbyname" = "no"
1112 then
1113 AC_CHECK_LIB(socket, gethostbyname,
1114 LIBS="-lsocket -lnsl $LIBS", , -lnsl)
1115 fi
1116 AC_SEARCH_LIBS(socket, socket, ,
1117 AC_CHECK_LIB(socket, socket, LIBS="-lsocket -lnsl $LIBS", , -lnsl))
1118 # DLPI needs putmsg under HPUX so test for -lstr while we're at it
1119 AC_SEARCH_LIBS(putmsg, str)
1120 ])
1121
1122 dnl Copyright (c) 1999 WIDE Project. All rights reserved.
1123 dnl
1124 dnl Redistribution and use in source and binary forms, with or without
1125 dnl modification, are permitted provided that the following conditions
1126 dnl are met:
1127 dnl 1. Redistributions of source code must retain the above copyright
1128 dnl notice, this list of conditions and the following disclaimer.
1129 dnl 2. Redistributions in binary form must reproduce the above copyright
1130 dnl notice, this list of conditions and the following disclaimer in the
1131 dnl documentation and/or other materials provided with the distribution.
1132 dnl 3. Neither the name of the project nor the names of its contributors
1133 dnl may be used to endorse or promote products derived from this software
1134 dnl without specific prior written permission.
1135 dnl
1136 dnl THIS SOFTWARE IS PROVIDED BY THE PROJECT AND CONTRIBUTORS ``AS IS'' AND
1137 dnl ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
1138 dnl IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
1139 dnl ARE DISCLAIMED. IN NO EVENT SHALL THE PROJECT OR CONTRIBUTORS BE LIABLE
1140 dnl FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
1141 dnl DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
1142 dnl OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
1143 dnl HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
1144 dnl LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
1145 dnl OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
1146 dnl SUCH DAMAGE.
1147
1148 dnl
1149 dnl Checks to see if AF_INET6 is defined
1150 AC_DEFUN(AC_CHECK_AF_INET6, [
1151 AC_MSG_CHECKING(for AF_INET6)
1152 AC_CACHE_VAL($1,
1153 AC_TRY_COMPILE([
1154 # include <sys/types.h>
1155 # include <sys/socket.h>],
1156 [int a = AF_INET6],
1157 $1=yes,
1158 $1=no))
1159 AC_MSG_RESULT($$1)
1160 if test $$1 = yes ; then
1161 AC_DEFINE(HAVE_AF_INET6)
1162 fi
1163 ])
1164
1165 dnl
1166 dnl Checks to see if the sockaddr struct has the 4.4 BSD sa_len member
1167 dnl borrowed from LBL libpcap
1168 AC_DEFUN(AC_CHECK_SA_LEN, [
1169 AC_MSG_CHECKING(if sockaddr struct has sa_len member)
1170 AC_CACHE_VAL($1,
1171 AC_TRY_COMPILE([
1172 # include <sys/types.h>
1173 # include <sys/socket.h>],
1174 [u_int i = sizeof(((struct sockaddr *)0)->sa_len)],
1175 $1=yes,
1176 $1=no))
1177 AC_MSG_RESULT($$1)
1178 if test $$1 = yes ; then
1179 AC_DEFINE(HAVE_SOCKADDR_SA_LEN)
1180 fi
1181 ])
1182
1183 dnl
1184 dnl Checks for addrinfo structure
1185 AC_DEFUN(AC_STRUCT_ADDRINFO, [
1186 AC_MSG_CHECKING(for addrinfo)
1187 AC_CACHE_VAL($1,
1188 AC_TRY_COMPILE([
1189 # include <netdb.h>],
1190 [struct addrinfo a],
1191 $1=yes,
1192 $1=no))
1193 AC_MSG_RESULT($$1)
1194 if test $$1 = yes; then
1195 AC_DEFINE(HAVE_ADDRINFO, 1,
1196 [define if you have the addrinfo function])
1197 else
1198 AC_DEFINE(NEED_ADDRINFO_H, 1,
1199 [define if you need to include missing/addrinfo.h])
1200 fi
1201 ])
1202
1203 dnl
1204 dnl Checks for NI_MAXSERV
1205 AC_DEFUN(AC_NI_MAXSERV, [
1206 AC_MSG_CHECKING(for NI_MAXSERV)
1207 AC_CACHE_VAL($1,
1208 AC_EGREP_CPP(yes, [#include <netdb.h>
1209 #ifdef NI_MAXSERV
1210 yes
1211 #endif],
1212 $1=yes,
1213 $1=no))
1214 AC_MSG_RESULT($$1)
1215 if test $$1 != yes; then
1216 AC_DEFINE(NEED_ADDRINFO_H)
1217 fi
1218 ])
1219
1220 dnl
1221 dnl Checks for NI_NAMEREQD
1222 AC_DEFUN(AC_NI_NAMEREQD, [
1223 AC_MSG_CHECKING(for NI_NAMEREQD)
1224 AC_CACHE_VAL($1,
1225 AC_EGREP_CPP(yes, [#include <netdb.h>
1226 #ifdef NI_NOFQDN
1227 yes
1228 #endif],
1229 $1=yes,
1230 $1=no))
1231 AC_MSG_RESULT($$1)
1232 if test $$1 != yes; then
1233 AC_DEFINE(NEED_ADDRINFO_H)
1234 fi
1235 ])
1236
1237 dnl
1238 dnl Checks for sockaddr_storage structure
1239 AC_DEFUN(AC_STRUCT_SA_STORAGE, [
1240 AC_MSG_CHECKING(for sockaddr_storage)
1241 AC_CACHE_VAL($1,
1242 AC_TRY_COMPILE([
1243 # include <sys/types.h>
1244 # include <sys/socket.h>],
1245 [struct sockaddr_storage s],
1246 $1=yes,
1247 $1=no))
1248 AC_MSG_RESULT($$1)
1249 if test $$1 = yes; then
1250 AC_DEFINE(HAVE_SOCKADDR_STORAGE, 1,
1251 [define if you have struct sockaddr_storage])
1252 fi
1253 ])
1254
1255 dnl
1256 dnl check for h_errno
1257 AC_DEFUN(AC_VAR_H_ERRNO, [
1258 AC_MSG_CHECKING(for h_errno)
1259 AC_CACHE_VAL(ac_cv_var_h_errno,
1260 AC_TRY_COMPILE([
1261 # include <sys/types.h>
1262 # include <netdb.h>],
1263 [int foo = h_errno;],
1264 ac_cv_var_h_errno=yes,
1265 ac_cv_var_h_errno=no))
1266 AC_MSG_RESULT($ac_cv_var_h_errno)
1267 if test "$ac_cv_var_h_errno" = "yes"; then
1268 AC_DEFINE(HAVE_H_ERRNO, 1,
1269 [define if you have the h_errno variable])
1270 fi
1271 ])
1272
1273 dnl
1274 dnl Test for __attribute__
1275 dnl
1276
1277 AC_DEFUN(AC_C___ATTRIBUTE__, [
1278 AC_MSG_CHECKING(for __attribute__)
1279 AC_CACHE_VAL(ac_cv___attribute__, [
1280 AC_COMPILE_IFELSE([
1281 AC_LANG_SOURCE([[
1282 #include <stdlib.h>
1283
1284 static void foo(void) __attribute__ ((noreturn));
1285
1286 static void
1287 foo(void)
1288 {
1289 exit(1);
1290 }
1291
1292 int
1293 main(int argc, char **argv)
1294 {
1295 foo();
1296 }
1297 ]])],
1298 ac_cv___attribute__=yes,
1299 ac_cv___attribute__=no)])
1300 if test "$ac_cv___attribute__" = "yes"; then
1301 AC_DEFINE(HAVE___ATTRIBUTE__, 1, [define if your compiler has __attribute__])
1302 V_DEFS="$V_DEFS -D_U_=\"__attribute__((unused))\""
1303 else
1304 V_DEFS="$V_DEFS -D_U_=\"\""
1305 fi
1306 AC_MSG_RESULT($ac_cv___attribute__)
1307 ])
1308
1309
1310 dnl
1311 dnl Test whether __attribute__((format)) can be applied to function
1312 dnl pointers
1313 dnl
1314
1315 AC_DEFUN(AC_C___ATTRIBUTE___FORMAT_FUNCTION_POINTER, [
1316 AC_MSG_CHECKING([whether __attribute__((format)) can be applied to function pointers])
1317 AC_CACHE_VAL(ac_cv___attribute___format_function_pointer, [
1318 AC_COMPILE_IFELSE([
1319 AC_LANG_SOURCE([[
1320 #include <stdlib.h>
1321
1322 extern int (*foo)(const char *fmt, ...)
1323 __attribute__ ((format (printf, 1, 2)));
1324
1325 int
1326 main(int argc, char **argv)
1327 {
1328 (*foo)("%s", "test");
1329 }
1330 ]])],
1331 ac_cv___attribute___format_function_pointer=yes,
1332 ac_cv___attribute___format_function_pointer=no)])
1333 if test "$ac_cv___attribute___format_function_pointer" = "yes"; then
1334 AC_DEFINE(__ATTRIBUTE___FORMAT_OK_FOR_FUNCTION_POINTERS, 1,
1335 [define if your compiler allows __attribute__((format)) to be applied to function pointers])
1336 fi
1337 AC_MSG_RESULT($ac_cv___attribute___format_function_pointer)
1338 ])
1339
1340 AC_DEFUN(AC_LBL_SSLEAY,
1341 [
1342 #
1343 # Find the last component of $libdir; it's not necessarily
1344 # "lib" - it might be "lib64" on, for example, x86-64
1345 # Linux systems.
1346 #
1347 # We assume the directory in which we're looking for
1348 # libcrypto has a subdirectory with that as its name.
1349 #
1350 tmplib=`echo "$libdir" | sed 's,.*/,,'`
1351
1352 #
1353 # XXX - is there a better way to check if a given library is
1354 # in a given directory than checking each of the possible
1355 # shared library suffixes?
1356 #
1357 # Are there any other suffixes we need to look for? Do we
1358 # have to worry about ".so.{version}"?
1359 #
1360 # Or should we just look for "libcrypto.*"?
1361 #
1362 if test -d "$1/$tmplib" -a \( -f "$1/$tmplib/libcrypto.a" -o \
1363 -f "$1/$tmplib/libcrypto.so" -o \
1364 -f "$1/$tmplib/libcrypto.sl" -o \
1365 -f "$1/$tmplib/libcrypto.dylib" \); then
1366 ac_cv_ssleay_path="$1"
1367 fi
1368
1369 #
1370 # Make sure we have the headers as well.
1371 #
1372 if test -d "$1/include/openssl" -a -f "$1/include/openssl/des.h"; then
1373 incdir="-I$1/include"
1374 fi
1375 ])
[mirror] the TCPdump network dissector