The Tcpdump Group git mirrors - tcpdump/blob - configure.in

   1 dnl @(#) $Header: /tcpdump/master/tcpdump/configure.in,v 1.143 2001-10-09 06:56:24 guy Exp $ (LBL)
   2 dnl
   3 dnl Copyright (c) 1994, 1995, 1996, 1997
   4 dnl     The Regents of the University of California.  All rights reserved.
   5 dnl
   6 dnl Process this file with autoconf to produce a configure script.
   7 dnl
   8
   9 AC_REVISION($Revision: 1.143 $)
  10 AC_PREREQ(2.13)
  11 AC_INIT(tcpdump.c)
  12
  13 AC_CANONICAL_SYSTEM
  14
  15 AC_LBL_C_INIT(V_CCOPT, V_INCLS)
  16 AC_C_INLINE
  17 AC_C___ATTRIBUTE__
  18
  19 AC_CHECK_HEADERS(fcntl.h rpc/rpcent.h netinet/if_ether.h)
  20 AC_HEADER_TIME
  21
  22 case "$target_os" in
  23
  24 linux*)
  25         AC_MSG_CHECKING(Linux kernel version)
  26         if test "$cross_compiling" = yes; then
  27                 AC_CACHE_VAL(ac_cv_linux_vers,
  28                     ac_cv_linux_vers=unknown)
  29         else
  30                 AC_CACHE_VAL(ac_cv_linux_vers,
  31                     ac_cv_linux_vers=`uname -r 2>&1 | \
  32                         sed -n -e '$s/.* //' -e '$s/\..*//p'`)
  33         fi
  34         AC_MSG_RESULT($ac_cv_linux_vers)
  35         if test $ac_cv_linux_vers = unknown ; then
  36                 AC_MSG_ERROR(cannot determine linux version when cross-compiling)
  37         fi
  38         if test $ac_cv_linux_vers -lt 2 ; then
  39                 AC_MSG_ERROR(version 2 or higher required; see the INSTALL doc for more info)
  40         fi
  41         ;;
  42
  43 *)
  44         ;;
  45 esac
  46
  47
  48 AC_CHECK_HEADERS(smi.h)
  49 AC_CHECK_LIB(smi, smiInit)
  50 if test "$ac_cv_header_smi_h" = yes -a "$ac_cv_lib_smi_smiInit" = yes
  51 then
  52 AC_MSG_CHECKING([whether to enable libsmi])
  53         AC_TRY_RUN([ /* libsmi available check */
  54 #include <smi.h>
  55 main()
  56 {
  57   int current, revision, age, n;
  58   const int required = 2;
  59   if (smiInit(""))
  60     exit(1);
  61   if (strcmp(SMI_LIBRARY_VERSION, smi_library_version))
  62     exit(2);
  63   n = sscanf(smi_library_version, "%d:%d:%d", &current, &revision, &age);
  64   if (n != 3)
  65     exit(3);
  66   if (required < current - age || required > current)
  67     exit(4);
  68   exit(0);
  69 }
  70 ],
  71 [ AC_MSG_RESULT(yes)
  72   AC_DEFINE(LIBSMI)
  73   libsmi=yes],
  74 dnl autoconf documentation says that $? contains the exit value.
  75 dnl reality is that it does not.  We leave this in just in case
  76 dnl autoconf ever comes back to match the documentation.
  77 [ case $? in
  78   1) AC_MSG_RESULT(no - smiInit failed) ;;
  79   2) AC_MSG_RESULT(no - header/library version mismatch) ;;
  80   3) AC_MSG_RESULT(no - can't determine library version) ;;
  81   4) AC_MSG_RESULT(no - too old) ;;
  82   *) AC_MSG_RESULT(no) ;;
  83   esac
  84   libsmi=no],
  85 [ AC_MSG_RESULT(not when cross-compiling)
  86   libsmi=no]
  87 )
  88 fi
  89
  90 AC_MSG_CHECKING([whether to enable the possibly-buggy SMB printer])
  91 AC_ARG_ENABLE(smb,
  92 [  --enable-smb            enable possibly-buggy SMB printer],
  93 [ case "$enableval" in
  94 yes)    AC_MSG_RESULT(yes)
  95         AC_WARN([The SMB printer may have exploitable buffer overflows!!!])
  96         AC_DEFINE(TCPDUMP_DO_SMB)
  97         LOCALSRC="print-smb.c smbutil.c $LOCALSRC"
  98         ;;
  99 *)      AC_MSG_RESULT(no)
 100         ;;
 101   esac
 102 ], AC_MSG_RESULT(no))
 103
 104 CFLAGS="$CFLAGS -Dss_family=__ss_family -Dss_len=__ss_len"
 105 AC_MSG_CHECKING([whether to enable ipv6])
 106 AC_ARG_ENABLE(ipv6,
 107 [  --enable-ipv6           enable ipv6 (with ipv4) support
 108   --disable-ipv6          disable ipv6 support],
 109 [ case "$enableval" in
 110 yes)   AC_MSG_RESULT(yes)
 111        LOCALSRC="print-ip6.c print-ip6opts.c print-ripng.c print-icmp6.c print-frag6.c print-rt6.c print-ospf6.c print-dhcp6.c $LOCALSRC"
 112        AC_DEFINE(INET6)
 113        ipv6=yes
 114        ;;
 115 *)
 116        AC_MSG_RESULT(no)
 117        ipv6=no
 118        ;;
 119   esac ],
 120
 121   AC_TRY_RUN([ /* AF_INET6 available check */
 122 #include <sys/types.h>
 123 #include <sys/socket.h>
 124 main()
 125 {
 126  if (socket(AF_INET6, SOCK_STREAM, 0) < 0)
 127    exit(1);
 128  else
 129    exit(0);
 130 }
 131 ],
 132 [ AC_MSG_RESULT(yes)
 133   LOCALSRC="print-ip6.c print-ip6opts.c print-ripng.c print-icmp6.c print-frag6.c print-rt6.c print-ospf6.c print-dhcp6.c $LOCALSRC"
 134   AC_DEFINE(INET6)
 135   ipv6=yes],
 136 [ AC_MSG_RESULT(no)
 137   ipv6=no],
 138 [ AC_MSG_RESULT(no)
 139   ipv6=no]
 140 ))
 141
 142 ipv6type=unknown
 143 ipv6lib=none
 144 ipv6trylibc=no
 145
 146 if test "$ipv6" = "yes"; then
 147         AC_MSG_CHECKING([ipv6 stack type])
 148         for i in inria kame linux-glibc linux-libinet6 toshiba v6d zeta; do
 149                 case $i in
 150                 inria)
 151                         dnl http://www.kame.net/
 152                         AC_EGREP_CPP(yes, [dnl
 153 #include <netinet/in.h>
 154 #ifdef IPV6_INRIA_VERSION
 155 yes
 156 #endif],
 157                                 [ipv6type=$i;
 158                                 CFLAGS="-DINET6 $CFLAGS"])
 159                         ;;
 160                 kame)
 161                         dnl http://www.kame.net/
 162                         AC_EGREP_CPP(yes, [dnl
 163 #include <netinet/in.h>
 164 #ifdef __KAME__
 165 yes
 166 #endif],
 167                                 [ipv6type=$i;
 168                                 ipv6lib=inet6;
 169                                 ipv6libdir=/usr/local/v6/lib;
 170                                 ipv6trylibc=yes;
 171                                 CFLAGS="-DINET6 $CFLAGS"])
 172                         ;;
 173                 linux-glibc)
 174                         dnl http://www.v6.linux.or.jp/
 175                         AC_EGREP_CPP(yes, [dnl
 176 #include <features.h>
 177 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 178 yes
 179 #endif],
 180                                 [ipv6type=$i;
 181                                 CFLAGS="-DINET6 $CFLAGS"])
 182                         ;;
 183                 linux-libinet6)
 184                         dnl http://www.v6.linux.or.jp/
 185                         if test -d /usr/inet6 -o -f /usr/include/netinet/ip6.h; then
 186                                 ipv6type=$i
 187                                 ipv6lib=inet6
 188                                 ipv6libdir=/usr/inet6/lib
 189                                 ipv6trylibc=yes;
 190                                 CFLAGS="-DINET6 -I/usr/inet6/include $CFLAGS"
 191                         fi
 192                         ;;
 193                 toshiba)
 194                         AC_EGREP_CPP(yes, [dnl
 195 #include <sys/param.h>
 196 #ifdef _TOSHIBA_INET6
 197 yes
 198 #endif],
 199                                 [ipv6type=$i;
 200                                 ipv6lib=inet6;
 201                                 ipv6libdir=/usr/local/v6/lib;
 202                                 CFLAGS="-DINET6 $CFLAGS"])
 203                         ;;
 204                 v6d)
 205                         AC_EGREP_CPP(yes, [dnl
 206 #include </usr/local/v6/include/sys/v6config.h>
 207 #ifdef __V6D__
 208 yes
 209 #endif],
 210                                 [ipv6type=$i;
 211                                 ipv6lib=v6;
 212                                 ipv6libdir=/usr/local/v6/lib;
 213                                 CFLAGS="-I/usr/local/v6/include $CFLAGS"])
 214                         ;;
 215                 zeta)
 216                         AC_EGREP_CPP(yes, [dnl
 217 #include <sys/param.h>
 218 #ifdef _ZETA_MINAMI_INET6
 219 yes
 220 #endif],
 221                                 [ipv6type=$i;
 222                                 ipv6lib=inet6;
 223                                 ipv6libdir=/usr/local/v6/lib;
 224                                 CFLAGS="-DINET6 $CFLAGS"])
 225                         ;;
 226                 esac
 227                 if test "$ipv6type" != "unknown"; then
 228                         break
 229                 fi
 230         done
 231         AC_MSG_RESULT($ipv6type)
 232 fi
 233
 234 if test "$ipv6" = "yes" -a "$ipv6lib" != "none"; then
 235         if test -d $ipv6libdir -a -f $ipv6libdir/lib$ipv6lib.a; then
 236                 LIBS="-L$ipv6libdir -l$ipv6lib $LIBS"
 237                 echo "You have $ipv6lib library, using it"
 238         else
 239                 if test "$ipv6trylibc" = "yes"; then
 240                         echo "You do not have $ipv6lib library, using libc"
 241                 else
 242                         echo 'Fatal: no $ipv6lib library found.  cannot continue.'
 243                         echo "You need to fetch lib$ipv6lib.a from appropriate"
 244                         echo 'ipv6 kit and compile beforehand.'
 245                         exit 1
 246                 fi
 247         fi
 248 fi
 249
 250
 251 if test "$ipv6" = "yes"; then
 252         AC_SEARCH_LIBS(getaddrinfo, socket, [dnl
 253         AC_MSG_CHECKING(getaddrinfo bug)
 254         AC_TRY_RUN([
 255 #include <sys/types.h>
 256 #include <netdb.h>
 257 #include <string.h>
 258 #include <sys/socket.h>
 259 #include <netinet/in.h>
 260
 261 main()
 262 {
 263   int passive, gaierr, inet4 = 0, inet6 = 0;
 264   struct addrinfo hints, *ai, *aitop;
 265   char straddr[INET6_ADDRSTRLEN], strport[16];
 266
 267   for (passive = 0; passive <= 1; passive++) {
 268     memset(&hints, 0, sizeof(hints));
 269     hints.ai_family = AF_UNSPEC;
 270     hints.ai_flags = passive ? AI_PASSIVE : 0;
 271     hints.ai_socktype = SOCK_STREAM;
 272     if ((gaierr = getaddrinfo(NULL, "54321", &hints, &aitop)) != 0) {
 273       (void)gai_strerror(gaierr);
 274       goto bad;
 275     }
 276     for (ai = aitop; ai; ai = ai->ai_next) {
 277       if (ai->ai_addr == NULL ||
 278           ai->ai_addrlen == 0 ||
 279           getnameinfo(ai->ai_addr, ai->ai_addrlen,
 280                       straddr, sizeof(straddr), strport, sizeof(strport),
 281                       NI_NUMERICHOST|NI_NUMERICSERV) != 0) {
 282         goto bad;
 283       }
 284       switch (ai->ai_family) {
 285       case AF_INET:
 286         if (strcmp(strport, "54321") != 0) {
 287           goto bad;
 288         }
 289         if (passive) {
 290           if (strcmp(straddr, "0.0.0.0") != 0) {
 291             goto bad;
 292           }
 293         } else {
 294           if (strcmp(straddr, "127.0.0.1") != 0) {
 295             goto bad;
 296           }
 297         }
 298         inet4++;
 299         break;
 300       case AF_INET6:
 301         if (strcmp(strport, "54321") != 0) {
 302           goto bad;
 303         }
 304         if (passive) {
 305           if (strcmp(straddr, "::") != 0) {
 306             goto bad;
 307           }
 308         } else {
 309           if (strcmp(straddr, "::1") != 0) {
 310             goto bad;
 311           }
 312         }
 313         inet6++;
 314         break;
 315       case AF_UNSPEC:
 316         goto bad;
 317         break;
 318 #ifdef AF_UNIX
 319       case AF_UNIX:
 320 #else
 321 #ifdef AF_LOCAL
 322       case AF_LOCAL:
 323 #endif
 324 #endif
 325       default:
 326         /* another family support? */
 327         break;
 328       }
 329     }
 330   }
 331
 332   /* supported family should be 2, unsupported family should be 0 */
 333   if (!(inet4 == 0 || inet4 == 2))
 334     goto bad;
 335   if (!(inet6 == 0 || inet6 == 2))
 336     goto bad;
 337
 338   if (aitop)
 339     freeaddrinfo(aitop);
 340   exit(0);
 341
 342  bad:
 343   if (aitop)
 344     freeaddrinfo(aitop);
 345   exit(1);
 346 }
 347 ],
 348         AC_MSG_RESULT(good)
 349         buggygetaddrinfo=no,
 350         AC_MSG_RESULT(buggy)
 351         buggygetaddrinfo=yes,
 352         AC_MSG_RESULT(buggy)
 353         buggygetaddrinfo=yes)], [buggygetaddrinfo=yes])
 354
 355         if test "$buggygetaddrinfo" = "yes"; then
 356                 if test "$ipv6type" != "linux"; then
 357                         echo 'Fatal: You must get working getaddrinfo() function.'
 358                         echo '       or you can specify "--disable-ipv6"'.
 359                         exit 1
 360                 else
 361                         echo 'Warning: getaddrinfo() implementation on your system seems be buggy.'
 362                         echo '         Better upgreade your system library to newest version'
 363                         echo '         of GNU C library (aka glibc).'
 364                 fi
 365         fi
 366         AC_REPLACE_FUNCS(getaddrinfo getnameinfo)
 367 fi
 368 dnl AC_TRY_COMPILE(inet_ntop inet_pton inet_aton)
 369 AC_MSG_CHECKING(for inet_ntop)
 370 AC_TRY_COMPILE([#include <sys/types.h>
 371 #include <sys/socket.h>
 372 #include <netinet/in.h>
 373 #include <arpa/inet.h>], [char src[4], dst[128];
 374 inet_ntop(AF_INET, src, dst, sizeof(dst));],
 375         [AC_MSG_RESULT(yes)], [AC_MSG_RESULT(no)
 376         AC_REPLACE_FUNCS(inet_ntop)])
 377 AC_MSG_CHECKING(for inet_pton)
 378 AC_TRY_COMPILE([#include <sys/types.h>
 379 #include <sys/socket.h>
 380 #include <netinet/in.h>
 381 #include <arpa/inet.h>], [char src[128], dst[4];
 382 inet_pton(AF_INET, src, dst);],
 383         [AC_MSG_RESULT(yes)], [AC_MSG_RESULT(no)
 384         AC_REPLACE_FUNCS(inet_pton)])
 385 AC_MSG_CHECKING(for inet_aton)
 386 AC_TRY_COMPILE([#include <sys/types.h>
 387 #include <netinet/in.h>
 388 #include <arpa/inet.h>], [char src[128];
 389 struct in_addr dst;
 390 inet_aton(src, &dst);],
 391         [AC_MSG_RESULT(yes)], [AC_MSG_RESULT(no)
 392         AC_REPLACE_FUNCS(inet_aton)])
 393
 394 dnl portability macros for getaddrinfo/getnameinfo
 395 dnl
 396 dnl Check for sa_len
 397 AC_CHECK_SA_LEN(ac_cv_sockaddr_has_sa_len)
 398 if test "$ac_cv_sockaddr_has_sa_len" = no; then
 399         missing_includes=yes
 400 fi
 401
 402 dnl
 403 dnl check sizeof basic types.
 404 dnl They're very likely to be wrong for cross-compiling.
 405 AC_CHECK_SIZEOF(char, 1)
 406 AC_CHECK_SIZEOF(short, 2)
 407 AC_CHECK_SIZEOF(int, 4)
 408 AC_CHECK_SIZEOF(long, 4)
 409
 410 dnl
 411 dnl Checks for u_intXX_t
 412 dnl AC_CHECK_BITTYPES(ac_cv_bittypes)
 413 dnl if test "$ac_cv_bittypes" = no; then
 414 dnl     missing_includes=yes
 415 dnl fi
 416
 417 dnl
 418 dnl Checks for addrinfo structure
 419 AC_STRUCT_ADDRINFO(ac_cv_addrinfo)
 420 if test "$ac_cv_addrinfo" = no; then
 421         missing_includes=yes
 422 fi
 423
 424 dnl
 425 dnl Checks for NI_MAXSERV
 426 AC_NI_MAXSERV(ac_cv_maxserv)
 427 if test "$ac_cv_maxserv" = no; then
 428         missing_includes=yes
 429 fi
 430
 431 dnl
 432 dnl Checks for NI_NAMEREQD
 433 AC_NI_NAMEREQD(ac_cv_namereqd)
 434 if test "$ac_cv_namereqd" = no; then
 435         missing_includes=yes
 436 fi
 437
 438 dnl
 439 dnl Checks for sockaddr_storage structure
 440 AC_STRUCT_SA_STORAGE(ac_cv_sa_storage)
 441 if test "$ac_cv_sa_storage" = no; then
 442         missing_includes=yes
 443 fi
 444
 445 dnl
 446 dnl Checks for IN[6]ADDRSZ
 447 AC_CHECK_ADDRSZ(ac_cv_addrsz)
 448 if test "$ac_cv_addrsz" = no; then
 449         missing_includes=yes
 450 fi
 451
 452 dnl
 453 dnl Checks for RES_USE_INET6
 454 AC_CHECK_RES_USE_INET6(ac_cv_res_inet6)
 455 if test "$ac_cv_res_inet6" = no; then
 456         missing_includes=yes
 457 fi
 458
 459 dnl
 460 dnl Checks for res_state_ext structure
 461 AC_STRUCT_RES_STATE_EXT(ac_cv_res_state_ext)
 462 if test "$ac_cv_res_state_ext" = no; then
 463         missing_includes=yes
 464 fi
 465
 466 dnl
 467 dnl Checks if res_state structure has nsort member.
 468 AC_STRUCT_RES_STATE(ac_cv_res_state)
 469
 470 dnl
 471 dnl set additional include path if necessary
 472 if test "$missing_includes" = "yes"; then
 473         CPPFLAGS="$CPPFLAGS -I\$(srcdir)/missing"
 474         V_INCLS="$V_INCLS -I\$(srcdir)/missing"
 475 fi
 476
 477
 478 AC_REPLACE_FUNCS(vfprintf strcasecmp strlcat strlcpy strdup)
 479 AC_CHECK_FUNCS(ether_ntohost, [
 480     AC_CACHE_CHECK(for buggy ether_ntohost, ac_cv_buggy_ether_ntohost, [
 481         AC_TRY_RUN([
 482                 #include <netdb.h>
 483                 #include <sys/types.h>
 484                 #include <sys/param.h>
 485                 #include <sys/socket.h>
 486
 487                 int
 488                 main(int argc, char **argv)
 489                 {
 490                         u_char ea[6] = { 0xff, 0xff, 0xff, 0xff, 0xff };
 491                         char name[MAXHOSTNAMELEN];
 492
 493                         ether_ntohost(name, (struct ether_addr *)ea);
 494                         exit(0);
 495                 }
 496         ], [ac_cv_buggy_ether_ntohost=no],
 497            [ac_cv_buggy_ether_ntohost=yes],
 498            [ac_cv_buggy_ether_ntohost=not while cross-compiling])])
 499     if test "$ac_cv_buggy_ether_ntohost" = "no"; then
 500         AC_DEFINE(USE_ETHER_NTOHOST)
 501     fi
 502 ])
 503 AC_CHECK_FUNCS(setlinebuf)
 504
 505 needsnprintf=no
 506 AC_CHECK_FUNCS(vsnprintf snprintf,,
 507         [needsnprintf=yes])
 508 if test $needsnprintf = yes; then
 509         LIBOBJS="$LIBOBJS snprintf.o"
 510 fi
 511
 512 AC_LBL_TYPE_SIGNAL
 513
 514 AC_CHECK_LIB(dnet, dnet_htoa)
 515
 516 AC_CHECK_LIB(rpc, main)         dnl It's unclear why we might need -lrpc
 517
 518 dnl HP/UX may need -lnsl for getrpcbynumber.
 519 AC_SEARCH_LIBS(getrpcbynumber, nsl)
 520
 521 dnl AC_CHECK_LIB(z, uncompress)
 522 dnl AC_CHECK_HEADERS(zlib.h)
 523
 524 AC_LBL_LIBPCAP(V_PCAPDEP, V_INCLS)
 525
 526 AC_REPLACE_FUNCS(bpf_dump)      dnl moved to libpcap in 0.6
 527
 528 V_GROUP=0
 529 if test -f /etc/group -a ! -z "`grep '^wheel:' /etc/group`" ; then
 530         V_GROUP=wheel
 531 fi
 532 case "$target_os" in
 533
 534 aix*)
 535         dnl Workaround to enable certain features
 536         AC_DEFINE(_SUN)
 537         ;;
 538
 539 irix*)
 540         V_GROUP=sys
 541         ;;
 542
 543 osf*)
 544         V_GROUP=system
 545         ;;
 546
 547 solaris*)
 548         V_GROUP=sys
 549         ;;
 550 esac
 551
 552 if test -f /dev/bpf0 ; then
 553         V_GROUP=bpf
 554 fi
 555
 556 AC_LBL_CHECK_TYPE(u_int8_t, u_char)
 557 AC_LBL_CHECK_TYPE(int16_t, short)
 558 AC_LBL_CHECK_TYPE(u_int16_t, u_short)
 559 AC_LBL_CHECK_TYPE(int32_t, int)
 560 AC_LBL_CHECK_TYPE(u_int32_t, u_int)
 561
 562 AC_LBL_DEVEL(V_CCOPT)
 563
 564 AC_LBL_SOCKADDR_SA_LEN
 565
 566 AC_LBL_UNALIGNED_ACCESS
 567
 568 AC_VAR_H_ERRNO
 569
 570 AC_ARG_WITH(crypto, [  --without-crypto        disable crypto support],
 571         [], [
 572 AC_MSG_CHECKING(for SSLeay)
 573 ac_cv_ssleay_path=no
 574 incdir=no
 575 for dir in /usr /usr/local /usr/local/ssl /usr/pkg; do
 576         if test -d $dir/lib -a -f $dir/lib/libcrypto.a; then
 577                 ac_cv_ssleay_path=$dir
 578         fi
 579         if test -d $dir/include/openssl -a -f $dir/include/openssl/des.h; then
 580                 incdir="-I$dir/include"
 581         fi
 582         if test "$ac_cv_ssleay_path" != "no" -a "$incdir" != "no"; then
 583                 break;
 584         else
 585                 ac_cv_ssleay_path=no
 586                 incdir=no
 587         fi
 588 done
 589 AC_MSG_RESULT($ac_cv_ssleay_path)
 590 if test "$ac_cv_ssleay_path" != no; then
 591         V_INCLS="$V_INCLS $incdir"
 592         LDFLAGS="-L$dir/lib $LDFLAGS"
 593         if test -f $ac_cv_ssleay_path/lib/libRSAglue.a; then
 594                 LIBS="$LIBS -lRSAglue"
 595         fi
 596         if test -f $ac_cv_ssleay_path/lib/librsaref.a; then
 597                 LIBS="$LIBS -lrsaref"
 598         fi
 599         AC_CHECK_LIB(crypto, des_cbc_encrypt)
 600
 601         bak_CPPFLAGS=$CPPFLAGS
 602         CPPFLAGS="$CPPFLAGS $V_INCLS"
 603         AC_CHECK_HEADERS(cast.h)
 604
 605         if test "$ac_cv_header_cast_h" = "yes"; then
 606                 AC_MSG_CHECKING(for buggy CAST128)
 607                 AC_TRY_RUN(dnl
 608 [
 609 #include <cast.h>
 610 main()
 611 {
 612         unsigned char key[] = {0x01,0x23,0x45,0x67,0x12};
 613         unsigned char in[] = {0x01,0x23,0x45,0x67,0x89,0xAB,0xCD,0xEF};
 614         unsigned char out[sizeof(in)];
 615         unsigned char ok[] = {0x7A,0xC8,0x16,0xD1,0x6E,0x9B,0x30,0x2E};
 616         CAST_KEY ks;
 617         CAST_set_key(&ks, sizeof(key), key);
 618         CAST_ecb_encrypt(in, out, &ks, CAST_ENCRYPT);
 619         if (memcmp(out, ok, sizeof(ok)) != 0)
 620                 return 0;
 621         else
 622                 return 1;
 623 }],
 624                         [buggy_cast128=yes],
 625                         [buggy_cast128=no],
 626                         [buggy_cast128="cross-compiling, assume yes"])
 627                 AC_MSG_RESULT($buggy_cast128)
 628                 if test "$buggy_cast128" != no; then
 629                         echo "NOTE: SSLeay 0.9.0b has a bug in CAST128 en/decoding routine."
 630                         echo "disabling CAST128 support."
 631                         AC_DEFINE(HAVE_BUGGY_CAST128)
 632                 fi
 633         fi
 634
 635         CPPFLAGS=$bak_CPPFLAGS
 636 fi
 637 ])
 638 AC_CHECK_HEADERS(rc5.h)
 639
 640 AC_SUBST(V_CCOPT)
 641 AC_SUBST(V_GROUP)
 642 AC_SUBST(V_INCLS)
 643 AC_SUBST(V_PCAPDEP)
 644 AC_SUBST(LOCALSRC)
 645
 646 AC_PROG_INSTALL
 647
 648 AC_CONFIG_HEADER(config.h)
 649
 650 AC_OUTPUT_COMMANDS([if test -f .devel; then
 651         echo timestamp > stamp-h
 652         cat Makefile-devel-adds >> Makefile
 653         make depend
 654 fi])
 655 AC_OUTPUT(Makefile)
 656 exit 0