The Tcpdump Group git mirrors - tcpdump/blob - aclocal.m4

   1 dnl @(#) $Header: /tcpdump/master/tcpdump/aclocal.m4,v 1.72 2000-09-19 04:01:25 guy Exp $ (LBL)
   2 dnl
   3 dnl Copyright (c) 1995, 1996, 1997, 1998
   4 dnl     The Regents of the University of California.  All rights reserved.
   5 dnl
   6 dnl Redistribution and use in source and binary forms, with or without
   7 dnl modification, are permitted provided that: (1) source code distributions
   8 dnl retain the above copyright notice and this paragraph in its entirety, (2)
   9 dnl distributions including binary code include the above copyright notice and
  10 dnl this paragraph in its entirety in the documentation or other materials
  11 dnl provided with the distribution, and (3) all advertising materials mentioning
  12 dnl features or use of this software display the following acknowledgement:
  13 dnl ``This product includes software developed by the University of California,
  14 dnl Lawrence Berkeley Laboratory and its contributors.'' Neither the name of
  15 dnl the University nor the names of its contributors may be used to endorse
  16 dnl or promote products derived from this software without specific prior
  17 dnl written permission.
  18 dnl THIS SOFTWARE IS PROVIDED ``AS IS'' AND WITHOUT ANY EXPRESS OR IMPLIED
  19 dnl WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED WARRANTIES OF
  20 dnl MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE.
  21 dnl
  22 dnl LBL autoconf macros
  23 dnl
  24
  25 dnl
  26 dnl Determine which compiler we're using (cc or gcc)
  27 dnl If using gcc, determine the version number
  28 dnl If using cc, require that it support ansi prototypes
  29 dnl If using gcc, use -O2 (otherwise use -O)
  30 dnl If using cc, explicitly specify /usr/local/include
  31 dnl
  32 dnl usage:
  33 dnl
  34 dnl     AC_LBL_C_INIT(copt, incls)
  35 dnl
  36 dnl results:
  37 dnl
  38 dnl     $1 (copt set)
  39 dnl     $2 (incls set)
  40 dnl     CC
  41 dnl     LDFLAGS
  42 dnl     ac_cv_lbl_gcc_vers
  43 dnl     LBL_CFLAGS
  44 dnl
  45 AC_DEFUN(AC_LBL_C_INIT,
  46     [AC_PREREQ(2.12)
  47     AC_BEFORE([$0], [AC_PROG_CC])
  48     AC_BEFORE([$0], [AC_LBL_FIXINCLUDES])
  49     AC_BEFORE([$0], [AC_LBL_DEVEL])
  50     AC_ARG_WITH(gcc, [  --without-gcc           don't use gcc])
  51     $1="-O"
  52     $2=""
  53     if test "${srcdir}" != "." ; then
  54             $2="-I\$(srcdir)"
  55     fi
  56     if test "${CFLAGS+set}" = set; then
  57             LBL_CFLAGS="$CFLAGS"
  58     fi
  59     if test -z "$CC" ; then
  60             case "$target_os" in
  61
  62             bsdi*)
  63                     AC_CHECK_PROG(SHLICC2, shlicc2, yes, no)
  64                     if test $SHLICC2 = yes ; then
  65                             CC=shlicc2
  66                             export CC
  67                     fi
  68                     ;;
  69             esac
  70     fi
  71     if test -z "$CC" -a "$with_gcc" = no ; then
  72             CC=cc
  73             export CC
  74     fi
  75     AC_PROG_CC
  76     if test "$GCC" = yes ; then
  77             if test "$SHLICC2" = yes ; then
  78                     ac_cv_lbl_gcc_vers=2
  79                     $1="-O2"
  80             else
  81                     AC_MSG_CHECKING(gcc version)
  82                     AC_CACHE_VAL(ac_cv_lbl_gcc_vers,
  83                         ac_cv_lbl_gcc_vers=`$CC -v 2>&1 | \
  84                             sed -e '/^gcc version /!d' \
  85                                 -e 's/^gcc version //' \
  86                                 -e 's/ .*//' -e 's/^[[[^0-9]]]*//' \
  87                                 -e 's/\..*//'`)
  88                     AC_MSG_RESULT($ac_cv_lbl_gcc_vers)
  89                     if test $ac_cv_lbl_gcc_vers -gt 1 ; then
  90                             $1="-O2"
  91                     fi
  92             fi
  93     else
  94             AC_MSG_CHECKING(that $CC handles ansi prototypes)
  95             AC_CACHE_VAL(ac_cv_lbl_cc_ansi_prototypes,
  96                 AC_TRY_COMPILE(
  97                     [#include <sys/types.h>],
  98                     [int frob(int, char *)],
  99                     ac_cv_lbl_cc_ansi_prototypes=yes,
 100                     ac_cv_lbl_cc_ansi_prototypes=no))
 101             AC_MSG_RESULT($ac_cv_lbl_cc_ansi_prototypes)
 102             if test $ac_cv_lbl_cc_ansi_prototypes = no ; then
 103                     case "$target_os" in
 104
 105                     hpux*)
 106                             AC_MSG_CHECKING(for HP-UX ansi compiler ($CC -Aa -D_HPUX_SOURCE))
 107                             savedcflags="$CFLAGS"
 108                             CFLAGS="-Aa -D_HPUX_SOURCE $CFLAGS"
 109                             AC_CACHE_VAL(ac_cv_lbl_cc_hpux_cc_aa,
 110                                 AC_TRY_COMPILE(
 111                                     [#include <sys/types.h>],
 112                                     [int frob(int, char *)],
 113                                     ac_cv_lbl_cc_hpux_cc_aa=yes,
 114                                     ac_cv_lbl_cc_hpux_cc_aa=no))
 115                             AC_MSG_RESULT($ac_cv_lbl_cc_hpux_cc_aa)
 116                             if test $ac_cv_lbl_cc_hpux_cc_aa = no ; then
 117                                     AC_MSG_ERROR(see the INSTALL doc for more info)
 118                             fi
 119                             CFLAGS="$savedcflags"
 120                             V_CCOPT="-Aa $V_CCOPT"
 121                             AC_DEFINE(_HPUX_SOURCE)
 122                             ;;
 123
 124                     *)
 125                             AC_MSG_ERROR(see the INSTALL doc for more info)
 126                             ;;
 127                     esac
 128             fi
 129             $2="$$2 -I/usr/local/include"
 130             LDFLAGS="$LDFLAGS -L/usr/local/lib"
 131
 132             case "$target_os" in
 133
 134             irix*)
 135                     V_CCOPT="$V_CCOPT -xansi -signed -g3"
 136                     ;;
 137
 138             osf*)
 139                     V_CCOPT="$V_CCOPT -std1 -g3"
 140                     ;;
 141
 142             ultrix*)
 143                     AC_MSG_CHECKING(that Ultrix $CC hacks const in prototypes)
 144                     AC_CACHE_VAL(ac_cv_lbl_cc_const_proto,
 145                         AC_TRY_COMPILE(
 146                             [#include <sys/types.h>],
 147                             [struct a { int b; };
 148                             void c(const struct a *)],
 149                             ac_cv_lbl_cc_const_proto=yes,
 150                             ac_cv_lbl_cc_const_proto=no))
 151                     AC_MSG_RESULT($ac_cv_lbl_cc_const_proto)
 152                     if test $ac_cv_lbl_cc_const_proto = no ; then
 153                             AC_DEFINE(const,)
 154                     fi
 155                     ;;
 156             esac
 157     fi
 158 ])
 159
 160 dnl
 161 dnl Use pfopen.c if available and pfopen() not in standard libraries
 162 dnl Require libpcap
 163 dnl Look for libpcap in ..
 164 dnl Use the installed libpcap if there is no local version
 165 dnl
 166 dnl usage:
 167 dnl
 168 dnl     AC_LBL_LIBPCAP(pcapdep, incls)
 169 dnl
 170 dnl results:
 171 dnl
 172 dnl     $1 (pcapdep set)
 173 dnl     $2 (incls appended)
 174 dnl     LIBS
 175 dnl     LBL_LIBS
 176 dnl
 177 AC_DEFUN(AC_LBL_LIBPCAP,
 178     [AC_REQUIRE([AC_LBL_LIBRARY_NET])
 179     dnl
 180     dnl save a copy before locating libpcap.a
 181     dnl
 182     LBL_LIBS="$LIBS"
 183     pfopen=/usr/examples/packetfilter/pfopen.c
 184     if test -f $pfopen ; then
 185             AC_CHECK_FUNCS(pfopen)
 186             if test $ac_cv_func_pfopen = "no" ; then
 187                     AC_MSG_RESULT(Using $pfopen)
 188                     LIBS="$LIBS $pfopen"
 189             fi
 190     fi
 191     AC_MSG_CHECKING(for local pcap library)
 192     libpcap=FAIL
 193     lastdir=FAIL
 194     places=`ls .. | sed -e 's,/$,,' -e 's,^,../,' | \
 195         egrep '/libpcap-[[0-9]]*.[[0-9]]*(.[[0-9]]*)?([[ab]][[0-9]]*)?$'`
 196     for dir in $places ../libpcap libpcap ; do
 197             basedir=`echo $dir | sed -e 's/[[ab]][[0-9]]*$//'`
 198             if test $lastdir = $basedir ; then
 199                     dnl skip alphas when an actual release is present
 200                     continue;
 201             fi
 202             lastdir=$dir
 203             if test -r $dir/libpcap.a ; then
 204                     libpcap=$dir/libpcap.a
 205                     d=$dir
 206                     dnl continue and select the last one that exists
 207             fi
 208     done
 209     if test $libpcap = FAIL ; then
 210             AC_MSG_RESULT(not found)
 211             AC_CHECK_LIB(pcap, main, libpcap="-lpcap")
 212             if test $libpcap = FAIL ; then
 213                     AC_MSG_ERROR(see the INSTALL doc for more info)
 214             fi
 215     else
 216             $1=$libpcap
 217             if test -r $d/pcap.h; then
 218             $2="-I$d $$2"
 219             elif test -r $srcdir/../libpcap/pcap.h; then
 220                     $2="-I$d -I$srcdir/../libpcap $$2"
 221             else
 222                     AC_MSG_ERROR(cannot find pcap.h, see INSTALL)
 223             fi
 224             AC_MSG_RESULT($libpcap)
 225     fi
 226     LIBS="$libpcap $LIBS"
 227     case "$target_os" in
 228
 229     aix*)
 230             pseexe="/lib/pse.exp"
 231             AC_MSG_CHECKING(for $pseexe)
 232             if test -f $pseexe ; then
 233                     AC_MSG_RESULT(yes)
 234                     LIBS="$LIBS -I:$pseexe"
 235             fi
 236             ;;
 237     esac])
 238
 239 dnl
 240 dnl Define RETSIGTYPE and RETSIGVAL
 241 dnl
 242 dnl usage:
 243 dnl
 244 dnl     AC_LBL_TYPE_SIGNAL
 245 dnl
 246 dnl results:
 247 dnl
 248 dnl     RETSIGTYPE (defined)
 249 dnl     RETSIGVAL (defined)
 250 dnl
 251 AC_DEFUN(AC_LBL_TYPE_SIGNAL,
 252     [AC_BEFORE([$0], [AC_LBL_LIBPCAP])
 253     AC_TYPE_SIGNAL
 254     if test "$ac_cv_type_signal" = void ; then
 255             AC_DEFINE(RETSIGVAL,)
 256     else
 257             AC_DEFINE(RETSIGVAL,(0))
 258     fi
 259     case "$target_os" in
 260
 261     irix*)
 262             AC_DEFINE(_BSD_SIGNALS)
 263             ;;
 264
 265     *)
 266             dnl prefer sigset() to sigaction()
 267             AC_CHECK_FUNCS(sigset)
 268             if test $ac_cv_func_sigset = no ; then
 269                     AC_CHECK_FUNCS(sigaction)
 270             fi
 271             ;;
 272     esac])
 273
 274 dnl
 275 dnl If using gcc, make sure we have ANSI ioctl definitions
 276 dnl
 277 dnl usage:
 278 dnl
 279 dnl     AC_LBL_FIXINCLUDES
 280 dnl
 281 AC_DEFUN(AC_LBL_FIXINCLUDES,
 282     [if test "$GCC" = yes ; then
 283             AC_MSG_CHECKING(for ANSI ioctl definitions)
 284             AC_CACHE_VAL(ac_cv_lbl_gcc_fixincludes,
 285                 AC_TRY_COMPILE(
 286                     [/*
 287                      * This generates a "duplicate case value" when fixincludes
 288                      * has not be run.
 289                      */
 290 #               include <sys/types.h>
 291 #               include <sys/time.h>
 292 #               include <sys/ioctl.h>
 293 #               ifdef HAVE_SYS_IOCCOM_H
 294 #               include <sys/ioccom.h>
 295 #               endif],
 296                     [switch (0) {
 297                     case _IO('A', 1):;
 298                     case _IO('B', 1):;
 299                     }],
 300                     ac_cv_lbl_gcc_fixincludes=yes,
 301                     ac_cv_lbl_gcc_fixincludes=no))
 302             AC_MSG_RESULT($ac_cv_lbl_gcc_fixincludes)
 303             if test $ac_cv_lbl_gcc_fixincludes = no ; then
 304                     # Don't cache failure
 305                     unset ac_cv_lbl_gcc_fixincludes
 306                     AC_MSG_ERROR(see the INSTALL for more info)
 307             fi
 308     fi])
 309
 310 dnl
 311 dnl Check for flex, default to lex
 312 dnl Require flex 2.4 or higher
 313 dnl Check for bison, default to yacc
 314 dnl Default to lex/yacc if both flex and bison are not available
 315 dnl Define the yy prefix string if using flex and bison
 316 dnl
 317 dnl usage:
 318 dnl
 319 dnl     AC_LBL_LEX_AND_YACC(lex, yacc, yyprefix)
 320 dnl
 321 dnl results:
 322 dnl
 323 dnl     $1 (lex set)
 324 dnl     $2 (yacc appended)
 325 dnl     $3 (optional flex and bison -P prefix)
 326 dnl
 327 AC_DEFUN(AC_LBL_LEX_AND_YACC,
 328     [AC_ARG_WITH(flex, [  --without-flex          don't use flex])
 329     AC_ARG_WITH(bison, [  --without-bison         don't use bison])
 330     if test "$with_flex" = no ; then
 331             $1=lex
 332     else
 333             AC_CHECK_PROGS($1, flex, lex)
 334     fi
 335     if test "$$1" = flex ; then
 336             # The -V flag was added in 2.4
 337             AC_MSG_CHECKING(for flex 2.4 or higher)
 338             AC_CACHE_VAL(ac_cv_lbl_flex_v24,
 339                 if flex -V >/dev/null 2>&1; then
 340                         ac_cv_lbl_flex_v24=yes
 341                 else
 342                         ac_cv_lbl_flex_v24=no
 343                 fi)
 344             AC_MSG_RESULT($ac_cv_lbl_flex_v24)
 345             if test $ac_cv_lbl_flex_v24 = no ; then
 346                     s="2.4 or higher required"
 347                     AC_MSG_WARN(ignoring obsolete flex executable ($s))
 348                     $1=lex
 349             fi
 350     fi
 351     if test "$with_bison" = no ; then
 352             $2=yacc
 353     else
 354             AC_CHECK_PROGS($2, bison, yacc)
 355     fi
 356     if test "$$2" = bison ; then
 357             $2="$$2 -y"
 358     fi
 359     if test "$$1" != lex -a "$$2" = yacc -o "$$1" = lex -a "$$2" != yacc ; then
 360             AC_MSG_WARN(don't have both flex and bison; reverting to lex/yacc)
 361             $1=lex
 362             $2=yacc
 363     fi
 364     if test "$$1" = flex -a -n "$3" ; then
 365             $1="$$1 -P$3"
 366             $2="$$2 -p $3"
 367     fi])
 368
 369 dnl
 370 dnl Checks to see if union wait is used with WEXITSTATUS()
 371 dnl
 372 dnl usage:
 373 dnl
 374 dnl     AC_LBL_UNION_WAIT
 375 dnl
 376 dnl results:
 377 dnl
 378 dnl     DECLWAITSTATUS (defined)
 379 dnl
 380 AC_DEFUN(AC_LBL_UNION_WAIT,
 381     [AC_MSG_CHECKING(if union wait is used)
 382     AC_CACHE_VAL(ac_cv_lbl_union_wait,
 383         AC_TRY_COMPILE([
 384 #       include <sys/types.h>
 385 #       include <sys/wait.h>],
 386             [int status;
 387             u_int i = WEXITSTATUS(status);
 388             u_int j = waitpid(0, &status, 0);],
 389             ac_cv_lbl_union_wait=no,
 390             ac_cv_lbl_union_wait=yes))
 391     AC_MSG_RESULT($ac_cv_lbl_union_wait)
 392     if test $ac_cv_lbl_union_wait = yes ; then
 393             AC_DEFINE(DECLWAITSTATUS,union wait)
 394     else
 395             AC_DEFINE(DECLWAITSTATUS,int)
 396     fi])
 397
 398 dnl
 399 dnl Checks to see if the sockaddr struct has the 4.4 BSD sa_len member
 400 dnl
 401 dnl usage:
 402 dnl
 403 dnl     AC_LBL_SOCKADDR_SA_LEN
 404 dnl
 405 dnl results:
 406 dnl
 407 dnl     HAVE_SOCKADDR_SA_LEN (defined)
 408 dnl
 409 AC_DEFUN(AC_LBL_SOCKADDR_SA_LEN,
 410     [AC_MSG_CHECKING(if sockaddr struct has sa_len member)
 411     AC_CACHE_VAL(ac_cv_lbl_sockaddr_has_sa_len,
 412         AC_TRY_COMPILE([
 413 #       include <sys/types.h>
 414 #       include <sys/socket.h>],
 415         [u_int i = sizeof(((struct sockaddr *)0)->sa_len)],
 416         ac_cv_lbl_sockaddr_has_sa_len=yes,
 417         ac_cv_lbl_sockaddr_has_sa_len=no))
 418     AC_MSG_RESULT($ac_cv_lbl_sockaddr_has_sa_len)
 419     if test $ac_cv_lbl_sockaddr_has_sa_len = yes ; then
 420             AC_DEFINE(HAVE_SOCKADDR_SA_LEN)
 421     fi])
 422
 423 dnl
 424 dnl Checks to see if -R is used
 425 dnl
 426 dnl usage:
 427 dnl
 428 dnl     AC_LBL_HAVE_RUN_PATH
 429 dnl
 430 dnl results:
 431 dnl
 432 dnl     ac_cv_lbl_have_run_path (yes or no)
 433 dnl
 434 AC_DEFUN(AC_LBL_HAVE_RUN_PATH,
 435     [AC_MSG_CHECKING(for ${CC-cc} -R)
 436     AC_CACHE_VAL(ac_cv_lbl_have_run_path,
 437         [echo 'main(){}' > conftest.c
 438         ${CC-cc} -o conftest conftest.c -R/a1/b2/c3 >conftest.out 2>&1
 439         if test ! -s conftest.out ; then
 440                 ac_cv_lbl_have_run_path=yes
 441         else
 442                 ac_cv_lbl_have_run_path=no
 443         fi
 444         rm -f conftest*])
 445     AC_MSG_RESULT($ac_cv_lbl_have_run_path)
 446     ])
 447
 448 dnl
 449 dnl Due to the stupid way it's implemented, AC_CHECK_TYPE is nearly useless.
 450 dnl
 451 dnl usage:
 452 dnl
 453 dnl     AC_LBL_CHECK_TYPE
 454 dnl
 455 dnl results:
 456 dnl
 457 dnl     int32_t (defined)
 458 dnl     u_int32_t (defined)
 459 dnl
 460 AC_DEFUN(AC_LBL_CHECK_TYPE,
 461     [AC_MSG_CHECKING(for $1 using $CC)
 462     AC_CACHE_VAL(ac_cv_lbl_have_$1,
 463         AC_TRY_COMPILE([
 464 #       include "confdefs.h"
 465 #       include <sys/types.h>
 466 #       if STDC_HEADERS
 467 #       include <stdlib.h>
 468 #       include <stddef.h>
 469 #       endif],
 470         [$1 i],
 471         ac_cv_lbl_have_$1=yes,
 472         ac_cv_lbl_have_$1=no))
 473     AC_MSG_RESULT($ac_cv_lbl_have_$1)
 474     if test $ac_cv_lbl_have_$1 = no ; then
 475             AC_DEFINE($1, $2)
 476     fi])
 477
 478 dnl
 479 dnl Checks to see if unaligned memory accesses fail
 480 dnl
 481 dnl usage:
 482 dnl
 483 dnl     AC_LBL_UNALIGNED_ACCESS
 484 dnl
 485 dnl results:
 486 dnl
 487 dnl     LBL_ALIGN (DEFINED)
 488 dnl
 489 AC_DEFUN(AC_LBL_UNALIGNED_ACCESS,
 490     [AC_MSG_CHECKING(if unaligned accesses fail)
 491     AC_CACHE_VAL(ac_cv_lbl_unaligned_fail,
 492         [case "$target_cpu" in
 493
 494         # XXX: should also check that they don't do weird things (like on arm)
 495         alpha*|arm*|hp*|mips|sparc)
 496                 ac_cv_lbl_unaligned_fail=yes
 497                 ;;
 498
 499         *)
 500                 cat >conftest.c <<EOF
 501 #               include <sys/types.h>
 502 #               include <sys/wait.h>
 503 #               include <stdio.h>
 504                 unsigned char a[[5]] = { 1, 2, 3, 4, 5 };
 505                 main() {
 506                 unsigned int i;
 507                 pid_t pid;
 508                 int status;
 509                 /* avoid "core dumped" message */
 510                 pid = fork();
 511                 if (pid <  0)
 512                         exit(2);
 513                 if (pid > 0) {
 514                         /* parent */
 515                         pid = waitpid(pid, &status, 0);
 516                         if (pid < 0)
 517                                 exit(3);
 518                         exit(!WIFEXITED(status));
 519                 }
 520                 /* child */
 521                 i = *(unsigned int *)&a[[1]];
 522                 printf("%d\n", i);
 523                 exit(0);
 524                 }
 525 EOF
 526                 ${CC-cc} -o conftest $CFLAGS $CPPFLAGS $LDFLAGS \
 527                     conftest.c $LIBS >/dev/null 2>&1
 528                 if test ! -x conftest ; then
 529                         dnl failed to compile for some reason
 530                         ac_cv_lbl_unaligned_fail=yes
 531                 else
 532                         ./conftest >conftest.out
 533                         if test ! -s conftest.out ; then
 534                                 ac_cv_lbl_unaligned_fail=yes
 535                         else
 536                                 ac_cv_lbl_unaligned_fail=no
 537                         fi
 538                 fi
 539                 rm -f conftest* core core.conftest
 540                 ;;
 541         esac])
 542     AC_MSG_RESULT($ac_cv_lbl_unaligned_fail)
 543     if test $ac_cv_lbl_unaligned_fail = yes ; then
 544             AC_DEFINE(LBL_ALIGN)
 545     fi])
 546
 547 dnl
 548 dnl If using gcc and the file .devel exists:
 549 dnl     Compile with -g (if supported) and -Wall
 550 dnl     If using gcc 2, do extra prototype checking
 551 dnl     If an os prototype include exists, symlink os-proto.h to it
 552 dnl
 553 dnl usage:
 554 dnl
 555 dnl     AC_LBL_DEVEL(copt)
 556 dnl
 557 dnl results:
 558 dnl
 559 dnl     $1 (copt appended)
 560 dnl     HAVE_OS_PROTO_H (defined)
 561 dnl     os-proto.h (symlinked)
 562 dnl
 563 AC_DEFUN(AC_LBL_DEVEL,
 564     [rm -f os-proto.h
 565     if test "${LBL_CFLAGS+set}" = set; then
 566             $1="$$1 ${LBL_CFLAGS}"
 567     fi
 568     if test -f .devel ; then
 569             if test "$GCC" = yes ; then
 570                     if test "${LBL_CFLAGS+set}" != set; then
 571                             if test "$ac_cv_prog_cc_g" = yes ; then
 572                                     $1="-g $$1"
 573                             fi
 574                             $1="$$1 -Wall"
 575                             if test $ac_cv_lbl_gcc_vers -gt 1 ; then
 576                                     $1="$$1 -Wmissing-prototypes -Wstrict-prototypes"
 577                             fi
 578                     fi
 579             else
 580                     case "$target_os" in
 581
 582                     irix6*)
 583                             V_CCOPT="$V_CCOPT -n32"
 584                             ;;
 585
 586                     *)
 587                             ;;
 588                     esac
 589             fi
 590             os=`echo $target_os | sed -e 's/\([[0-9]][[0-9]]*\)[[^0-9]].*$/\1/'`
 591             name="lbl/os-$os.h"
 592             if test -f $name ; then
 593                     ln -s $name os-proto.h
 594                     AC_DEFINE(HAVE_OS_PROTO_H)
 595             else
 596                     AC_MSG_WARN(can't find $name)
 597             fi
 598     fi])
 599
 600 dnl
 601 dnl Improved version of AC_CHECK_LIB
 602 dnl
 603 dnl Thanks to John Hawkinson (jhawk@mit.edu)
 604 dnl
 605 dnl usage:
 606 dnl
 607 dnl     AC_LBL_CHECK_LIB(LIBRARY, FUNCTION [, ACTION-IF-FOUND [,
 608 dnl         ACTION-IF-NOT-FOUND [, OTHER-LIBRARIES]]])
 609 dnl
 610 dnl results:
 611 dnl
 612 dnl     LIBS
 613 dnl
 614
 615 define(AC_LBL_CHECK_LIB,
 616 [AC_MSG_CHECKING([for $2 in -l$1])
 617 dnl Use a cache variable name containing both the library and function name,
 618 dnl because the test really is for library $1 defining function $2, not
 619 dnl just for library $1.  Separate tests with the same $1 and different $2's
 620 dnl may have different results.
 621 ac_lib_var=`echo $1['_']$2['_']$5 | sed 'y%./+- %__p__%'`
 622 AC_CACHE_VAL(ac_cv_lbl_lib_$ac_lib_var,
 623 [ac_save_LIBS="$LIBS"
 624 LIBS="-l$1 $5 $LIBS"
 625 AC_TRY_LINK(dnl
 626 ifelse([$2], [main], , dnl Avoid conflicting decl of main.
 627 [/* Override any gcc2 internal prototype to avoid an error.  */
 628 ]ifelse(AC_LANG, CPLUSPLUS, [#ifdef __cplusplus
 629 extern "C"
 630 #endif
 631 ])dnl
 632 [/* We use char because int might match the return type of a gcc2
 633     builtin and then its argument prototype would still apply.  */
 634 char $2();
 635 ]),
 636             [$2()],
 637             eval "ac_cv_lbl_lib_$ac_lib_var=yes",
 638             eval "ac_cv_lbl_lib_$ac_lib_var=no")
 639 LIBS="$ac_save_LIBS"
 640 ])dnl
 641 if eval "test \"`echo '$ac_cv_lbl_lib_'$ac_lib_var`\" = yes"; then
 642   AC_MSG_RESULT(yes)
 643   ifelse([$3], ,
 644 [changequote(, )dnl
 645   ac_tr_lib=HAVE_LIB`echo $1 | sed -e 's/[^a-zA-Z0-9_]/_/g' \
 646     -e 'y/abcdefghijklmnopqrstuvwxyz/ABCDEFGHIJKLMNOPQRSTUVWXYZ/'`
 647 changequote([, ])dnl
 648   AC_DEFINE_UNQUOTED($ac_tr_lib)
 649   LIBS="-l$1 $LIBS"
 650 ], [$3])
 651 else
 652   AC_MSG_RESULT(no)
 653 ifelse([$4], , , [$4
 654 ])dnl
 655 fi
 656 ])
 657
 658 dnl
 659 dnl AC_LBL_LIBRARY_NET
 660 dnl
 661 dnl This test is for network applications that need socket() and
 662 dnl gethostbyname() -ish functions.  Under Solaris, those applications
 663 dnl need to link with "-lsocket -lnsl".  Under IRIX, they need to link
 664 dnl with "-lnsl" but should *not* link with "-lsocket" because
 665 dnl libsocket.a breaks a number of things (for instance:
 666 dnl gethostbyname() under IRIX 5.2, and snoop sockets under most
 667 dnl versions of IRIX).
 668 dnl
 669 dnl Unfortunately, many application developers are not aware of this,
 670 dnl and mistakenly write tests that cause -lsocket to be used under
 671 dnl IRIX.  It is also easy to write tests that cause -lnsl to be used
 672 dnl under operating systems where neither are necessary (or useful),
 673 dnl such as SunOS 4.1.4, which uses -lnsl for TLI.
 674 dnl
 675 dnl This test exists so that every application developer does not test
 676 dnl this in a different, and subtly broken fashion.
 677
 678 dnl It has been argued that this test should be broken up into two
 679 dnl seperate tests, one for the resolver libraries, and one for the
 680 dnl libraries necessary for using Sockets API. Unfortunately, the two
 681 dnl are carefully intertwined and allowing the autoconf user to use
 682 dnl them independantly potentially results in unfortunate ordering
 683 dnl dependancies -- as such, such component macros would have to
 684 dnl carefully use indirection and be aware if the other components were
 685 dnl executed. Since other autoconf macros do not go to this trouble,
 686 dnl and almost no applications use sockets without the resolver, this
 687 dnl complexity has not been implemented.
 688 dnl
 689 dnl The check for libresolv is in case you are attempting to link
 690 dnl statically and happen to have a libresolv.a lying around (and no
 691 dnl libnsl.a).
 692 dnl
 693 AC_DEFUN(AC_LBL_LIBRARY_NET, [
 694     # Most operating systems have gethostbyname() in the default searched
 695     # libraries (i.e. libc):
 696     AC_CHECK_FUNC(gethostbyname, ,
 697         # Some OSes (eg. Solaris) place it in libnsl:
 698         AC_LBL_CHECK_LIB(nsl, gethostbyname, ,
 699             # Some strange OSes (SINIX) have it in libsocket:
 700             AC_LBL_CHECK_LIB(socket, gethostbyname, ,
 701                 # Unfortunately libsocket sometimes depends on libnsl.
 702                 # AC_CHECK_LIB's API is essentially broken so the
 703                 # following ugliness is necessary:
 704                 AC_LBL_CHECK_LIB(socket, gethostbyname,
 705                     LIBS="-lsocket -lnsl $LIBS",
 706                     AC_CHECK_LIB(resolv, gethostbyname),
 707                     -lnsl))))
 708     AC_CHECK_FUNC(socket, , AC_CHECK_LIB(socket, socket, ,
 709         AC_LBL_CHECK_LIB(socket, socket, LIBS="-lsocket -lnsl $LIBS", ,
 710             -lnsl)))
 711     # DLPI needs putmsg under HPUX so test for -lstr while we're at it
 712     AC_CHECK_LIB(str, putmsg)
 713     ])
 714
 715 dnl Copyright (c) 1999 WIDE Project. All rights reserved.
 716 dnl
 717 dnl Redistribution and use in source and binary forms, with or without
 718 dnl modification, are permitted provided that the following conditions
 719 dnl are met:
 720 dnl 1. Redistributions of source code must retain the above copyright
 721 dnl    notice, this list of conditions and the following disclaimer.
 722 dnl 2. Redistributions in binary form must reproduce the above copyright
 723 dnl    notice, this list of conditions and the following disclaimer in the
 724 dnl    documentation and/or other materials provided with the distribution.
 725 dnl 3. Neither the name of the project nor the names of its contributors
 726 dnl    may be used to endorse or promote products derived from this software
 727 dnl    without specific prior written permission.
 728 dnl
 729 dnl THIS SOFTWARE IS PROVIDED BY THE PROJECT AND CONTRIBUTORS ``AS IS'' AND
 730 dnl ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
 731 dnl IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
 732 dnl ARE DISCLAIMED.  IN NO EVENT SHALL THE PROJECT OR CONTRIBUTORS BE LIABLE
 733 dnl FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
 734 dnl DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
 735 dnl OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
 736 dnl HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
 737 dnl LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
 738 dnl OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
 739 dnl SUCH DAMAGE.
 740
 741 dnl
 742 dnl Checks to see if AF_INET6 is defined
 743 AC_DEFUN(AC_CHECK_AF_INET6, [
 744         AC_MSG_CHECKING(for AF_INET6)
 745         AC_CACHE_VAL($1,
 746         AC_TRY_COMPILE([
 747 #               include <sys/types.h>
 748 #               include <sys/socket.h>],
 749                 [int a = AF_INET6],
 750                 $1=yes,
 751                 $1=no))
 752         AC_MSG_RESULT($$1)
 753                 if test $$1 = yes ; then
 754                         AC_DEFINE(HAVE_AF_INET6)
 755         fi
 756 ])
 757
 758 dnl
 759 dnl Checks to see if the sockaddr struct has the 4.4 BSD sa_len member
 760 dnl borrowed from LBL libpcap
 761 AC_DEFUN(AC_CHECK_SA_LEN, [
 762         AC_MSG_CHECKING(if sockaddr struct has sa_len member)
 763         AC_CACHE_VAL($1,
 764         AC_TRY_COMPILE([
 765 #               include <sys/types.h>
 766 #               include <sys/socket.h>],
 767                 [u_int i = sizeof(((struct sockaddr *)0)->sa_len)],
 768                 $1=yes,
 769                 $1=no))
 770         AC_MSG_RESULT($$1)
 771                 if test $$1 = yes ; then
 772                         AC_DEFINE(HAVE_SOCKADDR_SA_LEN)
 773         fi
 774 ])
 775
 776 dnl
 777 dnl Checks for portable prototype declaration macro
 778 AC_DEFUN(AC_CHECK_PORTABLE_PROTO,  [
 779         AC_MSG_CHECKING(for __P)
 780         AC_CACHE_VAL($1,
 781         AC_TRY_COMPILE([
 782 #               include <unistd.h>],
 783                 [int f __P(())],
 784                 $1=yes,
 785                 $1=no))
 786         AC_MSG_RESULT($$1)
 787         if test $$1 = yes; then
 788                 AC_DEFINE(HAVE_PORTABLE_PROTOTYPE)
 789         fi
 790 ])
 791
 792 dnl checks for u_intXX_t
 793 AC_DEFUN(AC_CHECK_BITTYPES, [
 794         $1=yes
 795 dnl check for u_int8_t
 796         AC_MSG_CHECKING(for u_int8_t)
 797         AC_CACHE_VAL(ac_cv_u_int8_t,
 798         AC_TRY_COMPILE([
 799 #               include <sys/types.h>],
 800                 [u_int8_t i],
 801                 ac_cv_u_int8_t=yes,
 802                 ac_cv_u_int8_t=no))
 803         AC_MSG_RESULT($ac_cv_u_int8_t)
 804         if test $ac_cv_u_int8_t = yes; then
 805                 AC_DEFINE(HAVE_U_INT8_T)
 806         else
 807                 $1=no
 808         fi
 809 dnl check for u_int16_t
 810         AC_MSG_CHECKING(for u_int16_t)
 811         AC_CACHE_VAL(ac_cv_u_int16_t,
 812         AC_TRY_COMPILE([
 813 #               include <sys/types.h>],
 814                 [u_int16_t i],
 815                 ac_cv_u_int16_t=yes,
 816                 ac_cv_u_int16_t=no))
 817         AC_MSG_RESULT($ac_cv_u_int16_t)
 818         if test $ac_cv_u_int16_t = yes; then
 819                 AC_DEFINE(HAVE_U_INT16_T)
 820         else
 821                 $1=no
 822         fi
 823 dnl check for u_int32_t
 824         AC_MSG_CHECKING(for u_int32_t)
 825         AC_CACHE_VAL(ac_cv_u_int32_t,
 826         AC_TRY_COMPILE([
 827 #               include <sys/types.h>],
 828                 [u_int32_t i],
 829                 ac_cv_u_int32_t=yes,
 830                 ac_cv_u_int32_t=no))
 831         AC_MSG_RESULT($ac_cv_u_int32_t)
 832         if test $ac_cv_u_int32_t = yes; then
 833                 AC_DEFINE(HAVE_U_INT32_T)
 834         else
 835                 $1=no
 836         fi
 837 ])
 838
 839 dnl
 840 dnl Checks for addrinfo structure
 841 AC_DEFUN(AC_STRUCT_ADDRINFO, [
 842         AC_MSG_CHECKING(for addrinfo)
 843         AC_CACHE_VAL($1,
 844         AC_TRY_COMPILE([
 845 #               include <netdb.h>],
 846                 [struct addrinfo a],
 847                 $1=yes,
 848                 $1=no))
 849         AC_MSG_RESULT($$1)
 850         if test $$1 = yes; then
 851                 AC_DEFINE(HAVE_ADDRINFO)
 852         else
 853                 AC_DEFINE(NEED_ADDRINFO_H)
 854         fi
 855 ])
 856
 857 dnl
 858 dnl Checks for NI_MAXSERV
 859 AC_DEFUN(AC_NI_MAXSERV, [
 860         AC_MSG_CHECKING(for NI_MAXSERV)
 861         AC_CACHE_VAL($1,
 862         AC_EGREP_CPP(yes, [#include <netdb.h>
 863 #ifdef NI_MAXSERV
 864 yes
 865 #endif],
 866                 $1=yes,
 867                 $1=no))
 868         AC_MSG_RESULT($$1)
 869         if test $$1 != yes; then
 870                 AC_DEFINE(NEED_ADDRINFO_H)
 871         fi
 872 ])
 873
 874 dnl
 875 dnl Checks for NI_NAMEREQD
 876 AC_DEFUN(AC_NI_NAMEREQD, [
 877         AC_MSG_CHECKING(for NI_NAMEREQD)
 878         AC_CACHE_VAL($1,
 879         AC_EGREP_CPP(yes, [#include <netdb.h>
 880 #ifdef NI_NOFQDN
 881 yes
 882 #endif],
 883                 $1=yes,
 884                 $1=no))
 885         AC_MSG_RESULT($$1)
 886         if test $$1 != yes; then
 887                 AC_DEFINE(NEED_ADDRINFO_H)
 888         fi
 889 ])
 890
 891 dnl
 892 dnl Checks for sockaddr_storage structure
 893 AC_DEFUN(AC_STRUCT_SA_STORAGE, [
 894         AC_MSG_CHECKING(for sockaddr_storage)
 895         AC_CACHE_VAL($1,
 896         AC_TRY_COMPILE([
 897 #               include <sys/types.h>
 898 #               include <sys/socket.h>],
 899                 [struct sockaddr_storage s],
 900                 $1=yes,
 901                 $1=no))
 902         AC_MSG_RESULT($$1)
 903         if test $$1 = yes; then
 904                 AC_DEFINE(HAVE_SOCKADDR_STORAGE)
 905         fi
 906 ])
 907
 908 dnl
 909 dnl Checks for macro of IP address size
 910 AC_DEFUN(AC_CHECK_ADDRSZ, [
 911         $1=yes
 912 dnl check for INADDRSZ
 913         AC_MSG_CHECKING(for INADDRSZ)
 914         AC_CACHE_VAL(ac_cv_inaddrsz,
 915         AC_TRY_COMPILE([
 916 #               include <arpa/nameser.h>],
 917                 [int a = INADDRSZ],
 918                 ac_cv_inaddrsz=yes,
 919                 ac_cv_inaddrsz=no))
 920         AC_MSG_RESULT($ac_cv_inaddrsz)
 921         if test $ac_cv_inaddrsz = yes; then
 922                 AC_DEFINE(HAVE_INADDRSZ)
 923         else
 924                 $1=no
 925         fi
 926 dnl check for IN6ADDRSZ
 927         AC_MSG_CHECKING(for IN6ADDRSZ)
 928         AC_CACHE_VAL(ac_cv_in6addrsz,
 929         AC_TRY_COMPILE([
 930 #               include <arpa/nameser.h>],
 931                 [int a = IN6ADDRSZ],
 932                 ac_cv_in6addrsz=yes,
 933                 ac_cv_in6addrsz=no))
 934         AC_MSG_RESULT($ac_cv_in6addrsz)
 935         if test $ac_cv_in6addrsz = yes; then
 936                 AC_DEFINE(HAVE_IN6ADDRSZ)
 937         else
 938                 $1=no
 939         fi
 940 ])
 941
 942 dnl
 943 dnl check for RES_USE_INET6
 944 AC_DEFUN(AC_CHECK_RES_USE_INET6, [
 945         AC_MSG_CHECKING(for RES_USE_INET6)
 946         AC_CACHE_VAL($1,
 947         AC_TRY_COMPILE([
 948 #               include <sys/types.h>
 949 #               include <netinet/in.h>
 950 #               include <resolv.h>],
 951                 [int a = RES_USE_INET6],
 952                 $1=yes,
 953                 $1=no))
 954         AC_MSG_RESULT($$1)
 955         if test $$1 = yes; then
 956                 AC_DEFINE(HAVE_RES_USE_INET6)
 957         fi
 958 ])
 959
 960 dnl
 961 dnl check for AAAA
 962 AC_DEFUN(AC_CHECK_AAAA, [
 963         AC_MSG_CHECKING(for AAAA)
 964         AC_CACHE_VAL($1,
 965         AC_TRY_COMPILE([
 966 #               include <sys/types.h>
 967 #               include <arpa/nameser.h>],
 968                 [int a = T_AAAA],
 969                 $1=yes,
 970                 $1=no))
 971         AC_MSG_RESULT($$1)
 972         if test $$1 = yes; then
 973                 AC_DEFINE(HAVE_AAAA)
 974         fi
 975 ])
 976
 977 dnl
 978 dnl check for struct res_state_ext
 979 AC_DEFUN(AC_STRUCT_RES_STATE_EXT, [
 980         AC_MSG_CHECKING(for res_state_ext)
 981         AC_CACHE_VAL($1,
 982         AC_TRY_COMPILE([
 983 #               include <sys/types.h>
 984 #               include <netinet/in.h>
 985 #               include <netinet6/in6.h>
 986 #               include <resolv.h>],
 987                 [struct __res_state_ext e],
 988                 $1=yes,
 989                 $1=no))
 990         AC_MSG_RESULT($$1)
 991         if test $$1 = yes; then
 992                 AC_DEFINE(HAVE_RES_STATE_EXT)
 993         fi
 994 ])
 995
 996 dnl
 997 dnl check for struct res_state_ext
 998 AC_DEFUN(AC_STRUCT_RES_STATE, [
 999         AC_MSG_CHECKING(for nsort in res_state)
1000         AC_CACHE_VAL($1,
1001         AC_TRY_COMPILE([
1002 #               include <sys/types.h>
1003 #               include <netinet/in.h>
1004 #               include <netinet6/in6.h>
1005 #               include <resolv.h>],
1006                 [struct __res_state e; e.nsort = 0],
1007                 $1=yes,
1008                 $1=no))
1009         AC_MSG_RESULT($$1)
1010         if test $$1 = yes; then
1011                 AC_DEFINE(HAVE_NEW_RES_STATE)
1012         fi
1013 ])
1014
1015 dnl
1016 dnl check for h_errno
1017 AC_DEFUN(AC_VAR_H_ERRNO, [
1018         AC_MSG_CHECKING(for h_errno)
1019         AC_CACHE_VAL(ac_cv_var_h_errno,
1020         AC_TRY_COMPILE([
1021 #               include <sys/types.h>
1022 #               include <netdb.h>],
1023                 [int foo = h_errno;],
1024                 ac_cv_var_h_errno=yes,
1025                 ac_cv_var_h_errno=no))
1026         AC_MSG_RESULT($ac_cv_var_h_errno)
1027         if test "$ac_cv_var_h_errno" = "yes"; then
1028                 AC_DEFINE(HAVE_H_ERRNO)
1029         fi
1030 ])
1031
1032 dnl
1033 dnl Test for __attribute__
1034 dnl
1035
1036 AC_DEFUN(AC_C___ATTRIBUTE__, [
1037 AC_MSG_CHECKING(for __attribute__)
1038 AC_CACHE_VAL(ac_cv___attribute__, [
1039 AC_TRY_COMPILE([
1040 #include <stdlib.h>
1041 ],
1042 [
1043 static void foo(void) __attribute__ ((noreturn));
1044
1045 static void
1046 foo(void)
1047 {
1048   exit(1);
1049 }
1050 ],
1051 ac_cv___attribute__=yes,
1052 ac_cv___attribute__=no)])
1053 if test "$ac_cv___attribute__" = "yes"; then
1054   AC_DEFINE(HAVE___ATTRIBUTE__, 1, [define if your compiler has __attribute__])
1055 fi
1056 AC_MSG_RESULT($ac_cv___attribute__)
1057 ])