The Tcpdump Group git mirrors - tcpdump/blob - configure.ac

   1 dnl Copyright (c) 1994, 1995, 1996, 1997
   2 dnl     The Regents of the University of California.  All rights reserved.
   3 dnl
   4 dnl Process this file with autoconf to produce a configure script.
   5 dnl
   6
   7 #
   8 # See
   9 #
  10 #       http://ftp.gnu.org/gnu/config/README
  11 #
  12 # for the URLs to use to fetch new versions of config.guess and
  13 # config.sub.
  14 #
  15
  16 AC_PREREQ(2.64)
  17 AC_INIT(tcpdump, m4_esyscmd_s([cat VERSION]))
  18 AC_CONFIG_SRCDIR(tcpdump.c)
  19
  20 AC_CANONICAL_HOST
  21
  22 AC_LBL_C_INIT_BEFORE_CC(V_INCLS)
  23 #
  24 # Try to enable as many C99 features as we can.
  25 # At minimum, we want C++/C99-style // comments.
  26 #
  27 AC_PROG_CC_C99
  28 if test "$ac_cv_prog_cc_c99" = "no"; then
  29         AC_MSG_WARN([The C compiler does not support C99; there may be compiler errors])
  30 fi
  31 AC_LBL_C_INIT(V_CCOPT, V_INCLS)
  32 AC_LBL_C_INLINE
  33
  34 AC_CHECK_HEADERS(fcntl.h rpc/rpc.h rpc/rpcent.h net/if.h)
  35 AC_CHECK_HEADERS(net/pfvar.h, , , [#include <sys/types.h>
  36 #include <sys/socket.h>
  37 #include <net/if.h>])
  38 if test "$ac_cv_header_net_pfvar_h" = yes; then
  39         AC_CHECK_HEADERS(net/if_pflog.h, , , [#include <sys/types.h>
  40         #include <sys/socket.h>
  41         #include <net/if.h>
  42         #include <net/pfvar.h>])
  43         if test "$ac_cv_header_net_if_pflog_h" = yes; then
  44                 LOCALSRC="print-pflog.c $LOCALSRC"
  45         fi
  46 fi
  47
  48 case "$host_os" in
  49
  50 darwin*)
  51         AC_ARG_ENABLE(universal,
  52         AC_HELP_STRING([--disable-universal],[don't build universal on macOS]))
  53         if test "$enable_universal" != "no"; then
  54                 case "$host_os" in
  55
  56                 darwin9.*)
  57                         #
  58                         # Leopard.  Build for x86 and 32-bit PowerPC, with
  59                         # x86 first.  (That's what Apple does.)
  60                         #
  61                         V_CCOPT="$V_CCOPT -arch i386 -arch ppc"
  62                         LDFLAGS="$LDFLAGS -arch i386 -arch ppc"
  63                         ;;
  64
  65                 darwin10.*)
  66                         #
  67                         # Snow Leopard.  Build for x86-64 and x86, with
  68                         # x86-64 first.  (That's what Apple does.)
  69                         #
  70                         V_CCOPT="$V_CCOPT -arch x86_64 -arch i386"
  71                         LDFLAGS="$LDFLAGS -arch x86_64 -arch i386"
  72                         ;;
  73                 esac
  74         fi
  75         ;;
  76 esac
  77
  78
  79 AC_ARG_WITH(smi,
  80 [  --with-smi              link with libsmi (allows to load MIBs on the fly to decode SNMP packets. [default=yes]
  81   --without-smi           don't link with libsmi],,
  82    with_smi=yes)
  83
  84 if test "x$with_smi" != "xno" ; then
  85         AC_CHECK_HEADER(smi.h,
  86         [
  87                 #
  88                 # OK, we found smi.h.  Do we have libsmi with smiInit?
  89                 #
  90                 AC_CHECK_LIB(smi, smiInit,
  91                 [
  92                         #
  93                         # OK, we have libsmi with smiInit.  Can we use it?
  94                         #
  95                         AC_MSG_CHECKING([whether to enable libsmi])
  96                         savedlibs="$LIBS"
  97                         LIBS="-lsmi $LIBS"
  98                         AC_TRY_RUN(
  99                                 [
 100 /* libsmi available check */
 101 #include <smi.h>
 102 main()
 103 {
 104   int current, revision, age, n;
 105   const int required = 2;
 106   if (smiInit(""))
 107     exit(1);
 108   if (strcmp(SMI_LIBRARY_VERSION, smi_library_version))
 109     exit(2);
 110   n = sscanf(smi_library_version, "%d:%d:%d", &current, &revision, &age);
 111   if (n != 3)
 112     exit(3);
 113   if (required < current - age || required > current)
 114     exit(4);
 115   exit(0);
 116 }
 117                                 ],
 118                                 [
 119                                         AC_MSG_RESULT(yes)
 120                                         AC_DEFINE(USE_LIBSMI, 1,
 121                                             [Define if you enable support for libsmi])
 122                                 ],
 123                                 [
 124                                         dnl autoconf documentation says that
 125                                         dnl $? contains the exit value.
 126                                         dnl reality is that it does not.
 127                                         dnl We leave this in just in case
 128                                         dnl autoconf ever comes back to
 129                                         dnl match the documentation.
 130                                         case $? in
 131                                           1) AC_MSG_RESULT(no - smiInit failed) ;;
 132                                           2) AC_MSG_RESULT(no - header/library version mismatch) ;;
 133                                           3) AC_MSG_RESULT(no - can't determine library version) ;;
 134                                           4) AC_MSG_RESULT(no - too old) ;;
 135                                           *) AC_MSG_RESULT(no) ;;
 136                                         esac
 137                                         LIBS="$savedlibs"
 138                                 ],
 139                                 [
 140                                         AC_MSG_RESULT(not when cross-compiling)
 141                                         LIBS="$savedlibs"
 142                                 ]
 143                         )
 144                 ])
 145         ])
 146 fi
 147
 148 AC_MSG_CHECKING([whether to enable the possibly-buggy SMB printer])
 149 AC_ARG_ENABLE(smb,
 150 [  --enable-smb            enable possibly-buggy SMB printer [default=yes]
 151   --disable-smb           disable possibly-buggy SMB printer],,
 152    enableval=yes)
 153 case "$enableval" in
 154 yes)    AC_MSG_RESULT(yes)
 155         AC_DEFINE(ENABLE_SMB, 1,
 156             [define if you want to build the possibly-buggy SMB printer])
 157         LOCALSRC="print-smb.c smbutil.c $LOCALSRC"
 158         ;;
 159 *)      AC_MSG_RESULT(no)
 160         ;;
 161 esac
 162
 163 AC_ARG_WITH(user, [  --with-user=USERNAME    drop privileges by default to USERNAME])
 164 AC_MSG_CHECKING([whether to drop root privileges by default])
 165 if test ! -z "$with_user" ; then
 166        AC_DEFINE_UNQUOTED(WITH_USER, "$withval",
 167            [define if should drop privileges by default])
 168        AC_MSG_RESULT(to \"$withval\")
 169 else
 170        AC_MSG_RESULT(no)
 171 fi
 172
 173 AC_ARG_WITH(chroot, [  --with-chroot=DIRECTORY when dropping privileges, chroot to DIRECTORY])
 174 AC_MSG_CHECKING([whether to chroot])
 175 if test ! -z "$with_chroot" && test "$with_chroot" != "no" ; then
 176        AC_DEFINE_UNQUOTED(WITH_CHROOT, "$withval",
 177            [define if should chroot when dropping privileges])
 178        AC_MSG_RESULT(to \"$withval\")
 179 else
 180        AC_MSG_RESULT(no)
 181 fi
 182
 183 AC_ARG_WITH(sandbox-capsicum,
 184         AS_HELP_STRING([--with-sandbox-capsicum],
 185                        [use Capsicum security functions @<:@default=yes, if available@:>@]))
 186 #
 187 # Check whether various functions are available.  If any are, set
 188 # ac_lbl_capsicum_function_seen to yes; if any are not, set
 189 # ac_lbl_capsicum_function_not_seen to yes.
 190 #
 191 # We don't check cap_rights_init(), as it's a macro, wrapping another
 192 # function, in at least some versions of FreeBSD, and AC_CHECK_FUNCS()
 193 # doesn't handle that.
 194 #
 195 # All of the ones we check for must be available in order to enable
 196 # capsicum sandboxing.
 197 #
 198 # XXX - do we need to check for all of them, or are there some that, if
 199 # present, imply others are present?
 200 #
 201 if test ! -z "$with_sandbox-capsicum" && test "$with_sandbox-capsicum" != "no" ; then
 202         #
 203         # First, make sure we have the required header.
 204         #
 205         AC_CHECK_HEADER(sys/capsicum.h,
 206         [
 207                 #
 208                 # We do; now make sure we have the required functions.
 209                 #
 210                 AC_CHECK_FUNCS(cap_enter cap_rights_limit cap_ioctls_limit openat,
 211                     ac_lbl_capsicum_function_seen=yes,
 212                     ac_lbl_capsicum_function_not_seen=yes)
 213         ])
 214         AC_CHECK_LIB(casper, cap_init, LIBS="$LIBS -lcasper")
 215         AC_CHECK_LIB(cap_dns, cap_gethostbyaddr, LIBS="$LIBS -lcap_dns")
 216 fi
 217 AC_MSG_CHECKING([whether to sandbox using capsicum])
 218 if test "x$ac_lbl_capsicum_function_seen" = "xyes" -a "x$ac_lbl_capsicum_function_not_seen" != "xyes"; then
 219         AC_DEFINE(HAVE_CAPSICUM, 1, [capsicum support available])
 220         AC_MSG_RESULT(yes)
 221 else
 222         AC_MSG_RESULT(no)
 223 fi
 224 AC_MSG_CHECKING([whether to sandbox using Casper library])
 225 if test "x$ac_cv_lib_casper_cap_init" = "xyes" -a "x$ac_cv_lib_cap_dns_cap_gethostbyaddr" = "xyes"; then
 226         AC_DEFINE(HAVE_CASPER, 1, [Casper support available])
 227         AC_MSG_RESULT(yes)
 228 else
 229         AC_MSG_RESULT(no)
 230 fi
 231
 232 #
 233 # We must check this before checking whether to check the OS's IPv6,
 234 # support because, on some platforms (such as SunOS 5.x), the test
 235 # program requires the extra networking libraries.
 236 #
 237 AC_LBL_LIBRARY_NET
 238
 239 #
 240 # Check whether AF_INET6 and struct in6_addr are defined.
 241 # If they aren't both defined, we don't have sufficient OS
 242 # support for IPv6, so we don't look for IPv6 support libraries,
 243 # and we define AF_INET6 and struct in6_addr ourselves.
 244 #
 245 AC_MSG_CHECKING([whether the operating system supports IPv6])
 246 AC_COMPILE_IFELSE(
 247     [
 248       AC_LANG_SOURCE(
 249         [[
 250 /* AF_INET6 available check */
 251 #include <sys/types.h>
 252 #ifdef _WIN32
 253 #include <ws2tcpip.h>
 254 #else
 255 #include <sys/socket.h>
 256 #include <netinet/in.h>
 257 #endif
 258 #ifdef AF_INET6
 259 void
 260 foo(struct in6_addr *addr)
 261 {
 262  memset(addr, 0, sizeof (struct in6_addr));
 263 }
 264 #else
 265 #error "AF_INET6 not defined"
 266 #endif
 267         ]])
 268     ],
 269     [
 270         AC_MSG_RESULT(yes)
 271         AC_DEFINE(HAVE_OS_IPV6_SUPPORT, 1,
 272             [define if the OS provides AF_INET6 and struct in6_addr])
 273         ipv6=yes
 274     ],
 275     [
 276         AC_MSG_RESULT(no)
 277         ipv6=no
 278     ]
 279 )
 280
 281 ipv6type=unknown
 282 ipv6lib=none
 283 ipv6trylibc=no
 284
 285 if test "$ipv6" = "yes"; then
 286         AC_MSG_CHECKING([ipv6 stack type])
 287         for i in inria kame linux-glibc linux-libinet6 toshiba v6d zeta; do
 288                 case $i in
 289                 inria)
 290                         dnl http://www.kame.net/
 291                         AC_EGREP_CPP(yes,
 292 [#include <netinet/in.h>
 293 #ifdef IPV6_INRIA_VERSION
 294 yes
 295 #endif],
 296                                 [ipv6type=$i])
 297                         ;;
 298                 kame)
 299                         dnl http://www.kame.net/
 300                         AC_EGREP_CPP(yes,
 301 [#include <netinet/in.h>
 302 #ifdef __KAME__
 303 yes
 304 #endif],
 305                                 [ipv6type=$i;
 306                                 ipv6lib=inet6;
 307                                 ipv6libdir=/usr/local/v6/lib;
 308                                 ipv6trylibc=yes])
 309                         ;;
 310                 linux-glibc)
 311                         dnl http://www.v6.linux.or.jp/
 312                         AC_EGREP_CPP(yes,
 313 [#include <features.h>
 314 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 315 yes
 316 #endif],
 317                                 [ipv6type=$i])
 318                         ;;
 319                 linux-libinet6)
 320                         dnl http://www.v6.linux.or.jp/
 321                         dnl
 322                         dnl This also matches Solaris 8 and Tru64 UNIX 5.1,
 323                         dnl and possibly other versions of those OSes
 324                         dnl
 325                         if test -d /usr/inet6 -o -f /usr/include/netinet/ip6.h; then
 326                                 ipv6type=$i
 327                                 ipv6lib=inet6
 328                                 ipv6libdir=/usr/inet6/lib
 329                                 ipv6trylibc=yes;
 330                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 331                         fi
 332                         ;;
 333                 toshiba)
 334                         AC_EGREP_CPP(yes,
 335 [#include <sys/param.h>
 336 #ifdef _TOSHIBA_INET6
 337 yes
 338 #endif],
 339                                 [ipv6type=$i;
 340                                 ipv6lib=inet6;
 341                                 ipv6libdir=/usr/local/v6/lib])
 342                         ;;
 343                 v6d)
 344                         AC_EGREP_CPP(yes,
 345 [#include </usr/local/v6/include/sys/v6config.h>
 346 #ifdef __V6D__
 347 yes
 348 #endif],
 349                                 [ipv6type=$i;
 350                                 ipv6lib=v6;
 351                                 ipv6libdir=/usr/local/v6/lib;
 352                                 CFLAGS="-I/usr/local/v6/include $CFLAGS"])
 353                         ;;
 354                 zeta)
 355                         AC_EGREP_CPP(yes,
 356 [#include <sys/param.h>
 357 #ifdef _ZETA_MINAMI_INET6
 358 yes
 359 #endif],
 360                                 [ipv6type=$i;
 361                                 ipv6lib=inet6;
 362                                 ipv6libdir=/usr/local/v6/lib])
 363                         ;;
 364                 esac
 365                 if test "$ipv6type" != "unknown"; then
 366                         break
 367                 fi
 368         done
 369         AC_MSG_RESULT($ipv6type)
 370 fi
 371
 372 if test "$ipv6" = "yes" -a "$ipv6lib" != "none"; then
 373         if test -d $ipv6libdir -a -f $ipv6libdir/lib$ipv6lib.a; then
 374                 LIBS="-L$ipv6libdir -l$ipv6lib $LIBS"
 375                 echo "You have $ipv6lib library, using it"
 376         else
 377                 if test "$ipv6trylibc" = "yes"; then
 378                         echo "You do not have $ipv6lib library, using libc"
 379                 else
 380                         echo 'Fatal: no $ipv6lib library found.  cannot continue.'
 381                         echo "You need to fetch lib$ipv6lib.a from appropriate"
 382                         echo 'ipv6 kit and compile beforehand.'
 383                         exit 1
 384                 fi
 385         fi
 386 fi
 387
 388 AC_SEARCH_LIBS(dnet_htoa, dnet,
 389 [
 390         AC_DEFINE(HAVE_DNET_HTOA, 1,
 391             [define if you have the dnet_htoa function])
 392         #
 393         # OK, we have dnet_htoa().  Do we have netdnet/dnetdb.h?
 394         #
 395         AC_CHECK_HEADERS(netdnet/dnetdb.h)
 396         if test "$ac_cv_header_netdnet_dnetdb_h" = "yes"; then
 397                 #
 398                 # Yes.  Does it declare dnet_htoa()?
 399                 #
 400                 AC_CHECK_DECL(dnet_htoa,
 401                 [
 402                         # Yes.
 403                         AC_DEFINE(NETDNET_DNETDB_H_DECLARES_DNET_HTOA,,
 404                             [Define to 1 if netenet/dnetdb.h declares `dnet_htoa'])
 405                 ],,
 406                 [
 407 AC_INCLUDES_DEFAULT
 408 #include <netdnet/dnetdb.h>
 409                 ])
 410         fi
 411
 412         #
 413         # Do we have netdnet/dn.h?
 414         #
 415         AC_CHECK_HEADERS(netdnet/dn.h)
 416         if test "$ac_cv_header_netdnet_dn_h" = "yes"; then
 417                 #
 418                 # Yes.  Does it declare struct dn_naddr?
 419                 #
 420                 AC_CHECK_TYPES(struct dn_naddr,,,
 421                 [
 422 #include <netdnet/dn.h>
 423                 ])
 424         fi
 425 ])
 426
 427 AC_REPLACE_FUNCS(strlcat strlcpy strdup strsep getservent getopt_long)
 428 AC_CHECK_FUNCS(fork vfork strftime)
 429 AC_CHECK_FUNCS(setlinebuf)
 430
 431 needsnprintf=no
 432 AC_CHECK_FUNCS(vsnprintf snprintf,,
 433         [needsnprintf=yes])
 434 if test $needsnprintf = yes; then
 435         AC_LIBOBJ(snprintf)
 436 fi
 437
 438 AC_CHECK_LIB(rpc, main)         dnl It's unclear why we might need -lrpc
 439
 440 dnl Some platforms may need -lnsl for getrpcbynumber.
 441 AC_SEARCH_LIBS(getrpcbynumber, nsl,
 442     AC_DEFINE(HAVE_GETRPCBYNUMBER, 1, [define if you have getrpcbynumber()]))
 443
 444 AC_LBL_LIBPCAP(V_PCAPDEP, V_INCLS)
 445
 446 #
 447 # Check for these after AC_LBL_LIBPCAP, so we link with the appropriate
 448 # libraries (e.g., "-lsocket -lnsl" on Solaris).
 449 #
 450 # You are in a twisty little maze of UN*Xes, all different.
 451 # Some might not have ether_ntohost().
 452 # Some might have it and declare it in <net/ethernet.h>.
 453 # Some might have it and declare it in <netinet/ether.h>
 454 # Some might have it and declare it in <sys/ethernet.h>.
 455 # Some might have it and declare it in <arpa/inet.h>.
 456 # Some might have it and declare it in <netinet/if_ether.h>.
 457 # Some might have it and not declare it in any header file.
 458 #
 459 # Before you is a C compiler.
 460 #
 461 AC_CHECK_FUNCS(ether_ntohost, [
 462     AC_CACHE_CHECK(for buggy ether_ntohost, ac_cv_buggy_ether_ntohost, [
 463         AC_TRY_RUN([
 464                 #include <netdb.h>
 465                 #include <sys/types.h>
 466                 #include <sys/param.h>
 467                 #include <sys/socket.h>
 468
 469                 int
 470                 main(int argc, char **argv)
 471                 {
 472                         u_char ea[6] = { 0xff, 0xff, 0xff, 0xff, 0xff };
 473                         char name[MAXHOSTNAMELEN];
 474
 475                         ether_ntohost(name, (struct ether_addr *)ea);
 476                         exit(0);
 477                 }
 478         ], [ac_cv_buggy_ether_ntohost=no],
 479            [ac_cv_buggy_ether_ntohost=yes],
 480            [ac_cv_buggy_ether_ntohost="not while cross-compiling"])])
 481     if test "$ac_cv_buggy_ether_ntohost" = "no"; then
 482         AC_DEFINE(USE_ETHER_NTOHOST, 1,
 483             [define if you have ether_ntohost() and it works])
 484     fi
 485 ])
 486 if test "$ac_cv_func_ether_ntohost" = yes -a \
 487     "$ac_cv_buggy_ether_ntohost" = "no"; then
 488         #
 489         # OK, we have ether_ntohost().  Is it declared in <net/ethernet.h>?
 490         #
 491         # This test fails if we don't have <net/ethernet.h> or if we do
 492         # but it doesn't declare ether_ntohost().
 493         #
 494         AC_CHECK_DECL(ether_ntohost,
 495             [
 496                 AC_DEFINE(NET_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
 497                     [Define to 1 if net/ethernet.h declares `ether_ntohost'])
 498             ],,
 499             [
 500 #include <net/ethernet.h>
 501             ])
 502         #
 503         # Did that succeed?
 504         #
 505         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 506                 #
 507                 # No, how about <netinet/ether.h>, as on Linux?
 508                 #
 509                 # This test fails if we don't have <netinet/ether.h>
 510                 # or if we do but it doesn't declare ether_ntohost().
 511                 #
 512                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 513                 # treat the previous failure as a cached value and
 514                 # suppress the next test.
 515                 #
 516                 unset ac_cv_have_decl_ether_ntohost
 517                 AC_CHECK_DECL(ether_ntohost,
 518                     [
 519                         AC_DEFINE(NETINET_ETHER_H_DECLARES_ETHER_NTOHOST,,
 520                             [Define to 1 if netinet/ether.h declares `ether_ntohost'])
 521                     ],,
 522                     [
 523 #include <netinet/ether.h>
 524                     ])
 525         fi
 526         #
 527         # Did that succeed?
 528         #
 529         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 530                 #
 531                 # No, how about <sys/ethernet.h>, as on Solaris 10
 532                 # and later?
 533                 #
 534                 # This test fails if we don't have <sys/ethernet.h>
 535                 # or if we do but it doesn't declare ether_ntohost().
 536                 #
 537                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 538                 # treat the previous failure as a cached value and
 539                 # suppress the next test.
 540                 #
 541                 unset ac_cv_have_decl_ether_ntohost
 542                 AC_CHECK_DECL(ether_ntohost,
 543                     [
 544                         AC_DEFINE(SYS_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
 545                             [Define to 1 if sys/ethernet.h declares `ether_ntohost'])
 546                     ],,
 547                     [
 548 #include <sys/ethernet.h>
 549                     ])
 550         fi
 551         #
 552         # Did that succeed?
 553         #
 554         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 555                 #
 556                 # No, how about <arpa/inet.h>, as in AIX?
 557                 #
 558                 # This test fails if we don't have <arpa/inet.h>
 559                 # (if we have ether_ntohost(), we should have
 560                 # networking, and if we have networking, we should
 561                 # have <arpa/inet.h>) or if we do but it doesn't
 562                 # declare ether_ntohost().
 563                 #
 564                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 565                 # treat the previous failure as a cached value and
 566                 # suppress the next test.
 567                 #
 568                 unset ac_cv_have_decl_ether_ntohost
 569                 AC_CHECK_DECL(ether_ntohost,
 570                     [
 571                         AC_DEFINE(ARPA_INET_H_DECLARES_ETHER_NTOHOST,,
 572                             [Define to 1 if arpa/inet.h declares `ether_ntohost'])
 573                     ],,
 574                     [
 575 #include <arpa/inet.h>
 576                     ])
 577         fi
 578         #
 579         # Did that succeed?
 580         #
 581         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 582                 #
 583                 # No, how about <netinet/if_ether.h>?
 584                 # On some platforms, it requires <net/if.h> and
 585                 # <netinet/in.h>, and we always include it with
 586                 # both of them, so test it with both of them.
 587                 #
 588                 # This test fails if we don't have <netinet/if_ether.h>
 589                 # and the headers we include before it, or if we do but
 590                 # <netinet/if_ether.h> doesn't declare ether_hostton().
 591                 #
 592                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 593                 # treat the previous failure as a cached value and
 594                 # suppress the next test.
 595                 #
 596                 unset ac_cv_have_decl_ether_ntohost
 597                 AC_CHECK_DECL(ether_ntohost,
 598                     [
 599                         AC_DEFINE(NETINET_IF_ETHER_H_DECLARES_ETHER_NTOHOST,,
 600                             [Define to 1 if netinet/if_ether.h declares `ether_ntohost'])
 601                     ],,
 602                     [
 603 #include <sys/types.h>
 604 #include <sys/socket.h>
 605 #include <net/if.h>
 606 #include <netinet/in.h>
 607 #include <netinet/if_ether.h>
 608                     ])
 609         fi
 610         #
 611         # After all that, is ether_ntohost() declared?
 612         #
 613         if test "$ac_cv_have_decl_ether_ntohost" = yes; then
 614                 #
 615                 # Yes.
 616                 #
 617                 AC_DEFINE(HAVE_DECL_ETHER_NTOHOST, 1,
 618                     [Define to 1 if you have the declaration of `ether_ntohost'])
 619         else
 620                 #
 621                 # No, we'll have to declare it ourselves.
 622                 # Do we have "struct ether_addr" if we include
 623                 # <netinet/if_ether.h>?
 624                 #
 625                 AC_CHECK_TYPES(struct ether_addr,,,
 626                     [
 627                         #include <sys/types.h>
 628                         #include <sys/socket.h>
 629                         #include <net/if.h>
 630                         #include <netinet/in.h>
 631                         #include <netinet/if_ether.h>
 632                     ])
 633         fi
 634 fi
 635
 636 dnl
 637 dnl Check for "pcap_list_datalinks()" and use a substitute version if
 638 dnl it's not present.  If it is present, check for "pcap_free_datalinks()";
 639 dnl if it's not present, we don't replace it for now.  (We could do so
 640 dnl on UN*X, but not on Windows, where hilarity ensues if a program
 641 dnl built with one version of the MSVC support library tries to free
 642 dnl something allocated by a library built with another version of
 643 dnl the MSVC support library.)
 644 dnl
 645 AC_CHECK_FUNC(pcap_list_datalinks,
 646         [
 647             AC_DEFINE(HAVE_PCAP_LIST_DATALINKS, 1,
 648                 [define if libpcap has pcap_list_datalinks()])
 649             AC_CHECK_FUNCS(pcap_free_datalinks)
 650         ],
 651         [
 652             AC_LIBOBJ(datalinks)
 653         ])
 654
 655 dnl
 656 dnl Check for "pcap_datalink_name_to_val()", and use a substitute
 657 dnl version if it's not present.  If it is present, check for
 658 dnl "pcap_datalink_val_to_description()", and if we don't have it,
 659 dnl use a substitute version.
 660 dnl
 661 AC_CHECK_FUNC(pcap_datalink_name_to_val,
 662         [
 663             AC_DEFINE(HAVE_PCAP_DATALINK_NAME_TO_VAL, 1,
 664                 [define if libpcap has pcap_datalink_name_to_val()])
 665             AC_CHECK_FUNC(pcap_datalink_val_to_description,
 666                 AC_DEFINE(HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION, 1,
 667                     [define if libpcap has pcap_datalink_val_to_description()]),
 668                 [
 669                     AC_LIBOBJ(dlnames)
 670                 ])
 671         ],
 672         [
 673             AC_LIBOBJ(dlnames)
 674         ])
 675
 676 dnl
 677 dnl Check for "pcap_set_datalink()"; you can't substitute for it if
 678 dnl it's absent (it has hooks into libpcap), so just define the
 679 dnl HAVE_ value if it's there.
 680 dnl
 681 AC_CHECK_FUNCS(pcap_set_datalink)
 682
 683 dnl
 684 dnl Check for "pcap_breakloop()"; you can't substitute for it if
 685 dnl it's absent (it has hooks into the live capture routines),
 686 dnl so just define the HAVE_ value if it's there.
 687 dnl
 688 AC_CHECK_FUNCS(pcap_breakloop)
 689
 690 #
 691 # Do we have the new open API?  Check for pcap_create, and assume that,
 692 # if we do, we also have pcap_activate() and the other new routines
 693 # introduced in libpcap 1.0.0.
 694 #
 695 AC_CHECK_FUNCS(pcap_create)
 696 if test $ac_cv_func_pcap_create = "yes" ; then
 697         #
 698         # OK, do we have pcap_set_tstamp_type?  If so, assume we have
 699         # pcap_list_tstamp_types and pcap_free_tstamp_types as well.
 700         #
 701         AC_CHECK_FUNCS(pcap_set_tstamp_type)
 702         #
 703         # And do we have pcap_set_tstamp_precision?  If so, we assume
 704         # we also have pcap_open_offline_with_tstamp_precision.
 705         #
 706         AC_CHECK_FUNCS(pcap_set_tstamp_precision)
 707 fi
 708
 709 #
 710 # Check for a miscellaneous collection of functions which we use
 711 # if we have them.
 712 #
 713 AC_CHECK_FUNCS(pcap_findalldevs)
 714 if test $ac_cv_func_pcap_findalldevs = "yes" ; then
 715 dnl Check for libpcap having pcap_findalldevs() but the pcap.h header
 716 dnl not having pcap_if_t; some versions of Mac OS X shipped with pcap.h
 717 dnl from 0.6 and libpcap 0.8, so that libpcap had pcap_findalldevs but
 718 dnl pcap.h didn't have pcap_if_t.
 719     savedcppflags="$CPPFLAGS"
 720     CPPFLAGS="$CPPFLAGS $V_INCLS"
 721     AC_CHECK_TYPES(pcap_if_t, , , [#include <pcap.h>])
 722     CPPFLAGS="$savedcppflags"
 723 fi
 724 AC_CHECK_FUNCS(pcap_dump_flush pcap_lib_version)
 725 if test $ac_cv_func_pcap_lib_version = "no" ; then
 726     AC_MSG_CHECKING(whether pcap_version is defined by libpcap)
 727     AC_TRY_LINK([],
 728        [
 729         extern char pcap_version[];
 730
 731         return (int)pcap_version;
 732        ],
 733        ac_lbl_cv_pcap_version_defined=yes,
 734        ac_lbl_cv_pcap_version_defined=no)
 735     if test "$ac_lbl_cv_pcap_version_defined" = yes ; then
 736         AC_MSG_RESULT(yes)
 737         AC_DEFINE(HAVE_PCAP_VERSION, 1, [define if libpcap has pcap_version])
 738     else
 739         AC_MSG_RESULT(no)
 740     fi
 741 fi
 742 AC_CHECK_FUNCS(pcap_setdirection pcap_set_immediate_mode pcap_dump_ftell64)
 743 AC_CHECK_FUNCS(pcap_open pcap_findalldevs_ex)
 744 AC_REPLACE_FUNCS(pcap_dump_ftell)
 745
 746 #
 747 # Check for special debugging functions
 748 #
 749 AC_CHECK_FUNCS(pcap_set_parser_debug)
 750 if test "$ac_cv_func_pcap_set_parser_debug" = "no" ; then
 751         #
 752         # OK, we don't have pcap_set_parser_debug() to set the libpcap
 753         # filter expression parser debug flag; can we directly set the
 754         # flag?
 755         AC_MSG_CHECKING(whether pcap_debug is defined by libpcap)
 756         AC_TRY_LINK([],
 757            [
 758                 extern int pcap_debug;
 759
 760                 return pcap_debug;
 761            ],
 762            ac_lbl_cv_pcap_debug_defined=yes,
 763            ac_lbl_cv_pcap_debug_defined=no)
 764         if test "$ac_lbl_cv_pcap_debug_defined" = yes ; then
 765                 AC_MSG_RESULT(yes)
 766                 AC_DEFINE(HAVE_PCAP_DEBUG, 1, [define if libpcap has pcap_debug])
 767         else
 768                 AC_MSG_RESULT(no)
 769                 #
 770                 # OK, what about "yydebug"?
 771                 #
 772                 AC_MSG_CHECKING(whether yydebug is defined by libpcap)
 773                 AC_TRY_LINK([],
 774                    [
 775                         extern int yydebug;
 776
 777                         return yydebug;
 778                    ],
 779                    ac_lbl_cv_yydebug_defined=yes,
 780                    ac_lbl_cv_yydebug_defined=no)
 781                 if test "$ac_lbl_cv_yydebug_defined" = yes ; then
 782                         AC_MSG_RESULT(yes)
 783                         AC_DEFINE(HAVE_YYDEBUG, 1, [define if libpcap has yydebug])
 784                 else
 785                         AC_MSG_RESULT(no)
 786                 fi
 787         fi
 788 fi
 789 AC_CHECK_FUNCS(pcap_set_optimizer_debug)
 790 AC_REPLACE_FUNCS(bpf_dump)      dnl moved to libpcap in 0.6
 791
 792 V_GROUP=0
 793 if test -f /etc/group -a ! -z "`grep '^wheel:' /etc/group`" ; then
 794         V_GROUP=wheel
 795 fi
 796 #
 797 # Assume V7/BSD convention for man pages (file formats in section 5,
 798 # miscellaneous info in section 7).
 799 #
 800 MAN_FILE_FORMATS=5
 801 MAN_MISC_INFO=7
 802 case "$host_os" in
 803
 804 aix*)
 805         dnl Workaround to enable certain features
 806         AC_DEFINE(_SUN,1,[define on AIX to get certain functions])
 807         ;;
 808
 809 hpux*)
 810         #
 811         # Use System V conventions for man pages.
 812         #
 813         MAN_FILE_FORMATS=4
 814         MAN_MISC_INFO=5
 815         ;;
 816
 817 irix*)
 818         V_GROUP=sys
 819
 820         #
 821         # Use System V conventions for man pages.
 822         #
 823         MAN_FILE_FORMATS=4
 824         MAN_MISC_INFO=5
 825         ;;
 826
 827 osf*)
 828         V_GROUP=system
 829
 830         #
 831         # Use System V conventions for man pages.
 832         #
 833         MAN_FILE_FORMATS=4
 834         MAN_MISC_INFO=5
 835         ;;
 836
 837 solaris*)
 838         V_GROUP=sys
 839
 840         #
 841         # Use System V conventions for man pages.
 842         #
 843         MAN_FILE_FORMATS=4
 844         MAN_MISC_INFO=5
 845         ;;
 846 esac
 847
 848 if test -f /dev/bpf0 ; then
 849         V_GROUP=bpf
 850 fi
 851
 852 #
 853 # Make sure we have a definition for C99's uintptr_t (regardless of
 854 # whether the environment is a C99 environment or not).
 855 #
 856 AC_TYPE_UINTPTR_T
 857
 858 #
 859 # Check whether we have pcap/pcap-inttypes.h.
 860 # If we do, we use that to get the C99 types defined.
 861 #
 862 savedcppflags="$CPPFLAGS"
 863 CPPFLAGS="$CPPFLAGS $V_INCLS"
 864 AC_CHECK_HEADERS(pcap/pcap-inttypes.h)
 865 CPPFLAGS="$savedcppflags"
 866
 867 #
 868 # Define the old BSD specified-width types in terms of the C99 types;
 869 # we may need them with libpcap include files.
 870 #
 871 AC_CHECK_TYPE([u_int8_t], ,
 872         [AC_DEFINE([u_int8_t], [uint8_t],
 873         [Define to `uint8_t' if u_int8_t not defined.])],
 874         [AC_INCLUDES_DEFAULT
 875 #include <sys/types.h>
 876 ])
 877 AC_CHECK_TYPE([u_int16_t], ,
 878         [AC_DEFINE([u_int16_t], [uint16_t],
 879         [Define to `uint16_t' if u_int16_t not defined.])],
 880         [AC_INCLUDES_DEFAULT
 881 #include <sys/types.h>
 882 ])
 883 AC_CHECK_TYPE([u_int32_t], ,
 884         [AC_DEFINE([u_int32_t], [uint32_t],
 885         [Define to `uint32_t' if u_int32_t not defined.])],
 886         [AC_INCLUDES_DEFAULT
 887 #include <sys/types.h>
 888 ])
 889 AC_CHECK_TYPE([u_int64_t], ,
 890         [AC_DEFINE([u_int64_t], [uint64_t],
 891         [Define to `uint64_t' if u_int64_t not defined.])],
 892         [AC_INCLUDES_DEFAULT
 893 #include <sys/types.h>
 894 ])
 895
 896 AC_PROG_RANLIB
 897 AC_CHECK_TOOL([AR], [ar])
 898
 899 AC_LBL_DEVEL(V_CCOPT)
 900
 901 # Check for OpenSSL/libressl libcrypto
 902 AC_MSG_CHECKING(whether to use OpenSSL/libressl libcrypto)
 903 # Specify location for both includes and libraries.
 904 want_libcrypto=ifavailable
 905 AC_ARG_WITH(crypto,
 906     AS_HELP_STRING([--with-crypto]@<:@=DIR@:>@,
 907                    [use OpenSSL/libressl libcrypto (located in directory DIR, if specified) @<:@default=yes, if available@:>@]),
 908 [
 909         if test $withval = no
 910         then
 911                 # User doesn't want to link with libcrypto.
 912                 want_libcrypto=no
 913                 AC_MSG_RESULT(no)
 914         elif test $withval = yes
 915         then
 916                 # User wants to link with libcrypto but hasn't specified
 917                 # a directory.
 918                 want_libcrypto=yes
 919                 AC_MSG_RESULT(yes)
 920         else
 921                 # User wants to link with libcrypto and has specified
 922                 # a directory, so use the provided value.
 923                 want_libcrypto=yes
 924                 libcrypto_root=$withval
 925                 AC_MSG_RESULT([yes, using the version installed in $withval])
 926
 927                 #
 928                 # Put the subdirectories of the libcrypto root directory
 929                 # at the front of the header and library search path.
 930                 #
 931                 CFLAGS="-I$withval/include $CFLAGS"
 932                 LIBS="-L$withval/lib $LIBS"
 933         fi
 934 ],[
 935         #
 936         # Use libcrypto if it's present, otherwise don't; no directory
 937         # was specified.
 938         #
 939         want_libcrypto=ifavailable
 940         AC_MSG_RESULT([yes, if available])
 941 ])
 942 if test "$want_libcrypto" != "no"; then
 943         #
 944         # Don't check for libcrypto unless we have its headers;
 945         # Apple, bless their pointy little heads, apparently ship
 946         # libcrypto as a library, but not the header files, in
 947         # El Capitan, probably because they don't want you writing
 948         # nasty portable code that could run on other UN*Xes, they
 949         # want you writing code that uses their Shiny New Crypto
 950         # Library and that only runs on macOS.
 951         #
 952         AC_CHECK_HEADER(openssl/crypto.h,
 953         [
 954                 AC_CHECK_LIB(crypto, DES_cbc_encrypt)
 955                 if test "$ac_cv_lib_crypto_DES_cbc_encrypt" = "yes"; then
 956                         AC_CHECK_HEADERS(openssl/evp.h)
 957                         #
 958                         # OK, then:
 959                         #
 960                         # 1) do we have EVP_CIPHER_CTX_new?
 961                         # If so, we use it to allocate an
 962                         # EVP_CIPHER_CTX, as EVP_CIPHER_CTX may be
 963                         # opaque; otherwise, we allocate it ourselves.
 964                         #
 965                         # 2) do we have EVP_CipherInit_ex()?
 966                         # If so, we use it, because we need to be
 967                         # able to make two "initialize the cipher"
 968                         # calls, one with the cipher and key, and
 969                         # one with the IV, and, as of OpenSSL 1.1,
 970                         # You Can't Do That with EVP_CipherInit(),
 971                         # because a call to EVP_CipherInit() will
 972                         # unconditionally clear the context, and
 973                         # if you don't supply a cipher, it'll
 974                         # clear the cipher, rendering the context
 975                         # unusable and causing a crash.
 976                         #
 977                         AC_CHECK_FUNCS(EVP_CIPHER_CTX_new EVP_CipherInit_ex)
 978                 fi
 979         ])
 980 fi
 981
 982 # Check for libcap-ng
 983 AC_MSG_CHECKING(whether to use libcap-ng)
 984 # Specify location for both includes and libraries.
 985 want_libcap_ng=ifavailable
 986 AC_ARG_WITH(cap_ng,
 987     AS_HELP_STRING([--with-cap-ng],
 988                    [use libcap-ng @<:@default=yes, if available@:>@]),
 989 [
 990         if test $withval = no
 991         then
 992                 want_libcap_ng=no
 993                 AC_MSG_RESULT(no)
 994         elif test $withval = yes
 995         then
 996                 want_libcap_ng=yes
 997                 AC_MSG_RESULT(yes)
 998         fi
 999 ],[
1000         #
1001         # Use libcap-ng if it's present, otherwise don't.
1002         #
1003         want_libcap_ng=ifavailable
1004         AC_MSG_RESULT([yes, if available])
1005 ])
1006 if test "$want_libcap_ng" != "no"; then
1007         AC_CHECK_LIB(cap-ng, capng_change_id)
1008         AC_CHECK_HEADERS(cap-ng.h)
1009 fi
1010
1011 dnl
1012 dnl set additional include path if necessary
1013 if test "$missing_includes" = "yes"; then
1014         CPPFLAGS="$CPPFLAGS -I$srcdir/missing"
1015         V_INCLS="$V_INCLS -I$srcdir/missing"
1016 fi
1017
1018 AC_SUBST(V_CCOPT)
1019 AC_SUBST(V_DEFS)
1020 AC_SUBST(V_GROUP)
1021 AC_SUBST(V_INCLS)
1022 AC_SUBST(V_PCAPDEP)
1023 AC_SUBST(LOCALSRC)
1024 AC_SUBST(MAN_FILE_FORMATS)
1025 AC_SUBST(MAN_MISC_INFO)
1026
1027 AC_PROG_INSTALL
1028
1029 AC_CONFIG_HEADER(config.h)
1030
1031 AC_OUTPUT_COMMANDS([if test -f .devel; then
1032         echo timestamp > stamp-h
1033         cat Makefile-devel-adds >> Makefile
1034         make depend
1035 fi])
1036 AC_OUTPUT(Makefile tcpdump.1)
1037 exit 0