The Tcpdump Group git mirrors - tcpdump/blob - aclocal.m4

   1 dnl @(#) $Header: /tcpdump/master/tcpdump/aclocal.m4,v 1.87 2002-08-04 21:20:29 guy Exp $ (LBL)
   2 dnl
   3 dnl Copyright (c) 1995, 1996, 1997, 1998
   4 dnl     The Regents of the University of California.  All rights reserved.
   5 dnl
   6 dnl Redistribution and use in source and binary forms, with or without
   7 dnl modification, are permitted provided that: (1) source code distributions
   8 dnl retain the above copyright notice and this paragraph in its entirety, (2)
   9 dnl distributions including binary code include the above copyright notice and
  10 dnl this paragraph in its entirety in the documentation or other materials
  11 dnl provided with the distribution, and (3) all advertising materials mentioning
  12 dnl features or use of this software display the following acknowledgement:
  13 dnl ``This product includes software developed by the University of California,
  14 dnl Lawrence Berkeley Laboratory and its contributors.'' Neither the name of
  15 dnl the University nor the names of its contributors may be used to endorse
  16 dnl or promote products derived from this software without specific prior
  17 dnl written permission.
  18 dnl THIS SOFTWARE IS PROVIDED ``AS IS'' AND WITHOUT ANY EXPRESS OR IMPLIED
  19 dnl WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED WARRANTIES OF
  20 dnl MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE.
  21 dnl
  22 dnl LBL autoconf macros
  23 dnl
  24
  25 dnl
  26 dnl Determine which compiler we're using (cc or gcc)
  27 dnl If using gcc, determine the version number
  28 dnl If using cc, require that it support ansi prototypes
  29 dnl If using gcc, use -O2 (otherwise use -O)
  30 dnl If using cc, explicitly specify /usr/local/include
  31 dnl
  32 dnl usage:
  33 dnl
  34 dnl     AC_LBL_C_INIT(copt, incls)
  35 dnl
  36 dnl results:
  37 dnl
  38 dnl     $1 (copt set)
  39 dnl     $2 (incls set)
  40 dnl     CC
  41 dnl     LDFLAGS
  42 dnl     ac_cv_lbl_gcc_vers
  43 dnl     LBL_CFLAGS
  44 dnl
  45 AC_DEFUN(AC_LBL_C_INIT,
  46     [AC_PREREQ(2.12)
  47     AC_BEFORE([$0], [AC_PROG_CC])
  48     AC_BEFORE([$0], [AC_LBL_FIXINCLUDES])
  49     AC_BEFORE([$0], [AC_LBL_DEVEL])
  50     AC_ARG_WITH(gcc, [  --without-gcc           don't use gcc])
  51     $1="-O"
  52     $2=""
  53     if test "${srcdir}" != "." ; then
  54             $2="-I\$(srcdir)"
  55     fi
  56     if test "${CFLAGS+set}" = set; then
  57             LBL_CFLAGS="$CFLAGS"
  58     fi
  59     if test -z "$CC" ; then
  60             case "$host_os" in
  61
  62             bsdi*)
  63                     AC_CHECK_PROG(SHLICC2, shlicc2, yes, no)
  64                     if test $SHLICC2 = yes ; then
  65                             CC=shlicc2
  66                             export CC
  67                     fi
  68                     ;;
  69             esac
  70     fi
  71     if test -z "$CC" -a "$with_gcc" = no ; then
  72             CC=cc
  73             export CC
  74     fi
  75     AC_PROG_CC
  76     if test "$GCC" = yes ; then
  77             if test "$SHLICC2" = yes ; then
  78                     ac_cv_lbl_gcc_vers=2
  79                     $1="-O2"
  80             else
  81                     AC_MSG_CHECKING(gcc version)
  82                     AC_CACHE_VAL(ac_cv_lbl_gcc_vers,
  83                         ac_cv_lbl_gcc_vers=`$CC -v 2>&1 | \
  84                             sed -e '/^gcc version /!d' \
  85                                 -e 's/^gcc version //' \
  86                                 -e 's/ .*//' -e 's/^[[[^0-9]]]*//' \
  87                                 -e 's/\..*//'`)
  88                     AC_MSG_RESULT($ac_cv_lbl_gcc_vers)
  89                     if test $ac_cv_lbl_gcc_vers -gt 1 ; then
  90                             $1="-O2"
  91                     fi
  92             fi
  93     else
  94             AC_MSG_CHECKING(that $CC handles ansi prototypes)
  95             AC_CACHE_VAL(ac_cv_lbl_cc_ansi_prototypes,
  96                 AC_TRY_COMPILE(
  97                     [#include <sys/types.h>],
  98                     [int frob(int, char *)],
  99                     ac_cv_lbl_cc_ansi_prototypes=yes,
 100                     ac_cv_lbl_cc_ansi_prototypes=no))
 101             AC_MSG_RESULT($ac_cv_lbl_cc_ansi_prototypes)
 102             if test $ac_cv_lbl_cc_ansi_prototypes = no ; then
 103                     case "$host_os" in
 104
 105                     hpux*)
 106                             AC_MSG_CHECKING(for HP-UX ansi compiler ($CC -Aa -D_HPUX_SOURCE))
 107                             savedcflags="$CFLAGS"
 108                             CFLAGS="-Aa -D_HPUX_SOURCE $CFLAGS"
 109                             AC_CACHE_VAL(ac_cv_lbl_cc_hpux_cc_aa,
 110                                 AC_TRY_COMPILE(
 111                                     [#include <sys/types.h>],
 112                                     [int frob(int, char *)],
 113                                     ac_cv_lbl_cc_hpux_cc_aa=yes,
 114                                     ac_cv_lbl_cc_hpux_cc_aa=no))
 115                             AC_MSG_RESULT($ac_cv_lbl_cc_hpux_cc_aa)
 116                             if test $ac_cv_lbl_cc_hpux_cc_aa = no ; then
 117                                     AC_MSG_ERROR(see the INSTALL doc for more info)
 118                             fi
 119                             CFLAGS="$savedcflags"
 120                             V_CCOPT="-Aa $V_CCOPT"
 121                             AC_DEFINE(_HPUX_SOURCE)
 122                             ;;
 123
 124                     *)
 125                             AC_MSG_ERROR(see the INSTALL doc for more info)
 126                             ;;
 127                     esac
 128             fi
 129             $2="$$2 -I/usr/local/include"
 130             LDFLAGS="$LDFLAGS -L/usr/local/lib"
 131
 132             case "$host_os" in
 133
 134             irix*)
 135                     V_CCOPT="$V_CCOPT -xansi -signed -O"
 136                     ;;
 137
 138             osf*)
 139                     V_CCOPT="$V_CCOPT -std1 -O"
 140                     ;;
 141
 142             ultrix*)
 143                     AC_MSG_CHECKING(that Ultrix $CC hacks const in prototypes)
 144                     AC_CACHE_VAL(ac_cv_lbl_cc_const_proto,
 145                         AC_TRY_COMPILE(
 146                             [#include <sys/types.h>],
 147                             [struct a { int b; };
 148                             void c(const struct a *)],
 149                             ac_cv_lbl_cc_const_proto=yes,
 150                             ac_cv_lbl_cc_const_proto=no))
 151                     AC_MSG_RESULT($ac_cv_lbl_cc_const_proto)
 152                     if test $ac_cv_lbl_cc_const_proto = no ; then
 153                             AC_DEFINE(const,)
 154                     fi
 155                     ;;
 156             esac
 157     fi
 158 ])
 159
 160 #
 161 # Try compiling a sample of the type of code that appears in
 162 # gencode.c with "inline", "__inline__", and "__inline".
 163 #
 164 # Autoconf's AC_C_INLINE, at least in autoconf 2.13, isn't good enough,
 165 # as it just tests whether a function returning "int" can be inlined;
 166 # at least some versions of HP's C compiler can inline that, but can't
 167 # inline a function that returns a struct pointer.
 168 #
 169 AC_DEFUN(AC_LBL_C_INLINE,
 170     [AC_MSG_CHECKING(for inline)
 171     AC_CACHE_VAL(ac_cv_lbl_inline, [
 172         ac_cv_lbl_inline=""
 173         ac_lbl_cc_inline=no
 174         for ac_lbl_inline in inline __inline__ __inline
 175         do
 176             AC_TRY_COMPILE(
 177                 [#define inline $ac_lbl_inline
 178                 static inline struct iltest *foo(void);
 179                 struct iltest {
 180                     int iltest1;
 181                     int iltest2;
 182                 };
 183
 184                 static inline struct iltest *
 185                 foo()
 186                 {
 187                     static struct iltest xxx;
 188
 189                     return &xxx;
 190                 }],,ac_lbl_cc_inline=yes,)
 191             if test "$ac_lbl_cc_inline" = yes ; then
 192                 break;
 193             fi
 194         done
 195         if test "$ac_lbl_cc_inline" = yes ; then
 196             ac_cv_lbl_inline=$ac_lbl_inline
 197         fi])
 198     if test ! -z "$ac_cv_lbl_inline" ; then
 199         AC_MSG_RESULT($ac_cv_lbl_inline)
 200     else
 201         AC_MSG_RESULT(no)
 202     fi
 203     AC_DEFINE_UNQUOTED(inline, $ac_cv_lbl_inline, [Define as token for inline if inlining supported])])
 204
 205 dnl
 206 dnl Use pfopen.c if available and pfopen() not in standard libraries
 207 dnl Require libpcap
 208 dnl Look for libpcap in ..
 209 dnl Use the installed libpcap if there is no local version
 210 dnl
 211 dnl usage:
 212 dnl
 213 dnl     AC_LBL_LIBPCAP(pcapdep, incls)
 214 dnl
 215 dnl results:
 216 dnl
 217 dnl     $1 (pcapdep set)
 218 dnl     $2 (incls appended)
 219 dnl     LIBS
 220 dnl     LBL_LIBS
 221 dnl
 222 AC_DEFUN(AC_LBL_LIBPCAP,
 223     [AC_REQUIRE([AC_LBL_LIBRARY_NET])
 224     dnl
 225     dnl save a copy before locating libpcap.a
 226     dnl
 227     LBL_LIBS="$LIBS"
 228     pfopen=/usr/examples/packetfilter/pfopen.c
 229     if test -f $pfopen ; then
 230             AC_CHECK_FUNCS(pfopen)
 231             if test $ac_cv_func_pfopen = "no" ; then
 232                     AC_MSG_RESULT(Using $pfopen)
 233                     LIBS="$LIBS $pfopen"
 234             fi
 235     fi
 236     AC_MSG_CHECKING(for local pcap library)
 237     libpcap=FAIL
 238     lastdir=FAIL
 239     places=`ls .. | sed -e 's,/$,,' -e 's,^,../,' | \
 240         egrep '/libpcap-[[0-9]]*.[[0-9]]*(.[[0-9]]*)?([[ab]][[0-9]]*)?$'`
 241     for dir in $places ../libpcap libpcap ; do
 242             basedir=`echo $dir | sed -e 's/[[ab]][[0-9]]*$//'`
 243             if test $lastdir = $basedir ; then
 244                     dnl skip alphas when an actual release is present
 245                     continue;
 246             fi
 247             lastdir=$dir
 248             if test -r $dir/libpcap.a ; then
 249                     libpcap=$dir/libpcap.a
 250                     d=$dir
 251                     dnl continue and select the last one that exists
 252             fi
 253     done
 254     if test $libpcap = FAIL ; then
 255             AC_MSG_RESULT(not found)
 256             AC_CHECK_LIB(pcap, main, libpcap="-lpcap")
 257             if test $libpcap = FAIL ; then
 258                     AC_MSG_ERROR(see the INSTALL doc for more info)
 259             fi
 260     else
 261             $1=$libpcap
 262             places=`ls $srcdir/.. | sed -e 's,/$,,' -e "s,^,$srcdir/../," | \
 263                         egrep '/libpcap-[[0-9]]*.[[0-9]]*(.[[0-9]]*)?([[ab]][[0-9]]*)?$'`
 264             if test -r $d/pcap.h; then
 265                     $2="-I$d $$2"
 266             elif test -r $places/pcap.h; then
 267                     $2="-I$places $$2"
 268             else
 269                     AC_MSG_ERROR(cannot find pcap.h, see INSTALL)
 270             fi
 271             AC_MSG_RESULT($libpcap)
 272     fi
 273     LIBS="$libpcap $LIBS"
 274     case "$host_os" in
 275
 276     aix*)
 277             pseexe="/lib/pse.exp"
 278             AC_MSG_CHECKING(for $pseexe)
 279             if test -f $pseexe ; then
 280                     AC_MSG_RESULT(yes)
 281                     LIBS="$LIBS -I:$pseexe"
 282             fi
 283             ;;
 284     esac])
 285
 286 dnl
 287 dnl Define RETSIGTYPE and RETSIGVAL
 288 dnl
 289 dnl usage:
 290 dnl
 291 dnl     AC_LBL_TYPE_SIGNAL
 292 dnl
 293 dnl results:
 294 dnl
 295 dnl     RETSIGTYPE (defined)
 296 dnl     RETSIGVAL (defined)
 297 dnl
 298 AC_DEFUN(AC_LBL_TYPE_SIGNAL,
 299     [AC_BEFORE([$0], [AC_LBL_LIBPCAP])
 300     AC_TYPE_SIGNAL
 301     if test "$ac_cv_type_signal" = void ; then
 302             AC_DEFINE(RETSIGVAL,)
 303     else
 304             AC_DEFINE(RETSIGVAL,(0))
 305     fi
 306     case "$host_os" in
 307
 308     irix*)
 309             AC_DEFINE(_BSD_SIGNALS)
 310             ;;
 311
 312     *)
 313             dnl prefer sigaction() to sigset()
 314             AC_CHECK_FUNCS(sigaction)
 315             if test $ac_cv_func_sigaction = no ; then
 316                     AC_CHECK_FUNCS(sigset)
 317             fi
 318             ;;
 319     esac])
 320
 321 dnl
 322 dnl If using gcc, make sure we have ANSI ioctl definitions
 323 dnl
 324 dnl usage:
 325 dnl
 326 dnl     AC_LBL_FIXINCLUDES
 327 dnl
 328 AC_DEFUN(AC_LBL_FIXINCLUDES,
 329     [if test "$GCC" = yes ; then
 330             AC_MSG_CHECKING(for ANSI ioctl definitions)
 331             AC_CACHE_VAL(ac_cv_lbl_gcc_fixincludes,
 332                 AC_TRY_COMPILE(
 333                     [/*
 334                      * This generates a "duplicate case value" when fixincludes
 335                      * has not be run.
 336                      */
 337 #               include <sys/types.h>
 338 #               include <sys/time.h>
 339 #               include <sys/ioctl.h>
 340 #               ifdef HAVE_SYS_IOCCOM_H
 341 #               include <sys/ioccom.h>
 342 #               endif],
 343                     [switch (0) {
 344                     case _IO('A', 1):;
 345                     case _IO('B', 1):;
 346                     }],
 347                     ac_cv_lbl_gcc_fixincludes=yes,
 348                     ac_cv_lbl_gcc_fixincludes=no))
 349             AC_MSG_RESULT($ac_cv_lbl_gcc_fixincludes)
 350             if test $ac_cv_lbl_gcc_fixincludes = no ; then
 351                     # Don't cache failure
 352                     unset ac_cv_lbl_gcc_fixincludes
 353                     AC_MSG_ERROR(see the INSTALL for more info)
 354             fi
 355     fi])
 356
 357 dnl
 358 dnl Check for flex, default to lex
 359 dnl Require flex 2.4 or higher
 360 dnl Check for bison, default to yacc
 361 dnl Default to lex/yacc if both flex and bison are not available
 362 dnl Define the yy prefix string if using flex and bison
 363 dnl
 364 dnl usage:
 365 dnl
 366 dnl     AC_LBL_LEX_AND_YACC(lex, yacc, yyprefix)
 367 dnl
 368 dnl results:
 369 dnl
 370 dnl     $1 (lex set)
 371 dnl     $2 (yacc appended)
 372 dnl     $3 (optional flex and bison -P prefix)
 373 dnl
 374 AC_DEFUN(AC_LBL_LEX_AND_YACC,
 375     [AC_ARG_WITH(flex, [  --without-flex          don't use flex])
 376     AC_ARG_WITH(bison, [  --without-bison         don't use bison])
 377     if test "$with_flex" = no ; then
 378             $1=lex
 379     else
 380             AC_CHECK_PROGS($1, flex, lex)
 381     fi
 382     if test "$$1" = flex ; then
 383             # The -V flag was added in 2.4
 384             AC_MSG_CHECKING(for flex 2.4 or higher)
 385             AC_CACHE_VAL(ac_cv_lbl_flex_v24,
 386                 if flex -V >/dev/null 2>&1; then
 387                         ac_cv_lbl_flex_v24=yes
 388                 else
 389                         ac_cv_lbl_flex_v24=no
 390                 fi)
 391             AC_MSG_RESULT($ac_cv_lbl_flex_v24)
 392             if test $ac_cv_lbl_flex_v24 = no ; then
 393                     s="2.4 or higher required"
 394                     AC_MSG_WARN(ignoring obsolete flex executable ($s))
 395                     $1=lex
 396             fi
 397     fi
 398     if test "$with_bison" = no ; then
 399             $2=yacc
 400     else
 401             AC_CHECK_PROGS($2, bison, yacc)
 402     fi
 403     if test "$$2" = bison ; then
 404             $2="$$2 -y"
 405     fi
 406     if test "$$1" != lex -a "$$2" = yacc -o "$$1" = lex -a "$$2" != yacc ; then
 407             AC_MSG_WARN(don't have both flex and bison; reverting to lex/yacc)
 408             $1=lex
 409             $2=yacc
 410     fi
 411     if test "$$1" = flex -a -n "$3" ; then
 412             $1="$$1 -P$3"
 413             $2="$$2 -p $3"
 414     fi])
 415
 416 dnl
 417 dnl Checks to see if union wait is used with WEXITSTATUS()
 418 dnl
 419 dnl usage:
 420 dnl
 421 dnl     AC_LBL_UNION_WAIT
 422 dnl
 423 dnl results:
 424 dnl
 425 dnl     DECLWAITSTATUS (defined)
 426 dnl
 427 AC_DEFUN(AC_LBL_UNION_WAIT,
 428     [AC_MSG_CHECKING(if union wait is used)
 429     AC_CACHE_VAL(ac_cv_lbl_union_wait,
 430         AC_TRY_COMPILE([
 431 #       include <sys/types.h>
 432 #       include <sys/wait.h>],
 433             [int status;
 434             u_int i = WEXITSTATUS(status);
 435             u_int j = waitpid(0, &status, 0);],
 436             ac_cv_lbl_union_wait=no,
 437             ac_cv_lbl_union_wait=yes))
 438     AC_MSG_RESULT($ac_cv_lbl_union_wait)
 439     if test $ac_cv_lbl_union_wait = yes ; then
 440             AC_DEFINE(DECLWAITSTATUS,union wait)
 441     else
 442             AC_DEFINE(DECLWAITSTATUS,int)
 443     fi])
 444
 445 dnl
 446 dnl Checks to see if the sockaddr struct has the 4.4 BSD sa_len member
 447 dnl
 448 dnl usage:
 449 dnl
 450 dnl     AC_LBL_SOCKADDR_SA_LEN
 451 dnl
 452 dnl results:
 453 dnl
 454 dnl     HAVE_SOCKADDR_SA_LEN (defined)
 455 dnl
 456 AC_DEFUN(AC_LBL_SOCKADDR_SA_LEN,
 457     [AC_MSG_CHECKING(if sockaddr struct has sa_len member)
 458     AC_CACHE_VAL(ac_cv_lbl_sockaddr_has_sa_len,
 459         AC_TRY_COMPILE([
 460 #       include <sys/types.h>
 461 #       include <sys/socket.h>],
 462         [u_int i = sizeof(((struct sockaddr *)0)->sa_len)],
 463         ac_cv_lbl_sockaddr_has_sa_len=yes,
 464         ac_cv_lbl_sockaddr_has_sa_len=no))
 465     AC_MSG_RESULT($ac_cv_lbl_sockaddr_has_sa_len)
 466     if test $ac_cv_lbl_sockaddr_has_sa_len = yes ; then
 467             AC_DEFINE(HAVE_SOCKADDR_SA_LEN)
 468     fi])
 469
 470 dnl
 471 dnl Checks to see if -R is used
 472 dnl
 473 dnl usage:
 474 dnl
 475 dnl     AC_LBL_HAVE_RUN_PATH
 476 dnl
 477 dnl results:
 478 dnl
 479 dnl     ac_cv_lbl_have_run_path (yes or no)
 480 dnl
 481 AC_DEFUN(AC_LBL_HAVE_RUN_PATH,
 482     [AC_MSG_CHECKING(for ${CC-cc} -R)
 483     AC_CACHE_VAL(ac_cv_lbl_have_run_path,
 484         [echo 'main(){}' > conftest.c
 485         ${CC-cc} -o conftest conftest.c -R/a1/b2/c3 >conftest.out 2>&1
 486         if test ! -s conftest.out ; then
 487                 ac_cv_lbl_have_run_path=yes
 488         else
 489                 ac_cv_lbl_have_run_path=no
 490         fi
 491         rm -f conftest*])
 492     AC_MSG_RESULT($ac_cv_lbl_have_run_path)
 493     ])
 494
 495 dnl
 496 dnl Due to the stupid way it's implemented, AC_CHECK_TYPE is nearly useless.
 497 dnl
 498 dnl usage:
 499 dnl
 500 dnl     AC_LBL_CHECK_TYPE
 501 dnl
 502 dnl results:
 503 dnl
 504 dnl     int32_t (defined)
 505 dnl     u_int32_t (defined)
 506 dnl
 507 AC_DEFUN(AC_LBL_CHECK_TYPE,
 508     [AC_MSG_CHECKING(for $1 using $CC)
 509     AC_CACHE_VAL(ac_cv_lbl_have_$1,
 510         AC_TRY_COMPILE([
 511 #       include "confdefs.h"
 512 #       include <sys/types.h>
 513 #       if STDC_HEADERS
 514 #       include <stdlib.h>
 515 #       include <stddef.h>
 516 #       endif],
 517         [$1 i],
 518         ac_cv_lbl_have_$1=yes,
 519         ac_cv_lbl_have_$1=no))
 520     AC_MSG_RESULT($ac_cv_lbl_have_$1)
 521     if test $ac_cv_lbl_have_$1 = no ; then
 522             AC_DEFINE($1, $2)
 523     fi])
 524
 525 dnl
 526 dnl Checks to see if unaligned memory accesses fail
 527 dnl
 528 dnl usage:
 529 dnl
 530 dnl     AC_LBL_UNALIGNED_ACCESS
 531 dnl
 532 dnl results:
 533 dnl
 534 dnl     LBL_ALIGN (DEFINED)
 535 dnl
 536 AC_DEFUN(AC_LBL_UNALIGNED_ACCESS,
 537     [AC_MSG_CHECKING(if unaligned accesses fail)
 538     AC_CACHE_VAL(ac_cv_lbl_unaligned_fail,
 539         [case "$host_cpu" in
 540
 541         # XXX: should also check that they don't do weird things (like on arm)
 542         alpha*|arm*|hp*|mips*|sparc*|ia64)
 543                 ac_cv_lbl_unaligned_fail=yes
 544                 ;;
 545
 546         *)
 547                 cat >conftest.c <<EOF
 548 #               include <sys/types.h>
 549 #               include <sys/wait.h>
 550 #               include <stdio.h>
 551                 unsigned char a[[5]] = { 1, 2, 3, 4, 5 };
 552                 main() {
 553                 unsigned int i;
 554                 pid_t pid;
 555                 int status;
 556                 /* avoid "core dumped" message */
 557                 pid = fork();
 558                 if (pid <  0)
 559                         exit(2);
 560                 if (pid > 0) {
 561                         /* parent */
 562                         pid = waitpid(pid, &status, 0);
 563                         if (pid < 0)
 564                                 exit(3);
 565                         exit(!WIFEXITED(status));
 566                 }
 567                 /* child */
 568                 i = *(unsigned int *)&a[[1]];
 569                 printf("%d\n", i);
 570                 exit(0);
 571                 }
 572 EOF
 573                 ${CC-cc} -o conftest $CFLAGS $CPPFLAGS $LDFLAGS \
 574                     conftest.c $LIBS >/dev/null 2>&1
 575                 if test ! -x conftest ; then
 576                         dnl failed to compile for some reason
 577                         ac_cv_lbl_unaligned_fail=yes
 578                 else
 579                         ./conftest >conftest.out
 580                         if test ! -s conftest.out ; then
 581                                 ac_cv_lbl_unaligned_fail=yes
 582                         else
 583                                 ac_cv_lbl_unaligned_fail=no
 584                         fi
 585                 fi
 586                 rm -f conftest* core core.conftest
 587                 ;;
 588         esac])
 589     AC_MSG_RESULT($ac_cv_lbl_unaligned_fail)
 590     if test $ac_cv_lbl_unaligned_fail = yes ; then
 591             AC_DEFINE(LBL_ALIGN)
 592     fi])
 593
 594 dnl
 595 dnl If using gcc and the file .devel exists:
 596 dnl     Compile with -g (if supported) and -Wall
 597 dnl     If using gcc 2, do extra prototype checking
 598 dnl     If an os prototype include exists, symlink os-proto.h to it
 599 dnl
 600 dnl usage:
 601 dnl
 602 dnl     AC_LBL_DEVEL(copt)
 603 dnl
 604 dnl results:
 605 dnl
 606 dnl     $1 (copt appended)
 607 dnl     HAVE_OS_PROTO_H (defined)
 608 dnl     os-proto.h (symlinked)
 609 dnl
 610 AC_DEFUN(AC_LBL_DEVEL,
 611     [rm -f os-proto.h
 612     if test "${LBL_CFLAGS+set}" = set; then
 613             $1="$$1 ${LBL_CFLAGS}"
 614     fi
 615     if test -f .devel ; then
 616             if test "$GCC" = yes ; then
 617                     if test "${LBL_CFLAGS+set}" != set; then
 618                             if test "$ac_cv_prog_cc_g" = yes ; then
 619                                     $1="-g $$1"
 620                             fi
 621                             $1="$$1 -Wall"
 622                             if test $ac_cv_lbl_gcc_vers -gt 1 ; then
 623                                     $1="$$1 -Wmissing-prototypes -Wstrict-prototypes"
 624                             fi
 625                     fi
 626             else
 627                     case "$host_os" in
 628
 629                     irix6*)
 630                             V_CCOPT="$V_CCOPT -n32"
 631                             ;;
 632
 633                     *)
 634                             ;;
 635                     esac
 636             fi
 637             os=`echo $host_os | sed -e 's/\([[0-9]][[0-9]]*\)[[^0-9]].*$/\1/'`
 638             name="lbl/os-$os.h"
 639             if test -f $name ; then
 640                     ln -s $name os-proto.h
 641                     AC_DEFINE(HAVE_OS_PROTO_H)
 642             else
 643                     AC_MSG_WARN(can't find $name)
 644             fi
 645     fi])
 646
 647 dnl
 648 dnl Improved version of AC_CHECK_LIB
 649 dnl
 650 dnl Thanks to John Hawkinson (jhawk@mit.edu)
 651 dnl
 652 dnl usage:
 653 dnl
 654 dnl     AC_LBL_CHECK_LIB(LIBRARY, FUNCTION [, ACTION-IF-FOUND [,
 655 dnl         ACTION-IF-NOT-FOUND [, OTHER-LIBRARIES]]])
 656 dnl
 657 dnl results:
 658 dnl
 659 dnl     LIBS
 660 dnl
 661 dnl XXX - "AC_LBL_LIBRARY_NET" was redone to use "AC_SEARCH_LIBS"
 662 dnl rather than "AC_LBL_CHECK_LIB", so this isn't used any more.
 663 dnl We keep it around for reference purposes in case it's ever
 664 dnl useful in the future.
 665 dnl
 666
 667 define(AC_LBL_CHECK_LIB,
 668 [AC_MSG_CHECKING([for $2 in -l$1])
 669 dnl Use a cache variable name containing the library, function
 670 dnl name, and extra libraries to link with, because the test really is
 671 dnl for library $1 defining function $2, when linked with potinal
 672 dnl library $5, not just for library $1.  Separate tests with the same
 673 dnl $1 and different $2's or $5's may have different results.
 674 ac_lib_var=`echo $1['_']$2['_']$5 | sed 'y%./+- %__p__%'`
 675 AC_CACHE_VAL(ac_cv_lbl_lib_$ac_lib_var,
 676 [ac_save_LIBS="$LIBS"
 677 LIBS="-l$1 $5 $LIBS"
 678 AC_TRY_LINK(dnl
 679 ifelse([$2], [main], , dnl Avoid conflicting decl of main.
 680 [/* Override any gcc2 internal prototype to avoid an error.  */
 681 ]ifelse(AC_LANG, CPLUSPLUS, [#ifdef __cplusplus
 682 extern "C"
 683 #endif
 684 ])dnl
 685 [/* We use char because int might match the return type of a gcc2
 686     builtin and then its argument prototype would still apply.  */
 687 char $2();
 688 ]),
 689             [$2()],
 690             eval "ac_cv_lbl_lib_$ac_lib_var=yes",
 691             eval "ac_cv_lbl_lib_$ac_lib_var=no")
 692 LIBS="$ac_save_LIBS"
 693 ])dnl
 694 if eval "test \"`echo '$ac_cv_lbl_lib_'$ac_lib_var`\" = yes"; then
 695   AC_MSG_RESULT(yes)
 696   ifelse([$3], ,
 697 [changequote(, )dnl
 698   ac_tr_lib=HAVE_LIB`echo $1 | sed -e 's/[^a-zA-Z0-9_]/_/g' \
 699     -e 'y/abcdefghijklmnopqrstuvwxyz/ABCDEFGHIJKLMNOPQRSTUVWXYZ/'`
 700 changequote([, ])dnl
 701   AC_DEFINE_UNQUOTED($ac_tr_lib)
 702   LIBS="-l$1 $LIBS"
 703 ], [$3])
 704 else
 705   AC_MSG_RESULT(no)
 706 ifelse([$4], , , [$4
 707 ])dnl
 708 fi
 709 ])
 710
 711 dnl
 712 dnl AC_LBL_LIBRARY_NET
 713 dnl
 714 dnl This test is for network applications that need socket() and
 715 dnl gethostbyname() -ish functions.  Under Solaris, those applications
 716 dnl need to link with "-lsocket -lnsl".  Under IRIX, they need to link
 717 dnl with "-lnsl" but should *not* link with "-lsocket" because
 718 dnl libsocket.a breaks a number of things (for instance:
 719 dnl gethostbyname() under IRIX 5.2, and snoop sockets under most
 720 dnl versions of IRIX).
 721 dnl
 722 dnl Unfortunately, many application developers are not aware of this,
 723 dnl and mistakenly write tests that cause -lsocket to be used under
 724 dnl IRIX.  It is also easy to write tests that cause -lnsl to be used
 725 dnl under operating systems where neither are necessary (or useful),
 726 dnl such as SunOS 4.1.4, which uses -lnsl for TLI.
 727 dnl
 728 dnl This test exists so that every application developer does not test
 729 dnl this in a different, and subtly broken fashion.
 730
 731 dnl It has been argued that this test should be broken up into two
 732 dnl seperate tests, one for the resolver libraries, and one for the
 733 dnl libraries necessary for using Sockets API. Unfortunately, the two
 734 dnl are carefully intertwined and allowing the autoconf user to use
 735 dnl them independantly potentially results in unfortunate ordering
 736 dnl dependancies -- as such, such component macros would have to
 737 dnl carefully use indirection and be aware if the other components were
 738 dnl executed. Since other autoconf macros do not go to this trouble,
 739 dnl and almost no applications use sockets without the resolver, this
 740 dnl complexity has not been implemented.
 741 dnl
 742 dnl The check for libresolv is in case you are attempting to link
 743 dnl statically and happen to have a libresolv.a lying around (and no
 744 dnl libnsl.a).
 745 dnl
 746 AC_DEFUN(AC_LBL_LIBRARY_NET, [
 747     # Most operating systems have gethostbyname() in the default searched
 748     # libraries (i.e. libc):
 749     # Some OSes (eg. Solaris) place it in libnsl
 750     # Some strange OSes (SINIX) have it in libsocket:
 751     AC_SEARCH_LIBS(gethostbyname, nsl socket resolv)
 752     # Unfortunately libsocket sometimes depends on libnsl and
 753     # AC_SEARCH_LIBS isn't up to the task of handling dependencies like this.
 754     if test "$ac_cv_search_gethostbyname" = "no"
 755     then
 756         AC_CHECK_LIB(socket, gethostbyname,
 757                      LIBS="-lsocket -lnsl $LIBS", , -lnsl)
 758     fi
 759     AC_SEARCH_LIBS(socket, socket, ,
 760         AC_CHECK_LIB(socket, socket, LIBS="-lsocket -lnsl $LIBS", , -lnsl))
 761     # DLPI needs putmsg under HPUX so test for -lstr while we're at it
 762     AC_SEARCH_LIBS(putmsg, str)
 763     ])
 764
 765 dnl Copyright (c) 1999 WIDE Project. All rights reserved.
 766 dnl
 767 dnl Redistribution and use in source and binary forms, with or without
 768 dnl modification, are permitted provided that the following conditions
 769 dnl are met:
 770 dnl 1. Redistributions of source code must retain the above copyright
 771 dnl    notice, this list of conditions and the following disclaimer.
 772 dnl 2. Redistributions in binary form must reproduce the above copyright
 773 dnl    notice, this list of conditions and the following disclaimer in the
 774 dnl    documentation and/or other materials provided with the distribution.
 775 dnl 3. Neither the name of the project nor the names of its contributors
 776 dnl    may be used to endorse or promote products derived from this software
 777 dnl    without specific prior written permission.
 778 dnl
 779 dnl THIS SOFTWARE IS PROVIDED BY THE PROJECT AND CONTRIBUTORS ``AS IS'' AND
 780 dnl ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
 781 dnl IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
 782 dnl ARE DISCLAIMED.  IN NO EVENT SHALL THE PROJECT OR CONTRIBUTORS BE LIABLE
 783 dnl FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
 784 dnl DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
 785 dnl OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
 786 dnl HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
 787 dnl LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
 788 dnl OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
 789 dnl SUCH DAMAGE.
 790
 791 dnl
 792 dnl Checks to see if AF_INET6 is defined
 793 AC_DEFUN(AC_CHECK_AF_INET6, [
 794         AC_MSG_CHECKING(for AF_INET6)
 795         AC_CACHE_VAL($1,
 796         AC_TRY_COMPILE([
 797 #               include <sys/types.h>
 798 #               include <sys/socket.h>],
 799                 [int a = AF_INET6],
 800                 $1=yes,
 801                 $1=no))
 802         AC_MSG_RESULT($$1)
 803                 if test $$1 = yes ; then
 804                         AC_DEFINE(HAVE_AF_INET6)
 805         fi
 806 ])
 807
 808 dnl
 809 dnl Checks to see if the sockaddr struct has the 4.4 BSD sa_len member
 810 dnl borrowed from LBL libpcap
 811 AC_DEFUN(AC_CHECK_SA_LEN, [
 812         AC_MSG_CHECKING(if sockaddr struct has sa_len member)
 813         AC_CACHE_VAL($1,
 814         AC_TRY_COMPILE([
 815 #               include <sys/types.h>
 816 #               include <sys/socket.h>],
 817                 [u_int i = sizeof(((struct sockaddr *)0)->sa_len)],
 818                 $1=yes,
 819                 $1=no))
 820         AC_MSG_RESULT($$1)
 821                 if test $$1 = yes ; then
 822                         AC_DEFINE(HAVE_SOCKADDR_SA_LEN)
 823         fi
 824 ])
 825
 826 dnl
 827 dnl Checks for portable prototype declaration macro
 828 AC_DEFUN(AC_CHECK_PORTABLE_PROTO,  [
 829         AC_MSG_CHECKING(for __P)
 830         AC_CACHE_VAL($1,
 831         AC_TRY_COMPILE([
 832 #               include <unistd.h>],
 833                 [int f __P(())],
 834                 $1=yes,
 835                 $1=no))
 836         AC_MSG_RESULT($$1)
 837         if test $$1 = yes; then
 838                 AC_DEFINE(HAVE_PORTABLE_PROTOTYPE)
 839         fi
 840 ])
 841
 842 dnl checks for u_intXX_t
 843 AC_DEFUN(AC_CHECK_BITTYPES, [
 844         $1=yes
 845 dnl check for u_int8_t
 846         AC_MSG_CHECKING(for u_int8_t)
 847         AC_CACHE_VAL(ac_cv_u_int8_t,
 848         AC_TRY_COMPILE([
 849 #               include <sys/types.h>],
 850                 [u_int8_t i],
 851                 ac_cv_u_int8_t=yes,
 852                 ac_cv_u_int8_t=no))
 853         AC_MSG_RESULT($ac_cv_u_int8_t)
 854         if test $ac_cv_u_int8_t = yes; then
 855                 AC_DEFINE(HAVE_U_INT8_T)
 856         else
 857                 $1=no
 858         fi
 859 dnl check for u_int16_t
 860         AC_MSG_CHECKING(for u_int16_t)
 861         AC_CACHE_VAL(ac_cv_u_int16_t,
 862         AC_TRY_COMPILE([
 863 #               include <sys/types.h>],
 864                 [u_int16_t i],
 865                 ac_cv_u_int16_t=yes,
 866                 ac_cv_u_int16_t=no))
 867         AC_MSG_RESULT($ac_cv_u_int16_t)
 868         if test $ac_cv_u_int16_t = yes; then
 869                 AC_DEFINE(HAVE_U_INT16_T)
 870         else
 871                 $1=no
 872         fi
 873 dnl check for u_int32_t
 874         AC_MSG_CHECKING(for u_int32_t)
 875         AC_CACHE_VAL(ac_cv_u_int32_t,
 876         AC_TRY_COMPILE([
 877 #               include <sys/types.h>],
 878                 [u_int32_t i],
 879                 ac_cv_u_int32_t=yes,
 880                 ac_cv_u_int32_t=no))
 881         AC_MSG_RESULT($ac_cv_u_int32_t)
 882         if test $ac_cv_u_int32_t = yes; then
 883                 AC_DEFINE(HAVE_U_INT32_T)
 884         else
 885                 $1=no
 886         fi
 887 ])
 888
 889 dnl
 890 dnl Checks for addrinfo structure
 891 AC_DEFUN(AC_STRUCT_ADDRINFO, [
 892         AC_MSG_CHECKING(for addrinfo)
 893         AC_CACHE_VAL($1,
 894         AC_TRY_COMPILE([
 895 #               include <netdb.h>],
 896                 [struct addrinfo a],
 897                 $1=yes,
 898                 $1=no))
 899         AC_MSG_RESULT($$1)
 900         if test $$1 = yes; then
 901                 AC_DEFINE(HAVE_ADDRINFO)
 902         else
 903                 AC_DEFINE(NEED_ADDRINFO_H)
 904         fi
 905 ])
 906
 907 dnl
 908 dnl Checks for NI_MAXSERV
 909 AC_DEFUN(AC_NI_MAXSERV, [
 910         AC_MSG_CHECKING(for NI_MAXSERV)
 911         AC_CACHE_VAL($1,
 912         AC_EGREP_CPP(yes, [#include <netdb.h>
 913 #ifdef NI_MAXSERV
 914 yes
 915 #endif],
 916                 $1=yes,
 917                 $1=no))
 918         AC_MSG_RESULT($$1)
 919         if test $$1 != yes; then
 920                 AC_DEFINE(NEED_ADDRINFO_H)
 921         fi
 922 ])
 923
 924 dnl
 925 dnl Checks for NI_NAMEREQD
 926 AC_DEFUN(AC_NI_NAMEREQD, [
 927         AC_MSG_CHECKING(for NI_NAMEREQD)
 928         AC_CACHE_VAL($1,
 929         AC_EGREP_CPP(yes, [#include <netdb.h>
 930 #ifdef NI_NOFQDN
 931 yes
 932 #endif],
 933                 $1=yes,
 934                 $1=no))
 935         AC_MSG_RESULT($$1)
 936         if test $$1 != yes; then
 937                 AC_DEFINE(NEED_ADDRINFO_H)
 938         fi
 939 ])
 940
 941 dnl
 942 dnl Checks for sockaddr_storage structure
 943 AC_DEFUN(AC_STRUCT_SA_STORAGE, [
 944         AC_MSG_CHECKING(for sockaddr_storage)
 945         AC_CACHE_VAL($1,
 946         AC_TRY_COMPILE([
 947 #               include <sys/types.h>
 948 #               include <sys/socket.h>],
 949                 [struct sockaddr_storage s],
 950                 $1=yes,
 951                 $1=no))
 952         AC_MSG_RESULT($$1)
 953         if test $$1 = yes; then
 954                 AC_DEFINE(HAVE_SOCKADDR_STORAGE)
 955         fi
 956 ])
 957
 958 dnl
 959 dnl Checks for macro of IP address size
 960 AC_DEFUN(AC_CHECK_ADDRSZ, [
 961         $1=yes
 962 dnl check for INADDRSZ
 963         AC_MSG_CHECKING(for INADDRSZ)
 964         AC_CACHE_VAL(ac_cv_inaddrsz,
 965         AC_TRY_COMPILE([
 966 #               include <arpa/nameser.h>],
 967                 [int a = INADDRSZ],
 968                 ac_cv_inaddrsz=yes,
 969                 ac_cv_inaddrsz=no))
 970         AC_MSG_RESULT($ac_cv_inaddrsz)
 971         if test $ac_cv_inaddrsz = yes; then
 972                 AC_DEFINE(HAVE_INADDRSZ)
 973         else
 974                 $1=no
 975         fi
 976 dnl check for IN6ADDRSZ
 977         AC_MSG_CHECKING(for IN6ADDRSZ)
 978         AC_CACHE_VAL(ac_cv_in6addrsz,
 979         AC_TRY_COMPILE([
 980 #               include <arpa/nameser.h>],
 981                 [int a = IN6ADDRSZ],
 982                 ac_cv_in6addrsz=yes,
 983                 ac_cv_in6addrsz=no))
 984         AC_MSG_RESULT($ac_cv_in6addrsz)
 985         if test $ac_cv_in6addrsz = yes; then
 986                 AC_DEFINE(HAVE_IN6ADDRSZ)
 987         else
 988                 $1=no
 989         fi
 990 ])
 991
 992 dnl
 993 dnl check for RES_USE_INET6
 994 AC_DEFUN(AC_CHECK_RES_USE_INET6, [
 995         AC_MSG_CHECKING(for RES_USE_INET6)
 996         AC_CACHE_VAL($1,
 997         AC_TRY_COMPILE([
 998 #               include <sys/types.h>
 999 #               include <netinet/in.h>
1000 #               include <resolv.h>],
1001                 [int a = RES_USE_INET6],
1002                 $1=yes,
1003                 $1=no))
1004         AC_MSG_RESULT($$1)
1005         if test $$1 = yes; then
1006                 AC_DEFINE(HAVE_RES_USE_INET6)
1007         fi
1008 ])
1009
1010 dnl
1011 dnl check for AAAA
1012 AC_DEFUN(AC_CHECK_AAAA, [
1013         AC_MSG_CHECKING(for AAAA)
1014         AC_CACHE_VAL($1,
1015         AC_TRY_COMPILE([
1016 #               include <sys/types.h>
1017 #               include <arpa/nameser.h>],
1018                 [int a = T_AAAA],
1019                 $1=yes,
1020                 $1=no))
1021         AC_MSG_RESULT($$1)
1022         if test $$1 = yes; then
1023                 AC_DEFINE(HAVE_AAAA)
1024         fi
1025 ])
1026
1027 dnl
1028 dnl check for struct res_state_ext
1029 AC_DEFUN(AC_STRUCT_RES_STATE_EXT, [
1030         AC_MSG_CHECKING(for res_state_ext)
1031         AC_CACHE_VAL($1,
1032         AC_TRY_COMPILE([
1033 #               include <sys/types.h>
1034 #               include <netinet/in.h>
1035 #               include <netinet6/in6.h>
1036 #               include <resolv.h>],
1037                 [struct __res_state_ext e],
1038                 $1=yes,
1039                 $1=no))
1040         AC_MSG_RESULT($$1)
1041         if test $$1 = yes; then
1042                 AC_DEFINE(HAVE_RES_STATE_EXT)
1043         fi
1044 ])
1045
1046 dnl
1047 dnl check for struct res_state_ext
1048 AC_DEFUN(AC_STRUCT_RES_STATE, [
1049         AC_MSG_CHECKING(for nsort in res_state)
1050         AC_CACHE_VAL($1,
1051         AC_TRY_COMPILE([
1052 #               include <sys/types.h>
1053 #               include <netinet/in.h>
1054 #               include <netinet6/in6.h>
1055 #               include <resolv.h>],
1056                 [struct __res_state e; e.nsort = 0],
1057                 $1=yes,
1058                 $1=no))
1059         AC_MSG_RESULT($$1)
1060         if test $$1 = yes; then
1061                 AC_DEFINE(HAVE_NEW_RES_STATE)
1062         fi
1063 ])
1064
1065 dnl
1066 dnl check for h_errno
1067 AC_DEFUN(AC_VAR_H_ERRNO, [
1068         AC_MSG_CHECKING(for h_errno)
1069         AC_CACHE_VAL(ac_cv_var_h_errno,
1070         AC_TRY_COMPILE([
1071 #               include <sys/types.h>
1072 #               include <netdb.h>],
1073                 [int foo = h_errno;],
1074                 ac_cv_var_h_errno=yes,
1075                 ac_cv_var_h_errno=no))
1076         AC_MSG_RESULT($ac_cv_var_h_errno)
1077         if test "$ac_cv_var_h_errno" = "yes"; then
1078                 AC_DEFINE(HAVE_H_ERRNO)
1079         fi
1080 ])
1081
1082 dnl
1083 dnl Test for __attribute__
1084 dnl
1085
1086 AC_DEFUN(AC_C___ATTRIBUTE__, [
1087 AC_MSG_CHECKING(for __attribute__)
1088 AC_CACHE_VAL(ac_cv___attribute__, [
1089 AC_TRY_COMPILE([
1090 #include <stdlib.h>
1091 ],
1092 [
1093 static void foo(void) __attribute__ ((noreturn));
1094
1095 static void
1096 foo(void)
1097 {
1098   exit(1);
1099 }
1100 ],
1101 ac_cv___attribute__=yes,
1102 ac_cv___attribute__=no)])
1103 if test "$ac_cv___attribute__" = "yes"; then
1104   AC_DEFINE(HAVE___ATTRIBUTE__, 1, [define if your compiler has __attribute__])
1105 fi
1106 AC_MSG_RESULT($ac_cv___attribute__)
1107 ])