The Tcpdump Group git mirrors - tcpdump/blob - configure.ac

   1 dnl Copyright (c) 1994, 1995, 1996, 1997
   2 dnl     The Regents of the University of California.  All rights reserved.
   3 dnl
   4 dnl Process this file with autoconf to produce a configure script.
   5 dnl
   6
   7 #
   8 # See
   9 #
  10 #       https://ftp.gnu.org/gnu/config/README
  11 #
  12 # for the URLs to use to fetch new versions of config.guess and
  13 # config.sub.
  14 #
  15
  16 AC_PREREQ([2.69])
  17 AC_INIT([tcpdump],[m4_esyscmd_s(cat VERSION)])
  18 AC_CONFIG_SRCDIR(tcpdump.c)
  19
  20 AC_CANONICAL_HOST
  21
  22 AC_LBL_C_INIT_BEFORE_CC(V_INCLS)
  23 #
  24 # Try to enable as many C99 features as we can.
  25 # At minimum, we want C++/C99-style // comments.
  26 #
  27 AC_PROG_CC_C99
  28 if test "$ac_cv_prog_cc_c99" = "no"; then
  29         AC_MSG_WARN([The C compiler does not support C99; there may be compiler errors])
  30 fi
  31 AC_LBL_C_INIT(V_CCOPT, V_INCLS)
  32 AC_LBL_C_INLINE
  33
  34 AC_CHECK_HEADERS(fcntl.h rpc/rpc.h rpc/rpcent.h net/if.h)
  35
  36 case "$host_os" in
  37
  38 darwin*)
  39         AC_ARG_ENABLE(universal,
  40         AS_HELP_STRING([--disable-universal],[don't build universal on macOS]))
  41         if test "$enable_universal" != "no"; then
  42                 case "$host_os" in
  43
  44                 darwin9.*)
  45                         #
  46                         # Leopard.  Build for x86 and 32-bit PowerPC, with
  47                         # x86 first.  (That's what Apple does.)
  48                         #
  49                         V_CCOPT="$V_CCOPT -arch i386 -arch ppc"
  50                         LDFLAGS="$LDFLAGS -arch i386 -arch ppc"
  51                         ;;
  52
  53                 darwin10.*)
  54                         #
  55                         # Snow Leopard.  Build for x86-64 and x86, with
  56                         # x86-64 first.  (That's what Apple does.)
  57                         #
  58                         V_CCOPT="$V_CCOPT -arch x86_64 -arch i386"
  59                         LDFLAGS="$LDFLAGS -arch x86_64 -arch i386"
  60                         ;;
  61                 esac
  62         fi
  63         ;;
  64 esac
  65
  66
  67 AC_ARG_WITH([smi],
  68    [AS_HELP_STRING([--with-smi],
  69      [link with libsmi (allows to load MIBs on the fly to decode SNMP packets) [default=yes, if available]])],
  70    [],
  71    [with_smi=yes])
  72
  73 if test "x$with_smi" != "xno" ; then
  74         AC_CHECK_HEADER(smi.h,
  75         [
  76                 #
  77                 # OK, we found smi.h.  Do we have libsmi with smiInit?
  78                 #
  79                 AC_CHECK_LIB(smi, smiInit,
  80                 [
  81                         #
  82                         # OK, we have libsmi with smiInit.  Can we use it?
  83                         #
  84                         AC_MSG_CHECKING([whether to enable libsmi])
  85                         savedlibs="$LIBS"
  86                         LIBS="-lsmi $LIBS"
  87                         AC_RUN_IFELSE([AC_LANG_SOURCE([[
  88 /* libsmi available check */
  89 #include <stdio.h>
  90 #include <stdlib.h>
  91 #include <string.h>
  92 #include <smi.h>
  93 int main()
  94 {
  95   int current, revision, age, n;
  96   const int required = 2;
  97   if (smiInit(""))
  98     exit(1);
  99   if (strcmp(SMI_LIBRARY_VERSION, smi_library_version))
 100     exit(2);
 101   n = sscanf(smi_library_version, "%d:%d:%d", &current, &revision, &age);
 102   if (n != 3)
 103     exit(3);
 104   if (required < current - age || required > current)
 105     exit(4);
 106   exit(0);
 107 }
 108                                 ]])
 109                                 ],
 110                                 [
 111                                         AC_MSG_RESULT(yes)
 112                                         AC_DEFINE(USE_LIBSMI, 1,
 113                                             [Define if you enable support for libsmi])
 114                                 ],
 115                                 [
 116                                         dnl autoconf documentation says that
 117                                         dnl $? contains the exit value.
 118                                         dnl reality is that it does not.
 119                                         dnl We leave this in just in case
 120                                         dnl autoconf ever comes back to
 121                                         dnl match the documentation.
 122                                         case $? in
 123                                           1) AC_MSG_RESULT(no - smiInit failed) ;;
 124                                           2) AC_MSG_RESULT(no - header/library version mismatch) ;;
 125                                           3) AC_MSG_RESULT(no - can't determine library version) ;;
 126                                           4) AC_MSG_RESULT(no - too old) ;;
 127                                           *) AC_MSG_RESULT(no) ;;
 128                                         esac
 129                                         LIBS="$savedlibs"
 130                                 ],
 131                                 [
 132                                         AC_MSG_RESULT(not when cross-compiling)
 133                                         LIBS="$savedlibs"
 134                                 ]
 135                         )
 136                 ])
 137         ])
 138 fi
 139
 140 AC_MSG_CHECKING([whether to enable the possibly-buggy SMB printer])
 141 AC_ARG_ENABLE([smb],
 142    [AS_HELP_STRING([--enable-smb],
 143      [enable possibly-buggy SMB printer [default=no]])],
 144    [],
 145    [enableval=no])
 146 case "$enableval" in
 147 yes)    AC_MSG_RESULT(yes)
 148         AC_DEFINE(ENABLE_SMB, 1,
 149             [define if you want to build the possibly-buggy SMB printer])
 150         LOCALSRC="print-smb.c smbutil.c $LOCALSRC"
 151         ;;
 152 *)      AC_MSG_RESULT(no)
 153         ;;
 154 esac
 155
 156 AC_MSG_CHECKING([whether to drop root privileges by default])
 157 AC_ARG_WITH(
 158         [user],
 159         [AS_HELP_STRING([--with-user=USERNAME],
 160                 [drop privileges by default to USERNAME]
 161         )],
 162         [],
 163         [withval=no])
 164 AS_CASE(["$withval"],
 165         [no], [AC_MSG_RESULT(no)],
 166         [''|yes], [AC_MSG_ERROR([--with-user requires a username])],
 167         [
 168                 AC_DEFINE_UNQUOTED(WITH_USER, "$withval",
 169                     [define if should drop privileges by default])
 170                 AC_MSG_RESULT([yes, to user "$withval"])
 171         ]
 172 )
 173
 174 AC_MSG_CHECKING([whether to chroot])
 175 AC_ARG_WITH(
 176         [chroot],
 177         [AS_HELP_STRING([--with-chroot=DIRECTORY],
 178                 [when dropping privileges, chroot to DIRECTORY]
 179         )],
 180         [],
 181         [withval=no]
 182 )
 183 AS_CASE(["$withval"],
 184         [no], [AC_MSG_RESULT(no)],
 185         [''|yes], [AC_MSG_ERROR([--with-chroot requires a directory])],
 186         [
 187                 AC_DEFINE_UNQUOTED(WITH_CHROOT, "$withval",
 188                     [define if should chroot when dropping privileges])
 189                 AC_MSG_RESULT([yes, to directory "$withval"])
 190         ]
 191 )
 192
 193 AC_ARG_WITH(sandbox-capsicum,
 194         AS_HELP_STRING([--with-sandbox-capsicum],
 195                        [use Capsicum security functions @<:@default=yes, if available@:>@]))
 196 #
 197 # Check whether various functions are available.  If any are, set
 198 # ac_lbl_capsicum_function_seen to yes; if any are not, set
 199 # ac_lbl_capsicum_function_not_seen to yes.
 200 #
 201 # We don't check cap_rights_init(), as it's a macro, wrapping another
 202 # function, in at least some versions of FreeBSD, and AC_CHECK_FUNCS()
 203 # doesn't handle that.
 204 #
 205 # All of the ones we check for must be available in order to enable
 206 # capsicum sandboxing.
 207 #
 208 # XXX - do we need to check for all of them, or are there some that, if
 209 # present, imply others are present?
 210 #
 211 if test -z "$with_sandbox_capsicum" || test "$with_sandbox_capsicum" != "no" ; then
 212         #
 213         # First, make sure we have the required header.
 214         #
 215         AC_CHECK_HEADER(sys/capsicum.h,
 216         [
 217                 #
 218                 # We do; now make sure we have the required functions.
 219                 #
 220                 AC_CHECK_FUNCS(cap_enter cap_rights_limit cap_ioctls_limit openat,
 221                     ac_lbl_capsicum_function_seen=yes,
 222                     ac_lbl_capsicum_function_not_seen=yes)
 223         ])
 224         AC_CHECK_LIB(casper, cap_init, LIBS="$LIBS -lcasper")
 225         AC_CHECK_LIB(cap_dns, cap_gethostbyaddr, LIBS="$LIBS -lcap_dns")
 226 fi
 227 AC_MSG_CHECKING([whether to sandbox using capsicum])
 228 if test "x$ac_lbl_capsicum_function_seen" = "xyes" -a "x$ac_lbl_capsicum_function_not_seen" != "xyes"; then
 229         AC_DEFINE(HAVE_CAPSICUM, 1, [capsicum support available])
 230         AC_MSG_RESULT(yes)
 231 else
 232         AC_MSG_RESULT(no)
 233 fi
 234 AC_MSG_CHECKING([whether to sandbox using Casper library])
 235 if test "x$ac_cv_lib_casper_cap_init" = "xyes" -a "x$ac_cv_lib_cap_dns_cap_gethostbyaddr" = "xyes"; then
 236         AC_DEFINE(HAVE_CASPER, 1, [Casper support available])
 237         AC_MSG_RESULT(yes)
 238 else
 239         AC_MSG_RESULT(no)
 240 fi
 241
 242 #
 243 # We must check this before checking whether to check the OS's IPv6,
 244 # support because, on some platforms (such as SunOS 5.x), the test
 245 # program requires the extra networking libraries.
 246 #
 247 AC_LBL_LIBRARY_NET
 248
 249 #
 250 # Check whether AF_INET6 and struct in6_addr are defined.
 251 # If they aren't both defined, we don't have sufficient OS
 252 # support for IPv6, so we don't look for IPv6 support libraries,
 253 # and we define AF_INET6 and struct in6_addr ourselves.
 254 #
 255 AC_MSG_CHECKING([whether the operating system supports IPv6])
 256 AC_COMPILE_IFELSE(
 257     [
 258       AC_LANG_SOURCE(
 259         [[
 260 #include <string.h>
 261 /* AF_INET6 available check */
 262 #include <sys/types.h>
 263 #ifdef _WIN32
 264 #include <ws2tcpip.h>
 265 #else
 266 #include <sys/socket.h>
 267 #include <netinet/in.h>
 268 #endif
 269 #ifdef AF_INET6
 270 void
 271 foo(struct in6_addr *addr)
 272 {
 273  memset(addr, 0, sizeof (struct in6_addr));
 274 }
 275 #else
 276 #error "AF_INET6 not defined"
 277 #endif
 278         ]])
 279     ],
 280     [
 281         AC_MSG_RESULT(yes)
 282         AC_DEFINE(HAVE_OS_IPV6_SUPPORT, 1,
 283             [define if the OS provides AF_INET6 and struct in6_addr])
 284         ipv6=yes
 285     ],
 286     [
 287         AC_MSG_RESULT(no)
 288         ipv6=no
 289     ]
 290 )
 291
 292 ipv6type=unknown
 293 ipv6lib=none
 294 ipv6trylibc=no
 295
 296 if test "$ipv6" = "yes"; then
 297         AC_MSG_CHECKING([ipv6 stack type])
 298         for i in inria kame linux-glibc linux-libinet6 toshiba v6d zeta; do
 299                 case $i in
 300                 inria)
 301                         dnl http://www.kame.net/
 302                         AC_EGREP_CPP(yes,
 303 [#include <netinet/in.h>
 304 #ifdef IPV6_INRIA_VERSION
 305 yes
 306 #endif],
 307                                 [ipv6type=$i])
 308                         ;;
 309                 kame)
 310                         dnl http://www.kame.net/
 311                         AC_EGREP_CPP(yes,
 312 [#include <netinet/in.h>
 313 #ifdef __KAME__
 314 yes
 315 #endif],
 316                                 [ipv6type=$i;
 317                                 ipv6lib=inet6;
 318                                 ipv6libdir=/usr/local/v6/lib;
 319                                 ipv6trylibc=yes])
 320                         ;;
 321                 linux-glibc)
 322                         dnl http://www.v6.linux.or.jp/
 323                         AC_EGREP_CPP(yes,
 324 [#include <features.h>
 325 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 326 yes
 327 #endif],
 328                                 [ipv6type=$i])
 329                         ;;
 330                 linux-libinet6)
 331                         dnl http://www.v6.linux.or.jp/
 332                         dnl
 333                         dnl This also matches Solaris 8 and Tru64 UNIX 5.1,
 334                         dnl and possibly other versions of those OSes
 335                         dnl
 336                         if test -d /usr/inet6 -o -f /usr/include/netinet/ip6.h; then
 337                                 ipv6type=$i
 338                                 ipv6lib=inet6
 339                                 ipv6libdir=/usr/inet6/lib
 340                                 ipv6trylibc=yes;
 341                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 342                         fi
 343                         ;;
 344                 toshiba)
 345                         AC_EGREP_CPP(yes,
 346 [#include <sys/param.h>
 347 #ifdef _TOSHIBA_INET6
 348 yes
 349 #endif],
 350                                 [ipv6type=$i;
 351                                 ipv6lib=inet6;
 352                                 ipv6libdir=/usr/local/v6/lib])
 353                         ;;
 354                 v6d)
 355                         AC_EGREP_CPP(yes,
 356 [#include </usr/local/v6/include/sys/v6config.h>
 357 #ifdef __V6D__
 358 yes
 359 #endif],
 360                                 [ipv6type=$i;
 361                                 ipv6lib=v6;
 362                                 ipv6libdir=/usr/local/v6/lib;
 363                                 CFLAGS="-I/usr/local/v6/include $CFLAGS"])
 364                         ;;
 365                 zeta)
 366                         AC_EGREP_CPP(yes,
 367 [#include <sys/param.h>
 368 #ifdef _ZETA_MINAMI_INET6
 369 yes
 370 #endif],
 371                                 [ipv6type=$i;
 372                                 ipv6lib=inet6;
 373                                 ipv6libdir=/usr/local/v6/lib])
 374                         ;;
 375                 esac
 376                 if test "$ipv6type" != "unknown"; then
 377                         break
 378                 fi
 379         done
 380         AC_MSG_RESULT($ipv6type)
 381 fi
 382
 383 if test "$ipv6" = "yes" -a "$ipv6lib" != "none"; then
 384         if test -d $ipv6libdir -a -f $ipv6libdir/lib$ipv6lib.a; then
 385                 LIBS="-L$ipv6libdir -l$ipv6lib $LIBS"
 386                 echo "You have $ipv6lib library, using it"
 387         else
 388                 if test "$ipv6trylibc" = "yes"; then
 389                         echo "You do not have $ipv6lib library, using libc"
 390                 else
 391                         echo 'Fatal: no $ipv6lib library found.  cannot continue.'
 392                         echo "You need to fetch lib$ipv6lib.a from appropriate"
 393                         echo 'ipv6 kit and compile beforehand.'
 394                         exit 1
 395                 fi
 396         fi
 397 fi
 398
 399 AC_REPLACE_FUNCS(strlcat strlcpy strdup strsep getservent getopt_long)
 400 AC_CHECK_FUNCS(fork vfork)
 401 AC_CHECK_FUNCS(setlinebuf)
 402
 403 #
 404 # Make sure we have snprintf(); we require it.
 405 #
 406 AC_CHECK_FUNC(snprintf,,
 407     AC_MSG_ERROR([snprintf() is required but wasn't found]))
 408
 409 #
 410 # It became apparent at some point that using a suitable C99 compiler does not
 411 # automatically mean snprintf(3) implementation in the libc supports all the
 412 # modifiers and specifiers used in the project, so let's test that before the
 413 # build, not after.
 414 #
 415 # Testing the sizeof_t length modifier takes making an snprintf() call and
 416 # comparing the actual result with the expected result.  If this fails, it will
 417 # most likely happen at run time, not compile time.
 418 #
 419 # Testing the 64-bit conversion specifiers in addition to that requires the
 420 # <inttypes.h> header to be present and the macros to be defined, so if this
 421 # fails, it will more likely happen at compile time.
 422 #
 423 AC_MSG_CHECKING([whether snprintf is suitable])
 424 AC_RUN_IFELSE(
 425     [
 426         AC_LANG_SOURCE([[
 427 #include <stdio.h>
 428 #include <string.h>
 429 #include <inttypes.h>
 430 #include <sys/types.h>
 431
 432 int main()
 433 {
 434   char buf[100];
 435   uint64_t t = (uint64_t)1 << 32;
 436
 437   snprintf(buf, sizeof(buf), "%zu", sizeof(buf));
 438   if (strncmp(buf, "100", sizeof(buf)))
 439     return 1;
 440
 441   snprintf(buf, sizeof(buf), "%zd", -sizeof(buf));
 442   if (strncmp(buf, "-100", sizeof(buf)))
 443     return 2;
 444
 445   snprintf(buf, sizeof(buf), "%" PRId64, -t);
 446   if (strncmp(buf, "-4294967296", sizeof(buf)))
 447     return 3;
 448
 449   snprintf(buf, sizeof(buf), "0o%" PRIo64, t);
 450   if (strncmp(buf, "0o40000000000", sizeof(buf)))
 451     return 4;
 452
 453   snprintf(buf, sizeof(buf), "0x%" PRIx64, t);
 454   if (strncmp(buf, "0x100000000", sizeof(buf)))
 455     return 5;
 456
 457   snprintf(buf, sizeof(buf), "%" PRIu64, t);
 458   if (strncmp(buf, "4294967296", sizeof(buf)))
 459     return 6;
 460
 461   return 0;
 462 }
 463         ]])
 464     ],
 465     [
 466         AC_MSG_RESULT(yes)
 467     ],
 468     [
 469         AC_MSG_RESULT(no)
 470         AC_MSG_ERROR(
 471 [The snprintf(3) implementation in this libc is not suitable,
 472 tcpdump would not work correctly even if it managed to compile.])
 473     ],
 474     [
 475         AC_MSG_RESULT(not while cross-compiling)
 476     ]
 477 )
 478
 479 AC_CHECK_LIB(rpc, main)         dnl It's unclear why we might need -lrpc
 480
 481 dnl Some platforms may need -lnsl for getrpcbynumber.
 482 AC_SEARCH_LIBS(getrpcbynumber, nsl,
 483     AC_DEFINE(HAVE_GETRPCBYNUMBER, 1, [define if you have getrpcbynumber()]))
 484
 485 AC_LBL_LIBPCAP(V_PCAPDEP, V_INCLS)
 486
 487 #
 488 # Check for these after AC_LBL_LIBPCAP, so we link with the appropriate
 489 # libraries (e.g., "-lsocket -lnsl" on Solaris).
 490 #
 491 # You are in a twisty little maze of UN*Xes, all different.
 492 # Some might not have ether_ntohost().
 493 # Some might have it and declare it in <net/ethernet.h>.
 494 # Some might have it and declare it in <netinet/ether.h>
 495 # Some might have it and declare it in <sys/ethernet.h>.
 496 # Some might have it and declare it in <arpa/inet.h>.
 497 # Some might have it and declare it in <netinet/if_ether.h>.
 498 # Some might have it and not declare it in any header file.
 499 #
 500 # Before you is a C compiler.
 501 #
 502 AC_CHECK_FUNCS(ether_ntohost, [
 503     AC_CACHE_CHECK(for buggy ether_ntohost, ac_cv_buggy_ether_ntohost, [
 504         AC_RUN_IFELSE([AC_LANG_SOURCE([[
 505                 #include <netdb.h>
 506                 #include <netinet/ether.h>
 507                 #include <stdlib.h>
 508                 #include <sys/types.h>
 509                 #include <sys/param.h>
 510                 #include <sys/socket.h>
 511
 512                 int
 513                 main(int argc, char **argv)
 514                 {
 515                         u_char ea[6] = { 0xff, 0xff, 0xff, 0xff, 0xff };
 516                         char name[MAXHOSTNAMELEN];
 517
 518                         ether_ntohost(name, (struct ether_addr *)ea);
 519                         exit(0);
 520                 }
 521         ]])
 522         ], [ac_cv_buggy_ether_ntohost=no],
 523            [ac_cv_buggy_ether_ntohost=yes],
 524            [ac_cv_buggy_ether_ntohost="not while cross-compiling"])])
 525     if test "$ac_cv_buggy_ether_ntohost" = "no"; then
 526         AC_DEFINE(USE_ETHER_NTOHOST, 1,
 527             [define if you have ether_ntohost() and it works])
 528     fi
 529 ])
 530 if test "$ac_cv_func_ether_ntohost" = yes -a \
 531     "$ac_cv_buggy_ether_ntohost" = "no"; then
 532         #
 533         # OK, we have ether_ntohost().  Is it declared in <net/ethernet.h>?
 534         #
 535         # This test fails if we don't have <net/ethernet.h> or if we do
 536         # but it doesn't declare ether_ntohost().
 537         #
 538         AC_CHECK_DECL(ether_ntohost,
 539             [
 540                 AC_DEFINE(NET_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
 541                     [Define to 1 if net/ethernet.h declares `ether_ntohost'])
 542             ],,
 543             [
 544 #include <net/ethernet.h>
 545             ])
 546         #
 547         # Did that succeed?
 548         #
 549         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 550                 #
 551                 # No, how about <netinet/ether.h>, as on Linux?
 552                 #
 553                 # This test fails if we don't have <netinet/ether.h>
 554                 # or if we do but it doesn't declare ether_ntohost().
 555                 #
 556                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 557                 # treat the previous failure as a cached value and
 558                 # suppress the next test.
 559                 #
 560                 unset ac_cv_have_decl_ether_ntohost
 561                 AC_CHECK_DECL(ether_ntohost,
 562                     [
 563                         AC_DEFINE(NETINET_ETHER_H_DECLARES_ETHER_NTOHOST,,
 564                             [Define to 1 if netinet/ether.h declares `ether_ntohost'])
 565                     ],,
 566                     [
 567 #include <netinet/ether.h>
 568                     ])
 569         fi
 570         #
 571         # Did that succeed?
 572         #
 573         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 574                 #
 575                 # No, how about <sys/ethernet.h>, as on Solaris 10
 576                 # and later?
 577                 #
 578                 # This test fails if we don't have <sys/ethernet.h>
 579                 # or if we do but it doesn't declare ether_ntohost().
 580                 #
 581                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 582                 # treat the previous failure as a cached value and
 583                 # suppress the next test.
 584                 #
 585                 unset ac_cv_have_decl_ether_ntohost
 586                 AC_CHECK_DECL(ether_ntohost,
 587                     [
 588                         AC_DEFINE(SYS_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
 589                             [Define to 1 if sys/ethernet.h declares `ether_ntohost'])
 590                     ],,
 591                     [
 592 #include <sys/ethernet.h>
 593                     ])
 594         fi
 595         #
 596         # Did that succeed?
 597         #
 598         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 599                 #
 600                 # No, how about <arpa/inet.h>, as in AIX?
 601                 #
 602                 # This test fails if we don't have <arpa/inet.h>
 603                 # (if we have ether_ntohost(), we should have
 604                 # networking, and if we have networking, we should
 605                 # have <arpa/inet.h>) or if we do but it doesn't
 606                 # declare ether_ntohost().
 607                 #
 608                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 609                 # treat the previous failure as a cached value and
 610                 # suppress the next test.
 611                 #
 612                 unset ac_cv_have_decl_ether_ntohost
 613                 AC_CHECK_DECL(ether_ntohost,
 614                     [
 615                         AC_DEFINE(ARPA_INET_H_DECLARES_ETHER_NTOHOST,,
 616                             [Define to 1 if arpa/inet.h declares `ether_ntohost'])
 617                     ],,
 618                     [
 619 #include <arpa/inet.h>
 620                     ])
 621         fi
 622         #
 623         # Did that succeed?
 624         #
 625         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 626                 #
 627                 # No, how about <netinet/if_ether.h>?
 628                 # On some platforms, it requires <net/if.h> and
 629                 # <netinet/in.h>, and we always include it with
 630                 # both of them, so test it with both of them.
 631                 #
 632                 # This test fails if we don't have <netinet/if_ether.h>
 633                 # and the headers we include before it, or if we do but
 634                 # <netinet/if_ether.h> doesn't declare ether_hostton().
 635                 #
 636                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 637                 # treat the previous failure as a cached value and
 638                 # suppress the next test.
 639                 #
 640                 unset ac_cv_have_decl_ether_ntohost
 641                 AC_CHECK_DECL(ether_ntohost,
 642                     [
 643                         AC_DEFINE(NETINET_IF_ETHER_H_DECLARES_ETHER_NTOHOST,,
 644                             [Define to 1 if netinet/if_ether.h declares `ether_ntohost'])
 645                     ],,
 646                     [
 647 #include <sys/types.h>
 648 #include <sys/socket.h>
 649 #include <net/if.h>
 650 #include <netinet/in.h>
 651 #include <netinet/if_ether.h>
 652                     ])
 653         fi
 654         #
 655         # After all that, is ether_ntohost() declared?
 656         #
 657         if test "$ac_cv_have_decl_ether_ntohost" = yes; then
 658                 #
 659                 # Yes.
 660                 #
 661                 AC_DEFINE(HAVE_DECL_ETHER_NTOHOST, 1,
 662                     [Define to 1 if you have the declaration of `ether_ntohost'])
 663         else
 664                 #
 665                 # No, we'll have to declare it ourselves.
 666                 # Do we have "struct ether_addr" if we include
 667                 # <netinet/if_ether.h>?
 668                 #
 669                 AC_CHECK_TYPES(struct ether_addr,,,
 670                     [
 671                         #include <sys/types.h>
 672                         #include <sys/socket.h>
 673                         #include <net/if.h>
 674                         #include <netinet/in.h>
 675                         #include <netinet/if_ether.h>
 676                     ])
 677         fi
 678 fi
 679
 680 dnl
 681 dnl Check for "pcap_list_datalinks()" and use a substitute version if
 682 dnl it's not present.  If it is present, check for "pcap_free_datalinks()";
 683 dnl if it's not present, we don't replace it for now.  (We could do so
 684 dnl on UN*X, but not on Windows, where hilarity ensues if a program
 685 dnl built with one version of the MSVC support library tries to free
 686 dnl something allocated by a library built with another version of
 687 dnl the MSVC support library.)
 688 dnl
 689 AC_CHECK_FUNC(pcap_list_datalinks,
 690         [
 691             AC_DEFINE(HAVE_PCAP_LIST_DATALINKS, 1,
 692                 [define if libpcap has pcap_list_datalinks()])
 693             AC_CHECK_FUNCS(pcap_free_datalinks)
 694         ],
 695         [
 696             AC_LIBOBJ(datalinks)
 697         ])
 698
 699 dnl
 700 dnl Check for "pcap_datalink_name_to_val()", and use a substitute
 701 dnl version if it's not present.  If it is present, check for
 702 dnl "pcap_datalink_val_to_description()", and if we don't have it,
 703 dnl use a substitute version.
 704 dnl
 705 AC_CHECK_FUNC(pcap_datalink_name_to_val,
 706         [
 707             AC_DEFINE(HAVE_PCAP_DATALINK_NAME_TO_VAL, 1,
 708                 [define if libpcap has pcap_datalink_name_to_val()])
 709             AC_CHECK_FUNC(pcap_datalink_val_to_description,
 710                 AC_DEFINE(HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION, 1,
 711                     [define if libpcap has pcap_datalink_val_to_description()]),
 712                 [
 713                     AC_LIBOBJ(dlnames)
 714                 ])
 715         ],
 716         [
 717             AC_LIBOBJ(dlnames)
 718         ])
 719
 720 dnl
 721 dnl Check for "pcap_set_datalink()"; you can't substitute for it if
 722 dnl it's absent (it has hooks into libpcap), so just define the
 723 dnl HAVE_ value if it's there.
 724 dnl
 725 AC_CHECK_FUNCS(pcap_set_datalink)
 726
 727 dnl
 728 dnl Check for "pcap_breakloop()"; you can't substitute for it if
 729 dnl it's absent (it has hooks into the live capture routines),
 730 dnl so just define the HAVE_ value if it's there.
 731 dnl
 732 AC_CHECK_FUNCS(pcap_breakloop)
 733
 734 #
 735 # Do we have the new open API?  Check for pcap_create, and assume that,
 736 # if we do, we also have pcap_activate() and the other new routines
 737 # introduced in libpcap 1.0.0.
 738 #
 739 AC_CHECK_FUNCS(pcap_create)
 740 if test $ac_cv_func_pcap_create = "yes" ; then
 741         #
 742         # OK, do we have pcap_set_tstamp_type?  If so, assume we have
 743         # pcap_list_tstamp_types and pcap_free_tstamp_types as well.
 744         #
 745         AC_CHECK_FUNCS(pcap_set_tstamp_type)
 746         #
 747         # And do we have pcap_set_tstamp_precision?  If so, we assume
 748         # we also have pcap_open_offline_with_tstamp_precision.
 749         #
 750         AC_CHECK_FUNCS(pcap_set_tstamp_precision)
 751 fi
 752
 753 #
 754 # Check for a miscellaneous collection of functions which we use
 755 # if we have them.
 756 #
 757 AC_CHECK_FUNCS(pcap_findalldevs)
 758 if test $ac_cv_func_pcap_findalldevs = "yes" ; then
 759 dnl Check for libpcap having pcap_findalldevs() but the pcap.h header
 760 dnl not having pcap_if_t; some versions of Mac OS X shipped with pcap.h
 761 dnl from 0.6 and libpcap 0.8, so that libpcap had pcap_findalldevs but
 762 dnl pcap.h didn't have pcap_if_t.
 763     savedcppflags="$CPPFLAGS"
 764     CPPFLAGS="$CPPFLAGS $V_INCLS"
 765     AC_CHECK_TYPES(pcap_if_t, , , [#include <pcap.h>])
 766     CPPFLAGS="$savedcppflags"
 767 fi
 768 AC_CHECK_FUNCS(pcap_dump_flush pcap_lib_version)
 769 if test $ac_cv_func_pcap_lib_version = "no" ; then
 770     AC_MSG_CHECKING(whether pcap_version is defined by libpcap)
 771     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
 772         extern char pcap_version[];
 773
 774         return (int)pcap_version;
 775        ]])
 776        ],
 777        [ac_lbl_cv_pcap_version_defined=yes],
 778        [ac_lbl_cv_pcap_version_defined=no])
 779     if test "$ac_lbl_cv_pcap_version_defined" = yes ; then
 780         AC_MSG_RESULT(yes)
 781         AC_DEFINE(HAVE_PCAP_VERSION, 1, [define if libpcap has pcap_version])
 782     else
 783         AC_MSG_RESULT(no)
 784     fi
 785 fi
 786 AC_CHECK_FUNCS(pcap_setdirection pcap_set_immediate_mode pcap_dump_ftell64)
 787 AC_CHECK_FUNCS(pcap_open pcap_findalldevs_ex)
 788 AC_REPLACE_FUNCS(pcap_dump_ftell)
 789
 790 #
 791 # Check for special debugging functions
 792 #
 793 AC_CHECK_FUNCS(pcap_set_parser_debug)
 794 if test "$ac_cv_func_pcap_set_parser_debug" = "no" ; then
 795         #
 796         # OK, we don't have pcap_set_parser_debug() to set the libpcap
 797         # filter expression parser debug flag; can we directly set the
 798         # flag?
 799         AC_MSG_CHECKING(whether pcap_debug is defined by libpcap)
 800         AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
 801                 extern int pcap_debug;
 802
 803                 return pcap_debug;
 804            ]])
 805            ],
 806            [ac_lbl_cv_pcap_debug_defined=yes],
 807            [ac_lbl_cv_pcap_debug_defined=no])
 808         if test "$ac_lbl_cv_pcap_debug_defined" = yes ; then
 809                 AC_MSG_RESULT(yes)
 810                 AC_DEFINE(HAVE_PCAP_DEBUG, 1, [define if libpcap has pcap_debug])
 811         else
 812                 AC_MSG_RESULT(no)
 813                 #
 814                 # OK, what about "yydebug"?
 815                 #
 816                 AC_MSG_CHECKING(whether yydebug is defined by libpcap)
 817                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
 818                         extern int yydebug;
 819
 820                         return yydebug;
 821                    ]])
 822                    ],
 823                    [ac_lbl_cv_yydebug_defined=yes],
 824                    [ac_lbl_cv_yydebug_defined=no])
 825                 if test "$ac_lbl_cv_yydebug_defined" = yes ; then
 826                         AC_MSG_RESULT(yes)
 827                         AC_DEFINE(HAVE_YYDEBUG, 1, [define if libpcap has yydebug])
 828                 else
 829                         AC_MSG_RESULT(no)
 830                 fi
 831         fi
 832 fi
 833 AC_CHECK_FUNCS(pcap_set_optimizer_debug)
 834 AC_REPLACE_FUNCS(bpf_dump)      dnl moved to libpcap in 0.6
 835
 836 V_GROUP=0
 837 if test -f /etc/group -a ! -z "`grep '^wheel:' /etc/group`" ; then
 838         V_GROUP=wheel
 839 fi
 840 #
 841 # Assume V7/BSD convention for man pages (file formats in section 5,
 842 # miscellaneous info in section 7).
 843 #
 844 MAN_FILE_FORMATS=5
 845 MAN_MISC_INFO=7
 846 case "$host_os" in
 847
 848 aix*)
 849         dnl Workaround to enable certain features
 850         AC_DEFINE(_SUN,1,[define on AIX to get certain functions])
 851         ;;
 852
 853 hpux*)
 854         #
 855         # Use System V conventions for man pages.
 856         #
 857         MAN_FILE_FORMATS=4
 858         MAN_MISC_INFO=5
 859         ;;
 860
 861 irix*)
 862         V_GROUP=sys
 863
 864         #
 865         # Use System V conventions for man pages.
 866         #
 867         MAN_FILE_FORMATS=4
 868         MAN_MISC_INFO=5
 869         ;;
 870
 871 osf*)
 872         V_GROUP=system
 873
 874         #
 875         # Use System V conventions for man pages.
 876         #
 877         MAN_FILE_FORMATS=4
 878         MAN_MISC_INFO=5
 879         ;;
 880
 881 solaris*)
 882         V_GROUP=sys
 883
 884         #
 885         # Use System V conventions for man pages.
 886         #
 887         MAN_FILE_FORMATS=4
 888         MAN_MISC_INFO=5
 889         ;;
 890 esac
 891
 892 if test -f /dev/bpf0 ; then
 893         V_GROUP=bpf
 894 fi
 895
 896 #
 897 # Make sure we have a definition for C99's uintptr_t (regardless of
 898 # whether the environment is a C99 environment or not).
 899 #
 900 AC_TYPE_UINTPTR_T
 901
 902 #
 903 # Check whether we have pcap/pcap-inttypes.h.
 904 # If we do, we use that to get the C99 types defined.
 905 #
 906 savedcppflags="$CPPFLAGS"
 907 CPPFLAGS="$CPPFLAGS $V_INCLS"
 908 AC_CHECK_HEADERS(pcap/pcap-inttypes.h)
 909 CPPFLAGS="$savedcppflags"
 910
 911 #
 912 # Define the old BSD specified-width types in terms of the C99 types;
 913 # we may need them with libpcap include files.
 914 #
 915 AC_CHECK_TYPE([u_int8_t], ,
 916         [AC_DEFINE([u_int8_t], [uint8_t],
 917         [Define to `uint8_t' if u_int8_t not defined.])],
 918         [AC_INCLUDES_DEFAULT
 919 #include <sys/types.h>
 920 ])
 921 AC_CHECK_TYPE([u_int16_t], ,
 922         [AC_DEFINE([u_int16_t], [uint16_t],
 923         [Define to `uint16_t' if u_int16_t not defined.])],
 924         [AC_INCLUDES_DEFAULT
 925 #include <sys/types.h>
 926 ])
 927 AC_CHECK_TYPE([u_int32_t], ,
 928         [AC_DEFINE([u_int32_t], [uint32_t],
 929         [Define to `uint32_t' if u_int32_t not defined.])],
 930         [AC_INCLUDES_DEFAULT
 931 #include <sys/types.h>
 932 ])
 933 AC_CHECK_TYPE([u_int64_t], ,
 934         [AC_DEFINE([u_int64_t], [uint64_t],
 935         [Define to `uint64_t' if u_int64_t not defined.])],
 936         [AC_INCLUDES_DEFAULT
 937 #include <sys/types.h>
 938 ])
 939
 940 AC_PROG_RANLIB
 941 AC_CHECK_TOOL([AR], [ar])
 942
 943 AC_LBL_DEVEL(V_CCOPT)
 944
 945 # Check for OpenSSL/libressl libcrypto
 946 AC_MSG_CHECKING(whether to use OpenSSL/libressl libcrypto)
 947 # Specify location for both includes and libraries.
 948 want_libcrypto=ifavailable
 949 AC_ARG_WITH(crypto,
 950     AS_HELP_STRING([--with-crypto]@<:@=DIR@:>@,
 951                    [use OpenSSL/libressl libcrypto (located in directory DIR, if specified) @<:@default=yes, if available@:>@]),
 952 [
 953         if test $withval = no
 954         then
 955                 # User doesn't want to link with libcrypto.
 956                 want_libcrypto=no
 957                 AC_MSG_RESULT(no)
 958         elif test $withval = yes
 959         then
 960                 # User wants to link with libcrypto but hasn't specified
 961                 # a directory.
 962                 want_libcrypto=yes
 963                 AC_MSG_RESULT(yes)
 964         else
 965                 # User wants to link with libcrypto and has specified
 966                 # a directory, so use the provided value.
 967                 want_libcrypto=yes
 968                 libcrypto_root=$withval
 969                 AC_MSG_RESULT([yes, using the version installed in $withval])
 970
 971                 #
 972                 # Put the subdirectories of the libcrypto root directory
 973                 # at the front of the header and library search path.
 974                 #
 975                 CFLAGS="-I$withval/include $CFLAGS"
 976                 LIBS="-L$withval/lib $LIBS"
 977         fi
 978 ],[
 979         #
 980         # Use libcrypto if it's present, otherwise don't; no directory
 981         # was specified.
 982         #
 983         want_libcrypto=ifavailable
 984         AC_MSG_RESULT([yes, if available])
 985 ])
 986 if test "$want_libcrypto" != "no"; then
 987         #
 988         # Don't check for libcrypto unless we have its headers;
 989         # Apple, bless their pointy little heads, apparently ship
 990         # libcrypto as a library, but not the header files, in
 991         # El Capitan, probably because they don't want you writing
 992         # nasty portable code that could run on other UN*Xes, they
 993         # want you writing code that uses their Shiny New Crypto
 994         # Library and that only runs on macOS.
 995         #
 996         AC_CHECK_HEADER(openssl/crypto.h,
 997         [
 998                 AC_CHECK_LIB(crypto, DES_cbc_encrypt)
 999                 if test "$ac_cv_lib_crypto_DES_cbc_encrypt" = "yes"; then
1000                         AC_CHECK_HEADERS(openssl/evp.h)
1001                         #
1002                         # OK, then:
1003                         #
1004                         # 1) do we have EVP_CIPHER_CTX_new?
1005                         # If so, we use it to allocate an
1006                         # EVP_CIPHER_CTX, as EVP_CIPHER_CTX may be
1007                         # opaque; otherwise, we allocate it ourselves.
1008                         #
1009                         # 2) do we have EVP_DecryptInit_ex()?
1010                         # If so, we use it, because we need to be
1011                         # able to make two "initialize the cipher"
1012                         # calls, one with the cipher and key, and
1013                         # one with the IV, and, as of OpenSSL 1.1,
1014                         # You Can't Do That with EVP_DecryptInit(),
1015                         # because a call to EVP_DecryptInit() will
1016                         # unconditionally clear the context, and
1017                         # if you don't supply a cipher, it'll
1018                         # clear the cipher, rendering the context
1019                         # unusable and causing a crash.
1020                         #
1021                         AC_CHECK_FUNCS(EVP_CIPHER_CTX_new EVP_DecryptInit_ex)
1022                 fi
1023         ])
1024 fi
1025
1026 # Check for libcap-ng
1027 AC_MSG_CHECKING(whether to use libcap-ng)
1028 # Specify location for both includes and libraries.
1029 want_libcap_ng=ifavailable
1030 AC_ARG_WITH(cap_ng,
1031     AS_HELP_STRING([--with-cap-ng],
1032                    [use libcap-ng @<:@default=yes, if available@:>@]),
1033 [
1034         if test $withval = no
1035         then
1036                 want_libcap_ng=no
1037                 AC_MSG_RESULT(no)
1038         elif test $withval = yes
1039         then
1040                 want_libcap_ng=yes
1041                 AC_MSG_RESULT(yes)
1042         fi
1043 ],[
1044         #
1045         # Use libcap-ng if it's present, otherwise don't.
1046         #
1047         want_libcap_ng=ifavailable
1048         AC_MSG_RESULT([yes, if available])
1049 ])
1050 if test "$want_libcap_ng" != "no"; then
1051         AC_CHECK_LIB(cap-ng, capng_change_id)
1052         AC_CHECK_HEADERS(cap-ng.h)
1053 fi
1054
1055 dnl
1056 dnl set additional include path if necessary
1057 if test "$missing_includes" = "yes"; then
1058         CPPFLAGS="$CPPFLAGS -I$srcdir/missing"
1059         V_INCLS="$V_INCLS -I$srcdir/missing"
1060 fi
1061
1062 AC_SUBST(V_CCOPT)
1063 AC_SUBST(V_DEFS)
1064 AC_SUBST(V_GROUP)
1065 AC_SUBST(V_INCLS)
1066 AC_SUBST(V_PCAPDEP)
1067 AC_SUBST(LOCALSRC)
1068 AC_SUBST(MAN_FILE_FORMATS)
1069 AC_SUBST(MAN_MISC_INFO)
1070
1071 AC_PROG_INSTALL
1072
1073 AC_CONFIG_HEADER(config.h)
1074
1075 AC_CONFIG_COMMANDS([.devel],[[if test -f .devel; then
1076         echo timestamp > stamp-h
1077         cat $srcdir/Makefile-devel-adds >> Makefile
1078         make depend || exit 1
1079 fi]],[[]])
1080 AC_CONFIG_FILES([Makefile tcpdump.1])
1081 AC_OUTPUT
1082 exit 0