The Tcpdump Group git mirrors - tcpdump/blob - aclocal.m4

   1 dnl @(#) $Header: /tcpdump/master/tcpdump/aclocal.m4,v 1.66 1999-10-30 07:36:35 itojun Exp $ (LBL)
   2 dnl
   3 dnl Copyright (c) 1995, 1996, 1997, 1998
   4 dnl     The Regents of the University of California.  All rights reserved.
   5 dnl
   6 dnl Redistribution and use in source and binary forms, with or without
   7 dnl modification, are permitted provided that: (1) source code distributions
   8 dnl retain the above copyright notice and this paragraph in its entirety, (2)
   9 dnl distributions including binary code include the above copyright notice and
  10 dnl this paragraph in its entirety in the documentation or other materials
  11 dnl provided with the distribution, and (3) all advertising materials mentioning
  12 dnl features or use of this software display the following acknowledgement:
  13 dnl ``This product includes software developed by the University of California,
  14 dnl Lawrence Berkeley Laboratory and its contributors.'' Neither the name of
  15 dnl the University nor the names of its contributors may be used to endorse
  16 dnl or promote products derived from this software without specific prior
  17 dnl written permission.
  18 dnl THIS SOFTWARE IS PROVIDED ``AS IS'' AND WITHOUT ANY EXPRESS OR IMPLIED
  19 dnl WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED WARRANTIES OF
  20 dnl MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE.
  21 dnl
  22 dnl LBL autoconf macros
  23 dnl
  24
  25 dnl
  26 dnl Determine which compiler we're using (cc or gcc)
  27 dnl If using gcc, determine the version number
  28 dnl If using cc, require that it support ansi prototypes
  29 dnl If using gcc, use -O2 (otherwise use -O)
  30 dnl If using cc, explicitly specify /usr/local/include
  31 dnl
  32 dnl usage:
  33 dnl
  34 dnl     AC_LBL_C_INIT(copt, incls)
  35 dnl
  36 dnl results:
  37 dnl
  38 dnl     $1 (copt set)
  39 dnl     $2 (incls set)
  40 dnl     CC
  41 dnl     LDFLAGS
  42 dnl     ac_cv_lbl_gcc_vers
  43 dnl     LBL_CFLAGS
  44 dnl
  45 AC_DEFUN(AC_LBL_C_INIT,
  46     [AC_PREREQ(2.12)
  47     AC_BEFORE([$0], [AC_PROG_CC])
  48     AC_BEFORE([$0], [AC_LBL_FIXINCLUDES])
  49     AC_BEFORE([$0], [AC_LBL_DEVEL])
  50     AC_ARG_WITH(gcc, [  --without-gcc           don't use gcc])
  51     $1="-O"
  52     $2=""
  53     if test "${srcdir}" != "." ; then
  54             $2="-I\$(srcdir)"
  55     fi
  56     if test "${CFLAGS+set}" = set; then
  57             LBL_CFLAGS="$CFLAGS"
  58     fi
  59     if test -z "$CC" ; then
  60             case "$target_os" in
  61
  62             bsdi*)
  63                     AC_CHECK_PROG(SHLICC2, shlicc2, yes, no)
  64                     if test $SHLICC2 = yes ; then
  65                             CC=shlicc2
  66                             export CC
  67                     fi
  68                     ;;
  69             esac
  70     fi
  71     if test -z "$CC" -a "$with_gcc" = no ; then
  72             CC=cc
  73             export CC
  74     fi
  75     AC_PROG_CC
  76     if test "$GCC" = yes ; then
  77             if test "$SHLICC2" = yes ; then
  78                     ac_cv_lbl_gcc_vers=2
  79                     $1="-O2"
  80             else
  81                     AC_MSG_CHECKING(gcc version)
  82                     AC_CACHE_VAL(ac_cv_lbl_gcc_vers,
  83                         ac_cv_lbl_gcc_vers=`$CC -v 2>&1 | \
  84                             sed -e '/^gcc version /!d' \
  85                                 -e 's/^gcc version //' \
  86                                 -e 's/ .*//' -e 's/^[[[^0-9]]]*//' \
  87                                 -e 's/\..*//'`)
  88                     AC_MSG_RESULT($ac_cv_lbl_gcc_vers)
  89                     if test $ac_cv_lbl_gcc_vers -gt 1 ; then
  90                             $1="-O2"
  91                     fi
  92             fi
  93     else
  94             AC_MSG_CHECKING(that $CC handles ansi prototypes)
  95             AC_CACHE_VAL(ac_cv_lbl_cc_ansi_prototypes,
  96                 AC_TRY_COMPILE(
  97                     [#include <sys/types.h>],
  98                     [int frob(int, char *)],
  99                     ac_cv_lbl_cc_ansi_prototypes=yes,
 100                     ac_cv_lbl_cc_ansi_prototypes=no))
 101             AC_MSG_RESULT($ac_cv_lbl_cc_ansi_prototypes)
 102             if test $ac_cv_lbl_cc_ansi_prototypes = no ; then
 103                     case "$target_os" in
 104
 105                     hpux*)
 106                             AC_MSG_CHECKING(for HP-UX ansi compiler ($CC -Aa -D_HPUX_SOURCE))
 107                             savedcflags="$CFLAGS"
 108                             CFLAGS="-Aa -D_HPUX_SOURCE $CFLAGS"
 109                             AC_CACHE_VAL(ac_cv_lbl_cc_hpux_cc_aa,
 110                                 AC_TRY_COMPILE(
 111                                     [#include <sys/types.h>],
 112                                     [int frob(int, char *)],
 113                                     ac_cv_lbl_cc_hpux_cc_aa=yes,
 114                                     ac_cv_lbl_cc_hpux_cc_aa=no))
 115                             AC_MSG_RESULT($ac_cv_lbl_cc_hpux_cc_aa)
 116                             if test $ac_cv_lbl_cc_hpux_cc_aa = no ; then
 117                                     AC_MSG_ERROR(see the INSTALL doc for more info)
 118                             fi
 119                             CFLAGS="$savedcflags"
 120                             V_CCOPT="-Aa $V_CCOPT"
 121                             AC_DEFINE(_HPUX_SOURCE)
 122                             ;;
 123
 124                     *)
 125                             AC_MSG_ERROR(see the INSTALL doc for more info)
 126                             ;;
 127                     esac
 128             fi
 129             $2="$$2 -I/usr/local/include"
 130             LDFLAGS="$LDFLAGS -L/usr/local/lib"
 131
 132             case "$target_os" in
 133
 134             irix*)
 135                     V_CCOPT="$V_CCOPT -xansi -signed -g3"
 136                     ;;
 137
 138             osf*)
 139                     V_CCOPT="$V_CCOPT -std1 -g3"
 140                     ;;
 141
 142             ultrix*)
 143                     AC_MSG_CHECKING(that Ultrix $CC hacks const in prototypes)
 144                     AC_CACHE_VAL(ac_cv_lbl_cc_const_proto,
 145                         AC_TRY_COMPILE(
 146                             [#include <sys/types.h>],
 147                             [struct a { int b; };
 148                             void c(const struct a *)],
 149                             ac_cv_lbl_cc_const_proto=yes,
 150                             ac_cv_lbl_cc_const_proto=no))
 151                     AC_MSG_RESULT($ac_cv_lbl_cc_const_proto)
 152                     if test $ac_cv_lbl_cc_const_proto = no ; then
 153                             AC_DEFINE(const,)
 154                     fi
 155                     ;;
 156             esac
 157     fi
 158 ])
 159
 160 dnl
 161 dnl Use pfopen.c if available and pfopen() not in standard libraries
 162 dnl Require libpcap
 163 dnl Look for libpcap in ..
 164 dnl Use the installed libpcap if there is no local version
 165 dnl
 166 dnl usage:
 167 dnl
 168 dnl     AC_LBL_LIBPCAP(pcapdep, incls)
 169 dnl
 170 dnl results:
 171 dnl
 172 dnl     $1 (pcapdep set)
 173 dnl     $2 (incls appended)
 174 dnl     LIBS
 175 dnl     LBL_LIBS
 176 dnl
 177 AC_DEFUN(AC_LBL_LIBPCAP,
 178     [AC_REQUIRE([AC_LBL_LIBRARY_NET])
 179     dnl
 180     dnl save a copy before locating libpcap.a
 181     dnl
 182     LBL_LIBS="$LIBS"
 183     pfopen=/usr/examples/packetfilter/pfopen.c
 184     if test -f $pfopen ; then
 185             AC_CHECK_FUNCS(pfopen)
 186             if test $ac_cv_func_pfopen = "no" ; then
 187                     AC_MSG_RESULT(Using $pfopen)
 188                     LIBS="$LIBS $pfopen"
 189             fi
 190     fi
 191     AC_MSG_CHECKING(for local pcap library)
 192     libpcap=FAIL
 193     lastdir=FAIL
 194     places=`ls .. | sed -e 's,/$,,' -e 's,^,../,' | \
 195         egrep '/libpcap-[[0-9]]*\.[[0-9]]*(\.[[0-9]]*)?([[ab]][[0-9]]*)?$'`
 196     for dir in $places ../libpcap libpcap ; do
 197             basedir=`echo $dir | sed -e 's/[[ab]][[0-9]]*$//'`
 198             if test $lastdir = $basedir ; then
 199                     dnl skip alphas when an actual release is present
 200                     continue;
 201             fi
 202             lastdir=$dir
 203             if test -r $dir/libpcap.a ; then
 204                     libpcap=$dir/libpcap.a
 205                     d=$dir
 206                     dnl continue and select the last one that exists
 207             fi
 208     done
 209     if test $libpcap = FAIL ; then
 210             AC_MSG_RESULT(not found)
 211             AC_CHECK_LIB(pcap, main, libpcap="-lpcap")
 212             if test $libpcap = FAIL ; then
 213                     AC_MSG_ERROR(see the INSTALL doc for more info)
 214             fi
 215     else
 216             $1=$libpcap
 217             if test -r $d/pcap.h; then
 218             $2="-I$d $$2"
 219             elif test -r $srcdir/../libpcap/pcap.h; then
 220                     $2="-I$d -I$srcdir/../libpcap $$2"
 221             else
 222                     AC_MSG_ERROR(cannot find pcap.h, see INSTALL)
 223             fi
 224             AC_MSG_RESULT($libpcap)
 225     fi
 226     LIBS="$libpcap $LIBS"
 227     case "$target_os" in
 228
 229     aix*)
 230             pseexe="/lib/pse.exp"
 231             AC_MSG_CHECKING(for $pseexe)
 232             if test -f $pseexe ; then
 233                     AC_MSG_RESULT(yes)
 234                     LIBS="$LIBS -I:$pseexe"
 235             fi
 236             ;;
 237     esac])
 238
 239 dnl
 240 dnl Define RETSIGTYPE and RETSIGVAL
 241 dnl
 242 dnl usage:
 243 dnl
 244 dnl     AC_LBL_TYPE_SIGNAL
 245 dnl
 246 dnl results:
 247 dnl
 248 dnl     RETSIGTYPE (defined)
 249 dnl     RETSIGVAL (defined)
 250 dnl
 251 AC_DEFUN(AC_LBL_TYPE_SIGNAL,
 252     [AC_BEFORE([$0], [AC_LBL_LIBPCAP])
 253     AC_TYPE_SIGNAL
 254     if test "$ac_cv_type_signal" = void ; then
 255             AC_DEFINE(RETSIGVAL,)
 256     else
 257             AC_DEFINE(RETSIGVAL,(0))
 258     fi
 259     case "$target_os" in
 260
 261     irix*)
 262             AC_DEFINE(_BSD_SIGNALS)
 263             ;;
 264
 265     *)
 266             dnl prefer sigset() to sigaction()
 267             AC_CHECK_FUNCS(sigset)
 268             if test $ac_cv_func_sigset = no ; then
 269                     AC_CHECK_FUNCS(sigaction)
 270             fi
 271             ;;
 272     esac])
 273
 274 dnl
 275 dnl If using gcc, make sure we have ANSI ioctl definitions
 276 dnl
 277 dnl usage:
 278 dnl
 279 dnl     AC_LBL_FIXINCLUDES
 280 dnl
 281 AC_DEFUN(AC_LBL_FIXINCLUDES,
 282     [if test "$GCC" = yes ; then
 283             AC_MSG_CHECKING(for ANSI ioctl definitions)
 284             AC_CACHE_VAL(ac_cv_lbl_gcc_fixincludes,
 285                 AC_TRY_COMPILE(
 286                     [/*
 287                      * This generates a "duplicate case value" when fixincludes
 288                      * has not be run.
 289                      */
 290 #               include <sys/types.h>
 291 #               include <sys/time.h>
 292 #               include <sys/ioctl.h>
 293 #               ifdef HAVE_SYS_IOCCOM_H
 294 #               include <sys/ioccom.h>
 295 #               endif],
 296                     [switch (0) {
 297                     case _IO('A', 1):;
 298                     case _IO('B', 1):;
 299                     }],
 300                     ac_cv_lbl_gcc_fixincludes=yes,
 301                     ac_cv_lbl_gcc_fixincludes=no))
 302             AC_MSG_RESULT($ac_cv_lbl_gcc_fixincludes)
 303             if test $ac_cv_lbl_gcc_fixincludes = no ; then
 304                     # Don't cache failure
 305                     unset ac_cv_lbl_gcc_fixincludes
 306                     AC_MSG_ERROR(see the INSTALL for more info)
 307             fi
 308     fi])
 309
 310 dnl
 311 dnl Check for flex, default to lex
 312 dnl Require flex 2.4 or higher
 313 dnl Check for bison, default to yacc
 314 dnl Default to lex/yacc if both flex and bison are not available
 315 dnl Define the yy prefix string if using flex and bison
 316 dnl
 317 dnl usage:
 318 dnl
 319 dnl     AC_LBL_LEX_AND_YACC(lex, yacc, yyprefix)
 320 dnl
 321 dnl results:
 322 dnl
 323 dnl     $1 (lex set)
 324 dnl     $2 (yacc appended)
 325 dnl     $3 (optional flex and bison -P prefix)
 326 dnl
 327 AC_DEFUN(AC_LBL_LEX_AND_YACC,
 328     [AC_ARG_WITH(flex, [  --without-flex          don't use flex])
 329     AC_ARG_WITH(bison, [  --without-bison         don't use bison])
 330     if test "$with_flex" = no ; then
 331             $1=lex
 332     else
 333             AC_CHECK_PROGS($1, flex, lex)
 334     fi
 335     if test "$$1" = flex ; then
 336             # The -V flag was added in 2.4
 337             AC_MSG_CHECKING(for flex 2.4 or higher)
 338             AC_CACHE_VAL(ac_cv_lbl_flex_v24,
 339                 if flex -V >/dev/null 2>&1; then
 340                         ac_cv_lbl_flex_v24=yes
 341                 else
 342                         ac_cv_lbl_flex_v24=no
 343                 fi)
 344             AC_MSG_RESULT($ac_cv_lbl_flex_v24)
 345             if test $ac_cv_lbl_flex_v24 = no ; then
 346                     s="2.4 or higher required"
 347                     AC_MSG_WARN(ignoring obsolete flex executable ($s))
 348                     $1=lex
 349             fi
 350     fi
 351     if test "$with_bison" = no ; then
 352             $2=yacc
 353     else
 354             AC_CHECK_PROGS($2, bison, yacc)
 355     fi
 356     if test "$$2" = bison ; then
 357             $2="$$2 -y"
 358     fi
 359     if test "$$1" != lex -a "$$2" = yacc -o "$$1" = lex -a "$$2" != yacc ; then
 360             AC_MSG_WARN(don't have both flex and bison; reverting to lex/yacc)
 361             $1=lex
 362             $2=yacc
 363     fi
 364     if test "$$1" = flex -a -n "$3" ; then
 365             $1="$$1 -P$3"
 366             $2="$$2 -p $3"
 367     fi])
 368
 369 dnl
 370 dnl Checks to see if union wait is used with WEXITSTATUS()
 371 dnl
 372 dnl usage:
 373 dnl
 374 dnl     AC_LBL_UNION_WAIT
 375 dnl
 376 dnl results:
 377 dnl
 378 dnl     DECLWAITSTATUS (defined)
 379 dnl
 380 AC_DEFUN(AC_LBL_UNION_WAIT,
 381     [AC_MSG_CHECKING(if union wait is used)
 382     AC_CACHE_VAL(ac_cv_lbl_union_wait,
 383         AC_TRY_COMPILE([
 384 #       include <sys/types.h>
 385 #       include <sys/wait.h>],
 386             [int status;
 387             u_int i = WEXITSTATUS(status);
 388             u_int j = waitpid(0, &status, 0);],
 389             ac_cv_lbl_union_wait=no,
 390             ac_cv_lbl_union_wait=yes))
 391     AC_MSG_RESULT($ac_cv_lbl_union_wait)
 392     if test $ac_cv_lbl_union_wait = yes ; then
 393             AC_DEFINE(DECLWAITSTATUS,union wait)
 394     else
 395             AC_DEFINE(DECLWAITSTATUS,int)
 396     fi])
 397
 398 dnl
 399 dnl Checks to see if the sockaddr struct has the 4.4 BSD sa_len member
 400 dnl
 401 dnl usage:
 402 dnl
 403 dnl     AC_LBL_SOCKADDR_SA_LEN
 404 dnl
 405 dnl results:
 406 dnl
 407 dnl     HAVE_SOCKADDR_SA_LEN (defined)
 408 dnl
 409 AC_DEFUN(AC_LBL_SOCKADDR_SA_LEN,
 410     [AC_MSG_CHECKING(if sockaddr struct has sa_len member)
 411     AC_CACHE_VAL(ac_cv_lbl_sockaddr_has_sa_len,
 412         AC_TRY_COMPILE([
 413 #       include <sys/types.h>
 414 #       include <sys/socket.h>],
 415         [u_int i = sizeof(((struct sockaddr *)0)->sa_len)],
 416         ac_cv_lbl_sockaddr_has_sa_len=yes,
 417         ac_cv_lbl_sockaddr_has_sa_len=no))
 418     AC_MSG_RESULT($ac_cv_lbl_sockaddr_has_sa_len)
 419     if test $ac_cv_lbl_sockaddr_has_sa_len = yes ; then
 420             AC_DEFINE(HAVE_SOCKADDR_SA_LEN)
 421     fi])
 422
 423 dnl
 424 dnl Checks to see if -R is used
 425 dnl
 426 dnl usage:
 427 dnl
 428 dnl     AC_LBL_HAVE_RUN_PATH
 429 dnl
 430 dnl results:
 431 dnl
 432 dnl     ac_cv_lbl_have_run_path (yes or no)
 433 dnl
 434 AC_DEFUN(AC_LBL_HAVE_RUN_PATH,
 435     [AC_MSG_CHECKING(for ${CC-cc} -R)
 436     AC_CACHE_VAL(ac_cv_lbl_have_run_path,
 437         [echo 'main(){}' > conftest.c
 438         ${CC-cc} -o conftest conftest.c -R/a1/b2/c3 >conftest.out 2>&1
 439         if test ! -s conftest.out ; then
 440                 ac_cv_lbl_have_run_path=yes
 441         else
 442                 ac_cv_lbl_have_run_path=no
 443         fi
 444         rm -f conftest*])
 445     AC_MSG_RESULT($ac_cv_lbl_have_run_path)
 446     ])
 447
 448 dnl
 449 dnl Due to the stupid way it's implemented, AC_CHECK_TYPE is nearly useless.
 450 dnl
 451 dnl usage:
 452 dnl
 453 dnl     AC_LBL_CHECK_TYPE
 454 dnl
 455 dnl results:
 456 dnl
 457 dnl     int32_t (defined)
 458 dnl     u_int32_t (defined)
 459 dnl
 460 AC_DEFUN(AC_LBL_CHECK_TYPE,
 461     [AC_MSG_CHECKING(for $1 using $CC)
 462     AC_CACHE_VAL(ac_cv_lbl_have_$1,
 463         AC_TRY_COMPILE([
 464 #       include "confdefs.h"
 465 #       include <sys/types.h>
 466 #       if STDC_HEADERS
 467 #       include <stdlib.h>
 468 #       include <stddef.h>
 469 #       endif],
 470         [$1 i],
 471         ac_cv_lbl_have_$1=yes,
 472         ac_cv_lbl_have_$1=no))
 473     AC_MSG_RESULT($ac_cv_lbl_have_$1)
 474     if test $ac_cv_lbl_have_$1 = no ; then
 475             AC_DEFINE($1, $2)
 476     fi])
 477
 478 dnl
 479 dnl Checks to see if unaligned memory accesses fail
 480 dnl
 481 dnl usage:
 482 dnl
 483 dnl     AC_LBL_UNALIGNED_ACCESS
 484 dnl
 485 dnl results:
 486 dnl
 487 dnl     LBL_ALIGN (DEFINED)
 488 dnl
 489 AC_DEFUN(AC_LBL_UNALIGNED_ACCESS,
 490     [AC_MSG_CHECKING(if unaligned accesses fail)
 491     AC_CACHE_VAL(ac_cv_lbl_unaligned_fail,
 492         [case "$target_cpu" in
 493
 494         alpha|hp*|mips|sparc)
 495                 ac_cv_lbl_unaligned_fail=yes
 496                 ;;
 497
 498         *)
 499                 cat >conftest.c <<EOF
 500 #               include <sys/types.h>
 501 #               include <sys/wait.h>
 502 #               include <stdio.h>
 503                 unsigned char a[[5]] = { 1, 2, 3, 4, 5 };
 504                 main() {
 505                 unsigned int i;
 506                 pid_t pid;
 507                 int status;
 508                 /* avoid "core dumped" message */
 509                 pid = fork();
 510                 if (pid <  0)
 511                         exit(2);
 512                 if (pid > 0) {
 513                         /* parent */
 514                         pid = waitpid(pid, &status, 0);
 515                         if (pid < 0)
 516                                 exit(3);
 517                         exit(!WIFEXITED(status));
 518                 }
 519                 /* child */
 520                 i = *(unsigned int *)&a[[1]];
 521                 printf("%d\n", i);
 522                 exit(0);
 523                 }
 524 EOF
 525                 ${CC-cc} -o conftest $CFLAGS $CPPFLAGS $LDFLAGS \
 526                     conftest.c $LIBS >/dev/null 2>&1
 527                 if test ! -x conftest ; then
 528                         dnl failed to compile for some reason
 529                         ac_cv_lbl_unaligned_fail=yes
 530                 else
 531                         ./conftest >conftest.out
 532                         if test ! -s conftest.out ; then
 533                                 ac_cv_lbl_unaligned_fail=yes
 534                         else
 535                                 ac_cv_lbl_unaligned_fail=no
 536                         fi
 537                 fi
 538                 rm -f conftest* core core.conftest
 539                 ;;
 540         esac])
 541     AC_MSG_RESULT($ac_cv_lbl_unaligned_fail)
 542     if test $ac_cv_lbl_unaligned_fail = yes ; then
 543             AC_DEFINE(LBL_ALIGN)
 544     fi])
 545
 546 dnl
 547 dnl If using gcc and the file .devel exists:
 548 dnl     Compile with -g (if supported) and -Wall
 549 dnl     If using gcc 2, do extra prototype checking
 550 dnl     If an os prototype include exists, symlink os-proto.h to it
 551 dnl
 552 dnl usage:
 553 dnl
 554 dnl     AC_LBL_DEVEL(copt)
 555 dnl
 556 dnl results:
 557 dnl
 558 dnl     $1 (copt appended)
 559 dnl     HAVE_OS_PROTO_H (defined)
 560 dnl     os-proto.h (symlinked)
 561 dnl
 562 AC_DEFUN(AC_LBL_DEVEL,
 563     [rm -f os-proto.h
 564     if test "${LBL_CFLAGS+set}" = set; then
 565             $1="$$1 ${LBL_CFLAGS}"
 566     fi
 567     if test -f .devel ; then
 568             if test "$GCC" = yes ; then
 569                     if test "${LBL_CFLAGS+set}" != set; then
 570                             if test "$ac_cv_prog_cc_g" = yes ; then
 571                                     $1="-g $$1"
 572                             fi
 573                             $1="$$1 -Wall"
 574                             if test $ac_cv_lbl_gcc_vers -gt 1 ; then
 575                                     $1="$$1 -Wmissing-prototypes -Wstrict-prototypes"
 576                             fi
 577                     fi
 578             else
 579                     case "$target_os" in
 580
 581                     irix6*)
 582                             V_CCOPT="$V_CCOPT -n32"
 583                             ;;
 584
 585                     *)
 586                             ;;
 587                     esac
 588             fi
 589             os=`echo $target_os | sed -e 's/\([[0-9]][[0-9]]*\)[[^0-9]].*$/\1/'`
 590             name="lbl/os-$os.h"
 591             if test -f $name ; then
 592                     ln -s $name os-proto.h
 593                     AC_DEFINE(HAVE_OS_PROTO_H)
 594             else
 595                     AC_MSG_WARN(can't find $name)
 596             fi
 597     fi])
 598
 599 dnl
 600 dnl Improved version of AC_CHECK_LIB
 601 dnl
 602 dnl Thanks to John Hawkinson (jhawk@mit.edu)
 603 dnl
 604 dnl usage:
 605 dnl
 606 dnl     AC_LBL_CHECK_LIB(LIBRARY, FUNCTION [, ACTION-IF-FOUND [,
 607 dnl         ACTION-IF-NOT-FOUND [, OTHER-LIBRARIES]]])
 608 dnl
 609 dnl results:
 610 dnl
 611 dnl     LIBS
 612 dnl
 613
 614 define(AC_LBL_CHECK_LIB,
 615 [AC_MSG_CHECKING([for $2 in -l$1])
 616 dnl Use a cache variable name containing both the library and function name,
 617 dnl because the test really is for library $1 defining function $2, not
 618 dnl just for library $1.  Separate tests with the same $1 and different $2's
 619 dnl may have different results.
 620 ac_lib_var=`echo $1['_']$2['_']$5 | sed 'y%./+- %__p__%'`
 621 AC_CACHE_VAL(ac_cv_lbl_lib_$ac_lib_var,
 622 [ac_save_LIBS="$LIBS"
 623 LIBS="-l$1 $5 $LIBS"
 624 AC_TRY_LINK(dnl
 625 ifelse([$2], [main], , dnl Avoid conflicting decl of main.
 626 [/* Override any gcc2 internal prototype to avoid an error.  */
 627 ]ifelse(AC_LANG, CPLUSPLUS, [#ifdef __cplusplus
 628 extern "C"
 629 #endif
 630 ])dnl
 631 [/* We use char because int might match the return type of a gcc2
 632     builtin and then its argument prototype would still apply.  */
 633 char $2();
 634 ]),
 635             [$2()],
 636             eval "ac_cv_lbl_lib_$ac_lib_var=yes",
 637             eval "ac_cv_lbl_lib_$ac_lib_var=no")
 638 LIBS="$ac_save_LIBS"
 639 ])dnl
 640 if eval "test \"`echo '$ac_cv_lbl_lib_'$ac_lib_var`\" = yes"; then
 641   AC_MSG_RESULT(yes)
 642   ifelse([$3], ,
 643 [changequote(, )dnl
 644   ac_tr_lib=HAVE_LIB`echo $1 | sed -e 's/[^a-zA-Z0-9_]/_/g' \
 645     -e 'y/abcdefghijklmnopqrstuvwxyz/ABCDEFGHIJKLMNOPQRSTUVWXYZ/'`
 646 changequote([, ])dnl
 647   AC_DEFINE_UNQUOTED($ac_tr_lib)
 648   LIBS="-l$1 $LIBS"
 649 ], [$3])
 650 else
 651   AC_MSG_RESULT(no)
 652 ifelse([$4], , , [$4
 653 ])dnl
 654 fi
 655 ])
 656
 657 dnl
 658 dnl AC_LBL_LIBRARY_NET
 659 dnl
 660 dnl This test is for network applications that need socket() and
 661 dnl gethostbyname() -ish functions.  Under Solaris, those applications
 662 dnl need to link with "-lsocket -lnsl".  Under IRIX, they need to link
 663 dnl with "-lnsl" but should *not* link with "-lsocket" because
 664 dnl libsocket.a breaks a number of things (for instance:
 665 dnl gethostbyname() under IRIX 5.2, and snoop sockets under most
 666 dnl versions of IRIX).
 667 dnl
 668 dnl Unfortunately, many application developers are not aware of this,
 669 dnl and mistakenly write tests that cause -lsocket to be used under
 670 dnl IRIX.  It is also easy to write tests that cause -lnsl to be used
 671 dnl under operating systems where neither are necessary (or useful),
 672 dnl such as SunOS 4.1.4, which uses -lnsl for TLI.
 673 dnl
 674 dnl This test exists so that every application developer does not test
 675 dnl this in a different, and subtly broken fashion.
 676
 677 dnl It has been argued that this test should be broken up into two
 678 dnl seperate tests, one for the resolver libraries, and one for the
 679 dnl libraries necessary for using Sockets API. Unfortunately, the two
 680 dnl are carefully intertwined and allowing the autoconf user to use
 681 dnl them independantly potentially results in unfortunate ordering
 682 dnl dependancies -- as such, such component macros would have to
 683 dnl carefully use indirection and be aware if the other components were
 684 dnl executed. Since other autoconf macros do not go to this trouble,
 685 dnl and almost no applications use sockets without the resolver, this
 686 dnl complexity has not been implemented.
 687 dnl
 688 dnl The check for libresolv is in case you are attempting to link
 689 dnl statically and happen to have a libresolv.a lying around (and no
 690 dnl libnsl.a).
 691 dnl
 692 AC_DEFUN(AC_LBL_LIBRARY_NET, [
 693     # Most operating systems have gethostbyname() in the default searched
 694     # libraries (i.e. libc):
 695     AC_CHECK_FUNC(gethostbyname, ,
 696         # Some OSes (eg. Solaris) place it in libnsl:
 697         AC_LBL_CHECK_LIB(nsl, gethostbyname, ,
 698             # Some strange OSes (SINIX) have it in libsocket:
 699             AC_LBL_CHECK_LIB(socket, gethostbyname, ,
 700                 # Unfortunately libsocket sometimes depends on libnsl.
 701                 # AC_CHECK_LIB's API is essentially broken so the
 702                 # following ugliness is necessary:
 703                 AC_LBL_CHECK_LIB(socket, gethostbyname,
 704                     LIBS="-lsocket -lnsl $LIBS",
 705                     AC_CHECK_LIB(resolv, gethostbyname),
 706                     -lnsl))))
 707     AC_CHECK_FUNC(socket, , AC_CHECK_LIB(socket, socket, ,
 708         AC_LBL_CHECK_LIB(socket, socket, LIBS="-lsocket -lnsl $LIBS", ,
 709             -lnsl)))
 710     # DLPI needs putmsg under HPUX so test for -lstr while we're at it
 711     AC_CHECK_LIB(str, putmsg)
 712     ])
 713
 714 dnl Copyright (c) 1999 WIDE Project. All rights reserved.
 715 dnl
 716 dnl Redistribution and use in source and binary forms, with or without
 717 dnl modification, are permitted provided that the following conditions
 718 dnl are met:
 719 dnl 1. Redistributions of source code must retain the above copyright
 720 dnl    notice, this list of conditions and the following disclaimer.
 721 dnl 2. Redistributions in binary form must reproduce the above copyright
 722 dnl    notice, this list of conditions and the following disclaimer in the
 723 dnl    documentation and/or other materials provided with the distribution.
 724 dnl 3. Neither the name of the project nor the names of its contributors
 725 dnl    may be used to endorse or promote products derived from this software
 726 dnl    without specific prior written permission.
 727 dnl
 728 dnl THIS SOFTWARE IS PROVIDED BY THE PROJECT AND CONTRIBUTORS ``AS IS'' AND
 729 dnl ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
 730 dnl IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
 731 dnl ARE DISCLAIMED.  IN NO EVENT SHALL THE PROJECT OR CONTRIBUTORS BE LIABLE
 732 dnl FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
 733 dnl DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
 734 dnl OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
 735 dnl HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
 736 dnl LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
 737 dnl OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
 738 dnl SUCH DAMAGE.
 739
 740 dnl
 741 dnl Checks to see if AF_INET6 is defined
 742 AC_DEFUN(AC_CHECK_AF_INET6, [
 743         AC_MSG_CHECKING(for AF_INET6)
 744         AC_CACHE_VAL($1,
 745         AC_TRY_COMPILE([
 746 #               include <sys/types.h>
 747 #               include <sys/socket.h>],
 748                 [int a = AF_INET6],
 749                 $1=yes,
 750                 $1=no))
 751         AC_MSG_RESULT($$1)
 752                 if test $$1 = yes ; then
 753                         AC_DEFINE(HAVE_AF_INET6)
 754         fi
 755 ])
 756
 757 dnl
 758 dnl Checks to see if the sockaddr struct has the 4.4 BSD sa_len member
 759 dnl borrowed from LBL libpcap
 760 AC_DEFUN(AC_CHECK_SA_LEN, [
 761         AC_MSG_CHECKING(if sockaddr struct has sa_len member)
 762         AC_CACHE_VAL($1,
 763         AC_TRY_COMPILE([
 764 #               include <sys/types.h>
 765 #               include <sys/socket.h>],
 766                 [u_int i = sizeof(((struct sockaddr *)0)->sa_len)],
 767                 $1=yes,
 768                 $1=no))
 769         AC_MSG_RESULT($$1)
 770                 if test $$1 = yes ; then
 771                         AC_DEFINE(HAVE_SOCKADDR_SA_LEN)
 772         fi
 773 ])
 774
 775 dnl
 776 dnl Checks for portable prototype declaration macro
 777 AC_DEFUN(AC_CHECK_PORTABLE_PROTO,  [
 778         AC_MSG_CHECKING(for __P)
 779         AC_CACHE_VAL($1,
 780         AC_TRY_COMPILE([
 781 #               include <unistd.h>],
 782                 [int f __P(())],
 783                 $1=yes,
 784                 $1=no))
 785         AC_MSG_RESULT($$1)
 786         if test $$1 = yes; then
 787                 AC_DEFINE(HAVE_PORTABLE_PROTOTYPE)
 788         fi
 789 ])
 790
 791 dnl checks for u_intXX_t
 792 AC_DEFUN(AC_CHECK_BITTYPES, [
 793         $1=yes
 794 dnl check for u_int8_t
 795         AC_MSG_CHECKING(for u_int8_t)
 796         AC_CACHE_VAL(ac_cv_u_int8_t,
 797         AC_TRY_COMPILE([
 798 #               include <sys/types.h>],
 799                 [u_int8_t i],
 800                 ac_cv_u_int8_t=yes,
 801                 ac_cv_u_int8_t=no))
 802         AC_MSG_RESULT($ac_cv_u_int8_t)
 803         if test $ac_cv_u_int8_t = yes; then
 804                 AC_DEFINE(HAVE_U_INT8_T)
 805         else
 806                 $1=no
 807         fi
 808 dnl check for u_int16_t
 809         AC_MSG_CHECKING(for u_int16_t)
 810         AC_CACHE_VAL(ac_cv_u_int16_t,
 811         AC_TRY_COMPILE([
 812 #               include <sys/types.h>],
 813                 [u_int16_t i],
 814                 ac_cv_u_int16_t=yes,
 815                 ac_cv_u_int16_t=no))
 816         AC_MSG_RESULT($ac_cv_u_int16_t)
 817         if test $ac_cv_u_int16_t = yes; then
 818                 AC_DEFINE(HAVE_U_INT16_T)
 819         else
 820                 $1=no
 821         fi
 822 dnl check for u_int32_t
 823         AC_MSG_CHECKING(for u_int32_t)
 824         AC_CACHE_VAL(ac_cv_u_int32_t,
 825         AC_TRY_COMPILE([
 826 #               include <sys/types.h>],
 827                 [u_int32_t i],
 828                 ac_cv_u_int32_t=yes,
 829                 ac_cv_u_int32_t=no))
 830         AC_MSG_RESULT($ac_cv_u_int32_t)
 831         if test $ac_cv_u_int32_t = yes; then
 832                 AC_DEFINE(HAVE_U_INT32_T)
 833         else
 834                 $1=no
 835         fi
 836 ])
 837
 838 dnl
 839 dnl Checks for addrinfo structure
 840 AC_DEFUN(AC_STRUCT_ADDRINFO, [
 841         AC_MSG_CHECKING(for addrinfo)
 842         AC_CACHE_VAL($1,
 843         AC_TRY_COMPILE([
 844 #               include <netdb.h>],
 845                 [struct addrinfo a],
 846                 $1=yes,
 847                 $1=no))
 848         AC_MSG_RESULT($$1)
 849         if test $$1 = yes; then
 850                 AC_DEFINE(HAVE_ADDRINFO)
 851         fi
 852 ])
 853
 854 dnl
 855 dnl Checks for sockaddr_storage structure
 856 AC_DEFUN(AC_STRUCT_SA_STORAGE, [
 857         AC_MSG_CHECKING(for sockaddr_storage)
 858         AC_CACHE_VAL($1,
 859         AC_TRY_COMPILE([
 860 #               include <sys/types.h>
 861 #               include <sys/socket.h>],
 862                 [struct sockaddr_storage s],
 863                 $1=yes,
 864                 $1=no))
 865         AC_MSG_RESULT($$1)
 866         if test $$1 = yes; then
 867                 AC_DEFINE(HAVE_SOCKADDR_STORAGE)
 868         fi
 869 ])
 870
 871 dnl
 872 dnl Checks for macro of IP address size
 873 AC_DEFUN(AC_CHECK_ADDRSZ, [
 874         $1=yes
 875 dnl check for INADDRSZ
 876         AC_MSG_CHECKING(for INADDRSZ)
 877         AC_CACHE_VAL(ac_cv_inaddrsz,
 878         AC_TRY_COMPILE([
 879 #               include <arpa/nameser.h>],
 880                 [int a = INADDRSZ],
 881                 ac_cv_inaddrsz=yes,
 882                 ac_cv_inaddrsz=no))
 883         AC_MSG_RESULT($ac_cv_inaddrsz)
 884         if test $ac_cv_inaddrsz = yes; then
 885                 AC_DEFINE(HAVE_INADDRSZ)
 886         else
 887                 $1=no
 888         fi
 889 dnl check for IN6ADDRSZ
 890         AC_MSG_CHECKING(for IN6ADDRSZ)
 891         AC_CACHE_VAL(ac_cv_in6addrsz,
 892         AC_TRY_COMPILE([
 893 #               include <arpa/nameser.h>],
 894                 [int a = IN6ADDRSZ],
 895                 ac_cv_in6addrsz=yes,
 896                 ac_cv_in6addrsz=no))
 897         AC_MSG_RESULT($ac_cv_in6addrsz)
 898         if test $ac_cv_in6addrsz = yes; then
 899                 AC_DEFINE(HAVE_IN6ADDRSZ)
 900         else
 901                 $1=no
 902         fi
 903 ])
 904
 905 dnl
 906 dnl check for RES_USE_INET6
 907 AC_DEFUN(AC_CHECK_RES_USE_INET6, [
 908         AC_MSG_CHECKING(for RES_USE_INET6)
 909         AC_CACHE_VAL($1,
 910         AC_TRY_COMPILE([
 911 #               include <sys/types.h>
 912 #               include <netinet/in.h>
 913 #               include <resolv.h>],
 914                 [int a = RES_USE_INET6],
 915                 $1=yes,
 916                 $1=no))
 917         AC_MSG_RESULT($$1)
 918         if test $$1 = yes; then
 919                 AC_DEFINE(HAVE_RES_USE_INET6)
 920         fi
 921 ])
 922
 923 dnl
 924 dnl check for AAAA
 925 AC_DEFUN(AC_CHECK_AAAA, [
 926         AC_MSG_CHECKING(for AAAA)
 927         AC_CACHE_VAL($1,
 928         AC_TRY_COMPILE([
 929 #               include <sys/types.h>
 930 #               include <arpa/nameser.h>],
 931                 [int a = T_AAAA],
 932                 $1=yes,
 933                 $1=no))
 934         AC_MSG_RESULT($$1)
 935         if test $$1 = yes; then
 936                 AC_DEFINE(HAVE_AAAA)
 937         fi
 938 ])
 939
 940 dnl
 941 dnl check for struct res_state_ext
 942 AC_DEFUN(AC_STRUCT_RES_STATE_EXT, [
 943         AC_MSG_CHECKING(for res_state_ext)
 944         AC_CACHE_VAL($1,
 945         AC_TRY_COMPILE([
 946 #               include <sys/types.h>
 947 #               include <netinet/in.h>
 948 #               include <netinet6/in6.h>
 949 #               include <resolv.h>],
 950                 [struct __res_state_ext e],
 951                 $1=yes,
 952                 $1=no))
 953         AC_MSG_RESULT($$1)
 954         if test $$1 = yes; then
 955                 AC_DEFINE(HAVE_RES_STATE_EXT)
 956         fi
 957 ])
 958
 959 dnl
 960 dnl check for struct res_state_ext
 961 AC_DEFUN(AC_STRUCT_RES_STATE, [
 962         AC_MSG_CHECKING(for nsort in res_state)
 963         AC_CACHE_VAL($1,
 964         AC_TRY_COMPILE([
 965 #               include <sys/types.h>
 966 #               include <netinet/in.h>
 967 #               include <netinet6/in6.h>
 968 #               include <resolv.h>],
 969                 [struct __res_state e; e.nsort = 0],
 970                 $1=yes,
 971                 $1=no))
 972         AC_MSG_RESULT($$1)
 973         if test $$1 = yes; then
 974                 AC_DEFINE(HAVE_NEW_RES_STATE)
 975         fi
 976 ])
 977