The Tcpdump Group git mirrors - tcpdump/blob - aclocal.m4

   1 dnl @(#) $Header: /tcpdump/master/tcpdump/aclocal.m4,v 1.90 2002-12-17 09:55:14 guy Exp $ (LBL)
   2 dnl
   3 dnl Copyright (c) 1995, 1996, 1997, 1998
   4 dnl     The Regents of the University of California.  All rights reserved.
   5 dnl
   6 dnl Redistribution and use in source and binary forms, with or without
   7 dnl modification, are permitted provided that: (1) source code distributions
   8 dnl retain the above copyright notice and this paragraph in its entirety, (2)
   9 dnl distributions including binary code include the above copyright notice and
  10 dnl this paragraph in its entirety in the documentation or other materials
  11 dnl provided with the distribution, and (3) all advertising materials mentioning
  12 dnl features or use of this software display the following acknowledgement:
  13 dnl ``This product includes software developed by the University of California,
  14 dnl Lawrence Berkeley Laboratory and its contributors.'' Neither the name of
  15 dnl the University nor the names of its contributors may be used to endorse
  16 dnl or promote products derived from this software without specific prior
  17 dnl written permission.
  18 dnl THIS SOFTWARE IS PROVIDED ``AS IS'' AND WITHOUT ANY EXPRESS OR IMPLIED
  19 dnl WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED WARRANTIES OF
  20 dnl MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE.
  21 dnl
  22 dnl LBL autoconf macros
  23 dnl
  24
  25 dnl
  26 dnl Determine which compiler we're using (cc or gcc)
  27 dnl If using gcc, determine the version number
  28 dnl If using cc, require that it support ansi prototypes
  29 dnl If using gcc, use -O2 (otherwise use -O)
  30 dnl If using cc, explicitly specify /usr/local/include
  31 dnl
  32 dnl usage:
  33 dnl
  34 dnl     AC_LBL_C_INIT(copt, incls)
  35 dnl
  36 dnl results:
  37 dnl
  38 dnl     $1 (copt set)
  39 dnl     $2 (incls set)
  40 dnl     CC
  41 dnl     LDFLAGS
  42 dnl     ac_cv_lbl_gcc_vers
  43 dnl     LBL_CFLAGS
  44 dnl
  45 AC_DEFUN(AC_LBL_C_INIT,
  46     [AC_PREREQ(2.12)
  47     AC_BEFORE([$0], [AC_PROG_CC])
  48     AC_BEFORE([$0], [AC_LBL_FIXINCLUDES])
  49     AC_BEFORE([$0], [AC_LBL_DEVEL])
  50     AC_ARG_WITH(gcc, [  --without-gcc           don't use gcc])
  51     $1="-O"
  52     $2=""
  53     if test "${srcdir}" != "." ; then
  54             $2="-I\$(srcdir)"
  55     fi
  56     if test "${CFLAGS+set}" = set; then
  57             LBL_CFLAGS="$CFLAGS"
  58     fi
  59     if test -z "$CC" ; then
  60             case "$host_os" in
  61
  62             bsdi*)
  63                     AC_CHECK_PROG(SHLICC2, shlicc2, yes, no)
  64                     if test $SHLICC2 = yes ; then
  65                             CC=shlicc2
  66                             export CC
  67                     fi
  68                     ;;
  69             esac
  70     fi
  71     if test -z "$CC" -a "$with_gcc" = no ; then
  72             CC=cc
  73             export CC
  74     fi
  75     AC_PROG_CC
  76     if test "$GCC" = yes ; then
  77             if test "$SHLICC2" = yes ; then
  78                     ac_cv_lbl_gcc_vers=2
  79                     $1="-O2"
  80             else
  81                     AC_MSG_CHECKING(gcc version)
  82                     AC_CACHE_VAL(ac_cv_lbl_gcc_vers,
  83                         ac_cv_lbl_gcc_vers=`$CC -v 2>&1 | \
  84                             sed -e '/^gcc version /!d' \
  85                                 -e 's/^gcc version //' \
  86                                 -e 's/ .*//' -e 's/^[[[^0-9]]]*//' \
  87                                 -e 's/\..*//'`)
  88                     AC_MSG_RESULT($ac_cv_lbl_gcc_vers)
  89                     if test $ac_cv_lbl_gcc_vers -gt 1 ; then
  90                             $1="-O2"
  91                     fi
  92             fi
  93     else
  94             AC_MSG_CHECKING(that $CC handles ansi prototypes)
  95             AC_CACHE_VAL(ac_cv_lbl_cc_ansi_prototypes,
  96                 AC_TRY_COMPILE(
  97                     [#include <sys/types.h>],
  98                     [int frob(int, char *)],
  99                     ac_cv_lbl_cc_ansi_prototypes=yes,
 100                     ac_cv_lbl_cc_ansi_prototypes=no))
 101             AC_MSG_RESULT($ac_cv_lbl_cc_ansi_prototypes)
 102             if test $ac_cv_lbl_cc_ansi_prototypes = no ; then
 103                     case "$host_os" in
 104
 105                     hpux*)
 106                             AC_MSG_CHECKING(for HP-UX ansi compiler ($CC -Aa -D_HPUX_SOURCE))
 107                             savedcflags="$CFLAGS"
 108                             CFLAGS="-Aa -D_HPUX_SOURCE $CFLAGS"
 109                             AC_CACHE_VAL(ac_cv_lbl_cc_hpux_cc_aa,
 110                                 AC_TRY_COMPILE(
 111                                     [#include <sys/types.h>],
 112                                     [int frob(int, char *)],
 113                                     ac_cv_lbl_cc_hpux_cc_aa=yes,
 114                                     ac_cv_lbl_cc_hpux_cc_aa=no))
 115                             AC_MSG_RESULT($ac_cv_lbl_cc_hpux_cc_aa)
 116                             if test $ac_cv_lbl_cc_hpux_cc_aa = no ; then
 117                                     AC_MSG_ERROR(see the INSTALL doc for more info)
 118                             fi
 119                             CFLAGS="$savedcflags"
 120                             V_CCOPT="-Aa $V_CCOPT"
 121                             AC_DEFINE(_HPUX_SOURCE)
 122                             ;;
 123
 124                     *)
 125                             AC_MSG_ERROR(see the INSTALL doc for more info)
 126                             ;;
 127                     esac
 128             fi
 129             $2="$$2 -I/usr/local/include"
 130             LDFLAGS="$LDFLAGS -L/usr/local/lib"
 131
 132             case "$host_os" in
 133
 134             irix*)
 135                     V_CCOPT="$V_CCOPT -xansi -signed -O"
 136                     ;;
 137
 138             osf*)
 139                     V_CCOPT="$V_CCOPT -std1 -O"
 140                     ;;
 141
 142             ultrix*)
 143                     AC_MSG_CHECKING(that Ultrix $CC hacks const in prototypes)
 144                     AC_CACHE_VAL(ac_cv_lbl_cc_const_proto,
 145                         AC_TRY_COMPILE(
 146                             [#include <sys/types.h>],
 147                             [struct a { int b; };
 148                             void c(const struct a *)],
 149                             ac_cv_lbl_cc_const_proto=yes,
 150                             ac_cv_lbl_cc_const_proto=no))
 151                     AC_MSG_RESULT($ac_cv_lbl_cc_const_proto)
 152                     if test $ac_cv_lbl_cc_const_proto = no ; then
 153                             AC_DEFINE(const,)
 154                     fi
 155                     ;;
 156             esac
 157     fi
 158 ])
 159
 160 #
 161 # Try compiling a sample of the type of code that appears in
 162 # gencode.c with "inline", "__inline__", and "__inline".
 163 #
 164 # Autoconf's AC_C_INLINE, at least in autoconf 2.13, isn't good enough,
 165 # as it just tests whether a function returning "int" can be inlined;
 166 # at least some versions of HP's C compiler can inline that, but can't
 167 # inline a function that returns a struct pointer.
 168 #
 169 AC_DEFUN(AC_LBL_C_INLINE,
 170     [AC_MSG_CHECKING(for inline)
 171     AC_CACHE_VAL(ac_cv_lbl_inline, [
 172         ac_cv_lbl_inline=""
 173         ac_lbl_cc_inline=no
 174         for ac_lbl_inline in inline __inline__ __inline
 175         do
 176             AC_TRY_COMPILE(
 177                 [#define inline $ac_lbl_inline
 178                 static inline struct iltest *foo(void);
 179                 struct iltest {
 180                     int iltest1;
 181                     int iltest2;
 182                 };
 183
 184                 static inline struct iltest *
 185                 foo()
 186                 {
 187                     static struct iltest xxx;
 188
 189                     return &xxx;
 190                 }],,ac_lbl_cc_inline=yes,)
 191             if test "$ac_lbl_cc_inline" = yes ; then
 192                 break;
 193             fi
 194         done
 195         if test "$ac_lbl_cc_inline" = yes ; then
 196             ac_cv_lbl_inline=$ac_lbl_inline
 197         fi])
 198     if test ! -z "$ac_cv_lbl_inline" ; then
 199         AC_MSG_RESULT($ac_cv_lbl_inline)
 200     else
 201         AC_MSG_RESULT(no)
 202     fi
 203     AC_DEFINE_UNQUOTED(inline, $ac_cv_lbl_inline, [Define as token for inline if inlining supported])])
 204
 205 dnl
 206 dnl Use pfopen.c if available and pfopen() not in standard libraries
 207 dnl Require libpcap
 208 dnl Look for libpcap in ..
 209 dnl Use the installed libpcap if there is no local version
 210 dnl
 211 dnl usage:
 212 dnl
 213 dnl     AC_LBL_LIBPCAP(pcapdep, incls)
 214 dnl
 215 dnl results:
 216 dnl
 217 dnl     $1 (pcapdep set)
 218 dnl     $2 (incls appended)
 219 dnl     LIBS
 220 dnl     LBL_LIBS
 221 dnl
 222 AC_DEFUN(AC_LBL_LIBPCAP,
 223     [AC_REQUIRE([AC_LBL_LIBRARY_NET])
 224     dnl
 225     dnl save a copy before locating libpcap.a
 226     dnl
 227     LBL_LIBS="$LIBS"
 228     pfopen=/usr/examples/packetfilter/pfopen.c
 229     if test -f $pfopen ; then
 230             AC_CHECK_FUNCS(pfopen)
 231             if test $ac_cv_func_pfopen = "no" ; then
 232                     AC_MSG_RESULT(Using $pfopen)
 233                     LIBS="$LIBS $pfopen"
 234             fi
 235     fi
 236     AC_MSG_CHECKING(for local pcap library)
 237     libpcap=FAIL
 238     lastdir=FAIL
 239     places=`ls .. | sed -e 's,/$,,' -e 's,^,../,' | \
 240         egrep '/libpcap-[[0-9]]*.[[0-9]]*(.[[0-9]]*)?([[ab]][[0-9]]*)?$'`
 241     for dir in $places ../libpcap libpcap ; do
 242             basedir=`echo $dir | sed -e 's/[[ab]][[0-9]]*$//'`
 243             if test $lastdir = $basedir ; then
 244                     dnl skip alphas when an actual release is present
 245                     continue;
 246             fi
 247             lastdir=$dir
 248             if test -r $dir/libpcap.a ; then
 249                     libpcap=$dir/libpcap.a
 250                     d=$dir
 251                     dnl continue and select the last one that exists
 252             fi
 253     done
 254     if test $libpcap = FAIL ; then
 255             AC_MSG_RESULT(not found)
 256             AC_CHECK_LIB(pcap, main, libpcap="-lpcap")
 257             if test $libpcap = FAIL ; then
 258                     AC_MSG_ERROR(see the INSTALL doc for more info)
 259             fi
 260             #
 261             # Good old Red Hat Linux puts "pcap.h" in
 262             # "/usr/include/pcap"; had the LBL folks done so,
 263             # that would have been a good idea, but for
 264             # the Red Hat folks to do so just breaks source
 265             # compatibility with other systems.
 266             #
 267             # We work around this by assuming that, as we didn't
 268             # find a local libpcap, libpcap is in /usr/lib or
 269             # /usr/local/lib and that the corresponding header
 270             # file is under one of those directories; if we don't
 271             # find it in either of those directories, we check to
 272             # see if it's in a "pcap" subdirectory of them and,
 273             # if so, add that subdirectory to the "-I" list.
 274             #
 275             AC_MSG_CHECKING(for extraneous pcap header directories)
 276             if ! test \( -r /usr/local/include/pcap.h -o \
 277                          -r /usr/include/pcap.h \); then
 278                 if test -r /usr/local/include/pcap/pcap.h; then
 279                     d="/usr/local/include/pcap"
 280                 elif test -r /usr/include/pcap/pcap.h; then
 281                     d="/usr/include/pcap"
 282                 fi
 283             fi
 284             if test -z $d ; then
 285                 AC_MSG_RESULT(not found)
 286             else
 287                 $2="-I$d $$2"
 288                 AC_MSG_RESULT(found -- -I$d added)
 289             fi
 290     else
 291             $1=$libpcap
 292             places=`ls $srcdir/.. | sed -e 's,/$,,' -e "s,^,$srcdir/../," | \
 293                         egrep '/libpcap-[[0-9]]*.[[0-9]]*(.[[0-9]]*)?([[ab]][[0-9]]*)?$'`
 294             if test -r $d/pcap.h; then
 295                     $2="-I$d $$2"
 296             elif test -r $places/pcap.h; then
 297                     $2="-I$places $$2"
 298             else
 299                     AC_MSG_ERROR(cannot find pcap.h, see INSTALL)
 300             fi
 301             AC_MSG_RESULT($libpcap)
 302     fi
 303     LIBS="$libpcap $LIBS"
 304     case "$host_os" in
 305
 306     aix*)
 307             pseexe="/lib/pse.exp"
 308             AC_MSG_CHECKING(for $pseexe)
 309             if test -f $pseexe ; then
 310                     AC_MSG_RESULT(yes)
 311                     LIBS="$LIBS -I:$pseexe"
 312             fi
 313             ;;
 314     esac])
 315
 316 dnl
 317 dnl Define RETSIGTYPE and RETSIGVAL
 318 dnl
 319 dnl usage:
 320 dnl
 321 dnl     AC_LBL_TYPE_SIGNAL
 322 dnl
 323 dnl results:
 324 dnl
 325 dnl     RETSIGTYPE (defined)
 326 dnl     RETSIGVAL (defined)
 327 dnl
 328 AC_DEFUN(AC_LBL_TYPE_SIGNAL,
 329     [AC_BEFORE([$0], [AC_LBL_LIBPCAP])
 330     AC_TYPE_SIGNAL
 331     if test "$ac_cv_type_signal" = void ; then
 332             AC_DEFINE(RETSIGVAL,)
 333     else
 334             AC_DEFINE(RETSIGVAL,(0))
 335     fi
 336     case "$host_os" in
 337
 338     irix*)
 339             AC_DEFINE(_BSD_SIGNALS)
 340             ;;
 341
 342     *)
 343             dnl prefer sigaction() to sigset()
 344             AC_CHECK_FUNCS(sigaction)
 345             if test $ac_cv_func_sigaction = no ; then
 346                     AC_CHECK_FUNCS(sigset)
 347             fi
 348             ;;
 349     esac])
 350
 351 dnl
 352 dnl If using gcc, make sure we have ANSI ioctl definitions
 353 dnl
 354 dnl usage:
 355 dnl
 356 dnl     AC_LBL_FIXINCLUDES
 357 dnl
 358 AC_DEFUN(AC_LBL_FIXINCLUDES,
 359     [if test "$GCC" = yes ; then
 360             AC_MSG_CHECKING(for ANSI ioctl definitions)
 361             AC_CACHE_VAL(ac_cv_lbl_gcc_fixincludes,
 362                 AC_TRY_COMPILE(
 363                     [/*
 364                      * This generates a "duplicate case value" when fixincludes
 365                      * has not be run.
 366                      */
 367 #               include <sys/types.h>
 368 #               include <sys/time.h>
 369 #               include <sys/ioctl.h>
 370 #               ifdef HAVE_SYS_IOCCOM_H
 371 #               include <sys/ioccom.h>
 372 #               endif],
 373                     [switch (0) {
 374                     case _IO('A', 1):;
 375                     case _IO('B', 1):;
 376                     }],
 377                     ac_cv_lbl_gcc_fixincludes=yes,
 378                     ac_cv_lbl_gcc_fixincludes=no))
 379             AC_MSG_RESULT($ac_cv_lbl_gcc_fixincludes)
 380             if test $ac_cv_lbl_gcc_fixincludes = no ; then
 381                     # Don't cache failure
 382                     unset ac_cv_lbl_gcc_fixincludes
 383                     AC_MSG_ERROR(see the INSTALL for more info)
 384             fi
 385     fi])
 386
 387 dnl
 388 dnl Check for flex, default to lex
 389 dnl Require flex 2.4 or higher
 390 dnl Check for bison, default to yacc
 391 dnl Default to lex/yacc if both flex and bison are not available
 392 dnl Define the yy prefix string if using flex and bison
 393 dnl
 394 dnl usage:
 395 dnl
 396 dnl     AC_LBL_LEX_AND_YACC(lex, yacc, yyprefix)
 397 dnl
 398 dnl results:
 399 dnl
 400 dnl     $1 (lex set)
 401 dnl     $2 (yacc appended)
 402 dnl     $3 (optional flex and bison -P prefix)
 403 dnl
 404 AC_DEFUN(AC_LBL_LEX_AND_YACC,
 405     [AC_ARG_WITH(flex, [  --without-flex          don't use flex])
 406     AC_ARG_WITH(bison, [  --without-bison         don't use bison])
 407     if test "$with_flex" = no ; then
 408             $1=lex
 409     else
 410             AC_CHECK_PROGS($1, flex, lex)
 411     fi
 412     if test "$$1" = flex ; then
 413             # The -V flag was added in 2.4
 414             AC_MSG_CHECKING(for flex 2.4 or higher)
 415             AC_CACHE_VAL(ac_cv_lbl_flex_v24,
 416                 if flex -V >/dev/null 2>&1; then
 417                         ac_cv_lbl_flex_v24=yes
 418                 else
 419                         ac_cv_lbl_flex_v24=no
 420                 fi)
 421             AC_MSG_RESULT($ac_cv_lbl_flex_v24)
 422             if test $ac_cv_lbl_flex_v24 = no ; then
 423                     s="2.4 or higher required"
 424                     AC_MSG_WARN(ignoring obsolete flex executable ($s))
 425                     $1=lex
 426             fi
 427     fi
 428     if test "$with_bison" = no ; then
 429             $2=yacc
 430     else
 431             AC_CHECK_PROGS($2, bison, yacc)
 432     fi
 433     if test "$$2" = bison ; then
 434             $2="$$2 -y"
 435     fi
 436     if test "$$1" != lex -a "$$2" = yacc -o "$$1" = lex -a "$$2" != yacc ; then
 437             AC_MSG_WARN(don't have both flex and bison; reverting to lex/yacc)
 438             $1=lex
 439             $2=yacc
 440     fi
 441     if test "$$1" = flex -a -n "$3" ; then
 442             $1="$$1 -P$3"
 443             $2="$$2 -p $3"
 444     fi])
 445
 446 dnl
 447 dnl Checks to see if union wait is used with WEXITSTATUS()
 448 dnl
 449 dnl usage:
 450 dnl
 451 dnl     AC_LBL_UNION_WAIT
 452 dnl
 453 dnl results:
 454 dnl
 455 dnl     DECLWAITSTATUS (defined)
 456 dnl
 457 AC_DEFUN(AC_LBL_UNION_WAIT,
 458     [AC_MSG_CHECKING(if union wait is used)
 459     AC_CACHE_VAL(ac_cv_lbl_union_wait,
 460         AC_TRY_COMPILE([
 461 #       include <sys/types.h>
 462 #       include <sys/wait.h>],
 463             [int status;
 464             u_int i = WEXITSTATUS(status);
 465             u_int j = waitpid(0, &status, 0);],
 466             ac_cv_lbl_union_wait=no,
 467             ac_cv_lbl_union_wait=yes))
 468     AC_MSG_RESULT($ac_cv_lbl_union_wait)
 469     if test $ac_cv_lbl_union_wait = yes ; then
 470             AC_DEFINE(DECLWAITSTATUS,union wait)
 471     else
 472             AC_DEFINE(DECLWAITSTATUS,int)
 473     fi])
 474
 475 dnl
 476 dnl Checks to see if the sockaddr struct has the 4.4 BSD sa_len member
 477 dnl
 478 dnl usage:
 479 dnl
 480 dnl     AC_LBL_SOCKADDR_SA_LEN
 481 dnl
 482 dnl results:
 483 dnl
 484 dnl     HAVE_SOCKADDR_SA_LEN (defined)
 485 dnl
 486 AC_DEFUN(AC_LBL_SOCKADDR_SA_LEN,
 487     [AC_MSG_CHECKING(if sockaddr struct has sa_len member)
 488     AC_CACHE_VAL(ac_cv_lbl_sockaddr_has_sa_len,
 489         AC_TRY_COMPILE([
 490 #       include <sys/types.h>
 491 #       include <sys/socket.h>],
 492         [u_int i = sizeof(((struct sockaddr *)0)->sa_len)],
 493         ac_cv_lbl_sockaddr_has_sa_len=yes,
 494         ac_cv_lbl_sockaddr_has_sa_len=no))
 495     AC_MSG_RESULT($ac_cv_lbl_sockaddr_has_sa_len)
 496     if test $ac_cv_lbl_sockaddr_has_sa_len = yes ; then
 497             AC_DEFINE(HAVE_SOCKADDR_SA_LEN)
 498     fi])
 499
 500 dnl
 501 dnl Checks to see if -R is used
 502 dnl
 503 dnl usage:
 504 dnl
 505 dnl     AC_LBL_HAVE_RUN_PATH
 506 dnl
 507 dnl results:
 508 dnl
 509 dnl     ac_cv_lbl_have_run_path (yes or no)
 510 dnl
 511 AC_DEFUN(AC_LBL_HAVE_RUN_PATH,
 512     [AC_MSG_CHECKING(for ${CC-cc} -R)
 513     AC_CACHE_VAL(ac_cv_lbl_have_run_path,
 514         [echo 'main(){}' > conftest.c
 515         ${CC-cc} -o conftest conftest.c -R/a1/b2/c3 >conftest.out 2>&1
 516         if test ! -s conftest.out ; then
 517                 ac_cv_lbl_have_run_path=yes
 518         else
 519                 ac_cv_lbl_have_run_path=no
 520         fi
 521         rm -f conftest*])
 522     AC_MSG_RESULT($ac_cv_lbl_have_run_path)
 523     ])
 524
 525 dnl
 526 dnl Due to the stupid way it's implemented, AC_CHECK_TYPE is nearly useless.
 527 dnl
 528 dnl usage:
 529 dnl
 530 dnl     AC_LBL_CHECK_TYPE
 531 dnl
 532 dnl results:
 533 dnl
 534 dnl     int32_t (defined)
 535 dnl     u_int32_t (defined)
 536 dnl
 537 AC_DEFUN(AC_LBL_CHECK_TYPE,
 538     [AC_MSG_CHECKING(for $1 using $CC)
 539     AC_CACHE_VAL(ac_cv_lbl_have_$1,
 540         AC_TRY_COMPILE([
 541 #       include "confdefs.h"
 542 #       include <sys/types.h>
 543 #       if STDC_HEADERS
 544 #       include <stdlib.h>
 545 #       include <stddef.h>
 546 #       endif],
 547         [$1 i],
 548         ac_cv_lbl_have_$1=yes,
 549         ac_cv_lbl_have_$1=no))
 550     AC_MSG_RESULT($ac_cv_lbl_have_$1)
 551     if test $ac_cv_lbl_have_$1 = no ; then
 552             AC_DEFINE($1, $2)
 553     fi])
 554
 555 dnl
 556 dnl Checks to see if unaligned memory accesses fail
 557 dnl
 558 dnl usage:
 559 dnl
 560 dnl     AC_LBL_UNALIGNED_ACCESS
 561 dnl
 562 dnl results:
 563 dnl
 564 dnl     LBL_ALIGN (DEFINED)
 565 dnl
 566 AC_DEFUN(AC_LBL_UNALIGNED_ACCESS,
 567     [AC_MSG_CHECKING(if unaligned accesses fail)
 568     AC_CACHE_VAL(ac_cv_lbl_unaligned_fail,
 569         [case "$host_cpu" in
 570
 571         # XXX: should also check that they don't do weird things (like on arm)
 572         alpha*|arm*|hp*|mips*|sparc*|ia64)
 573                 ac_cv_lbl_unaligned_fail=yes
 574                 ;;
 575
 576         *)
 577                 cat >conftest.c <<EOF
 578 #               include <sys/types.h>
 579 #               include <sys/wait.h>
 580 #               include <stdio.h>
 581                 unsigned char a[[5]] = { 1, 2, 3, 4, 5 };
 582                 main() {
 583                 unsigned int i;
 584                 pid_t pid;
 585                 int status;
 586                 /* avoid "core dumped" message */
 587                 pid = fork();
 588                 if (pid <  0)
 589                         exit(2);
 590                 if (pid > 0) {
 591                         /* parent */
 592                         pid = waitpid(pid, &status, 0);
 593                         if (pid < 0)
 594                                 exit(3);
 595                         exit(!WIFEXITED(status));
 596                 }
 597                 /* child */
 598                 i = *(unsigned int *)&a[[1]];
 599                 printf("%d\n", i);
 600                 exit(0);
 601                 }
 602 EOF
 603                 ${CC-cc} -o conftest $CFLAGS $CPPFLAGS $LDFLAGS \
 604                     conftest.c $LIBS >/dev/null 2>&1
 605                 if test ! -x conftest ; then
 606                         dnl failed to compile for some reason
 607                         ac_cv_lbl_unaligned_fail=yes
 608                 else
 609                         ./conftest >conftest.out
 610                         if test ! -s conftest.out ; then
 611                                 ac_cv_lbl_unaligned_fail=yes
 612                         else
 613                                 ac_cv_lbl_unaligned_fail=no
 614                         fi
 615                 fi
 616                 rm -f conftest* core core.conftest
 617                 ;;
 618         esac])
 619     AC_MSG_RESULT($ac_cv_lbl_unaligned_fail)
 620     if test $ac_cv_lbl_unaligned_fail = yes ; then
 621             AC_DEFINE(LBL_ALIGN)
 622     fi])
 623
 624 dnl
 625 dnl If using gcc and the file .devel exists:
 626 dnl     Compile with -g (if supported) and -Wall
 627 dnl     If using gcc 2 or later, do extra prototype checking and some other
 628 dnl     checks
 629 dnl     If an os prototype include exists, symlink os-proto.h to it
 630 dnl
 631 dnl usage:
 632 dnl
 633 dnl     AC_LBL_DEVEL(copt)
 634 dnl
 635 dnl results:
 636 dnl
 637 dnl     $1 (copt appended)
 638 dnl     HAVE_OS_PROTO_H (defined)
 639 dnl     os-proto.h (symlinked)
 640 dnl
 641 AC_DEFUN(AC_LBL_DEVEL,
 642     [rm -f os-proto.h
 643     if test "${LBL_CFLAGS+set}" = set; then
 644             $1="$$1 ${LBL_CFLAGS}"
 645     fi
 646     if test -f .devel ; then
 647             if test "$GCC" = yes ; then
 648                     if test "${LBL_CFLAGS+set}" != set; then
 649                             if test "$ac_cv_prog_cc_g" = yes ; then
 650                                     $1="-g $$1"
 651                             fi
 652                             $1="$$1 -Wall"
 653                             if test $ac_cv_lbl_gcc_vers -gt 1 ; then
 654                                     $1="$$1 -Wmissing-prototypes -Wstrict-prototypes -Wwrite-strings -W"
 655                             fi
 656                     fi
 657             else
 658                     case "$host_os" in
 659
 660                     irix6*)
 661                             V_CCOPT="$V_CCOPT -n32"
 662                             ;;
 663
 664                     *)
 665                             ;;
 666                     esac
 667             fi
 668             os=`echo $host_os | sed -e 's/\([[0-9]][[0-9]]*\)[[^0-9]].*$/\1/'`
 669             name="lbl/os-$os.h"
 670             if test -f $name ; then
 671                     ln -s $name os-proto.h
 672                     AC_DEFINE(HAVE_OS_PROTO_H)
 673             else
 674                     AC_MSG_WARN(can't find $name)
 675             fi
 676     fi])
 677
 678 dnl
 679 dnl Improved version of AC_CHECK_LIB
 680 dnl
 681 dnl Thanks to John Hawkinson (jhawk@mit.edu)
 682 dnl
 683 dnl usage:
 684 dnl
 685 dnl     AC_LBL_CHECK_LIB(LIBRARY, FUNCTION [, ACTION-IF-FOUND [,
 686 dnl         ACTION-IF-NOT-FOUND [, OTHER-LIBRARIES]]])
 687 dnl
 688 dnl results:
 689 dnl
 690 dnl     LIBS
 691 dnl
 692 dnl XXX - "AC_LBL_LIBRARY_NET" was redone to use "AC_SEARCH_LIBS"
 693 dnl rather than "AC_LBL_CHECK_LIB", so this isn't used any more.
 694 dnl We keep it around for reference purposes in case it's ever
 695 dnl useful in the future.
 696 dnl
 697
 698 define(AC_LBL_CHECK_LIB,
 699 [AC_MSG_CHECKING([for $2 in -l$1])
 700 dnl Use a cache variable name containing the library, function
 701 dnl name, and extra libraries to link with, because the test really is
 702 dnl for library $1 defining function $2, when linked with potinal
 703 dnl library $5, not just for library $1.  Separate tests with the same
 704 dnl $1 and different $2's or $5's may have different results.
 705 ac_lib_var=`echo $1['_']$2['_']$5 | sed 'y%./+- %__p__%'`
 706 AC_CACHE_VAL(ac_cv_lbl_lib_$ac_lib_var,
 707 [ac_save_LIBS="$LIBS"
 708 LIBS="-l$1 $5 $LIBS"
 709 AC_TRY_LINK(dnl
 710 ifelse([$2], [main], , dnl Avoid conflicting decl of main.
 711 [/* Override any gcc2 internal prototype to avoid an error.  */
 712 ]ifelse(AC_LANG, CPLUSPLUS, [#ifdef __cplusplus
 713 extern "C"
 714 #endif
 715 ])dnl
 716 [/* We use char because int might match the return type of a gcc2
 717     builtin and then its argument prototype would still apply.  */
 718 char $2();
 719 ]),
 720             [$2()],
 721             eval "ac_cv_lbl_lib_$ac_lib_var=yes",
 722             eval "ac_cv_lbl_lib_$ac_lib_var=no")
 723 LIBS="$ac_save_LIBS"
 724 ])dnl
 725 if eval "test \"`echo '$ac_cv_lbl_lib_'$ac_lib_var`\" = yes"; then
 726   AC_MSG_RESULT(yes)
 727   ifelse([$3], ,
 728 [changequote(, )dnl
 729   ac_tr_lib=HAVE_LIB`echo $1 | sed -e 's/[^a-zA-Z0-9_]/_/g' \
 730     -e 'y/abcdefghijklmnopqrstuvwxyz/ABCDEFGHIJKLMNOPQRSTUVWXYZ/'`
 731 changequote([, ])dnl
 732   AC_DEFINE_UNQUOTED($ac_tr_lib)
 733   LIBS="-l$1 $LIBS"
 734 ], [$3])
 735 else
 736   AC_MSG_RESULT(no)
 737 ifelse([$4], , , [$4
 738 ])dnl
 739 fi
 740 ])
 741
 742 dnl
 743 dnl AC_LBL_LIBRARY_NET
 744 dnl
 745 dnl This test is for network applications that need socket() and
 746 dnl gethostbyname() -ish functions.  Under Solaris, those applications
 747 dnl need to link with "-lsocket -lnsl".  Under IRIX, they need to link
 748 dnl with "-lnsl" but should *not* link with "-lsocket" because
 749 dnl libsocket.a breaks a number of things (for instance:
 750 dnl gethostbyname() under IRIX 5.2, and snoop sockets under most
 751 dnl versions of IRIX).
 752 dnl
 753 dnl Unfortunately, many application developers are not aware of this,
 754 dnl and mistakenly write tests that cause -lsocket to be used under
 755 dnl IRIX.  It is also easy to write tests that cause -lnsl to be used
 756 dnl under operating systems where neither are necessary (or useful),
 757 dnl such as SunOS 4.1.4, which uses -lnsl for TLI.
 758 dnl
 759 dnl This test exists so that every application developer does not test
 760 dnl this in a different, and subtly broken fashion.
 761
 762 dnl It has been argued that this test should be broken up into two
 763 dnl seperate tests, one for the resolver libraries, and one for the
 764 dnl libraries necessary for using Sockets API. Unfortunately, the two
 765 dnl are carefully intertwined and allowing the autoconf user to use
 766 dnl them independantly potentially results in unfortunate ordering
 767 dnl dependancies -- as such, such component macros would have to
 768 dnl carefully use indirection and be aware if the other components were
 769 dnl executed. Since other autoconf macros do not go to this trouble,
 770 dnl and almost no applications use sockets without the resolver, this
 771 dnl complexity has not been implemented.
 772 dnl
 773 dnl The check for libresolv is in case you are attempting to link
 774 dnl statically and happen to have a libresolv.a lying around (and no
 775 dnl libnsl.a).
 776 dnl
 777 AC_DEFUN(AC_LBL_LIBRARY_NET, [
 778     # Most operating systems have gethostbyname() in the default searched
 779     # libraries (i.e. libc):
 780     # Some OSes (eg. Solaris) place it in libnsl
 781     # Some strange OSes (SINIX) have it in libsocket:
 782     AC_SEARCH_LIBS(gethostbyname, nsl socket resolv)
 783     # Unfortunately libsocket sometimes depends on libnsl and
 784     # AC_SEARCH_LIBS isn't up to the task of handling dependencies like this.
 785     if test "$ac_cv_search_gethostbyname" = "no"
 786     then
 787         AC_CHECK_LIB(socket, gethostbyname,
 788                      LIBS="-lsocket -lnsl $LIBS", , -lnsl)
 789     fi
 790     AC_SEARCH_LIBS(socket, socket, ,
 791         AC_CHECK_LIB(socket, socket, LIBS="-lsocket -lnsl $LIBS", , -lnsl))
 792     # DLPI needs putmsg under HPUX so test for -lstr while we're at it
 793     AC_SEARCH_LIBS(putmsg, str)
 794     ])
 795
 796 dnl Copyright (c) 1999 WIDE Project. All rights reserved.
 797 dnl
 798 dnl Redistribution and use in source and binary forms, with or without
 799 dnl modification, are permitted provided that the following conditions
 800 dnl are met:
 801 dnl 1. Redistributions of source code must retain the above copyright
 802 dnl    notice, this list of conditions and the following disclaimer.
 803 dnl 2. Redistributions in binary form must reproduce the above copyright
 804 dnl    notice, this list of conditions and the following disclaimer in the
 805 dnl    documentation and/or other materials provided with the distribution.
 806 dnl 3. Neither the name of the project nor the names of its contributors
 807 dnl    may be used to endorse or promote products derived from this software
 808 dnl    without specific prior written permission.
 809 dnl
 810 dnl THIS SOFTWARE IS PROVIDED BY THE PROJECT AND CONTRIBUTORS ``AS IS'' AND
 811 dnl ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
 812 dnl IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
 813 dnl ARE DISCLAIMED.  IN NO EVENT SHALL THE PROJECT OR CONTRIBUTORS BE LIABLE
 814 dnl FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
 815 dnl DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
 816 dnl OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
 817 dnl HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
 818 dnl LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
 819 dnl OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
 820 dnl SUCH DAMAGE.
 821
 822 dnl
 823 dnl Checks to see if AF_INET6 is defined
 824 AC_DEFUN(AC_CHECK_AF_INET6, [
 825         AC_MSG_CHECKING(for AF_INET6)
 826         AC_CACHE_VAL($1,
 827         AC_TRY_COMPILE([
 828 #               include <sys/types.h>
 829 #               include <sys/socket.h>],
 830                 [int a = AF_INET6],
 831                 $1=yes,
 832                 $1=no))
 833         AC_MSG_RESULT($$1)
 834                 if test $$1 = yes ; then
 835                         AC_DEFINE(HAVE_AF_INET6)
 836         fi
 837 ])
 838
 839 dnl
 840 dnl Checks to see if the sockaddr struct has the 4.4 BSD sa_len member
 841 dnl borrowed from LBL libpcap
 842 AC_DEFUN(AC_CHECK_SA_LEN, [
 843         AC_MSG_CHECKING(if sockaddr struct has sa_len member)
 844         AC_CACHE_VAL($1,
 845         AC_TRY_COMPILE([
 846 #               include <sys/types.h>
 847 #               include <sys/socket.h>],
 848                 [u_int i = sizeof(((struct sockaddr *)0)->sa_len)],
 849                 $1=yes,
 850                 $1=no))
 851         AC_MSG_RESULT($$1)
 852                 if test $$1 = yes ; then
 853                         AC_DEFINE(HAVE_SOCKADDR_SA_LEN)
 854         fi
 855 ])
 856
 857 dnl
 858 dnl Checks for portable prototype declaration macro
 859 AC_DEFUN(AC_CHECK_PORTABLE_PROTO,  [
 860         AC_MSG_CHECKING(for __P)
 861         AC_CACHE_VAL($1,
 862         AC_TRY_COMPILE([
 863 #               include <unistd.h>],
 864                 [int f __P(())],
 865                 $1=yes,
 866                 $1=no))
 867         AC_MSG_RESULT($$1)
 868         if test $$1 = yes; then
 869                 AC_DEFINE(HAVE_PORTABLE_PROTOTYPE)
 870         fi
 871 ])
 872
 873 dnl checks for u_intXX_t
 874 AC_DEFUN(AC_CHECK_BITTYPES, [
 875         $1=yes
 876 dnl check for u_int8_t
 877         AC_MSG_CHECKING(for u_int8_t)
 878         AC_CACHE_VAL(ac_cv_u_int8_t,
 879         AC_TRY_COMPILE([
 880 #               include <sys/types.h>],
 881                 [u_int8_t i],
 882                 ac_cv_u_int8_t=yes,
 883                 ac_cv_u_int8_t=no))
 884         AC_MSG_RESULT($ac_cv_u_int8_t)
 885         if test $ac_cv_u_int8_t = yes; then
 886                 AC_DEFINE(HAVE_U_INT8_T)
 887         else
 888                 $1=no
 889         fi
 890 dnl check for u_int16_t
 891         AC_MSG_CHECKING(for u_int16_t)
 892         AC_CACHE_VAL(ac_cv_u_int16_t,
 893         AC_TRY_COMPILE([
 894 #               include <sys/types.h>],
 895                 [u_int16_t i],
 896                 ac_cv_u_int16_t=yes,
 897                 ac_cv_u_int16_t=no))
 898         AC_MSG_RESULT($ac_cv_u_int16_t)
 899         if test $ac_cv_u_int16_t = yes; then
 900                 AC_DEFINE(HAVE_U_INT16_T)
 901         else
 902                 $1=no
 903         fi
 904 dnl check for u_int32_t
 905         AC_MSG_CHECKING(for u_int32_t)
 906         AC_CACHE_VAL(ac_cv_u_int32_t,
 907         AC_TRY_COMPILE([
 908 #               include <sys/types.h>],
 909                 [u_int32_t i],
 910                 ac_cv_u_int32_t=yes,
 911                 ac_cv_u_int32_t=no))
 912         AC_MSG_RESULT($ac_cv_u_int32_t)
 913         if test $ac_cv_u_int32_t = yes; then
 914                 AC_DEFINE(HAVE_U_INT32_T)
 915         else
 916                 $1=no
 917         fi
 918 ])
 919
 920 dnl
 921 dnl Checks for addrinfo structure
 922 AC_DEFUN(AC_STRUCT_ADDRINFO, [
 923         AC_MSG_CHECKING(for addrinfo)
 924         AC_CACHE_VAL($1,
 925         AC_TRY_COMPILE([
 926 #               include <netdb.h>],
 927                 [struct addrinfo a],
 928                 $1=yes,
 929                 $1=no))
 930         AC_MSG_RESULT($$1)
 931         if test $$1 = yes; then
 932                 AC_DEFINE(HAVE_ADDRINFO)
 933         else
 934                 AC_DEFINE(NEED_ADDRINFO_H)
 935         fi
 936 ])
 937
 938 dnl
 939 dnl Checks for NI_MAXSERV
 940 AC_DEFUN(AC_NI_MAXSERV, [
 941         AC_MSG_CHECKING(for NI_MAXSERV)
 942         AC_CACHE_VAL($1,
 943         AC_EGREP_CPP(yes, [#include <netdb.h>
 944 #ifdef NI_MAXSERV
 945 yes
 946 #endif],
 947                 $1=yes,
 948                 $1=no))
 949         AC_MSG_RESULT($$1)
 950         if test $$1 != yes; then
 951                 AC_DEFINE(NEED_ADDRINFO_H)
 952         fi
 953 ])
 954
 955 dnl
 956 dnl Checks for NI_NAMEREQD
 957 AC_DEFUN(AC_NI_NAMEREQD, [
 958         AC_MSG_CHECKING(for NI_NAMEREQD)
 959         AC_CACHE_VAL($1,
 960         AC_EGREP_CPP(yes, [#include <netdb.h>
 961 #ifdef NI_NOFQDN
 962 yes
 963 #endif],
 964                 $1=yes,
 965                 $1=no))
 966         AC_MSG_RESULT($$1)
 967         if test $$1 != yes; then
 968                 AC_DEFINE(NEED_ADDRINFO_H)
 969         fi
 970 ])
 971
 972 dnl
 973 dnl Checks for sockaddr_storage structure
 974 AC_DEFUN(AC_STRUCT_SA_STORAGE, [
 975         AC_MSG_CHECKING(for sockaddr_storage)
 976         AC_CACHE_VAL($1,
 977         AC_TRY_COMPILE([
 978 #               include <sys/types.h>
 979 #               include <sys/socket.h>],
 980                 [struct sockaddr_storage s],
 981                 $1=yes,
 982                 $1=no))
 983         AC_MSG_RESULT($$1)
 984         if test $$1 = yes; then
 985                 AC_DEFINE(HAVE_SOCKADDR_STORAGE)
 986         fi
 987 ])
 988
 989 dnl
 990 dnl Checks for macro of IP address size
 991 AC_DEFUN(AC_CHECK_ADDRSZ, [
 992         $1=yes
 993 dnl check for INADDRSZ
 994         AC_MSG_CHECKING(for INADDRSZ)
 995         AC_CACHE_VAL(ac_cv_inaddrsz,
 996         AC_TRY_COMPILE([
 997 #               include <arpa/nameser.h>],
 998                 [int a = INADDRSZ],
 999                 ac_cv_inaddrsz=yes,
1000                 ac_cv_inaddrsz=no))
1001         AC_MSG_RESULT($ac_cv_inaddrsz)
1002         if test $ac_cv_inaddrsz = yes; then
1003                 AC_DEFINE(HAVE_INADDRSZ)
1004         else
1005                 $1=no
1006         fi
1007 dnl check for IN6ADDRSZ
1008         AC_MSG_CHECKING(for IN6ADDRSZ)
1009         AC_CACHE_VAL(ac_cv_in6addrsz,
1010         AC_TRY_COMPILE([
1011 #               include <arpa/nameser.h>],
1012                 [int a = IN6ADDRSZ],
1013                 ac_cv_in6addrsz=yes,
1014                 ac_cv_in6addrsz=no))
1015         AC_MSG_RESULT($ac_cv_in6addrsz)
1016         if test $ac_cv_in6addrsz = yes; then
1017                 AC_DEFINE(HAVE_IN6ADDRSZ)
1018         else
1019                 $1=no
1020         fi
1021 ])
1022
1023 dnl
1024 dnl check for RES_USE_INET6
1025 AC_DEFUN(AC_CHECK_RES_USE_INET6, [
1026         AC_MSG_CHECKING(for RES_USE_INET6)
1027         AC_CACHE_VAL($1,
1028         AC_TRY_COMPILE([
1029 #               include <sys/types.h>
1030 #               include <netinet/in.h>
1031 #               include <resolv.h>],
1032                 [int a = RES_USE_INET6],
1033                 $1=yes,
1034                 $1=no))
1035         AC_MSG_RESULT($$1)
1036         if test $$1 = yes; then
1037                 AC_DEFINE(HAVE_RES_USE_INET6)
1038         fi
1039 ])
1040
1041 dnl
1042 dnl check for AAAA
1043 AC_DEFUN(AC_CHECK_AAAA, [
1044         AC_MSG_CHECKING(for AAAA)
1045         AC_CACHE_VAL($1,
1046         AC_TRY_COMPILE([
1047 #               include <sys/types.h>
1048 #               include <arpa/nameser.h>],
1049                 [int a = T_AAAA],
1050                 $1=yes,
1051                 $1=no))
1052         AC_MSG_RESULT($$1)
1053         if test $$1 = yes; then
1054                 AC_DEFINE(HAVE_AAAA)
1055         fi
1056 ])
1057
1058 dnl
1059 dnl check for struct res_state_ext
1060 AC_DEFUN(AC_STRUCT_RES_STATE_EXT, [
1061         AC_MSG_CHECKING(for res_state_ext)
1062         AC_CACHE_VAL($1,
1063         AC_TRY_COMPILE([
1064 #               include <sys/types.h>
1065 #               include <netinet/in.h>
1066 #               include <netinet6/in6.h>
1067 #               include <resolv.h>],
1068                 [struct __res_state_ext e],
1069                 $1=yes,
1070                 $1=no))
1071         AC_MSG_RESULT($$1)
1072         if test $$1 = yes; then
1073                 AC_DEFINE(HAVE_RES_STATE_EXT)
1074         fi
1075 ])
1076
1077 dnl
1078 dnl check for struct res_state_ext
1079 AC_DEFUN(AC_STRUCT_RES_STATE, [
1080         AC_MSG_CHECKING(for nsort in res_state)
1081         AC_CACHE_VAL($1,
1082         AC_TRY_COMPILE([
1083 #               include <sys/types.h>
1084 #               include <netinet/in.h>
1085 #               include <netinet6/in6.h>
1086 #               include <resolv.h>],
1087                 [struct __res_state e; e.nsort = 0],
1088                 $1=yes,
1089                 $1=no))
1090         AC_MSG_RESULT($$1)
1091         if test $$1 = yes; then
1092                 AC_DEFINE(HAVE_NEW_RES_STATE)
1093         fi
1094 ])
1095
1096 dnl
1097 dnl check for h_errno
1098 AC_DEFUN(AC_VAR_H_ERRNO, [
1099         AC_MSG_CHECKING(for h_errno)
1100         AC_CACHE_VAL(ac_cv_var_h_errno,
1101         AC_TRY_COMPILE([
1102 #               include <sys/types.h>
1103 #               include <netdb.h>],
1104                 [int foo = h_errno;],
1105                 ac_cv_var_h_errno=yes,
1106                 ac_cv_var_h_errno=no))
1107         AC_MSG_RESULT($ac_cv_var_h_errno)
1108         if test "$ac_cv_var_h_errno" = "yes"; then
1109                 AC_DEFINE(HAVE_H_ERRNO)
1110         fi
1111 ])
1112
1113 dnl
1114 dnl Test for __attribute__
1115 dnl
1116
1117 AC_DEFUN(AC_C___ATTRIBUTE__, [
1118 AC_MSG_CHECKING(for __attribute__)
1119 AC_CACHE_VAL(ac_cv___attribute__, [
1120 AC_TRY_COMPILE([
1121 #include <stdlib.h>
1122 ],
1123 [
1124 static void foo(void) __attribute__ ((noreturn));
1125
1126 static void
1127 foo(void)
1128 {
1129   exit(1);
1130 }
1131 ],
1132 ac_cv___attribute__=yes,
1133 ac_cv___attribute__=no)])
1134 if test "$ac_cv___attribute__" = "yes"; then
1135   AC_DEFINE(HAVE___ATTRIBUTE__, 1, [define if your compiler has __attribute__])
1136 fi
1137 AC_MSG_RESULT($ac_cv___attribute__)
1138 ])