The Tcpdump Group git mirrors - tcpdump/blob - configure.ac

   1 dnl Copyright (c) 1994, 1995, 1996, 1997
   2 dnl     The Regents of the University of California.  All rights reserved.
   3 dnl
   4 dnl Process this file with autoconf to produce a configure script.
   5 dnl
   6
   7 #
   8 # See
   9 #
  10 #       https://ftp.gnu.org/gnu/config/README
  11 #
  12 # for the URLs to use to fetch new versions of config.guess and
  13 # config.sub.
  14 #
  15
  16 AC_PREREQ(2.64)
  17 AC_INIT(tcpdump, m4_esyscmd_s([cat VERSION]))
  18 AC_CONFIG_SRCDIR(tcpdump.c)
  19
  20 AC_CANONICAL_HOST
  21
  22 AC_LBL_C_INIT_BEFORE_CC(V_INCLS)
  23 #
  24 # Try to enable as many C99 features as we can.
  25 # At minimum, we want C++/C99-style // comments.
  26 #
  27 AC_PROG_CC_C99
  28 if test "$ac_cv_prog_cc_c99" = "no"; then
  29         AC_MSG_WARN([The C compiler does not support C99; there may be compiler errors])
  30 fi
  31 AC_LBL_C_INIT(V_CCOPT, V_INCLS)
  32 AC_LBL_C_INLINE
  33
  34 AC_CHECK_HEADERS(fcntl.h rpc/rpc.h rpc/rpcent.h net/if.h)
  35
  36 case "$host_os" in
  37
  38 darwin*)
  39         AC_ARG_ENABLE(universal,
  40         AS_HELP_STRING([--disable-universal],[don't build universal on macOS]))
  41         if test "$enable_universal" != "no"; then
  42                 case "$host_os" in
  43
  44                 darwin9.*)
  45                         #
  46                         # Leopard.  Build for x86 and 32-bit PowerPC, with
  47                         # x86 first.  (That's what Apple does.)
  48                         #
  49                         V_CCOPT="$V_CCOPT -arch i386 -arch ppc"
  50                         LDFLAGS="$LDFLAGS -arch i386 -arch ppc"
  51                         ;;
  52
  53                 darwin10.*)
  54                         #
  55                         # Snow Leopard.  Build for x86-64 and x86, with
  56                         # x86-64 first.  (That's what Apple does.)
  57                         #
  58                         V_CCOPT="$V_CCOPT -arch x86_64 -arch i386"
  59                         LDFLAGS="$LDFLAGS -arch x86_64 -arch i386"
  60                         ;;
  61                 esac
  62         fi
  63         ;;
  64 esac
  65
  66
  67 AC_ARG_WITH([smi],
  68    [AS_HELP_STRING([--with-smi],
  69      [link with libsmi (allows to load MIBs on the fly to decode SNMP packets) [default=yes, if available]])],
  70    [],
  71    [with_smi=yes])
  72
  73 if test "x$with_smi" != "xno" ; then
  74         AC_CHECK_HEADER(smi.h,
  75         [
  76                 #
  77                 # OK, we found smi.h.  Do we have libsmi with smiInit?
  78                 #
  79                 AC_CHECK_LIB(smi, smiInit,
  80                 [
  81                         #
  82                         # OK, we have libsmi with smiInit.  Can we use it?
  83                         #
  84                         AC_MSG_CHECKING([whether to enable libsmi])
  85                         savedlibs="$LIBS"
  86                         LIBS="-lsmi $LIBS"
  87                         AC_TRY_RUN(
  88                                 [
  89 /* libsmi available check */
  90 #include <smi.h>
  91 main()
  92 {
  93   int current, revision, age, n;
  94   const int required = 2;
  95   if (smiInit(""))
  96     exit(1);
  97   if (strcmp(SMI_LIBRARY_VERSION, smi_library_version))
  98     exit(2);
  99   n = sscanf(smi_library_version, "%d:%d:%d", &current, &revision, &age);
 100   if (n != 3)
 101     exit(3);
 102   if (required < current - age || required > current)
 103     exit(4);
 104   exit(0);
 105 }
 106                                 ],
 107                                 [
 108                                         AC_MSG_RESULT(yes)
 109                                         AC_DEFINE(USE_LIBSMI, 1,
 110                                             [Define if you enable support for libsmi])
 111                                 ],
 112                                 [
 113                                         dnl autoconf documentation says that
 114                                         dnl $? contains the exit value.
 115                                         dnl reality is that it does not.
 116                                         dnl We leave this in just in case
 117                                         dnl autoconf ever comes back to
 118                                         dnl match the documentation.
 119                                         case $? in
 120                                           1) AC_MSG_RESULT(no - smiInit failed) ;;
 121                                           2) AC_MSG_RESULT(no - header/library version mismatch) ;;
 122                                           3) AC_MSG_RESULT(no - can't determine library version) ;;
 123                                           4) AC_MSG_RESULT(no - too old) ;;
 124                                           *) AC_MSG_RESULT(no) ;;
 125                                         esac
 126                                         LIBS="$savedlibs"
 127                                 ],
 128                                 [
 129                                         AC_MSG_RESULT(not when cross-compiling)
 130                                         LIBS="$savedlibs"
 131                                 ]
 132                         )
 133                 ])
 134         ])
 135 fi
 136
 137 AC_MSG_CHECKING([whether to enable the instrument functions code])
 138 AC_ARG_ENABLE([instrument-functions],
 139    [AS_HELP_STRING([--enable-instrument-functions],
 140      [enable instrument functions code [default=no]])],
 141    [],
 142    [enableval=no])
 143 case "$enableval" in
 144 yes)    AC_MSG_RESULT(yes)
 145         AC_CHECK_LIB([bfd], [bfd_init],
 146             [true],
 147             [AC_MSG_ERROR(
 148                [--enable-instrument-functions was given, but test for library libbfd failed. Please install the 'binutils-dev' package.])],
 149             [])
 150         AC_DEFINE(ENABLE_INSTRUMENT_FUNCTIONS, 1,
 151             [define if you want to build the instrument functions code])
 152         LOCALSRC="$LOCALSRC instrument-functions.c"
 153         # Add '-finstrument-functions' instrumentation option to generate
 154         # instrumentation calls for entry and exit to functions.
 155         # Try to avoid Address Space Layout Randomization (ALSR).
 156         CFLAGS="$CFLAGS -O0 -ggdb -finstrument-functions -fno-stack-protector -fno-pic"
 157         LDFLAGS="$LDFLAGS -O0 -ggdb -fno-stack-protector -no-pie"
 158         LIBS="$LIBS -lbfd"
 159         ;;
 160 *)      AC_MSG_RESULT(no)
 161         ;;
 162 esac
 163
 164 AC_MSG_CHECKING([whether to enable the possibly-buggy SMB printer])
 165 AC_ARG_ENABLE([smb],
 166    [AS_HELP_STRING([--enable-smb],
 167      [enable possibly-buggy SMB printer [default=no]])],
 168    [],
 169    [enableval=no])
 170 case "$enableval" in
 171 yes)    AC_MSG_RESULT(yes)
 172         AC_DEFINE(ENABLE_SMB, 1,
 173             [define if you want to build the possibly-buggy SMB printer])
 174         LOCALSRC="print-smb.c smbutil.c $LOCALSRC"
 175         ;;
 176 *)      AC_MSG_RESULT(no)
 177         ;;
 178 esac
 179
 180 AC_ARG_WITH(user, [  --with-user=USERNAME    drop privileges by default to USERNAME])
 181 AC_MSG_CHECKING([whether to drop root privileges by default])
 182 if test ! -z "$with_user" ; then
 183        AC_DEFINE_UNQUOTED(WITH_USER, "$withval",
 184            [define if should drop privileges by default])
 185        AC_MSG_RESULT(to \"$withval\")
 186 else
 187        AC_MSG_RESULT(no)
 188 fi
 189
 190 AC_ARG_WITH(chroot, [  --with-chroot=DIRECTORY when dropping privileges, chroot to DIRECTORY])
 191 AC_MSG_CHECKING([whether to chroot])
 192 if test ! -z "$with_chroot" && test "$with_chroot" != "no" ; then
 193        AC_DEFINE_UNQUOTED(WITH_CHROOT, "$withval",
 194            [define if should chroot when dropping privileges])
 195        AC_MSG_RESULT(to \"$withval\")
 196 else
 197        AC_MSG_RESULT(no)
 198 fi
 199
 200 AC_ARG_WITH(sandbox-capsicum,
 201         AS_HELP_STRING([--with-sandbox-capsicum],
 202                        [use Capsicum security functions @<:@default=yes, if available@:>@]))
 203 #
 204 # Check whether various functions are available.  If any are, set
 205 # ac_lbl_capsicum_function_seen to yes; if any are not, set
 206 # ac_lbl_capsicum_function_not_seen to yes.
 207 #
 208 # We don't check cap_rights_init(), as it's a macro, wrapping another
 209 # function, in at least some versions of FreeBSD, and AC_CHECK_FUNCS()
 210 # doesn't handle that.
 211 #
 212 # All of the ones we check for must be available in order to enable
 213 # capsicum sandboxing.
 214 #
 215 # XXX - do we need to check for all of them, or are there some that, if
 216 # present, imply others are present?
 217 #
 218 if test -z "$with_sandbox_capsicum" || test "$with_sandbox_capsicum" != "no" ; then
 219         #
 220         # First, make sure we have the required header.
 221         #
 222         AC_CHECK_HEADER(sys/capsicum.h,
 223         [
 224                 #
 225                 # We do; now make sure we have the required functions.
 226                 #
 227                 AC_CHECK_FUNCS(cap_enter cap_rights_limit cap_ioctls_limit openat,
 228                     ac_lbl_capsicum_function_seen=yes,
 229                     ac_lbl_capsicum_function_not_seen=yes)
 230         ])
 231         AC_CHECK_LIB(casper, cap_init, LIBS="$LIBS -lcasper")
 232         AC_CHECK_LIB(cap_dns, cap_gethostbyaddr, LIBS="$LIBS -lcap_dns")
 233 fi
 234 AC_MSG_CHECKING([whether to sandbox using capsicum])
 235 if test "x$ac_lbl_capsicum_function_seen" = "xyes" -a "x$ac_lbl_capsicum_function_not_seen" != "xyes"; then
 236         AC_DEFINE(HAVE_CAPSICUM, 1, [capsicum support available])
 237         AC_MSG_RESULT(yes)
 238 else
 239         AC_MSG_RESULT(no)
 240 fi
 241 AC_MSG_CHECKING([whether to sandbox using Casper library])
 242 if test "x$ac_cv_lib_casper_cap_init" = "xyes" -a "x$ac_cv_lib_cap_dns_cap_gethostbyaddr" = "xyes"; then
 243         AC_DEFINE(HAVE_CASPER, 1, [Casper support available])
 244         AC_MSG_RESULT(yes)
 245 else
 246         AC_MSG_RESULT(no)
 247 fi
 248
 249 #
 250 # We must check this before checking whether to check the OS's IPv6,
 251 # support because, on some platforms (such as SunOS 5.x), the test
 252 # program requires the extra networking libraries.
 253 #
 254 AC_LBL_LIBRARY_NET
 255
 256 #
 257 # Check whether AF_INET6 and struct in6_addr are defined.
 258 # If they aren't both defined, we don't have sufficient OS
 259 # support for IPv6, so we don't look for IPv6 support libraries,
 260 # and we define AF_INET6 and struct in6_addr ourselves.
 261 #
 262 AC_MSG_CHECKING([whether the operating system supports IPv6])
 263 AC_COMPILE_IFELSE(
 264     [
 265       AC_LANG_SOURCE(
 266         [[
 267 /* AF_INET6 available check */
 268 #include <sys/types.h>
 269 #ifdef _WIN32
 270 #include <ws2tcpip.h>
 271 #else
 272 #include <sys/socket.h>
 273 #include <netinet/in.h>
 274 #endif
 275 #ifdef AF_INET6
 276 void
 277 foo(struct in6_addr *addr)
 278 {
 279  memset(addr, 0, sizeof (struct in6_addr));
 280 }
 281 #else
 282 #error "AF_INET6 not defined"
 283 #endif
 284         ]])
 285     ],
 286     [
 287         AC_MSG_RESULT(yes)
 288         AC_DEFINE(HAVE_OS_IPV6_SUPPORT, 1,
 289             [define if the OS provides AF_INET6 and struct in6_addr])
 290         ipv6=yes
 291     ],
 292     [
 293         AC_MSG_RESULT(no)
 294         ipv6=no
 295     ]
 296 )
 297
 298 ipv6type=unknown
 299 ipv6lib=none
 300 ipv6trylibc=no
 301
 302 if test "$ipv6" = "yes"; then
 303         AC_MSG_CHECKING([ipv6 stack type])
 304         for i in inria kame linux-glibc linux-libinet6 toshiba v6d zeta; do
 305                 case $i in
 306                 inria)
 307                         dnl http://www.kame.net/
 308                         AC_EGREP_CPP(yes,
 309 [#include <netinet/in.h>
 310 #ifdef IPV6_INRIA_VERSION
 311 yes
 312 #endif],
 313                                 [ipv6type=$i])
 314                         ;;
 315                 kame)
 316                         dnl http://www.kame.net/
 317                         AC_EGREP_CPP(yes,
 318 [#include <netinet/in.h>
 319 #ifdef __KAME__
 320 yes
 321 #endif],
 322                                 [ipv6type=$i;
 323                                 ipv6lib=inet6;
 324                                 ipv6libdir=/usr/local/v6/lib;
 325                                 ipv6trylibc=yes])
 326                         ;;
 327                 linux-glibc)
 328                         dnl http://www.v6.linux.or.jp/
 329                         AC_EGREP_CPP(yes,
 330 [#include <features.h>
 331 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 332 yes
 333 #endif],
 334                                 [ipv6type=$i])
 335                         ;;
 336                 linux-libinet6)
 337                         dnl http://www.v6.linux.or.jp/
 338                         dnl
 339                         dnl This also matches Solaris 8 and Tru64 UNIX 5.1,
 340                         dnl and possibly other versions of those OSes
 341                         dnl
 342                         if test -d /usr/inet6 -o -f /usr/include/netinet/ip6.h; then
 343                                 ipv6type=$i
 344                                 ipv6lib=inet6
 345                                 ipv6libdir=/usr/inet6/lib
 346                                 ipv6trylibc=yes;
 347                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 348                         fi
 349                         ;;
 350                 toshiba)
 351                         AC_EGREP_CPP(yes,
 352 [#include <sys/param.h>
 353 #ifdef _TOSHIBA_INET6
 354 yes
 355 #endif],
 356                                 [ipv6type=$i;
 357                                 ipv6lib=inet6;
 358                                 ipv6libdir=/usr/local/v6/lib])
 359                         ;;
 360                 v6d)
 361                         AC_EGREP_CPP(yes,
 362 [#include </usr/local/v6/include/sys/v6config.h>
 363 #ifdef __V6D__
 364 yes
 365 #endif],
 366                                 [ipv6type=$i;
 367                                 ipv6lib=v6;
 368                                 ipv6libdir=/usr/local/v6/lib;
 369                                 CFLAGS="-I/usr/local/v6/include $CFLAGS"])
 370                         ;;
 371                 zeta)
 372                         AC_EGREP_CPP(yes,
 373 [#include <sys/param.h>
 374 #ifdef _ZETA_MINAMI_INET6
 375 yes
 376 #endif],
 377                                 [ipv6type=$i;
 378                                 ipv6lib=inet6;
 379                                 ipv6libdir=/usr/local/v6/lib])
 380                         ;;
 381                 esac
 382                 if test "$ipv6type" != "unknown"; then
 383                         break
 384                 fi
 385         done
 386         AC_MSG_RESULT($ipv6type)
 387 fi
 388
 389 if test "$ipv6" = "yes" -a "$ipv6lib" != "none"; then
 390         if test -d $ipv6libdir -a -f $ipv6libdir/lib$ipv6lib.a; then
 391                 LIBS="-L$ipv6libdir -l$ipv6lib $LIBS"
 392                 echo "You have $ipv6lib library, using it"
 393         else
 394                 if test "$ipv6trylibc" = "yes"; then
 395                         echo "You do not have $ipv6lib library, using libc"
 396                 else
 397                         echo 'Fatal: no $ipv6lib library found.  cannot continue.'
 398                         echo "You need to fetch lib$ipv6lib.a from appropriate"
 399                         echo 'ipv6 kit and compile beforehand.'
 400                         exit 1
 401                 fi
 402         fi
 403 fi
 404
 405 AC_REPLACE_FUNCS(strlcat strlcpy strdup strsep getservent getopt_long)
 406 AC_CHECK_FUNCS(fork vfork strftime)
 407 AC_CHECK_FUNCS(setlinebuf)
 408
 409 #
 410 # Make sure we have vsnprintf() and snprintf(); we require them.
 411 #
 412 AC_CHECK_FUNC(vsnprintf,,
 413     AC_MSG_ERROR([vsnprintf() is required but wasn't found]))
 414 AC_CHECK_FUNC(snprintf,,
 415     AC_MSG_ERROR([snprintf() is required but wasn't found]))
 416
 417 #
 418 # Define HAVE_NO_PRINTF_Z to make it possible to disable test cases that
 419 # depend on %zu.
 420 #
 421 AC_MSG_CHECKING([whether printf(3) supports the z length modifier])
 422 AC_RUN_IFELSE(
 423     [
 424         AC_LANG_SOURCE([[
 425 #include <stdio.h>
 426 #include <string.h>
 427
 428 int main()
 429 {
 430   char buf[100];
 431   snprintf(buf, sizeof(buf), "%zu", sizeof(buf));
 432   return strncmp(buf, "100", sizeof(buf)) ? 1 : 0;
 433 }
 434         ]])
 435     ],
 436     [
 437         AC_MSG_RESULT(yes)
 438     ],
 439     [
 440         AC_MSG_RESULT(no)
 441         AC_DEFINE(HAVE_NO_PRINTF_Z, 1,
 442             [Define to 1 if printf(3) does not support the z length modifier.])
 443     ],
 444     [
 445         AC_MSG_RESULT(not while cross-compiling)
 446     ]
 447 )
 448
 449 AC_CHECK_LIB(rpc, main)         dnl It's unclear why we might need -lrpc
 450
 451 dnl Some platforms may need -lnsl for getrpcbynumber.
 452 AC_SEARCH_LIBS(getrpcbynumber, nsl,
 453     AC_DEFINE(HAVE_GETRPCBYNUMBER, 1, [define if you have getrpcbynumber()]))
 454
 455 AC_LBL_LIBPCAP(V_PCAPDEP, V_INCLS)
 456
 457 #
 458 # Check for these after AC_LBL_LIBPCAP, so we link with the appropriate
 459 # libraries (e.g., "-lsocket -lnsl" on Solaris).
 460 #
 461 # You are in a twisty little maze of UN*Xes, all different.
 462 # Some might not have ether_ntohost().
 463 # Some might have it and declare it in <net/ethernet.h>.
 464 # Some might have it and declare it in <netinet/ether.h>
 465 # Some might have it and declare it in <sys/ethernet.h>.
 466 # Some might have it and declare it in <arpa/inet.h>.
 467 # Some might have it and declare it in <netinet/if_ether.h>.
 468 # Some might have it and not declare it in any header file.
 469 #
 470 # Before you is a C compiler.
 471 #
 472 AC_CHECK_FUNCS(ether_ntohost, [
 473     AC_CACHE_CHECK(for buggy ether_ntohost, ac_cv_buggy_ether_ntohost, [
 474         AC_TRY_RUN([
 475                 #include <netdb.h>
 476                 #include <sys/types.h>
 477                 #include <sys/param.h>
 478                 #include <sys/socket.h>
 479
 480                 int
 481                 main(int argc, char **argv)
 482                 {
 483                         u_char ea[6] = { 0xff, 0xff, 0xff, 0xff, 0xff };
 484                         char name[MAXHOSTNAMELEN];
 485
 486                         ether_ntohost(name, (struct ether_addr *)ea);
 487                         exit(0);
 488                 }
 489         ], [ac_cv_buggy_ether_ntohost=no],
 490            [ac_cv_buggy_ether_ntohost=yes],
 491            [ac_cv_buggy_ether_ntohost="not while cross-compiling"])])
 492     if test "$ac_cv_buggy_ether_ntohost" = "no"; then
 493         AC_DEFINE(USE_ETHER_NTOHOST, 1,
 494             [define if you have ether_ntohost() and it works])
 495     fi
 496 ])
 497 if test "$ac_cv_func_ether_ntohost" = yes -a \
 498     "$ac_cv_buggy_ether_ntohost" = "no"; then
 499         #
 500         # OK, we have ether_ntohost().  Is it declared in <net/ethernet.h>?
 501         #
 502         # This test fails if we don't have <net/ethernet.h> or if we do
 503         # but it doesn't declare ether_ntohost().
 504         #
 505         AC_CHECK_DECL(ether_ntohost,
 506             [
 507                 AC_DEFINE(NET_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
 508                     [Define to 1 if net/ethernet.h declares `ether_ntohost'])
 509             ],,
 510             [
 511 #include <net/ethernet.h>
 512             ])
 513         #
 514         # Did that succeed?
 515         #
 516         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 517                 #
 518                 # No, how about <netinet/ether.h>, as on Linux?
 519                 #
 520                 # This test fails if we don't have <netinet/ether.h>
 521                 # or if we do but it doesn't declare ether_ntohost().
 522                 #
 523                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 524                 # treat the previous failure as a cached value and
 525                 # suppress the next test.
 526                 #
 527                 unset ac_cv_have_decl_ether_ntohost
 528                 AC_CHECK_DECL(ether_ntohost,
 529                     [
 530                         AC_DEFINE(NETINET_ETHER_H_DECLARES_ETHER_NTOHOST,,
 531                             [Define to 1 if netinet/ether.h declares `ether_ntohost'])
 532                     ],,
 533                     [
 534 #include <netinet/ether.h>
 535                     ])
 536         fi
 537         #
 538         # Did that succeed?
 539         #
 540         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 541                 #
 542                 # No, how about <sys/ethernet.h>, as on Solaris 10
 543                 # and later?
 544                 #
 545                 # This test fails if we don't have <sys/ethernet.h>
 546                 # or if we do but it doesn't declare ether_ntohost().
 547                 #
 548                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 549                 # treat the previous failure as a cached value and
 550                 # suppress the next test.
 551                 #
 552                 unset ac_cv_have_decl_ether_ntohost
 553                 AC_CHECK_DECL(ether_ntohost,
 554                     [
 555                         AC_DEFINE(SYS_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
 556                             [Define to 1 if sys/ethernet.h declares `ether_ntohost'])
 557                     ],,
 558                     [
 559 #include <sys/ethernet.h>
 560                     ])
 561         fi
 562         #
 563         # Did that succeed?
 564         #
 565         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 566                 #
 567                 # No, how about <arpa/inet.h>, as in AIX?
 568                 #
 569                 # This test fails if we don't have <arpa/inet.h>
 570                 # (if we have ether_ntohost(), we should have
 571                 # networking, and if we have networking, we should
 572                 # have <arpa/inet.h>) or if we do but it doesn't
 573                 # declare ether_ntohost().
 574                 #
 575                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 576                 # treat the previous failure as a cached value and
 577                 # suppress the next test.
 578                 #
 579                 unset ac_cv_have_decl_ether_ntohost
 580                 AC_CHECK_DECL(ether_ntohost,
 581                     [
 582                         AC_DEFINE(ARPA_INET_H_DECLARES_ETHER_NTOHOST,,
 583                             [Define to 1 if arpa/inet.h declares `ether_ntohost'])
 584                     ],,
 585                     [
 586 #include <arpa/inet.h>
 587                     ])
 588         fi
 589         #
 590         # Did that succeed?
 591         #
 592         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 593                 #
 594                 # No, how about <netinet/if_ether.h>?
 595                 # On some platforms, it requires <net/if.h> and
 596                 # <netinet/in.h>, and we always include it with
 597                 # both of them, so test it with both of them.
 598                 #
 599                 # This test fails if we don't have <netinet/if_ether.h>
 600                 # and the headers we include before it, or if we do but
 601                 # <netinet/if_ether.h> doesn't declare ether_hostton().
 602                 #
 603                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 604                 # treat the previous failure as a cached value and
 605                 # suppress the next test.
 606                 #
 607                 unset ac_cv_have_decl_ether_ntohost
 608                 AC_CHECK_DECL(ether_ntohost,
 609                     [
 610                         AC_DEFINE(NETINET_IF_ETHER_H_DECLARES_ETHER_NTOHOST,,
 611                             [Define to 1 if netinet/if_ether.h declares `ether_ntohost'])
 612                     ],,
 613                     [
 614 #include <sys/types.h>
 615 #include <sys/socket.h>
 616 #include <net/if.h>
 617 #include <netinet/in.h>
 618 #include <netinet/if_ether.h>
 619                     ])
 620         fi
 621         #
 622         # After all that, is ether_ntohost() declared?
 623         #
 624         if test "$ac_cv_have_decl_ether_ntohost" = yes; then
 625                 #
 626                 # Yes.
 627                 #
 628                 AC_DEFINE(HAVE_DECL_ETHER_NTOHOST, 1,
 629                     [Define to 1 if you have the declaration of `ether_ntohost'])
 630         else
 631                 #
 632                 # No, we'll have to declare it ourselves.
 633                 # Do we have "struct ether_addr" if we include
 634                 # <netinet/if_ether.h>?
 635                 #
 636                 AC_CHECK_TYPES(struct ether_addr,,,
 637                     [
 638                         #include <sys/types.h>
 639                         #include <sys/socket.h>
 640                         #include <net/if.h>
 641                         #include <netinet/in.h>
 642                         #include <netinet/if_ether.h>
 643                     ])
 644         fi
 645 fi
 646
 647 dnl
 648 dnl Check for "pcap_list_datalinks()" and use a substitute version if
 649 dnl it's not present.  If it is present, check for "pcap_free_datalinks()";
 650 dnl if it's not present, we don't replace it for now.  (We could do so
 651 dnl on UN*X, but not on Windows, where hilarity ensues if a program
 652 dnl built with one version of the MSVC support library tries to free
 653 dnl something allocated by a library built with another version of
 654 dnl the MSVC support library.)
 655 dnl
 656 AC_CHECK_FUNC(pcap_list_datalinks,
 657         [
 658             AC_DEFINE(HAVE_PCAP_LIST_DATALINKS, 1,
 659                 [define if libpcap has pcap_list_datalinks()])
 660             AC_CHECK_FUNCS(pcap_free_datalinks)
 661         ],
 662         [
 663             AC_LIBOBJ(datalinks)
 664         ])
 665
 666 dnl
 667 dnl Check for "pcap_datalink_name_to_val()", and use a substitute
 668 dnl version if it's not present.  If it is present, check for
 669 dnl "pcap_datalink_val_to_description()", and if we don't have it,
 670 dnl use a substitute version.
 671 dnl
 672 AC_CHECK_FUNC(pcap_datalink_name_to_val,
 673         [
 674             AC_DEFINE(HAVE_PCAP_DATALINK_NAME_TO_VAL, 1,
 675                 [define if libpcap has pcap_datalink_name_to_val()])
 676             AC_CHECK_FUNC(pcap_datalink_val_to_description,
 677                 AC_DEFINE(HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION, 1,
 678                     [define if libpcap has pcap_datalink_val_to_description()]),
 679                 [
 680                     AC_LIBOBJ(dlnames)
 681                 ])
 682         ],
 683         [
 684             AC_LIBOBJ(dlnames)
 685         ])
 686
 687 dnl
 688 dnl Check for "pcap_set_datalink()"; you can't substitute for it if
 689 dnl it's absent (it has hooks into libpcap), so just define the
 690 dnl HAVE_ value if it's there.
 691 dnl
 692 AC_CHECK_FUNCS(pcap_set_datalink)
 693
 694 dnl
 695 dnl Check for "pcap_breakloop()"; you can't substitute for it if
 696 dnl it's absent (it has hooks into the live capture routines),
 697 dnl so just define the HAVE_ value if it's there.
 698 dnl
 699 AC_CHECK_FUNCS(pcap_breakloop)
 700
 701 #
 702 # Do we have the new open API?  Check for pcap_create, and assume that,
 703 # if we do, we also have pcap_activate() and the other new routines
 704 # introduced in libpcap 1.0.0.
 705 #
 706 AC_CHECK_FUNCS(pcap_create)
 707 if test $ac_cv_func_pcap_create = "yes" ; then
 708         #
 709         # OK, do we have pcap_set_tstamp_type?  If so, assume we have
 710         # pcap_list_tstamp_types and pcap_free_tstamp_types as well.
 711         #
 712         AC_CHECK_FUNCS(pcap_set_tstamp_type)
 713         #
 714         # And do we have pcap_set_tstamp_precision?  If so, we assume
 715         # we also have pcap_open_offline_with_tstamp_precision.
 716         #
 717         AC_CHECK_FUNCS(pcap_set_tstamp_precision)
 718 fi
 719
 720 #
 721 # Check for a miscellaneous collection of functions which we use
 722 # if we have them.
 723 #
 724 AC_CHECK_FUNCS(pcap_findalldevs)
 725 if test $ac_cv_func_pcap_findalldevs = "yes" ; then
 726 dnl Check for libpcap having pcap_findalldevs() but the pcap.h header
 727 dnl not having pcap_if_t; some versions of Mac OS X shipped with pcap.h
 728 dnl from 0.6 and libpcap 0.8, so that libpcap had pcap_findalldevs but
 729 dnl pcap.h didn't have pcap_if_t.
 730     savedcppflags="$CPPFLAGS"
 731     CPPFLAGS="$CPPFLAGS $V_INCLS"
 732     AC_CHECK_TYPES(pcap_if_t, , , [#include <pcap.h>])
 733     CPPFLAGS="$savedcppflags"
 734 fi
 735 AC_CHECK_FUNCS(pcap_dump_flush pcap_lib_version)
 736 if test $ac_cv_func_pcap_lib_version = "no" ; then
 737     AC_MSG_CHECKING(whether pcap_version is defined by libpcap)
 738     AC_TRY_LINK([],
 739        [
 740         extern char pcap_version[];
 741
 742         return (int)pcap_version;
 743        ],
 744        ac_lbl_cv_pcap_version_defined=yes,
 745        ac_lbl_cv_pcap_version_defined=no)
 746     if test "$ac_lbl_cv_pcap_version_defined" = yes ; then
 747         AC_MSG_RESULT(yes)
 748         AC_DEFINE(HAVE_PCAP_VERSION, 1, [define if libpcap has pcap_version])
 749     else
 750         AC_MSG_RESULT(no)
 751     fi
 752 fi
 753 AC_CHECK_FUNCS(pcap_setdirection pcap_set_immediate_mode pcap_dump_ftell64)
 754 AC_CHECK_FUNCS(pcap_open pcap_findalldevs_ex)
 755 AC_REPLACE_FUNCS(pcap_dump_ftell)
 756
 757 #
 758 # Check for special debugging functions
 759 #
 760 AC_CHECK_FUNCS(pcap_set_parser_debug)
 761 if test "$ac_cv_func_pcap_set_parser_debug" = "no" ; then
 762         #
 763         # OK, we don't have pcap_set_parser_debug() to set the libpcap
 764         # filter expression parser debug flag; can we directly set the
 765         # flag?
 766         AC_MSG_CHECKING(whether pcap_debug is defined by libpcap)
 767         AC_TRY_LINK([],
 768            [
 769                 extern int pcap_debug;
 770
 771                 return pcap_debug;
 772            ],
 773            ac_lbl_cv_pcap_debug_defined=yes,
 774            ac_lbl_cv_pcap_debug_defined=no)
 775         if test "$ac_lbl_cv_pcap_debug_defined" = yes ; then
 776                 AC_MSG_RESULT(yes)
 777                 AC_DEFINE(HAVE_PCAP_DEBUG, 1, [define if libpcap has pcap_debug])
 778         else
 779                 AC_MSG_RESULT(no)
 780                 #
 781                 # OK, what about "yydebug"?
 782                 #
 783                 AC_MSG_CHECKING(whether yydebug is defined by libpcap)
 784                 AC_TRY_LINK([],
 785                    [
 786                         extern int yydebug;
 787
 788                         return yydebug;
 789                    ],
 790                    ac_lbl_cv_yydebug_defined=yes,
 791                    ac_lbl_cv_yydebug_defined=no)
 792                 if test "$ac_lbl_cv_yydebug_defined" = yes ; then
 793                         AC_MSG_RESULT(yes)
 794                         AC_DEFINE(HAVE_YYDEBUG, 1, [define if libpcap has yydebug])
 795                 else
 796                         AC_MSG_RESULT(no)
 797                 fi
 798         fi
 799 fi
 800 AC_CHECK_FUNCS(pcap_set_optimizer_debug)
 801 AC_REPLACE_FUNCS(bpf_dump)      dnl moved to libpcap in 0.6
 802
 803 V_GROUP=0
 804 if test -f /etc/group -a ! -z "`grep '^wheel:' /etc/group`" ; then
 805         V_GROUP=wheel
 806 fi
 807 #
 808 # Assume V7/BSD convention for man pages (file formats in section 5,
 809 # miscellaneous info in section 7).
 810 #
 811 MAN_FILE_FORMATS=5
 812 MAN_MISC_INFO=7
 813 case "$host_os" in
 814
 815 aix*)
 816         dnl Workaround to enable certain features
 817         AC_DEFINE(_SUN,1,[define on AIX to get certain functions])
 818         ;;
 819
 820 hpux*)
 821         #
 822         # Use System V conventions for man pages.
 823         #
 824         MAN_FILE_FORMATS=4
 825         MAN_MISC_INFO=5
 826         ;;
 827
 828 irix*)
 829         V_GROUP=sys
 830
 831         #
 832         # Use System V conventions for man pages.
 833         #
 834         MAN_FILE_FORMATS=4
 835         MAN_MISC_INFO=5
 836         ;;
 837
 838 osf*)
 839         V_GROUP=system
 840
 841         #
 842         # Use System V conventions for man pages.
 843         #
 844         MAN_FILE_FORMATS=4
 845         MAN_MISC_INFO=5
 846         ;;
 847
 848 solaris*)
 849         V_GROUP=sys
 850
 851         #
 852         # Use System V conventions for man pages.
 853         #
 854         MAN_FILE_FORMATS=4
 855         MAN_MISC_INFO=5
 856         ;;
 857 esac
 858
 859 if test -f /dev/bpf0 ; then
 860         V_GROUP=bpf
 861 fi
 862
 863 #
 864 # Make sure we have a definition for C99's uintptr_t (regardless of
 865 # whether the environment is a C99 environment or not).
 866 #
 867 AC_TYPE_UINTPTR_T
 868
 869 #
 870 # Check whether we have pcap/pcap-inttypes.h.
 871 # If we do, we use that to get the C99 types defined.
 872 #
 873 savedcppflags="$CPPFLAGS"
 874 CPPFLAGS="$CPPFLAGS $V_INCLS"
 875 AC_CHECK_HEADERS(pcap/pcap-inttypes.h)
 876 CPPFLAGS="$savedcppflags"
 877
 878 #
 879 # Define the old BSD specified-width types in terms of the C99 types;
 880 # we may need them with libpcap include files.
 881 #
 882 AC_CHECK_TYPE([u_int8_t], ,
 883         [AC_DEFINE([u_int8_t], [uint8_t],
 884         [Define to `uint8_t' if u_int8_t not defined.])],
 885         [AC_INCLUDES_DEFAULT
 886 #include <sys/types.h>
 887 ])
 888 AC_CHECK_TYPE([u_int16_t], ,
 889         [AC_DEFINE([u_int16_t], [uint16_t],
 890         [Define to `uint16_t' if u_int16_t not defined.])],
 891         [AC_INCLUDES_DEFAULT
 892 #include <sys/types.h>
 893 ])
 894 AC_CHECK_TYPE([u_int32_t], ,
 895         [AC_DEFINE([u_int32_t], [uint32_t],
 896         [Define to `uint32_t' if u_int32_t not defined.])],
 897         [AC_INCLUDES_DEFAULT
 898 #include <sys/types.h>
 899 ])
 900 AC_CHECK_TYPE([u_int64_t], ,
 901         [AC_DEFINE([u_int64_t], [uint64_t],
 902         [Define to `uint64_t' if u_int64_t not defined.])],
 903         [AC_INCLUDES_DEFAULT
 904 #include <sys/types.h>
 905 ])
 906
 907 AC_PROG_RANLIB
 908 AC_CHECK_TOOL([AR], [ar])
 909
 910 AC_LBL_DEVEL(V_CCOPT)
 911
 912 # Check for OpenSSL/libressl libcrypto
 913 AC_MSG_CHECKING(whether to use OpenSSL/libressl libcrypto)
 914 # Specify location for both includes and libraries.
 915 want_libcrypto=ifavailable
 916 AC_ARG_WITH(crypto,
 917     AS_HELP_STRING([--with-crypto]@<:@=DIR@:>@,
 918                    [use OpenSSL/libressl libcrypto (located in directory DIR, if specified) @<:@default=yes, if available@:>@]),
 919 [
 920         if test $withval = no
 921         then
 922                 # User doesn't want to link with libcrypto.
 923                 want_libcrypto=no
 924                 AC_MSG_RESULT(no)
 925         elif test $withval = yes
 926         then
 927                 # User wants to link with libcrypto but hasn't specified
 928                 # a directory.
 929                 want_libcrypto=yes
 930                 AC_MSG_RESULT(yes)
 931         else
 932                 # User wants to link with libcrypto and has specified
 933                 # a directory, so use the provided value.
 934                 want_libcrypto=yes
 935                 libcrypto_root=$withval
 936                 AC_MSG_RESULT([yes, using the version installed in $withval])
 937
 938                 #
 939                 # Put the subdirectories of the libcrypto root directory
 940                 # at the front of the header and library search path.
 941                 #
 942                 CFLAGS="-I$withval/include $CFLAGS"
 943                 LIBS="-L$withval/lib $LIBS"
 944         fi
 945 ],[
 946         #
 947         # Use libcrypto if it's present, otherwise don't; no directory
 948         # was specified.
 949         #
 950         want_libcrypto=ifavailable
 951         AC_MSG_RESULT([yes, if available])
 952 ])
 953 if test "$want_libcrypto" != "no"; then
 954         #
 955         # Don't check for libcrypto unless we have its headers;
 956         # Apple, bless their pointy little heads, apparently ship
 957         # libcrypto as a library, but not the header files, in
 958         # El Capitan, probably because they don't want you writing
 959         # nasty portable code that could run on other UN*Xes, they
 960         # want you writing code that uses their Shiny New Crypto
 961         # Library and that only runs on macOS.
 962         #
 963         AC_CHECK_HEADER(openssl/crypto.h,
 964         [
 965                 AC_CHECK_LIB(crypto, DES_cbc_encrypt)
 966                 if test "$ac_cv_lib_crypto_DES_cbc_encrypt" = "yes"; then
 967                         AC_CHECK_HEADERS(openssl/evp.h)
 968                         #
 969                         # OK, then:
 970                         #
 971                         # 1) do we have EVP_CIPHER_CTX_new?
 972                         # If so, we use it to allocate an
 973                         # EVP_CIPHER_CTX, as EVP_CIPHER_CTX may be
 974                         # opaque; otherwise, we allocate it ourselves.
 975                         #
 976                         # 2) do we have EVP_DecryptInit_ex()?
 977                         # If so, we use it, because we need to be
 978                         # able to make two "initialize the cipher"
 979                         # calls, one with the cipher and key, and
 980                         # one with the IV, and, as of OpenSSL 1.1,
 981                         # You Can't Do That with EVP_DecryptInit(),
 982                         # because a call to EVP_DecryptInit() will
 983                         # unconditionally clear the context, and
 984                         # if you don't supply a cipher, it'll
 985                         # clear the cipher, rendering the context
 986                         # unusable and causing a crash.
 987                         #
 988                         AC_CHECK_FUNCS(EVP_CIPHER_CTX_new EVP_DecryptInit_ex)
 989                 fi
 990         ])
 991 fi
 992
 993 # Check for libcap-ng
 994 AC_MSG_CHECKING(whether to use libcap-ng)
 995 # Specify location for both includes and libraries.
 996 want_libcap_ng=ifavailable
 997 AC_ARG_WITH(cap_ng,
 998     AS_HELP_STRING([--with-cap-ng],
 999                    [use libcap-ng @<:@default=yes, if available@:>@]),
1000 [
1001         if test $withval = no
1002         then
1003                 want_libcap_ng=no
1004                 AC_MSG_RESULT(no)
1005         elif test $withval = yes
1006         then
1007                 want_libcap_ng=yes
1008                 AC_MSG_RESULT(yes)
1009         fi
1010 ],[
1011         #
1012         # Use libcap-ng if it's present, otherwise don't.
1013         #
1014         want_libcap_ng=ifavailable
1015         AC_MSG_RESULT([yes, if available])
1016 ])
1017 if test "$want_libcap_ng" != "no"; then
1018         AC_CHECK_LIB(cap-ng, capng_change_id)
1019         AC_CHECK_HEADERS(cap-ng.h)
1020 fi
1021
1022 dnl
1023 dnl set additional include path if necessary
1024 if test "$missing_includes" = "yes"; then
1025         CPPFLAGS="$CPPFLAGS -I$srcdir/missing"
1026         V_INCLS="$V_INCLS -I$srcdir/missing"
1027 fi
1028
1029 AC_SUBST(V_CCOPT)
1030 AC_SUBST(V_DEFS)
1031 AC_SUBST(V_GROUP)
1032 AC_SUBST(V_INCLS)
1033 AC_SUBST(V_PCAPDEP)
1034 AC_SUBST(LOCALSRC)
1035 AC_SUBST(MAN_FILE_FORMATS)
1036 AC_SUBST(MAN_MISC_INFO)
1037
1038 AC_PROG_INSTALL
1039
1040 AC_CONFIG_HEADER(config.h)
1041
1042 AC_OUTPUT_COMMANDS([if test -f .devel; then
1043         echo timestamp > stamp-h
1044         cat $srcdir/Makefile-devel-adds >> Makefile
1045         make depend || exit 1
1046 fi])
1047 AC_OUTPUT(Makefile tcpdump.1)
1048 exit 0