The Tcpdump Group git mirrors - tcpdump/blob - configure.ac

   1 dnl Copyright (c) 1994, 1995, 1996, 1997
   2 dnl     The Regents of the University of California.  All rights reserved.
   3 dnl
   4 dnl Process this file with autoconf to produce a configure script.
   5 dnl
   6
   7 #
   8 # See
   9 #
  10 #       https://ftp.gnu.org/gnu/config/README
  11 #
  12 # for the URLs to use to fetch new versions of config.guess and
  13 # config.sub.
  14 #
  15
  16 AC_PREREQ([2.69])
  17 AC_INIT([tcpdump],[m4_esyscmd_s(cat VERSION)],[https://github.com/the-tcpdump-group/tcpdump/issues])
  18 AC_CONFIG_SRCDIR(tcpdump.c)
  19
  20 AC_CANONICAL_HOST
  21
  22 AC_LBL_C_INIT_BEFORE_CC(V_INCLS)
  23 #
  24 # Try to enable as many C99 features as we can.
  25 # At minimum, we want C++/C99-style // comments.
  26 #
  27 AC_PROG_CC_C99
  28 if test "$ac_cv_prog_cc_c99" = "no"; then
  29         AC_MSG_WARN([The C compiler does not support C99; there may be compiler errors])
  30 fi
  31 AC_LBL_C_INIT(V_CCOPT, V_INCLS)
  32
  33 AC_CHECK_HEADERS(rpc/rpc.h rpc/rpcent.h net/if.h)
  34 #
  35 # Get the size of a void *, to know whether this is a 32-bit or 64-bit build.
  36 #
  37 AC_CHECK_SIZEOF([void *])
  38
  39 #
  40 # Get the size of a time_t, to know whether it's 32-bit or 64-bit.
  41 #
  42 AC_CHECK_SIZEOF([time_t],,[#include <time.h>])
  43
  44 case "$host_os" in
  45
  46 darwin*)
  47         AC_ARG_ENABLE(universal,
  48         AS_HELP_STRING([--disable-universal],[don't build universal on macOS]))
  49         if test "$enable_universal" != "no"; then
  50                 case "$host_os" in
  51
  52                 darwin9.*)
  53                         #
  54                         # Leopard.  Build for x86 and 32-bit PowerPC, with
  55                         # x86 first.  (That's what Apple does.)
  56                         #
  57                         V_CCOPT="$V_CCOPT -arch i386 -arch ppc"
  58                         LDFLAGS="$LDFLAGS -arch i386 -arch ppc"
  59                         ;;
  60
  61                 darwin10.*)
  62                         #
  63                         # Snow Leopard.  Build for x86-64 and x86, with
  64                         # x86-64 first.  (That's what Apple does.)
  65                         #
  66                         V_CCOPT="$V_CCOPT -arch x86_64 -arch i386"
  67                         LDFLAGS="$LDFLAGS -arch x86_64 -arch i386"
  68                         ;;
  69                 esac
  70         fi
  71         ;;
  72 esac
  73
  74 AC_ARG_WITH([smi],
  75    [AS_HELP_STRING([--with-smi],
  76      [link with libsmi (allows to load MIBs on the fly to decode SNMP packets) [default=yes, if available]])],
  77    [],
  78    [with_smi=yes])
  79
  80 if test "x$with_smi" != "xno" ; then
  81         AC_CHECK_HEADER(smi.h,
  82         [
  83                 #
  84                 # OK, we found smi.h.  Do we have libsmi with smiInit?
  85                 #
  86                 AC_CHECK_LIB(smi, smiInit,
  87                 [
  88                         #
  89                         # OK, we have libsmi with smiInit.  Can we use it?
  90                         #
  91                         AC_MSG_CHECKING([whether to enable libsmi])
  92                         savedlibs="$LIBS"
  93                         LIBS="-lsmi $LIBS"
  94                         AC_RUN_IFELSE([AC_LANG_SOURCE([[
  95 /* libsmi available check */
  96 #include <stdio.h>
  97 #include <stdlib.h>
  98 #include <string.h>
  99 #include <smi.h>
 100 int main()
 101 {
 102   int current, revision, age, n;
 103   const int required = 2;
 104   if (smiInit(""))
 105     exit(1);
 106   if (strcmp(SMI_LIBRARY_VERSION, smi_library_version))
 107     exit(2);
 108   n = sscanf(smi_library_version, "%d:%d:%d", &current, &revision, &age);
 109   if (n != 3)
 110     exit(3);
 111   if (required < current - age || required > current)
 112     exit(4);
 113   exit(0);
 114 }
 115                                 ]])
 116                                 ],
 117                                 [
 118                                         AC_MSG_RESULT(yes)
 119                                         AC_DEFINE(USE_LIBSMI, 1,
 120                                             [Define if you enable support for libsmi])
 121                                 ],
 122                                 [
 123                                         dnl autoconf documentation says that
 124                                         dnl $? contains the exit value.
 125                                         dnl reality is that it does not.
 126                                         dnl We leave this in just in case
 127                                         dnl autoconf ever comes back to
 128                                         dnl match the documentation.
 129                                         case $? in
 130                                           1) AC_MSG_RESULT(no - smiInit failed) ;;
 131                                           2) AC_MSG_RESULT(no - header/library version mismatch) ;;
 132                                           3) AC_MSG_RESULT(no - can't determine library version) ;;
 133                                           4) AC_MSG_RESULT(no - too old) ;;
 134                                           *) AC_MSG_RESULT(no) ;;
 135                                         esac
 136                                         LIBS="$savedlibs"
 137                                 ],
 138                                 [
 139                                         AC_MSG_RESULT(not when cross-compiling)
 140                                         LIBS="$savedlibs"
 141                                 ]
 142                         )
 143                 ])
 144         ])
 145 fi
 146
 147 AC_MSG_CHECKING([whether to enable the instrument functions code])
 148 AC_ARG_ENABLE([instrument-functions],
 149    [AS_HELP_STRING([--enable-instrument-functions],
 150      [enable instrument functions code [default=no]])],
 151    [],
 152    [enableval=no])
 153 case "$enableval" in
 154 yes)    AC_MSG_RESULT(yes)
 155         AC_CHECK_LIB([bfd], [bfd_init],
 156             [true],
 157             [AC_MSG_ERROR(
 158                [--enable-instrument-functions was given, but test for library libbfd failed. Please install the 'binutils-dev' package.])],
 159             [])
 160         AC_DEFINE(ENABLE_INSTRUMENT_FUNCTIONS, 1,
 161             [define if you want to build the instrument functions code])
 162         LOCALSRC="$LOCALSRC instrument-functions.c"
 163         # Add '-finstrument-functions' instrumentation option to generate
 164         # instrumentation calls for entry and exit to functions.
 165         # Try to avoid Address Space Layout Randomization (ALSR).
 166         CFLAGS="$CFLAGS -O0 -ggdb -finstrument-functions -fno-stack-protector -fno-pic"
 167         LDFLAGS="$LDFLAGS -O0 -ggdb -fno-stack-protector -no-pie"
 168         LIBS="$LIBS -lbfd"
 169         ;;
 170 *)      AC_MSG_RESULT(no)
 171         ;;
 172 esac
 173
 174 AC_MSG_CHECKING([whether to enable the possibly-buggy SMB printer])
 175 AC_ARG_ENABLE([smb],
 176    [AS_HELP_STRING([--enable-smb],
 177      [enable possibly-buggy SMB printer [default=no]])],
 178    [],
 179    [enableval=no])
 180 case "$enableval" in
 181 yes)    AC_MSG_RESULT(yes)
 182         AC_DEFINE(ENABLE_SMB, 1,
 183             [define if you want to build the possibly-buggy SMB printer])
 184         LOCALSRC="print-smb.c smbutil.c $LOCALSRC"
 185         ;;
 186 *)      AC_MSG_RESULT(no)
 187         ;;
 188 esac
 189
 190 AC_MSG_CHECKING([whether to drop root privileges by default])
 191 AC_ARG_WITH(
 192         [user],
 193         [AS_HELP_STRING([--with-user=USERNAME],
 194                 [drop privileges by default to USERNAME]
 195         )],
 196         [],
 197         [withval=no])
 198 AS_CASE(["$withval"],
 199         [no], [AC_MSG_RESULT(no)],
 200         [''|yes], [AC_MSG_ERROR([--with-user requires a username])],
 201         [
 202                 AC_DEFINE_UNQUOTED(WITH_USER, "$withval",
 203                     [define if should drop privileges by default])
 204                 AC_MSG_RESULT([yes, to user "$withval"])
 205         ]
 206 )
 207
 208 AC_MSG_CHECKING([whether to chroot])
 209 AC_ARG_WITH(
 210         [chroot],
 211         [AS_HELP_STRING([--with-chroot=DIRECTORY],
 212                 [when dropping privileges, chroot to DIRECTORY]
 213         )],
 214         [],
 215         [withval=no]
 216 )
 217 AS_CASE(["$withval"],
 218         [no], [AC_MSG_RESULT(no)],
 219         [''|yes], [AC_MSG_ERROR([--with-chroot requires a directory])],
 220         [
 221                 AC_DEFINE_UNQUOTED(WITH_CHROOT, "$withval",
 222                     [define if should chroot when dropping privileges])
 223                 AC_MSG_RESULT([yes, to directory "$withval"])
 224         ]
 225 )
 226
 227 AC_ARG_WITH(sandbox-capsicum,
 228         AS_HELP_STRING([--with-sandbox-capsicum],
 229                        [use Capsicum security functions @<:@default=yes, if available@:>@]))
 230 #
 231 # Check whether various functions are available.  If any are, set
 232 # ac_lbl_capsicum_function_seen to yes; if any are not, set
 233 # ac_lbl_capsicum_function_not_seen to yes.
 234 #
 235 # We don't check cap_rights_init(), as it's a macro, wrapping another
 236 # function, in at least some versions of FreeBSD, and AC_CHECK_FUNCS()
 237 # doesn't handle that.
 238 #
 239 # All of the ones we check for must be available in order to enable
 240 # capsicum sandboxing.
 241 #
 242 # XXX - do we need to check for all of them, or are there some that, if
 243 # present, imply others are present?
 244 #
 245 if test -z "$with_sandbox_capsicum" || test "$with_sandbox_capsicum" != "no" ; then
 246         #
 247         # First, make sure we have the required header.
 248         #
 249         AC_CHECK_HEADER(sys/capsicum.h,
 250         [
 251                 #
 252                 # We do; now make sure we have the required functions.
 253                 #
 254                 AC_CHECK_FUNCS(cap_enter cap_rights_limit cap_ioctls_limit openat,
 255                     ac_lbl_capsicum_function_seen=yes,
 256                     ac_lbl_capsicum_function_not_seen=yes)
 257         ])
 258         AC_CHECK_LIB(casper, cap_init, LIBS="$LIBS -lcasper")
 259         AC_CHECK_LIB(cap_dns, cap_gethostbyaddr, LIBS="$LIBS -lcap_dns")
 260 fi
 261 AC_MSG_CHECKING([whether to sandbox using capsicum])
 262 if test "x$ac_lbl_capsicum_function_seen" = "xyes" -a "x$ac_lbl_capsicum_function_not_seen" != "xyes"; then
 263         AC_DEFINE(HAVE_CAPSICUM, 1, [capsicum support available])
 264         AC_MSG_RESULT(yes)
 265 else
 266         AC_MSG_RESULT(no)
 267 fi
 268 AC_MSG_CHECKING([whether to sandbox using Casper library])
 269 if test "x$ac_cv_lib_casper_cap_init" = "xyes" -a "x$ac_cv_lib_cap_dns_cap_gethostbyaddr" = "xyes"; then
 270         AC_DEFINE(HAVE_CASPER, 1, [Casper support available])
 271         AC_MSG_RESULT(yes)
 272 else
 273         AC_MSG_RESULT(no)
 274 fi
 275
 276 #
 277 # We must check this before checking whether to check the OS's IPv6,
 278 # support because, on some platforms (such as SunOS 5.x), the test
 279 # program requires the extra networking libraries.
 280 #
 281 AC_LBL_LIBRARY_NET
 282
 283 AC_REPLACE_FUNCS(strlcat strlcpy strsep getservent getopt_long)
 284 AC_CHECK_FUNCS(fork vfork)
 285
 286 #
 287 # It became apparent at some point that using a suitable C99 compiler does not
 288 # automatically mean snprintf(3) implementation in the libc supports all the
 289 # modifiers and specifiers used in the project, so let's test that before the
 290 # build, not after.
 291 #
 292 # Testing the sizeof_t length modifier takes making an snprintf() call and
 293 # comparing the actual result with the expected result.  If this fails, it will
 294 # most likely happen at run time, not compile time.
 295 #
 296 # Testing the 64-bit conversion specifiers in addition to that requires the
 297 # <inttypes.h> header to be present and the macros to be defined, so if this
 298 # fails, it will more likely happen at compile time.
 299 #
 300 AC_MSG_CHECKING([whether snprintf is suitable])
 301 AC_RUN_IFELSE(
 302     [
 303         AC_LANG_SOURCE([[
 304 #include <stdio.h>
 305 #include <string.h>
 306 #include <inttypes.h>
 307 #include <sys/types.h>
 308
 309 int main()
 310 {
 311   char buf[100];
 312   uint64_t t = (uint64_t)1 << 32;
 313
 314   snprintf(buf, sizeof(buf), "%zu", sizeof(buf));
 315   if (strncmp(buf, "100", sizeof(buf)))
 316     return 1;
 317
 318   snprintf(buf, sizeof(buf), "%zd", -sizeof(buf));
 319   if (strncmp(buf, "-100", sizeof(buf)))
 320     return 2;
 321
 322   snprintf(buf, sizeof(buf), "%" PRId64, -t);
 323   if (strncmp(buf, "-4294967296", sizeof(buf)))
 324     return 3;
 325
 326   snprintf(buf, sizeof(buf), "0o%" PRIo64, t);
 327   if (strncmp(buf, "0o40000000000", sizeof(buf)))
 328     return 4;
 329
 330   snprintf(buf, sizeof(buf), "0x%" PRIx64, t);
 331   if (strncmp(buf, "0x100000000", sizeof(buf)))
 332     return 5;
 333
 334   snprintf(buf, sizeof(buf), "%" PRIu64, t);
 335   if (strncmp(buf, "4294967296", sizeof(buf)))
 336     return 6;
 337
 338   return 0;
 339 }
 340         ]])
 341     ],
 342     [
 343         AC_MSG_RESULT(yes)
 344     ],
 345     [
 346         AC_MSG_RESULT(no)
 347         AC_MSG_ERROR(
 348 [The snprintf(3) implementation in this libc is not suitable,
 349 tcpdump would not work correctly even if it managed to compile.])
 350     ],
 351     [
 352         AC_MSG_RESULT(not while cross-compiling)
 353     ]
 354 )
 355
 356 AC_CHECK_LIB(rpc, main)         dnl It's unclear why we might need -lrpc
 357
 358 dnl Some platforms may need -lnsl for getrpcbynumber.
 359 AC_SEARCH_LIBS(getrpcbynumber, nsl,
 360     AC_DEFINE(HAVE_GETRPCBYNUMBER, 1, [define if you have getrpcbynumber()]))
 361
 362 AC_LBL_LIBPCAP(V_PCAPDEP, V_INCLS)
 363
 364 #
 365 # Check for these after AC_LBL_LIBPCAP, so we link with the appropriate
 366 # libraries (e.g., "-lsocket -lnsl" on Solaris).
 367 #
 368 # You are in a twisty little maze of UN*Xes, all different.
 369 # Some might not have ether_ntohost().
 370 # Some might have it and declare it in <net/ethernet.h>.
 371 # Some might have it and declare it in <netinet/ether.h>
 372 # Some might have it and declare it in <sys/ethernet.h>.
 373 # Some might have it and declare it in <arpa/inet.h>.
 374 # Some might have it and declare it in <netinet/if_ether.h>.
 375 # Some might have it and not declare it in any header file.
 376 #
 377 # Before you is a C compiler.
 378 #
 379 AC_CHECK_FUNCS(ether_ntohost, [
 380     AC_CACHE_CHECK(for buggy ether_ntohost, ac_cv_buggy_ether_ntohost, [
 381         AC_RUN_IFELSE([AC_LANG_SOURCE([[
 382                 #include <netdb.h>
 383                 #include <netinet/ether.h>
 384                 #include <stdlib.h>
 385                 #include <sys/types.h>
 386                 #include <sys/param.h>
 387                 #include <sys/socket.h>
 388
 389                 int
 390                 main(int argc, char **argv)
 391                 {
 392                         u_char ea[6] = { 0xff, 0xff, 0xff, 0xff, 0xff };
 393                         char name[MAXHOSTNAMELEN];
 394
 395                         ether_ntohost(name, (struct ether_addr *)ea);
 396                         exit(0);
 397                 }
 398         ]])
 399         ], [ac_cv_buggy_ether_ntohost=no],
 400            [ac_cv_buggy_ether_ntohost=yes],
 401            [ac_cv_buggy_ether_ntohost="not while cross-compiling"])])
 402     if test "$ac_cv_buggy_ether_ntohost" = "no"; then
 403         AC_DEFINE(USE_ETHER_NTOHOST, 1,
 404             [define if you have ether_ntohost() and it works])
 405     fi
 406 ])
 407 if test "$ac_cv_func_ether_ntohost" = yes -a \
 408     "$ac_cv_buggy_ether_ntohost" = "no"; then
 409         #
 410         # OK, we have ether_ntohost().  Is it declared in <net/ethernet.h>?
 411         #
 412         # This test fails if we don't have <net/ethernet.h> or if we do
 413         # but it doesn't declare ether_ntohost().
 414         #
 415         AC_CHECK_DECL(ether_ntohost,
 416             [
 417                 AC_DEFINE(NET_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
 418                     [Define to 1 if net/ethernet.h declares `ether_ntohost'])
 419             ],,
 420             [
 421 #include <net/ethernet.h>
 422             ])
 423         #
 424         # Did that succeed?
 425         #
 426         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 427                 #
 428                 # No, how about <netinet/ether.h>, as on Linux?
 429                 #
 430                 # This test fails if we don't have <netinet/ether.h>
 431                 # or if we do but it doesn't declare ether_ntohost().
 432                 #
 433                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 434                 # treat the previous failure as a cached value and
 435                 # suppress the next test.
 436                 #
 437                 unset ac_cv_have_decl_ether_ntohost
 438                 AC_CHECK_DECL(ether_ntohost,
 439                     [
 440                         AC_DEFINE(NETINET_ETHER_H_DECLARES_ETHER_NTOHOST,,
 441                             [Define to 1 if netinet/ether.h declares `ether_ntohost'])
 442                     ],,
 443                     [
 444 #include <netinet/ether.h>
 445                     ])
 446         fi
 447         #
 448         # Did that succeed?
 449         #
 450         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 451                 #
 452                 # No, how about <sys/ethernet.h>, as on Solaris 10
 453                 # and later?
 454                 #
 455                 # This test fails if we don't have <sys/ethernet.h>
 456                 # or if we do but it doesn't declare ether_ntohost().
 457                 #
 458                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 459                 # treat the previous failure as a cached value and
 460                 # suppress the next test.
 461                 #
 462                 unset ac_cv_have_decl_ether_ntohost
 463                 AC_CHECK_DECL(ether_ntohost,
 464                     [
 465                         AC_DEFINE(SYS_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
 466                             [Define to 1 if sys/ethernet.h declares `ether_ntohost'])
 467                     ],,
 468                     [
 469 #include <sys/ethernet.h>
 470                     ])
 471         fi
 472         #
 473         # Did that succeed?
 474         #
 475         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 476                 #
 477                 # No, how about <arpa/inet.h>, as in AIX?
 478                 #
 479                 # This test fails if we don't have <arpa/inet.h>
 480                 # (if we have ether_ntohost(), we should have
 481                 # networking, and if we have networking, we should
 482                 # have <arpa/inet.h>) or if we do but it doesn't
 483                 # declare ether_ntohost().
 484                 #
 485                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 486                 # treat the previous failure as a cached value and
 487                 # suppress the next test.
 488                 #
 489                 unset ac_cv_have_decl_ether_ntohost
 490                 AC_CHECK_DECL(ether_ntohost,
 491                     [
 492                         AC_DEFINE(ARPA_INET_H_DECLARES_ETHER_NTOHOST,,
 493                             [Define to 1 if arpa/inet.h declares `ether_ntohost'])
 494                     ],,
 495                     [
 496 #include <arpa/inet.h>
 497                     ])
 498         fi
 499         #
 500         # Did that succeed?
 501         #
 502         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 503                 #
 504                 # No, how about <netinet/if_ether.h>?
 505                 # On some platforms, it requires <net/if.h> and
 506                 # <netinet/in.h>, and we always include it with
 507                 # both of them, so test it with both of them.
 508                 #
 509                 # This test fails if we don't have <netinet/if_ether.h>
 510                 # and the headers we include before it, or if we do but
 511                 # <netinet/if_ether.h> doesn't declare ether_hostton().
 512                 #
 513                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 514                 # treat the previous failure as a cached value and
 515                 # suppress the next test.
 516                 #
 517                 unset ac_cv_have_decl_ether_ntohost
 518                 AC_CHECK_DECL(ether_ntohost,
 519                     [
 520                         AC_DEFINE(NETINET_IF_ETHER_H_DECLARES_ETHER_NTOHOST,,
 521                             [Define to 1 if netinet/if_ether.h declares `ether_ntohost'])
 522                     ],,
 523                     [
 524 #include <sys/types.h>
 525 #include <sys/socket.h>
 526 #include <net/if.h>
 527 #include <netinet/in.h>
 528 #include <netinet/if_ether.h>
 529                     ])
 530         fi
 531         #
 532         # After all that, is ether_ntohost() declared?
 533         #
 534         if test "$ac_cv_have_decl_ether_ntohost" = yes; then
 535                 #
 536                 # Yes.
 537                 #
 538                 AC_DEFINE(HAVE_DECL_ETHER_NTOHOST, 1,
 539                     [Define to 1 if you have the declaration of `ether_ntohost'])
 540         else
 541                 #
 542                 # No, we'll have to declare it ourselves.
 543                 # Do we have "struct ether_addr" if we include
 544                 # <netinet/if_ether.h>?
 545                 #
 546                 AC_CHECK_TYPES(struct ether_addr,,,
 547                     [
 548                         #include <sys/types.h>
 549                         #include <sys/socket.h>
 550                         #include <net/if.h>
 551                         #include <netinet/in.h>
 552                         #include <netinet/if_ether.h>
 553                     ])
 554         fi
 555 fi
 556
 557 dnl
 558 dnl Check for "pcap_list_datalinks()" and use a substitute version if
 559 dnl it's not present.  If it is present, check for "pcap_free_datalinks()";
 560 dnl if it's not present, we don't replace it for now.  (We could do so
 561 dnl on UN*X, but not on Windows, where hilarity ensues if a program
 562 dnl built with one version of the MSVC support library tries to free
 563 dnl something allocated by a library built with another version of
 564 dnl the MSVC support library.)
 565 dnl
 566 AC_CHECK_FUNC(pcap_list_datalinks,
 567         [
 568             AC_DEFINE(HAVE_PCAP_LIST_DATALINKS, 1,
 569                 [define if libpcap has pcap_list_datalinks()])
 570             AC_CHECK_FUNCS(pcap_free_datalinks)
 571         ],
 572         [
 573             AC_LIBOBJ(datalinks)
 574         ])
 575
 576 dnl
 577 dnl Check for "pcap_datalink_name_to_val()", and use a substitute
 578 dnl version if it's not present.  If it is present, check for
 579 dnl "pcap_datalink_val_to_description()", and if we don't have it,
 580 dnl use a substitute version.
 581 dnl
 582 AC_CHECK_FUNC(pcap_datalink_name_to_val,
 583         [
 584             AC_DEFINE(HAVE_PCAP_DATALINK_NAME_TO_VAL, 1,
 585                 [define if libpcap has pcap_datalink_name_to_val()])
 586             AC_CHECK_FUNC(pcap_datalink_val_to_description,
 587                 AC_DEFINE(HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION, 1,
 588                     [define if libpcap has pcap_datalink_val_to_description()]),
 589                 [
 590                     AC_LIBOBJ(dlnames)
 591                 ])
 592         ],
 593         [
 594             AC_LIBOBJ(dlnames)
 595         ])
 596
 597 dnl
 598 dnl Check for "pcap_set_datalink()"; you can't substitute for it if
 599 dnl it's absent (it has hooks into libpcap), so just define the
 600 dnl HAVE_ value if it's there.
 601 dnl
 602 AC_CHECK_FUNCS(pcap_set_datalink)
 603
 604 dnl
 605 dnl Check for "pcap_breakloop()"; you can't substitute for it if
 606 dnl it's absent (it has hooks into the live capture routines),
 607 dnl so just define the HAVE_ value if it's there.
 608 dnl
 609 AC_CHECK_FUNCS(pcap_breakloop)
 610
 611 #
 612 # Do we have the new open API?  Check for pcap_create, and assume that,
 613 # if we do, we also have pcap_activate() and the other new routines
 614 # introduced in libpcap 1.0.0.
 615 #
 616 AC_CHECK_FUNCS(pcap_create)
 617 if test $ac_cv_func_pcap_create = "yes" ; then
 618         #
 619         # OK, do we have pcap_set_tstamp_type?  If so, assume we have
 620         # pcap_list_tstamp_types and pcap_free_tstamp_types as well.
 621         #
 622         AC_CHECK_FUNCS(pcap_set_tstamp_type)
 623         #
 624         # And do we have pcap_set_tstamp_precision?  If so, we assume
 625         # we also have pcap_open_offline_with_tstamp_precision.
 626         #
 627         AC_CHECK_FUNCS(pcap_set_tstamp_precision)
 628 fi
 629
 630 #
 631 # Check for a miscellaneous collection of functions which we use
 632 # if we have them.
 633 #
 634 AC_CHECK_FUNCS(pcap_findalldevs)
 635 AC_CHECK_FUNCS(pcap_dump_flush pcap_lib_version)
 636 if test $ac_cv_func_pcap_lib_version = "no" ; then
 637     AC_MSG_CHECKING(whether pcap_version is defined by libpcap)
 638     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
 639         extern char pcap_version[];
 640
 641         return (int)pcap_version;
 642        ]])
 643        ],
 644        [ac_lbl_cv_pcap_version_defined=yes],
 645        [ac_lbl_cv_pcap_version_defined=no])
 646     if test "$ac_lbl_cv_pcap_version_defined" = yes ; then
 647         AC_MSG_RESULT(yes)
 648         AC_DEFINE(HAVE_PCAP_VERSION, 1, [define if libpcap has pcap_version])
 649     else
 650         AC_MSG_RESULT(no)
 651     fi
 652 fi
 653 AC_CHECK_FUNCS(pcap_setdirection pcap_set_immediate_mode pcap_dump_ftell64)
 654 AC_CHECK_FUNCS(pcap_open pcap_findalldevs_ex)
 655 AC_REPLACE_FUNCS(pcap_dump_ftell)
 656
 657 #
 658 # Check for special debugging functions
 659 #
 660 AC_CHECK_FUNCS(pcap_set_parser_debug)
 661 if test "$ac_cv_func_pcap_set_parser_debug" = "no" ; then
 662         #
 663         # OK, we don't have pcap_set_parser_debug() to set the libpcap
 664         # filter expression parser debug flag; can we directly set the
 665         # flag?
 666         AC_MSG_CHECKING(whether pcap_debug is defined by libpcap)
 667         AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
 668                 extern int pcap_debug;
 669
 670                 return pcap_debug;
 671            ]])
 672            ],
 673            [ac_lbl_cv_pcap_debug_defined=yes],
 674            [ac_lbl_cv_pcap_debug_defined=no])
 675         if test "$ac_lbl_cv_pcap_debug_defined" = yes ; then
 676                 AC_MSG_RESULT(yes)
 677                 AC_DEFINE(HAVE_PCAP_DEBUG, 1, [define if libpcap has pcap_debug])
 678         else
 679                 AC_MSG_RESULT(no)
 680                 #
 681                 # OK, what about "yydebug"?
 682                 #
 683                 AC_MSG_CHECKING(whether yydebug is defined by libpcap)
 684                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
 685                         extern int yydebug;
 686
 687                         return yydebug;
 688                    ]])
 689                    ],
 690                    [ac_lbl_cv_yydebug_defined=yes],
 691                    [ac_lbl_cv_yydebug_defined=no])
 692                 if test "$ac_lbl_cv_yydebug_defined" = yes ; then
 693                         AC_MSG_RESULT(yes)
 694                         AC_DEFINE(HAVE_YYDEBUG, 1, [define if libpcap has yydebug])
 695                 else
 696                         AC_MSG_RESULT(no)
 697                 fi
 698         fi
 699 fi
 700 AC_CHECK_FUNCS(pcap_set_optimizer_debug)
 701 AC_REPLACE_FUNCS(bpf_dump)      dnl moved to libpcap in 0.6
 702
 703 #
 704 # Assume V7/BSD convention for man pages (file formats in section 5,
 705 # miscellaneous info in section 7).
 706 #
 707 MAN_FILE_FORMATS=5
 708 MAN_MISC_INFO=7
 709 case "$host_os" in
 710
 711 hpux*)
 712         #
 713         # Use System V conventions for man pages.
 714         #
 715         MAN_FILE_FORMATS=4
 716         MAN_MISC_INFO=5
 717         ;;
 718
 719 solaris*)
 720         #
 721         # Use System V conventions for man pages.
 722         #
 723         MAN_FILE_FORMATS=4
 724         MAN_MISC_INFO=5
 725         ;;
 726 esac
 727
 728 savedcppflags="$CPPFLAGS"
 729 CPPFLAGS="$CPPFLAGS $V_INCLS"
 730
 731 #
 732 # Check whether we have pcap/pcap-inttypes.h.
 733 # If we do, we use that to get the C99 types defined.
 734 #
 735 AC_CHECK_HEADERS(pcap/pcap-inttypes.h)
 736
 737 #
 738 # At compile time HAVE_PCAP_FINDALLDEVS depends on HAVE_PCAP_IF_T.
 739 #
 740 AC_CHECK_TYPES(pcap_if_t, , , [#include <pcap.h>])
 741
 742 CPPFLAGS="$savedcppflags"
 743
 744 #
 745 # Define the old BSD specified-width types in terms of the C99 types;
 746 # we may need them with libpcap include files.
 747 #
 748 AC_CHECK_TYPE([u_int8_t], ,
 749         [AC_DEFINE([u_int8_t], [uint8_t],
 750         [Define to `uint8_t' if u_int8_t not defined.])],
 751         [AC_INCLUDES_DEFAULT
 752 #include <sys/types.h>
 753 ])
 754 AC_CHECK_TYPE([u_int16_t], ,
 755         [AC_DEFINE([u_int16_t], [uint16_t],
 756         [Define to `uint16_t' if u_int16_t not defined.])],
 757         [AC_INCLUDES_DEFAULT
 758 #include <sys/types.h>
 759 ])
 760 AC_CHECK_TYPE([u_int32_t], ,
 761         [AC_DEFINE([u_int32_t], [uint32_t],
 762         [Define to `uint32_t' if u_int32_t not defined.])],
 763         [AC_INCLUDES_DEFAULT
 764 #include <sys/types.h>
 765 ])
 766 AC_CHECK_TYPE([u_int64_t], ,
 767         [AC_DEFINE([u_int64_t], [uint64_t],
 768         [Define to `uint64_t' if u_int64_t not defined.])],
 769         [AC_INCLUDES_DEFAULT
 770 #include <sys/types.h>
 771 ])
 772
 773 AC_PROG_RANLIB
 774 AC_CHECK_TOOL([AR], [ar])
 775
 776 AC_LBL_DEVEL(V_CCOPT)
 777
 778 # Check for OpenSSL/libressl libcrypto
 779 AC_MSG_CHECKING(whether to use OpenSSL/libressl libcrypto)
 780 # Specify location for both includes and libraries.
 781 want_libcrypto=ifavailable
 782 AC_ARG_WITH(crypto,
 783     AS_HELP_STRING([--with-crypto]@<:@=DIR@:>@,
 784                    [use OpenSSL/libressl libcrypto (located in directory DIR, if specified) @<:@default=yes, if available@:>@]),
 785 [
 786         if test $withval = no
 787         then
 788                 # User doesn't want to link with libcrypto.
 789                 want_libcrypto=no
 790                 AC_MSG_RESULT(no)
 791         elif test $withval = yes
 792         then
 793                 # User wants to link with libcrypto but hasn't specified
 794                 # a directory.
 795                 want_libcrypto=yes
 796                 AC_MSG_RESULT(yes)
 797         else
 798                 # User wants to link with libcrypto and has specified
 799                 # a directory, so use the provided value.
 800                 want_libcrypto=yes
 801                 libcrypto_root=$withval
 802                 AC_MSG_RESULT([yes, using the version installed in $withval])
 803
 804                 #
 805                 # Put the subdirectories of the libcrypto root directory
 806                 # at the front of the header and library search path.
 807                 #
 808                 CFLAGS="-I$withval/include $CFLAGS"
 809                 LIBS="-L$withval/lib $LIBS"
 810         fi
 811 ],[
 812         #
 813         # Use libcrypto if it's present, otherwise don't; no directory
 814         # was specified.
 815         #
 816         want_libcrypto=ifavailable
 817         AC_MSG_RESULT([yes, if available])
 818 ])
 819 if test "$want_libcrypto" != "no"; then
 820         #
 821         # Don't check for libcrypto unless we have its headers;
 822         # Apple, bless their pointy little heads, apparently ship
 823         # libcrypto as a library, but not the header files, in
 824         # El Capitan, probably because they don't want you writing
 825         # nasty portable code that could run on other UN*Xes, they
 826         # want you writing code that uses their Shiny New Crypto
 827         # Library and that only runs on macOS.
 828         #
 829         AC_CHECK_HEADER(openssl/crypto.h,
 830         [
 831                 AC_CHECK_LIB(crypto, DES_cbc_encrypt)
 832                 if test "$ac_cv_lib_crypto_DES_cbc_encrypt" = "yes"; then
 833                         AC_CHECK_HEADERS(openssl/evp.h)
 834                         #
 835                         # OK, then:
 836                         #
 837                         # 1) do we have EVP_CIPHER_CTX_new?
 838                         # If so, we use it to allocate an
 839                         # EVP_CIPHER_CTX, as EVP_CIPHER_CTX may be
 840                         # opaque; otherwise, we allocate it ourselves.
 841                         #
 842                         # 2) do we have EVP_DecryptInit_ex()?
 843                         # If so, we use it, because we need to be
 844                         # able to make two "initialize the cipher"
 845                         # calls, one with the cipher and key, and
 846                         # one with the IV, and, as of OpenSSL 1.1,
 847                         # You Can't Do That with EVP_DecryptInit(),
 848                         # because a call to EVP_DecryptInit() will
 849                         # unconditionally clear the context, and
 850                         # if you don't supply a cipher, it'll
 851                         # clear the cipher, rendering the context
 852                         # unusable and causing a crash.
 853                         #
 854                         AC_CHECK_FUNCS(EVP_CIPHER_CTX_new EVP_DecryptInit_ex)
 855                 fi
 856         ])
 857 fi
 858
 859 # Check for libcap-ng
 860 AC_MSG_CHECKING(whether to use libcap-ng)
 861 # Specify location for both includes and libraries.
 862 want_libcap_ng=ifavailable
 863 AC_ARG_WITH(cap_ng,
 864     AS_HELP_STRING([--with-cap-ng],
 865                    [use libcap-ng @<:@default=yes, if available@:>@]),
 866 [
 867         if test $withval = no
 868         then
 869                 want_libcap_ng=no
 870                 AC_MSG_RESULT(no)
 871         elif test $withval = yes
 872         then
 873                 want_libcap_ng=yes
 874                 AC_MSG_RESULT(yes)
 875         fi
 876 ],[
 877         #
 878         # Use libcap-ng if it's present, otherwise don't.
 879         #
 880         want_libcap_ng=ifavailable
 881         AC_MSG_RESULT([yes, if available])
 882 ])
 883 if test "$want_libcap_ng" != "no"; then
 884         AC_CHECK_LIB(cap-ng, capng_change_id)
 885         AC_CHECK_HEADERS(cap-ng.h)
 886 fi
 887
 888 dnl
 889 dnl set additional include path if necessary
 890 if test "$missing_includes" = "yes"; then
 891         CPPFLAGS="$CPPFLAGS -I$srcdir/missing"
 892         V_INCLS="$V_INCLS -I$srcdir/missing"
 893 fi
 894
 895 AC_SUBST(V_CCOPT)
 896 AC_SUBST(V_DEFS)
 897 AC_SUBST(V_INCLS)
 898 AC_SUBST(V_PCAPDEP)
 899 AC_SUBST(LOCALSRC)
 900 AC_SUBST(MAN_FILE_FORMATS)
 901 AC_SUBST(MAN_MISC_INFO)
 902
 903 AC_PROG_INSTALL
 904
 905 AC_CONFIG_HEADERS([config.h])
 906
 907 AC_CONFIG_COMMANDS([.devel],[[if test -f .devel; then
 908         echo timestamp > stamp-h
 909         cat $srcdir/Makefile-devel-adds >> Makefile
 910         make depend || exit 1
 911 fi]])
 912 AC_CONFIG_FILES([Makefile tcpdump.1])
 913 AC_OUTPUT
 914 exit 0