The Tcpdump Group git mirrors - tcpdump/blob - configure.ac

   1 dnl Copyright (c) 1994, 1995, 1996, 1997
   2 dnl     The Regents of the University of California.  All rights reserved.
   3 dnl
   4 dnl Process this file with autoconf to produce a configure script.
   5 dnl
   6
   7 #
   8 # See
   9 #
  10 #       https://ftp.gnu.org/gnu/config/README
  11 #
  12 # for the URLs to use to fetch new versions of config.guess and
  13 # config.sub.
  14 #
  15
  16 AC_PREREQ(2.64)
  17 AC_INIT(tcpdump, m4_esyscmd_s([cat VERSION]))
  18 AC_CONFIG_SRCDIR(tcpdump.c)
  19
  20 AC_CANONICAL_HOST
  21
  22 AC_LBL_C_INIT_BEFORE_CC(V_INCLS)
  23 #
  24 # Try to enable as many C99 features as we can.
  25 # At minimum, we want C++/C99-style // comments.
  26 #
  27 AC_PROG_CC_C99
  28 if test "$ac_cv_prog_cc_c99" = "no"; then
  29         AC_MSG_WARN([The C compiler does not support C99; there may be compiler errors])
  30 fi
  31 AC_LBL_C_INIT(V_CCOPT, V_INCLS)
  32 AC_LBL_C_INLINE
  33
  34 AC_CHECK_HEADERS(fcntl.h rpc/rpc.h rpc/rpcent.h net/if.h)
  35
  36 case "$host_os" in
  37
  38 darwin*)
  39         AC_ARG_ENABLE(universal,
  40         AS_HELP_STRING([--disable-universal],[don't build universal on macOS]))
  41         if test "$enable_universal" != "no"; then
  42                 case "$host_os" in
  43
  44                 darwin9.*)
  45                         #
  46                         # Leopard.  Build for x86 and 32-bit PowerPC, with
  47                         # x86 first.  (That's what Apple does.)
  48                         #
  49                         V_CCOPT="$V_CCOPT -arch i386 -arch ppc"
  50                         LDFLAGS="$LDFLAGS -arch i386 -arch ppc"
  51                         ;;
  52
  53                 darwin10.*)
  54                         #
  55                         # Snow Leopard.  Build for x86-64 and x86, with
  56                         # x86-64 first.  (That's what Apple does.)
  57                         #
  58                         V_CCOPT="$V_CCOPT -arch x86_64 -arch i386"
  59                         LDFLAGS="$LDFLAGS -arch x86_64 -arch i386"
  60                         ;;
  61                 esac
  62         fi
  63         ;;
  64 esac
  65
  66
  67 AC_ARG_WITH([smi],
  68    [AS_HELP_STRING([--with-smi],
  69      [link with libsmi (allows to load MIBs on the fly to decode SNMP packets) [default=yes, if available]])],
  70    [],
  71    [with_smi=yes])
  72
  73 if test "x$with_smi" != "xno" ; then
  74         AC_CHECK_HEADER(smi.h,
  75         [
  76                 #
  77                 # OK, we found smi.h.  Do we have libsmi with smiInit?
  78                 #
  79                 AC_CHECK_LIB(smi, smiInit,
  80                 [
  81                         #
  82                         # OK, we have libsmi with smiInit.  Can we use it?
  83                         #
  84                         AC_MSG_CHECKING([whether to enable libsmi])
  85                         savedlibs="$LIBS"
  86                         LIBS="-lsmi $LIBS"
  87                         AC_TRY_RUN(
  88                                 [
  89 /* libsmi available check */
  90 #include <smi.h>
  91 main()
  92 {
  93   int current, revision, age, n;
  94   const int required = 2;
  95   if (smiInit(""))
  96     exit(1);
  97   if (strcmp(SMI_LIBRARY_VERSION, smi_library_version))
  98     exit(2);
  99   n = sscanf(smi_library_version, "%d:%d:%d", &current, &revision, &age);
 100   if (n != 3)
 101     exit(3);
 102   if (required < current - age || required > current)
 103     exit(4);
 104   exit(0);
 105 }
 106                                 ],
 107                                 [
 108                                         AC_MSG_RESULT(yes)
 109                                         AC_DEFINE(USE_LIBSMI, 1,
 110                                             [Define if you enable support for libsmi])
 111                                 ],
 112                                 [
 113                                         dnl autoconf documentation says that
 114                                         dnl $? contains the exit value.
 115                                         dnl reality is that it does not.
 116                                         dnl We leave this in just in case
 117                                         dnl autoconf ever comes back to
 118                                         dnl match the documentation.
 119                                         case $? in
 120                                           1) AC_MSG_RESULT(no - smiInit failed) ;;
 121                                           2) AC_MSG_RESULT(no - header/library version mismatch) ;;
 122                                           3) AC_MSG_RESULT(no - can't determine library version) ;;
 123                                           4) AC_MSG_RESULT(no - too old) ;;
 124                                           *) AC_MSG_RESULT(no) ;;
 125                                         esac
 126                                         LIBS="$savedlibs"
 127                                 ],
 128                                 [
 129                                         AC_MSG_RESULT(not when cross-compiling)
 130                                         LIBS="$savedlibs"
 131                                 ]
 132                         )
 133                 ])
 134         ])
 135 fi
 136
 137 AC_MSG_CHECKING([whether to enable the possibly-buggy SMB printer])
 138 AC_ARG_ENABLE([smb],
 139    [AS_HELP_STRING([--enable-smb],
 140      [enable possibly-buggy SMB printer [default=no]])],
 141    [],
 142    [enableval=no])
 143 case "$enableval" in
 144 yes)    AC_MSG_RESULT(yes)
 145         AC_DEFINE(ENABLE_SMB, 1,
 146             [define if you want to build the possibly-buggy SMB printer])
 147         LOCALSRC="print-smb.c smbutil.c $LOCALSRC"
 148         ;;
 149 *)      AC_MSG_RESULT(no)
 150         ;;
 151 esac
 152
 153 AC_ARG_WITH(user, [  --with-user=USERNAME    drop privileges by default to USERNAME])
 154 AC_MSG_CHECKING([whether to drop root privileges by default])
 155 if test ! -z "$with_user" ; then
 156        AC_DEFINE_UNQUOTED(WITH_USER, "$withval",
 157            [define if should drop privileges by default])
 158        AC_MSG_RESULT(to \"$withval\")
 159 else
 160        AC_MSG_RESULT(no)
 161 fi
 162
 163 AC_ARG_WITH(chroot, [  --with-chroot=DIRECTORY when dropping privileges, chroot to DIRECTORY])
 164 AC_MSG_CHECKING([whether to chroot])
 165 if test ! -z "$with_chroot" && test "$with_chroot" != "no" ; then
 166        AC_DEFINE_UNQUOTED(WITH_CHROOT, "$withval",
 167            [define if should chroot when dropping privileges])
 168        AC_MSG_RESULT(to \"$withval\")
 169 else
 170        AC_MSG_RESULT(no)
 171 fi
 172
 173 AC_ARG_WITH(sandbox-capsicum,
 174         AS_HELP_STRING([--with-sandbox-capsicum],
 175                        [use Capsicum security functions @<:@default=yes, if available@:>@]))
 176 #
 177 # Check whether various functions are available.  If any are, set
 178 # ac_lbl_capsicum_function_seen to yes; if any are not, set
 179 # ac_lbl_capsicum_function_not_seen to yes.
 180 #
 181 # We don't check cap_rights_init(), as it's a macro, wrapping another
 182 # function, in at least some versions of FreeBSD, and AC_CHECK_FUNCS()
 183 # doesn't handle that.
 184 #
 185 # All of the ones we check for must be available in order to enable
 186 # capsicum sandboxing.
 187 #
 188 # XXX - do we need to check for all of them, or are there some that, if
 189 # present, imply others are present?
 190 #
 191 if test -z "$with_sandbox_capsicum" || test "$with_sandbox_capsicum" != "no" ; then
 192         #
 193         # First, make sure we have the required header.
 194         #
 195         AC_CHECK_HEADER(sys/capsicum.h,
 196         [
 197                 #
 198                 # We do; now make sure we have the required functions.
 199                 #
 200                 AC_CHECK_FUNCS(cap_enter cap_rights_limit cap_ioctls_limit openat,
 201                     ac_lbl_capsicum_function_seen=yes,
 202                     ac_lbl_capsicum_function_not_seen=yes)
 203         ])
 204         AC_CHECK_LIB(casper, cap_init, LIBS="$LIBS -lcasper")
 205         AC_CHECK_LIB(cap_dns, cap_gethostbyaddr, LIBS="$LIBS -lcap_dns")
 206 fi
 207 AC_MSG_CHECKING([whether to sandbox using capsicum])
 208 if test "x$ac_lbl_capsicum_function_seen" = "xyes" -a "x$ac_lbl_capsicum_function_not_seen" != "xyes"; then
 209         AC_DEFINE(HAVE_CAPSICUM, 1, [capsicum support available])
 210         AC_MSG_RESULT(yes)
 211 else
 212         AC_MSG_RESULT(no)
 213 fi
 214 AC_MSG_CHECKING([whether to sandbox using Casper library])
 215 if test "x$ac_cv_lib_casper_cap_init" = "xyes" -a "x$ac_cv_lib_cap_dns_cap_gethostbyaddr" = "xyes"; then
 216         AC_DEFINE(HAVE_CASPER, 1, [Casper support available])
 217         AC_MSG_RESULT(yes)
 218 else
 219         AC_MSG_RESULT(no)
 220 fi
 221
 222 #
 223 # We must check this before checking whether to check the OS's IPv6,
 224 # support because, on some platforms (such as SunOS 5.x), the test
 225 # program requires the extra networking libraries.
 226 #
 227 AC_LBL_LIBRARY_NET
 228
 229 #
 230 # Check whether AF_INET6 and struct in6_addr are defined.
 231 # If they aren't both defined, we don't have sufficient OS
 232 # support for IPv6, so we don't look for IPv6 support libraries,
 233 # and we define AF_INET6 and struct in6_addr ourselves.
 234 #
 235 AC_MSG_CHECKING([whether the operating system supports IPv6])
 236 AC_COMPILE_IFELSE(
 237     [
 238       AC_LANG_SOURCE(
 239         [[
 240 /* AF_INET6 available check */
 241 #include <sys/types.h>
 242 #ifdef _WIN32
 243 #include <ws2tcpip.h>
 244 #else
 245 #include <sys/socket.h>
 246 #include <netinet/in.h>
 247 #endif
 248 #ifdef AF_INET6
 249 void
 250 foo(struct in6_addr *addr)
 251 {
 252  memset(addr, 0, sizeof (struct in6_addr));
 253 }
 254 #else
 255 #error "AF_INET6 not defined"
 256 #endif
 257         ]])
 258     ],
 259     [
 260         AC_MSG_RESULT(yes)
 261         AC_DEFINE(HAVE_OS_IPV6_SUPPORT, 1,
 262             [define if the OS provides AF_INET6 and struct in6_addr])
 263         ipv6=yes
 264     ],
 265     [
 266         AC_MSG_RESULT(no)
 267         ipv6=no
 268     ]
 269 )
 270
 271 ipv6type=unknown
 272 ipv6lib=none
 273 ipv6trylibc=no
 274
 275 if test "$ipv6" = "yes"; then
 276         AC_MSG_CHECKING([ipv6 stack type])
 277         for i in inria kame linux-glibc linux-libinet6 toshiba v6d zeta; do
 278                 case $i in
 279                 inria)
 280                         dnl http://www.kame.net/
 281                         AC_EGREP_CPP(yes,
 282 [#include <netinet/in.h>
 283 #ifdef IPV6_INRIA_VERSION
 284 yes
 285 #endif],
 286                                 [ipv6type=$i])
 287                         ;;
 288                 kame)
 289                         dnl http://www.kame.net/
 290                         AC_EGREP_CPP(yes,
 291 [#include <netinet/in.h>
 292 #ifdef __KAME__
 293 yes
 294 #endif],
 295                                 [ipv6type=$i;
 296                                 ipv6lib=inet6;
 297                                 ipv6libdir=/usr/local/v6/lib;
 298                                 ipv6trylibc=yes])
 299                         ;;
 300                 linux-glibc)
 301                         dnl http://www.v6.linux.or.jp/
 302                         AC_EGREP_CPP(yes,
 303 [#include <features.h>
 304 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 305 yes
 306 #endif],
 307                                 [ipv6type=$i])
 308                         ;;
 309                 linux-libinet6)
 310                         dnl http://www.v6.linux.or.jp/
 311                         dnl
 312                         dnl This also matches Solaris 8 and Tru64 UNIX 5.1,
 313                         dnl and possibly other versions of those OSes
 314                         dnl
 315                         if test -d /usr/inet6 -o -f /usr/include/netinet/ip6.h; then
 316                                 ipv6type=$i
 317                                 ipv6lib=inet6
 318                                 ipv6libdir=/usr/inet6/lib
 319                                 ipv6trylibc=yes;
 320                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 321                         fi
 322                         ;;
 323                 toshiba)
 324                         AC_EGREP_CPP(yes,
 325 [#include <sys/param.h>
 326 #ifdef _TOSHIBA_INET6
 327 yes
 328 #endif],
 329                                 [ipv6type=$i;
 330                                 ipv6lib=inet6;
 331                                 ipv6libdir=/usr/local/v6/lib])
 332                         ;;
 333                 v6d)
 334                         AC_EGREP_CPP(yes,
 335 [#include </usr/local/v6/include/sys/v6config.h>
 336 #ifdef __V6D__
 337 yes
 338 #endif],
 339                                 [ipv6type=$i;
 340                                 ipv6lib=v6;
 341                                 ipv6libdir=/usr/local/v6/lib;
 342                                 CFLAGS="-I/usr/local/v6/include $CFLAGS"])
 343                         ;;
 344                 zeta)
 345                         AC_EGREP_CPP(yes,
 346 [#include <sys/param.h>
 347 #ifdef _ZETA_MINAMI_INET6
 348 yes
 349 #endif],
 350                                 [ipv6type=$i;
 351                                 ipv6lib=inet6;
 352                                 ipv6libdir=/usr/local/v6/lib])
 353                         ;;
 354                 esac
 355                 if test "$ipv6type" != "unknown"; then
 356                         break
 357                 fi
 358         done
 359         AC_MSG_RESULT($ipv6type)
 360 fi
 361
 362 if test "$ipv6" = "yes" -a "$ipv6lib" != "none"; then
 363         if test -d $ipv6libdir -a -f $ipv6libdir/lib$ipv6lib.a; then
 364                 LIBS="-L$ipv6libdir -l$ipv6lib $LIBS"
 365                 echo "You have $ipv6lib library, using it"
 366         else
 367                 if test "$ipv6trylibc" = "yes"; then
 368                         echo "You do not have $ipv6lib library, using libc"
 369                 else
 370                         echo 'Fatal: no $ipv6lib library found.  cannot continue.'
 371                         echo "You need to fetch lib$ipv6lib.a from appropriate"
 372                         echo 'ipv6 kit and compile beforehand.'
 373                         exit 1
 374                 fi
 375         fi
 376 fi
 377
 378 AC_REPLACE_FUNCS(strlcat strlcpy strdup strsep getservent getopt_long)
 379 AC_CHECK_FUNCS(fork vfork strftime)
 380 AC_CHECK_FUNCS(setlinebuf)
 381
 382 #
 383 # Make sure we have vsnprintf() and snprintf(); we require them.
 384 #
 385 AC_CHECK_FUNC(vsnprintf,,
 386     AC_MSG_ERROR([vsnprintf() is required but wasn't found]))
 387 AC_CHECK_FUNC(snprintf,,
 388     AC_MSG_ERROR([snprintf() is required but wasn't found]))
 389
 390 #
 391 # Define HAVE_NO_PRINTF_Z to make it possible to disable test cases that
 392 # depend on %zu.
 393 #
 394 AC_MSG_CHECKING([whether printf(3) supports the z length modifier])
 395 AC_RUN_IFELSE(
 396     [
 397         AC_LANG_SOURCE([[
 398 #include <stdio.h>
 399 #include <string.h>
 400
 401 int main()
 402 {
 403   char buf[100];
 404   snprintf(buf, sizeof(buf), "%zu", sizeof(buf));
 405   return strncmp(buf, "100", sizeof(buf)) ? 1 : 0;
 406 }
 407         ]])
 408     ],
 409     [
 410         AC_MSG_RESULT(yes)
 411     ],
 412     [
 413         AC_MSG_RESULT(no)
 414         AC_DEFINE(HAVE_NO_PRINTF_Z, 1,
 415             [Define to 1 if printf(3) does not support the z length modifier.])
 416     ],
 417     [
 418         AC_MSG_RESULT(not while cross-compiling)
 419     ]
 420 )
 421
 422 AC_CHECK_LIB(rpc, main)         dnl It's unclear why we might need -lrpc
 423
 424 dnl Some platforms may need -lnsl for getrpcbynumber.
 425 AC_SEARCH_LIBS(getrpcbynumber, nsl,
 426     AC_DEFINE(HAVE_GETRPCBYNUMBER, 1, [define if you have getrpcbynumber()]))
 427
 428 AC_LBL_LIBPCAP(V_PCAPDEP, V_INCLS)
 429
 430 #
 431 # Check for these after AC_LBL_LIBPCAP, so we link with the appropriate
 432 # libraries (e.g., "-lsocket -lnsl" on Solaris).
 433 #
 434 # You are in a twisty little maze of UN*Xes, all different.
 435 # Some might not have ether_ntohost().
 436 # Some might have it and declare it in <net/ethernet.h>.
 437 # Some might have it and declare it in <netinet/ether.h>
 438 # Some might have it and declare it in <sys/ethernet.h>.
 439 # Some might have it and declare it in <arpa/inet.h>.
 440 # Some might have it and declare it in <netinet/if_ether.h>.
 441 # Some might have it and not declare it in any header file.
 442 #
 443 # Before you is a C compiler.
 444 #
 445 AC_CHECK_FUNCS(ether_ntohost, [
 446     AC_CACHE_CHECK(for buggy ether_ntohost, ac_cv_buggy_ether_ntohost, [
 447         AC_TRY_RUN([
 448                 #include <netdb.h>
 449                 #include <sys/types.h>
 450                 #include <sys/param.h>
 451                 #include <sys/socket.h>
 452
 453                 int
 454                 main(int argc, char **argv)
 455                 {
 456                         u_char ea[6] = { 0xff, 0xff, 0xff, 0xff, 0xff };
 457                         char name[MAXHOSTNAMELEN];
 458
 459                         ether_ntohost(name, (struct ether_addr *)ea);
 460                         exit(0);
 461                 }
 462         ], [ac_cv_buggy_ether_ntohost=no],
 463            [ac_cv_buggy_ether_ntohost=yes],
 464            [ac_cv_buggy_ether_ntohost="not while cross-compiling"])])
 465     if test "$ac_cv_buggy_ether_ntohost" = "no"; then
 466         AC_DEFINE(USE_ETHER_NTOHOST, 1,
 467             [define if you have ether_ntohost() and it works])
 468     fi
 469 ])
 470 if test "$ac_cv_func_ether_ntohost" = yes -a \
 471     "$ac_cv_buggy_ether_ntohost" = "no"; then
 472         #
 473         # OK, we have ether_ntohost().  Is it declared in <net/ethernet.h>?
 474         #
 475         # This test fails if we don't have <net/ethernet.h> or if we do
 476         # but it doesn't declare ether_ntohost().
 477         #
 478         AC_CHECK_DECL(ether_ntohost,
 479             [
 480                 AC_DEFINE(NET_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
 481                     [Define to 1 if net/ethernet.h declares `ether_ntohost'])
 482             ],,
 483             [
 484 #include <net/ethernet.h>
 485             ])
 486         #
 487         # Did that succeed?
 488         #
 489         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 490                 #
 491                 # No, how about <netinet/ether.h>, as on Linux?
 492                 #
 493                 # This test fails if we don't have <netinet/ether.h>
 494                 # or if we do but it doesn't declare ether_ntohost().
 495                 #
 496                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 497                 # treat the previous failure as a cached value and
 498                 # suppress the next test.
 499                 #
 500                 unset ac_cv_have_decl_ether_ntohost
 501                 AC_CHECK_DECL(ether_ntohost,
 502                     [
 503                         AC_DEFINE(NETINET_ETHER_H_DECLARES_ETHER_NTOHOST,,
 504                             [Define to 1 if netinet/ether.h declares `ether_ntohost'])
 505                     ],,
 506                     [
 507 #include <netinet/ether.h>
 508                     ])
 509         fi
 510         #
 511         # Did that succeed?
 512         #
 513         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 514                 #
 515                 # No, how about <sys/ethernet.h>, as on Solaris 10
 516                 # and later?
 517                 #
 518                 # This test fails if we don't have <sys/ethernet.h>
 519                 # or if we do but it doesn't declare ether_ntohost().
 520                 #
 521                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 522                 # treat the previous failure as a cached value and
 523                 # suppress the next test.
 524                 #
 525                 unset ac_cv_have_decl_ether_ntohost
 526                 AC_CHECK_DECL(ether_ntohost,
 527                     [
 528                         AC_DEFINE(SYS_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
 529                             [Define to 1 if sys/ethernet.h declares `ether_ntohost'])
 530                     ],,
 531                     [
 532 #include <sys/ethernet.h>
 533                     ])
 534         fi
 535         #
 536         # Did that succeed?
 537         #
 538         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 539                 #
 540                 # No, how about <arpa/inet.h>, as in AIX?
 541                 #
 542                 # This test fails if we don't have <arpa/inet.h>
 543                 # (if we have ether_ntohost(), we should have
 544                 # networking, and if we have networking, we should
 545                 # have <arpa/inet.h>) or if we do but it doesn't
 546                 # declare ether_ntohost().
 547                 #
 548                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 549                 # treat the previous failure as a cached value and
 550                 # suppress the next test.
 551                 #
 552                 unset ac_cv_have_decl_ether_ntohost
 553                 AC_CHECK_DECL(ether_ntohost,
 554                     [
 555                         AC_DEFINE(ARPA_INET_H_DECLARES_ETHER_NTOHOST,,
 556                             [Define to 1 if arpa/inet.h declares `ether_ntohost'])
 557                     ],,
 558                     [
 559 #include <arpa/inet.h>
 560                     ])
 561         fi
 562         #
 563         # Did that succeed?
 564         #
 565         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 566                 #
 567                 # No, how about <netinet/if_ether.h>?
 568                 # On some platforms, it requires <net/if.h> and
 569                 # <netinet/in.h>, and we always include it with
 570                 # both of them, so test it with both of them.
 571                 #
 572                 # This test fails if we don't have <netinet/if_ether.h>
 573                 # and the headers we include before it, or if we do but
 574                 # <netinet/if_ether.h> doesn't declare ether_hostton().
 575                 #
 576                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 577                 # treat the previous failure as a cached value and
 578                 # suppress the next test.
 579                 #
 580                 unset ac_cv_have_decl_ether_ntohost
 581                 AC_CHECK_DECL(ether_ntohost,
 582                     [
 583                         AC_DEFINE(NETINET_IF_ETHER_H_DECLARES_ETHER_NTOHOST,,
 584                             [Define to 1 if netinet/if_ether.h declares `ether_ntohost'])
 585                     ],,
 586                     [
 587 #include <sys/types.h>
 588 #include <sys/socket.h>
 589 #include <net/if.h>
 590 #include <netinet/in.h>
 591 #include <netinet/if_ether.h>
 592                     ])
 593         fi
 594         #
 595         # After all that, is ether_ntohost() declared?
 596         #
 597         if test "$ac_cv_have_decl_ether_ntohost" = yes; then
 598                 #
 599                 # Yes.
 600                 #
 601                 AC_DEFINE(HAVE_DECL_ETHER_NTOHOST, 1,
 602                     [Define to 1 if you have the declaration of `ether_ntohost'])
 603         else
 604                 #
 605                 # No, we'll have to declare it ourselves.
 606                 # Do we have "struct ether_addr" if we include
 607                 # <netinet/if_ether.h>?
 608                 #
 609                 AC_CHECK_TYPES(struct ether_addr,,,
 610                     [
 611                         #include <sys/types.h>
 612                         #include <sys/socket.h>
 613                         #include <net/if.h>
 614                         #include <netinet/in.h>
 615                         #include <netinet/if_ether.h>
 616                     ])
 617         fi
 618 fi
 619
 620 dnl
 621 dnl Check for "pcap_list_datalinks()" and use a substitute version if
 622 dnl it's not present.  If it is present, check for "pcap_free_datalinks()";
 623 dnl if it's not present, we don't replace it for now.  (We could do so
 624 dnl on UN*X, but not on Windows, where hilarity ensues if a program
 625 dnl built with one version of the MSVC support library tries to free
 626 dnl something allocated by a library built with another version of
 627 dnl the MSVC support library.)
 628 dnl
 629 AC_CHECK_FUNC(pcap_list_datalinks,
 630         [
 631             AC_DEFINE(HAVE_PCAP_LIST_DATALINKS, 1,
 632                 [define if libpcap has pcap_list_datalinks()])
 633             AC_CHECK_FUNCS(pcap_free_datalinks)
 634         ],
 635         [
 636             AC_LIBOBJ(datalinks)
 637         ])
 638
 639 dnl
 640 dnl Check for "pcap_datalink_name_to_val()", and use a substitute
 641 dnl version if it's not present.  If it is present, check for
 642 dnl "pcap_datalink_val_to_description()", and if we don't have it,
 643 dnl use a substitute version.
 644 dnl
 645 AC_CHECK_FUNC(pcap_datalink_name_to_val,
 646         [
 647             AC_DEFINE(HAVE_PCAP_DATALINK_NAME_TO_VAL, 1,
 648                 [define if libpcap has pcap_datalink_name_to_val()])
 649             AC_CHECK_FUNC(pcap_datalink_val_to_description,
 650                 AC_DEFINE(HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION, 1,
 651                     [define if libpcap has pcap_datalink_val_to_description()]),
 652                 [
 653                     AC_LIBOBJ(dlnames)
 654                 ])
 655         ],
 656         [
 657             AC_LIBOBJ(dlnames)
 658         ])
 659
 660 dnl
 661 dnl Check for "pcap_set_datalink()"; you can't substitute for it if
 662 dnl it's absent (it has hooks into libpcap), so just define the
 663 dnl HAVE_ value if it's there.
 664 dnl
 665 AC_CHECK_FUNCS(pcap_set_datalink)
 666
 667 dnl
 668 dnl Check for "pcap_breakloop()"; you can't substitute for it if
 669 dnl it's absent (it has hooks into the live capture routines),
 670 dnl so just define the HAVE_ value if it's there.
 671 dnl
 672 AC_CHECK_FUNCS(pcap_breakloop)
 673
 674 #
 675 # Do we have the new open API?  Check for pcap_create, and assume that,
 676 # if we do, we also have pcap_activate() and the other new routines
 677 # introduced in libpcap 1.0.0.
 678 #
 679 AC_CHECK_FUNCS(pcap_create)
 680 if test $ac_cv_func_pcap_create = "yes" ; then
 681         #
 682         # OK, do we have pcap_set_tstamp_type?  If so, assume we have
 683         # pcap_list_tstamp_types and pcap_free_tstamp_types as well.
 684         #
 685         AC_CHECK_FUNCS(pcap_set_tstamp_type)
 686         #
 687         # And do we have pcap_set_tstamp_precision?  If so, we assume
 688         # we also have pcap_open_offline_with_tstamp_precision.
 689         #
 690         AC_CHECK_FUNCS(pcap_set_tstamp_precision)
 691 fi
 692
 693 #
 694 # Check for a miscellaneous collection of functions which we use
 695 # if we have them.
 696 #
 697 AC_CHECK_FUNCS(pcap_findalldevs)
 698 if test $ac_cv_func_pcap_findalldevs = "yes" ; then
 699 dnl Check for libpcap having pcap_findalldevs() but the pcap.h header
 700 dnl not having pcap_if_t; some versions of Mac OS X shipped with pcap.h
 701 dnl from 0.6 and libpcap 0.8, so that libpcap had pcap_findalldevs but
 702 dnl pcap.h didn't have pcap_if_t.
 703     savedcppflags="$CPPFLAGS"
 704     CPPFLAGS="$CPPFLAGS $V_INCLS"
 705     AC_CHECK_TYPES(pcap_if_t, , , [#include <pcap.h>])
 706     CPPFLAGS="$savedcppflags"
 707 fi
 708 AC_CHECK_FUNCS(pcap_dump_flush pcap_lib_version)
 709 if test $ac_cv_func_pcap_lib_version = "no" ; then
 710     AC_MSG_CHECKING(whether pcap_version is defined by libpcap)
 711     AC_TRY_LINK([],
 712        [
 713         extern char pcap_version[];
 714
 715         return (int)pcap_version;
 716        ],
 717        ac_lbl_cv_pcap_version_defined=yes,
 718        ac_lbl_cv_pcap_version_defined=no)
 719     if test "$ac_lbl_cv_pcap_version_defined" = yes ; then
 720         AC_MSG_RESULT(yes)
 721         AC_DEFINE(HAVE_PCAP_VERSION, 1, [define if libpcap has pcap_version])
 722     else
 723         AC_MSG_RESULT(no)
 724     fi
 725 fi
 726 AC_CHECK_FUNCS(pcap_setdirection pcap_set_immediate_mode pcap_dump_ftell64)
 727 AC_CHECK_FUNCS(pcap_open pcap_findalldevs_ex)
 728 AC_REPLACE_FUNCS(pcap_dump_ftell)
 729
 730 #
 731 # Check for special debugging functions
 732 #
 733 AC_CHECK_FUNCS(pcap_set_parser_debug)
 734 if test "$ac_cv_func_pcap_set_parser_debug" = "no" ; then
 735         #
 736         # OK, we don't have pcap_set_parser_debug() to set the libpcap
 737         # filter expression parser debug flag; can we directly set the
 738         # flag?
 739         AC_MSG_CHECKING(whether pcap_debug is defined by libpcap)
 740         AC_TRY_LINK([],
 741            [
 742                 extern int pcap_debug;
 743
 744                 return pcap_debug;
 745            ],
 746            ac_lbl_cv_pcap_debug_defined=yes,
 747            ac_lbl_cv_pcap_debug_defined=no)
 748         if test "$ac_lbl_cv_pcap_debug_defined" = yes ; then
 749                 AC_MSG_RESULT(yes)
 750                 AC_DEFINE(HAVE_PCAP_DEBUG, 1, [define if libpcap has pcap_debug])
 751         else
 752                 AC_MSG_RESULT(no)
 753                 #
 754                 # OK, what about "yydebug"?
 755                 #
 756                 AC_MSG_CHECKING(whether yydebug is defined by libpcap)
 757                 AC_TRY_LINK([],
 758                    [
 759                         extern int yydebug;
 760
 761                         return yydebug;
 762                    ],
 763                    ac_lbl_cv_yydebug_defined=yes,
 764                    ac_lbl_cv_yydebug_defined=no)
 765                 if test "$ac_lbl_cv_yydebug_defined" = yes ; then
 766                         AC_MSG_RESULT(yes)
 767                         AC_DEFINE(HAVE_YYDEBUG, 1, [define if libpcap has yydebug])
 768                 else
 769                         AC_MSG_RESULT(no)
 770                 fi
 771         fi
 772 fi
 773 AC_CHECK_FUNCS(pcap_set_optimizer_debug)
 774 AC_REPLACE_FUNCS(bpf_dump)      dnl moved to libpcap in 0.6
 775
 776 V_GROUP=0
 777 if test -f /etc/group -a ! -z "`grep '^wheel:' /etc/group`" ; then
 778         V_GROUP=wheel
 779 fi
 780 #
 781 # Assume V7/BSD convention for man pages (file formats in section 5,
 782 # miscellaneous info in section 7).
 783 #
 784 MAN_FILE_FORMATS=5
 785 MAN_MISC_INFO=7
 786 case "$host_os" in
 787
 788 aix*)
 789         dnl Workaround to enable certain features
 790         AC_DEFINE(_SUN,1,[define on AIX to get certain functions])
 791         ;;
 792
 793 hpux*)
 794         #
 795         # Use System V conventions for man pages.
 796         #
 797         MAN_FILE_FORMATS=4
 798         MAN_MISC_INFO=5
 799         ;;
 800
 801 irix*)
 802         V_GROUP=sys
 803
 804         #
 805         # Use System V conventions for man pages.
 806         #
 807         MAN_FILE_FORMATS=4
 808         MAN_MISC_INFO=5
 809         ;;
 810
 811 osf*)
 812         V_GROUP=system
 813
 814         #
 815         # Use System V conventions for man pages.
 816         #
 817         MAN_FILE_FORMATS=4
 818         MAN_MISC_INFO=5
 819         ;;
 820
 821 solaris*)
 822         V_GROUP=sys
 823
 824         #
 825         # Use System V conventions for man pages.
 826         #
 827         MAN_FILE_FORMATS=4
 828         MAN_MISC_INFO=5
 829         ;;
 830 esac
 831
 832 if test -f /dev/bpf0 ; then
 833         V_GROUP=bpf
 834 fi
 835
 836 #
 837 # Make sure we have a definition for C99's uintptr_t (regardless of
 838 # whether the environment is a C99 environment or not).
 839 #
 840 AC_TYPE_UINTPTR_T
 841
 842 #
 843 # Check whether we have pcap/pcap-inttypes.h.
 844 # If we do, we use that to get the C99 types defined.
 845 #
 846 savedcppflags="$CPPFLAGS"
 847 CPPFLAGS="$CPPFLAGS $V_INCLS"
 848 AC_CHECK_HEADERS(pcap/pcap-inttypes.h)
 849 CPPFLAGS="$savedcppflags"
 850
 851 #
 852 # Define the old BSD specified-width types in terms of the C99 types;
 853 # we may need them with libpcap include files.
 854 #
 855 AC_CHECK_TYPE([u_int8_t], ,
 856         [AC_DEFINE([u_int8_t], [uint8_t],
 857         [Define to `uint8_t' if u_int8_t not defined.])],
 858         [AC_INCLUDES_DEFAULT
 859 #include <sys/types.h>
 860 ])
 861 AC_CHECK_TYPE([u_int16_t], ,
 862         [AC_DEFINE([u_int16_t], [uint16_t],
 863         [Define to `uint16_t' if u_int16_t not defined.])],
 864         [AC_INCLUDES_DEFAULT
 865 #include <sys/types.h>
 866 ])
 867 AC_CHECK_TYPE([u_int32_t], ,
 868         [AC_DEFINE([u_int32_t], [uint32_t],
 869         [Define to `uint32_t' if u_int32_t not defined.])],
 870         [AC_INCLUDES_DEFAULT
 871 #include <sys/types.h>
 872 ])
 873 AC_CHECK_TYPE([u_int64_t], ,
 874         [AC_DEFINE([u_int64_t], [uint64_t],
 875         [Define to `uint64_t' if u_int64_t not defined.])],
 876         [AC_INCLUDES_DEFAULT
 877 #include <sys/types.h>
 878 ])
 879
 880 AC_PROG_RANLIB
 881 AC_CHECK_TOOL([AR], [ar])
 882
 883 AC_LBL_DEVEL(V_CCOPT)
 884
 885 # Check for OpenSSL/libressl libcrypto
 886 AC_MSG_CHECKING(whether to use OpenSSL/libressl libcrypto)
 887 # Specify location for both includes and libraries.
 888 want_libcrypto=ifavailable
 889 AC_ARG_WITH(crypto,
 890     AS_HELP_STRING([--with-crypto]@<:@=DIR@:>@,
 891                    [use OpenSSL/libressl libcrypto (located in directory DIR, if specified) @<:@default=yes, if available@:>@]),
 892 [
 893         if test $withval = no
 894         then
 895                 # User doesn't want to link with libcrypto.
 896                 want_libcrypto=no
 897                 AC_MSG_RESULT(no)
 898         elif test $withval = yes
 899         then
 900                 # User wants to link with libcrypto but hasn't specified
 901                 # a directory.
 902                 want_libcrypto=yes
 903                 AC_MSG_RESULT(yes)
 904         else
 905                 # User wants to link with libcrypto and has specified
 906                 # a directory, so use the provided value.
 907                 want_libcrypto=yes
 908                 libcrypto_root=$withval
 909                 AC_MSG_RESULT([yes, using the version installed in $withval])
 910
 911                 #
 912                 # Put the subdirectories of the libcrypto root directory
 913                 # at the front of the header and library search path.
 914                 #
 915                 CFLAGS="-I$withval/include $CFLAGS"
 916                 LIBS="-L$withval/lib $LIBS"
 917         fi
 918 ],[
 919         #
 920         # Use libcrypto if it's present, otherwise don't; no directory
 921         # was specified.
 922         #
 923         want_libcrypto=ifavailable
 924         AC_MSG_RESULT([yes, if available])
 925 ])
 926 if test "$want_libcrypto" != "no"; then
 927         #
 928         # Don't check for libcrypto unless we have its headers;
 929         # Apple, bless their pointy little heads, apparently ship
 930         # libcrypto as a library, but not the header files, in
 931         # El Capitan, probably because they don't want you writing
 932         # nasty portable code that could run on other UN*Xes, they
 933         # want you writing code that uses their Shiny New Crypto
 934         # Library and that only runs on macOS.
 935         #
 936         AC_CHECK_HEADER(openssl/crypto.h,
 937         [
 938                 AC_CHECK_LIB(crypto, DES_cbc_encrypt)
 939                 if test "$ac_cv_lib_crypto_DES_cbc_encrypt" = "yes"; then
 940                         AC_CHECK_HEADERS(openssl/evp.h)
 941                         #
 942                         # OK, then:
 943                         #
 944                         # 1) do we have EVP_CIPHER_CTX_new?
 945                         # If so, we use it to allocate an
 946                         # EVP_CIPHER_CTX, as EVP_CIPHER_CTX may be
 947                         # opaque; otherwise, we allocate it ourselves.
 948                         #
 949                         # 2) do we have EVP_DecryptInit_ex()?
 950                         # If so, we use it, because we need to be
 951                         # able to make two "initialize the cipher"
 952                         # calls, one with the cipher and key, and
 953                         # one with the IV, and, as of OpenSSL 1.1,
 954                         # You Can't Do That with EVP_DecryptInit(),
 955                         # because a call to EVP_DecryptInit() will
 956                         # unconditionally clear the context, and
 957                         # if you don't supply a cipher, it'll
 958                         # clear the cipher, rendering the context
 959                         # unusable and causing a crash.
 960                         #
 961                         AC_CHECK_FUNCS(EVP_CIPHER_CTX_new EVP_DecryptInit_ex)
 962                 fi
 963         ])
 964 fi
 965
 966 # Check for libcap-ng
 967 AC_MSG_CHECKING(whether to use libcap-ng)
 968 # Specify location for both includes and libraries.
 969 want_libcap_ng=ifavailable
 970 AC_ARG_WITH(cap_ng,
 971     AS_HELP_STRING([--with-cap-ng],
 972                    [use libcap-ng @<:@default=yes, if available@:>@]),
 973 [
 974         if test $withval = no
 975         then
 976                 want_libcap_ng=no
 977                 AC_MSG_RESULT(no)
 978         elif test $withval = yes
 979         then
 980                 want_libcap_ng=yes
 981                 AC_MSG_RESULT(yes)
 982         fi
 983 ],[
 984         #
 985         # Use libcap-ng if it's present, otherwise don't.
 986         #
 987         want_libcap_ng=ifavailable
 988         AC_MSG_RESULT([yes, if available])
 989 ])
 990 if test "$want_libcap_ng" != "no"; then
 991         AC_CHECK_LIB(cap-ng, capng_change_id)
 992         AC_CHECK_HEADERS(cap-ng.h)
 993 fi
 994
 995 dnl
 996 dnl set additional include path if necessary
 997 if test "$missing_includes" = "yes"; then
 998         CPPFLAGS="$CPPFLAGS -I$srcdir/missing"
 999         V_INCLS="$V_INCLS -I$srcdir/missing"
1000 fi
1001
1002 AC_SUBST(V_CCOPT)
1003 AC_SUBST(V_DEFS)
1004 AC_SUBST(V_GROUP)
1005 AC_SUBST(V_INCLS)
1006 AC_SUBST(V_PCAPDEP)
1007 AC_SUBST(LOCALSRC)
1008 AC_SUBST(MAN_FILE_FORMATS)
1009 AC_SUBST(MAN_MISC_INFO)
1010
1011 AC_PROG_INSTALL
1012
1013 AC_CONFIG_HEADER(config.h)
1014
1015 AC_OUTPUT_COMMANDS([if test -f .devel; then
1016         echo timestamp > stamp-h
1017         cat $srcdir/Makefile-devel-adds >> Makefile
1018         make depend || exit 1
1019 fi])
1020 AC_OUTPUT(Makefile tcpdump.1)
1021 exit 0