The Tcpdump Group git mirrors - tcpdump/blob - configure.in

   1 dnl @(#) $Header: /tcpdump/master/tcpdump/configure.in,v 1.145 2002-01-17 05:00:16 guy Exp $ (LBL)
   2 dnl
   3 dnl Copyright (c) 1994, 1995, 1996, 1997
   4 dnl     The Regents of the University of California.  All rights reserved.
   5 dnl
   6 dnl Process this file with autoconf to produce a configure script.
   7 dnl
   8
   9 AC_REVISION($Revision: 1.145 $)
  10 AC_PREREQ(2.13)
  11 AC_INIT(tcpdump.c)
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_LBL_C_INIT(V_CCOPT, V_INCLS)
  16 AC_C_INLINE
  17 AC_C___ATTRIBUTE__
  18
  19 AC_CHECK_HEADERS(fcntl.h rpc/rpcent.h netinet/if_ether.h)
  20 AC_HEADER_TIME
  21
  22 case "$host_os" in
  23
  24 linux*)
  25         AC_MSG_CHECKING(Linux kernel version)
  26         if test "$cross_compiling" = yes; then
  27                 AC_CACHE_VAL(ac_cv_linux_vers,
  28                     ac_cv_linux_vers=unknown)
  29         else
  30                 AC_CACHE_VAL(ac_cv_linux_vers,
  31                     ac_cv_linux_vers=`uname -r 2>&1 | \
  32                         sed -n -e '$s/.* //' -e '$s/\..*//p'`)
  33         fi
  34         AC_MSG_RESULT($ac_cv_linux_vers)
  35         if test $ac_cv_linux_vers = unknown ; then
  36                 AC_MSG_ERROR(cannot determine linux version when cross-compiling)
  37         fi
  38         if test $ac_cv_linux_vers -lt 2 ; then
  39                 AC_MSG_ERROR(version 2 or higher required; see the INSTALL doc for more info)
  40         fi
  41         ;;
  42
  43 *)
  44         ;;
  45 esac
  46
  47
  48 AC_CHECK_HEADERS(smi.h)
  49 AC_CHECK_LIB(smi, smiInit)
  50 if test "$ac_cv_header_smi_h" = yes -a "$ac_cv_lib_smi_smiInit" = yes
  51 then
  52 AC_MSG_CHECKING([whether to enable libsmi])
  53         AC_TRY_RUN([ /* libsmi available check */
  54 #include <smi.h>
  55 main()
  56 {
  57   int current, revision, age, n;
  58   const int required = 2;
  59   if (smiInit(""))
  60     exit(1);
  61   if (strcmp(SMI_LIBRARY_VERSION, smi_library_version))
  62     exit(2);
  63   n = sscanf(smi_library_version, "%d:%d:%d", &current, &revision, &age);
  64   if (n != 3)
  65     exit(3);
  66   if (required < current - age || required > current)
  67     exit(4);
  68   exit(0);
  69 }
  70 ],
  71 [ AC_MSG_RESULT(yes)
  72   AC_DEFINE(LIBSMI)
  73   libsmi=yes],
  74 dnl autoconf documentation says that $? contains the exit value.
  75 dnl reality is that it does not.  We leave this in just in case
  76 dnl autoconf ever comes back to match the documentation.
  77 [ case $? in
  78   1) AC_MSG_RESULT(no - smiInit failed) ;;
  79   2) AC_MSG_RESULT(no - header/library version mismatch) ;;
  80   3) AC_MSG_RESULT(no - can't determine library version) ;;
  81   4) AC_MSG_RESULT(no - too old) ;;
  82   *) AC_MSG_RESULT(no) ;;
  83   esac
  84   libsmi=no],
  85 [ AC_MSG_RESULT(not when cross-compiling)
  86   libsmi=no]
  87 )
  88 fi
  89
  90 AC_MSG_CHECKING([whether to enable the possibly-buggy SMB printer])
  91 AC_ARG_ENABLE(smb,
  92 [  --enable-smb            enable possibly-buggy SMB printer [default=yes]
  93   --disable-smb           disable possibly-buggy SMB printer],,
  94    enableval=yes)
  95 case "$enableval" in
  96 yes)    AC_MSG_RESULT(yes)
  97         AC_WARN([The SMB printer may have exploitable buffer overflows!!!])
  98         AC_DEFINE(TCPDUMP_DO_SMB)
  99         LOCALSRC="print-smb.c smbutil.c $LOCALSRC"
 100         ;;
 101 *)      AC_MSG_RESULT(no)
 102         ;;
 103 esac
 104
 105 CFLAGS="$CFLAGS -Dss_family=__ss_family -Dss_len=__ss_len"
 106 AC_MSG_CHECKING([whether to enable ipv6])
 107 AC_ARG_ENABLE(ipv6,
 108 [  --enable-ipv6           enable ipv6 (with ipv4) support
 109   --disable-ipv6          disable ipv6 support],
 110 [ case "$enableval" in
 111 yes)   AC_MSG_RESULT(yes)
 112        LOCALSRC="print-ip6.c print-ip6opts.c print-ripng.c print-icmp6.c print-frag6.c print-rt6.c print-ospf6.c print-dhcp6.c $LOCALSRC"
 113        AC_DEFINE(INET6)
 114        ipv6=yes
 115        ;;
 116 *)
 117        AC_MSG_RESULT(no)
 118        ipv6=no
 119        ;;
 120   esac ],
 121
 122   AC_TRY_RUN([ /* AF_INET6 available check */
 123 #include <sys/types.h>
 124 #include <sys/socket.h>
 125 main()
 126 {
 127  if (socket(AF_INET6, SOCK_STREAM, 0) < 0)
 128    exit(1);
 129  else
 130    exit(0);
 131 }
 132 ],
 133 [ AC_MSG_RESULT(yes)
 134   LOCALSRC="print-ip6.c print-ip6opts.c print-ripng.c print-icmp6.c print-frag6.c print-rt6.c print-ospf6.c print-dhcp6.c $LOCALSRC"
 135   AC_DEFINE(INET6)
 136   ipv6=yes],
 137 [ AC_MSG_RESULT(no)
 138   ipv6=no],
 139 [ AC_MSG_RESULT(no)
 140   ipv6=no]
 141 ))
 142
 143 ipv6type=unknown
 144 ipv6lib=none
 145 ipv6trylibc=no
 146
 147 if test "$ipv6" = "yes"; then
 148         AC_MSG_CHECKING([ipv6 stack type])
 149         for i in inria kame linux-glibc linux-libinet6 toshiba v6d zeta; do
 150                 case $i in
 151                 inria)
 152                         dnl http://www.kame.net/
 153                         AC_EGREP_CPP(yes, [dnl
 154 #include <netinet/in.h>
 155 #ifdef IPV6_INRIA_VERSION
 156 yes
 157 #endif],
 158                                 [ipv6type=$i;
 159                                 CFLAGS="-DINET6 $CFLAGS"])
 160                         ;;
 161                 kame)
 162                         dnl http://www.kame.net/
 163                         AC_EGREP_CPP(yes, [dnl
 164 #include <netinet/in.h>
 165 #ifdef __KAME__
 166 yes
 167 #endif],
 168                                 [ipv6type=$i;
 169                                 ipv6lib=inet6;
 170                                 ipv6libdir=/usr/local/v6/lib;
 171                                 ipv6trylibc=yes;
 172                                 CFLAGS="-DINET6 $CFLAGS"])
 173                         ;;
 174                 linux-glibc)
 175                         dnl http://www.v6.linux.or.jp/
 176                         AC_EGREP_CPP(yes, [dnl
 177 #include <features.h>
 178 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 179 yes
 180 #endif],
 181                                 [ipv6type=$i;
 182                                 CFLAGS="-DINET6 $CFLAGS"])
 183                         ;;
 184                 linux-libinet6)
 185                         dnl http://www.v6.linux.or.jp/
 186                         if test -d /usr/inet6 -o -f /usr/include/netinet/ip6.h; then
 187                                 ipv6type=$i
 188                                 ipv6lib=inet6
 189                                 ipv6libdir=/usr/inet6/lib
 190                                 ipv6trylibc=yes;
 191                                 CFLAGS="-DINET6 -I/usr/inet6/include $CFLAGS"
 192                         fi
 193                         ;;
 194                 toshiba)
 195                         AC_EGREP_CPP(yes, [dnl
 196 #include <sys/param.h>
 197 #ifdef _TOSHIBA_INET6
 198 yes
 199 #endif],
 200                                 [ipv6type=$i;
 201                                 ipv6lib=inet6;
 202                                 ipv6libdir=/usr/local/v6/lib;
 203                                 CFLAGS="-DINET6 $CFLAGS"])
 204                         ;;
 205                 v6d)
 206                         AC_EGREP_CPP(yes, [dnl
 207 #include </usr/local/v6/include/sys/v6config.h>
 208 #ifdef __V6D__
 209 yes
 210 #endif],
 211                                 [ipv6type=$i;
 212                                 ipv6lib=v6;
 213                                 ipv6libdir=/usr/local/v6/lib;
 214                                 CFLAGS="-I/usr/local/v6/include $CFLAGS"])
 215                         ;;
 216                 zeta)
 217                         AC_EGREP_CPP(yes, [dnl
 218 #include <sys/param.h>
 219 #ifdef _ZETA_MINAMI_INET6
 220 yes
 221 #endif],
 222                                 [ipv6type=$i;
 223                                 ipv6lib=inet6;
 224                                 ipv6libdir=/usr/local/v6/lib;
 225                                 CFLAGS="-DINET6 $CFLAGS"])
 226                         ;;
 227                 esac
 228                 if test "$ipv6type" != "unknown"; then
 229                         break
 230                 fi
 231         done
 232         AC_MSG_RESULT($ipv6type)
 233 fi
 234
 235 if test "$ipv6" = "yes" -a "$ipv6lib" != "none"; then
 236         if test -d $ipv6libdir -a -f $ipv6libdir/lib$ipv6lib.a; then
 237                 LIBS="-L$ipv6libdir -l$ipv6lib $LIBS"
 238                 echo "You have $ipv6lib library, using it"
 239         else
 240                 if test "$ipv6trylibc" = "yes"; then
 241                         echo "You do not have $ipv6lib library, using libc"
 242                 else
 243                         echo 'Fatal: no $ipv6lib library found.  cannot continue.'
 244                         echo "You need to fetch lib$ipv6lib.a from appropriate"
 245                         echo 'ipv6 kit and compile beforehand.'
 246                         exit 1
 247                 fi
 248         fi
 249 fi
 250
 251
 252 if test "$ipv6" = "yes"; then
 253         AC_SEARCH_LIBS(getaddrinfo, socket, [dnl
 254         AC_MSG_CHECKING(getaddrinfo bug)
 255         AC_TRY_RUN([
 256 #include <sys/types.h>
 257 #include <netdb.h>
 258 #include <string.h>
 259 #include <sys/socket.h>
 260 #include <netinet/in.h>
 261
 262 main()
 263 {
 264   int passive, gaierr, inet4 = 0, inet6 = 0;
 265   struct addrinfo hints, *ai, *aitop;
 266   char straddr[INET6_ADDRSTRLEN], strport[16];
 267
 268   for (passive = 0; passive <= 1; passive++) {
 269     memset(&hints, 0, sizeof(hints));
 270     hints.ai_family = AF_UNSPEC;
 271     hints.ai_flags = passive ? AI_PASSIVE : 0;
 272     hints.ai_socktype = SOCK_STREAM;
 273     if ((gaierr = getaddrinfo(NULL, "54321", &hints, &aitop)) != 0) {
 274       (void)gai_strerror(gaierr);
 275       goto bad;
 276     }
 277     for (ai = aitop; ai; ai = ai->ai_next) {
 278       if (ai->ai_addr == NULL ||
 279           ai->ai_addrlen == 0 ||
 280           getnameinfo(ai->ai_addr, ai->ai_addrlen,
 281                       straddr, sizeof(straddr), strport, sizeof(strport),
 282                       NI_NUMERICHOST|NI_NUMERICSERV) != 0) {
 283         goto bad;
 284       }
 285       switch (ai->ai_family) {
 286       case AF_INET:
 287         if (strcmp(strport, "54321") != 0) {
 288           goto bad;
 289         }
 290         if (passive) {
 291           if (strcmp(straddr, "0.0.0.0") != 0) {
 292             goto bad;
 293           }
 294         } else {
 295           if (strcmp(straddr, "127.0.0.1") != 0) {
 296             goto bad;
 297           }
 298         }
 299         inet4++;
 300         break;
 301       case AF_INET6:
 302         if (strcmp(strport, "54321") != 0) {
 303           goto bad;
 304         }
 305         if (passive) {
 306           if (strcmp(straddr, "::") != 0) {
 307             goto bad;
 308           }
 309         } else {
 310           if (strcmp(straddr, "::1") != 0) {
 311             goto bad;
 312           }
 313         }
 314         inet6++;
 315         break;
 316       case AF_UNSPEC:
 317         goto bad;
 318         break;
 319 #ifdef AF_UNIX
 320       case AF_UNIX:
 321 #else
 322 #ifdef AF_LOCAL
 323       case AF_LOCAL:
 324 #endif
 325 #endif
 326       default:
 327         /* another family support? */
 328         break;
 329       }
 330     }
 331   }
 332
 333   /* supported family should be 2, unsupported family should be 0 */
 334   if (!(inet4 == 0 || inet4 == 2))
 335     goto bad;
 336   if (!(inet6 == 0 || inet6 == 2))
 337     goto bad;
 338
 339   if (aitop)
 340     freeaddrinfo(aitop);
 341   exit(0);
 342
 343  bad:
 344   if (aitop)
 345     freeaddrinfo(aitop);
 346   exit(1);
 347 }
 348 ],
 349         AC_MSG_RESULT(good)
 350         buggygetaddrinfo=no,
 351         AC_MSG_RESULT(buggy)
 352         buggygetaddrinfo=yes,
 353         AC_MSG_RESULT(buggy)
 354         buggygetaddrinfo=yes)], [buggygetaddrinfo=yes])
 355
 356         if test "$buggygetaddrinfo" = "yes"; then
 357                 if test "$ipv6type" != "linux"; then
 358                         echo 'Fatal: You must get working getaddrinfo() function.'
 359                         echo '       or you can specify "--disable-ipv6"'.
 360                         exit 1
 361                 else
 362                         echo 'Warning: getaddrinfo() implementation on your system seems be buggy.'
 363                         echo '         Better upgreade your system library to newest version'
 364                         echo '         of GNU C library (aka glibc).'
 365                 fi
 366         fi
 367         AC_REPLACE_FUNCS(getaddrinfo getnameinfo)
 368 fi
 369 dnl AC_TRY_COMPILE(inet_ntop inet_pton inet_aton)
 370 AC_MSG_CHECKING(for inet_ntop)
 371 AC_TRY_COMPILE([#include <sys/types.h>
 372 #include <sys/socket.h>
 373 #include <netinet/in.h>
 374 #include <arpa/inet.h>], [char src[4], dst[128];
 375 inet_ntop(AF_INET, src, dst, sizeof(dst));],
 376         [AC_MSG_RESULT(yes)], [AC_MSG_RESULT(no)
 377         AC_REPLACE_FUNCS(inet_ntop)])
 378 AC_MSG_CHECKING(for inet_pton)
 379 AC_TRY_COMPILE([#include <sys/types.h>
 380 #include <sys/socket.h>
 381 #include <netinet/in.h>
 382 #include <arpa/inet.h>], [char src[128], dst[4];
 383 inet_pton(AF_INET, src, dst);],
 384         [AC_MSG_RESULT(yes)], [AC_MSG_RESULT(no)
 385         AC_REPLACE_FUNCS(inet_pton)])
 386 AC_MSG_CHECKING(for inet_aton)
 387 AC_TRY_COMPILE([#include <sys/types.h>
 388 #include <netinet/in.h>
 389 #include <arpa/inet.h>], [char src[128];
 390 struct in_addr dst;
 391 inet_aton(src, &dst);],
 392         [AC_MSG_RESULT(yes)], [AC_MSG_RESULT(no)
 393         AC_REPLACE_FUNCS(inet_aton)])
 394
 395 dnl portability macros for getaddrinfo/getnameinfo
 396 dnl
 397 dnl Check for sa_len
 398 AC_CHECK_SA_LEN(ac_cv_sockaddr_has_sa_len)
 399 if test "$ac_cv_sockaddr_has_sa_len" = no; then
 400         missing_includes=yes
 401 fi
 402
 403 dnl
 404 dnl check sizeof basic types.
 405 dnl They're very likely to be wrong for cross-compiling.
 406 AC_CHECK_SIZEOF(char, 1)
 407 AC_CHECK_SIZEOF(short, 2)
 408 AC_CHECK_SIZEOF(int, 4)
 409 AC_CHECK_SIZEOF(long, 4)
 410
 411 dnl
 412 dnl Checks for u_intXX_t
 413 dnl AC_CHECK_BITTYPES(ac_cv_bittypes)
 414 dnl if test "$ac_cv_bittypes" = no; then
 415 dnl     missing_includes=yes
 416 dnl fi
 417
 418 dnl
 419 dnl Checks for addrinfo structure
 420 AC_STRUCT_ADDRINFO(ac_cv_addrinfo)
 421 if test "$ac_cv_addrinfo" = no; then
 422         missing_includes=yes
 423 fi
 424
 425 dnl
 426 dnl Checks for NI_MAXSERV
 427 AC_NI_MAXSERV(ac_cv_maxserv)
 428 if test "$ac_cv_maxserv" = no; then
 429         missing_includes=yes
 430 fi
 431
 432 dnl
 433 dnl Checks for NI_NAMEREQD
 434 AC_NI_NAMEREQD(ac_cv_namereqd)
 435 if test "$ac_cv_namereqd" = no; then
 436         missing_includes=yes
 437 fi
 438
 439 dnl
 440 dnl Checks for sockaddr_storage structure
 441 AC_STRUCT_SA_STORAGE(ac_cv_sa_storage)
 442 if test "$ac_cv_sa_storage" = no; then
 443         missing_includes=yes
 444 fi
 445
 446 dnl
 447 dnl Checks for IN[6]ADDRSZ
 448 AC_CHECK_ADDRSZ(ac_cv_addrsz)
 449 if test "$ac_cv_addrsz" = no; then
 450         missing_includes=yes
 451 fi
 452
 453 dnl
 454 dnl Checks for RES_USE_INET6
 455 AC_CHECK_RES_USE_INET6(ac_cv_res_inet6)
 456 if test "$ac_cv_res_inet6" = no; then
 457         missing_includes=yes
 458 fi
 459
 460 dnl
 461 dnl Checks for res_state_ext structure
 462 AC_STRUCT_RES_STATE_EXT(ac_cv_res_state_ext)
 463 if test "$ac_cv_res_state_ext" = no; then
 464         missing_includes=yes
 465 fi
 466
 467 dnl
 468 dnl Checks if res_state structure has nsort member.
 469 AC_STRUCT_RES_STATE(ac_cv_res_state)
 470
 471 dnl
 472 dnl set additional include path if necessary
 473 if test "$missing_includes" = "yes"; then
 474         CPPFLAGS="$CPPFLAGS -I\$(srcdir)/missing"
 475         V_INCLS="$V_INCLS -I\$(srcdir)/missing"
 476 fi
 477
 478
 479 AC_REPLACE_FUNCS(vfprintf strcasecmp strlcat strlcpy strdup)
 480 AC_CHECK_FUNCS(ether_ntohost, [
 481     AC_CACHE_CHECK(for buggy ether_ntohost, ac_cv_buggy_ether_ntohost, [
 482         AC_TRY_RUN([
 483                 #include <netdb.h>
 484                 #include <sys/types.h>
 485                 #include <sys/param.h>
 486                 #include <sys/socket.h>
 487
 488                 int
 489                 main(int argc, char **argv)
 490                 {
 491                         u_char ea[6] = { 0xff, 0xff, 0xff, 0xff, 0xff };
 492                         char name[MAXHOSTNAMELEN];
 493
 494                         ether_ntohost(name, (struct ether_addr *)ea);
 495                         exit(0);
 496                 }
 497         ], [ac_cv_buggy_ether_ntohost=no],
 498            [ac_cv_buggy_ether_ntohost=yes],
 499            [ac_cv_buggy_ether_ntohost=not while cross-compiling])])
 500     if test "$ac_cv_buggy_ether_ntohost" = "no"; then
 501         AC_DEFINE(USE_ETHER_NTOHOST)
 502     fi
 503 ])
 504 AC_CHECK_FUNCS(setlinebuf)
 505
 506 needsnprintf=no
 507 AC_CHECK_FUNCS(vsnprintf snprintf,,
 508         [needsnprintf=yes])
 509 if test $needsnprintf = yes; then
 510         LIBOBJS="$LIBOBJS snprintf.o"
 511 fi
 512
 513 AC_LBL_TYPE_SIGNAL
 514
 515 AC_CHECK_LIB(dnet, dnet_htoa)
 516
 517 AC_CHECK_LIB(rpc, main)         dnl It's unclear why we might need -lrpc
 518
 519 dnl HP/UX may need -lnsl for getrpcbynumber.
 520 AC_SEARCH_LIBS(getrpcbynumber, nsl)
 521
 522 dnl AC_CHECK_LIB(z, uncompress)
 523 dnl AC_CHECK_HEADERS(zlib.h)
 524
 525 AC_LBL_LIBPCAP(V_PCAPDEP, V_INCLS)
 526
 527 AC_REPLACE_FUNCS(bpf_dump)      dnl moved to libpcap in 0.6
 528
 529 V_GROUP=0
 530 if test -f /etc/group -a ! -z "`grep '^wheel:' /etc/group`" ; then
 531         V_GROUP=wheel
 532 fi
 533 case "$host_os" in
 534
 535 aix*)
 536         dnl Workaround to enable certain features
 537         AC_DEFINE(_SUN)
 538         ;;
 539
 540 irix*)
 541         V_GROUP=sys
 542         ;;
 543
 544 osf*)
 545         V_GROUP=system
 546         ;;
 547
 548 solaris*)
 549         V_GROUP=sys
 550         ;;
 551 esac
 552
 553 if test -f /dev/bpf0 ; then
 554         V_GROUP=bpf
 555 fi
 556
 557 AC_LBL_CHECK_TYPE(u_int8_t, u_char)
 558 AC_LBL_CHECK_TYPE(int16_t, short)
 559 AC_LBL_CHECK_TYPE(u_int16_t, u_short)
 560 AC_LBL_CHECK_TYPE(int32_t, int)
 561 AC_LBL_CHECK_TYPE(u_int32_t, u_int)
 562
 563 AC_LBL_DEVEL(V_CCOPT)
 564
 565 AC_LBL_SOCKADDR_SA_LEN
 566
 567 AC_LBL_UNALIGNED_ACCESS
 568
 569 AC_VAR_H_ERRNO
 570
 571 AC_ARG_WITH(crypto, [  --without-crypto        disable crypto support],
 572         [], [
 573 AC_MSG_CHECKING(for SSLeay)
 574 ac_cv_ssleay_path=no
 575 incdir=no
 576 for dir in /usr /usr/local /usr/local/ssl /usr/pkg; do
 577         if test -d $dir/lib -a -f $dir/lib/libcrypto.a; then
 578                 ac_cv_ssleay_path=$dir
 579         fi
 580         if test -d $dir/include/openssl -a -f $dir/include/openssl/des.h; then
 581                 incdir="-I$dir/include"
 582         fi
 583         if test "$ac_cv_ssleay_path" != "no" -a "$incdir" != "no"; then
 584                 break;
 585         else
 586                 ac_cv_ssleay_path=no
 587                 incdir=no
 588         fi
 589 done
 590 AC_MSG_RESULT($ac_cv_ssleay_path)
 591 if test "$ac_cv_ssleay_path" != no; then
 592         V_INCLS="$V_INCLS $incdir"
 593         LDFLAGS="-L$dir/lib $LDFLAGS"
 594         if test -f $ac_cv_ssleay_path/lib/libRSAglue.a; then
 595                 LIBS="$LIBS -lRSAglue"
 596         fi
 597         if test -f $ac_cv_ssleay_path/lib/librsaref.a; then
 598                 LIBS="$LIBS -lrsaref"
 599         fi
 600         AC_CHECK_LIB(crypto, des_cbc_encrypt)
 601
 602         bak_CPPFLAGS=$CPPFLAGS
 603         CPPFLAGS="$CPPFLAGS $V_INCLS"
 604         AC_CHECK_HEADERS(cast.h)
 605
 606         if test "$ac_cv_header_cast_h" = "yes"; then
 607                 AC_MSG_CHECKING(for buggy CAST128)
 608                 AC_TRY_RUN(dnl
 609 [
 610 #include <cast.h>
 611 main()
 612 {
 613         unsigned char key[] = {0x01,0x23,0x45,0x67,0x12};
 614         unsigned char in[] = {0x01,0x23,0x45,0x67,0x89,0xAB,0xCD,0xEF};
 615         unsigned char out[sizeof(in)];
 616         unsigned char ok[] = {0x7A,0xC8,0x16,0xD1,0x6E,0x9B,0x30,0x2E};
 617         CAST_KEY ks;
 618         CAST_set_key(&ks, sizeof(key), key);
 619         CAST_ecb_encrypt(in, out, &ks, CAST_ENCRYPT);
 620         if (memcmp(out, ok, sizeof(ok)) != 0)
 621                 return 0;
 622         else
 623                 return 1;
 624 }],
 625                         [buggy_cast128=yes],
 626                         [buggy_cast128=no],
 627                         [buggy_cast128="cross-compiling, assume yes"])
 628                 AC_MSG_RESULT($buggy_cast128)
 629                 if test "$buggy_cast128" != no; then
 630                         echo "NOTE: SSLeay 0.9.0b has a bug in CAST128 en/decoding routine."
 631                         echo "disabling CAST128 support."
 632                         AC_DEFINE(HAVE_BUGGY_CAST128)
 633                 fi
 634         fi
 635
 636         CPPFLAGS=$bak_CPPFLAGS
 637 fi
 638 ])
 639 AC_CHECK_HEADERS(rc5.h)
 640
 641 AC_SUBST(V_CCOPT)
 642 AC_SUBST(V_GROUP)
 643 AC_SUBST(V_INCLS)
 644 AC_SUBST(V_PCAPDEP)
 645 AC_SUBST(LOCALSRC)
 646
 647 AC_PROG_INSTALL
 648
 649 AC_CONFIG_HEADER(config.h)
 650
 651 AC_OUTPUT_COMMANDS([if test -f .devel; then
 652         echo timestamp > stamp-h
 653         cat Makefile-devel-adds >> Makefile
 654         make depend
 655 fi])
 656 AC_OUTPUT(Makefile)
 657 exit 0