]> The Tcpdump Group git mirrors - tcpdump/blob - aclocal.m4
projects / tcpdump / blob
summary | shortlog | log | commit | commitdiff | tree
history | raw | HEAD
Clean up comments.
[tcpdump] / aclocal.m4
1 dnl Copyright (c) 1995, 1996, 1997, 1998
2 dnl The Regents of the University of California. All rights reserved.
3 dnl
4 dnl Redistribution and use in source and binary forms, with or without
5 dnl modification, are permitted provided that: (1) source code distributions
6 dnl retain the above copyright notice and this paragraph in its entirety, (2)
7 dnl distributions including binary code include the above copyright notice and
8 dnl this paragraph in its entirety in the documentation or other materials
9 dnl provided with the distribution, and (3) all advertising materials mentioning
10 dnl features or use of this software display the following acknowledgement:
11 dnl ``This product includes software developed by the University of California,
12 dnl Lawrence Berkeley Laboratory and its contributors.'' Neither the name of
13 dnl the University nor the names of its contributors may be used to endorse
14 dnl or promote products derived from this software without specific prior
15 dnl written permission.
16 dnl THIS SOFTWARE IS PROVIDED ``AS IS'' AND WITHOUT ANY EXPRESS OR IMPLIED
17 dnl WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED WARRANTIES OF
18 dnl MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE.
19 dnl
20 dnl LBL autoconf macros
21 dnl
22
23 dnl
24 dnl Do whatever AC_LBL_C_INIT work is necessary before using AC_PROG_CC.
25 dnl
26 dnl It appears that newer versions of autoconf (2.64 and later) will,
27 dnl if you use AC_TRY_COMPILE in a macro, stick AC_PROG_CC at the
28 dnl beginning of the macro, even if the macro itself calls AC_PROG_CC.
29 dnl See the "Prerequisite Macros" and "Expanded Before Required" sections
30 dnl in the Autoconf documentation.
31 dnl
32 dnl This causes a steaming heap of fail in our case, as we were, in
33 dnl AC_LBL_C_INIT, doing the tests we now do in AC_LBL_C_INIT_BEFORE_CC,
34 dnl calling AC_PROG_CC, and then doing the tests we now do in
35 dnl AC_LBL_C_INIT. Now, we run AC_LBL_C_INIT_BEFORE_CC, AC_PROG_CC,
36 dnl and AC_LBL_C_INIT at the top level.
37 dnl
38 AC_DEFUN(AC_LBL_C_INIT_BEFORE_CC,
39 [
40 AC_BEFORE([$0], [AC_LBL_C_INIT])
41 AC_BEFORE([$0], [AC_PROG_CC])
42 AC_BEFORE([$0], [AC_LBL_FIXINCLUDES])
43 AC_BEFORE([$0], [AC_LBL_DEVEL])
44 AC_ARG_WITH(gcc, [ --without-gcc don't use gcc])
45 $1=""
46 if test "${srcdir}" != "." ; then
47 $1="-I$srcdir"
48 fi
49 if test "${CFLAGS+set}" = set; then
50 LBL_CFLAGS="$CFLAGS"
51 fi
52 if test -z "$CC" ; then
53 case "$host_os" in
54
55 bsdi*)
56 AC_CHECK_PROG(SHLICC2, shlicc2, yes, no)
57 if test $SHLICC2 = yes ; then
58 CC=shlicc2
59 export CC
60 fi
61 ;;
62 esac
63 fi
64 if test -z "$CC" -a "$with_gcc" = no ; then
65 CC=cc
66 export CC
67 fi
68 ])
69
70 dnl
71 dnl Determine which compiler we're using (cc or gcc)
72 dnl If using gcc, determine the version number
73 dnl If using cc:
74 dnl require that it support ansi prototypes
75 dnl use -O (AC_PROG_CC will use -g -O2 on gcc, so we don't need to
76 dnl do that ourselves for gcc)
77 dnl add -g flags, as appropriate
78 dnl explicitly specify /usr/local/include
79 dnl
80 dnl NOTE WELL: with newer versions of autoconf, "gcc" means any compiler
81 dnl that defines __GNUC__, which means clang, for example, counts as "gcc".
82 dnl
83 dnl usage:
84 dnl
85 dnl AC_LBL_C_INIT(copt, incls)
86 dnl
87 dnl results:
88 dnl
89 dnl $1 (copt set)
90 dnl $2 (incls set)
91 dnl CC
92 dnl LDFLAGS
93 dnl LBL_CFLAGS
94 dnl
95 AC_DEFUN(AC_LBL_C_INIT,
96 [
97 AC_BEFORE([$0], [AC_LBL_FIXINCLUDES])
98 AC_BEFORE([$0], [AC_LBL_DEVEL])
99 AC_BEFORE([$0], [AC_LBL_SHLIBS_INIT])
100 if test "$GCC" = yes ; then
101 #
102 # -Werror forces warnings to be errors.
103 #
104 ac_lbl_cc_force_warning_errors=-Werror
105
106 #
107 # Use -ffloat-store so that, on 32-bit x86, we don't
108 # do 80-bit arithmetic with the FPU; that way we should
109 # get the same results for floating-point calculations
110 # on x86-32 and x86-64.
111 #
112 AC_LBL_CHECK_COMPILER_OPT($1, -ffloat-store)
113 else
114 $2="$$2 -I/usr/local/include"
115 LDFLAGS="$LDFLAGS -L/usr/local/lib"
116
117 case "$host_os" in
118
119 darwin*)
120 #
121 # This is assumed either to be GCC or clang, both
122 # of which use -Werror to force warnings to be errors.
123 #
124 ac_lbl_cc_force_warning_errors=-Werror
125 ;;
126
127 hpux*)
128 #
129 # HP C, which is what we presume we're using, doesn't
130 # exit with a non-zero exit status if we hand it an
131 # invalid -W flag, can't be forced to do so even with
132 # +We, and doesn't handle GCC-style -W flags, so we
133 # don't want to try using GCC-style -W flags.
134 #
135 ac_lbl_cc_dont_try_gcc_dashW=yes
136 ;;
137
138 irix*)
139 #
140 # MIPS C, which is what we presume we're using, doesn't
141 # necessarily exit with a non-zero exit status if we
142 # hand it an invalid -W flag, can't be forced to do
143 # so, and doesn't handle GCC-style -W flags, so we
144 # don't want to try using GCC-style -W flags.
145 #
146 ac_lbl_cc_dont_try_gcc_dashW=yes
147 #
148 # It also, apparently, defaults to "char" being
149 # unsigned, unlike most other C implementations;
150 # I suppose we could say "signed char" whenever
151 # we want to guarantee a signed "char", but let's
152 # just force signed chars.
153 #
154 # -xansi is normally the default, but the
155 # configure script was setting it; perhaps -cckr
156 # was the default in the Old Days. (Then again,
157 # that would probably be for backwards compatibility
158 # in the days when ANSI C was Shiny and New, i.e.
159 # 1989 and the early '90's, so maybe we can just
160 # drop support for those compilers.)
161 #
162 # -g is equivalent to -g2, which turns off
163 # optimization; we choose -g3, which generates
164 # debugging information but doesn't turn off
165 # optimization (even if the optimization would
166 # cause inaccuracies in debugging).
167 #
168 $1="$$1 -xansi -signed -g3"
169 ;;
170
171 osf*)
172 #
173 # Presumed to be DEC OSF/1, Digital UNIX, or
174 # Tru64 UNIX.
175 #
176 # The DEC C compiler, which is what we presume we're
177 # using, doesn't exit with a non-zero exit status if we
178 # hand it an invalid -W flag, can't be forced to do
179 # so, and doesn't handle GCC-style -W flags, so we
180 # don't want to try using GCC-style -W flags.
181 #
182 ac_lbl_cc_dont_try_gcc_dashW=yes
183 #
184 # -g is equivalent to -g2, which turns off
185 # optimization; we choose -g3, which generates
186 # debugging information but doesn't turn off
187 # optimization (even if the optimization would
188 # cause inaccuracies in debugging).
189 #
190 $1="$$1 -g3"
191 ;;
192
193 solaris*)
194 #
195 # Assumed to be Sun C, which requires -errwarn to force
196 # warnings to be treated as errors.
197 #
198 ac_lbl_cc_force_warning_errors=-errwarn
199 ;;
200
201 ultrix*)
202 AC_MSG_CHECKING(that Ultrix $CC hacks const in prototypes)
203 AC_CACHE_VAL(ac_cv_lbl_cc_const_proto,
204 AC_TRY_COMPILE(
205 [#include <sys/types.h>],
206 [struct a { int b; };
207 void c(const struct a *)],
208 ac_cv_lbl_cc_const_proto=yes,
209 ac_cv_lbl_cc_const_proto=no))
210 AC_MSG_RESULT($ac_cv_lbl_cc_const_proto)
211 if test $ac_cv_lbl_cc_const_proto = no ; then
212 AC_DEFINE(const,[],
213 [to handle Ultrix compilers that don't support const in prototypes])
214 fi
215 ;;
216 esac
217 $1="$$1 -O"
218 fi
219 ])
220
221 dnl
222 dnl Check whether, if you pass an unknown warning option to the
223 dnl compiler, it fails or just prints a warning message and succeeds.
224 dnl Set ac_lbl_unknown_warning_option_error to the appropriate flag
225 dnl to force an error if it would otherwise just print a warning message
226 dnl and succeed.
227 dnl
228 AC_DEFUN(AC_LBL_CHECK_UNKNOWN_WARNING_OPTION_ERROR,
229 [
230 AC_MSG_CHECKING([whether the compiler fails when given an unknown warning option])
231 save_CFLAGS="$CFLAGS"
232 CFLAGS="$CFLAGS -Wxyzzy-this-will-never-succeed-xyzzy"
233 AC_TRY_COMPILE(
234 [],
235 [return 0],
236 [
237 AC_MSG_RESULT([no])
238 #
239 # We're assuming this is clang, where
240 # -Werror=unknown-warning-option is the appropriate
241 # option to force the compiler to fail.
242 #
243 ac_lbl_unknown_warning_option_error="-Werror=unknown-warning-option"
244 ],
245 [
246 AC_MSG_RESULT([yes])
247 ])
248 CFLAGS="$save_CFLAGS"
249 ])
250
251 dnl
252 dnl Check whether the compiler option specified as the second argument
253 dnl is supported by the compiler and, if so, add it to the macro
254 dnl specified as the first argument
255 dnl
256 AC_DEFUN(AC_LBL_CHECK_COMPILER_OPT,
257 [
258 AC_MSG_CHECKING([whether the compiler supports the $2 option])
259 save_CFLAGS="$CFLAGS"
260 if expr "x$2" : "x-W.*" >/dev/null
261 then
262 CFLAGS="$CFLAGS $ac_lbl_unknown_warning_option_error $2"
263 elif expr "x$2" : "x-f.*" >/dev/null
264 then
265 CFLAGS="$CFLAGS -Werror $2"
266 elif expr "x$2" : "x-m.*" >/dev/null
267 then
268 CFLAGS="$CFLAGS -Werror $2"
269 else
270 CFLAGS="$CFLAGS $2"
271 fi
272 AC_TRY_COMPILE(
273 [],
274 [return 0],
275 [
276 AC_MSG_RESULT([yes])
277 CFLAGS="$save_CFLAGS"
278 $1="$$1 $2"
279 ],
280 [
281 AC_MSG_RESULT([no])
282 CFLAGS="$save_CFLAGS"
283 ])
284 ])
285
286 dnl
287 dnl Check whether the compiler supports an option to generate
288 dnl Makefile-style dependency lines
289 dnl
290 dnl GCC uses -M for this. Non-GCC compilers that support this
291 dnl use a variety of flags, including but not limited to -M.
292 dnl
293 dnl We test whether the flag in question is supported, as older
294 dnl versions of compilers might not support it.
295 dnl
296 dnl We don't try all the possible flags, just in case some flag means
297 dnl "generate dependencies" on one compiler but means something else
298 dnl on another compiler.
299 dnl
300 dnl Most compilers that support this send the output to the standard
301 dnl output by default. IBM's XLC, however, supports -M but sends
302 dnl the output to {sourcefile-basename}.u, and AIX has no /dev/stdout
303 dnl to work around that, so we don't bother with XLC.
304 dnl
305 AC_DEFUN(AC_LBL_CHECK_DEPENDENCY_GENERATION_OPT,
306 [
307 AC_MSG_CHECKING([whether the compiler supports generating dependencies])
308 if test "$GCC" = yes ; then
309 #
310 # GCC, or a compiler deemed to be GCC by AC_PROG_CC (even
311 # though it's not); we assume that, in this case, the flag
312 # would be -M.
313 #
314 ac_lbl_dependency_flag="-M"
315 else
316 #
317 # Not GCC or a compiler deemed to be GCC; what platform is
318 # this? (We're assuming that if the compiler isn't GCC
319 # it's the compiler from the vendor of the OS; that won't
320 # necessarily be true for x86 platforms, where it might be
321 # the Intel C compiler.)
322 #
323 case "$host_os" in
324
325 irix*|osf*|darwin*)
326 #
327 # MIPS C for IRIX, DEC C, and clang all use -M.
328 #
329 ac_lbl_dependency_flag="-M"
330 ;;
331
332 solaris*)
333 #
334 # Sun C uses -xM.
335 #
336 ac_lbl_dependency_flag="-xM"
337 ;;
338
339 hpux*)
340 #
341 # HP's older C compilers don't support this.
342 # HP's newer C compilers support this with
343 # either +M or +Make; the older compilers
344 # interpret +M as something completely
345 # different, so we use +Make so we don't
346 # think it works with the older compilers.
347 #
348 ac_lbl_dependency_flag="+Make"
349 ;;
350
351 *)
352 #
353 # Not one of the above; assume no support for
354 # generating dependencies.
355 #
356 ac_lbl_dependency_flag=""
357 ;;
358 esac
359 fi
360
361 #
362 # Is ac_lbl_dependency_flag defined and, if so, does the compiler
363 # complain about it?
364 #
365 # Note: clang doesn't seem to exit with an error status when handed
366 # an unknown non-warning error, even if you pass it
367 # -Werror=unknown-warning-option. However, it always supports
368 # -M, so the fact that this test always succeeds with clang
369 # isn't an issue.
370 #
371 if test ! -z "$ac_lbl_dependency_flag"; then
372 AC_LANG_CONFTEST(
373 [AC_LANG_SOURCE([[int main(void) { return 0; }]])])
374 if AC_RUN_LOG([eval "$CC $ac_lbl_dependency_flag conftest.c >/dev/null 2>&1"]); then
375 AC_MSG_RESULT([yes, with $ac_lbl_dependency_flag])
376 DEPENDENCY_CFLAG="$ac_lbl_dependency_flag"
377 MKDEP='${srcdir}/mkdep'
378 else
379 AC_MSG_RESULT([no])
380 #
381 # We can't run mkdep, so have "make depend" do
382 # nothing.
383 #
384 MKDEP=:
385 fi
386 rm -rf conftest*
387 else
388 AC_MSG_RESULT([no])
389 #
390 # We can't run mkdep, so have "make depend" do
391 # nothing.
392 #
393 MKDEP=:
394 fi
395 AC_SUBST(DEPENDENCY_CFLAG)
396 AC_SUBST(MKDEP)
397 ])
398
399 #
400 # Try compiling a sample of the type of code that appears in
401 # gencode.c with "inline", "__inline__", and "__inline".
402 #
403 # Autoconf's AC_C_INLINE, at least in autoconf 2.13, isn't good enough,
404 # as it just tests whether a function returning "int" can be inlined;
405 # at least some versions of HP's C compiler can inline that, but can't
406 # inline a function that returns a struct pointer.
407 #
408 # Make sure we use the V_CCOPT flags, because some of those might
409 # disable inlining.
410 #
411 AC_DEFUN(AC_LBL_C_INLINE,
412 [AC_MSG_CHECKING(for inline)
413 save_CFLAGS="$CFLAGS"
414 CFLAGS="$V_CCOPT"
415 AC_CACHE_VAL(ac_cv_lbl_inline, [
416 ac_cv_lbl_inline=""
417 ac_lbl_cc_inline=no
418 for ac_lbl_inline in inline __inline__ __inline
419 do
420 AC_TRY_COMPILE(
421 [#define inline $ac_lbl_inline
422 static inline struct iltest *foo(void);
423 struct iltest {
424 int iltest1;
425 int iltest2;
426 };
427
428 static inline struct iltest *
429 foo()
430 {
431 static struct iltest xxx;
432
433 return &xxx;
434 }],,ac_lbl_cc_inline=yes,)
435 if test "$ac_lbl_cc_inline" = yes ; then
436 break;
437 fi
438 done
439 if test "$ac_lbl_cc_inline" = yes ; then
440 ac_cv_lbl_inline=$ac_lbl_inline
441 fi])
442 CFLAGS="$save_CFLAGS"
443 if test ! -z "$ac_cv_lbl_inline" ; then
444 AC_MSG_RESULT($ac_cv_lbl_inline)
445 else
446 AC_MSG_RESULT(no)
447 fi
448 AC_DEFINE_UNQUOTED(inline, $ac_cv_lbl_inline, [Define as token for inline if inlining supported])])
449
450 dnl
451 dnl Use pfopen.c if available and pfopen() not in standard libraries
452 dnl Require libpcap
453 dnl Look for libpcap in directories under ..; those are local versions.
454 dnl Look for an installed libpcap if there is no local version or if
455 dnl the user said not to look for a local version.
456 dnl
457 dnl usage:
458 dnl
459 dnl AC_LBL_LIBPCAP(pcapdep, incls)
460 dnl
461 dnl results:
462 dnl
463 dnl $1 (pcapdep set)
464 dnl $2 (incls appended)
465 dnl LIBS
466 dnl LBL_LIBS
467 dnl
468 AC_DEFUN(AC_LBL_LIBPCAP,
469 [AC_REQUIRE([AC_LBL_LIBRARY_NET])
470 dnl
471 dnl save a copy before locating libpcap.a
472 dnl
473 LBL_LIBS="$LIBS"
474 pfopen=/usr/examples/packetfilter/pfopen.c
475 if test -f $pfopen ; then
476 AC_CHECK_FUNCS(pfopen)
477 if test $ac_cv_func_pfopen = "no" ; then
478 AC_MSG_RESULT(Using $pfopen)
479 LIBS="$LIBS $pfopen"
480 fi
481 fi
482 libpcap=FAIL
483 AC_ARG_WITH([system-libpcap],
484 [AS_HELP_STRING([--with-system-libpcap], [don't use local pcap library])],
485 [
486 #
487 # Don't look for a local libpcap.
488 #
489 using_local_libpcap=no
490 ],
491 [
492 #
493 # Look for a local pcap library.
494 #
495 AC_MSG_CHECKING(for local pcap library)
496 lastdir=FAIL
497 places=`ls $srcdir/.. | sed -e 's,/$,,' -e "s,^,$srcdir/../," | \
498 egrep '/libpcap-[[0-9]]+\.[[0-9]]+(\.[[0-9]]*)?([[ab]][[0-9]]*|-PRE-GIT)?$'`
499 places2=`ls .. | sed -e 's,/$,,' -e "s,^,../," | \
500 egrep '/libpcap-[[0-9]]+\.[[0-9]]+(\.[[0-9]]*)?([[ab]][[0-9]]*|-PRE-GIT)?$'`
501 for dir in $places $srcdir/../libpcap ../libpcap $srcdir/libpcap $places2 ; do
502 basedir=`echo $dir | sed -e 's/[[ab]][[0-9]]*$//' | \
503 sed -e 's/-PRE-GIT$//' `
504 if test $lastdir = $basedir ; then
505 dnl skip alphas when an actual release is present
506 continue;
507 fi
508 lastdir=$dir
509 if test -r $dir/libpcap.a ; then
510 libpcap=$dir/libpcap.a
511 local_pcap_dir=$dir
512 dnl continue and select the last one that exists
513 fi
514 done
515 if test $libpcap = FAIL ; then
516 #
517 # We didn't find a local libpcap.
518 #
519 AC_MSG_RESULT(not found)
520 using_local_libpcap=no;
521 else
522 #
523 # We found a local libpcap.
524 #
525 AC_MSG_RESULT($libpcap)
526 using_local_libpcap=yes
527 fi
528 ])
529
530 if test $using_local_libpcap = no ; then
531 #
532 # We didn't find a local libpcap.
533 # Look for an installed pkg-config.
534 #
535 AC_PATH_TOOL(PKG_CONFIG, pkg-config)
536 if test -n "$PKG_CONFIG" ; then
537 #
538 # We have it. Are there .pc files for libpcap?
539 #
540 # --exists was introduced in pkg-config 0.4.0; that
541 # dates back to late 2000, so we won't worry about
542 # earlier releases that lack it.
543 #
544 AC_MSG_CHECKING(whether there are .pc files for libpcap)
545 if "$PKG_CONFIG" libpcap --exists ; then
546 #
547 # Yes, so we can use pkg-config to get configuration
548 # information for libpcap.
549 #
550 AC_MSG_RESULT(yes)
551 pkg_config_usable=yes
552 else
553 #
554 # No, so we can't use pkg-config to get configuration
555 # information for libpcap.
556 #
557 AC_MSG_RESULT(no)
558 pkg_config_usable=no
559 fi
560 else
561 #
562 # We don't have it, so we obviously can't use it.
563 #
564 pkg_config_usable=no
565 fi
566 if test "$pkg_config_usable" = "yes" ; then
567 #
568 # Found both - use pkg-config to get the include flags for
569 # libpcap and the flags to link with libpcap.
570 #
571 # Please read section 11.6 "Shell Substitutions"
572 # in the autoconf manual before doing anything
573 # to this that involves quoting. Especially note
574 # the statement "There is just no portable way to use
575 # double-quoted strings inside double-quoted back-quoted
576 # expressions (pfew!)."
577 #
578 cflags=`"$PKG_CONFIG" libpcap --cflags`
579 $2="$cflags $$2"
580 libpcap=`"$PKG_CONFIG" libpcap --libs`
581 else
582 #
583 # No pkg-config
584 # Look for an installed pcap-config.
585 #
586 AC_PATH_TOOL(PCAP_CONFIG, pcap-config)
587 if test -n "$PCAP_CONFIG" ; then
588 #
589 # Found - use it to get the include flags for
590 # libpcap and the flags to link with libpcap.
591 #
592 # Please read section 11.6 "Shell Substitutions"
593 # in the autoconf manual before doing anything
594 # to this that involves quoting. Especially note
595 # the statement "There is just no portable way to use
596 # double-quoted strings inside double-quoted back-quoted
597 # expressions (pfew!)."
598 #
599 cflags=`"$PCAP_CONFIG" --cflags`
600 $2="$cflags $$2"
601 libpcap=`"$PCAP_CONFIG" --libs`
602 else
603 #
604 # Not found; look for an installed pcap.
605 #
606 AC_CHECK_LIB(pcap, main, libpcap="-lpcap")
607 if test $libpcap = FAIL ; then
608 AC_MSG_ERROR(see the INSTALL doc for more info)
609 fi
610 dnl
611 dnl Some versions of Red Hat Linux put "pcap.h" in
612 dnl "/usr/include/pcap"; had the LBL folks done so,
613 dnl that would have been a good idea, but for
614 dnl the Red Hat folks to do so just breaks source
615 dnl compatibility with other systems.
616 dnl
617 dnl We work around this by assuming that, as we didn't
618 dnl find a local libpcap, libpcap is in /usr/lib or
619 dnl /usr/local/lib and that the corresponding header
620 dnl file is under one of those directories; if we don't
621 dnl find it in either of those directories, we check to
622 dnl see if it's in a "pcap" subdirectory of them and,
623 dnl if so, add that subdirectory to the "-I" list.
624 dnl
625 dnl (We now also put pcap.h in /usr/include/pcap, but we
626 dnl leave behind a /usr/include/pcap.h that includes it,
627 dnl so you can still just include <pcap.h>.)
628 dnl
629 AC_MSG_CHECKING(for extraneous pcap header directories)
630 if test \( ! -r /usr/local/include/pcap.h \) -a \
631 \( ! -r /usr/include/pcap.h \); then
632 if test -r /usr/local/include/pcap/pcap.h; then
633 d="/usr/local/include/pcap"
634 elif test -r /usr/include/pcap/pcap.h; then
635 d="/usr/include/pcap"
636 fi
637 fi
638 if test -z "$d" ; then
639 AC_MSG_RESULT(not found)
640 else
641 $2="-I$d $$2"
642 AC_MSG_RESULT(found -- -I$d added)
643 fi
644 fi
645 fi
646 else
647 #
648 # We found a local libpcap. Add it to the dependencies for
649 # tcpdump.
650 #
651 $1=$libpcap
652
653 #
654 # Look for its pcap-config script.
655 #
656 AC_PATH_PROG(PCAP_CONFIG, pcap-config,, $local_pcap_dir)
657
658 if test -n "$PCAP_CONFIG"; then
659 #
660 # We don't want its --cflags or --libs output, because
661 # those presume it's installed. For the C compiler flags,
662 # we add the source directory for the local libpcap, so
663 # we pick up its header files.
664 #
665 # We do, however, want its additional libraries, as required
666 # when linking statically, because it makes calls to
667 # routines in those libraries, so we'll need to link with
668 # them, because we'll be linking statically with it.
669 #
670 $2="-I$local_pcap_dir $$2"
671 additional_libs=`"$PCAP_CONFIG" --static --additional-libs`
672 libpcap="$libpcap $additional_libs"
673 else
674 #
675 # It doesn't have a pcap-config script.
676 # Make sure it has a pcap.h file.
677 #
678 places=`ls $srcdir/.. | sed -e 's,/$,,' -e "s,^,$srcdir/../," | \
679 egrep '/libpcap-[[0-9]]*.[[0-9]]*(.[[0-9]]*)?([[ab]][[0-9]]*)?$'`
680 places2=`ls .. | sed -e 's,/$,,' -e "s,^,../," | \
681 egrep '/libpcap-[[0-9]]*.[[0-9]]*(.[[0-9]]*)?([[ab]][[0-9]]*)?$'`
682 pcapH=FAIL
683 if test -r $local_pcap_dir/pcap.h; then
684 pcapH=$local_pcap_dir
685 else
686 for dir in $places $srcdir/../libpcap ../libpcap $srcdir/libpcap $places2 ; do
687 if test -r $dir/pcap.h ; then
688 pcapH=$dir
689 fi
690 done
691 fi
692
693 if test $pcapH = FAIL ; then
694 AC_MSG_ERROR(cannot find pcap.h: see INSTALL)
695 fi
696
697 #
698 # Force the compiler to look for header files in the
699 # directory containing pcap.h.
700 #
701 $2="-I$pcapH $$2"
702 fi
703 fi
704
705 if test -z "$PKG_CONFIG" -a -z "$PCAP_CONFIG"; then
706 #
707 # We don't have pkg-config or pcap-config; find out any additional
708 # link flags we need. (If we have pkg-config or pcap-config, we
709 # assume it tells us what we need.)
710 #
711 case "$host_os" in
712
713 aix*)
714 #
715 # If libpcap is DLPI-based, we have to use /lib/pse.exp if
716 # present, as we use the STREAMS routines.
717 #
718 # (XXX - true only if we're linking with a static libpcap?)
719 #
720 pseexe="/lib/pse.exp"
721 AC_MSG_CHECKING(for $pseexe)
722 if test -f $pseexe ; then
723 AC_MSG_RESULT(yes)
724 LIBS="$LIBS -I:$pseexe"
725 fi
726
727 #
728 # If libpcap is BPF-based, we need "-lodm" and "-lcfg", as
729 # we use them to load the BPF module.
730 #
731 # (XXX - true only if we're linking with a static libpcap?)
732 #
733 LIBS="$LIBS -lodm -lcfg"
734 ;;
735
736 solaris*)
737 # libdlpi is needed for Solaris 11 and later.
738 AC_CHECK_LIB(dlpi, dlpi_walk, LIBS="$LIBS -ldlpi" LDFLAGS="-L/lib $LDFLAGS", ,-L/lib)
739 ;;
740 esac
741 fi
742
743 LIBS="$libpcap $LIBS"
744
745 dnl
746 dnl Check for "pcap_loop()", to make sure we found a working
747 dnl libpcap and have all the right other libraries with which
748 dnl to link. (Otherwise, the checks below will fail, not
749 dnl because the routines are missing from the library, but
750 dnl because we aren't linking properly with libpcap, and
751 dnl that will cause confusing errors at build time.)
752 dnl
753 AC_CHECK_FUNC(pcap_loop,,
754 [
755 AC_MSG_ERROR(
756 [This is a bug, please follow the guidelines in CONTRIBUTING and include the
757 config.log file in your report. If you have downloaded libpcap from
758 tcpdump.org, and built it yourself, please also include the config.log
759 file from the libpcap source directory, the Makefile from the libpcap
760 source directory, and the output of the make process for libpcap, as
761 this could be a problem with the libpcap that was built, and we will
762 not be able to determine why this is happening, and thus will not be
763 able to fix it, without that information, as we have not been able to
764 reproduce this problem ourselves.])
765 ])
766 ])
767
768 dnl
769 dnl If using gcc, make sure we have ANSI ioctl definitions
770 dnl
771 dnl usage:
772 dnl
773 dnl AC_LBL_FIXINCLUDES
774 dnl
775 AC_DEFUN(AC_LBL_FIXINCLUDES,
776 [if test "$GCC" = yes ; then
777 AC_MSG_CHECKING(for ANSI ioctl definitions)
778 AC_CACHE_VAL(ac_cv_lbl_gcc_fixincludes,
779 AC_TRY_COMPILE(
780 [/*
781 * This generates a "duplicate case value" when fixincludes
782 * has not be run.
783 */
784 # include <sys/types.h>
785 # include <sys/time.h>
786 # include <sys/ioctl.h>
787 # ifdef HAVE_SYS_IOCCOM_H
788 # include <sys/ioccom.h>
789 # endif],
790 [switch (0) {
791 case _IO('A', 1):;
792 case _IO('B', 1):;
793 }],
794 ac_cv_lbl_gcc_fixincludes=yes,
795 ac_cv_lbl_gcc_fixincludes=no))
796 AC_MSG_RESULT($ac_cv_lbl_gcc_fixincludes)
797 if test $ac_cv_lbl_gcc_fixincludes = no ; then
798 # Don't cache failure
799 unset ac_cv_lbl_gcc_fixincludes
800 AC_MSG_ERROR(see the INSTALL for more info)
801 fi
802 fi])
803
804 dnl
805 dnl Checks to see if union wait is used with WEXITSTATUS()
806 dnl
807 dnl usage:
808 dnl
809 dnl AC_LBL_UNION_WAIT
810 dnl
811 dnl results:
812 dnl
813 dnl DECLWAITSTATUS (defined)
814 dnl
815 AC_DEFUN(AC_LBL_UNION_WAIT,
816 [AC_MSG_CHECKING(if union wait is used)
817 AC_CACHE_VAL(ac_cv_lbl_union_wait,
818 AC_TRY_COMPILE([
819 # include <sys/types.h>
820 # include <sys/wait.h>],
821 [int status;
822 u_int i = WEXITSTATUS(status);
823 u_int j = waitpid(0, &status, 0);],
824 ac_cv_lbl_union_wait=no,
825 ac_cv_lbl_union_wait=yes))
826 AC_MSG_RESULT($ac_cv_lbl_union_wait)
827 if test $ac_cv_lbl_union_wait = yes ; then
828 AC_DEFINE(DECLWAITSTATUS,union wait,[type for wait])
829 else
830 AC_DEFINE(DECLWAITSTATUS,int,[type for wait])
831 fi])
832
833 dnl
834 dnl Checks to see if -R is used
835 dnl
836 dnl usage:
837 dnl
838 dnl AC_LBL_HAVE_RUN_PATH
839 dnl
840 dnl results:
841 dnl
842 dnl ac_cv_lbl_have_run_path (yes or no)
843 dnl
844 AC_DEFUN(AC_LBL_HAVE_RUN_PATH,
845 [AC_MSG_CHECKING(for ${CC-cc} -R)
846 AC_CACHE_VAL(ac_cv_lbl_have_run_path,
847 [echo 'main(){}' > conftest.c
848 ${CC-cc} -o conftest conftest.c -R/a1/b2/c3 >conftest.out 2>&1
849 if test ! -s conftest.out ; then
850 ac_cv_lbl_have_run_path=yes
851 else
852 ac_cv_lbl_have_run_path=no
853 fi
854 rm -f -r conftest*])
855 AC_MSG_RESULT($ac_cv_lbl_have_run_path)
856 ])
857
858 dnl
859 dnl Check whether a given format can be used to print 64-bit integers
860 dnl
861 AC_DEFUN(AC_LBL_CHECK_64BIT_FORMAT,
862 [
863 AC_MSG_CHECKING([whether %$1x can be used to format 64-bit integers])
864 AC_RUN_IFELSE(
865 [
866 AC_LANG_SOURCE(
867 [[
868 # ifdef HAVE_INTTYPES_H
869 #include <inttypes.h>
870 # endif
871 #include <stdio.h>
872 #include <sys/types.h>
873
874 main()
875 {
876 uint64_t t = 1;
877 char strbuf[16+1];
878 sprintf(strbuf, "%016$1x", t << 32);
879 if (strcmp(strbuf, "0000000100000000") == 0)
880 exit(0);
881 else
882 exit(1);
883 }
884 ]])
885 ],
886 [
887 AC_DEFINE(PRId64, "$1d", [define if the platform doesn't define PRId64])
888 AC_DEFINE(PRIo64, "$1o", [define if the platform doesn't define PRIo64])
889 AC_DEFINE(PRIx64, "$1x", [define if the platform doesn't define PRIu64])
890 AC_DEFINE(PRIu64, "$1u", [define if the platform doesn't define PRIx64])
891 AC_MSG_RESULT(yes)
892 ],
893 [
894 AC_MSG_RESULT(no)
895 $2
896 ])
897 ])
898
899 dnl
900 dnl If the file .devel exists:
901 dnl Add some warning flags if the compiler supports them
902 dnl If an os prototype include exists, symlink os-proto.h to it
903 dnl
904 dnl usage:
905 dnl
906 dnl AC_LBL_DEVEL(copt)
907 dnl
908 dnl results:
909 dnl
910 dnl $1 (copt appended)
911 dnl HAVE_OS_PROTO_H (defined)
912 dnl os-proto.h (symlinked)
913 dnl
914 AC_DEFUN(AC_LBL_DEVEL,
915 [rm -f os-proto.h
916 if test "${LBL_CFLAGS+set}" = set; then
917 $1="$$1 ${LBL_CFLAGS}"
918 fi
919 if test -f .devel ; then
920 #
921 # Skip all the warning option stuff on some compilers.
922 #
923 if test "$ac_lbl_cc_dont_try_gcc_dashW" != yes; then
924 AC_LBL_CHECK_UNKNOWN_WARNING_OPTION_ERROR()
925 AC_LBL_CHECK_COMPILER_OPT($1, -W)
926 AC_LBL_CHECK_COMPILER_OPT($1, -Wall)
927 AC_LBL_CHECK_COMPILER_OPT($1, -Wassign-enum)
928 AC_LBL_CHECK_COMPILER_OPT($1, -Wcast-qual)
929 AC_LBL_CHECK_COMPILER_OPT($1, -Wmissing-prototypes)
930 AC_LBL_CHECK_COMPILER_OPT($1, -Wold-style-definition)
931 AC_LBL_CHECK_COMPILER_OPT($1, -Wpedantic)
932 AC_LBL_CHECK_COMPILER_OPT($1, -Wpointer-arith)
933 AC_LBL_CHECK_COMPILER_OPT($1, -Wpointer-sign)
934 AC_LBL_CHECK_COMPILER_OPT($1, -Wshadow)
935 AC_LBL_CHECK_COMPILER_OPT($1, -Wsign-compare)
936 AC_LBL_CHECK_COMPILER_OPT($1, -Wstrict-prototypes)
937 AC_LBL_CHECK_COMPILER_OPT($1, -Wunreachable-code-return)
938 AC_LBL_CHECK_COMPILER_OPT($1, -Wused-but-marked-unused)
939 AC_LBL_CHECK_COMPILER_OPT($1, -Wwrite-strings)
940 fi
941 AC_LBL_CHECK_DEPENDENCY_GENERATION_OPT()
942 #
943 # We used to set -n32 for IRIX 6 when not using GCC (presumed
944 # to mean that we're using MIPS C or MIPSpro C); it specified
945 # the "new" faster 32-bit ABI, introduced in IRIX 6.2. I'm
946 # not sure why that would be something to do *only* with a
947 # .devel file; why should the ABI for which we produce code
948 # depend on .devel?
949 #
950 os=`echo $host_os | sed -e 's/\([[0-9]][[0-9]]*\)[[^0-9]].*$/\1/'`
951 name="lbl/os-$os.h"
952 if test -f $name ; then
953 ln -s $name os-proto.h
954 AC_DEFINE(HAVE_OS_PROTO_H, 1,
955 [if there's an os_proto.h for this platform, to use additional prototypes])
956 else
957 AC_MSG_WARN(can't find $name)
958 fi
959 fi])
960
961 dnl
962 dnl Improved version of AC_CHECK_LIB
963 dnl
964 dnl Thanks to John Hawkinson (jhawk@mit.edu)
965 dnl
966 dnl usage:
967 dnl
968 dnl AC_LBL_CHECK_LIB(LIBRARY, FUNCTION [, ACTION-IF-FOUND [,
969 dnl ACTION-IF-NOT-FOUND [, OTHER-LIBRARIES]]])
970 dnl
971 dnl results:
972 dnl
973 dnl LIBS
974 dnl
975 dnl XXX - "AC_LBL_LIBRARY_NET" was redone to use "AC_SEARCH_LIBS"
976 dnl rather than "AC_LBL_CHECK_LIB", so this isn't used any more.
977 dnl We keep it around for reference purposes in case it's ever
978 dnl useful in the future.
979 dnl
980
981 define(AC_LBL_CHECK_LIB,
982 [AC_MSG_CHECKING([for $2 in -l$1])
983 dnl Use a cache variable name containing the library, function
984 dnl name, and extra libraries to link with, because the test really is
985 dnl for library $1 defining function $2, when linked with potinal
986 dnl library $5, not just for library $1. Separate tests with the same
987 dnl $1 and different $2's or $5's may have different results.
988 ac_lib_var=`echo $1['_']$2['_']$5 | sed 'y%./+- %__p__%'`
989 AC_CACHE_VAL(ac_cv_lbl_lib_$ac_lib_var,
990 [ac_save_LIBS="$LIBS"
991 LIBS="-l$1 $5 $LIBS"
992 AC_TRY_LINK(dnl
993 ifelse([$2], [main], , dnl Avoid conflicting decl of main.
994 [/* Override any gcc2 internal prototype to avoid an error. */
995 ]ifelse(AC_LANG, CPLUSPLUS, [#ifdef __cplusplus
996 extern "C"
997 #endif
998 ])dnl
999 [/* We use char because int might match the return type of a gcc2
1000 builtin and then its argument prototype would still apply. */
1001 char $2();
1002 ]),
1003 [$2()],
1004 eval "ac_cv_lbl_lib_$ac_lib_var=yes",
1005 eval "ac_cv_lbl_lib_$ac_lib_var=no")
1006 LIBS="$ac_save_LIBS"
1007 ])dnl
1008 if eval "test \"`echo '$ac_cv_lbl_lib_'$ac_lib_var`\" = yes"; then
1009 AC_MSG_RESULT(yes)
1010 ifelse([$3], ,
1011 [changequote(, )dnl
1012 ac_tr_lib=HAVE_LIB`echo $1 | sed -e 's/[^a-zA-Z0-9_]/_/g' \
1013 -e 'y/abcdefghijklmnopqrstuvwxyz/ABCDEFGHIJKLMNOPQRSTUVWXYZ/'`
1014 changequote([, ])dnl
1015 AC_DEFINE_UNQUOTED($ac_tr_lib)
1016 LIBS="-l$1 $LIBS"
1017 ], [$3])
1018 else
1019 AC_MSG_RESULT(no)
1020 ifelse([$4], , , [$4
1021 ])dnl
1022 fi
1023 ])
1024
1025 dnl
1026 dnl AC_LBL_LIBRARY_NET
1027 dnl
1028 dnl This test is for network applications that need socket() and
1029 dnl gethostbyname() -ish functions. Under Solaris, those applications
1030 dnl need to link with "-lsocket -lnsl". Under IRIX, they need to link
1031 dnl with "-lnsl" but should *not* link with "-lsocket" because
1032 dnl libsocket.a breaks a number of things (for instance:
1033 dnl gethostbyname() under IRIX 5.2, and snoop sockets under most
1034 dnl versions of IRIX).
1035 dnl
1036 dnl Unfortunately, many application developers are not aware of this,
1037 dnl and mistakenly write tests that cause -lsocket to be used under
1038 dnl IRIX. It is also easy to write tests that cause -lnsl to be used
1039 dnl under operating systems where neither are necessary (or useful),
1040 dnl such as SunOS 4.1.4, which uses -lnsl for TLI.
1041 dnl
1042 dnl This test exists so that every application developer does not test
1043 dnl this in a different, and subtly broken fashion.
1044
1045 dnl It has been argued that this test should be broken up into two
1046 dnl separate tests, one for the resolver libraries, and one for the
1047 dnl libraries necessary for using Sockets API. Unfortunately, the two
1048 dnl are carefully intertwined and allowing the autoconf user to use
1049 dnl them independently potentially results in unfortunate ordering
1050 dnl dependencies -- as such, such component macros would have to
1051 dnl carefully use indirection and be aware if the other components were
1052 dnl executed. Since other autoconf macros do not go to this trouble,
1053 dnl and almost no applications use sockets without the resolver, this
1054 dnl complexity has not been implemented.
1055 dnl
1056 dnl The check for libresolv is in case you are attempting to link
1057 dnl statically and happen to have a libresolv.a lying around (and no
1058 dnl libnsl.a).
1059 dnl
1060 AC_DEFUN(AC_LBL_LIBRARY_NET, [
1061 # Most operating systems have gethostbyname() in the default searched
1062 # libraries (i.e. libc):
1063 # Some OSes (eg. Solaris) place it in libnsl
1064 # Some strange OSes (SINIX) have it in libsocket:
1065 AC_SEARCH_LIBS(gethostbyname, nsl socket resolv)
1066 # Unfortunately libsocket sometimes depends on libnsl and
1067 # AC_SEARCH_LIBS isn't up to the task of handling dependencies like this.
1068 if test "$ac_cv_search_gethostbyname" = "no"
1069 then
1070 AC_CHECK_LIB(socket, gethostbyname,
1071 LIBS="-lsocket -lnsl $LIBS", , -lnsl)
1072 fi
1073 AC_SEARCH_LIBS(socket, socket, ,
1074 AC_CHECK_LIB(socket, socket, LIBS="-lsocket -lnsl $LIBS", , -lnsl))
1075 # DLPI needs putmsg under HPUX so test for -lstr while we're at it
1076 AC_SEARCH_LIBS(putmsg, str)
1077 ])
1078
1079 dnl Copyright (c) 1999 WIDE Project. All rights reserved.
1080 dnl
1081 dnl Redistribution and use in source and binary forms, with or without
1082 dnl modification, are permitted provided that the following conditions
1083 dnl are met:
1084 dnl 1. Redistributions of source code must retain the above copyright
1085 dnl notice, this list of conditions and the following disclaimer.
1086 dnl 2. Redistributions in binary form must reproduce the above copyright
1087 dnl notice, this list of conditions and the following disclaimer in the
1088 dnl documentation and/or other materials provided with the distribution.
1089 dnl 3. Neither the name of the project nor the names of its contributors
1090 dnl may be used to endorse or promote products derived from this software
1091 dnl without specific prior written permission.
1092 dnl
1093 dnl THIS SOFTWARE IS PROVIDED BY THE PROJECT AND CONTRIBUTORS ``AS IS'' AND
1094 dnl ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
1095 dnl IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
1096 dnl ARE DISCLAIMED. IN NO EVENT SHALL THE PROJECT OR CONTRIBUTORS BE LIABLE
1097 dnl FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
1098 dnl DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
1099 dnl OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
1100 dnl HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
1101 dnl LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
1102 dnl OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
1103 dnl SUCH DAMAGE.
1104
1105 AC_DEFUN(AC_LBL_SSLEAY,
1106 [
1107 #
1108 # Find the last component of $libdir; it's not necessarily
1109 # "lib" - it might be "lib64" on, for example, x86-64
1110 # Linux systems.
1111 #
1112 # We assume the directory in which we're looking for
1113 # libcrypto has a subdirectory with that as its name.
1114 #
1115 tmplib=`echo "$libdir" | sed 's,.*/,,'`
1116
1117 #
1118 # XXX - is there a better way to check if a given library is
1119 # in a given directory than checking each of the possible
1120 # shared library suffixes?
1121 #
1122 # Are there any other suffixes we need to look for? Do we
1123 # have to worry about ".so.{version}"?
1124 #
1125 # Or should we just look for "libcrypto.*"?
1126 #
1127 if test -d "$1/$tmplib" -a \( -f "$1/$tmplib/libcrypto.a" -o \
1128 -f "$1/$tmplib/libcrypto.so" -o \
1129 -f "$1/$tmplib/libcrypto.sl" -o \
1130 -f "$1/$tmplib/libcrypto.dylib" \); then
1131 ac_cv_ssleay_path="$1"
1132 fi
1133
1134 #
1135 # Make sure we have the headers as well.
1136 #
1137 if test -d "$1/include/openssl" -a -f "$1/include/openssl/des.h"; then
1138 incdir="-I$1/include"
1139 fi
1140 ])
[mirror] the TCPdump network dissector