The Tcpdump Group git mirrors - tcpdump/blob - configure.in

   1 dnl @(#) $Header: /tcpdump/master/tcpdump/configure.in,v 1.204 2008-11-18 07:39:20 guy Exp $ (LBL)
   2 dnl
   3 dnl Copyright (c) 1994, 1995, 1996, 1997
   4 dnl     The Regents of the University of California.  All rights reserved.
   5 dnl
   6 dnl Process this file with autoconf to produce a configure script.
   7 dnl
   8
   9 #
  10 # See
  11 #
  12 #       http://ftp.gnu.org/gnu/config/README
  13 #
  14 # for the URLs to use to fetch new versions of config.guess and
  15 # config.sub.
  16 #
  17
  18 AC_REVISION($Revision: 1.204 $)
  19 AC_PREREQ(2.50)
  20 AC_INIT(tcpdump.c)
  21
  22 AC_CANONICAL_HOST
  23
  24 AC_LBL_C_INIT_BEFORE_CC(V_CCOPT, V_INCLS)
  25 AC_PROG_CC
  26 AC_LBL_C_INIT(V_CCOPT, V_INCLS)
  27 AC_LBL_C_INLINE
  28 AC_C___ATTRIBUTE__
  29 if test "$ac_cv___attribute__" = "yes"; then
  30         AC_C___ATTRIBUTE___FORMAT_FUNCTION_POINTER
  31 fi
  32 AC_CHECK_HEADERS(fcntl.h rpc/rpcent.h netdnet/dnetdb.h)
  33 AC_CHECK_HEADERS(net/pfvar.h, , , [#include <sys/types.h>
  34 #include <sys/socket.h>
  35 #include <net/if.h>])
  36 if test "$ac_cv_header_net_pfvar_h" = yes; then
  37         LOCALSRC="print-pflog.c $LOCALSRC"
  38 fi
  39 AC_CHECK_HEADERS(netinet/if_ether.h, , , [#include <sys/types.h>
  40 #include <sys/socket.h>])
  41 if test "$ac_cv_header_netinet_if_ether_h" != yes; then
  42         #
  43         # The simple test didn't work.
  44         # Do we need to include <net/if.h> first?
  45         # Unset ac_cv_header_netinet_if_ether_h so we don't
  46         # treat the previous failure as a cached value and
  47         # suppress the next test.
  48         #
  49         AC_MSG_NOTICE([Rechecking with some additional includes])
  50         unset ac_cv_header_netinet_if_ether_h
  51         AC_CHECK_HEADERS(netinet/if_ether.h, , , [#include <sys/types.h>
  52 #include <sys/socket.h>
  53 #include <netinet/in.h>
  54 struct mbuf;
  55 struct rtentry;
  56 #include <net/if.h>])
  57 fi
  58
  59 AC_HEADER_TIME
  60
  61 case "$host_os" in
  62
  63 darwin*)
  64         AC_ARG_ENABLE(universal,
  65         AC_HELP_STRING([--disable-universal],[don't build universal on OS X]))
  66         if test "$enable_universal" != "no"; then
  67                 case "$host_os" in
  68
  69                 darwin9.*)
  70                         #
  71                         # Leopard.  Build for x86 and 32-bit PowerPC, with
  72                         # x86 first.  (That's what Apple does.)
  73                         #
  74                         V_CCOPT="$V_CCOPT -arch i386 -arch ppc"
  75                         LDFLAGS="$LDFLAGS -arch i386 -arch ppc"
  76                         ;;
  77
  78                 darwin10.*)
  79                         #
  80                         # Snow Leopard.  Build for x86-64 and x86, with
  81                         # x86-64 first.  (That's what Apple does.)
  82                         #
  83                         V_CCOPT="$V_CCOPT -arch x86_64 -arch i386"
  84                         LDFLAGS="$LDFLAGS -arch x86_64 -arch i386"
  85                         ;;
  86                 esac
  87         fi
  88         ;;
  89
  90 linux*)
  91         AC_MSG_CHECKING(Linux kernel version)
  92         if test "$cross_compiling" = yes; then
  93                 AC_CACHE_VAL(ac_cv_linux_vers,
  94                     ac_cv_linux_vers=unknown)
  95         else
  96                 AC_CACHE_VAL(ac_cv_linux_vers,
  97                     ac_cv_linux_vers=`uname -r 2>&1 | \
  98                         sed -n -e '$s/.* //' -e '$s/\..*//p'`)
  99         fi
 100         AC_MSG_RESULT($ac_cv_linux_vers)
 101         if test $ac_cv_linux_vers = unknown ; then
 102                 AC_MSG_ERROR(cannot determine linux version when cross-compiling)
 103         fi
 104         if test $ac_cv_linux_vers -lt 2 ; then
 105                 AC_MSG_ERROR(version 2 or higher required; see the INSTALL doc for more info)
 106         fi
 107         ;;
 108
 109 *)
 110         ;;
 111 esac
 112
 113
 114 AC_ARG_WITH(smi,
 115 [  --with-smi              link with libsmi (allows to load MIBs on the fly to decode SNMP packets. [default=yes]
 116   --without-smi           don't link with libsmi],,
 117    with_smi=yes)
 118
 119 if test "x$with_smi" != "xno" ; then
 120 AC_CHECK_HEADERS(smi.h)
 121 AC_CHECK_LIB(smi, smiInit)
 122 if test "$ac_cv_header_smi_h" = yes -a "$ac_cv_lib_smi_smiInit" = yes
 123 then
 124 AC_MSG_CHECKING([whether to enable libsmi])
 125         AC_TRY_RUN([ /* libsmi available check */
 126 #include <smi.h>
 127 main()
 128 {
 129   int current, revision, age, n;
 130   const int required = 2;
 131   if (smiInit(""))
 132     exit(1);
 133   if (strcmp(SMI_LIBRARY_VERSION, smi_library_version))
 134     exit(2);
 135   n = sscanf(smi_library_version, "%d:%d:%d", &current, &revision, &age);
 136   if (n != 3)
 137     exit(3);
 138   if (required < current - age || required > current)
 139     exit(4);
 140   exit(0);
 141 }
 142 ],
 143 [ AC_MSG_RESULT(yes)
 144   AC_DEFINE(LIBSMI)
 145   libsmi=yes],
 146 dnl autoconf documentation says that $? contains the exit value.
 147 dnl reality is that it does not.  We leave this in just in case
 148 dnl autoconf ever comes back to match the documentation.
 149 [ case $? in
 150   1) AC_MSG_RESULT(no - smiInit failed) ;;
 151   2) AC_MSG_RESULT(no - header/library version mismatch) ;;
 152   3) AC_MSG_RESULT(no - can't determine library version) ;;
 153   4) AC_MSG_RESULT(no - too old) ;;
 154   *) AC_MSG_RESULT(no) ;;
 155   esac
 156   libsmi=no],
 157 [ AC_MSG_RESULT(not when cross-compiling)
 158   libsmi=no]
 159 )
 160 fi
 161 fi
 162
 163 AC_MSG_CHECKING([whether to enable the possibly-buggy SMB printer])
 164 AC_ARG_ENABLE(smb,
 165 [  --enable-smb            enable possibly-buggy SMB printer [default=yes]
 166   --disable-smb           disable possibly-buggy SMB printer],,
 167    enableval=yes)
 168 case "$enableval" in
 169 yes)    AC_MSG_RESULT(yes)
 170         AC_WARN([The SMB printer may have exploitable buffer overflows!!!])
 171         AC_DEFINE(TCPDUMP_DO_SMB)
 172         LOCALSRC="print-smb.c smbutil.c $LOCALSRC"
 173         ;;
 174 *)      AC_MSG_RESULT(no)
 175         ;;
 176 esac
 177
 178 AC_ARG_WITH(user, [  --with-user=USERNAME    drop privileges by default to USERNAME])
 179 AC_MSG_CHECKING([whether to drop root privileges by default])
 180 if test ! -z "$with_user" ; then
 181         AC_DEFINE_UNQUOTED(WITH_USER, "$withval")
 182        AC_MSG_RESULT(to \"$withval\")
 183 else
 184        AC_MSG_RESULT(no)
 185 fi
 186
 187 AC_ARG_WITH(chroot, [  --with-chroot=DIRECTORY when dropping privileges, chroot to DIRECTORY])
 188 AC_MSG_CHECKING([whether to chroot])
 189 if test ! -z "$with_chroot" && test "$with_chroot" != "no" ; then
 190         AC_DEFINE_UNQUOTED(WITH_CHROOT, "$withval")
 191        AC_MSG_RESULT(to \"$withval\")
 192 else
 193        AC_MSG_RESULT(no)
 194 fi
 195
 196 AC_MSG_CHECKING([whether to enable ipv6])
 197 AC_ARG_ENABLE(ipv6,
 198 [  --enable-ipv6           enable ipv6 (with ipv4) support
 199   --disable-ipv6          disable ipv6 support],
 200 [ case "$enableval" in
 201 yes)   AC_MSG_RESULT(yes)
 202        LOCALSRC="print-ip6.c print-ip6opts.c print-mobility.c print-ripng.c print-icmp6.c print-frag6.c print-rt6.c print-ospf6.c print-dhcp6.c $LOCALSRC"
 203        AC_DEFINE(INET6)
 204        ipv6=yes
 205        ;;
 206 *)
 207        AC_MSG_RESULT(no)
 208        ipv6=no
 209        ;;
 210   esac ],
 211
 212   AC_TRY_RUN([ /* AF_INET6 available check */
 213 #include <sys/types.h>
 214 #include <sys/socket.h>
 215 main()
 216 {
 217  if (socket(AF_INET6, SOCK_STREAM, 0) < 0)
 218    exit(1);
 219  else
 220    exit(0);
 221 }
 222 ],
 223 [ AC_MSG_RESULT(yes)
 224   LOCALSRC="print-ip6.c print-ip6opts.c print-mobility.c print-ripng.c print-icmp6.c print-frag6.c print-rt6.c print-ospf6.c print-dhcp6.c $LOCALSRC"
 225   AC_DEFINE(INET6)
 226   ipv6=yes],
 227 [ AC_MSG_RESULT(no)
 228   ipv6=no],
 229 [ AC_MSG_RESULT(no)
 230   ipv6=no]
 231 ))
 232
 233 ipv6type=unknown
 234 ipv6lib=none
 235 ipv6trylibc=no
 236
 237 if test "$ipv6" = "yes"; then
 238         AC_MSG_CHECKING([ipv6 stack type])
 239         for i in inria kame linux-glibc linux-libinet6 toshiba v6d zeta; do
 240                 case $i in
 241                 inria)
 242                         dnl http://www.kame.net/
 243                         AC_EGREP_CPP(yes,
 244 [#include <netinet/in.h>
 245 #ifdef IPV6_INRIA_VERSION
 246 yes
 247 #endif],
 248                                 [ipv6type=$i;
 249                                 CFLAGS="-DINET6 $CFLAGS"])
 250                         ;;
 251                 kame)
 252                         dnl http://www.kame.net/
 253                         AC_EGREP_CPP(yes,
 254 [#include <netinet/in.h>
 255 #ifdef __KAME__
 256 yes
 257 #endif],
 258                                 [ipv6type=$i;
 259                                 ipv6lib=inet6;
 260                                 ipv6libdir=/usr/local/v6/lib;
 261                                 ipv6trylibc=yes;
 262                                 CFLAGS="-DINET6 $CFLAGS"])
 263                         ;;
 264                 linux-glibc)
 265                         dnl http://www.v6.linux.or.jp/
 266                         AC_EGREP_CPP(yes,
 267 [#include <features.h>
 268 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 269 yes
 270 #endif],
 271                                 [ipv6type=$i;
 272                                 CFLAGS="-DINET6 $CFLAGS"])
 273                         ;;
 274                 linux-libinet6)
 275                         dnl http://www.v6.linux.or.jp/
 276                         dnl
 277                         dnl This also matches Solaris 8 and Tru64 UNIX 5.1,
 278                         dnl and possibly other versions of those OSes
 279                         dnl
 280                         if test -d /usr/inet6 -o -f /usr/include/netinet/ip6.h; then
 281                                 ipv6type=$i
 282                                 ipv6lib=inet6
 283                                 ipv6libdir=/usr/inet6/lib
 284                                 ipv6trylibc=yes;
 285                                 CFLAGS="-DINET6 -I/usr/inet6/include $CFLAGS"
 286                         fi
 287                         ;;
 288                 toshiba)
 289                         AC_EGREP_CPP(yes,
 290 [#include <sys/param.h>
 291 #ifdef _TOSHIBA_INET6
 292 yes
 293 #endif],
 294                                 [ipv6type=$i;
 295                                 ipv6lib=inet6;
 296                                 ipv6libdir=/usr/local/v6/lib;
 297                                 CFLAGS="-DINET6 $CFLAGS"])
 298                         ;;
 299                 v6d)
 300                         AC_EGREP_CPP(yes,
 301 [#include </usr/local/v6/include/sys/v6config.h>
 302 #ifdef __V6D__
 303 yes
 304 #endif],
 305                                 [ipv6type=$i;
 306                                 ipv6lib=v6;
 307                                 ipv6libdir=/usr/local/v6/lib;
 308                                 CFLAGS="-I/usr/local/v6/include $CFLAGS"])
 309                         ;;
 310                 zeta)
 311                         AC_EGREP_CPP(yes,
 312 [#include <sys/param.h>
 313 #ifdef _ZETA_MINAMI_INET6
 314 yes
 315 #endif],
 316                                 [ipv6type=$i;
 317                                 ipv6lib=inet6;
 318                                 ipv6libdir=/usr/local/v6/lib;
 319                                 CFLAGS="-DINET6 $CFLAGS"])
 320                         ;;
 321                 esac
 322                 if test "$ipv6type" != "unknown"; then
 323                         break
 324                 fi
 325         done
 326         AC_MSG_RESULT($ipv6type)
 327 fi
 328
 329 if test "$ipv6" = "yes" -a "$ipv6lib" != "none"; then
 330         if test -d $ipv6libdir -a -f $ipv6libdir/lib$ipv6lib.a; then
 331                 LIBS="-L$ipv6libdir -l$ipv6lib $LIBS"
 332                 echo "You have $ipv6lib library, using it"
 333         else
 334                 if test "$ipv6trylibc" = "yes"; then
 335                         echo "You do not have $ipv6lib library, using libc"
 336                 else
 337                         echo 'Fatal: no $ipv6lib library found.  cannot continue.'
 338                         echo "You need to fetch lib$ipv6lib.a from appropriate"
 339                         echo 'ipv6 kit and compile beforehand.'
 340                         exit 1
 341                 fi
 342         fi
 343 fi
 344
 345
 346 if test "$ipv6" = "yes"; then
 347         #
 348         # XXX - on Tru64 UNIX 5.1, there is no "getaddrinfo()"
 349         # function in libc; there are "ngetaddrinfo()" and
 350         # "ogetaddrinfo()" functions, and <netdb.h> #defines
 351         # "getaddrinfo" to be either "ngetaddrinfo" or
 352         # "ogetaddrinfo", depending on whether _SOCKADDR_LEN
 353         # or _XOPEN_SOURCE_EXTENDED are defined or not.
 354         #
 355         # So this test doesn't work on Tru64 5.1, and possibly
 356         # on other 5.x releases.  This causes the configure
 357         # script to become confused, and results in libpcap
 358         # being unbuildable.
 359         #
 360         AC_SEARCH_LIBS(getaddrinfo, socket, [dnl
 361         AC_MSG_CHECKING(getaddrinfo bug)
 362         AC_CACHE_VAL(td_cv_buggygetaddrinfo, [AC_TRY_RUN([
 363 #include <sys/types.h>
 364 #include <netdb.h>
 365 #include <string.h>
 366 #include <sys/socket.h>
 367 #include <netinet/in.h>
 368
 369 main()
 370 {
 371   int passive, gaierr, inet4 = 0, inet6 = 0;
 372   struct addrinfo hints, *ai, *aitop;
 373   char straddr[INET6_ADDRSTRLEN], strport[16];
 374
 375   for (passive = 0; passive <= 1; passive++) {
 376     memset(&hints, 0, sizeof(hints));
 377     hints.ai_family = AF_UNSPEC;
 378     hints.ai_flags = passive ? AI_PASSIVE : 0;
 379     hints.ai_socktype = SOCK_STREAM;
 380     hints.ai_protocol = IPPROTO_TCP;
 381     if ((gaierr = getaddrinfo(NULL, "54321", &hints, &aitop)) != 0) {
 382       (void)gai_strerror(gaierr);
 383       goto bad;
 384     }
 385     for (ai = aitop; ai; ai = ai->ai_next) {
 386       if (ai->ai_addr == NULL ||
 387           ai->ai_addrlen == 0 ||
 388           getnameinfo(ai->ai_addr, ai->ai_addrlen,
 389                       straddr, sizeof(straddr), strport, sizeof(strport),
 390                       NI_NUMERICHOST|NI_NUMERICSERV) != 0) {
 391         goto bad;
 392       }
 393       switch (ai->ai_family) {
 394       case AF_INET:
 395         if (strcmp(strport, "54321") != 0) {
 396           goto bad;
 397         }
 398         if (passive) {
 399           if (strcmp(straddr, "0.0.0.0") != 0) {
 400             goto bad;
 401           }
 402         } else {
 403           if (strcmp(straddr, "127.0.0.1") != 0) {
 404             goto bad;
 405           }
 406         }
 407         inet4++;
 408         break;
 409       case AF_INET6:
 410         if (strcmp(strport, "54321") != 0) {
 411           goto bad;
 412         }
 413         if (passive) {
 414           if (strcmp(straddr, "::") != 0) {
 415             goto bad;
 416           }
 417         } else {
 418           if (strcmp(straddr, "::1") != 0) {
 419             goto bad;
 420           }
 421         }
 422         inet6++;
 423         break;
 424       case AF_UNSPEC:
 425         goto bad;
 426         break;
 427 #ifdef AF_UNIX
 428       case AF_UNIX:
 429 #else
 430 #ifdef AF_LOCAL
 431       case AF_LOCAL:
 432 #endif
 433 #endif
 434       default:
 435         /* another family support? */
 436         break;
 437       }
 438     }
 439   }
 440
 441   /* supported family should be 2, unsupported family should be 0 */
 442   if (!(inet4 == 0 || inet4 == 2))
 443     goto bad;
 444   if (!(inet6 == 0 || inet6 == 2))
 445     goto bad;
 446
 447   if (aitop)
 448     freeaddrinfo(aitop);
 449   exit(0);
 450
 451  bad:
 452   if (aitop)
 453     freeaddrinfo(aitop);
 454   exit(1);
 455 }
 456 ],
 457         td_cv_buggygetaddrinfo=no,
 458         td_cv_buggygetaddrinfo=yes,
 459         td_cv_buggygetaddrinfo=yes)])
 460         if test "$td_cv_buggygetaddrinfo" = no; then
 461                 AC_MSG_RESULT(good)
 462         else
 463                 AC_MSG_RESULT(buggy)
 464         fi
 465
 466         if test "$td_cv_buggygetaddrinfo" = "yes"; then
 467                 #
 468                 # XXX - it doesn't appear that "ipv6type" can ever be
 469                 # set to "linux".  Should this be testing for
 470                 # "linux-glibc", or for that *or* "linux-libinet6"?
 471                 # If the latter, note that "linux-libinet6" is also
 472                 # the type given to some non-Linux OSes.
 473                 #
 474                 if test "$ipv6type" != "linux"; then
 475                         echo 'Fatal: You must get working getaddrinfo() function.'
 476                         echo '       or you can specify "--disable-ipv6"'.
 477                         exit 1
 478                 else
 479                         echo 'Warning: getaddrinfo() implementation on your system seems be buggy.'
 480                         echo '         Better upgrade your system library to newest version'
 481                         echo '         of GNU C library (aka glibc).'
 482                 fi
 483         fi
 484         ])
 485         AC_REPLACE_FUNCS(getnameinfo)
 486 fi
 487
 488 AC_CACHE_CHECK([for dnet_htoa declaration in netdnet/dnetdb.h],
 489 [td_cv_decl_netdnet_dnetdb_h_dnet_htoa],
 490 [AC_EGREP_HEADER(dnet_htoa, netdnet/dnetdb.h,
 491         td_cv_decl_netdnet_dnetdb_h_dnet_htoa=yes,
 492         td_cv_decl_netdnet_dnetdb_h_dnet_htoa=no)])
 493 if test "$td_cv_decl_netdnet_dnetdb_h_dnet_htoa" = yes; then
 494         AC_DEFINE(HAVE_NETDNET_DNETDB_H_DNET_HTOA)
 495 fi
 496
 497 dnl
 498 dnl Checks for addrinfo structure
 499 AC_STRUCT_ADDRINFO(ac_cv_addrinfo)
 500 if test "$ac_cv_addrinfo" = no; then
 501         missing_includes=yes
 502 fi
 503
 504 dnl
 505 dnl Checks for NI_MAXSERV
 506 AC_NI_MAXSERV(ac_cv_maxserv)
 507 if test "$ac_cv_maxserv" = no; then
 508         missing_includes=yes
 509 fi
 510
 511 dnl
 512 dnl Checks for NI_NAMEREQD
 513 AC_NI_NAMEREQD(ac_cv_namereqd)
 514 if test "$ac_cv_namereqd" = no; then
 515         missing_includes=yes
 516 fi
 517
 518 dnl
 519 dnl Checks for sockaddr_storage structure
 520 AC_STRUCT_SA_STORAGE(ac_cv_sa_storage)
 521 if test "$ac_cv_sa_storage" = no; then
 522         missing_includes=yes
 523 fi
 524
 525 dnl
 526 dnl Checks for IN[6]ADDRSZ
 527 AC_CHECK_ADDRSZ(ac_cv_addrsz)
 528 if test "$ac_cv_addrsz" = no; then
 529         missing_includes=yes
 530 fi
 531
 532 dnl
 533 dnl Checks for RES_USE_INET6
 534 AC_CHECK_RES_USE_INET6(ac_cv_res_inet6)
 535 if test "$ac_cv_res_inet6" = no; then
 536         missing_includes=yes
 537 fi
 538
 539 dnl
 540 dnl Checks for res_state_ext structure
 541 AC_STRUCT_RES_STATE_EXT(ac_cv_res_state_ext)
 542 if test "$ac_cv_res_state_ext" = no; then
 543         missing_includes=yes
 544 fi
 545
 546 dnl
 547 dnl Checks if res_state structure has nsort member.
 548 AC_STRUCT_RES_STATE(ac_cv_res_state)
 549
 550
 551 AC_REPLACE_FUNCS(vfprintf strcasecmp strlcat strlcpy strdup strsep)
 552 AC_CHECK_FUNCS(strftime)
 553 AC_CHECK_FUNCS(setlinebuf alarm)
 554
 555 needsnprintf=no
 556 AC_CHECK_FUNCS(vsnprintf snprintf,,
 557         [needsnprintf=yes])
 558 if test $needsnprintf = yes; then
 559         AC_LIBOBJ(snprintf)
 560 fi
 561
 562 AC_LBL_TYPE_SIGNAL
 563
 564 AC_SEARCH_LIBS(dnet_htoa, dnet, AC_DEFINE(HAVE_DNET_HTOA))
 565
 566 AC_CHECK_LIB(rpc, main)         dnl It's unclear why we might need -lrpc
 567
 568 dnl Some platforms may need -lnsl for getrpcbynumber.
 569 AC_SEARCH_LIBS(getrpcbynumber, nsl, AC_DEFINE(HAVE_GETRPCBYNUMBER))
 570
 571 dnl AC_CHECK_LIB(z, uncompress)
 572 dnl AC_CHECK_HEADERS(zlib.h)
 573
 574 AC_LBL_LIBPCAP(V_PCAPDEP, V_INCLS)
 575
 576 #
 577 # Check for these after AC_LBL_LIBPCAP, so we link with the appropriate
 578 # libraries (e.g., "-lsocket -lnsl" on Solaris).
 579 #
 580 # We don't use AC_REPLACE_FUNCS because that uses AC_CHECK_FUNCS which
 581 # use AC_CHECK_FUNC which doesn't let us specify the right #includes
 582 # to make this work on BSD/OS 4.x.  BSD/OS 4.x ships with the BIND8
 583 # resolver, and the way it defines inet_{ntop,pton} is rather strange;
 584 # it does not ship with a libc symbol "inet_ntop()", it ships with
 585 # "_inet_ntop()", and has a #define macro in one of the system headers
 586 # to rename it.
 587 #
 588 dnl AC_TRY_COMPILE(inet_ntop inet_pton inet_aton)
 589 AC_MSG_CHECKING(for inet_ntop)
 590 AC_TRY_LINK([#include <sys/types.h>
 591 #include <sys/socket.h>
 592 #include <netinet/in.h>
 593 #include <arpa/inet.h>], [char src[4], dst[128];
 594 inet_ntop(AF_INET, src, dst, sizeof(dst));],
 595         [AC_MSG_RESULT(yes)], [AC_MSG_RESULT(no)
 596         AC_LIBOBJ(inet_ntop)])
 597 AC_MSG_CHECKING(for inet_pton)
 598 AC_TRY_LINK([#include <sys/types.h>
 599 #include <sys/socket.h>
 600 #include <netinet/in.h>
 601 #include <arpa/inet.h>], [char src[128], dst[4];
 602 inet_pton(AF_INET, src, dst);],
 603         [AC_MSG_RESULT(yes)], [AC_MSG_RESULT(no)
 604         AC_LIBOBJ(inet_pton)])
 605 AC_MSG_CHECKING(for inet_aton)
 606 AC_TRY_LINK([#include <sys/types.h>
 607 #include <netinet/in.h>
 608 #include <arpa/inet.h>], [char src[128];
 609 struct in_addr dst;
 610 inet_aton(src, &dst);],
 611         [AC_MSG_RESULT(yes)], [AC_MSG_RESULT(no)
 612         AC_LIBOBJ(inet_aton)])
 613
 614 #
 615 # Check for these after AC_LBL_LIBPCAP, for the same reason.
 616 #
 617 # You are in a twisty little maze of UN*Xes, all different.
 618 # Some might not have ether_ntohost().
 619 # Some might have it, but not declare it in any header file.
 620 # Some might have it, but declare it in <netinet/if_ether.h>.
 621 # Some might have it, but declare it in <netinet/ether.h>
 622 # (And some might have it but document it as something declared in
 623 # <netinet/ethernet.h>, although <netinet/if_ether.h> appears to work.)
 624 #
 625 # Before you is a C compiler.
 626 #
 627 AC_CHECK_FUNCS(ether_ntohost, [
 628     AC_CACHE_CHECK(for buggy ether_ntohost, ac_cv_buggy_ether_ntohost, [
 629         AC_TRY_RUN([
 630                 #include <netdb.h>
 631                 #include <sys/types.h>
 632                 #include <sys/param.h>
 633                 #include <sys/socket.h>
 634
 635                 int
 636                 main(int argc, char **argv)
 637                 {
 638                         u_char ea[6] = { 0xff, 0xff, 0xff, 0xff, 0xff };
 639                         char name[MAXHOSTNAMELEN];
 640
 641                         ether_ntohost(name, (struct ether_addr *)ea);
 642                         exit(0);
 643                 }
 644         ], [ac_cv_buggy_ether_ntohost=no],
 645            [ac_cv_buggy_ether_ntohost=yes],
 646            [ac_cv_buggy_ether_ntohost="not while cross-compiling"])])
 647     if test "$ac_cv_buggy_ether_ntohost" = "no"; then
 648         AC_DEFINE(USE_ETHER_NTOHOST)
 649     fi
 650 ])
 651 if test "$ac_cv_func_ether_ntohost" = yes -a \
 652     "$ac_cv_buggy_ether_ntohost" = "no"; then
 653         #
 654         # OK, we have ether_ntohost().  Do we have <netinet/if_ether.h>?
 655         #
 656         if test "$ac_cv_header_netinet_if_ether_h" = yes; then
 657                 #
 658                 # Yes.  Does it declare ether_ntohost()?
 659                 #
 660                 AC_CHECK_DECL(ether_ntohost,
 661                     [
 662                         AC_DEFINE(NETINET_IF_ETHER_H_DECLARES_ETHER_NTOHOST,,
 663                             [Define to 1 if netinet/if_ether.h declares `ether_ntohost'])
 664                     ],,
 665                     [
 666 #include <sys/types.h>
 667 #include <sys/socket.h>
 668 #include <netinet/in.h>
 669 #include <arpa/inet.h>
 670 struct mbuf;
 671 struct rtentry;
 672 #include <net/if.h>
 673 #include <netinet/if_ether.h>
 674                     ])
 675         fi
 676         #
 677         # Did that succeed?
 678         #
 679         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 680                 #
 681                 # No, how about <netinet/ether.h>, as on Linux?
 682                 #
 683                 AC_CHECK_HEADERS(netinet/ether.h)
 684                 if test "$ac_cv_header_netinet_ether_h" = yes; then
 685                         #
 686                         # We have it - does it declare ether_ntohost()?
 687                         # Unset ac_cv_have_decl_ether_ntohost so we don't
 688                         # treat the previous failure as a cached value and
 689                         # suppress the next test.
 690                         #
 691                         unset ac_cv_have_decl_ether_ntohost
 692                         AC_CHECK_DECL(ether_ntohost,
 693                             [
 694                                 AC_DEFINE(NETINET_ETHER_H_DECLARES_ETHER_NTOHOST,,
 695                                     [Define to 1 if netinet/ether.h declares `ether_ntohost'])
 696                             ],,
 697                             [
 698 #include <netinet/ether.h>
 699                             ])
 700                 fi
 701         fi
 702         #
 703         # Is ether_ntohost() declared?
 704         #
 705         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 706                 #
 707                 # No, we'll have to declare it ourselves.
 708                 # Do we have "struct ether_addr"?
 709                 #
 710                 AC_CHECK_TYPES(struct ether_addr,,,
 711                     [
 712 #include <sys/types.h>
 713 #include <sys/socket.h>
 714 #include <netinet/in.h>
 715 #include <arpa/inet.h>
 716 struct mbuf;
 717 struct rtentry;
 718 #include <net/if.h>
 719 #include <netinet/if_ether.h>
 720                     ])
 721                 AC_DEFINE(HAVE_DECL_ETHER_NTOHOST, 0,
 722                     [Define to 1 if you have the declaration of `ether_ntohost', and to 0 if you
 723 don't.])
 724         else
 725                 AC_DEFINE(HAVE_DECL_ETHER_NTOHOST, 1,
 726                     [Define to 1 if you have the declaration of `ether_ntohost', and to 0 if you
 727 don't.])
 728         fi
 729 fi
 730
 731 # libdlpi is needed for Solaris 11 and later.
 732 AC_CHECK_LIB(dlpi, dlpi_walk, LIBS="$LIBS -ldlpi" LDFLAGS="-L/lib $LDFLAGS", ,-L/lib)
 733
 734 dnl portability macros for getaddrinfo/getnameinfo
 735 dnl
 736 dnl Check for sa_len
 737 AC_CHECK_SA_LEN(ac_cv_sockaddr_has_sa_len)
 738 if test "$ac_cv_sockaddr_has_sa_len" = no; then
 739         missing_includes=yes
 740 fi
 741
 742 #
 743 # Do we have the new open API?  Check for pcap_create, and assume that,
 744 # if we do, we also have pcap_activate() and the other new routines
 745 # introduced in libpcap 1.0.0.
 746 #
 747 AC_CHECK_FUNCS(pcap_create)
 748 if test $ac_cv_func_pcap_create = "yes" ; then
 749         #
 750         # OK, do we have pcap_set_tstamp_type?  If so, assume we have
 751         # pcap_list_tstamp_types and pcap_free_tstamp_types as well.
 752         #
 753         AC_CHECK_FUNCS(pcap_set_tstamp_type)
 754 fi
 755
 756 AC_CHECK_FUNCS(pcap_findalldevs pcap_dump_flush pcap_lib_version)
 757 if test $ac_cv_func_pcap_findalldevs = "yes" ; then
 758 dnl Check for Mac OS X, which may ship pcap.h from 0.6 but libpcap may
 759 dnl be 0.8; this means that lib has pcap_findalldevs but header doesn't
 760 dnl have pcap_if_t.
 761     savedppflags="$CPPLAGS"
 762     CPPFLAGS="$CPPFLAGS $V_INCLS"
 763     AC_CHECK_TYPES(pcap_if_t, , , [#include <pcap.h>])
 764     CPPFLAGS="$savedcppflags"
 765 fi
 766
 767 if test $ac_cv_func_pcap_lib_version = "no" ; then
 768     AC_MSG_CHECKING(whether pcap_version is defined by libpcap)
 769     AC_TRY_LINK([],
 770        [
 771         extern char pcap_version[];
 772
 773         return (int)pcap_version;
 774        ],
 775        ac_lbl_cv_pcap_version_defined=yes,
 776        ac_lbl_cv_pcap_version_defined=no)
 777     if test "$ac_lbl_cv_pcap_version_defined" = yes ; then
 778         AC_MSG_RESULT(yes)
 779         AC_DEFINE(HAVE_PCAP_VERSION)
 780     else
 781         AC_MSG_RESULT(no)
 782     fi
 783 fi
 784 AC_MSG_CHECKING(whether pcap_debug is defined by libpcap)
 785 AC_TRY_LINK([],
 786    [
 787         extern int pcap_debug;
 788
 789         return pcap_debug;
 790    ],
 791    ac_lbl_cv_pcap_debug_defined=yes,
 792    ac_lbl_cv_pcap_debug_defined=no)
 793 if test "$ac_lbl_cv_pcap_debug_defined" = yes ; then
 794         AC_MSG_RESULT(yes)
 795         AC_DEFINE(HAVE_PCAP_DEBUG)
 796 else
 797         AC_MSG_RESULT(no)
 798         #
 799         # OK, what about "yydebug"?
 800         #
 801         AC_MSG_CHECKING(whether yydebug is defined by libpcap)
 802         AC_TRY_LINK([],
 803            [
 804                 extern int yydebug;
 805
 806                 return yydebug;
 807            ],
 808            ac_lbl_cv_yydebug_defined=yes,
 809            ac_lbl_cv_yydebug_defined=no)
 810         if test "$ac_lbl_cv_yydebug_defined" = yes ; then
 811                 AC_MSG_RESULT(yes)
 812                 AC_DEFINE(HAVE_YYDEBUG)
 813         else
 814                 AC_MSG_RESULT(no)
 815         fi
 816 fi
 817 AC_REPLACE_FUNCS(bpf_dump)      dnl moved to libpcap in 0.6
 818
 819 V_GROUP=0
 820 if test -f /etc/group -a ! -z "`grep '^wheel:' /etc/group`" ; then
 821         V_GROUP=wheel
 822 fi
 823 #
 824 # Assume V7/BSD convention for man pages (file formats in section 5,
 825 # miscellaneous info in section 7).
 826 #
 827 MAN_FILE_FORMATS=5
 828 MAN_MISC_INFO=7
 829 case "$host_os" in
 830
 831 aix*)
 832         dnl Workaround to enable certain features
 833         AC_DEFINE(_SUN,1,[define on AIX to get certain functions])
 834         ;;
 835
 836 hpux*)
 837         #
 838         # Use System V conventions for man pages.
 839         #
 840         MAN_FILE_FORMATS=4
 841         MAN_MISC_INFO=5
 842         ;;
 843
 844 irix*)
 845         V_GROUP=sys
 846
 847         #
 848         # Use System V conventions for man pages.
 849         #
 850         MAN_FILE_FORMATS=4
 851         MAN_MISC_INFO=5
 852         ;;
 853
 854 osf*)
 855         V_GROUP=system
 856
 857         #
 858         # Use System V conventions for man pages.
 859         #
 860         MAN_FILE_FORMATS=4
 861         MAN_MISC_INFO=5
 862         ;;
 863
 864 solaris*)
 865         V_GROUP=sys
 866
 867         #
 868         # Use System V conventions for man pages.
 869         #
 870         MAN_FILE_FORMATS=4
 871         MAN_MISC_INFO=5
 872         ;;
 873 esac
 874
 875 if test -f /dev/bpf0 ; then
 876         V_GROUP=bpf
 877 fi
 878
 879 #
 880 # Check for some headers introduced in later versions of libpcap
 881 # and used by some printers.
 882 #
 883 savedcppflags="$CPPFLAGS"
 884 CPPFLAGS="$CPPFLAGS $V_INCLS"
 885 AC_CHECK_HEADERS(pcap/bluetooth.h)
 886 AC_CHECK_HEADERS(pcap/usb.h)
 887 CPPFLAGS="$savedcppflags"
 888
 889 AC_CHECK_HEADERS(sys/bitypes.h)
 890
 891 AC_CHECK_TYPE([int8_t], ,
 892         [AC_DEFINE([int8_t], [signed char],
 893         [Define to `signed char' if int8_t not defined.])],
 894         [AC_INCLUDES_DEFAULT
 895 #ifdef HAVE_SYS_BITYPES_H
 896 #include <sys/bitypes.h>
 897 #endif])
 898 AC_CHECK_TYPE([u_int8_t], ,
 899         [AC_DEFINE([u_int8_t], [unsigned char],
 900         [Define to `unsigned char' if u_int8_t not defined.])],
 901         [AC_INCLUDES_DEFAULT
 902 #ifdef HAVE_SYS_BITYPES_H
 903 #include <sys/bitypes.h>
 904 #endif])
 905 AC_CHECK_TYPE([int16_t], ,
 906         [AC_DEFINE([int16_t], [short],
 907         [Define to `short' if int16_t not defined.])]
 908         [AC_INCLUDES_DEFAULT
 909 #ifdef HAVE_SYS_BITYPES_H
 910 #include <sys/bitypes.h>
 911 #endif])
 912 AC_CHECK_TYPE([u_int16_t], ,
 913         [AC_DEFINE([u_int16_t], [unsigned short],
 914         [Define to `unsigned short' if u_int16_t not defined.])],
 915         [AC_INCLUDES_DEFAULT
 916 #ifdef HAVE_SYS_BITYPES_H
 917 #include <sys/bitypes.h>
 918 #endif])
 919 AC_CHECK_TYPE([int32_t], ,
 920         [AC_DEFINE([int32_t], [int],
 921         [Define to `int' if int32_t not defined.])],
 922         [AC_INCLUDES_DEFAULT
 923 #ifdef HAVE_SYS_BITYPES_H
 924 #include <sys/bitypes.h>
 925 #endif])
 926 AC_CHECK_TYPE([u_int32_t], ,
 927         [AC_DEFINE([u_int32_t], [unsigned int],
 928         [Define to `unsigned int' if u_int32_t not defined.])],
 929         [AC_INCLUDES_DEFAULT
 930 #ifdef HAVE_SYS_BITYPES_H
 931 #include <sys/bitypes.h>
 932 #endif])
 933 AC_CHECK_TYPE([int64_t], ,
 934         [AC_DEFINE([int64_t], [long long],
 935         [Define to `long long' if int64_t not defined.])],
 936         [AC_INCLUDES_DEFAULT
 937 #ifdef HAVE_SYS_BITYPES_H
 938 #include <sys/bitypes.h>
 939 #endif])
 940 AC_CHECK_TYPE([u_int64_t], ,
 941         [AC_DEFINE([u_int64_t], [unsigned long long],
 942         [Define to `unsigned long long' if u_int64_t not defined.])],
 943         [AC_INCLUDES_DEFAULT
 944 #ifdef HAVE_SYS_BITYPES_H
 945 #include <sys/bitypes.h>
 946 #endif])
 947
 948 #
 949 # We can't just check for <inttypes.h> - some systems have one that
 950 # doesn't define all the PRI[doxu]64 macros.
 951 #
 952 AC_CHECK_HEADERS(inttypes.h,
 953   [
 954     #
 955     # OK, we have inttypes.h, but does it define those macros?
 956     #
 957     AC_MSG_CHECKING([[whether inttypes.h defines the PRI[doxu]64 macros]])
 958     AC_COMPILE_IFELSE(
 959       [
 960         AC_LANG_SOURCE(
 961           [[
 962             #include <inttypes.h>
 963             #include <stdio.h>
 964             #include <sys/types.h>
 965             #ifdef HAVE_SYS_BITYPES_H
 966             #include <sys/bitypes.h>
 967             #endif
 968
 969             main()
 970             {
 971               printf("%" PRId64 "\n", (u_int64_t)1);
 972               printf("%" PRIo64 "\n", (u_int64_t)1);
 973               printf("%" PRIx64 "\n", (u_int64_t)1);
 974               printf("%" PRIu64 "\n", (u_int64_t)1);
 975             }
 976           ]])
 977       ],
 978       [
 979         AC_MSG_RESULT(yes)
 980         ac_lbl_inttypes_h_defines_formats=yes
 981       ],
 982       [
 983         AC_MSG_RESULT(no)
 984         ac_lbl_inttypes_h_defines_formats=no
 985       ])
 986   ],
 987   [
 988     #
 989     # We don't have inttypes.h, so it obviously can't define those
 990     # macros.
 991     #
 992     ac_lbl_inttypes_h_defines_formats=no
 993   ])
 994 if test "$ac_lbl_inttypes_h_defines_formats" = no; then
 995   AC_LBL_CHECK_64BIT_FORMAT(l,
 996     [
 997       AC_LBL_CHECK_64BIT_FORMAT(ll,
 998         [
 999           AC_LBL_CHECK_64BIT_FORMAT(L,
1000             [
1001               AC_LBL_CHECK_64BIT_FORMAT(q,
1002                 [
1003                   AC_MSG_ERROR([neither %llx nor %Lx nor %qx worked on a 64-bit integer])
1004                 ])
1005             ])
1006         ])
1007     ])
1008 fi
1009
1010 AC_PROG_RANLIB
1011
1012 AC_LBL_DEVEL(V_CCOPT)
1013
1014 AC_LBL_SOCKADDR_SA_LEN
1015
1016 AC_LBL_UNALIGNED_ACCESS
1017
1018 AC_VAR_H_ERRNO
1019
1020 # Check for SSLeay
1021 AC_MSG_CHECKING(whether to use SSLeay libcrypto)
1022 # Specify location for both includes and libraries.
1023 want_libcrypto=youmama
1024 AC_ARG_WITH(crypto,
1025     AS_HELP_STRING([--with-crypto@<:@=PATH@:>@],
1026                    [use SSLeay libcrypto (located in directory PATH, if supplied).  @<:@default=yes, if available@:>@]),
1027 [
1028         if test $withval = no
1029         then
1030                 want_libcrypto=no
1031                 AC_MSG_RESULT(no)
1032         elif test $withval = yes
1033         then
1034                 want_libcrypto=yes
1035                 AC_MSG_RESULT(yes)
1036         else
1037                 want_libcrypto=yes
1038                 AC_MSG_RESULT(yes)
1039                 crypto_dir=$withval
1040         fi
1041 ],[
1042         #
1043         # Use libcrypto if it's present, otherwise don't.
1044         #
1045         want_libcrypto=ifavailable
1046         AC_MSG_RESULT([yes, if available])
1047 ])
1048 if test "$want_libcrypto" != "no"; then
1049         ac_cv_ssleay_path=no
1050         incdir=no
1051         if test "x$crypto_dir" = x; then
1052                 #
1053                 # Location not specified; check the default locations.
1054                 #
1055                 AC_MSG_CHECKING(where SSLeay is located)
1056                 dirs="/usr /usr/local /usr/local/ssl /usr/pkg"
1057                 if test "x${host_alias}" != x; then
1058                         dirs="/usr/${host_alias} $dirs"
1059                 fi
1060                 for dir in $dirs; do
1061                         AC_LBL_SSLEAY($dir)
1062
1063                         if test "$ac_cv_ssleay_path" != "no" -a "$incdir" != "no"; then
1064                                 break;
1065                         else
1066                                 ac_cv_ssleay_path=no
1067                                 incdir=no
1068                         fi
1069                 done
1070                 if test "$ac_cv_ssleay_path" != no; then
1071                         AC_MSG_RESULT($ac_cv_ssleay_path)
1072                 fi
1073         else
1074                 AC_MSG_CHECKING(for SSLeay in $crypto_dir)
1075                 AC_LBL_SSLEAY($crypto_dir)
1076                 if test "$ac_cv_ssleay_path" != no; then
1077                         AC_MSG_RESULT(found)
1078                 fi
1079         fi
1080         if test "$ac_cv_ssleay_path" != no; then
1081                 V_INCLS="$V_INCLS $incdir"
1082                 if test "$dir" != "/usr"; then
1083                         LDFLAGS="-L$dir/lib $LDFLAGS"
1084                 fi
1085                 if test -f $ac_cv_ssleay_path/lib/libRSAglue.a; then
1086                         LIBS="$LIBS -lRSAglue"
1087                 fi
1088                 if test -f $ac_cv_ssleay_path/lib/librsaref.a; then
1089                         LIBS="$LIBS -lrsaref"
1090                 fi
1091                 AC_CHECK_LIB(crypto, DES_cbc_encrypt)
1092
1093                 CPPFLAGS="$CPPFLAGS $V_INCLS"
1094                 AC_CHECK_HEADERS(openssl/evp.h)
1095         else
1096                 #
1097                 # Not found.  Did the user explicitly ask for it?
1098                 #
1099                 AC_MSG_RESULT(not found)
1100                 if test "$want_libcrypto" = yes; then
1101                         AC_MSG_ERROR(SSLeay not found)
1102                 fi
1103         fi
1104 fi
1105
1106 dnl
1107 dnl set additional include path if necessary
1108 if test "$missing_includes" = "yes"; then
1109         CPPFLAGS="$CPPFLAGS -I\$(srcdir)/missing"
1110         V_INCLS="$V_INCLS -I\$(srcdir)/missing"
1111 fi
1112
1113 AC_SUBST(V_CCOPT)
1114 AC_SUBST(V_DEFS)
1115 AC_SUBST(V_GROUP)
1116 AC_SUBST(V_INCLS)
1117 AC_SUBST(V_PCAPDEP)
1118 AC_SUBST(LOCALSRC)
1119 AC_SUBST(MAN_FILE_FORMATS)
1120 AC_SUBST(MAN_MISC_INFO)
1121
1122 AC_PROG_INSTALL
1123
1124 AC_CONFIG_HEADER(config.h)
1125
1126 AC_OUTPUT_COMMANDS([if test -f .devel; then
1127         echo timestamp > stamp-h
1128         cat Makefile-devel-adds >> Makefile
1129         make depend
1130 fi])
1131 AC_OUTPUT(Makefile tcpdump.1)
1132 exit 0