The Tcpdump Group git mirrors - tcpdump/blob - configure.ac

   1 dnl Copyright (c) 1994, 1995, 1996, 1997
   2 dnl     The Regents of the University of California.  All rights reserved.
   3 dnl
   4 dnl Process this file with autoconf to produce a configure script.
   5 dnl
   6
   7 #
   8 # See
   9 #
  10 #       https://ftp.gnu.org/gnu/config/README
  11 #
  12 # for the URLs to use to fetch new versions of config.guess and
  13 # config.sub.
  14 #
  15
  16 AC_PREREQ(2.64)
  17 AC_INIT(tcpdump, m4_esyscmd_s([cat VERSION]))
  18 AC_CONFIG_SRCDIR(tcpdump.c)
  19
  20 AC_CANONICAL_HOST
  21
  22 AC_LBL_C_INIT_BEFORE_CC(V_INCLS)
  23 #
  24 # Try to enable as many C99 features as we can.
  25 # At minimum, we want C++/C99-style // comments.
  26 #
  27 AC_PROG_CC_C99
  28 if test "$ac_cv_prog_cc_c99" = "no"; then
  29         AC_MSG_WARN([The C compiler does not support C99; there may be compiler errors])
  30 fi
  31 AC_LBL_C_INIT(V_CCOPT, V_INCLS)
  32 AC_LBL_C_INLINE
  33
  34 AC_CHECK_HEADERS(fcntl.h rpc/rpc.h rpc/rpcent.h net/if.h)
  35 AC_CHECK_HEADERS(net/pfvar.h, , , [#include <sys/types.h>
  36 #include <sys/socket.h>
  37 #include <net/if.h>])
  38 if test "$ac_cv_header_net_pfvar_h" = yes; then
  39         AC_CHECK_HEADERS(net/if_pflog.h, , , [#include <sys/types.h>
  40         #include <sys/socket.h>
  41         #include <net/if.h>
  42         #include <net/pfvar.h>])
  43         if test "$ac_cv_header_net_if_pflog_h" = yes; then
  44                 LOCALSRC="print-pflog.c $LOCALSRC"
  45         fi
  46 fi
  47
  48 case "$host_os" in
  49
  50 darwin*)
  51         AC_ARG_ENABLE(universal,
  52         AC_HELP_STRING([--disable-universal],[don't build universal on macOS]))
  53         if test "$enable_universal" != "no"; then
  54                 case "$host_os" in
  55
  56                 darwin9.*)
  57                         #
  58                         # Leopard.  Build for x86 and 32-bit PowerPC, with
  59                         # x86 first.  (That's what Apple does.)
  60                         #
  61                         V_CCOPT="$V_CCOPT -arch i386 -arch ppc"
  62                         LDFLAGS="$LDFLAGS -arch i386 -arch ppc"
  63                         ;;
  64
  65                 darwin10.*)
  66                         #
  67                         # Snow Leopard.  Build for x86-64 and x86, with
  68                         # x86-64 first.  (That's what Apple does.)
  69                         #
  70                         V_CCOPT="$V_CCOPT -arch x86_64 -arch i386"
  71                         LDFLAGS="$LDFLAGS -arch x86_64 -arch i386"
  72                         ;;
  73                 esac
  74         fi
  75         ;;
  76 esac
  77
  78
  79 AC_ARG_WITH(smi,
  80 [  --with-smi              link with libsmi (allows to load MIBs on the fly to decode SNMP packets. [default=yes]
  81   --without-smi           don't link with libsmi],,
  82    with_smi=yes)
  83
  84 if test "x$with_smi" != "xno" ; then
  85         AC_CHECK_HEADER(smi.h,
  86         [
  87                 #
  88                 # OK, we found smi.h.  Do we have libsmi with smiInit?
  89                 #
  90                 AC_CHECK_LIB(smi, smiInit,
  91                 [
  92                         #
  93                         # OK, we have libsmi with smiInit.  Can we use it?
  94                         #
  95                         AC_MSG_CHECKING([whether to enable libsmi])
  96                         savedlibs="$LIBS"
  97                         LIBS="-lsmi $LIBS"
  98                         AC_TRY_RUN(
  99                                 [
 100 /* libsmi available check */
 101 #include <smi.h>
 102 main()
 103 {
 104   int current, revision, age, n;
 105   const int required = 2;
 106   if (smiInit(""))
 107     exit(1);
 108   if (strcmp(SMI_LIBRARY_VERSION, smi_library_version))
 109     exit(2);
 110   n = sscanf(smi_library_version, "%d:%d:%d", &current, &revision, &age);
 111   if (n != 3)
 112     exit(3);
 113   if (required < current - age || required > current)
 114     exit(4);
 115   exit(0);
 116 }
 117                                 ],
 118                                 [
 119                                         AC_MSG_RESULT(yes)
 120                                         AC_DEFINE(USE_LIBSMI, 1,
 121                                             [Define if you enable support for libsmi])
 122                                 ],
 123                                 [
 124                                         dnl autoconf documentation says that
 125                                         dnl $? contains the exit value.
 126                                         dnl reality is that it does not.
 127                                         dnl We leave this in just in case
 128                                         dnl autoconf ever comes back to
 129                                         dnl match the documentation.
 130                                         case $? in
 131                                           1) AC_MSG_RESULT(no - smiInit failed) ;;
 132                                           2) AC_MSG_RESULT(no - header/library version mismatch) ;;
 133                                           3) AC_MSG_RESULT(no - can't determine library version) ;;
 134                                           4) AC_MSG_RESULT(no - too old) ;;
 135                                           *) AC_MSG_RESULT(no) ;;
 136                                         esac
 137                                         LIBS="$savedlibs"
 138                                 ],
 139                                 [
 140                                         AC_MSG_RESULT(not when cross-compiling)
 141                                         LIBS="$savedlibs"
 142                                 ]
 143                         )
 144                 ])
 145         ])
 146 fi
 147
 148 AC_MSG_CHECKING([whether to enable the possibly-buggy SMB printer])
 149 AC_ARG_ENABLE(smb,
 150 [  --enable-smb            enable possibly-buggy SMB printer [default=no]
 151   --disable-smb           disable possibly-buggy SMB printer],,
 152    enableval=no)
 153 case "$enableval" in
 154 yes)    AC_MSG_RESULT(yes)
 155         AC_DEFINE(ENABLE_SMB, 1,
 156             [define if you want to build the possibly-buggy SMB printer])
 157         LOCALSRC="print-smb.c smbutil.c $LOCALSRC"
 158         ;;
 159 *)      AC_MSG_RESULT(no)
 160         ;;
 161 esac
 162
 163 AC_ARG_WITH(user, [  --with-user=USERNAME    drop privileges by default to USERNAME])
 164 AC_MSG_CHECKING([whether to drop root privileges by default])
 165 if test ! -z "$with_user" ; then
 166        AC_DEFINE_UNQUOTED(WITH_USER, "$withval",
 167            [define if should drop privileges by default])
 168        AC_MSG_RESULT(to \"$withval\")
 169 else
 170        AC_MSG_RESULT(no)
 171 fi
 172
 173 AC_ARG_WITH(chroot, [  --with-chroot=DIRECTORY when dropping privileges, chroot to DIRECTORY])
 174 AC_MSG_CHECKING([whether to chroot])
 175 if test ! -z "$with_chroot" && test "$with_chroot" != "no" ; then
 176        AC_DEFINE_UNQUOTED(WITH_CHROOT, "$withval",
 177            [define if should chroot when dropping privileges])
 178        AC_MSG_RESULT(to \"$withval\")
 179 else
 180        AC_MSG_RESULT(no)
 181 fi
 182
 183 AC_ARG_WITH(sandbox-capsicum,
 184         AS_HELP_STRING([--with-sandbox-capsicum],
 185                        [use Capsicum security functions @<:@default=yes, if available@:>@]))
 186 #
 187 # Check whether various functions are available.  If any are, set
 188 # ac_lbl_capsicum_function_seen to yes; if any are not, set
 189 # ac_lbl_capsicum_function_not_seen to yes.
 190 #
 191 # We don't check cap_rights_init(), as it's a macro, wrapping another
 192 # function, in at least some versions of FreeBSD, and AC_CHECK_FUNCS()
 193 # doesn't handle that.
 194 #
 195 # All of the ones we check for must be available in order to enable
 196 # capsicum sandboxing.
 197 #
 198 # XXX - do we need to check for all of them, or are there some that, if
 199 # present, imply others are present?
 200 #
 201 if test -z "$with_sandbox_capsicum" || test "$with_sandbox_capsicum" != "no" ; then
 202         #
 203         # First, make sure we have the required header.
 204         #
 205         AC_CHECK_HEADER(sys/capsicum.h,
 206         [
 207                 #
 208                 # We do; now make sure we have the required functions.
 209                 #
 210                 AC_CHECK_FUNCS(cap_enter cap_rights_limit cap_ioctls_limit openat,
 211                     ac_lbl_capsicum_function_seen=yes,
 212                     ac_lbl_capsicum_function_not_seen=yes)
 213         ])
 214         AC_CHECK_LIB(casper, cap_init, LIBS="$LIBS -lcasper")
 215         AC_CHECK_LIB(cap_dns, cap_gethostbyaddr, LIBS="$LIBS -lcap_dns")
 216 fi
 217 AC_MSG_CHECKING([whether to sandbox using capsicum])
 218 if test "x$ac_lbl_capsicum_function_seen" = "xyes" -a "x$ac_lbl_capsicum_function_not_seen" != "xyes"; then
 219         AC_DEFINE(HAVE_CAPSICUM, 1, [capsicum support available])
 220         AC_MSG_RESULT(yes)
 221 else
 222         AC_MSG_RESULT(no)
 223 fi
 224 AC_MSG_CHECKING([whether to sandbox using Casper library])
 225 if test "x$ac_cv_lib_casper_cap_init" = "xyes" -a "x$ac_cv_lib_cap_dns_cap_gethostbyaddr" = "xyes"; then
 226         AC_DEFINE(HAVE_CASPER, 1, [Casper support available])
 227         AC_MSG_RESULT(yes)
 228 else
 229         AC_MSG_RESULT(no)
 230 fi
 231
 232 #
 233 # We must check this before checking whether to check the OS's IPv6,
 234 # support because, on some platforms (such as SunOS 5.x), the test
 235 # program requires the extra networking libraries.
 236 #
 237 AC_LBL_LIBRARY_NET
 238
 239 #
 240 # Check whether AF_INET6 and struct in6_addr are defined.
 241 # If they aren't both defined, we don't have sufficient OS
 242 # support for IPv6, so we don't look for IPv6 support libraries,
 243 # and we define AF_INET6 and struct in6_addr ourselves.
 244 #
 245 AC_MSG_CHECKING([whether the operating system supports IPv6])
 246 AC_COMPILE_IFELSE(
 247     [
 248       AC_LANG_SOURCE(
 249         [[
 250 /* AF_INET6 available check */
 251 #include <sys/types.h>
 252 #ifdef _WIN32
 253 #include <ws2tcpip.h>
 254 #else
 255 #include <sys/socket.h>
 256 #include <netinet/in.h>
 257 #endif
 258 #ifdef AF_INET6
 259 void
 260 foo(struct in6_addr *addr)
 261 {
 262  memset(addr, 0, sizeof (struct in6_addr));
 263 }
 264 #else
 265 #error "AF_INET6 not defined"
 266 #endif
 267         ]])
 268     ],
 269     [
 270         AC_MSG_RESULT(yes)
 271         AC_DEFINE(HAVE_OS_IPV6_SUPPORT, 1,
 272             [define if the OS provides AF_INET6 and struct in6_addr])
 273         ipv6=yes
 274     ],
 275     [
 276         AC_MSG_RESULT(no)
 277         ipv6=no
 278     ]
 279 )
 280
 281 ipv6type=unknown
 282 ipv6lib=none
 283 ipv6trylibc=no
 284
 285 if test "$ipv6" = "yes"; then
 286         AC_MSG_CHECKING([ipv6 stack type])
 287         for i in inria kame linux-glibc linux-libinet6 toshiba v6d zeta; do
 288                 case $i in
 289                 inria)
 290                         dnl http://www.kame.net/
 291                         AC_EGREP_CPP(yes,
 292 [#include <netinet/in.h>
 293 #ifdef IPV6_INRIA_VERSION
 294 yes
 295 #endif],
 296                                 [ipv6type=$i])
 297                         ;;
 298                 kame)
 299                         dnl http://www.kame.net/
 300                         AC_EGREP_CPP(yes,
 301 [#include <netinet/in.h>
 302 #ifdef __KAME__
 303 yes
 304 #endif],
 305                                 [ipv6type=$i;
 306                                 ipv6lib=inet6;
 307                                 ipv6libdir=/usr/local/v6/lib;
 308                                 ipv6trylibc=yes])
 309                         ;;
 310                 linux-glibc)
 311                         dnl http://www.v6.linux.or.jp/
 312                         AC_EGREP_CPP(yes,
 313 [#include <features.h>
 314 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 315 yes
 316 #endif],
 317                                 [ipv6type=$i])
 318                         ;;
 319                 linux-libinet6)
 320                         dnl http://www.v6.linux.or.jp/
 321                         dnl
 322                         dnl This also matches Solaris 8 and Tru64 UNIX 5.1,
 323                         dnl and possibly other versions of those OSes
 324                         dnl
 325                         if test -d /usr/inet6 -o -f /usr/include/netinet/ip6.h; then
 326                                 ipv6type=$i
 327                                 ipv6lib=inet6
 328                                 ipv6libdir=/usr/inet6/lib
 329                                 ipv6trylibc=yes;
 330                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 331                         fi
 332                         ;;
 333                 toshiba)
 334                         AC_EGREP_CPP(yes,
 335 [#include <sys/param.h>
 336 #ifdef _TOSHIBA_INET6
 337 yes
 338 #endif],
 339                                 [ipv6type=$i;
 340                                 ipv6lib=inet6;
 341                                 ipv6libdir=/usr/local/v6/lib])
 342                         ;;
 343                 v6d)
 344                         AC_EGREP_CPP(yes,
 345 [#include </usr/local/v6/include/sys/v6config.h>
 346 #ifdef __V6D__
 347 yes
 348 #endif],
 349                                 [ipv6type=$i;
 350                                 ipv6lib=v6;
 351                                 ipv6libdir=/usr/local/v6/lib;
 352                                 CFLAGS="-I/usr/local/v6/include $CFLAGS"])
 353                         ;;
 354                 zeta)
 355                         AC_EGREP_CPP(yes,
 356 [#include <sys/param.h>
 357 #ifdef _ZETA_MINAMI_INET6
 358 yes
 359 #endif],
 360                                 [ipv6type=$i;
 361                                 ipv6lib=inet6;
 362                                 ipv6libdir=/usr/local/v6/lib])
 363                         ;;
 364                 esac
 365                 if test "$ipv6type" != "unknown"; then
 366                         break
 367                 fi
 368         done
 369         AC_MSG_RESULT($ipv6type)
 370 fi
 371
 372 if test "$ipv6" = "yes" -a "$ipv6lib" != "none"; then
 373         if test -d $ipv6libdir -a -f $ipv6libdir/lib$ipv6lib.a; then
 374                 LIBS="-L$ipv6libdir -l$ipv6lib $LIBS"
 375                 echo "You have $ipv6lib library, using it"
 376         else
 377                 if test "$ipv6trylibc" = "yes"; then
 378                         echo "You do not have $ipv6lib library, using libc"
 379                 else
 380                         echo 'Fatal: no $ipv6lib library found.  cannot continue.'
 381                         echo "You need to fetch lib$ipv6lib.a from appropriate"
 382                         echo 'ipv6 kit and compile beforehand.'
 383                         exit 1
 384                 fi
 385         fi
 386 fi
 387
 388 AC_REPLACE_FUNCS(strlcat strlcpy strdup strsep getservent getopt_long)
 389 AC_CHECK_FUNCS(fork vfork strftime)
 390 AC_CHECK_FUNCS(setlinebuf)
 391
 392 #
 393 # Make sure we have vsnprintf() and snprintf(); we require them.
 394 #
 395 AC_CHECK_FUNC(vsnprintf,,
 396     AC_MSG_ERROR([vsnprintf() is required but wasn't found]))
 397 AC_CHECK_FUNC(snprintf,,
 398     AC_MSG_ERROR([snprintf() is required but wasn't found]))
 399
 400 #
 401 # Define HAVE_NO_PRINTF_Z to make it possible to disable test cases that
 402 # depend on %zu.
 403 #
 404 AC_MSG_CHECKING([whether printf(3) supports the z length modifier])
 405 AC_RUN_IFELSE(
 406     [
 407         AC_LANG_SOURCE([[
 408 #include <stdio.h>
 409 #include <string.h>
 410
 411 int main()
 412 {
 413   char buf[100];
 414   snprintf(buf, sizeof(buf), "%zu", sizeof(buf));
 415   return strncmp(buf, "100", sizeof(buf)) ? 1 : 0;
 416 }
 417         ]])
 418     ],
 419     [
 420         AC_MSG_RESULT(yes)
 421     ],
 422     [
 423         AC_MSG_RESULT(no)
 424         AC_DEFINE(HAVE_NO_PRINTF_Z, 1,
 425             [Define to 1 if printf(3) does not support the z length modifier.])
 426     ],
 427     [
 428         AC_MSG_RESULT(not while cross-compiling)
 429     ]
 430 )
 431
 432 AC_CHECK_LIB(rpc, main)         dnl It's unclear why we might need -lrpc
 433
 434 dnl Some platforms may need -lnsl for getrpcbynumber.
 435 AC_SEARCH_LIBS(getrpcbynumber, nsl,
 436     AC_DEFINE(HAVE_GETRPCBYNUMBER, 1, [define if you have getrpcbynumber()]))
 437
 438 AC_LBL_LIBPCAP(V_PCAPDEP, V_INCLS)
 439
 440 #
 441 # Check for these after AC_LBL_LIBPCAP, so we link with the appropriate
 442 # libraries (e.g., "-lsocket -lnsl" on Solaris).
 443 #
 444 # You are in a twisty little maze of UN*Xes, all different.
 445 # Some might not have ether_ntohost().
 446 # Some might have it and declare it in <net/ethernet.h>.
 447 # Some might have it and declare it in <netinet/ether.h>
 448 # Some might have it and declare it in <sys/ethernet.h>.
 449 # Some might have it and declare it in <arpa/inet.h>.
 450 # Some might have it and declare it in <netinet/if_ether.h>.
 451 # Some might have it and not declare it in any header file.
 452 #
 453 # Before you is a C compiler.
 454 #
 455 AC_CHECK_FUNCS(ether_ntohost, [
 456     AC_CACHE_CHECK(for buggy ether_ntohost, ac_cv_buggy_ether_ntohost, [
 457         AC_TRY_RUN([
 458                 #include <netdb.h>
 459                 #include <sys/types.h>
 460                 #include <sys/param.h>
 461                 #include <sys/socket.h>
 462
 463                 int
 464                 main(int argc, char **argv)
 465                 {
 466                         u_char ea[6] = { 0xff, 0xff, 0xff, 0xff, 0xff };
 467                         char name[MAXHOSTNAMELEN];
 468
 469                         ether_ntohost(name, (struct ether_addr *)ea);
 470                         exit(0);
 471                 }
 472         ], [ac_cv_buggy_ether_ntohost=no],
 473            [ac_cv_buggy_ether_ntohost=yes],
 474            [ac_cv_buggy_ether_ntohost="not while cross-compiling"])])
 475     if test "$ac_cv_buggy_ether_ntohost" = "no"; then
 476         AC_DEFINE(USE_ETHER_NTOHOST, 1,
 477             [define if you have ether_ntohost() and it works])
 478     fi
 479 ])
 480 if test "$ac_cv_func_ether_ntohost" = yes -a \
 481     "$ac_cv_buggy_ether_ntohost" = "no"; then
 482         #
 483         # OK, we have ether_ntohost().  Is it declared in <net/ethernet.h>?
 484         #
 485         # This test fails if we don't have <net/ethernet.h> or if we do
 486         # but it doesn't declare ether_ntohost().
 487         #
 488         AC_CHECK_DECL(ether_ntohost,
 489             [
 490                 AC_DEFINE(NET_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
 491                     [Define to 1 if net/ethernet.h declares `ether_ntohost'])
 492             ],,
 493             [
 494 #include <net/ethernet.h>
 495             ])
 496         #
 497         # Did that succeed?
 498         #
 499         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 500                 #
 501                 # No, how about <netinet/ether.h>, as on Linux?
 502                 #
 503                 # This test fails if we don't have <netinet/ether.h>
 504                 # or if we do but it doesn't declare ether_ntohost().
 505                 #
 506                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 507                 # treat the previous failure as a cached value and
 508                 # suppress the next test.
 509                 #
 510                 unset ac_cv_have_decl_ether_ntohost
 511                 AC_CHECK_DECL(ether_ntohost,
 512                     [
 513                         AC_DEFINE(NETINET_ETHER_H_DECLARES_ETHER_NTOHOST,,
 514                             [Define to 1 if netinet/ether.h declares `ether_ntohost'])
 515                     ],,
 516                     [
 517 #include <netinet/ether.h>
 518                     ])
 519         fi
 520         #
 521         # Did that succeed?
 522         #
 523         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 524                 #
 525                 # No, how about <sys/ethernet.h>, as on Solaris 10
 526                 # and later?
 527                 #
 528                 # This test fails if we don't have <sys/ethernet.h>
 529                 # or if we do but it doesn't declare ether_ntohost().
 530                 #
 531                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 532                 # treat the previous failure as a cached value and
 533                 # suppress the next test.
 534                 #
 535                 unset ac_cv_have_decl_ether_ntohost
 536                 AC_CHECK_DECL(ether_ntohost,
 537                     [
 538                         AC_DEFINE(SYS_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
 539                             [Define to 1 if sys/ethernet.h declares `ether_ntohost'])
 540                     ],,
 541                     [
 542 #include <sys/ethernet.h>
 543                     ])
 544         fi
 545         #
 546         # Did that succeed?
 547         #
 548         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 549                 #
 550                 # No, how about <arpa/inet.h>, as in AIX?
 551                 #
 552                 # This test fails if we don't have <arpa/inet.h>
 553                 # (if we have ether_ntohost(), we should have
 554                 # networking, and if we have networking, we should
 555                 # have <arpa/inet.h>) or if we do but it doesn't
 556                 # declare ether_ntohost().
 557                 #
 558                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 559                 # treat the previous failure as a cached value and
 560                 # suppress the next test.
 561                 #
 562                 unset ac_cv_have_decl_ether_ntohost
 563                 AC_CHECK_DECL(ether_ntohost,
 564                     [
 565                         AC_DEFINE(ARPA_INET_H_DECLARES_ETHER_NTOHOST,,
 566                             [Define to 1 if arpa/inet.h declares `ether_ntohost'])
 567                     ],,
 568                     [
 569 #include <arpa/inet.h>
 570                     ])
 571         fi
 572         #
 573         # Did that succeed?
 574         #
 575         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 576                 #
 577                 # No, how about <netinet/if_ether.h>?
 578                 # On some platforms, it requires <net/if.h> and
 579                 # <netinet/in.h>, and we always include it with
 580                 # both of them, so test it with both of them.
 581                 #
 582                 # This test fails if we don't have <netinet/if_ether.h>
 583                 # and the headers we include before it, or if we do but
 584                 # <netinet/if_ether.h> doesn't declare ether_hostton().
 585                 #
 586                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 587                 # treat the previous failure as a cached value and
 588                 # suppress the next test.
 589                 #
 590                 unset ac_cv_have_decl_ether_ntohost
 591                 AC_CHECK_DECL(ether_ntohost,
 592                     [
 593                         AC_DEFINE(NETINET_IF_ETHER_H_DECLARES_ETHER_NTOHOST,,
 594                             [Define to 1 if netinet/if_ether.h declares `ether_ntohost'])
 595                     ],,
 596                     [
 597 #include <sys/types.h>
 598 #include <sys/socket.h>
 599 #include <net/if.h>
 600 #include <netinet/in.h>
 601 #include <netinet/if_ether.h>
 602                     ])
 603         fi
 604         #
 605         # After all that, is ether_ntohost() declared?
 606         #
 607         if test "$ac_cv_have_decl_ether_ntohost" = yes; then
 608                 #
 609                 # Yes.
 610                 #
 611                 AC_DEFINE(HAVE_DECL_ETHER_NTOHOST, 1,
 612                     [Define to 1 if you have the declaration of `ether_ntohost'])
 613         else
 614                 #
 615                 # No, we'll have to declare it ourselves.
 616                 # Do we have "struct ether_addr" if we include
 617                 # <netinet/if_ether.h>?
 618                 #
 619                 AC_CHECK_TYPES(struct ether_addr,,,
 620                     [
 621                         #include <sys/types.h>
 622                         #include <sys/socket.h>
 623                         #include <net/if.h>
 624                         #include <netinet/in.h>
 625                         #include <netinet/if_ether.h>
 626                     ])
 627         fi
 628 fi
 629
 630 dnl
 631 dnl Check for "pcap_list_datalinks()" and use a substitute version if
 632 dnl it's not present.  If it is present, check for "pcap_free_datalinks()";
 633 dnl if it's not present, we don't replace it for now.  (We could do so
 634 dnl on UN*X, but not on Windows, where hilarity ensues if a program
 635 dnl built with one version of the MSVC support library tries to free
 636 dnl something allocated by a library built with another version of
 637 dnl the MSVC support library.)
 638 dnl
 639 AC_CHECK_FUNC(pcap_list_datalinks,
 640         [
 641             AC_DEFINE(HAVE_PCAP_LIST_DATALINKS, 1,
 642                 [define if libpcap has pcap_list_datalinks()])
 643             AC_CHECK_FUNCS(pcap_free_datalinks)
 644         ],
 645         [
 646             AC_LIBOBJ(datalinks)
 647         ])
 648
 649 dnl
 650 dnl Check for "pcap_datalink_name_to_val()", and use a substitute
 651 dnl version if it's not present.  If it is present, check for
 652 dnl "pcap_datalink_val_to_description()", and if we don't have it,
 653 dnl use a substitute version.
 654 dnl
 655 AC_CHECK_FUNC(pcap_datalink_name_to_val,
 656         [
 657             AC_DEFINE(HAVE_PCAP_DATALINK_NAME_TO_VAL, 1,
 658                 [define if libpcap has pcap_datalink_name_to_val()])
 659             AC_CHECK_FUNC(pcap_datalink_val_to_description,
 660                 AC_DEFINE(HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION, 1,
 661                     [define if libpcap has pcap_datalink_val_to_description()]),
 662                 [
 663                     AC_LIBOBJ(dlnames)
 664                 ])
 665         ],
 666         [
 667             AC_LIBOBJ(dlnames)
 668         ])
 669
 670 dnl
 671 dnl Check for "pcap_set_datalink()"; you can't substitute for it if
 672 dnl it's absent (it has hooks into libpcap), so just define the
 673 dnl HAVE_ value if it's there.
 674 dnl
 675 AC_CHECK_FUNCS(pcap_set_datalink)
 676
 677 dnl
 678 dnl Check for "pcap_breakloop()"; you can't substitute for it if
 679 dnl it's absent (it has hooks into the live capture routines),
 680 dnl so just define the HAVE_ value if it's there.
 681 dnl
 682 AC_CHECK_FUNCS(pcap_breakloop)
 683
 684 #
 685 # Do we have the new open API?  Check for pcap_create, and assume that,
 686 # if we do, we also have pcap_activate() and the other new routines
 687 # introduced in libpcap 1.0.0.
 688 #
 689 AC_CHECK_FUNCS(pcap_create)
 690 if test $ac_cv_func_pcap_create = "yes" ; then
 691         #
 692         # OK, do we have pcap_set_tstamp_type?  If so, assume we have
 693         # pcap_list_tstamp_types and pcap_free_tstamp_types as well.
 694         #
 695         AC_CHECK_FUNCS(pcap_set_tstamp_type)
 696         #
 697         # And do we have pcap_set_tstamp_precision?  If so, we assume
 698         # we also have pcap_open_offline_with_tstamp_precision.
 699         #
 700         AC_CHECK_FUNCS(pcap_set_tstamp_precision)
 701 fi
 702
 703 #
 704 # Check for a miscellaneous collection of functions which we use
 705 # if we have them.
 706 #
 707 AC_CHECK_FUNCS(pcap_findalldevs)
 708 if test $ac_cv_func_pcap_findalldevs = "yes" ; then
 709 dnl Check for libpcap having pcap_findalldevs() but the pcap.h header
 710 dnl not having pcap_if_t; some versions of Mac OS X shipped with pcap.h
 711 dnl from 0.6 and libpcap 0.8, so that libpcap had pcap_findalldevs but
 712 dnl pcap.h didn't have pcap_if_t.
 713     savedcppflags="$CPPFLAGS"
 714     CPPFLAGS="$CPPFLAGS $V_INCLS"
 715     AC_CHECK_TYPES(pcap_if_t, , , [#include <pcap.h>])
 716     CPPFLAGS="$savedcppflags"
 717 fi
 718 AC_CHECK_FUNCS(pcap_dump_flush pcap_lib_version)
 719 if test $ac_cv_func_pcap_lib_version = "no" ; then
 720     AC_MSG_CHECKING(whether pcap_version is defined by libpcap)
 721     AC_TRY_LINK([],
 722        [
 723         extern char pcap_version[];
 724
 725         return (int)pcap_version;
 726        ],
 727        ac_lbl_cv_pcap_version_defined=yes,
 728        ac_lbl_cv_pcap_version_defined=no)
 729     if test "$ac_lbl_cv_pcap_version_defined" = yes ; then
 730         AC_MSG_RESULT(yes)
 731         AC_DEFINE(HAVE_PCAP_VERSION, 1, [define if libpcap has pcap_version])
 732     else
 733         AC_MSG_RESULT(no)
 734     fi
 735 fi
 736 AC_CHECK_FUNCS(pcap_setdirection pcap_set_immediate_mode pcap_dump_ftell64)
 737 AC_CHECK_FUNCS(pcap_open pcap_findalldevs_ex)
 738 AC_REPLACE_FUNCS(pcap_dump_ftell)
 739
 740 #
 741 # Check for special debugging functions
 742 #
 743 AC_CHECK_FUNCS(pcap_set_parser_debug)
 744 if test "$ac_cv_func_pcap_set_parser_debug" = "no" ; then
 745         #
 746         # OK, we don't have pcap_set_parser_debug() to set the libpcap
 747         # filter expression parser debug flag; can we directly set the
 748         # flag?
 749         AC_MSG_CHECKING(whether pcap_debug is defined by libpcap)
 750         AC_TRY_LINK([],
 751            [
 752                 extern int pcap_debug;
 753
 754                 return pcap_debug;
 755            ],
 756            ac_lbl_cv_pcap_debug_defined=yes,
 757            ac_lbl_cv_pcap_debug_defined=no)
 758         if test "$ac_lbl_cv_pcap_debug_defined" = yes ; then
 759                 AC_MSG_RESULT(yes)
 760                 AC_DEFINE(HAVE_PCAP_DEBUG, 1, [define if libpcap has pcap_debug])
 761         else
 762                 AC_MSG_RESULT(no)
 763                 #
 764                 # OK, what about "yydebug"?
 765                 #
 766                 AC_MSG_CHECKING(whether yydebug is defined by libpcap)
 767                 AC_TRY_LINK([],
 768                    [
 769                         extern int yydebug;
 770
 771                         return yydebug;
 772                    ],
 773                    ac_lbl_cv_yydebug_defined=yes,
 774                    ac_lbl_cv_yydebug_defined=no)
 775                 if test "$ac_lbl_cv_yydebug_defined" = yes ; then
 776                         AC_MSG_RESULT(yes)
 777                         AC_DEFINE(HAVE_YYDEBUG, 1, [define if libpcap has yydebug])
 778                 else
 779                         AC_MSG_RESULT(no)
 780                 fi
 781         fi
 782 fi
 783 AC_CHECK_FUNCS(pcap_set_optimizer_debug)
 784 AC_REPLACE_FUNCS(bpf_dump)      dnl moved to libpcap in 0.6
 785
 786 V_GROUP=0
 787 if test -f /etc/group -a ! -z "`grep '^wheel:' /etc/group`" ; then
 788         V_GROUP=wheel
 789 fi
 790 #
 791 # Assume V7/BSD convention for man pages (file formats in section 5,
 792 # miscellaneous info in section 7).
 793 #
 794 MAN_FILE_FORMATS=5
 795 MAN_MISC_INFO=7
 796 case "$host_os" in
 797
 798 aix*)
 799         dnl Workaround to enable certain features
 800         AC_DEFINE(_SUN,1,[define on AIX to get certain functions])
 801         ;;
 802
 803 hpux*)
 804         #
 805         # Use System V conventions for man pages.
 806         #
 807         MAN_FILE_FORMATS=4
 808         MAN_MISC_INFO=5
 809         ;;
 810
 811 irix*)
 812         V_GROUP=sys
 813
 814         #
 815         # Use System V conventions for man pages.
 816         #
 817         MAN_FILE_FORMATS=4
 818         MAN_MISC_INFO=5
 819         ;;
 820
 821 osf*)
 822         V_GROUP=system
 823
 824         #
 825         # Use System V conventions for man pages.
 826         #
 827         MAN_FILE_FORMATS=4
 828         MAN_MISC_INFO=5
 829         ;;
 830
 831 solaris*)
 832         V_GROUP=sys
 833
 834         #
 835         # Use System V conventions for man pages.
 836         #
 837         MAN_FILE_FORMATS=4
 838         MAN_MISC_INFO=5
 839         ;;
 840 esac
 841
 842 if test -f /dev/bpf0 ; then
 843         V_GROUP=bpf
 844 fi
 845
 846 #
 847 # Make sure we have a definition for C99's uintptr_t (regardless of
 848 # whether the environment is a C99 environment or not).
 849 #
 850 AC_TYPE_UINTPTR_T
 851
 852 #
 853 # Check whether we have pcap/pcap-inttypes.h.
 854 # If we do, we use that to get the C99 types defined.
 855 #
 856 savedcppflags="$CPPFLAGS"
 857 CPPFLAGS="$CPPFLAGS $V_INCLS"
 858 AC_CHECK_HEADERS(pcap/pcap-inttypes.h)
 859 CPPFLAGS="$savedcppflags"
 860
 861 #
 862 # Define the old BSD specified-width types in terms of the C99 types;
 863 # we may need them with libpcap include files.
 864 #
 865 AC_CHECK_TYPE([u_int8_t], ,
 866         [AC_DEFINE([u_int8_t], [uint8_t],
 867         [Define to `uint8_t' if u_int8_t not defined.])],
 868         [AC_INCLUDES_DEFAULT
 869 #include <sys/types.h>
 870 ])
 871 AC_CHECK_TYPE([u_int16_t], ,
 872         [AC_DEFINE([u_int16_t], [uint16_t],
 873         [Define to `uint16_t' if u_int16_t not defined.])],
 874         [AC_INCLUDES_DEFAULT
 875 #include <sys/types.h>
 876 ])
 877 AC_CHECK_TYPE([u_int32_t], ,
 878         [AC_DEFINE([u_int32_t], [uint32_t],
 879         [Define to `uint32_t' if u_int32_t not defined.])],
 880         [AC_INCLUDES_DEFAULT
 881 #include <sys/types.h>
 882 ])
 883 AC_CHECK_TYPE([u_int64_t], ,
 884         [AC_DEFINE([u_int64_t], [uint64_t],
 885         [Define to `uint64_t' if u_int64_t not defined.])],
 886         [AC_INCLUDES_DEFAULT
 887 #include <sys/types.h>
 888 ])
 889
 890 AC_PROG_RANLIB
 891 AC_CHECK_TOOL([AR], [ar])
 892
 893 AC_LBL_DEVEL(V_CCOPT)
 894
 895 # Check for OpenSSL/libressl libcrypto
 896 AC_MSG_CHECKING(whether to use OpenSSL/libressl libcrypto)
 897 # Specify location for both includes and libraries.
 898 want_libcrypto=ifavailable
 899 AC_ARG_WITH(crypto,
 900     AS_HELP_STRING([--with-crypto]@<:@=DIR@:>@,
 901                    [use OpenSSL/libressl libcrypto (located in directory DIR, if specified) @<:@default=yes, if available@:>@]),
 902 [
 903         if test $withval = no
 904         then
 905                 # User doesn't want to link with libcrypto.
 906                 want_libcrypto=no
 907                 AC_MSG_RESULT(no)
 908         elif test $withval = yes
 909         then
 910                 # User wants to link with libcrypto but hasn't specified
 911                 # a directory.
 912                 want_libcrypto=yes
 913                 AC_MSG_RESULT(yes)
 914         else
 915                 # User wants to link with libcrypto and has specified
 916                 # a directory, so use the provided value.
 917                 want_libcrypto=yes
 918                 libcrypto_root=$withval
 919                 AC_MSG_RESULT([yes, using the version installed in $withval])
 920
 921                 #
 922                 # Put the subdirectories of the libcrypto root directory
 923                 # at the front of the header and library search path.
 924                 #
 925                 CFLAGS="-I$withval/include $CFLAGS"
 926                 LIBS="-L$withval/lib $LIBS"
 927         fi
 928 ],[
 929         #
 930         # Use libcrypto if it's present, otherwise don't; no directory
 931         # was specified.
 932         #
 933         want_libcrypto=ifavailable
 934         AC_MSG_RESULT([yes, if available])
 935 ])
 936 if test "$want_libcrypto" != "no"; then
 937         #
 938         # Don't check for libcrypto unless we have its headers;
 939         # Apple, bless their pointy little heads, apparently ship
 940         # libcrypto as a library, but not the header files, in
 941         # El Capitan, probably because they don't want you writing
 942         # nasty portable code that could run on other UN*Xes, they
 943         # want you writing code that uses their Shiny New Crypto
 944         # Library and that only runs on macOS.
 945         #
 946         AC_CHECK_HEADER(openssl/crypto.h,
 947         [
 948                 AC_CHECK_LIB(crypto, DES_cbc_encrypt)
 949                 if test "$ac_cv_lib_crypto_DES_cbc_encrypt" = "yes"; then
 950                         AC_CHECK_HEADERS(openssl/evp.h)
 951                         #
 952                         # OK, then:
 953                         #
 954                         # 1) do we have EVP_CIPHER_CTX_new?
 955                         # If so, we use it to allocate an
 956                         # EVP_CIPHER_CTX, as EVP_CIPHER_CTX may be
 957                         # opaque; otherwise, we allocate it ourselves.
 958                         #
 959                         # 2) do we have EVP_DecryptInit_ex()?
 960                         # If so, we use it, because we need to be
 961                         # able to make two "initialize the cipher"
 962                         # calls, one with the cipher and key, and
 963                         # one with the IV, and, as of OpenSSL 1.1,
 964                         # You Can't Do That with EVP_DecryptInit(),
 965                         # because a call to EVP_DecryptInit() will
 966                         # unconditionally clear the context, and
 967                         # if you don't supply a cipher, it'll
 968                         # clear the cipher, rendering the context
 969                         # unusable and causing a crash.
 970                         #
 971                         AC_CHECK_FUNCS(EVP_CIPHER_CTX_new EVP_DecryptInit_ex)
 972                 fi
 973         ])
 974 fi
 975
 976 # Check for libcap-ng
 977 AC_MSG_CHECKING(whether to use libcap-ng)
 978 # Specify location for both includes and libraries.
 979 want_libcap_ng=ifavailable
 980 AC_ARG_WITH(cap_ng,
 981     AS_HELP_STRING([--with-cap-ng],
 982                    [use libcap-ng @<:@default=yes, if available@:>@]),
 983 [
 984         if test $withval = no
 985         then
 986                 want_libcap_ng=no
 987                 AC_MSG_RESULT(no)
 988         elif test $withval = yes
 989         then
 990                 want_libcap_ng=yes
 991                 AC_MSG_RESULT(yes)
 992         fi
 993 ],[
 994         #
 995         # Use libcap-ng if it's present, otherwise don't.
 996         #
 997         want_libcap_ng=ifavailable
 998         AC_MSG_RESULT([yes, if available])
 999 ])
1000 if test "$want_libcap_ng" != "no"; then
1001         AC_CHECK_LIB(cap-ng, capng_change_id)
1002         AC_CHECK_HEADERS(cap-ng.h)
1003 fi
1004
1005 dnl
1006 dnl set additional include path if necessary
1007 if test "$missing_includes" = "yes"; then
1008         CPPFLAGS="$CPPFLAGS -I$srcdir/missing"
1009         V_INCLS="$V_INCLS -I$srcdir/missing"
1010 fi
1011
1012 AC_SUBST(V_CCOPT)
1013 AC_SUBST(V_DEFS)
1014 AC_SUBST(V_GROUP)
1015 AC_SUBST(V_INCLS)
1016 AC_SUBST(V_PCAPDEP)
1017 AC_SUBST(LOCALSRC)
1018 AC_SUBST(MAN_FILE_FORMATS)
1019 AC_SUBST(MAN_MISC_INFO)
1020
1021 AC_PROG_INSTALL
1022
1023 AC_CONFIG_HEADER(config.h)
1024
1025 AC_OUTPUT_COMMANDS([if test -f .devel; then
1026         echo timestamp > stamp-h
1027         cat $srcdir/Makefile-devel-adds >> Makefile
1028         make depend || exit 1
1029 fi])
1030 AC_OUTPUT(Makefile tcpdump.1)
1031 exit 0