The Tcpdump Group git mirrors - tcpdump/blob - configure.ac

   1 dnl Copyright (c) 1994, 1995, 1996, 1997
   2 dnl     The Regents of the University of California.  All rights reserved.
   3 dnl
   4 dnl Process this file with autoconf to produce a configure script.
   5 dnl
   6
   7 #
   8 # See
   9 #
  10 #       https://ftp.gnu.org/gnu/config/README
  11 #
  12 # for the URLs to use to fetch new versions of config.guess and
  13 # config.sub.
  14 #
  15
  16 AC_PREREQ([2.69])
  17 AC_INIT([tcpdump],[m4_esyscmd_s(cat VERSION)])
  18 AC_CONFIG_SRCDIR(tcpdump.c)
  19
  20 AC_CANONICAL_HOST
  21
  22 AC_LBL_C_INIT_BEFORE_CC(V_INCLS)
  23 #
  24 # Try to enable as many C99 features as we can.
  25 # At minimum, we want C++/C99-style // comments.
  26 #
  27 AC_PROG_CC_C99
  28 if test "$ac_cv_prog_cc_c99" = "no"; then
  29         AC_MSG_WARN([The C compiler does not support C99; there may be compiler errors])
  30 fi
  31 AC_LBL_C_INIT(V_CCOPT, V_INCLS)
  32 AC_C_INLINE
  33
  34 AC_CHECK_HEADERS(fcntl.h rpc/rpc.h rpc/rpcent.h net/if.h)
  35
  36 case "$host_os" in
  37
  38 darwin*)
  39         AC_ARG_ENABLE(universal,
  40         AS_HELP_STRING([--disable-universal],[don't build universal on macOS]))
  41         if test "$enable_universal" != "no"; then
  42                 case "$host_os" in
  43
  44                 darwin9.*)
  45                         #
  46                         # Leopard.  Build for x86 and 32-bit PowerPC, with
  47                         # x86 first.  (That's what Apple does.)
  48                         #
  49                         V_CCOPT="$V_CCOPT -arch i386 -arch ppc"
  50                         LDFLAGS="$LDFLAGS -arch i386 -arch ppc"
  51                         ;;
  52
  53                 darwin10.*)
  54                         #
  55                         # Snow Leopard.  Build for x86-64 and x86, with
  56                         # x86-64 first.  (That's what Apple does.)
  57                         #
  58                         V_CCOPT="$V_CCOPT -arch x86_64 -arch i386"
  59                         LDFLAGS="$LDFLAGS -arch x86_64 -arch i386"
  60                         ;;
  61                 esac
  62         fi
  63         ;;
  64 esac
  65
  66 AC_ARG_WITH([smi],
  67    [AS_HELP_STRING([--with-smi],
  68      [link with libsmi (allows to load MIBs on the fly to decode SNMP packets) [default=yes, if available]])],
  69    [],
  70    [with_smi=yes])
  71
  72 if test "x$with_smi" != "xno" ; then
  73         AC_CHECK_HEADER(smi.h,
  74         [
  75                 #
  76                 # OK, we found smi.h.  Do we have libsmi with smiInit?
  77                 #
  78                 AC_CHECK_LIB(smi, smiInit,
  79                 [
  80                         #
  81                         # OK, we have libsmi with smiInit.  Can we use it?
  82                         #
  83                         AC_MSG_CHECKING([whether to enable libsmi])
  84                         savedlibs="$LIBS"
  85                         LIBS="-lsmi $LIBS"
  86                         AC_RUN_IFELSE([AC_LANG_SOURCE([[
  87 /* libsmi available check */
  88 #include <stdio.h>
  89 #include <stdlib.h>
  90 #include <string.h>
  91 #include <smi.h>
  92 int main()
  93 {
  94   int current, revision, age, n;
  95   const int required = 2;
  96   if (smiInit(""))
  97     exit(1);
  98   if (strcmp(SMI_LIBRARY_VERSION, smi_library_version))
  99     exit(2);
 100   n = sscanf(smi_library_version, "%d:%d:%d", &current, &revision, &age);
 101   if (n != 3)
 102     exit(3);
 103   if (required < current - age || required > current)
 104     exit(4);
 105   exit(0);
 106 }
 107                                 ]])
 108                                 ],
 109                                 [
 110                                         AC_MSG_RESULT(yes)
 111                                         AC_DEFINE(USE_LIBSMI, 1,
 112                                             [Define if you enable support for libsmi])
 113                                 ],
 114                                 [
 115                                         dnl autoconf documentation says that
 116                                         dnl $? contains the exit value.
 117                                         dnl reality is that it does not.
 118                                         dnl We leave this in just in case
 119                                         dnl autoconf ever comes back to
 120                                         dnl match the documentation.
 121                                         case $? in
 122                                           1) AC_MSG_RESULT(no - smiInit failed) ;;
 123                                           2) AC_MSG_RESULT(no - header/library version mismatch) ;;
 124                                           3) AC_MSG_RESULT(no - can't determine library version) ;;
 125                                           4) AC_MSG_RESULT(no - too old) ;;
 126                                           *) AC_MSG_RESULT(no) ;;
 127                                         esac
 128                                         LIBS="$savedlibs"
 129                                 ],
 130                                 [
 131                                         AC_MSG_RESULT(not when cross-compiling)
 132                                         LIBS="$savedlibs"
 133                                 ]
 134                         )
 135                 ])
 136         ])
 137 fi
 138
 139 AC_MSG_CHECKING([whether to enable the instrument functions code])
 140 AC_ARG_ENABLE([instrument-functions],
 141    [AS_HELP_STRING([--enable-instrument-functions],
 142      [enable instrument functions code [default=no]])],
 143    [],
 144    [enableval=no])
 145 case "$enableval" in
 146 yes)    AC_MSG_RESULT(yes)
 147         AC_CHECK_LIB([bfd], [bfd_init],
 148             [true],
 149             [AC_MSG_ERROR(
 150                [--enable-instrument-functions was given, but test for library libbfd failed. Please install the 'binutils-dev' package.])],
 151             [])
 152         AC_DEFINE(ENABLE_INSTRUMENT_FUNCTIONS, 1,
 153             [define if you want to build the instrument functions code])
 154         LOCALSRC="$LOCALSRC instrument-functions.c"
 155         # Add '-finstrument-functions' instrumentation option to generate
 156         # instrumentation calls for entry and exit to functions.
 157         # Try to avoid Address Space Layout Randomization (ALSR).
 158         CFLAGS="$CFLAGS -O0 -ggdb -finstrument-functions -fno-stack-protector -fno-pic"
 159         LDFLAGS="$LDFLAGS -O0 -ggdb -fno-stack-protector -no-pie"
 160         LIBS="$LIBS -lbfd"
 161         ;;
 162 *)      AC_MSG_RESULT(no)
 163         ;;
 164 esac
 165
 166 AC_MSG_CHECKING([whether to enable the possibly-buggy SMB printer])
 167 AC_ARG_ENABLE([smb],
 168    [AS_HELP_STRING([--enable-smb],
 169      [enable possibly-buggy SMB printer [default=no]])],
 170    [],
 171    [enableval=no])
 172 case "$enableval" in
 173 yes)    AC_MSG_RESULT(yes)
 174         AC_DEFINE(ENABLE_SMB, 1,
 175             [define if you want to build the possibly-buggy SMB printer])
 176         LOCALSRC="print-smb.c smbutil.c $LOCALSRC"
 177         ;;
 178 *)      AC_MSG_RESULT(no)
 179         ;;
 180 esac
 181
 182 AC_ARG_WITH(user, [  --with-user=USERNAME    drop privileges by default to USERNAME])
 183 AC_MSG_CHECKING([whether to drop root privileges by default])
 184 if test ! -z "$withval" && test "$withval" != "no" ; then
 185        if test "$withval" = "yes" ; then
 186            AC_MSG_ERROR([--with-user requires a username])
 187        fi
 188        AC_DEFINE_UNQUOTED(WITH_USER, "$withval",
 189            [define if should drop privileges by default])
 190        AC_MSG_RESULT([yes, to user "$withval"])
 191 else
 192        AC_MSG_RESULT(no)
 193 fi
 194
 195 AC_ARG_WITH(chroot, [  --with-chroot=DIRECTORY when dropping privileges, chroot to DIRECTORY])
 196 AC_MSG_CHECKING([whether to chroot])
 197 if test ! -z "$withval" && test "$withval" != "no" ; then
 198        if test "$withval" = "yes" ; then
 199            AC_MSG_ERROR([--with-chroot requires a directory])
 200        fi
 201        AC_DEFINE_UNQUOTED(WITH_CHROOT, "$withval",
 202            [define if should chroot when dropping privileges])
 203        AC_MSG_RESULT([yes, to directory "$withval"])
 204 else
 205        AC_MSG_RESULT(no)
 206 fi
 207
 208 AC_ARG_WITH(sandbox-capsicum,
 209         AS_HELP_STRING([--with-sandbox-capsicum],
 210                        [use Capsicum security functions @<:@default=yes, if available@:>@]))
 211 #
 212 # Check whether various functions are available.  If any are, set
 213 # ac_lbl_capsicum_function_seen to yes; if any are not, set
 214 # ac_lbl_capsicum_function_not_seen to yes.
 215 #
 216 # We don't check cap_rights_init(), as it's a macro, wrapping another
 217 # function, in at least some versions of FreeBSD, and AC_CHECK_FUNCS()
 218 # doesn't handle that.
 219 #
 220 # All of the ones we check for must be available in order to enable
 221 # capsicum sandboxing.
 222 #
 223 # XXX - do we need to check for all of them, or are there some that, if
 224 # present, imply others are present?
 225 #
 226 if test -z "$with_sandbox_capsicum" || test "$with_sandbox_capsicum" != "no" ; then
 227         #
 228         # First, make sure we have the required header.
 229         #
 230         AC_CHECK_HEADER(sys/capsicum.h,
 231         [
 232                 #
 233                 # We do; now make sure we have the required functions.
 234                 #
 235                 AC_CHECK_FUNCS(cap_enter cap_rights_limit cap_ioctls_limit openat,
 236                     ac_lbl_capsicum_function_seen=yes,
 237                     ac_lbl_capsicum_function_not_seen=yes)
 238         ])
 239         AC_CHECK_LIB(casper, cap_init, LIBS="$LIBS -lcasper")
 240         AC_CHECK_LIB(cap_dns, cap_gethostbyaddr, LIBS="$LIBS -lcap_dns")
 241 fi
 242 AC_MSG_CHECKING([whether to sandbox using capsicum])
 243 if test "x$ac_lbl_capsicum_function_seen" = "xyes" -a "x$ac_lbl_capsicum_function_not_seen" != "xyes"; then
 244         AC_DEFINE(HAVE_CAPSICUM, 1, [capsicum support available])
 245         AC_MSG_RESULT(yes)
 246 else
 247         AC_MSG_RESULT(no)
 248 fi
 249 AC_MSG_CHECKING([whether to sandbox using Casper library])
 250 if test "x$ac_cv_lib_casper_cap_init" = "xyes" -a "x$ac_cv_lib_cap_dns_cap_gethostbyaddr" = "xyes"; then
 251         AC_DEFINE(HAVE_CASPER, 1, [Casper support available])
 252         AC_MSG_RESULT(yes)
 253 else
 254         AC_MSG_RESULT(no)
 255 fi
 256
 257 #
 258 # We must check this before checking whether to check the OS's IPv6,
 259 # support because, on some platforms (such as SunOS 5.x), the test
 260 # program requires the extra networking libraries.
 261 #
 262 AC_LBL_LIBRARY_NET
 263
 264 AC_REPLACE_FUNCS(strlcat strlcpy strsep getservent getopt_long)
 265 AC_CHECK_FUNCS(fork vfork)
 266 AC_CHECK_FUNCS(setlinebuf)
 267
 268 #
 269 # Make sure we have snprintf(); we require it.
 270 #
 271 AC_CHECK_FUNC(snprintf,,
 272     AC_MSG_ERROR([snprintf() is required but wasn't found]))
 273
 274 #
 275 # It became apparent at some point that using a suitable C99 compiler does not
 276 # automatically mean snprintf(3) implementation in the libc supports all the
 277 # modifiers and specifiers used in the project, so let's test that before the
 278 # build, not after.
 279 #
 280 # Testing the sizeof_t length modifier takes making an snprintf() call and
 281 # comparing the actual result with the expected result.  If this fails, it will
 282 # most likely happen at run time, not compile time.
 283 #
 284 # Testing the 64-bit conversion specifiers in addition to that requires the
 285 # <inttypes.h> header to be present and the macros to be defined, so if this
 286 # fails, it will more likely happen at compile time.
 287 #
 288 AC_MSG_CHECKING([whether snprintf is suitable])
 289 AC_RUN_IFELSE(
 290     [
 291         AC_LANG_SOURCE([[
 292 #include <stdio.h>
 293 #include <string.h>
 294 #include <inttypes.h>
 295 #include <sys/types.h>
 296
 297 int main()
 298 {
 299   char buf[100];
 300   uint64_t t = (uint64_t)1 << 32;
 301
 302   snprintf(buf, sizeof(buf), "%zu", sizeof(buf));
 303   if (strncmp(buf, "100", sizeof(buf)))
 304     return 1;
 305
 306   snprintf(buf, sizeof(buf), "%zd", -sizeof(buf));
 307   if (strncmp(buf, "-100", sizeof(buf)))
 308     return 2;
 309
 310   snprintf(buf, sizeof(buf), "%" PRId64, -t);
 311   if (strncmp(buf, "-4294967296", sizeof(buf)))
 312     return 3;
 313
 314   snprintf(buf, sizeof(buf), "0o%" PRIo64, t);
 315   if (strncmp(buf, "0o40000000000", sizeof(buf)))
 316     return 4;
 317
 318   snprintf(buf, sizeof(buf), "0x%" PRIx64, t);
 319   if (strncmp(buf, "0x100000000", sizeof(buf)))
 320     return 5;
 321
 322   snprintf(buf, sizeof(buf), "%" PRIu64, t);
 323   if (strncmp(buf, "4294967296", sizeof(buf)))
 324     return 6;
 325
 326   return 0;
 327 }
 328         ]])
 329     ],
 330     [
 331         AC_MSG_RESULT(yes)
 332     ],
 333     [
 334         AC_MSG_RESULT(no)
 335         AC_MSG_ERROR(
 336 [The snprintf(3) implementation in this libc is not suitable,
 337 tcpdump would not work correctly even if it managed to compile.])
 338     ],
 339     [
 340         AC_MSG_RESULT(not while cross-compiling)
 341     ]
 342 )
 343
 344 AC_CHECK_LIB(rpc, main)         dnl It's unclear why we might need -lrpc
 345
 346 dnl Some platforms may need -lnsl for getrpcbynumber.
 347 AC_SEARCH_LIBS(getrpcbynumber, nsl,
 348     AC_DEFINE(HAVE_GETRPCBYNUMBER, 1, [define if you have getrpcbynumber()]))
 349
 350 AC_LBL_LIBPCAP(V_PCAPDEP, V_INCLS)
 351
 352 #
 353 # Check for these after AC_LBL_LIBPCAP, so we link with the appropriate
 354 # libraries (e.g., "-lsocket -lnsl" on Solaris).
 355 #
 356 # You are in a twisty little maze of UN*Xes, all different.
 357 # Some might not have ether_ntohost().
 358 # Some might have it and declare it in <net/ethernet.h>.
 359 # Some might have it and declare it in <netinet/ether.h>
 360 # Some might have it and declare it in <sys/ethernet.h>.
 361 # Some might have it and declare it in <arpa/inet.h>.
 362 # Some might have it and declare it in <netinet/if_ether.h>.
 363 # Some might have it and not declare it in any header file.
 364 #
 365 # Before you is a C compiler.
 366 #
 367 AC_CHECK_FUNCS(ether_ntohost, [
 368     AC_CACHE_CHECK(for buggy ether_ntohost, ac_cv_buggy_ether_ntohost, [
 369         AC_RUN_IFELSE([AC_LANG_SOURCE([[
 370                 #include <netdb.h>
 371                 #include <netinet/ether.h>
 372                 #include <stdlib.h>
 373                 #include <sys/types.h>
 374                 #include <sys/param.h>
 375                 #include <sys/socket.h>
 376
 377                 int
 378                 main(int argc, char **argv)
 379                 {
 380                         u_char ea[6] = { 0xff, 0xff, 0xff, 0xff, 0xff };
 381                         char name[MAXHOSTNAMELEN];
 382
 383                         ether_ntohost(name, (struct ether_addr *)ea);
 384                         exit(0);
 385                 }
 386         ]])
 387         ], [ac_cv_buggy_ether_ntohost=no],
 388            [ac_cv_buggy_ether_ntohost=yes],
 389            [ac_cv_buggy_ether_ntohost="not while cross-compiling"])])
 390     if test "$ac_cv_buggy_ether_ntohost" = "no"; then
 391         AC_DEFINE(USE_ETHER_NTOHOST, 1,
 392             [define if you have ether_ntohost() and it works])
 393     fi
 394 ])
 395 if test "$ac_cv_func_ether_ntohost" = yes -a \
 396     "$ac_cv_buggy_ether_ntohost" = "no"; then
 397         #
 398         # OK, we have ether_ntohost().  Is it declared in <net/ethernet.h>?
 399         #
 400         # This test fails if we don't have <net/ethernet.h> or if we do
 401         # but it doesn't declare ether_ntohost().
 402         #
 403         AC_CHECK_DECL(ether_ntohost,
 404             [
 405                 AC_DEFINE(NET_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
 406                     [Define to 1 if net/ethernet.h declares `ether_ntohost'])
 407             ],,
 408             [
 409 #include <net/ethernet.h>
 410             ])
 411         #
 412         # Did that succeed?
 413         #
 414         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 415                 #
 416                 # No, how about <netinet/ether.h>, as on Linux?
 417                 #
 418                 # This test fails if we don't have <netinet/ether.h>
 419                 # or if we do but it doesn't declare ether_ntohost().
 420                 #
 421                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 422                 # treat the previous failure as a cached value and
 423                 # suppress the next test.
 424                 #
 425                 unset ac_cv_have_decl_ether_ntohost
 426                 AC_CHECK_DECL(ether_ntohost,
 427                     [
 428                         AC_DEFINE(NETINET_ETHER_H_DECLARES_ETHER_NTOHOST,,
 429                             [Define to 1 if netinet/ether.h declares `ether_ntohost'])
 430                     ],,
 431                     [
 432 #include <netinet/ether.h>
 433                     ])
 434         fi
 435         #
 436         # Did that succeed?
 437         #
 438         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 439                 #
 440                 # No, how about <sys/ethernet.h>, as on Solaris 10
 441                 # and later?
 442                 #
 443                 # This test fails if we don't have <sys/ethernet.h>
 444                 # or if we do but it doesn't declare ether_ntohost().
 445                 #
 446                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 447                 # treat the previous failure as a cached value and
 448                 # suppress the next test.
 449                 #
 450                 unset ac_cv_have_decl_ether_ntohost
 451                 AC_CHECK_DECL(ether_ntohost,
 452                     [
 453                         AC_DEFINE(SYS_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
 454                             [Define to 1 if sys/ethernet.h declares `ether_ntohost'])
 455                     ],,
 456                     [
 457 #include <sys/ethernet.h>
 458                     ])
 459         fi
 460         #
 461         # Did that succeed?
 462         #
 463         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 464                 #
 465                 # No, how about <arpa/inet.h>, as in AIX?
 466                 #
 467                 # This test fails if we don't have <arpa/inet.h>
 468                 # (if we have ether_ntohost(), we should have
 469                 # networking, and if we have networking, we should
 470                 # have <arpa/inet.h>) or if we do but it doesn't
 471                 # declare ether_ntohost().
 472                 #
 473                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 474                 # treat the previous failure as a cached value and
 475                 # suppress the next test.
 476                 #
 477                 unset ac_cv_have_decl_ether_ntohost
 478                 AC_CHECK_DECL(ether_ntohost,
 479                     [
 480                         AC_DEFINE(ARPA_INET_H_DECLARES_ETHER_NTOHOST,,
 481                             [Define to 1 if arpa/inet.h declares `ether_ntohost'])
 482                     ],,
 483                     [
 484 #include <arpa/inet.h>
 485                     ])
 486         fi
 487         #
 488         # Did that succeed?
 489         #
 490         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 491                 #
 492                 # No, how about <netinet/if_ether.h>?
 493                 # On some platforms, it requires <net/if.h> and
 494                 # <netinet/in.h>, and we always include it with
 495                 # both of them, so test it with both of them.
 496                 #
 497                 # This test fails if we don't have <netinet/if_ether.h>
 498                 # and the headers we include before it, or if we do but
 499                 # <netinet/if_ether.h> doesn't declare ether_hostton().
 500                 #
 501                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 502                 # treat the previous failure as a cached value and
 503                 # suppress the next test.
 504                 #
 505                 unset ac_cv_have_decl_ether_ntohost
 506                 AC_CHECK_DECL(ether_ntohost,
 507                     [
 508                         AC_DEFINE(NETINET_IF_ETHER_H_DECLARES_ETHER_NTOHOST,,
 509                             [Define to 1 if netinet/if_ether.h declares `ether_ntohost'])
 510                     ],,
 511                     [
 512 #include <sys/types.h>
 513 #include <sys/socket.h>
 514 #include <net/if.h>
 515 #include <netinet/in.h>
 516 #include <netinet/if_ether.h>
 517                     ])
 518         fi
 519         #
 520         # After all that, is ether_ntohost() declared?
 521         #
 522         if test "$ac_cv_have_decl_ether_ntohost" = yes; then
 523                 #
 524                 # Yes.
 525                 #
 526                 AC_DEFINE(HAVE_DECL_ETHER_NTOHOST, 1,
 527                     [Define to 1 if you have the declaration of `ether_ntohost'])
 528         else
 529                 #
 530                 # No, we'll have to declare it ourselves.
 531                 # Do we have "struct ether_addr" if we include
 532                 # <netinet/if_ether.h>?
 533                 #
 534                 AC_CHECK_TYPES(struct ether_addr,,,
 535                     [
 536                         #include <sys/types.h>
 537                         #include <sys/socket.h>
 538                         #include <net/if.h>
 539                         #include <netinet/in.h>
 540                         #include <netinet/if_ether.h>
 541                     ])
 542         fi
 543 fi
 544
 545 dnl
 546 dnl Check for "pcap_list_datalinks()" and use a substitute version if
 547 dnl it's not present.  If it is present, check for "pcap_free_datalinks()";
 548 dnl if it's not present, we don't replace it for now.  (We could do so
 549 dnl on UN*X, but not on Windows, where hilarity ensues if a program
 550 dnl built with one version of the MSVC support library tries to free
 551 dnl something allocated by a library built with another version of
 552 dnl the MSVC support library.)
 553 dnl
 554 AC_CHECK_FUNC(pcap_list_datalinks,
 555         [
 556             AC_DEFINE(HAVE_PCAP_LIST_DATALINKS, 1,
 557                 [define if libpcap has pcap_list_datalinks()])
 558             AC_CHECK_FUNCS(pcap_free_datalinks)
 559         ],
 560         [
 561             AC_LIBOBJ(datalinks)
 562         ])
 563
 564 dnl
 565 dnl Check for "pcap_datalink_name_to_val()", and use a substitute
 566 dnl version if it's not present.  If it is present, check for
 567 dnl "pcap_datalink_val_to_description()", and if we don't have it,
 568 dnl use a substitute version.
 569 dnl
 570 AC_CHECK_FUNC(pcap_datalink_name_to_val,
 571         [
 572             AC_DEFINE(HAVE_PCAP_DATALINK_NAME_TO_VAL, 1,
 573                 [define if libpcap has pcap_datalink_name_to_val()])
 574             AC_CHECK_FUNC(pcap_datalink_val_to_description,
 575                 AC_DEFINE(HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION, 1,
 576                     [define if libpcap has pcap_datalink_val_to_description()]),
 577                 [
 578                     AC_LIBOBJ(dlnames)
 579                 ])
 580         ],
 581         [
 582             AC_LIBOBJ(dlnames)
 583         ])
 584
 585 dnl
 586 dnl Check for "pcap_set_datalink()"; you can't substitute for it if
 587 dnl it's absent (it has hooks into libpcap), so just define the
 588 dnl HAVE_ value if it's there.
 589 dnl
 590 AC_CHECK_FUNCS(pcap_set_datalink)
 591
 592 dnl
 593 dnl Check for "pcap_breakloop()"; you can't substitute for it if
 594 dnl it's absent (it has hooks into the live capture routines),
 595 dnl so just define the HAVE_ value if it's there.
 596 dnl
 597 AC_CHECK_FUNCS(pcap_breakloop)
 598
 599 #
 600 # Do we have the new open API?  Check for pcap_create, and assume that,
 601 # if we do, we also have pcap_activate() and the other new routines
 602 # introduced in libpcap 1.0.0.
 603 #
 604 AC_CHECK_FUNCS(pcap_create)
 605 if test $ac_cv_func_pcap_create = "yes" ; then
 606         #
 607         # OK, do we have pcap_set_tstamp_type?  If so, assume we have
 608         # pcap_list_tstamp_types and pcap_free_tstamp_types as well.
 609         #
 610         AC_CHECK_FUNCS(pcap_set_tstamp_type)
 611         #
 612         # And do we have pcap_set_tstamp_precision?  If so, we assume
 613         # we also have pcap_open_offline_with_tstamp_precision.
 614         #
 615         AC_CHECK_FUNCS(pcap_set_tstamp_precision)
 616 fi
 617
 618 #
 619 # Check for a miscellaneous collection of functions which we use
 620 # if we have them.
 621 #
 622 AC_CHECK_FUNCS(pcap_findalldevs)
 623 AC_CHECK_FUNCS(pcap_dump_flush pcap_lib_version)
 624 if test $ac_cv_func_pcap_lib_version = "no" ; then
 625     AC_MSG_CHECKING(whether pcap_version is defined by libpcap)
 626     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
 627         extern char pcap_version[];
 628
 629         return (int)pcap_version;
 630        ]])
 631        ],
 632        [ac_lbl_cv_pcap_version_defined=yes],
 633        [ac_lbl_cv_pcap_version_defined=no])
 634     if test "$ac_lbl_cv_pcap_version_defined" = yes ; then
 635         AC_MSG_RESULT(yes)
 636         AC_DEFINE(HAVE_PCAP_VERSION, 1, [define if libpcap has pcap_version])
 637     else
 638         AC_MSG_RESULT(no)
 639     fi
 640 fi
 641 AC_CHECK_FUNCS(pcap_setdirection pcap_set_immediate_mode pcap_dump_ftell64)
 642 AC_CHECK_FUNCS(pcap_open pcap_findalldevs_ex)
 643 AC_REPLACE_FUNCS(pcap_dump_ftell)
 644
 645 #
 646 # Check for special debugging functions
 647 #
 648 AC_CHECK_FUNCS(pcap_set_parser_debug)
 649 if test "$ac_cv_func_pcap_set_parser_debug" = "no" ; then
 650         #
 651         # OK, we don't have pcap_set_parser_debug() to set the libpcap
 652         # filter expression parser debug flag; can we directly set the
 653         # flag?
 654         AC_MSG_CHECKING(whether pcap_debug is defined by libpcap)
 655         AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
 656                 extern int pcap_debug;
 657
 658                 return pcap_debug;
 659            ]])
 660            ],
 661            [ac_lbl_cv_pcap_debug_defined=yes],
 662            [ac_lbl_cv_pcap_debug_defined=no])
 663         if test "$ac_lbl_cv_pcap_debug_defined" = yes ; then
 664                 AC_MSG_RESULT(yes)
 665                 AC_DEFINE(HAVE_PCAP_DEBUG, 1, [define if libpcap has pcap_debug])
 666         else
 667                 AC_MSG_RESULT(no)
 668                 #
 669                 # OK, what about "yydebug"?
 670                 #
 671                 AC_MSG_CHECKING(whether yydebug is defined by libpcap)
 672                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
 673                         extern int yydebug;
 674
 675                         return yydebug;
 676                    ]])
 677                    ],
 678                    [ac_lbl_cv_yydebug_defined=yes],
 679                    [ac_lbl_cv_yydebug_defined=no])
 680                 if test "$ac_lbl_cv_yydebug_defined" = yes ; then
 681                         AC_MSG_RESULT(yes)
 682                         AC_DEFINE(HAVE_YYDEBUG, 1, [define if libpcap has yydebug])
 683                 else
 684                         AC_MSG_RESULT(no)
 685                 fi
 686         fi
 687 fi
 688 AC_CHECK_FUNCS(pcap_set_optimizer_debug)
 689 AC_REPLACE_FUNCS(bpf_dump)      dnl moved to libpcap in 0.6
 690
 691 V_GROUP=0
 692 if test -f /etc/group -a ! -z "`grep '^wheel:' /etc/group`" ; then
 693         V_GROUP=wheel
 694 fi
 695 #
 696 # Assume V7/BSD convention for man pages (file formats in section 5,
 697 # miscellaneous info in section 7).
 698 #
 699 MAN_FILE_FORMATS=5
 700 MAN_MISC_INFO=7
 701 case "$host_os" in
 702
 703 aix*)
 704         dnl Workaround to enable certain features
 705         AC_DEFINE(_SUN,1,[define on AIX to get certain functions])
 706         ;;
 707
 708 hpux*)
 709         #
 710         # Use System V conventions for man pages.
 711         #
 712         MAN_FILE_FORMATS=4
 713         MAN_MISC_INFO=5
 714         ;;
 715
 716 irix*)
 717         V_GROUP=sys
 718
 719         #
 720         # Use System V conventions for man pages.
 721         #
 722         MAN_FILE_FORMATS=4
 723         MAN_MISC_INFO=5
 724         ;;
 725
 726 osf*)
 727         V_GROUP=system
 728
 729         #
 730         # Use System V conventions for man pages.
 731         #
 732         MAN_FILE_FORMATS=4
 733         MAN_MISC_INFO=5
 734         ;;
 735
 736 solaris*)
 737         V_GROUP=sys
 738
 739         #
 740         # Use System V conventions for man pages.
 741         #
 742         MAN_FILE_FORMATS=4
 743         MAN_MISC_INFO=5
 744         ;;
 745 esac
 746
 747 if test -f /dev/bpf0 ; then
 748         V_GROUP=bpf
 749 fi
 750
 751 #
 752 # Make sure we have a definition for C99's uintptr_t (regardless of
 753 # whether the environment is a C99 environment or not).
 754 #
 755 AC_TYPE_UINTPTR_T
 756
 757 savedcppflags="$CPPFLAGS"
 758 CPPFLAGS="$CPPFLAGS $V_INCLS"
 759
 760 #
 761 # Check whether we have pcap/pcap-inttypes.h.
 762 # If we do, we use that to get the C99 types defined.
 763 #
 764 AC_CHECK_HEADERS(pcap/pcap-inttypes.h)
 765
 766 #
 767 # At compile time HAVE_PCAP_FINDALLDEVS depends on HAVE_PCAP_IF_T.
 768 #
 769 AC_CHECK_TYPES(pcap_if_t, , , [#include <pcap.h>])
 770
 771 CPPFLAGS="$savedcppflags"
 772
 773 #
 774 # Define the old BSD specified-width types in terms of the C99 types;
 775 # we may need them with libpcap include files.
 776 #
 777 AC_CHECK_TYPE([u_int8_t], ,
 778         [AC_DEFINE([u_int8_t], [uint8_t],
 779         [Define to `uint8_t' if u_int8_t not defined.])],
 780         [AC_INCLUDES_DEFAULT
 781 #include <sys/types.h>
 782 ])
 783 AC_CHECK_TYPE([u_int16_t], ,
 784         [AC_DEFINE([u_int16_t], [uint16_t],
 785         [Define to `uint16_t' if u_int16_t not defined.])],
 786         [AC_INCLUDES_DEFAULT
 787 #include <sys/types.h>
 788 ])
 789 AC_CHECK_TYPE([u_int32_t], ,
 790         [AC_DEFINE([u_int32_t], [uint32_t],
 791         [Define to `uint32_t' if u_int32_t not defined.])],
 792         [AC_INCLUDES_DEFAULT
 793 #include <sys/types.h>
 794 ])
 795 AC_CHECK_TYPE([u_int64_t], ,
 796         [AC_DEFINE([u_int64_t], [uint64_t],
 797         [Define to `uint64_t' if u_int64_t not defined.])],
 798         [AC_INCLUDES_DEFAULT
 799 #include <sys/types.h>
 800 ])
 801
 802 AC_PROG_RANLIB
 803 AC_CHECK_TOOL([AR], [ar])
 804
 805 AC_LBL_DEVEL(V_CCOPT)
 806
 807 # Check for OpenSSL/libressl libcrypto
 808 AC_MSG_CHECKING(whether to use OpenSSL/libressl libcrypto)
 809 # Specify location for both includes and libraries.
 810 want_libcrypto=ifavailable
 811 AC_ARG_WITH(crypto,
 812     AS_HELP_STRING([--with-crypto]@<:@=DIR@:>@,
 813                    [use OpenSSL/libressl libcrypto (located in directory DIR, if specified) @<:@default=yes, if available@:>@]),
 814 [
 815         if test $withval = no
 816         then
 817                 # User doesn't want to link with libcrypto.
 818                 want_libcrypto=no
 819                 AC_MSG_RESULT(no)
 820         elif test $withval = yes
 821         then
 822                 # User wants to link with libcrypto but hasn't specified
 823                 # a directory.
 824                 want_libcrypto=yes
 825                 AC_MSG_RESULT(yes)
 826         else
 827                 # User wants to link with libcrypto and has specified
 828                 # a directory, so use the provided value.
 829                 want_libcrypto=yes
 830                 libcrypto_root=$withval
 831                 AC_MSG_RESULT([yes, using the version installed in $withval])
 832
 833                 #
 834                 # Put the subdirectories of the libcrypto root directory
 835                 # at the front of the header and library search path.
 836                 #
 837                 CFLAGS="-I$withval/include $CFLAGS"
 838                 LIBS="-L$withval/lib $LIBS"
 839         fi
 840 ],[
 841         #
 842         # Use libcrypto if it's present, otherwise don't; no directory
 843         # was specified.
 844         #
 845         want_libcrypto=ifavailable
 846         AC_MSG_RESULT([yes, if available])
 847 ])
 848 if test "$want_libcrypto" != "no"; then
 849         #
 850         # Don't check for libcrypto unless we have its headers;
 851         # Apple, bless their pointy little heads, apparently ship
 852         # libcrypto as a library, but not the header files, in
 853         # El Capitan, probably because they don't want you writing
 854         # nasty portable code that could run on other UN*Xes, they
 855         # want you writing code that uses their Shiny New Crypto
 856         # Library and that only runs on macOS.
 857         #
 858         AC_CHECK_HEADER(openssl/crypto.h,
 859         [
 860                 AC_CHECK_LIB(crypto, DES_cbc_encrypt)
 861                 if test "$ac_cv_lib_crypto_DES_cbc_encrypt" = "yes"; then
 862                         AC_CHECK_HEADERS(openssl/evp.h)
 863                         #
 864                         # OK, then:
 865                         #
 866                         # 1) do we have EVP_CIPHER_CTX_new?
 867                         # If so, we use it to allocate an
 868                         # EVP_CIPHER_CTX, as EVP_CIPHER_CTX may be
 869                         # opaque; otherwise, we allocate it ourselves.
 870                         #
 871                         # 2) do we have EVP_DecryptInit_ex()?
 872                         # If so, we use it, because we need to be
 873                         # able to make two "initialize the cipher"
 874                         # calls, one with the cipher and key, and
 875                         # one with the IV, and, as of OpenSSL 1.1,
 876                         # You Can't Do That with EVP_DecryptInit(),
 877                         # because a call to EVP_DecryptInit() will
 878                         # unconditionally clear the context, and
 879                         # if you don't supply a cipher, it'll
 880                         # clear the cipher, rendering the context
 881                         # unusable and causing a crash.
 882                         #
 883                         AC_CHECK_FUNCS(EVP_CIPHER_CTX_new EVP_DecryptInit_ex)
 884                 fi
 885         ])
 886 fi
 887
 888 # Check for libcap-ng
 889 AC_MSG_CHECKING(whether to use libcap-ng)
 890 # Specify location for both includes and libraries.
 891 want_libcap_ng=ifavailable
 892 AC_ARG_WITH(cap_ng,
 893     AS_HELP_STRING([--with-cap-ng],
 894                    [use libcap-ng @<:@default=yes, if available@:>@]),
 895 [
 896         if test $withval = no
 897         then
 898                 want_libcap_ng=no
 899                 AC_MSG_RESULT(no)
 900         elif test $withval = yes
 901         then
 902                 want_libcap_ng=yes
 903                 AC_MSG_RESULT(yes)
 904         fi
 905 ],[
 906         #
 907         # Use libcap-ng if it's present, otherwise don't.
 908         #
 909         want_libcap_ng=ifavailable
 910         AC_MSG_RESULT([yes, if available])
 911 ])
 912 if test "$want_libcap_ng" != "no"; then
 913         AC_CHECK_LIB(cap-ng, capng_change_id)
 914         AC_CHECK_HEADERS(cap-ng.h)
 915 fi
 916
 917 dnl
 918 dnl set additional include path if necessary
 919 if test "$missing_includes" = "yes"; then
 920         CPPFLAGS="$CPPFLAGS -I$srcdir/missing"
 921         V_INCLS="$V_INCLS -I$srcdir/missing"
 922 fi
 923
 924 AC_SUBST(V_CCOPT)
 925 AC_SUBST(V_DEFS)
 926 AC_SUBST(V_GROUP)
 927 AC_SUBST(V_INCLS)
 928 AC_SUBST(V_PCAPDEP)
 929 AC_SUBST(LOCALSRC)
 930 AC_SUBST(MAN_FILE_FORMATS)
 931 AC_SUBST(MAN_MISC_INFO)
 932
 933 AC_PROG_INSTALL
 934
 935 AC_CONFIG_HEADERS([config.h])
 936
 937 AC_CONFIG_COMMANDS([.devel],[[if test -f .devel; then
 938         echo timestamp > stamp-h
 939         cat $srcdir/Makefile-devel-adds >> Makefile
 940         make depend || exit 1
 941 fi]])
 942 AC_CONFIG_FILES([Makefile tcpdump.1])
 943 AC_OUTPUT
 944 exit 0