The Tcpdump Group git mirrors - tcpdump/blob - configure.ac

   1 dnl Copyright (c) 1994, 1995, 1996, 1997
   2 dnl     The Regents of the University of California.  All rights reserved.
   3 dnl
   4 dnl Process this file with autoconf to produce a configure script.
   5 dnl
   6
   7 #
   8 # See
   9 #
  10 #       http://ftp.gnu.org/gnu/config/README
  11 #
  12 # for the URLs to use to fetch new versions of config.guess and
  13 # config.sub.
  14 #
  15
  16 AC_PREREQ(2.64)
  17 AC_INIT(tcpdump, m4_esyscmd_s([cat VERSION]))
  18 AC_CONFIG_SRCDIR(tcpdump.c)
  19
  20 AC_CANONICAL_HOST
  21
  22 AC_LBL_C_INIT_BEFORE_CC(V_INCLS)
  23 AC_PROG_CC_C99
  24 AC_LBL_C_INIT(V_CCOPT, V_INCLS)
  25 AC_LBL_C_INLINE
  26 AC_C___ATTRIBUTE__
  27 if test "$ac_cv___attribute__" = "yes"; then
  28         AC_C___ATTRIBUTE___UNUSED
  29         AC_C___ATTRIBUTE___FALLTHROUGH
  30 fi
  31
  32 AC_CHECK_HEADERS(fcntl.h rpc/rpc.h rpc/rpcent.h)
  33 AC_CHECK_HEADERS(net/pfvar.h, , , [#include <sys/types.h>
  34 #include <sys/socket.h>
  35 #include <net/if.h>])
  36 if test "$ac_cv_header_net_pfvar_h" = yes; then
  37         AC_CHECK_HEADERS(net/if_pflog.h, , , [#include <sys/types.h>
  38         #include <sys/socket.h>
  39         #include <net/if.h>
  40         #include <net/pfvar.h>])
  41         if test "$ac_cv_header_net_if_pflog_h" = yes; then
  42                 LOCALSRC="print-pflog.c $LOCALSRC"
  43         fi
  44 fi
  45 AC_CHECK_HEADERS(netinet/if_ether.h, , , [#include <sys/types.h>
  46 #include <sys/socket.h>])
  47 if test "$ac_cv_header_netinet_if_ether_h" != yes; then
  48         #
  49         # The simple test didn't work.
  50         # Do we need to include <net/if.h> first?
  51         # Unset ac_cv_header_netinet_if_ether_h so we don't
  52         # treat the previous failure as a cached value and
  53         # suppress the next test.
  54         #
  55         AC_MSG_NOTICE([Rechecking with some additional includes])
  56         unset ac_cv_header_netinet_if_ether_h
  57         AC_CHECK_HEADERS(netinet/if_ether.h, , , [#include <sys/types.h>
  58 #include <sys/socket.h>
  59 #include <netinet/in.h>
  60 struct mbuf;
  61 struct rtentry;
  62 #include <net/if.h>])
  63 fi
  64
  65 case "$host_os" in
  66
  67 darwin*)
  68         AC_ARG_ENABLE(universal,
  69         AC_HELP_STRING([--disable-universal],[don't build universal on macOS]))
  70         if test "$enable_universal" != "no"; then
  71                 case "$host_os" in
  72
  73                 darwin9.*)
  74                         #
  75                         # Leopard.  Build for x86 and 32-bit PowerPC, with
  76                         # x86 first.  (That's what Apple does.)
  77                         #
  78                         V_CCOPT="$V_CCOPT -arch i386 -arch ppc"
  79                         LDFLAGS="$LDFLAGS -arch i386 -arch ppc"
  80                         ;;
  81
  82                 darwin10.*)
  83                         #
  84                         # Snow Leopard.  Build for x86-64 and x86, with
  85                         # x86-64 first.  (That's what Apple does.)
  86                         #
  87                         V_CCOPT="$V_CCOPT -arch x86_64 -arch i386"
  88                         LDFLAGS="$LDFLAGS -arch x86_64 -arch i386"
  89                         ;;
  90                 esac
  91         fi
  92         ;;
  93 esac
  94
  95
  96 AC_ARG_WITH(smi,
  97 [  --with-smi              link with libsmi (allows to load MIBs on the fly to decode SNMP packets. [default=yes]
  98   --without-smi           don't link with libsmi],,
  99    with_smi=yes)
 100
 101 if test "x$with_smi" != "xno" ; then
 102         AC_CHECK_HEADER(smi.h,
 103         [
 104                 #
 105                 # OK, we found smi.h.  Do we have libsmi with smiInit?
 106                 #
 107                 AC_CHECK_LIB(smi, smiInit,
 108                 [
 109                         #
 110                         # OK, we have libsmi with smiInit.  Can we use it?
 111                         #
 112                         AC_MSG_CHECKING([whether to enable libsmi])
 113                         savedlibs="$LIBS"
 114                         LIBS="-lsmi $LIBS"
 115                         AC_TRY_RUN(
 116                                 [
 117 /* libsmi available check */
 118 #include <smi.h>
 119 main()
 120 {
 121   int current, revision, age, n;
 122   const int required = 2;
 123   if (smiInit(""))
 124     exit(1);
 125   if (strcmp(SMI_LIBRARY_VERSION, smi_library_version))
 126     exit(2);
 127   n = sscanf(smi_library_version, "%d:%d:%d", &current, &revision, &age);
 128   if (n != 3)
 129     exit(3);
 130   if (required < current - age || required > current)
 131     exit(4);
 132   exit(0);
 133 }
 134                                 ],
 135                                 [
 136                                         AC_MSG_RESULT(yes)
 137                                         AC_DEFINE(USE_LIBSMI, 1,
 138                                             [Define if you enable support for libsmi])
 139                                 ],
 140                                 [
 141                                         dnl autoconf documentation says that
 142                                         dnl $? contains the exit value.
 143                                         dnl reality is that it does not.
 144                                         dnl We leave this in just in case
 145                                         dnl autoconf ever comes back to
 146                                         dnl match the documentation.
 147                                         case $? in
 148                                           1) AC_MSG_RESULT(no - smiInit failed) ;;
 149                                           2) AC_MSG_RESULT(no - header/library version mismatch) ;;
 150                                           3) AC_MSG_RESULT(no - can't determine library version) ;;
 151                                           4) AC_MSG_RESULT(no - too old) ;;
 152                                           *) AC_MSG_RESULT(no) ;;
 153                                         esac
 154                                         LIBS="$savedlibs"
 155                                 ],
 156                                 [
 157                                         AC_MSG_RESULT(not when cross-compiling)
 158                                         LIBS="$savedlibs"
 159                                 ]
 160                         )
 161                 ])
 162         ])
 163 fi
 164
 165 AC_MSG_CHECKING([whether to enable the possibly-buggy SMB printer])
 166 AC_ARG_ENABLE(smb,
 167 [  --enable-smb            enable possibly-buggy SMB printer [default=yes]
 168   --disable-smb           disable possibly-buggy SMB printer],,
 169    enableval=yes)
 170 case "$enableval" in
 171 yes)    AC_MSG_RESULT(yes)
 172         AC_WARN([The SMB printer may have exploitable buffer overflows!!!])
 173         AC_DEFINE(ENABLE_SMB, 1,
 174             [define if you want to build the possibly-buggy SMB printer])
 175         LOCALSRC="print-smb.c smbutil.c $LOCALSRC"
 176         ;;
 177 *)      AC_MSG_RESULT(no)
 178         ;;
 179 esac
 180
 181 AC_ARG_WITH(user, [  --with-user=USERNAME    drop privileges by default to USERNAME])
 182 AC_MSG_CHECKING([whether to drop root privileges by default])
 183 if test ! -z "$with_user" ; then
 184        AC_DEFINE_UNQUOTED(WITH_USER, "$withval",
 185            [define if should drop privileges by default])
 186        AC_MSG_RESULT(to \"$withval\")
 187 else
 188        AC_MSG_RESULT(no)
 189 fi
 190
 191 AC_ARG_WITH(chroot, [  --with-chroot=DIRECTORY when dropping privileges, chroot to DIRECTORY])
 192 AC_MSG_CHECKING([whether to chroot])
 193 if test ! -z "$with_chroot" && test "$with_chroot" != "no" ; then
 194        AC_DEFINE_UNQUOTED(WITH_CHROOT, "$withval",
 195            [define if should chroot when dropping privileges])
 196        AC_MSG_RESULT(to \"$withval\")
 197 else
 198        AC_MSG_RESULT(no)
 199 fi
 200
 201 AC_ARG_WITH(sandbox-capsicum,
 202         AS_HELP_STRING([--with-sandbox-capsicum],
 203                        [use Capsicum security functions @<:@default=yes, if available@:>@]))
 204 #
 205 # Check whether various functions are available.  If any are, set
 206 # ac_lbl_capsicum_function_seen to yes; if any are not, set
 207 # ac_lbl_capsicum_function_not_seen to yes.
 208 #
 209 # We don't check cap_rights_init(), as it's a macro, wrapping another
 210 # function, in at least some versions of FreeBSD, and AC_CHECK_FUNCS()
 211 # doesn't handle that.
 212 #
 213 # All of the ones we check for must be available in order to enable
 214 # capsicum sandboxing.
 215 #
 216 # XXX - do we need to check for all of them, or are there some that, if
 217 # present, imply others are present?
 218 #
 219 if test ! -z "$with_sandbox-capsicum" && test "$with_sandbox-capsicum" != "no" ; then
 220         AC_CHECK_FUNCS(cap_enter cap_rights_limit cap_ioctls_limit openat,
 221             ac_lbl_capsicum_function_seen=yes,
 222             ac_lbl_capsicum_function_not_seen=yes)
 223         AC_CHECK_LIB(casper, cap_init, LIBS="$LIBS -lcasper")
 224         AC_CHECK_LIB(cap_dns, cap_gethostbyaddr, LIBS="$LIBS -lcap_dns")
 225 fi
 226 AC_MSG_CHECKING([whether to sandbox using capsicum])
 227 if test "x$ac_lbl_capsicum_function_seen" = "xyes" -a "x$ac_lbl_capsicum_function_not_seen" != "xyes"; then
 228         AC_DEFINE(HAVE_CAPSICUM, 1, [capsicum support available])
 229         AC_MSG_RESULT(yes)
 230 else
 231         AC_MSG_RESULT(no)
 232 fi
 233 AC_MSG_CHECKING([whether to sandbox using Casper library])
 234 if test "x$ac_cv_lib_casper_cap_init" = "xyes" -a "x$ac_cv_lib_cap_dns_cap_gethostbyaddr" = "xyes"; then
 235         AC_DEFINE(HAVE_CASPER, 1, [Casper support available])
 236         AC_MSG_RESULT(yes)
 237 else
 238         AC_MSG_RESULT(no)
 239 fi
 240
 241 #
 242 # We must check this before checking whether to check the OS's IPv6,
 243 # support because, on some platforms (such as SunOS 5.x), the test
 244 # program requires the extra networking libraries.
 245 #
 246 AC_LBL_LIBRARY_NET
 247
 248 #
 249 # Check whether AF_INET6 and struct in6_addr are defined.
 250 # If they aren't both defined, we don't have sufficient OS
 251 # support for IPv6, so we don't look for IPv6 support libraries,
 252 # and we define AF_INET6 and struct in6_addr ourselves.
 253 #
 254 AC_MSG_CHECKING([whether the operating system supports IPv6])
 255 AC_COMPILE_IFELSE(
 256     [
 257       AC_LANG_SOURCE(
 258         [[
 259 /* AF_INET6 available check */
 260 #include <sys/types.h>
 261 #ifdef _WIN32
 262 #include <ws2tcpip.h>
 263 #else
 264 #include <sys/socket.h>
 265 #include <netinet/in.h>
 266 #endif
 267 #ifdef AF_INET6
 268 void
 269 foo(struct in6_addr *addr)
 270 {
 271  memset(addr, 0, sizeof (struct in6_addr));
 272 }
 273 #else
 274 #error "AF_INET6 not defined"
 275 #endif
 276         ]])
 277     ],
 278     [
 279         AC_MSG_RESULT(yes)
 280         AC_DEFINE(HAVE_OS_IPV6_SUPPORT, 1,
 281             [define if the OS provides AF_INET6 and struct in6_addr])
 282         ipv6=yes
 283     ],
 284     [
 285         AC_MSG_RESULT(no)
 286         ipv6=no
 287     ]
 288 )
 289
 290 ipv6type=unknown
 291 ipv6lib=none
 292 ipv6trylibc=no
 293
 294 if test "$ipv6" = "yes"; then
 295         AC_MSG_CHECKING([ipv6 stack type])
 296         for i in inria kame linux-glibc linux-libinet6 toshiba v6d zeta; do
 297                 case $i in
 298                 inria)
 299                         dnl http://www.kame.net/
 300                         AC_EGREP_CPP(yes,
 301 [#include <netinet/in.h>
 302 #ifdef IPV6_INRIA_VERSION
 303 yes
 304 #endif],
 305                                 [ipv6type=$i])
 306                         ;;
 307                 kame)
 308                         dnl http://www.kame.net/
 309                         AC_EGREP_CPP(yes,
 310 [#include <netinet/in.h>
 311 #ifdef __KAME__
 312 yes
 313 #endif],
 314                                 [ipv6type=$i;
 315                                 ipv6lib=inet6;
 316                                 ipv6libdir=/usr/local/v6/lib;
 317                                 ipv6trylibc=yes])
 318                         ;;
 319                 linux-glibc)
 320                         dnl http://www.v6.linux.or.jp/
 321                         AC_EGREP_CPP(yes,
 322 [#include <features.h>
 323 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 324 yes
 325 #endif],
 326                                 [ipv6type=$i])
 327                         ;;
 328                 linux-libinet6)
 329                         dnl http://www.v6.linux.or.jp/
 330                         dnl
 331                         dnl This also matches Solaris 8 and Tru64 UNIX 5.1,
 332                         dnl and possibly other versions of those OSes
 333                         dnl
 334                         if test -d /usr/inet6 -o -f /usr/include/netinet/ip6.h; then
 335                                 ipv6type=$i
 336                                 ipv6lib=inet6
 337                                 ipv6libdir=/usr/inet6/lib
 338                                 ipv6trylibc=yes;
 339                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 340                         fi
 341                         ;;
 342                 toshiba)
 343                         AC_EGREP_CPP(yes,
 344 [#include <sys/param.h>
 345 #ifdef _TOSHIBA_INET6
 346 yes
 347 #endif],
 348                                 [ipv6type=$i;
 349                                 ipv6lib=inet6;
 350                                 ipv6libdir=/usr/local/v6/lib])
 351                         ;;
 352                 v6d)
 353                         AC_EGREP_CPP(yes,
 354 [#include </usr/local/v6/include/sys/v6config.h>
 355 #ifdef __V6D__
 356 yes
 357 #endif],
 358                                 [ipv6type=$i;
 359                                 ipv6lib=v6;
 360                                 ipv6libdir=/usr/local/v6/lib;
 361                                 CFLAGS="-I/usr/local/v6/include $CFLAGS"])
 362                         ;;
 363                 zeta)
 364                         AC_EGREP_CPP(yes,
 365 [#include <sys/param.h>
 366 #ifdef _ZETA_MINAMI_INET6
 367 yes
 368 #endif],
 369                                 [ipv6type=$i;
 370                                 ipv6lib=inet6;
 371                                 ipv6libdir=/usr/local/v6/lib])
 372                         ;;
 373                 esac
 374                 if test "$ipv6type" != "unknown"; then
 375                         break
 376                 fi
 377         done
 378         AC_MSG_RESULT($ipv6type)
 379 fi
 380
 381 if test "$ipv6" = "yes" -a "$ipv6lib" != "none"; then
 382         if test -d $ipv6libdir -a -f $ipv6libdir/lib$ipv6lib.a; then
 383                 LIBS="-L$ipv6libdir -l$ipv6lib $LIBS"
 384                 echo "You have $ipv6lib library, using it"
 385         else
 386                 if test "$ipv6trylibc" = "yes"; then
 387                         echo "You do not have $ipv6lib library, using libc"
 388                 else
 389                         echo 'Fatal: no $ipv6lib library found.  cannot continue.'
 390                         echo "You need to fetch lib$ipv6lib.a from appropriate"
 391                         echo 'ipv6 kit and compile beforehand.'
 392                         exit 1
 393                 fi
 394         fi
 395 fi
 396
 397 AC_SEARCH_LIBS(dnet_htoa, dnet,
 398 [
 399         AC_DEFINE(HAVE_DNET_HTOA, 1,
 400             [define if you have the dnet_htoa function])
 401         #
 402         # OK, we have dnet_htoa().  Do we have netdnet/dnetdb.h?
 403         #
 404         AC_CHECK_HEADERS(netdnet/dnetdb.h)
 405         if test "$ac_cv_header_netdnet_dnetdb_h" = "yes"; then
 406                 #
 407                 # Yes.  Does it declare dnet_htoa()?
 408                 #
 409                 AC_CHECK_DECL(dnet_htoa,
 410                 [
 411                         # Yes.
 412                         AC_DEFINE(NETDNET_DNETDB_H_DECLARES_DNET_HTOA,,
 413                             [Define to 1 if netenet/dnetdb.h declares `dnet_htoa'])
 414                 ],,
 415                 [
 416 AC_INCLUDES_DEFAULT
 417 #include <netdnet/dnetdb.h>
 418                 ])
 419         fi
 420
 421         #
 422         # Do we have netdnet/dn.h?
 423         #
 424         AC_CHECK_HEADERS(netdnet/dn.h)
 425         if test "$ac_cv_header_netdnet_dn_h" = "yes"; then
 426                 #
 427                 # Yes.  Does it declare struct dn_naddr?
 428                 #
 429                 AC_CHECK_TYPES(struct dn_naddr,,,
 430                 [
 431 #include <netdnet/dn.h>
 432                 ])
 433         fi
 434 ])
 435
 436 AC_REPLACE_FUNCS(vfprintf strlcat strlcpy strdup strsep getservent getopt_long)
 437 AC_CHECK_FUNCS(fork vfork strftime)
 438 AC_CHECK_FUNCS(setlinebuf)
 439
 440 needsnprintf=no
 441 AC_CHECK_FUNCS(vsnprintf snprintf,,
 442         [needsnprintf=yes])
 443 if test $needsnprintf = yes; then
 444         AC_LIBOBJ(snprintf)
 445 fi
 446
 447 AC_CHECK_LIB(rpc, main)         dnl It's unclear why we might need -lrpc
 448
 449 dnl Some platforms may need -lnsl for getrpcbynumber.
 450 AC_SEARCH_LIBS(getrpcbynumber, nsl,
 451     AC_DEFINE(HAVE_GETRPCBYNUMBER, 1, [define if you have getrpcbynumber()]))
 452
 453 AC_LBL_LIBPCAP(V_PCAPDEP, V_INCLS)
 454
 455 #
 456 # Check for these after AC_LBL_LIBPCAP, so we link with the appropriate
 457 # libraries (e.g., "-lsocket -lnsl" on Solaris).
 458 #
 459 # You are in a twisty little maze of UN*Xes, all different.
 460 # Some might not have ether_ntohost().
 461 # Some might have it, but not declare it in any header file.
 462 # Some might have it, but declare it in <netinet/if_ether.h>.
 463 # Some might have it, but declare it in <netinet/ether.h>
 464 # (And some might have it but document it as something declared in
 465 # <netinet/ethernet.h>, although <netinet/if_ether.h> appears to work.)
 466 #
 467 # Before you is a C compiler.
 468 #
 469 AC_CHECK_FUNCS(ether_ntohost, [
 470     AC_CACHE_CHECK(for buggy ether_ntohost, ac_cv_buggy_ether_ntohost, [
 471         AC_TRY_RUN([
 472                 #include <netdb.h>
 473                 #include <sys/types.h>
 474                 #include <sys/param.h>
 475                 #include <sys/socket.h>
 476
 477                 int
 478                 main(int argc, char **argv)
 479                 {
 480                         u_char ea[6] = { 0xff, 0xff, 0xff, 0xff, 0xff };
 481                         char name[MAXHOSTNAMELEN];
 482
 483                         ether_ntohost(name, (struct ether_addr *)ea);
 484                         exit(0);
 485                 }
 486         ], [ac_cv_buggy_ether_ntohost=no],
 487            [ac_cv_buggy_ether_ntohost=yes],
 488            [ac_cv_buggy_ether_ntohost="not while cross-compiling"])])
 489     if test "$ac_cv_buggy_ether_ntohost" = "no"; then
 490         AC_DEFINE(USE_ETHER_NTOHOST, 1,
 491             [define if you have ether_ntohost() and it works])
 492     fi
 493 ])
 494 if test "$ac_cv_func_ether_ntohost" = yes -a \
 495     "$ac_cv_buggy_ether_ntohost" = "no"; then
 496         #
 497         # OK, we have ether_ntohost().  Do we have <netinet/if_ether.h>?
 498         #
 499         if test "$ac_cv_header_netinet_if_ether_h" = yes; then
 500                 #
 501                 # Yes.  Does it declare ether_ntohost()?
 502                 #
 503                 AC_CHECK_DECL(ether_ntohost,
 504                     [
 505                         AC_DEFINE(NETINET_IF_ETHER_H_DECLARES_ETHER_NTOHOST,,
 506                             [Define to 1 if netinet/if_ether.h declares `ether_ntohost'])
 507                     ],,
 508                     [
 509 #include <sys/types.h>
 510 #include <sys/socket.h>
 511 #include <netinet/in.h>
 512 #include <arpa/inet.h>
 513 struct mbuf;
 514 struct rtentry;
 515 #include <net/if.h>
 516 #include <netinet/if_ether.h>
 517                     ])
 518         fi
 519         #
 520         # Did that succeed?
 521         #
 522         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 523                 #
 524                 # No, how about <netinet/ether.h>, as on Linux?
 525                 #
 526                 AC_CHECK_HEADERS(netinet/ether.h)
 527                 if test "$ac_cv_header_netinet_ether_h" = yes; then
 528                         #
 529                         # We have it - does it declare ether_ntohost()?
 530                         # Unset ac_cv_have_decl_ether_ntohost so we don't
 531                         # treat the previous failure as a cached value and
 532                         # suppress the next test.
 533                         #
 534                         unset ac_cv_have_decl_ether_ntohost
 535                         AC_CHECK_DECL(ether_ntohost,
 536                             [
 537                                 AC_DEFINE(NETINET_ETHER_H_DECLARES_ETHER_NTOHOST,,
 538                                     [Define to 1 if netinet/ether.h declares `ether_ntohost'])
 539                             ],,
 540                             [
 541 #include <netinet/ether.h>
 542                             ])
 543                 fi
 544         fi
 545         #
 546         # Is ether_ntohost() declared?
 547         #
 548         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 549                 #
 550                 # No, we'll have to declare it ourselves.
 551                 # Do we have "struct ether_addr"?
 552                 #
 553                 AC_CHECK_TYPES(struct ether_addr,,,
 554                     [
 555 #include <sys/types.h>
 556 #include <sys/socket.h>
 557 #include <netinet/in.h>
 558 #include <arpa/inet.h>
 559 struct mbuf;
 560 struct rtentry;
 561 #include <net/if.h>
 562 #include <netinet/if_ether.h>
 563                     ])
 564                 AC_DEFINE(HAVE_DECL_ETHER_NTOHOST, 0,
 565                     [Define to 1 if you have the declaration of `ether_ntohost', and to 0 if you
 566 don't.])
 567         else
 568                 AC_DEFINE(HAVE_DECL_ETHER_NTOHOST, 1,
 569                     [Define to 1 if you have the declaration of `ether_ntohost', and to 0 if you
 570 don't.])
 571         fi
 572 fi
 573
 574 dnl
 575 dnl Check for "pcap_list_datalinks()", "pcap_set_datalink()",
 576 dnl and "pcap_datalink_name_to_val()", and use substitute versions
 577 dnl if they're not present.
 578 dnl
 579 AC_CHECK_FUNC(pcap_list_datalinks,
 580         [
 581             AC_DEFINE(HAVE_PCAP_LIST_DATALINKS, 1,
 582                 [define if libpcap has pcap_list_datalinks()])
 583             AC_CHECK_FUNCS(pcap_free_datalinks)
 584         ],
 585         [
 586             AC_LIBOBJ(datalinks)
 587         ])
 588 AC_CHECK_FUNCS(pcap_set_datalink)
 589 AC_CHECK_FUNC(pcap_datalink_name_to_val,
 590         [
 591             AC_DEFINE(HAVE_PCAP_DATALINK_NAME_TO_VAL, 1,
 592                 [define if libpcap has pcap_datalink_name_to_val()])
 593             AC_CHECK_FUNC(pcap_datalink_val_to_description,
 594                 AC_DEFINE(HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION, 1,
 595                     [define if libpcap has pcap_datalink_val_to_description()]),
 596                 [
 597                     AC_LIBOBJ(dlnames)
 598                 ])
 599         ],
 600         [
 601             AC_LIBOBJ(dlnames)
 602         ])
 603
 604 dnl
 605 dnl Check for "pcap_breakloop()"; you can't substitute for it if
 606 dnl it's absent (it has hooks into the live capture routines),
 607 dnl so just define the HAVE_ value if it's there.
 608 dnl
 609 AC_CHECK_FUNCS(pcap_breakloop)
 610
 611 dnl
 612 dnl Check for "pcap_dump_ftell()" and use a substitute version
 613 dnl if it's not present.
 614 dnl
 615 AC_CHECK_FUNC(pcap_dump_ftell,
 616         AC_DEFINE(HAVE_PCAP_DUMP_FTELL, 1,
 617             [define if libpcap has pcap_dump_ftell()]),
 618         [
 619             AC_LIBOBJ(pcap_dump_ftell)
 620         ])
 621
 622 #
 623 # Do we have the new open API?  Check for pcap_create, and assume that,
 624 # if we do, we also have pcap_activate() and the other new routines
 625 # introduced in libpcap 1.0.0.
 626 #
 627 AC_CHECK_FUNCS(pcap_create)
 628 if test $ac_cv_func_pcap_create = "yes" ; then
 629         #
 630         # OK, do we have pcap_set_tstamp_type?  If so, assume we have
 631         # pcap_list_tstamp_types and pcap_free_tstamp_types as well.
 632         #
 633         AC_CHECK_FUNCS(pcap_set_tstamp_type)
 634         #
 635         # And do we have pcap_set_tstamp_precision?  If so, we assume
 636         # we also have pcap_open_offline_with_tstamp_precision.
 637         #
 638         AC_CHECK_FUNCS(pcap_set_tstamp_precision)
 639 fi
 640
 641 #
 642 # Check for a miscellaneous collection of functions which we use
 643 # if we have them.
 644 #
 645 AC_CHECK_FUNCS(pcap_findalldevs)
 646 if test $ac_cv_func_pcap_findalldevs = "yes" ; then
 647 dnl Check for libpcap having pcap_findalldevs() but the pcap.h header
 648 dnl not having pcap_if_t; some versions of Mac OS X shipped with pcap.h
 649 dnl from 0.6 and libpcap 0.8, so that libpcap had pcap_findalldevs but
 650 dnl pcap.h didn't have pcap_if_t.
 651     savedcppflags="$CPPFLAGS"
 652     CPPFLAGS="$CPPFLAGS $V_INCLS"
 653     AC_CHECK_TYPES(pcap_if_t, , , [#include <pcap.h>])
 654     CPPFLAGS="$savedcppflags"
 655 fi
 656 AC_CHECK_FUNCS(pcap_dump_flush pcap_lib_version)
 657 if test $ac_cv_func_pcap_lib_version = "no" ; then
 658     AC_MSG_CHECKING(whether pcap_version is defined by libpcap)
 659     AC_TRY_LINK([],
 660        [
 661         extern char pcap_version[];
 662
 663         return (int)pcap_version;
 664        ],
 665        ac_lbl_cv_pcap_version_defined=yes,
 666        ac_lbl_cv_pcap_version_defined=no)
 667     if test "$ac_lbl_cv_pcap_version_defined" = yes ; then
 668         AC_MSG_RESULT(yes)
 669         AC_DEFINE(HAVE_PCAP_VERSION, 1, [define if libpcap has pcap_version])
 670     else
 671         AC_MSG_RESULT(no)
 672     fi
 673 fi
 674 AC_CHECK_FUNCS(pcap_setdirection pcap_set_immediate_mode pcap_dump_ftell64)
 675 AC_CHECK_FUNCS(pcap_open pcap_findalldevs_ex)
 676
 677 #
 678 # Check for special debugging functions
 679 #
 680 AC_CHECK_FUNCS(pcap_set_parser_debug)
 681 if test "$ac_cv_func_pcap_set_parser_debug" = "no" ; then
 682         #
 683         # OK, we don't have pcap_set_parser_debug() to set the libpcap
 684         # filter expression parser debug flag; can we directly set the
 685         # flag?
 686         AC_MSG_CHECKING(whether pcap_debug is defined by libpcap)
 687         AC_TRY_LINK([],
 688            [
 689                 extern int pcap_debug;
 690
 691                 return pcap_debug;
 692            ],
 693            ac_lbl_cv_pcap_debug_defined=yes,
 694            ac_lbl_cv_pcap_debug_defined=no)
 695         if test "$ac_lbl_cv_pcap_debug_defined" = yes ; then
 696                 AC_MSG_RESULT(yes)
 697                 AC_DEFINE(HAVE_PCAP_DEBUG, 1, [define if libpcap has pcap_debug])
 698         else
 699                 AC_MSG_RESULT(no)
 700                 #
 701                 # OK, what about "yydebug"?
 702                 #
 703                 AC_MSG_CHECKING(whether yydebug is defined by libpcap)
 704                 AC_TRY_LINK([],
 705                    [
 706                         extern int yydebug;
 707
 708                         return yydebug;
 709                    ],
 710                    ac_lbl_cv_yydebug_defined=yes,
 711                    ac_lbl_cv_yydebug_defined=no)
 712                 if test "$ac_lbl_cv_yydebug_defined" = yes ; then
 713                         AC_MSG_RESULT(yes)
 714                         AC_DEFINE(HAVE_YYDEBUG, 1, [define if libpcap has yydebug])
 715                 else
 716                         AC_MSG_RESULT(no)
 717                 fi
 718         fi
 719 fi
 720 AC_CHECK_FUNCS(pcap_set_optimizer_debug)
 721 AC_REPLACE_FUNCS(bpf_dump)      dnl moved to libpcap in 0.6
 722
 723 V_GROUP=0
 724 if test -f /etc/group -a ! -z "`grep '^wheel:' /etc/group`" ; then
 725         V_GROUP=wheel
 726 fi
 727 #
 728 # Assume V7/BSD convention for man pages (file formats in section 5,
 729 # miscellaneous info in section 7).
 730 #
 731 MAN_FILE_FORMATS=5
 732 MAN_MISC_INFO=7
 733 case "$host_os" in
 734
 735 aix*)
 736         dnl Workaround to enable certain features
 737         AC_DEFINE(_SUN,1,[define on AIX to get certain functions])
 738         ;;
 739
 740 hpux*)
 741         #
 742         # Use System V conventions for man pages.
 743         #
 744         MAN_FILE_FORMATS=4
 745         MAN_MISC_INFO=5
 746         ;;
 747
 748 irix*)
 749         V_GROUP=sys
 750
 751         #
 752         # Use System V conventions for man pages.
 753         #
 754         MAN_FILE_FORMATS=4
 755         MAN_MISC_INFO=5
 756         ;;
 757
 758 osf*)
 759         V_GROUP=system
 760
 761         #
 762         # Use System V conventions for man pages.
 763         #
 764         MAN_FILE_FORMATS=4
 765         MAN_MISC_INFO=5
 766         ;;
 767
 768 solaris*)
 769         V_GROUP=sys
 770
 771         #
 772         # Use System V conventions for man pages.
 773         #
 774         MAN_FILE_FORMATS=4
 775         MAN_MISC_INFO=5
 776         ;;
 777 esac
 778
 779 if test -f /dev/bpf0 ; then
 780         V_GROUP=bpf
 781 fi
 782
 783 #
 784 # Make sure we have a definition for C99's uintptr_t (regardless of
 785 # whether the environment is a C99 environment or not).
 786 #
 787 AC_TYPE_UINTPTR_T
 788
 789 #
 790 # Check whether we have pcap/pcap-inttypes.h.
 791 # If we do, we use that to get the C99 types defined.
 792 #
 793 savedcppflags="$CPPFLAGS"
 794 CPPFLAGS="$CPPFLAGS $V_INCLS"
 795 AC_CHECK_HEADERS(pcap/pcap-inttypes.h)
 796 CPPFLAGS="$savedcppflags"
 797
 798 #
 799 # Define the old BSD specified-width types in terms of the C99 types;
 800 # we may need them with libpcap include files.
 801 #
 802 AC_CHECK_TYPE([u_int8_t], ,
 803         [AC_DEFINE([u_int8_t], [uint8_t],
 804         [Define to `uint8_t' if u_int8_t not defined.])],
 805         [AC_INCLUDES_DEFAULT
 806 #include <sys/types.h>
 807 ])
 808 AC_CHECK_TYPE([u_int16_t], ,
 809         [AC_DEFINE([u_int16_t], [uint16_t],
 810         [Define to `uint16_t' if u_int16_t not defined.])],
 811         [AC_INCLUDES_DEFAULT
 812 #include <sys/types.h>
 813 ])
 814 AC_CHECK_TYPE([u_int32_t], ,
 815         [AC_DEFINE([u_int32_t], [uint32_t],
 816         [Define to `uint32_t' if u_int32_t not defined.])],
 817         [AC_INCLUDES_DEFAULT
 818 #include <sys/types.h>
 819 ])
 820 AC_CHECK_TYPE([u_int64_t], ,
 821         [AC_DEFINE([u_int64_t], [uint64_t],
 822         [Define to `uint64_t' if u_int64_t not defined.])],
 823         [AC_INCLUDES_DEFAULT
 824 #include <sys/types.h>
 825 ])
 826
 827 #
 828 # Check for some headers introduced in later versions of libpcap
 829 # and used by some printers.
 830 #
 831 # Those headers might use the {u_}intN_t types, so we must do this
 832 # after we check for what's needed to get them defined.
 833 #
 834 savedcppflags="$CPPFLAGS"
 835 CPPFLAGS="$CPPFLAGS $V_INCLS"
 836 AC_CHECK_HEADERS(pcap/bluetooth.h,,,[#include "netdissect-stdinc.h"])
 837 AC_CHECK_HEADERS(pcap/nflog.h,,,[#include "netdissect-stdinc.h"])
 838 CPPFLAGS="$savedcppflags"
 839
 840 AC_PROG_RANLIB
 841 AC_CHECK_TOOL([AR], [ar])
 842
 843 AC_LBL_DEVEL(V_CCOPT)
 844
 845 # Check for OpenSSL/libressl libcrypto
 846 AC_MSG_CHECKING(whether to use OpenSSL/libressl libcrypto)
 847 # Specify location for both includes and libraries.
 848 want_libcrypto=ifavailable
 849 AC_ARG_WITH(crypto,
 850     AS_HELP_STRING([--with-crypto]@<:@=DIR@:>@,
 851                    [use OpenSSL/libressl libcrypto (located in directory DIR, if specified) @<:@default=yes, if available@:>@]),
 852 [
 853         if test $withval = no
 854         then
 855                 # User doesn't want to link with libcrypto.
 856                 want_libcrypto=no
 857                 AC_MSG_RESULT(no)
 858         elif test $withval = yes
 859         then
 860                 # User wants to link with libcrypto but hasn't specified
 861                 # a directory.
 862                 want_libcrypto=yes
 863                 AC_MSG_RESULT(yes)
 864         else
 865                 # User wants to link with libcrypto and has specified
 866                 # a directory, so use the provided value.
 867                 want_libcrypto=yes
 868                 libcrypto_root=$withval
 869                 AC_MSG_RESULT([yes, using the version installed in $withval])
 870
 871                 #
 872                 # Put the subdirectories of the libcrypto root directory
 873                 # at the front of the header and library search path.
 874                 #
 875                 CFLAGS="-I$withval/include $CFLAGS"
 876                 LIBS="-L$withval/lib $LIBS"
 877         fi
 878 ],[
 879         #
 880         # Use libcrypto if it's present, otherwise don't; no directory
 881         # was specified.
 882         #
 883         want_libcrypto=ifavailable
 884         AC_MSG_RESULT([yes, if available])
 885 ])
 886 if test "$want_libcrypto" != "no"; then
 887         #
 888         # Don't check for libcrypto unless we have its headers;
 889         # Apple, bless their pointy little heads, apparently ship
 890         # libcrypto as a library, but not the header files, in
 891         # El Capitan, probably because they don't want you writing
 892         # nasty portable code that could run on other UN*Xes, they
 893         # want you writing code that uses their Shiny New Crypto
 894         # Library and that only runs on macOS.
 895         #
 896         AC_CHECK_HEADER(openssl/crypto.h,
 897         [
 898                 AC_CHECK_LIB(crypto, DES_cbc_encrypt)
 899                 if test "$ac_cv_lib_crypto_DES_cbc_encrypt" = "yes"; then
 900                         AC_CHECK_HEADERS(openssl/evp.h)
 901                         #
 902                         # OK, then:
 903                         #
 904                         # 1) do we have EVP_CIPHER_CTX_new?
 905                         # If so, we use it to allocate an
 906                         # EVP_CIPHER_CTX, as EVP_CIPHER_CTX may be
 907                         # opaque; otherwise, we allocate it ourselves.
 908                         #
 909                         # 2) do we have EVP_CipherInit_ex()?
 910                         # If so, we use it, because we need to be
 911                         # able to make two "initialize the cipher"
 912                         # calls, one with the cipher and key, and
 913                         # one with the IV, and, as of OpenSSL 1.1,
 914                         # You Can't Do That with EVP_CipherInit(),
 915                         # because a call to EVP_CipherInit() will
 916                         # unconditionally clear the context, and
 917                         # if you don't supply a cipher, it'll
 918                         # clear the cipher, rendering the context
 919                         # unusable and causing a crash.
 920                         #
 921                         AC_CHECK_FUNCS(EVP_CIPHER_CTX_new EVP_CipherInit_ex)
 922                 fi
 923         ])
 924 fi
 925
 926 # Check for libcap-ng
 927 AC_MSG_CHECKING(whether to use libcap-ng)
 928 # Specify location for both includes and libraries.
 929 want_libcap_ng=ifavailable
 930 AC_ARG_WITH(cap_ng,
 931     AS_HELP_STRING([--with-cap-ng],
 932                    [use libcap-ng @<:@default=yes, if available@:>@]),
 933 [
 934         if test $withval = no
 935         then
 936                 want_libcap_ng=no
 937                 AC_MSG_RESULT(no)
 938         elif test $withval = yes
 939         then
 940                 want_libcap_ng=yes
 941                 AC_MSG_RESULT(yes)
 942         fi
 943 ],[
 944         #
 945         # Use libcap-ng if it's present, otherwise don't.
 946         #
 947         want_libcap_ng=ifavailable
 948         AC_MSG_RESULT([yes, if available])
 949 ])
 950 if test "$want_libcap_ng" != "no"; then
 951         AC_CHECK_LIB(cap-ng, capng_change_id)
 952         AC_CHECK_HEADERS(cap-ng.h)
 953 fi
 954
 955 dnl
 956 dnl set additional include path if necessary
 957 if test "$missing_includes" = "yes"; then
 958         CPPFLAGS="$CPPFLAGS -I$srcdir/missing"
 959         V_INCLS="$V_INCLS -I$srcdir/missing"
 960 fi
 961
 962 AC_SUBST(V_CCOPT)
 963 AC_SUBST(V_DEFS)
 964 AC_SUBST(V_GROUP)
 965 AC_SUBST(V_INCLS)
 966 AC_SUBST(V_PCAPDEP)
 967 AC_SUBST(LOCALSRC)
 968 AC_SUBST(MAN_FILE_FORMATS)
 969 AC_SUBST(MAN_MISC_INFO)
 970
 971 AC_PROG_INSTALL
 972
 973 AC_CONFIG_HEADER(config.h)
 974
 975 AC_OUTPUT_COMMANDS([if test -f .devel; then
 976         echo timestamp > stamp-h
 977         cat Makefile-devel-adds >> Makefile
 978         make depend
 979 fi])
 980 AC_OUTPUT(Makefile tcpdump.1)
 981 exit 0