]> The Tcpdump Group git mirrors - tcpdump/blob - configure.ac
projects / tcpdump / blob


78c9b1bedc2a30ff51aabadd01c26d2e9e3f25d2
[tcpdump] / configure.ac
1 dnl Copyright (c) 1994, 1995, 1996, 1997
2 dnl The Regents of the University of California. All rights reserved.
3 dnl
4 dnl Process this file with autoconf to produce a configure script.
5 dnl
6
7 #
8 # See
9 #
10 # https://ftp.gnu.org/gnu/config/README
11 #
12 # for the URLs to use to fetch new versions of config.guess and
13 # config.sub.
14 #
15
16 AC_PREREQ([2.69])
17 AC_INIT([tcpdump],[m4_esyscmd_s(cat VERSION)],[https://github.com/the-tcpdump-group/tcpdump/issues])
18 AC_CONFIG_SRCDIR(tcpdump.c)
19
20 AC_CANONICAL_HOST
21
22 AC_LBL_C_INIT_BEFORE_CC(V_INCLS)
23 #
24 # Try to enable as many C99 features as we can.
25 # At minimum, we want C++/C99-style // comments.
26 #
27 AC_PROG_CC_C99
28 if test "$ac_cv_prog_cc_c99" = "no"; then
29 AC_MSG_WARN([The C compiler does not support C99; there may be compiler errors])
30 fi
31 AC_LBL_C_INIT(V_CCOPT, V_INCLS)
32 AC_C_INLINE
33
34 AC_CHECK_HEADERS(fcntl.h rpc/rpc.h rpc/rpcent.h net/if.h)
35 #
36 # Get the size of a void *, to know whether this is a 32-bit or 64-bit build.
37 #
38 AC_CHECK_SIZEOF([void *])
39
40 #
41 # Get the size of a time_t, to know whether it's 32-bit or 64-bit.
42 #
43 AC_CHECK_SIZEOF([time_t],,[#include <time.h>])
44
45 case "$host_os" in
46
47 darwin*)
48 AC_ARG_ENABLE(universal,
49 AS_HELP_STRING([--disable-universal],[don't build universal on macOS]))
50 if test "$enable_universal" != "no"; then
51 case "$host_os" in
52
53 darwin9.*)
54 #
55 # Leopard. Build for x86 and 32-bit PowerPC, with
56 # x86 first. (That's what Apple does.)
57 #
58 V_CCOPT="$V_CCOPT -arch i386 -arch ppc"
59 LDFLAGS="$LDFLAGS -arch i386 -arch ppc"
60 ;;
61
62 darwin10.*)
63 #
64 # Snow Leopard. Build for x86-64 and x86, with
65 # x86-64 first. (That's what Apple does.)
66 #
67 V_CCOPT="$V_CCOPT -arch x86_64 -arch i386"
68 LDFLAGS="$LDFLAGS -arch x86_64 -arch i386"
69 ;;
70 esac
71 fi
72 ;;
73 esac
74
75 AC_ARG_WITH([smi],
76 [AS_HELP_STRING([--with-smi],
77 [link with libsmi (allows to load MIBs on the fly to decode SNMP packets) [default=yes, if available]])],
78 [],
79 [with_smi=yes])
80
81 if test "x$with_smi" != "xno" ; then
82 AC_CHECK_HEADER(smi.h,
83 [
84 #
85 # OK, we found smi.h. Do we have libsmi with smiInit?
86 #
87 AC_CHECK_LIB(smi, smiInit,
88 [
89 #
90 # OK, we have libsmi with smiInit. Can we use it?
91 #
92 AC_MSG_CHECKING([whether to enable libsmi])
93 savedlibs="$LIBS"
94 LIBS="-lsmi $LIBS"
95 AC_RUN_IFELSE([AC_LANG_SOURCE([[
96 /* libsmi available check */
97 #include <stdio.h>
98 #include <stdlib.h>
99 #include <string.h>
100 #include <smi.h>
101 int main()
102 {
103 int current, revision, age, n;
104 const int required = 2;
105 if (smiInit(""))
106 exit(1);
107 if (strcmp(SMI_LIBRARY_VERSION, smi_library_version))
108 exit(2);
109 n = sscanf(smi_library_version, "%d:%d:%d", &current, &revision, &age);
110 if (n != 3)
111 exit(3);
112 if (required < current - age || required > current)
113 exit(4);
114 exit(0);
115 }
116 ]])
117 ],
118 [
119 AC_MSG_RESULT(yes)
120 AC_DEFINE(USE_LIBSMI, 1,
121 [Define if you enable support for libsmi])
122 ],
123 [
124 dnl autoconf documentation says that
125 dnl $? contains the exit value.
126 dnl reality is that it does not.
127 dnl We leave this in just in case
128 dnl autoconf ever comes back to
129 dnl match the documentation.
130 case $? in
131 1) AC_MSG_RESULT(no - smiInit failed) ;;
132 2) AC_MSG_RESULT(no - header/library version mismatch) ;;
133 3) AC_MSG_RESULT(no - can't determine library version) ;;
134 4) AC_MSG_RESULT(no - too old) ;;
135 *) AC_MSG_RESULT(no) ;;
136 esac
137 LIBS="$savedlibs"
138 ],
139 [
140 AC_MSG_RESULT(not when cross-compiling)
141 LIBS="$savedlibs"
142 ]
143 )
144 ])
145 ])
146 fi
147
148 AC_MSG_CHECKING([whether to enable the instrument functions code])
149 AC_ARG_ENABLE([instrument-functions],
150 [AS_HELP_STRING([--enable-instrument-functions],
151 [enable instrument functions code [default=no]])],
152 [],
153 [enableval=no])
154 case "$enableval" in
155 yes) AC_MSG_RESULT(yes)
156 AC_CHECK_LIB([bfd], [bfd_init],
157 [true],
158 [AC_MSG_ERROR(
159 [--enable-instrument-functions was given, but test for library libbfd failed. Please install the 'binutils-dev' package.])],
160 [])
161 AC_DEFINE(ENABLE_INSTRUMENT_FUNCTIONS, 1,
162 [define if you want to build the instrument functions code])
163 LOCALSRC="$LOCALSRC instrument-functions.c"
164 # Add '-finstrument-functions' instrumentation option to generate
165 # instrumentation calls for entry and exit to functions.
166 # Try to avoid Address Space Layout Randomization (ALSR).
167 CFLAGS="$CFLAGS -O0 -ggdb -finstrument-functions -fno-stack-protector -fno-pic"
168 LDFLAGS="$LDFLAGS -O0 -ggdb -fno-stack-protector -no-pie"
169 LIBS="$LIBS -lbfd"
170 ;;
171 *) AC_MSG_RESULT(no)
172 ;;
173 esac
174
175 AC_MSG_CHECKING([whether to enable the possibly-buggy SMB printer])
176 AC_ARG_ENABLE([smb],
177 [AS_HELP_STRING([--enable-smb],
178 [enable possibly-buggy SMB printer [default=no]])],
179 [],
180 [enableval=no])
181 case "$enableval" in
182 yes) AC_MSG_RESULT(yes)
183 AC_DEFINE(ENABLE_SMB, 1,
184 [define if you want to build the possibly-buggy SMB printer])
185 LOCALSRC="print-smb.c smbutil.c $LOCALSRC"
186 ;;
187 *) AC_MSG_RESULT(no)
188 ;;
189 esac
190
191 AC_MSG_CHECKING([whether to drop root privileges by default])
192 AC_ARG_WITH(
193 [user],
194 [AS_HELP_STRING([--with-user=USERNAME],
195 [drop privileges by default to USERNAME]
196 )],
197 [],
198 [withval=no])
199 AS_CASE(["$withval"],
200 [no], [AC_MSG_RESULT(no)],
201 [''|yes], [AC_MSG_ERROR([--with-user requires a username])],
202 [
203 AC_DEFINE_UNQUOTED(WITH_USER, "$withval",
204 [define if should drop privileges by default])
205 AC_MSG_RESULT([yes, to user "$withval"])
206 ]
207 )
208
209 AC_MSG_CHECKING([whether to chroot])
210 AC_ARG_WITH(
211 [chroot],
212 [AS_HELP_STRING([--with-chroot=DIRECTORY],
213 [when dropping privileges, chroot to DIRECTORY]
214 )],
215 [],
216 [withval=no]
217 )
218 AS_CASE(["$withval"],
219 [no], [AC_MSG_RESULT(no)],
220 [''|yes], [AC_MSG_ERROR([--with-chroot requires a directory])],
221 [
222 AC_DEFINE_UNQUOTED(WITH_CHROOT, "$withval",
223 [define if should chroot when dropping privileges])
224 AC_MSG_RESULT([yes, to directory "$withval"])
225 ]
226 )
227
228 AC_ARG_WITH(sandbox-capsicum,
229 AS_HELP_STRING([--with-sandbox-capsicum],
230 [use Capsicum security functions @<:@default=yes, if available@:>@]))
231 #
232 # Check whether various functions are available. If any are, set
233 # ac_lbl_capsicum_function_seen to yes; if any are not, set
234 # ac_lbl_capsicum_function_not_seen to yes.
235 #
236 # We don't check cap_rights_init(), as it's a macro, wrapping another
237 # function, in at least some versions of FreeBSD, and AC_CHECK_FUNCS()
238 # doesn't handle that.
239 #
240 # All of the ones we check for must be available in order to enable
241 # capsicum sandboxing.
242 #
243 # XXX - do we need to check for all of them, or are there some that, if
244 # present, imply others are present?
245 #
246 if test -z "$with_sandbox_capsicum" || test "$with_sandbox_capsicum" != "no" ; then
247 #
248 # First, make sure we have the required header.
249 #
250 AC_CHECK_HEADER(sys/capsicum.h,
251 [
252 #
253 # We do; now make sure we have the required functions.
254 #
255 AC_CHECK_FUNCS(cap_enter cap_rights_limit cap_ioctls_limit openat,
256 ac_lbl_capsicum_function_seen=yes,
257 ac_lbl_capsicum_function_not_seen=yes)
258 ])
259 AC_CHECK_LIB(casper, cap_init, LIBS="$LIBS -lcasper")
260 AC_CHECK_LIB(cap_dns, cap_gethostbyaddr, LIBS="$LIBS -lcap_dns")
261 fi
262 AC_MSG_CHECKING([whether to sandbox using capsicum])
263 if test "x$ac_lbl_capsicum_function_seen" = "xyes" -a "x$ac_lbl_capsicum_function_not_seen" != "xyes"; then
264 AC_DEFINE(HAVE_CAPSICUM, 1, [capsicum support available])
265 AC_MSG_RESULT(yes)
266 else
267 AC_MSG_RESULT(no)
268 fi
269 AC_MSG_CHECKING([whether to sandbox using Casper library])
270 if test "x$ac_cv_lib_casper_cap_init" = "xyes" -a "x$ac_cv_lib_cap_dns_cap_gethostbyaddr" = "xyes"; then
271 AC_DEFINE(HAVE_CASPER, 1, [Casper support available])
272 AC_MSG_RESULT(yes)
273 else
274 AC_MSG_RESULT(no)
275 fi
276
277 #
278 # We must check this before checking whether to check the OS's IPv6,
279 # support because, on some platforms (such as SunOS 5.x), the test
280 # program requires the extra networking libraries.
281 #
282 AC_LBL_LIBRARY_NET
283
284 AC_REPLACE_FUNCS(strlcat strlcpy strsep getservent getopt_long)
285 AC_CHECK_FUNCS(fork vfork)
286
287 #
288 # Make sure we have snprintf(); we require it.
289 #
290 AC_CHECK_FUNC(snprintf,,
291 AC_MSG_ERROR([snprintf() is required but wasn't found]))
292
293 #
294 # It became apparent at some point that using a suitable C99 compiler does not
295 # automatically mean snprintf(3) implementation in the libc supports all the
296 # modifiers and specifiers used in the project, so let's test that before the
297 # build, not after.
298 #
299 # Testing the sizeof_t length modifier takes making an snprintf() call and
300 # comparing the actual result with the expected result. If this fails, it will
301 # most likely happen at run time, not compile time.
302 #
303 # Testing the 64-bit conversion specifiers in addition to that requires the
304 # <inttypes.h> header to be present and the macros to be defined, so if this
305 # fails, it will more likely happen at compile time.
306 #
307 AC_MSG_CHECKING([whether snprintf is suitable])
308 AC_RUN_IFELSE(
309 [
310 AC_LANG_SOURCE([[
311 #include <stdio.h>
312 #include <string.h>
313 #include <inttypes.h>
314 #include <sys/types.h>
315
316 int main()
317 {
318 char buf[100];
319 uint64_t t = (uint64_t)1 << 32;
320
321 snprintf(buf, sizeof(buf), "%zu", sizeof(buf));
322 if (strncmp(buf, "100", sizeof(buf)))
323 return 1;
324
325 snprintf(buf, sizeof(buf), "%zd", -sizeof(buf));
326 if (strncmp(buf, "-100", sizeof(buf)))
327 return 2;
328
329 snprintf(buf, sizeof(buf), "%" PRId64, -t);
330 if (strncmp(buf, "-4294967296", sizeof(buf)))
331 return 3;
332
333 snprintf(buf, sizeof(buf), "0o%" PRIo64, t);
334 if (strncmp(buf, "0o40000000000", sizeof(buf)))
335 return 4;
336
337 snprintf(buf, sizeof(buf), "0x%" PRIx64, t);
338 if (strncmp(buf, "0x100000000", sizeof(buf)))
339 return 5;
340
341 snprintf(buf, sizeof(buf), "%" PRIu64, t);
342 if (strncmp(buf, "4294967296", sizeof(buf)))
343 return 6;
344
345 return 0;
346 }
347 ]])
348 ],
349 [
350 AC_MSG_RESULT(yes)
351 ],
352 [
353 AC_MSG_RESULT(no)
354 AC_MSG_ERROR(
355 [The snprintf(3) implementation in this libc is not suitable,
356 tcpdump would not work correctly even if it managed to compile.])
357 ],
358 [
359 AC_MSG_RESULT(not while cross-compiling)
360 ]
361 )
362
363 AC_CHECK_LIB(rpc, main) dnl It's unclear why we might need -lrpc
364
365 dnl Some platforms may need -lnsl for getrpcbynumber.
366 AC_SEARCH_LIBS(getrpcbynumber, nsl,
367 AC_DEFINE(HAVE_GETRPCBYNUMBER, 1, [define if you have getrpcbynumber()]))
368
369 AC_LBL_LIBPCAP(V_PCAPDEP, V_INCLS)
370
371 #
372 # Check for these after AC_LBL_LIBPCAP, so we link with the appropriate
373 # libraries (e.g., "-lsocket -lnsl" on Solaris).
374 #
375 # You are in a twisty little maze of UN*Xes, all different.
376 # Some might not have ether_ntohost().
377 # Some might have it and declare it in <net/ethernet.h>.
378 # Some might have it and declare it in <netinet/ether.h>
379 # Some might have it and declare it in <sys/ethernet.h>.
380 # Some might have it and declare it in <arpa/inet.h>.
381 # Some might have it and declare it in <netinet/if_ether.h>.
382 # Some might have it and not declare it in any header file.
383 #
384 # Before you is a C compiler.
385 #
386 AC_CHECK_FUNCS(ether_ntohost, [
387 AC_CACHE_CHECK(for buggy ether_ntohost, ac_cv_buggy_ether_ntohost, [
388 AC_RUN_IFELSE([AC_LANG_SOURCE([[
389 #include <netdb.h>
390 #include <netinet/ether.h>
391 #include <stdlib.h>
392 #include <sys/types.h>
393 #include <sys/param.h>
394 #include <sys/socket.h>
395
396 int
397 main(int argc, char **argv)
398 {
399 u_char ea[6] = { 0xff, 0xff, 0xff, 0xff, 0xff };
400 char name[MAXHOSTNAMELEN];
401
402 ether_ntohost(name, (struct ether_addr *)ea);
403 exit(0);
404 }
405 ]])
406 ], [ac_cv_buggy_ether_ntohost=no],
407 [ac_cv_buggy_ether_ntohost=yes],
408 [ac_cv_buggy_ether_ntohost="not while cross-compiling"])])
409 if test "$ac_cv_buggy_ether_ntohost" = "no"; then
410 AC_DEFINE(USE_ETHER_NTOHOST, 1,
411 [define if you have ether_ntohost() and it works])
412 fi
413 ])
414 if test "$ac_cv_func_ether_ntohost" = yes -a \
415 "$ac_cv_buggy_ether_ntohost" = "no"; then
416 #
417 # OK, we have ether_ntohost(). Is it declared in <net/ethernet.h>?
418 #
419 # This test fails if we don't have <net/ethernet.h> or if we do
420 # but it doesn't declare ether_ntohost().
421 #
422 AC_CHECK_DECL(ether_ntohost,
423 [
424 AC_DEFINE(NET_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
425 [Define to 1 if net/ethernet.h declares `ether_ntohost'])
426 ],,
427 [
428 #include <net/ethernet.h>
429 ])
430 #
431 # Did that succeed?
432 #
433 if test "$ac_cv_have_decl_ether_ntohost" != yes; then
434 #
435 # No, how about <netinet/ether.h>, as on Linux?
436 #
437 # This test fails if we don't have <netinet/ether.h>
438 # or if we do but it doesn't declare ether_ntohost().
439 #
440 # Unset ac_cv_have_decl_ether_ntohost so we don't
441 # treat the previous failure as a cached value and
442 # suppress the next test.
443 #
444 unset ac_cv_have_decl_ether_ntohost
445 AC_CHECK_DECL(ether_ntohost,
446 [
447 AC_DEFINE(NETINET_ETHER_H_DECLARES_ETHER_NTOHOST,,
448 [Define to 1 if netinet/ether.h declares `ether_ntohost'])
449 ],,
450 [
451 #include <netinet/ether.h>
452 ])
453 fi
454 #
455 # Did that succeed?
456 #
457 if test "$ac_cv_have_decl_ether_ntohost" != yes; then
458 #
459 # No, how about <sys/ethernet.h>, as on Solaris 10
460 # and later?
461 #
462 # This test fails if we don't have <sys/ethernet.h>
463 # or if we do but it doesn't declare ether_ntohost().
464 #
465 # Unset ac_cv_have_decl_ether_ntohost so we don't
466 # treat the previous failure as a cached value and
467 # suppress the next test.
468 #
469 unset ac_cv_have_decl_ether_ntohost
470 AC_CHECK_DECL(ether_ntohost,
471 [
472 AC_DEFINE(SYS_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
473 [Define to 1 if sys/ethernet.h declares `ether_ntohost'])
474 ],,
475 [
476 #include <sys/ethernet.h>
477 ])
478 fi
479 #
480 # Did that succeed?
481 #
482 if test "$ac_cv_have_decl_ether_ntohost" != yes; then
483 #
484 # No, how about <arpa/inet.h>, as in AIX?
485 #
486 # This test fails if we don't have <arpa/inet.h>
487 # (if we have ether_ntohost(), we should have
488 # networking, and if we have networking, we should
489 # have <arpa/inet.h>) or if we do but it doesn't
490 # declare ether_ntohost().
491 #
492 # Unset ac_cv_have_decl_ether_ntohost so we don't
493 # treat the previous failure as a cached value and
494 # suppress the next test.
495 #
496 unset ac_cv_have_decl_ether_ntohost
497 AC_CHECK_DECL(ether_ntohost,
498 [
499 AC_DEFINE(ARPA_INET_H_DECLARES_ETHER_NTOHOST,,
500 [Define to 1 if arpa/inet.h declares `ether_ntohost'])
501 ],,
502 [
503 #include <arpa/inet.h>
504 ])
505 fi
506 #
507 # Did that succeed?
508 #
509 if test "$ac_cv_have_decl_ether_ntohost" != yes; then
510 #
511 # No, how about <netinet/if_ether.h>?
512 # On some platforms, it requires <net/if.h> and
513 # <netinet/in.h>, and we always include it with
514 # both of them, so test it with both of them.
515 #
516 # This test fails if we don't have <netinet/if_ether.h>
517 # and the headers we include before it, or if we do but
518 # <netinet/if_ether.h> doesn't declare ether_hostton().
519 #
520 # Unset ac_cv_have_decl_ether_ntohost so we don't
521 # treat the previous failure as a cached value and
522 # suppress the next test.
523 #
524 unset ac_cv_have_decl_ether_ntohost
525 AC_CHECK_DECL(ether_ntohost,
526 [
527 AC_DEFINE(NETINET_IF_ETHER_H_DECLARES_ETHER_NTOHOST,,
528 [Define to 1 if netinet/if_ether.h declares `ether_ntohost'])
529 ],,
530 [
531 #include <sys/types.h>
532 #include <sys/socket.h>
533 #include <net/if.h>
534 #include <netinet/in.h>
535 #include <netinet/if_ether.h>
536 ])
537 fi
538 #
539 # After all that, is ether_ntohost() declared?
540 #
541 if test "$ac_cv_have_decl_ether_ntohost" = yes; then
542 #
543 # Yes.
544 #
545 AC_DEFINE(HAVE_DECL_ETHER_NTOHOST, 1,
546 [Define to 1 if you have the declaration of `ether_ntohost'])
547 else
548 #
549 # No, we'll have to declare it ourselves.
550 # Do we have "struct ether_addr" if we include
551 # <netinet/if_ether.h>?
552 #
553 AC_CHECK_TYPES(struct ether_addr,,,
554 [
555 #include <sys/types.h>
556 #include <sys/socket.h>
557 #include <net/if.h>
558 #include <netinet/in.h>
559 #include <netinet/if_ether.h>
560 ])
561 fi
562 fi
563
564 dnl
565 dnl Check for "pcap_list_datalinks()" and use a substitute version if
566 dnl it's not present. If it is present, check for "pcap_free_datalinks()";
567 dnl if it's not present, we don't replace it for now. (We could do so
568 dnl on UN*X, but not on Windows, where hilarity ensues if a program
569 dnl built with one version of the MSVC support library tries to free
570 dnl something allocated by a library built with another version of
571 dnl the MSVC support library.)
572 dnl
573 AC_CHECK_FUNC(pcap_list_datalinks,
574 [
575 AC_DEFINE(HAVE_PCAP_LIST_DATALINKS, 1,
576 [define if libpcap has pcap_list_datalinks()])
577 AC_CHECK_FUNCS(pcap_free_datalinks)
578 ],
579 [
580 AC_LIBOBJ(datalinks)
581 ])
582
583 dnl
584 dnl Check for "pcap_datalink_name_to_val()", and use a substitute
585 dnl version if it's not present. If it is present, check for
586 dnl "pcap_datalink_val_to_description()", and if we don't have it,
587 dnl use a substitute version.
588 dnl
589 AC_CHECK_FUNC(pcap_datalink_name_to_val,
590 [
591 AC_DEFINE(HAVE_PCAP_DATALINK_NAME_TO_VAL, 1,
592 [define if libpcap has pcap_datalink_name_to_val()])
593 AC_CHECK_FUNC(pcap_datalink_val_to_description,
594 AC_DEFINE(HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION, 1,
595 [define if libpcap has pcap_datalink_val_to_description()]),
596 [
597 AC_LIBOBJ(dlnames)
598 ])
599 ],
600 [
601 AC_LIBOBJ(dlnames)
602 ])
603
604 dnl
605 dnl Check for "pcap_set_datalink()"; you can't substitute for it if
606 dnl it's absent (it has hooks into libpcap), so just define the
607 dnl HAVE_ value if it's there.
608 dnl
609 AC_CHECK_FUNCS(pcap_set_datalink)
610
611 dnl
612 dnl Check for "pcap_breakloop()"; you can't substitute for it if
613 dnl it's absent (it has hooks into the live capture routines),
614 dnl so just define the HAVE_ value if it's there.
615 dnl
616 AC_CHECK_FUNCS(pcap_breakloop)
617
618 #
619 # Do we have the new open API? Check for pcap_create, and assume that,
620 # if we do, we also have pcap_activate() and the other new routines
621 # introduced in libpcap 1.0.0.
622 #
623 AC_CHECK_FUNCS(pcap_create)
624 if test $ac_cv_func_pcap_create = "yes" ; then
625 #
626 # OK, do we have pcap_set_tstamp_type? If so, assume we have
627 # pcap_list_tstamp_types and pcap_free_tstamp_types as well.
628 #
629 AC_CHECK_FUNCS(pcap_set_tstamp_type)
630 #
631 # And do we have pcap_set_tstamp_precision? If so, we assume
632 # we also have pcap_open_offline_with_tstamp_precision.
633 #
634 AC_CHECK_FUNCS(pcap_set_tstamp_precision)
635 fi
636
637 #
638 # Check for a miscellaneous collection of functions which we use
639 # if we have them.
640 #
641 AC_CHECK_FUNCS(pcap_findalldevs)
642 AC_CHECK_FUNCS(pcap_dump_flush pcap_lib_version)
643 if test $ac_cv_func_pcap_lib_version = "no" ; then
644 AC_MSG_CHECKING(whether pcap_version is defined by libpcap)
645 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
646 extern char pcap_version[];
647
648 return (int)pcap_version;
649 ]])
650 ],
651 [ac_lbl_cv_pcap_version_defined=yes],
652 [ac_lbl_cv_pcap_version_defined=no])
653 if test "$ac_lbl_cv_pcap_version_defined" = yes ; then
654 AC_MSG_RESULT(yes)
655 AC_DEFINE(HAVE_PCAP_VERSION, 1, [define if libpcap has pcap_version])
656 else
657 AC_MSG_RESULT(no)
658 fi
659 fi
660 AC_CHECK_FUNCS(pcap_setdirection pcap_set_immediate_mode pcap_dump_ftell64)
661 AC_CHECK_FUNCS(pcap_open pcap_findalldevs_ex)
662 AC_REPLACE_FUNCS(pcap_dump_ftell)
663
664 #
665 # Check for special debugging functions
666 #
667 AC_CHECK_FUNCS(pcap_set_parser_debug)
668 if test "$ac_cv_func_pcap_set_parser_debug" = "no" ; then
669 #
670 # OK, we don't have pcap_set_parser_debug() to set the libpcap
671 # filter expression parser debug flag; can we directly set the
672 # flag?
673 AC_MSG_CHECKING(whether pcap_debug is defined by libpcap)
674 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
675 extern int pcap_debug;
676
677 return pcap_debug;
678 ]])
679 ],
680 [ac_lbl_cv_pcap_debug_defined=yes],
681 [ac_lbl_cv_pcap_debug_defined=no])
682 if test "$ac_lbl_cv_pcap_debug_defined" = yes ; then
683 AC_MSG_RESULT(yes)
684 AC_DEFINE(HAVE_PCAP_DEBUG, 1, [define if libpcap has pcap_debug])
685 else
686 AC_MSG_RESULT(no)
687 #
688 # OK, what about "yydebug"?
689 #
690 AC_MSG_CHECKING(whether yydebug is defined by libpcap)
691 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
692 extern int yydebug;
693
694 return yydebug;
695 ]])
696 ],
697 [ac_lbl_cv_yydebug_defined=yes],
698 [ac_lbl_cv_yydebug_defined=no])
699 if test "$ac_lbl_cv_yydebug_defined" = yes ; then
700 AC_MSG_RESULT(yes)
701 AC_DEFINE(HAVE_YYDEBUG, 1, [define if libpcap has yydebug])
702 else
703 AC_MSG_RESULT(no)
704 fi
705 fi
706 fi
707 AC_CHECK_FUNCS(pcap_set_optimizer_debug)
708 AC_REPLACE_FUNCS(bpf_dump) dnl moved to libpcap in 0.6
709
710 #
711 # Assume V7/BSD convention for man pages (file formats in section 5,
712 # miscellaneous info in section 7).
713 #
714 MAN_FILE_FORMATS=5
715 MAN_MISC_INFO=7
716 case "$host_os" in
717
718 aix*)
719 dnl Workaround to enable certain features
720 AC_DEFINE(_SUN,1,[define on AIX to get certain functions])
721 ;;
722
723 hpux*)
724 #
725 # Use System V conventions for man pages.
726 #
727 MAN_FILE_FORMATS=4
728 MAN_MISC_INFO=5
729 ;;
730
731 solaris*)
732 #
733 # Use System V conventions for man pages.
734 #
735 MAN_FILE_FORMATS=4
736 MAN_MISC_INFO=5
737 ;;
738 esac
739
740 #
741 # Make sure we have a definition for C99's uintptr_t (regardless of
742 # whether the environment is a C99 environment or not).
743 #
744 AC_TYPE_UINTPTR_T
745
746 savedcppflags="$CPPFLAGS"
747 CPPFLAGS="$CPPFLAGS $V_INCLS"
748
749 #
750 # Check whether we have pcap/pcap-inttypes.h.
751 # If we do, we use that to get the C99 types defined.
752 #
753 AC_CHECK_HEADERS(pcap/pcap-inttypes.h)
754
755 #
756 # At compile time HAVE_PCAP_FINDALLDEVS depends on HAVE_PCAP_IF_T.
757 #
758 AC_CHECK_TYPES(pcap_if_t, , , [#include <pcap.h>])
759
760 CPPFLAGS="$savedcppflags"
761
762 #
763 # Define the old BSD specified-width types in terms of the C99 types;
764 # we may need them with libpcap include files.
765 #
766 AC_CHECK_TYPE([u_int8_t], ,
767 [AC_DEFINE([u_int8_t], [uint8_t],
768 [Define to `uint8_t' if u_int8_t not defined.])],
769 [AC_INCLUDES_DEFAULT
770 #include <sys/types.h>
771 ])
772 AC_CHECK_TYPE([u_int16_t], ,
773 [AC_DEFINE([u_int16_t], [uint16_t],
774 [Define to `uint16_t' if u_int16_t not defined.])],
775 [AC_INCLUDES_DEFAULT
776 #include <sys/types.h>
777 ])
778 AC_CHECK_TYPE([u_int32_t], ,
779 [AC_DEFINE([u_int32_t], [uint32_t],
780 [Define to `uint32_t' if u_int32_t not defined.])],
781 [AC_INCLUDES_DEFAULT
782 #include <sys/types.h>
783 ])
784 AC_CHECK_TYPE([u_int64_t], ,
785 [AC_DEFINE([u_int64_t], [uint64_t],
786 [Define to `uint64_t' if u_int64_t not defined.])],
787 [AC_INCLUDES_DEFAULT
788 #include <sys/types.h>
789 ])
790
791 AC_PROG_RANLIB
792 AC_CHECK_TOOL([AR], [ar])
793
794 AC_LBL_DEVEL(V_CCOPT)
795
796 # Check for OpenSSL/libressl libcrypto
797 AC_MSG_CHECKING(whether to use OpenSSL/libressl libcrypto)
798 # Specify location for both includes and libraries.
799 want_libcrypto=ifavailable
800 AC_ARG_WITH(crypto,
801 AS_HELP_STRING([--with-crypto]@<:@=DIR@:>@,
802 [use OpenSSL/libressl libcrypto (located in directory DIR, if specified) @<:@default=yes, if available@:>@]),
803 [
804 if test $withval = no
805 then
806 # User doesn't want to link with libcrypto.
807 want_libcrypto=no
808 AC_MSG_RESULT(no)
809 elif test $withval = yes
810 then
811 # User wants to link with libcrypto but hasn't specified
812 # a directory.
813 want_libcrypto=yes
814 AC_MSG_RESULT(yes)
815 else
816 # User wants to link with libcrypto and has specified
817 # a directory, so use the provided value.
818 want_libcrypto=yes
819 libcrypto_root=$withval
820 AC_MSG_RESULT([yes, using the version installed in $withval])
821
822 #
823 # Put the subdirectories of the libcrypto root directory
824 # at the front of the header and library search path.
825 #
826 CFLAGS="-I$withval/include $CFLAGS"
827 LIBS="-L$withval/lib $LIBS"
828 fi
829 ],[
830 #
831 # Use libcrypto if it's present, otherwise don't; no directory
832 # was specified.
833 #
834 want_libcrypto=ifavailable
835 AC_MSG_RESULT([yes, if available])
836 ])
837 if test "$want_libcrypto" != "no"; then
838 #
839 # Don't check for libcrypto unless we have its headers;
840 # Apple, bless their pointy little heads, apparently ship
841 # libcrypto as a library, but not the header files, in
842 # El Capitan, probably because they don't want you writing
843 # nasty portable code that could run on other UN*Xes, they
844 # want you writing code that uses their Shiny New Crypto
845 # Library and that only runs on macOS.
846 #
847 AC_CHECK_HEADER(openssl/crypto.h,
848 [
849 AC_CHECK_LIB(crypto, DES_cbc_encrypt)
850 if test "$ac_cv_lib_crypto_DES_cbc_encrypt" = "yes"; then
851 AC_CHECK_HEADERS(openssl/evp.h)
852 #
853 # OK, then:
854 #
855 # 1) do we have EVP_CIPHER_CTX_new?
856 # If so, we use it to allocate an
857 # EVP_CIPHER_CTX, as EVP_CIPHER_CTX may be
858 # opaque; otherwise, we allocate it ourselves.
859 #
860 # 2) do we have EVP_DecryptInit_ex()?
861 # If so, we use it, because we need to be
862 # able to make two "initialize the cipher"
863 # calls, one with the cipher and key, and
864 # one with the IV, and, as of OpenSSL 1.1,
865 # You Can't Do That with EVP_DecryptInit(),
866 # because a call to EVP_DecryptInit() will
867 # unconditionally clear the context, and
868 # if you don't supply a cipher, it'll
869 # clear the cipher, rendering the context
870 # unusable and causing a crash.
871 #
872 AC_CHECK_FUNCS(EVP_CIPHER_CTX_new EVP_DecryptInit_ex)
873 fi
874 ])
875 fi
876
877 # Check for libcap-ng
878 AC_MSG_CHECKING(whether to use libcap-ng)
879 # Specify location for both includes and libraries.
880 want_libcap_ng=ifavailable
881 AC_ARG_WITH(cap_ng,
882 AS_HELP_STRING([--with-cap-ng],
883 [use libcap-ng @<:@default=yes, if available@:>@]),
884 [
885 if test $withval = no
886 then
887 want_libcap_ng=no
888 AC_MSG_RESULT(no)
889 elif test $withval = yes
890 then
891 want_libcap_ng=yes
892 AC_MSG_RESULT(yes)
893 fi
894 ],[
895 #
896 # Use libcap-ng if it's present, otherwise don't.
897 #
898 want_libcap_ng=ifavailable
899 AC_MSG_RESULT([yes, if available])
900 ])
901 if test "$want_libcap_ng" != "no"; then
902 AC_CHECK_LIB(cap-ng, capng_change_id)
903 AC_CHECK_HEADERS(cap-ng.h)
904 fi
905
906 dnl
907 dnl set additional include path if necessary
908 if test "$missing_includes" = "yes"; then
909 CPPFLAGS="$CPPFLAGS -I$srcdir/missing"
910 V_INCLS="$V_INCLS -I$srcdir/missing"
911 fi
912
913 AC_SUBST(V_CCOPT)
914 AC_SUBST(V_DEFS)
915 AC_SUBST(V_INCLS)
916 AC_SUBST(V_PCAPDEP)
917 AC_SUBST(LOCALSRC)
918 AC_SUBST(MAN_FILE_FORMATS)
919 AC_SUBST(MAN_MISC_INFO)
920
921 AC_PROG_INSTALL
922
923 AC_CONFIG_HEADERS([config.h])
924
925 AC_CONFIG_COMMANDS([.devel],[[if test -f .devel; then
926 echo timestamp > stamp-h
927 cat $srcdir/Makefile-devel-adds >> Makefile
928 make depend || exit 1
929 fi]])
930 AC_CONFIG_FILES([Makefile tcpdump.1])
931 AC_OUTPUT
932 exit 0
[mirror] the TCPdump network dissector