The Tcpdump Group git mirrors - tcpdump/blob - configure.ac

   1 dnl Copyright (c) 1994, 1995, 1996, 1997
   2 dnl     The Regents of the University of California.  All rights reserved.
   3 dnl
   4 dnl Process this file with autoconf to produce a configure script.
   5 dnl
   6
   7 #
   8 # See
   9 #
  10 #       http://ftp.gnu.org/gnu/config/README
  11 #
  12 # for the URLs to use to fetch new versions of config.guess and
  13 # config.sub.
  14 #
  15
  16 AC_PREREQ(2.64)
  17 AC_INIT(tcpdump, m4_esyscmd_s([cat VERSION]))
  18 AC_CONFIG_SRCDIR(tcpdump.c)
  19
  20 AC_CANONICAL_HOST
  21
  22 AC_LBL_C_INIT_BEFORE_CC(V_INCLS)
  23 AC_PROG_CC_C99
  24 AC_LBL_C_INIT(V_CCOPT, V_INCLS)
  25 AC_LBL_C_INLINE
  26
  27 AC_CHECK_HEADERS(fcntl.h rpc/rpc.h rpc/rpcent.h)
  28 AC_CHECK_HEADERS(net/pfvar.h, , , [#include <sys/types.h>
  29 #include <sys/socket.h>
  30 #include <net/if.h>])
  31 if test "$ac_cv_header_net_pfvar_h" = yes; then
  32         AC_CHECK_HEADERS(net/if_pflog.h, , , [#include <sys/types.h>
  33         #include <sys/socket.h>
  34         #include <net/if.h>
  35         #include <net/pfvar.h>])
  36         if test "$ac_cv_header_net_if_pflog_h" = yes; then
  37                 LOCALSRC="print-pflog.c $LOCALSRC"
  38         fi
  39 fi
  40 AC_CHECK_HEADERS(netinet/if_ether.h, , , [#include <sys/types.h>
  41 #include <sys/socket.h>])
  42 if test "$ac_cv_header_netinet_if_ether_h" != yes; then
  43         #
  44         # The simple test didn't work.
  45         # Do we need to include <net/if.h> first?
  46         # Unset ac_cv_header_netinet_if_ether_h so we don't
  47         # treat the previous failure as a cached value and
  48         # suppress the next test.
  49         #
  50         AC_MSG_NOTICE([Rechecking with some additional includes])
  51         unset ac_cv_header_netinet_if_ether_h
  52         AC_CHECK_HEADERS(netinet/if_ether.h, , , [#include <sys/types.h>
  53 #include <sys/socket.h>
  54 #include <netinet/in.h>
  55 struct mbuf;
  56 struct rtentry;
  57 #include <net/if.h>])
  58 fi
  59
  60 case "$host_os" in
  61
  62 darwin*)
  63         AC_ARG_ENABLE(universal,
  64         AC_HELP_STRING([--disable-universal],[don't build universal on macOS]))
  65         if test "$enable_universal" != "no"; then
  66                 case "$host_os" in
  67
  68                 darwin9.*)
  69                         #
  70                         # Leopard.  Build for x86 and 32-bit PowerPC, with
  71                         # x86 first.  (That's what Apple does.)
  72                         #
  73                         V_CCOPT="$V_CCOPT -arch i386 -arch ppc"
  74                         LDFLAGS="$LDFLAGS -arch i386 -arch ppc"
  75                         ;;
  76
  77                 darwin10.*)
  78                         #
  79                         # Snow Leopard.  Build for x86-64 and x86, with
  80                         # x86-64 first.  (That's what Apple does.)
  81                         #
  82                         V_CCOPT="$V_CCOPT -arch x86_64 -arch i386"
  83                         LDFLAGS="$LDFLAGS -arch x86_64 -arch i386"
  84                         ;;
  85                 esac
  86         fi
  87         ;;
  88 esac
  89
  90
  91 AC_ARG_WITH(smi,
  92 [  --with-smi              link with libsmi (allows to load MIBs on the fly to decode SNMP packets. [default=yes]
  93   --without-smi           don't link with libsmi],,
  94    with_smi=yes)
  95
  96 if test "x$with_smi" != "xno" ; then
  97         AC_CHECK_HEADER(smi.h,
  98         [
  99                 #
 100                 # OK, we found smi.h.  Do we have libsmi with smiInit?
 101                 #
 102                 AC_CHECK_LIB(smi, smiInit,
 103                 [
 104                         #
 105                         # OK, we have libsmi with smiInit.  Can we use it?
 106                         #
 107                         AC_MSG_CHECKING([whether to enable libsmi])
 108                         savedlibs="$LIBS"
 109                         LIBS="-lsmi $LIBS"
 110                         AC_TRY_RUN(
 111                                 [
 112 /* libsmi available check */
 113 #include <smi.h>
 114 main()
 115 {
 116   int current, revision, age, n;
 117   const int required = 2;
 118   if (smiInit(""))
 119     exit(1);
 120   if (strcmp(SMI_LIBRARY_VERSION, smi_library_version))
 121     exit(2);
 122   n = sscanf(smi_library_version, "%d:%d:%d", &current, &revision, &age);
 123   if (n != 3)
 124     exit(3);
 125   if (required < current - age || required > current)
 126     exit(4);
 127   exit(0);
 128 }
 129                                 ],
 130                                 [
 131                                         AC_MSG_RESULT(yes)
 132                                         AC_DEFINE(USE_LIBSMI, 1,
 133                                             [Define if you enable support for libsmi])
 134                                 ],
 135                                 [
 136                                         dnl autoconf documentation says that
 137                                         dnl $? contains the exit value.
 138                                         dnl reality is that it does not.
 139                                         dnl We leave this in just in case
 140                                         dnl autoconf ever comes back to
 141                                         dnl match the documentation.
 142                                         case $? in
 143                                           1) AC_MSG_RESULT(no - smiInit failed) ;;
 144                                           2) AC_MSG_RESULT(no - header/library version mismatch) ;;
 145                                           3) AC_MSG_RESULT(no - can't determine library version) ;;
 146                                           4) AC_MSG_RESULT(no - too old) ;;
 147                                           *) AC_MSG_RESULT(no) ;;
 148                                         esac
 149                                         LIBS="$savedlibs"
 150                                 ],
 151                                 [
 152                                         AC_MSG_RESULT(not when cross-compiling)
 153                                         LIBS="$savedlibs"
 154                                 ]
 155                         )
 156                 ])
 157         ])
 158 fi
 159
 160 AC_MSG_CHECKING([whether to enable the possibly-buggy SMB printer])
 161 AC_ARG_ENABLE(smb,
 162 [  --enable-smb            enable possibly-buggy SMB printer [default=yes]
 163   --disable-smb           disable possibly-buggy SMB printer],,
 164    enableval=yes)
 165 case "$enableval" in
 166 yes)    AC_MSG_RESULT(yes)
 167         AC_WARN([The SMB printer may have exploitable buffer overflows!!!])
 168         AC_DEFINE(ENABLE_SMB, 1,
 169             [define if you want to build the possibly-buggy SMB printer])
 170         LOCALSRC="print-smb.c smbutil.c $LOCALSRC"
 171         ;;
 172 *)      AC_MSG_RESULT(no)
 173         ;;
 174 esac
 175
 176 AC_ARG_WITH(user, [  --with-user=USERNAME    drop privileges by default to USERNAME])
 177 AC_MSG_CHECKING([whether to drop root privileges by default])
 178 if test ! -z "$with_user" ; then
 179        AC_DEFINE_UNQUOTED(WITH_USER, "$withval",
 180            [define if should drop privileges by default])
 181        AC_MSG_RESULT(to \"$withval\")
 182 else
 183        AC_MSG_RESULT(no)
 184 fi
 185
 186 AC_ARG_WITH(chroot, [  --with-chroot=DIRECTORY when dropping privileges, chroot to DIRECTORY])
 187 AC_MSG_CHECKING([whether to chroot])
 188 if test ! -z "$with_chroot" && test "$with_chroot" != "no" ; then
 189        AC_DEFINE_UNQUOTED(WITH_CHROOT, "$withval",
 190            [define if should chroot when dropping privileges])
 191        AC_MSG_RESULT(to \"$withval\")
 192 else
 193        AC_MSG_RESULT(no)
 194 fi
 195
 196 AC_ARG_WITH(sandbox-capsicum,
 197         AS_HELP_STRING([--with-sandbox-capsicum],
 198                        [use Capsicum security functions @<:@default=yes, if available@:>@]))
 199 #
 200 # Check whether various functions are available.  If any are, set
 201 # ac_lbl_capsicum_function_seen to yes; if any are not, set
 202 # ac_lbl_capsicum_function_not_seen to yes.
 203 #
 204 # We don't check cap_rights_init(), as it's a macro, wrapping another
 205 # function, in at least some versions of FreeBSD, and AC_CHECK_FUNCS()
 206 # doesn't handle that.
 207 #
 208 # All of the ones we check for must be available in order to enable
 209 # capsicum sandboxing.
 210 #
 211 # XXX - do we need to check for all of them, or are there some that, if
 212 # present, imply others are present?
 213 #
 214 if test ! -z "$with_sandbox-capsicum" && test "$with_sandbox-capsicum" != "no" ; then
 215         AC_CHECK_FUNCS(cap_enter cap_rights_limit cap_ioctls_limit openat,
 216             ac_lbl_capsicum_function_seen=yes,
 217             ac_lbl_capsicum_function_not_seen=yes)
 218         AC_CHECK_LIB(casper, cap_init, LIBS="$LIBS -lcasper")
 219         AC_CHECK_LIB(cap_dns, cap_gethostbyaddr, LIBS="$LIBS -lcap_dns")
 220 fi
 221 AC_MSG_CHECKING([whether to sandbox using capsicum])
 222 if test "x$ac_lbl_capsicum_function_seen" = "xyes" -a "x$ac_lbl_capsicum_function_not_seen" != "xyes"; then
 223         AC_DEFINE(HAVE_CAPSICUM, 1, [capsicum support available])
 224         AC_MSG_RESULT(yes)
 225 else
 226         AC_MSG_RESULT(no)
 227 fi
 228 AC_MSG_CHECKING([whether to sandbox using Casper library])
 229 if test "x$ac_cv_lib_casper_cap_init" = "xyes" -a "x$ac_cv_lib_cap_dns_cap_gethostbyaddr" = "xyes"; then
 230         AC_DEFINE(HAVE_CASPER, 1, [Casper support available])
 231         AC_MSG_RESULT(yes)
 232 else
 233         AC_MSG_RESULT(no)
 234 fi
 235
 236 #
 237 # We must check this before checking whether to check the OS's IPv6,
 238 # support because, on some platforms (such as SunOS 5.x), the test
 239 # program requires the extra networking libraries.
 240 #
 241 AC_LBL_LIBRARY_NET
 242
 243 #
 244 # Check whether AF_INET6 and struct in6_addr are defined.
 245 # If they aren't both defined, we don't have sufficient OS
 246 # support for IPv6, so we don't look for IPv6 support libraries,
 247 # and we define AF_INET6 and struct in6_addr ourselves.
 248 #
 249 AC_MSG_CHECKING([whether the operating system supports IPv6])
 250 AC_COMPILE_IFELSE(
 251     [
 252       AC_LANG_SOURCE(
 253         [[
 254 /* AF_INET6 available check */
 255 #include <sys/types.h>
 256 #ifdef _WIN32
 257 #include <ws2tcpip.h>
 258 #else
 259 #include <sys/socket.h>
 260 #include <netinet/in.h>
 261 #endif
 262 #ifdef AF_INET6
 263 void
 264 foo(struct in6_addr *addr)
 265 {
 266  memset(addr, 0, sizeof (struct in6_addr));
 267 }
 268 #else
 269 #error "AF_INET6 not defined"
 270 #endif
 271         ]])
 272     ],
 273     [
 274         AC_MSG_RESULT(yes)
 275         AC_DEFINE(HAVE_OS_IPV6_SUPPORT, 1,
 276             [define if the OS provides AF_INET6 and struct in6_addr])
 277         ipv6=yes
 278     ],
 279     [
 280         AC_MSG_RESULT(no)
 281         ipv6=no
 282     ]
 283 )
 284
 285 ipv6type=unknown
 286 ipv6lib=none
 287 ipv6trylibc=no
 288
 289 if test "$ipv6" = "yes"; then
 290         AC_MSG_CHECKING([ipv6 stack type])
 291         for i in inria kame linux-glibc linux-libinet6 toshiba v6d zeta; do
 292                 case $i in
 293                 inria)
 294                         dnl http://www.kame.net/
 295                         AC_EGREP_CPP(yes,
 296 [#include <netinet/in.h>
 297 #ifdef IPV6_INRIA_VERSION
 298 yes
 299 #endif],
 300                                 [ipv6type=$i])
 301                         ;;
 302                 kame)
 303                         dnl http://www.kame.net/
 304                         AC_EGREP_CPP(yes,
 305 [#include <netinet/in.h>
 306 #ifdef __KAME__
 307 yes
 308 #endif],
 309                                 [ipv6type=$i;
 310                                 ipv6lib=inet6;
 311                                 ipv6libdir=/usr/local/v6/lib;
 312                                 ipv6trylibc=yes])
 313                         ;;
 314                 linux-glibc)
 315                         dnl http://www.v6.linux.or.jp/
 316                         AC_EGREP_CPP(yes,
 317 [#include <features.h>
 318 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 319 yes
 320 #endif],
 321                                 [ipv6type=$i])
 322                         ;;
 323                 linux-libinet6)
 324                         dnl http://www.v6.linux.or.jp/
 325                         dnl
 326                         dnl This also matches Solaris 8 and Tru64 UNIX 5.1,
 327                         dnl and possibly other versions of those OSes
 328                         dnl
 329                         if test -d /usr/inet6 -o -f /usr/include/netinet/ip6.h; then
 330                                 ipv6type=$i
 331                                 ipv6lib=inet6
 332                                 ipv6libdir=/usr/inet6/lib
 333                                 ipv6trylibc=yes;
 334                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 335                         fi
 336                         ;;
 337                 toshiba)
 338                         AC_EGREP_CPP(yes,
 339 [#include <sys/param.h>
 340 #ifdef _TOSHIBA_INET6
 341 yes
 342 #endif],
 343                                 [ipv6type=$i;
 344                                 ipv6lib=inet6;
 345                                 ipv6libdir=/usr/local/v6/lib])
 346                         ;;
 347                 v6d)
 348                         AC_EGREP_CPP(yes,
 349 [#include </usr/local/v6/include/sys/v6config.h>
 350 #ifdef __V6D__
 351 yes
 352 #endif],
 353                                 [ipv6type=$i;
 354                                 ipv6lib=v6;
 355                                 ipv6libdir=/usr/local/v6/lib;
 356                                 CFLAGS="-I/usr/local/v6/include $CFLAGS"])
 357                         ;;
 358                 zeta)
 359                         AC_EGREP_CPP(yes,
 360 [#include <sys/param.h>
 361 #ifdef _ZETA_MINAMI_INET6
 362 yes
 363 #endif],
 364                                 [ipv6type=$i;
 365                                 ipv6lib=inet6;
 366                                 ipv6libdir=/usr/local/v6/lib])
 367                         ;;
 368                 esac
 369                 if test "$ipv6type" != "unknown"; then
 370                         break
 371                 fi
 372         done
 373         AC_MSG_RESULT($ipv6type)
 374 fi
 375
 376 if test "$ipv6" = "yes" -a "$ipv6lib" != "none"; then
 377         if test -d $ipv6libdir -a -f $ipv6libdir/lib$ipv6lib.a; then
 378                 LIBS="-L$ipv6libdir -l$ipv6lib $LIBS"
 379                 echo "You have $ipv6lib library, using it"
 380         else
 381                 if test "$ipv6trylibc" = "yes"; then
 382                         echo "You do not have $ipv6lib library, using libc"
 383                 else
 384                         echo 'Fatal: no $ipv6lib library found.  cannot continue.'
 385                         echo "You need to fetch lib$ipv6lib.a from appropriate"
 386                         echo 'ipv6 kit and compile beforehand.'
 387                         exit 1
 388                 fi
 389         fi
 390 fi
 391
 392 AC_SEARCH_LIBS(dnet_htoa, dnet,
 393 [
 394         AC_DEFINE(HAVE_DNET_HTOA, 1,
 395             [define if you have the dnet_htoa function])
 396         #
 397         # OK, we have dnet_htoa().  Do we have netdnet/dnetdb.h?
 398         #
 399         AC_CHECK_HEADERS(netdnet/dnetdb.h)
 400         if test "$ac_cv_header_netdnet_dnetdb_h" = "yes"; then
 401                 #
 402                 # Yes.  Does it declare dnet_htoa()?
 403                 #
 404                 AC_CHECK_DECL(dnet_htoa,
 405                 [
 406                         # Yes.
 407                         AC_DEFINE(NETDNET_DNETDB_H_DECLARES_DNET_HTOA,,
 408                             [Define to 1 if netenet/dnetdb.h declares `dnet_htoa'])
 409                 ],,
 410                 [
 411 AC_INCLUDES_DEFAULT
 412 #include <netdnet/dnetdb.h>
 413                 ])
 414         fi
 415
 416         #
 417         # Do we have netdnet/dn.h?
 418         #
 419         AC_CHECK_HEADERS(netdnet/dn.h)
 420         if test "$ac_cv_header_netdnet_dn_h" = "yes"; then
 421                 #
 422                 # Yes.  Does it declare struct dn_naddr?
 423                 #
 424                 AC_CHECK_TYPES(struct dn_naddr,,,
 425                 [
 426 #include <netdnet/dn.h>
 427                 ])
 428         fi
 429 ])
 430
 431 AC_REPLACE_FUNCS(strlcat strlcpy strdup strsep getservent getopt_long)
 432 AC_CHECK_FUNCS(fork vfork strftime)
 433 AC_CHECK_FUNCS(setlinebuf)
 434
 435 needsnprintf=no
 436 AC_CHECK_FUNCS(vsnprintf snprintf,,
 437         [needsnprintf=yes])
 438 if test $needsnprintf = yes; then
 439         AC_LIBOBJ(snprintf)
 440 fi
 441
 442 AC_CHECK_LIB(rpc, main)         dnl It's unclear why we might need -lrpc
 443
 444 dnl Some platforms may need -lnsl for getrpcbynumber.
 445 AC_SEARCH_LIBS(getrpcbynumber, nsl,
 446     AC_DEFINE(HAVE_GETRPCBYNUMBER, 1, [define if you have getrpcbynumber()]))
 447
 448 AC_LBL_LIBPCAP(V_PCAPDEP, V_INCLS)
 449
 450 #
 451 # Check for these after AC_LBL_LIBPCAP, so we link with the appropriate
 452 # libraries (e.g., "-lsocket -lnsl" on Solaris).
 453 #
 454 # You are in a twisty little maze of UN*Xes, all different.
 455 # Some might not have ether_ntohost().
 456 # Some might have it, but not declare it in any header file.
 457 # Some might have it, but declare it in <netinet/if_ether.h>.
 458 # Some might have it, but declare it in <netinet/ether.h>
 459 # (And some might have it but document it as something declared in
 460 # <netinet/ethernet.h>, although <netinet/if_ether.h> appears to work.)
 461 #
 462 # Before you is a C compiler.
 463 #
 464 AC_CHECK_FUNCS(ether_ntohost, [
 465     AC_CACHE_CHECK(for buggy ether_ntohost, ac_cv_buggy_ether_ntohost, [
 466         AC_TRY_RUN([
 467                 #include <netdb.h>
 468                 #include <sys/types.h>
 469                 #include <sys/param.h>
 470                 #include <sys/socket.h>
 471
 472                 int
 473                 main(int argc, char **argv)
 474                 {
 475                         u_char ea[6] = { 0xff, 0xff, 0xff, 0xff, 0xff };
 476                         char name[MAXHOSTNAMELEN];
 477
 478                         ether_ntohost(name, (struct ether_addr *)ea);
 479                         exit(0);
 480                 }
 481         ], [ac_cv_buggy_ether_ntohost=no],
 482            [ac_cv_buggy_ether_ntohost=yes],
 483            [ac_cv_buggy_ether_ntohost="not while cross-compiling"])])
 484     if test "$ac_cv_buggy_ether_ntohost" = "no"; then
 485         AC_DEFINE(USE_ETHER_NTOHOST, 1,
 486             [define if you have ether_ntohost() and it works])
 487     fi
 488 ])
 489 if test "$ac_cv_func_ether_ntohost" = yes -a \
 490     "$ac_cv_buggy_ether_ntohost" = "no"; then
 491         #
 492         # OK, we have ether_ntohost().  Do we have <netinet/if_ether.h>?
 493         #
 494         if test "$ac_cv_header_netinet_if_ether_h" = yes; then
 495                 #
 496                 # Yes.  Does it declare ether_ntohost()?
 497                 #
 498                 AC_CHECK_DECL(ether_ntohost,
 499                     [
 500                         AC_DEFINE(NETINET_IF_ETHER_H_DECLARES_ETHER_NTOHOST,,
 501                             [Define to 1 if netinet/if_ether.h declares `ether_ntohost'])
 502                     ],,
 503                     [
 504 #include <sys/types.h>
 505 #include <sys/socket.h>
 506 #include <netinet/in.h>
 507 #include <arpa/inet.h>
 508 struct mbuf;
 509 struct rtentry;
 510 #include <net/if.h>
 511 #include <netinet/if_ether.h>
 512                     ])
 513         fi
 514         #
 515         # Did that succeed?
 516         #
 517         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 518                 #
 519                 # No, how about <netinet/ether.h>, as on Linux?
 520                 #
 521                 AC_CHECK_HEADERS(netinet/ether.h)
 522                 if test "$ac_cv_header_netinet_ether_h" = yes; then
 523                         #
 524                         # We have it - does it declare ether_ntohost()?
 525                         # Unset ac_cv_have_decl_ether_ntohost so we don't
 526                         # treat the previous failure as a cached value and
 527                         # suppress the next test.
 528                         #
 529                         unset ac_cv_have_decl_ether_ntohost
 530                         AC_CHECK_DECL(ether_ntohost,
 531                             [
 532                                 AC_DEFINE(NETINET_ETHER_H_DECLARES_ETHER_NTOHOST,,
 533                                     [Define to 1 if netinet/ether.h declares `ether_ntohost'])
 534                             ],,
 535                             [
 536 #include <netinet/ether.h>
 537                             ])
 538                 fi
 539         fi
 540         #
 541         # Is ether_ntohost() declared?
 542         #
 543         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 544                 #
 545                 # No, we'll have to declare it ourselves.
 546                 # Do we have "struct ether_addr"?
 547                 #
 548                 AC_CHECK_TYPES(struct ether_addr,,,
 549                     [
 550 #include <sys/types.h>
 551 #include <sys/socket.h>
 552 #include <netinet/in.h>
 553 #include <arpa/inet.h>
 554 struct mbuf;
 555 struct rtentry;
 556 #include <net/if.h>
 557 #include <netinet/if_ether.h>
 558                     ])
 559                 AC_DEFINE(HAVE_DECL_ETHER_NTOHOST, 0,
 560                     [Define to 1 if you have the declaration of `ether_ntohost', and to 0 if you
 561 don't.])
 562         else
 563                 AC_DEFINE(HAVE_DECL_ETHER_NTOHOST, 1,
 564                     [Define to 1 if you have the declaration of `ether_ntohost', and to 0 if you
 565 don't.])
 566         fi
 567 fi
 568
 569 dnl
 570 dnl Check for "pcap_list_datalinks()", "pcap_set_datalink()",
 571 dnl and "pcap_datalink_name_to_val()", and use substitute versions
 572 dnl if they're not present.
 573 dnl
 574 AC_CHECK_FUNC(pcap_list_datalinks,
 575         [
 576             AC_DEFINE(HAVE_PCAP_LIST_DATALINKS, 1,
 577                 [define if libpcap has pcap_list_datalinks()])
 578             AC_CHECK_FUNCS(pcap_free_datalinks)
 579         ],
 580         [
 581             AC_LIBOBJ(datalinks)
 582         ])
 583 AC_CHECK_FUNCS(pcap_set_datalink)
 584 AC_CHECK_FUNC(pcap_datalink_name_to_val,
 585         [
 586             AC_DEFINE(HAVE_PCAP_DATALINK_NAME_TO_VAL, 1,
 587                 [define if libpcap has pcap_datalink_name_to_val()])
 588             AC_CHECK_FUNC(pcap_datalink_val_to_description,
 589                 AC_DEFINE(HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION, 1,
 590                     [define if libpcap has pcap_datalink_val_to_description()]),
 591                 [
 592                     AC_LIBOBJ(dlnames)
 593                 ])
 594         ],
 595         [
 596             AC_LIBOBJ(dlnames)
 597         ])
 598
 599 dnl
 600 dnl Check for "pcap_breakloop()"; you can't substitute for it if
 601 dnl it's absent (it has hooks into the live capture routines),
 602 dnl so just define the HAVE_ value if it's there.
 603 dnl
 604 AC_CHECK_FUNCS(pcap_breakloop)
 605
 606 dnl
 607 dnl Check for "pcap_dump_ftell()" and use a substitute version
 608 dnl if it's not present.
 609 dnl
 610 AC_CHECK_FUNC(pcap_dump_ftell,
 611         AC_DEFINE(HAVE_PCAP_DUMP_FTELL, 1,
 612             [define if libpcap has pcap_dump_ftell()]),
 613         [
 614             AC_LIBOBJ(pcap_dump_ftell)
 615         ])
 616
 617 #
 618 # Do we have the new open API?  Check for pcap_create, and assume that,
 619 # if we do, we also have pcap_activate() and the other new routines
 620 # introduced in libpcap 1.0.0.
 621 #
 622 AC_CHECK_FUNCS(pcap_create)
 623 if test $ac_cv_func_pcap_create = "yes" ; then
 624         #
 625         # OK, do we have pcap_set_tstamp_type?  If so, assume we have
 626         # pcap_list_tstamp_types and pcap_free_tstamp_types as well.
 627         #
 628         AC_CHECK_FUNCS(pcap_set_tstamp_type)
 629         #
 630         # And do we have pcap_set_tstamp_precision?  If so, we assume
 631         # we also have pcap_open_offline_with_tstamp_precision.
 632         #
 633         AC_CHECK_FUNCS(pcap_set_tstamp_precision)
 634 fi
 635
 636 #
 637 # Check for a miscellaneous collection of functions which we use
 638 # if we have them.
 639 #
 640 AC_CHECK_FUNCS(pcap_findalldevs)
 641 if test $ac_cv_func_pcap_findalldevs = "yes" ; then
 642 dnl Check for libpcap having pcap_findalldevs() but the pcap.h header
 643 dnl not having pcap_if_t; some versions of Mac OS X shipped with pcap.h
 644 dnl from 0.6 and libpcap 0.8, so that libpcap had pcap_findalldevs but
 645 dnl pcap.h didn't have pcap_if_t.
 646     savedcppflags="$CPPFLAGS"
 647     CPPFLAGS="$CPPFLAGS $V_INCLS"
 648     AC_CHECK_TYPES(pcap_if_t, , , [#include <pcap.h>])
 649     CPPFLAGS="$savedcppflags"
 650 fi
 651 AC_CHECK_FUNCS(pcap_dump_flush pcap_lib_version)
 652 if test $ac_cv_func_pcap_lib_version = "no" ; then
 653     AC_MSG_CHECKING(whether pcap_version is defined by libpcap)
 654     AC_TRY_LINK([],
 655        [
 656         extern char pcap_version[];
 657
 658         return (int)pcap_version;
 659        ],
 660        ac_lbl_cv_pcap_version_defined=yes,
 661        ac_lbl_cv_pcap_version_defined=no)
 662     if test "$ac_lbl_cv_pcap_version_defined" = yes ; then
 663         AC_MSG_RESULT(yes)
 664         AC_DEFINE(HAVE_PCAP_VERSION, 1, [define if libpcap has pcap_version])
 665     else
 666         AC_MSG_RESULT(no)
 667     fi
 668 fi
 669 AC_CHECK_FUNCS(pcap_setdirection pcap_set_immediate_mode pcap_dump_ftell64)
 670 AC_CHECK_FUNCS(pcap_open pcap_findalldevs_ex)
 671
 672 #
 673 # Check for special debugging functions
 674 #
 675 AC_CHECK_FUNCS(pcap_set_parser_debug)
 676 if test "$ac_cv_func_pcap_set_parser_debug" = "no" ; then
 677         #
 678         # OK, we don't have pcap_set_parser_debug() to set the libpcap
 679         # filter expression parser debug flag; can we directly set the
 680         # flag?
 681         AC_MSG_CHECKING(whether pcap_debug is defined by libpcap)
 682         AC_TRY_LINK([],
 683            [
 684                 extern int pcap_debug;
 685
 686                 return pcap_debug;
 687            ],
 688            ac_lbl_cv_pcap_debug_defined=yes,
 689            ac_lbl_cv_pcap_debug_defined=no)
 690         if test "$ac_lbl_cv_pcap_debug_defined" = yes ; then
 691                 AC_MSG_RESULT(yes)
 692                 AC_DEFINE(HAVE_PCAP_DEBUG, 1, [define if libpcap has pcap_debug])
 693         else
 694                 AC_MSG_RESULT(no)
 695                 #
 696                 # OK, what about "yydebug"?
 697                 #
 698                 AC_MSG_CHECKING(whether yydebug is defined by libpcap)
 699                 AC_TRY_LINK([],
 700                    [
 701                         extern int yydebug;
 702
 703                         return yydebug;
 704                    ],
 705                    ac_lbl_cv_yydebug_defined=yes,
 706                    ac_lbl_cv_yydebug_defined=no)
 707                 if test "$ac_lbl_cv_yydebug_defined" = yes ; then
 708                         AC_MSG_RESULT(yes)
 709                         AC_DEFINE(HAVE_YYDEBUG, 1, [define if libpcap has yydebug])
 710                 else
 711                         AC_MSG_RESULT(no)
 712                 fi
 713         fi
 714 fi
 715 AC_CHECK_FUNCS(pcap_set_optimizer_debug)
 716 AC_REPLACE_FUNCS(bpf_dump)      dnl moved to libpcap in 0.6
 717
 718 V_GROUP=0
 719 if test -f /etc/group -a ! -z "`grep '^wheel:' /etc/group`" ; then
 720         V_GROUP=wheel
 721 fi
 722 #
 723 # Assume V7/BSD convention for man pages (file formats in section 5,
 724 # miscellaneous info in section 7).
 725 #
 726 MAN_FILE_FORMATS=5
 727 MAN_MISC_INFO=7
 728 case "$host_os" in
 729
 730 aix*)
 731         dnl Workaround to enable certain features
 732         AC_DEFINE(_SUN,1,[define on AIX to get certain functions])
 733         ;;
 734
 735 hpux*)
 736         #
 737         # Use System V conventions for man pages.
 738         #
 739         MAN_FILE_FORMATS=4
 740         MAN_MISC_INFO=5
 741         ;;
 742
 743 irix*)
 744         V_GROUP=sys
 745
 746         #
 747         # Use System V conventions for man pages.
 748         #
 749         MAN_FILE_FORMATS=4
 750         MAN_MISC_INFO=5
 751         ;;
 752
 753 osf*)
 754         V_GROUP=system
 755
 756         #
 757         # Use System V conventions for man pages.
 758         #
 759         MAN_FILE_FORMATS=4
 760         MAN_MISC_INFO=5
 761         ;;
 762
 763 solaris*)
 764         V_GROUP=sys
 765
 766         #
 767         # Use System V conventions for man pages.
 768         #
 769         MAN_FILE_FORMATS=4
 770         MAN_MISC_INFO=5
 771         ;;
 772 esac
 773
 774 if test -f /dev/bpf0 ; then
 775         V_GROUP=bpf
 776 fi
 777
 778 #
 779 # Make sure we have a definition for C99's uintptr_t (regardless of
 780 # whether the environment is a C99 environment or not).
 781 #
 782 AC_TYPE_UINTPTR_T
 783
 784 #
 785 # Check whether we have pcap/pcap-inttypes.h.
 786 # If we do, we use that to get the C99 types defined.
 787 #
 788 savedcppflags="$CPPFLAGS"
 789 CPPFLAGS="$CPPFLAGS $V_INCLS"
 790 AC_CHECK_HEADERS(pcap/pcap-inttypes.h)
 791 CPPFLAGS="$savedcppflags"
 792
 793 #
 794 # Define the old BSD specified-width types in terms of the C99 types;
 795 # we may need them with libpcap include files.
 796 #
 797 AC_CHECK_TYPE([u_int8_t], ,
 798         [AC_DEFINE([u_int8_t], [uint8_t],
 799         [Define to `uint8_t' if u_int8_t not defined.])],
 800         [AC_INCLUDES_DEFAULT
 801 #include <sys/types.h>
 802 ])
 803 AC_CHECK_TYPE([u_int16_t], ,
 804         [AC_DEFINE([u_int16_t], [uint16_t],
 805         [Define to `uint16_t' if u_int16_t not defined.])],
 806         [AC_INCLUDES_DEFAULT
 807 #include <sys/types.h>
 808 ])
 809 AC_CHECK_TYPE([u_int32_t], ,
 810         [AC_DEFINE([u_int32_t], [uint32_t],
 811         [Define to `uint32_t' if u_int32_t not defined.])],
 812         [AC_INCLUDES_DEFAULT
 813 #include <sys/types.h>
 814 ])
 815 AC_CHECK_TYPE([u_int64_t], ,
 816         [AC_DEFINE([u_int64_t], [uint64_t],
 817         [Define to `uint64_t' if u_int64_t not defined.])],
 818         [AC_INCLUDES_DEFAULT
 819 #include <sys/types.h>
 820 ])
 821
 822 #
 823 # Check for some headers introduced in later versions of libpcap
 824 # and used by some printers.
 825 #
 826 # Those headers might use the {u_}intN_t types, so we must do this
 827 # after we check for what's needed to get them defined.
 828 #
 829 savedcppflags="$CPPFLAGS"
 830 CPPFLAGS="$CPPFLAGS $V_INCLS"
 831 AC_CHECK_HEADERS(pcap/bluetooth.h,,,[#include "netdissect-stdinc.h"])
 832 AC_CHECK_HEADERS(pcap/nflog.h,,,[#include "netdissect-stdinc.h"])
 833 CPPFLAGS="$savedcppflags"
 834
 835 AC_PROG_RANLIB
 836 AC_CHECK_TOOL([AR], [ar])
 837
 838 AC_LBL_DEVEL(V_CCOPT)
 839
 840 # Check for OpenSSL/libressl libcrypto
 841 AC_MSG_CHECKING(whether to use OpenSSL/libressl libcrypto)
 842 # Specify location for both includes and libraries.
 843 want_libcrypto=ifavailable
 844 AC_ARG_WITH(crypto,
 845     AS_HELP_STRING([--with-crypto]@<:@=DIR@:>@,
 846                    [use OpenSSL/libressl libcrypto (located in directory DIR, if specified) @<:@default=yes, if available@:>@]),
 847 [
 848         if test $withval = no
 849         then
 850                 # User doesn't want to link with libcrypto.
 851                 want_libcrypto=no
 852                 AC_MSG_RESULT(no)
 853         elif test $withval = yes
 854         then
 855                 # User wants to link with libcrypto but hasn't specified
 856                 # a directory.
 857                 want_libcrypto=yes
 858                 AC_MSG_RESULT(yes)
 859         else
 860                 # User wants to link with libcrypto and has specified
 861                 # a directory, so use the provided value.
 862                 want_libcrypto=yes
 863                 libcrypto_root=$withval
 864                 AC_MSG_RESULT([yes, using the version installed in $withval])
 865
 866                 #
 867                 # Put the subdirectories of the libcrypto root directory
 868                 # at the front of the header and library search path.
 869                 #
 870                 CFLAGS="-I$withval/include $CFLAGS"
 871                 LIBS="-L$withval/lib $LIBS"
 872         fi
 873 ],[
 874         #
 875         # Use libcrypto if it's present, otherwise don't; no directory
 876         # was specified.
 877         #
 878         want_libcrypto=ifavailable
 879         AC_MSG_RESULT([yes, if available])
 880 ])
 881 if test "$want_libcrypto" != "no"; then
 882         #
 883         # Don't check for libcrypto unless we have its headers;
 884         # Apple, bless their pointy little heads, apparently ship
 885         # libcrypto as a library, but not the header files, in
 886         # El Capitan, probably because they don't want you writing
 887         # nasty portable code that could run on other UN*Xes, they
 888         # want you writing code that uses their Shiny New Crypto
 889         # Library and that only runs on macOS.
 890         #
 891         AC_CHECK_HEADER(openssl/crypto.h,
 892         [
 893                 AC_CHECK_LIB(crypto, DES_cbc_encrypt)
 894                 if test "$ac_cv_lib_crypto_DES_cbc_encrypt" = "yes"; then
 895                         AC_CHECK_HEADERS(openssl/evp.h)
 896                         #
 897                         # OK, then:
 898                         #
 899                         # 1) do we have EVP_CIPHER_CTX_new?
 900                         # If so, we use it to allocate an
 901                         # EVP_CIPHER_CTX, as EVP_CIPHER_CTX may be
 902                         # opaque; otherwise, we allocate it ourselves.
 903                         #
 904                         # 2) do we have EVP_CipherInit_ex()?
 905                         # If so, we use it, because we need to be
 906                         # able to make two "initialize the cipher"
 907                         # calls, one with the cipher and key, and
 908                         # one with the IV, and, as of OpenSSL 1.1,
 909                         # You Can't Do That with EVP_CipherInit(),
 910                         # because a call to EVP_CipherInit() will
 911                         # unconditionally clear the context, and
 912                         # if you don't supply a cipher, it'll
 913                         # clear the cipher, rendering the context
 914                         # unusable and causing a crash.
 915                         #
 916                         AC_CHECK_FUNCS(EVP_CIPHER_CTX_new EVP_CipherInit_ex)
 917                 fi
 918         ])
 919 fi
 920
 921 # Check for libcap-ng
 922 AC_MSG_CHECKING(whether to use libcap-ng)
 923 # Specify location for both includes and libraries.
 924 want_libcap_ng=ifavailable
 925 AC_ARG_WITH(cap_ng,
 926     AS_HELP_STRING([--with-cap-ng],
 927                    [use libcap-ng @<:@default=yes, if available@:>@]),
 928 [
 929         if test $withval = no
 930         then
 931                 want_libcap_ng=no
 932                 AC_MSG_RESULT(no)
 933         elif test $withval = yes
 934         then
 935                 want_libcap_ng=yes
 936                 AC_MSG_RESULT(yes)
 937         fi
 938 ],[
 939         #
 940         # Use libcap-ng if it's present, otherwise don't.
 941         #
 942         want_libcap_ng=ifavailable
 943         AC_MSG_RESULT([yes, if available])
 944 ])
 945 if test "$want_libcap_ng" != "no"; then
 946         AC_CHECK_LIB(cap-ng, capng_change_id)
 947         AC_CHECK_HEADERS(cap-ng.h)
 948 fi
 949
 950 dnl
 951 dnl set additional include path if necessary
 952 if test "$missing_includes" = "yes"; then
 953         CPPFLAGS="$CPPFLAGS -I$srcdir/missing"
 954         V_INCLS="$V_INCLS -I$srcdir/missing"
 955 fi
 956
 957 AC_SUBST(V_CCOPT)
 958 AC_SUBST(V_DEFS)
 959 AC_SUBST(V_GROUP)
 960 AC_SUBST(V_INCLS)
 961 AC_SUBST(V_PCAPDEP)
 962 AC_SUBST(LOCALSRC)
 963 AC_SUBST(MAN_FILE_FORMATS)
 964 AC_SUBST(MAN_MISC_INFO)
 965
 966 AC_PROG_INSTALL
 967
 968 AC_CONFIG_HEADER(config.h)
 969
 970 AC_OUTPUT_COMMANDS([if test -f .devel; then
 971         echo timestamp > stamp-h
 972         cat Makefile-devel-adds >> Makefile
 973         make depend
 974 fi])
 975 AC_OUTPUT(Makefile tcpdump.1)
 976 exit 0