]> The Tcpdump Group git mirrors - tcpdump/blob - configure.ac
projects / tcpdump / blob


77ad065c00d0f6a7f4b1ddb3fa097b6a17c3ce6a
[tcpdump] / configure.ac
1 dnl Copyright (c) 1994, 1995, 1996, 1997
2 dnl The Regents of the University of California. All rights reserved.
3 dnl
4 dnl Process this file with autoconf to produce a configure script.
5 dnl
6
7 #
8 # See
9 #
10 # https://ftp.gnu.org/gnu/config/README
11 #
12 # for the URLs to use to fetch new versions of config.guess and
13 # config.sub.
14 #
15
16 AC_PREREQ([2.69])
17 AC_INIT([tcpdump],[m4_esyscmd_s(cat VERSION)],[https://github.com/the-tcpdump-group/tcpdump/issues])
18 AC_CONFIG_SRCDIR(tcpdump.c)
19
20 AC_CANONICAL_HOST
21
22 AC_LBL_C_INIT_BEFORE_CC(V_INCLS)
23 #
24 # Try to enable as many C99 features as we can.
25 # At minimum, we want C++/C99-style // comments.
26 #
27 AC_PROG_CC_C99
28 if test "$ac_cv_prog_cc_c99" = "no"; then
29 AC_MSG_WARN([The C compiler does not support C99; there may be compiler errors])
30 fi
31 AC_LBL_C_INIT(V_CCOPT, V_INCLS)
32 AC_C_INLINE
33
34 AC_CHECK_HEADERS(fcntl.h rpc/rpc.h rpc/rpcent.h net/if.h)
35 #
36 # Get the size of a void *, to know whether this is a 32-bit or 64-bit build.
37 #
38 AC_CHECK_SIZEOF([void *])
39
40 #
41 # Get the size of a time_t, to know whether it's 32-bit or 64-bit.
42 #
43 AC_CHECK_SIZEOF([time_t],,[#include <time.h>])
44
45 case "$host_os" in
46
47 darwin*)
48 AC_ARG_ENABLE(universal,
49 AS_HELP_STRING([--disable-universal],[don't build universal on macOS]))
50 if test "$enable_universal" != "no"; then
51 case "$host_os" in
52
53 darwin9.*)
54 #
55 # Leopard. Build for x86 and 32-bit PowerPC, with
56 # x86 first. (That's what Apple does.)
57 #
58 V_CCOPT="$V_CCOPT -arch i386 -arch ppc"
59 LDFLAGS="$LDFLAGS -arch i386 -arch ppc"
60 ;;
61
62 darwin10.*)
63 #
64 # Snow Leopard. Build for x86-64 and x86, with
65 # x86-64 first. (That's what Apple does.)
66 #
67 V_CCOPT="$V_CCOPT -arch x86_64 -arch i386"
68 LDFLAGS="$LDFLAGS -arch x86_64 -arch i386"
69 ;;
70 esac
71 fi
72 ;;
73 esac
74
75 AC_ARG_WITH([smi],
76 [AS_HELP_STRING([--with-smi],
77 [link with libsmi (allows to load MIBs on the fly to decode SNMP packets) [default=yes, if available]])],
78 [],
79 [with_smi=yes])
80
81 if test "x$with_smi" != "xno" ; then
82 AC_CHECK_HEADER(smi.h,
83 [
84 #
85 # OK, we found smi.h. Do we have libsmi with smiInit?
86 #
87 AC_CHECK_LIB(smi, smiInit,
88 [
89 #
90 # OK, we have libsmi with smiInit. Can we use it?
91 #
92 AC_MSG_CHECKING([whether to enable libsmi])
93 savedlibs="$LIBS"
94 LIBS="-lsmi $LIBS"
95 AC_RUN_IFELSE([AC_LANG_SOURCE([[
96 /* libsmi available check */
97 #include <stdio.h>
98 #include <stdlib.h>
99 #include <string.h>
100 #include <smi.h>
101 int main()
102 {
103 int current, revision, age, n;
104 const int required = 2;
105 if (smiInit(""))
106 exit(1);
107 if (strcmp(SMI_LIBRARY_VERSION, smi_library_version))
108 exit(2);
109 n = sscanf(smi_library_version, "%d:%d:%d", &current, &revision, &age);
110 if (n != 3)
111 exit(3);
112 if (required < current - age || required > current)
113 exit(4);
114 exit(0);
115 }
116 ]])
117 ],
118 [
119 AC_MSG_RESULT(yes)
120 AC_DEFINE(USE_LIBSMI, 1,
121 [Define if you enable support for libsmi])
122 ],
123 [
124 dnl autoconf documentation says that
125 dnl $? contains the exit value.
126 dnl reality is that it does not.
127 dnl We leave this in just in case
128 dnl autoconf ever comes back to
129 dnl match the documentation.
130 case $? in
131 1) AC_MSG_RESULT(no - smiInit failed) ;;
132 2) AC_MSG_RESULT(no - header/library version mismatch) ;;
133 3) AC_MSG_RESULT(no - can't determine library version) ;;
134 4) AC_MSG_RESULT(no - too old) ;;
135 *) AC_MSG_RESULT(no) ;;
136 esac
137 LIBS="$savedlibs"
138 ],
139 [
140 AC_MSG_RESULT(not when cross-compiling)
141 LIBS="$savedlibs"
142 ]
143 )
144 ])
145 ])
146 fi
147
148 AC_MSG_CHECKING([whether to enable the instrument functions code])
149 AC_ARG_ENABLE([instrument-functions],
150 [AS_HELP_STRING([--enable-instrument-functions],
151 [enable instrument functions code [default=no]])],
152 [],
153 [enableval=no])
154 case "$enableval" in
155 yes) AC_MSG_RESULT(yes)
156 AC_CHECK_LIB([bfd], [bfd_init],
157 [true],
158 [AC_MSG_ERROR(
159 [--enable-instrument-functions was given, but test for library libbfd failed. Please install the 'binutils-dev' package.])],
160 [])
161 AC_DEFINE(ENABLE_INSTRUMENT_FUNCTIONS, 1,
162 [define if you want to build the instrument functions code])
163 LOCALSRC="$LOCALSRC instrument-functions.c"
164 # Add '-finstrument-functions' instrumentation option to generate
165 # instrumentation calls for entry and exit to functions.
166 # Try to avoid Address Space Layout Randomization (ALSR).
167 CFLAGS="$CFLAGS -O0 -ggdb -finstrument-functions -fno-stack-protector -fno-pic"
168 LDFLAGS="$LDFLAGS -O0 -ggdb -fno-stack-protector -no-pie"
169 LIBS="$LIBS -lbfd"
170 ;;
171 *) AC_MSG_RESULT(no)
172 ;;
173 esac
174
175 AC_MSG_CHECKING([whether to enable the possibly-buggy SMB printer])
176 AC_ARG_ENABLE([smb],
177 [AS_HELP_STRING([--enable-smb],
178 [enable possibly-buggy SMB printer [default=no]])],
179 [],
180 [enableval=no])
181 case "$enableval" in
182 yes) AC_MSG_RESULT(yes)
183 AC_DEFINE(ENABLE_SMB, 1,
184 [define if you want to build the possibly-buggy SMB printer])
185 LOCALSRC="print-smb.c smbutil.c $LOCALSRC"
186 ;;
187 *) AC_MSG_RESULT(no)
188 ;;
189 esac
190
191 AC_MSG_CHECKING([whether to drop root privileges by default])
192 AC_ARG_WITH(
193 [user],
194 [AS_HELP_STRING([--with-user=USERNAME],
195 [drop privileges by default to USERNAME]
196 )],
197 [],
198 [withval=no])
199 AS_CASE(["$withval"],
200 [no], [AC_MSG_RESULT(no)],
201 [''|yes], [AC_MSG_ERROR([--with-user requires a username])],
202 [
203 AC_DEFINE_UNQUOTED(WITH_USER, "$withval",
204 [define if should drop privileges by default])
205 AC_MSG_RESULT([yes, to user "$withval"])
206 ]
207 )
208
209 AC_MSG_CHECKING([whether to chroot])
210 AC_ARG_WITH(
211 [chroot],
212 [AS_HELP_STRING([--with-chroot=DIRECTORY],
213 [when dropping privileges, chroot to DIRECTORY]
214 )],
215 [],
216 [withval=no]
217 )
218 AS_CASE(["$withval"],
219 [no], [AC_MSG_RESULT(no)],
220 [''|yes], [AC_MSG_ERROR([--with-chroot requires a directory])],
221 [
222 AC_DEFINE_UNQUOTED(WITH_CHROOT, "$withval",
223 [define if should chroot when dropping privileges])
224 AC_MSG_RESULT([yes, to directory "$withval"])
225 ]
226 )
227
228 AC_ARG_WITH(sandbox-capsicum,
229 AS_HELP_STRING([--with-sandbox-capsicum],
230 [use Capsicum security functions @<:@default=yes, if available@:>@]))
231 #
232 # Check whether various functions are available. If any are, set
233 # ac_lbl_capsicum_function_seen to yes; if any are not, set
234 # ac_lbl_capsicum_function_not_seen to yes.
235 #
236 # We don't check cap_rights_init(), as it's a macro, wrapping another
237 # function, in at least some versions of FreeBSD, and AC_CHECK_FUNCS()
238 # doesn't handle that.
239 #
240 # All of the ones we check for must be available in order to enable
241 # capsicum sandboxing.
242 #
243 # XXX - do we need to check for all of them, or are there some that, if
244 # present, imply others are present?
245 #
246 if test -z "$with_sandbox_capsicum" || test "$with_sandbox_capsicum" != "no" ; then
247 #
248 # First, make sure we have the required header.
249 #
250 AC_CHECK_HEADER(sys/capsicum.h,
251 [
252 #
253 # We do; now make sure we have the required functions.
254 #
255 AC_CHECK_FUNCS(cap_enter cap_rights_limit cap_ioctls_limit openat,
256 ac_lbl_capsicum_function_seen=yes,
257 ac_lbl_capsicum_function_not_seen=yes)
258 ])
259 AC_CHECK_LIB(casper, cap_init, LIBS="$LIBS -lcasper")
260 AC_CHECK_LIB(cap_dns, cap_gethostbyaddr, LIBS="$LIBS -lcap_dns")
261 fi
262 AC_MSG_CHECKING([whether to sandbox using capsicum])
263 if test "x$ac_lbl_capsicum_function_seen" = "xyes" -a "x$ac_lbl_capsicum_function_not_seen" != "xyes"; then
264 AC_DEFINE(HAVE_CAPSICUM, 1, [capsicum support available])
265 AC_MSG_RESULT(yes)
266 else
267 AC_MSG_RESULT(no)
268 fi
269 AC_MSG_CHECKING([whether to sandbox using Casper library])
270 if test "x$ac_cv_lib_casper_cap_init" = "xyes" -a "x$ac_cv_lib_cap_dns_cap_gethostbyaddr" = "xyes"; then
271 AC_DEFINE(HAVE_CASPER, 1, [Casper support available])
272 AC_MSG_RESULT(yes)
273 else
274 AC_MSG_RESULT(no)
275 fi
276
277 #
278 # We must check this before checking whether to check the OS's IPv6,
279 # support because, on some platforms (such as SunOS 5.x), the test
280 # program requires the extra networking libraries.
281 #
282 AC_LBL_LIBRARY_NET
283
284 AC_REPLACE_FUNCS(strlcat strlcpy strsep getservent getopt_long)
285 AC_CHECK_FUNCS(fork vfork)
286 AC_CHECK_FUNCS(setlinebuf)
287
288 #
289 # Make sure we have snprintf(); we require it.
290 #
291 AC_CHECK_FUNC(snprintf,,
292 AC_MSG_ERROR([snprintf() is required but wasn't found]))
293
294 #
295 # It became apparent at some point that using a suitable C99 compiler does not
296 # automatically mean snprintf(3) implementation in the libc supports all the
297 # modifiers and specifiers used in the project, so let's test that before the
298 # build, not after.
299 #
300 # Testing the sizeof_t length modifier takes making an snprintf() call and
301 # comparing the actual result with the expected result. If this fails, it will
302 # most likely happen at run time, not compile time.
303 #
304 # Testing the 64-bit conversion specifiers in addition to that requires the
305 # <inttypes.h> header to be present and the macros to be defined, so if this
306 # fails, it will more likely happen at compile time.
307 #
308 AC_MSG_CHECKING([whether snprintf is suitable])
309 AC_RUN_IFELSE(
310 [
311 AC_LANG_SOURCE([[
312 #include <stdio.h>
313 #include <string.h>
314 #include <inttypes.h>
315 #include <sys/types.h>
316
317 int main()
318 {
319 char buf[100];
320 uint64_t t = (uint64_t)1 << 32;
321
322 snprintf(buf, sizeof(buf), "%zu", sizeof(buf));
323 if (strncmp(buf, "100", sizeof(buf)))
324 return 1;
325
326 snprintf(buf, sizeof(buf), "%zd", -sizeof(buf));
327 if (strncmp(buf, "-100", sizeof(buf)))
328 return 2;
329
330 snprintf(buf, sizeof(buf), "%" PRId64, -t);
331 if (strncmp(buf, "-4294967296", sizeof(buf)))
332 return 3;
333
334 snprintf(buf, sizeof(buf), "0o%" PRIo64, t);
335 if (strncmp(buf, "0o40000000000", sizeof(buf)))
336 return 4;
337
338 snprintf(buf, sizeof(buf), "0x%" PRIx64, t);
339 if (strncmp(buf, "0x100000000", sizeof(buf)))
340 return 5;
341
342 snprintf(buf, sizeof(buf), "%" PRIu64, t);
343 if (strncmp(buf, "4294967296", sizeof(buf)))
344 return 6;
345
346 return 0;
347 }
348 ]])
349 ],
350 [
351 AC_MSG_RESULT(yes)
352 ],
353 [
354 AC_MSG_RESULT(no)
355 AC_MSG_ERROR(
356 [The snprintf(3) implementation in this libc is not suitable,
357 tcpdump would not work correctly even if it managed to compile.])
358 ],
359 [
360 AC_MSG_RESULT(not while cross-compiling)
361 ]
362 )
363
364 AC_CHECK_LIB(rpc, main) dnl It's unclear why we might need -lrpc
365
366 dnl Some platforms may need -lnsl for getrpcbynumber.
367 AC_SEARCH_LIBS(getrpcbynumber, nsl,
368 AC_DEFINE(HAVE_GETRPCBYNUMBER, 1, [define if you have getrpcbynumber()]))
369
370 AC_LBL_LIBPCAP(V_PCAPDEP, V_INCLS)
371
372 #
373 # Check for these after AC_LBL_LIBPCAP, so we link with the appropriate
374 # libraries (e.g., "-lsocket -lnsl" on Solaris).
375 #
376 # You are in a twisty little maze of UN*Xes, all different.
377 # Some might not have ether_ntohost().
378 # Some might have it and declare it in <net/ethernet.h>.
379 # Some might have it and declare it in <netinet/ether.h>
380 # Some might have it and declare it in <sys/ethernet.h>.
381 # Some might have it and declare it in <arpa/inet.h>.
382 # Some might have it and declare it in <netinet/if_ether.h>.
383 # Some might have it and not declare it in any header file.
384 #
385 # Before you is a C compiler.
386 #
387 AC_CHECK_FUNCS(ether_ntohost, [
388 AC_CACHE_CHECK(for buggy ether_ntohost, ac_cv_buggy_ether_ntohost, [
389 AC_RUN_IFELSE([AC_LANG_SOURCE([[
390 #include <netdb.h>
391 #include <netinet/ether.h>
392 #include <stdlib.h>
393 #include <sys/types.h>
394 #include <sys/param.h>
395 #include <sys/socket.h>
396
397 int
398 main(int argc, char **argv)
399 {
400 u_char ea[6] = { 0xff, 0xff, 0xff, 0xff, 0xff };
401 char name[MAXHOSTNAMELEN];
402
403 ether_ntohost(name, (struct ether_addr *)ea);
404 exit(0);
405 }
406 ]])
407 ], [ac_cv_buggy_ether_ntohost=no],
408 [ac_cv_buggy_ether_ntohost=yes],
409 [ac_cv_buggy_ether_ntohost="not while cross-compiling"])])
410 if test "$ac_cv_buggy_ether_ntohost" = "no"; then
411 AC_DEFINE(USE_ETHER_NTOHOST, 1,
412 [define if you have ether_ntohost() and it works])
413 fi
414 ])
415 if test "$ac_cv_func_ether_ntohost" = yes -a \
416 "$ac_cv_buggy_ether_ntohost" = "no"; then
417 #
418 # OK, we have ether_ntohost(). Is it declared in <net/ethernet.h>?
419 #
420 # This test fails if we don't have <net/ethernet.h> or if we do
421 # but it doesn't declare ether_ntohost().
422 #
423 AC_CHECK_DECL(ether_ntohost,
424 [
425 AC_DEFINE(NET_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
426 [Define to 1 if net/ethernet.h declares `ether_ntohost'])
427 ],,
428 [
429 #include <net/ethernet.h>
430 ])
431 #
432 # Did that succeed?
433 #
434 if test "$ac_cv_have_decl_ether_ntohost" != yes; then
435 #
436 # No, how about <netinet/ether.h>, as on Linux?
437 #
438 # This test fails if we don't have <netinet/ether.h>
439 # or if we do but it doesn't declare ether_ntohost().
440 #
441 # Unset ac_cv_have_decl_ether_ntohost so we don't
442 # treat the previous failure as a cached value and
443 # suppress the next test.
444 #
445 unset ac_cv_have_decl_ether_ntohost
446 AC_CHECK_DECL(ether_ntohost,
447 [
448 AC_DEFINE(NETINET_ETHER_H_DECLARES_ETHER_NTOHOST,,
449 [Define to 1 if netinet/ether.h declares `ether_ntohost'])
450 ],,
451 [
452 #include <netinet/ether.h>
453 ])
454 fi
455 #
456 # Did that succeed?
457 #
458 if test "$ac_cv_have_decl_ether_ntohost" != yes; then
459 #
460 # No, how about <sys/ethernet.h>, as on Solaris 10
461 # and later?
462 #
463 # This test fails if we don't have <sys/ethernet.h>
464 # or if we do but it doesn't declare ether_ntohost().
465 #
466 # Unset ac_cv_have_decl_ether_ntohost so we don't
467 # treat the previous failure as a cached value and
468 # suppress the next test.
469 #
470 unset ac_cv_have_decl_ether_ntohost
471 AC_CHECK_DECL(ether_ntohost,
472 [
473 AC_DEFINE(SYS_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
474 [Define to 1 if sys/ethernet.h declares `ether_ntohost'])
475 ],,
476 [
477 #include <sys/ethernet.h>
478 ])
479 fi
480 #
481 # Did that succeed?
482 #
483 if test "$ac_cv_have_decl_ether_ntohost" != yes; then
484 #
485 # No, how about <arpa/inet.h>, as in AIX?
486 #
487 # This test fails if we don't have <arpa/inet.h>
488 # (if we have ether_ntohost(), we should have
489 # networking, and if we have networking, we should
490 # have <arpa/inet.h>) or if we do but it doesn't
491 # declare ether_ntohost().
492 #
493 # Unset ac_cv_have_decl_ether_ntohost so we don't
494 # treat the previous failure as a cached value and
495 # suppress the next test.
496 #
497 unset ac_cv_have_decl_ether_ntohost
498 AC_CHECK_DECL(ether_ntohost,
499 [
500 AC_DEFINE(ARPA_INET_H_DECLARES_ETHER_NTOHOST,,
501 [Define to 1 if arpa/inet.h declares `ether_ntohost'])
502 ],,
503 [
504 #include <arpa/inet.h>
505 ])
506 fi
507 #
508 # Did that succeed?
509 #
510 if test "$ac_cv_have_decl_ether_ntohost" != yes; then
511 #
512 # No, how about <netinet/if_ether.h>?
513 # On some platforms, it requires <net/if.h> and
514 # <netinet/in.h>, and we always include it with
515 # both of them, so test it with both of them.
516 #
517 # This test fails if we don't have <netinet/if_ether.h>
518 # and the headers we include before it, or if we do but
519 # <netinet/if_ether.h> doesn't declare ether_hostton().
520 #
521 # Unset ac_cv_have_decl_ether_ntohost so we don't
522 # treat the previous failure as a cached value and
523 # suppress the next test.
524 #
525 unset ac_cv_have_decl_ether_ntohost
526 AC_CHECK_DECL(ether_ntohost,
527 [
528 AC_DEFINE(NETINET_IF_ETHER_H_DECLARES_ETHER_NTOHOST,,
529 [Define to 1 if netinet/if_ether.h declares `ether_ntohost'])
530 ],,
531 [
532 #include <sys/types.h>
533 #include <sys/socket.h>
534 #include <net/if.h>
535 #include <netinet/in.h>
536 #include <netinet/if_ether.h>
537 ])
538 fi
539 #
540 # After all that, is ether_ntohost() declared?
541 #
542 if test "$ac_cv_have_decl_ether_ntohost" = yes; then
543 #
544 # Yes.
545 #
546 AC_DEFINE(HAVE_DECL_ETHER_NTOHOST, 1,
547 [Define to 1 if you have the declaration of `ether_ntohost'])
548 else
549 #
550 # No, we'll have to declare it ourselves.
551 # Do we have "struct ether_addr" if we include
552 # <netinet/if_ether.h>?
553 #
554 AC_CHECK_TYPES(struct ether_addr,,,
555 [
556 #include <sys/types.h>
557 #include <sys/socket.h>
558 #include <net/if.h>
559 #include <netinet/in.h>
560 #include <netinet/if_ether.h>
561 ])
562 fi
563 fi
564
565 dnl
566 dnl Check for "pcap_list_datalinks()" and use a substitute version if
567 dnl it's not present. If it is present, check for "pcap_free_datalinks()";
568 dnl if it's not present, we don't replace it for now. (We could do so
569 dnl on UN*X, but not on Windows, where hilarity ensues if a program
570 dnl built with one version of the MSVC support library tries to free
571 dnl something allocated by a library built with another version of
572 dnl the MSVC support library.)
573 dnl
574 AC_CHECK_FUNC(pcap_list_datalinks,
575 [
576 AC_DEFINE(HAVE_PCAP_LIST_DATALINKS, 1,
577 [define if libpcap has pcap_list_datalinks()])
578 AC_CHECK_FUNCS(pcap_free_datalinks)
579 ],
580 [
581 AC_LIBOBJ(datalinks)
582 ])
583
584 dnl
585 dnl Check for "pcap_datalink_name_to_val()", and use a substitute
586 dnl version if it's not present. If it is present, check for
587 dnl "pcap_datalink_val_to_description()", and if we don't have it,
588 dnl use a substitute version.
589 dnl
590 AC_CHECK_FUNC(pcap_datalink_name_to_val,
591 [
592 AC_DEFINE(HAVE_PCAP_DATALINK_NAME_TO_VAL, 1,
593 [define if libpcap has pcap_datalink_name_to_val()])
594 AC_CHECK_FUNC(pcap_datalink_val_to_description,
595 AC_DEFINE(HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION, 1,
596 [define if libpcap has pcap_datalink_val_to_description()]),
597 [
598 AC_LIBOBJ(dlnames)
599 ])
600 ],
601 [
602 AC_LIBOBJ(dlnames)
603 ])
604
605 dnl
606 dnl Check for "pcap_set_datalink()"; you can't substitute for it if
607 dnl it's absent (it has hooks into libpcap), so just define the
608 dnl HAVE_ value if it's there.
609 dnl
610 AC_CHECK_FUNCS(pcap_set_datalink)
611
612 dnl
613 dnl Check for "pcap_breakloop()"; you can't substitute for it if
614 dnl it's absent (it has hooks into the live capture routines),
615 dnl so just define the HAVE_ value if it's there.
616 dnl
617 AC_CHECK_FUNCS(pcap_breakloop)
618
619 #
620 # Do we have the new open API? Check for pcap_create, and assume that,
621 # if we do, we also have pcap_activate() and the other new routines
622 # introduced in libpcap 1.0.0.
623 #
624 AC_CHECK_FUNCS(pcap_create)
625 if test $ac_cv_func_pcap_create = "yes" ; then
626 #
627 # OK, do we have pcap_set_tstamp_type? If so, assume we have
628 # pcap_list_tstamp_types and pcap_free_tstamp_types as well.
629 #
630 AC_CHECK_FUNCS(pcap_set_tstamp_type)
631 #
632 # And do we have pcap_set_tstamp_precision? If so, we assume
633 # we also have pcap_open_offline_with_tstamp_precision.
634 #
635 AC_CHECK_FUNCS(pcap_set_tstamp_precision)
636 fi
637
638 #
639 # Check for a miscellaneous collection of functions which we use
640 # if we have them.
641 #
642 AC_CHECK_FUNCS(pcap_findalldevs)
643 AC_CHECK_FUNCS(pcap_dump_flush pcap_lib_version)
644 if test $ac_cv_func_pcap_lib_version = "no" ; then
645 AC_MSG_CHECKING(whether pcap_version is defined by libpcap)
646 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
647 extern char pcap_version[];
648
649 return (int)pcap_version;
650 ]])
651 ],
652 [ac_lbl_cv_pcap_version_defined=yes],
653 [ac_lbl_cv_pcap_version_defined=no])
654 if test "$ac_lbl_cv_pcap_version_defined" = yes ; then
655 AC_MSG_RESULT(yes)
656 AC_DEFINE(HAVE_PCAP_VERSION, 1, [define if libpcap has pcap_version])
657 else
658 AC_MSG_RESULT(no)
659 fi
660 fi
661 AC_CHECK_FUNCS(pcap_setdirection pcap_set_immediate_mode pcap_dump_ftell64)
662 AC_CHECK_FUNCS(pcap_open pcap_findalldevs_ex)
663 AC_REPLACE_FUNCS(pcap_dump_ftell)
664
665 #
666 # Check for special debugging functions
667 #
668 AC_CHECK_FUNCS(pcap_set_parser_debug)
669 if test "$ac_cv_func_pcap_set_parser_debug" = "no" ; then
670 #
671 # OK, we don't have pcap_set_parser_debug() to set the libpcap
672 # filter expression parser debug flag; can we directly set the
673 # flag?
674 AC_MSG_CHECKING(whether pcap_debug is defined by libpcap)
675 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
676 extern int pcap_debug;
677
678 return pcap_debug;
679 ]])
680 ],
681 [ac_lbl_cv_pcap_debug_defined=yes],
682 [ac_lbl_cv_pcap_debug_defined=no])
683 if test "$ac_lbl_cv_pcap_debug_defined" = yes ; then
684 AC_MSG_RESULT(yes)
685 AC_DEFINE(HAVE_PCAP_DEBUG, 1, [define if libpcap has pcap_debug])
686 else
687 AC_MSG_RESULT(no)
688 #
689 # OK, what about "yydebug"?
690 #
691 AC_MSG_CHECKING(whether yydebug is defined by libpcap)
692 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
693 extern int yydebug;
694
695 return yydebug;
696 ]])
697 ],
698 [ac_lbl_cv_yydebug_defined=yes],
699 [ac_lbl_cv_yydebug_defined=no])
700 if test "$ac_lbl_cv_yydebug_defined" = yes ; then
701 AC_MSG_RESULT(yes)
702 AC_DEFINE(HAVE_YYDEBUG, 1, [define if libpcap has yydebug])
703 else
704 AC_MSG_RESULT(no)
705 fi
706 fi
707 fi
708 AC_CHECK_FUNCS(pcap_set_optimizer_debug)
709 AC_REPLACE_FUNCS(bpf_dump) dnl moved to libpcap in 0.6
710
711 #
712 # Assume V7/BSD convention for man pages (file formats in section 5,
713 # miscellaneous info in section 7).
714 #
715 MAN_FILE_FORMATS=5
716 MAN_MISC_INFO=7
717 case "$host_os" in
718
719 aix*)
720 dnl Workaround to enable certain features
721 AC_DEFINE(_SUN,1,[define on AIX to get certain functions])
722 ;;
723
724 hpux*)
725 #
726 # Use System V conventions for man pages.
727 #
728 MAN_FILE_FORMATS=4
729 MAN_MISC_INFO=5
730 ;;
731
732 solaris*)
733 #
734 # Use System V conventions for man pages.
735 #
736 MAN_FILE_FORMATS=4
737 MAN_MISC_INFO=5
738 ;;
739 esac
740
741 #
742 # Make sure we have a definition for C99's uintptr_t (regardless of
743 # whether the environment is a C99 environment or not).
744 #
745 AC_TYPE_UINTPTR_T
746
747 savedcppflags="$CPPFLAGS"
748 CPPFLAGS="$CPPFLAGS $V_INCLS"
749
750 #
751 # Check whether we have pcap/pcap-inttypes.h.
752 # If we do, we use that to get the C99 types defined.
753 #
754 AC_CHECK_HEADERS(pcap/pcap-inttypes.h)
755
756 #
757 # At compile time HAVE_PCAP_FINDALLDEVS depends on HAVE_PCAP_IF_T.
758 #
759 AC_CHECK_TYPES(pcap_if_t, , , [#include <pcap.h>])
760
761 CPPFLAGS="$savedcppflags"
762
763 #
764 # Define the old BSD specified-width types in terms of the C99 types;
765 # we may need them with libpcap include files.
766 #
767 AC_CHECK_TYPE([u_int8_t], ,
768 [AC_DEFINE([u_int8_t], [uint8_t],
769 [Define to `uint8_t' if u_int8_t not defined.])],
770 [AC_INCLUDES_DEFAULT
771 #include <sys/types.h>
772 ])
773 AC_CHECK_TYPE([u_int16_t], ,
774 [AC_DEFINE([u_int16_t], [uint16_t],
775 [Define to `uint16_t' if u_int16_t not defined.])],
776 [AC_INCLUDES_DEFAULT
777 #include <sys/types.h>
778 ])
779 AC_CHECK_TYPE([u_int32_t], ,
780 [AC_DEFINE([u_int32_t], [uint32_t],
781 [Define to `uint32_t' if u_int32_t not defined.])],
782 [AC_INCLUDES_DEFAULT
783 #include <sys/types.h>
784 ])
785 AC_CHECK_TYPE([u_int64_t], ,
786 [AC_DEFINE([u_int64_t], [uint64_t],
787 [Define to `uint64_t' if u_int64_t not defined.])],
788 [AC_INCLUDES_DEFAULT
789 #include <sys/types.h>
790 ])
791
792 AC_PROG_RANLIB
793 AC_CHECK_TOOL([AR], [ar])
794
795 AC_LBL_DEVEL(V_CCOPT)
796
797 # Check for OpenSSL/libressl libcrypto
798 AC_MSG_CHECKING(whether to use OpenSSL/libressl libcrypto)
799 # Specify location for both includes and libraries.
800 want_libcrypto=ifavailable
801 AC_ARG_WITH(crypto,
802 AS_HELP_STRING([--with-crypto]@<:@=DIR@:>@,
803 [use OpenSSL/libressl libcrypto (located in directory DIR, if specified) @<:@default=yes, if available@:>@]),
804 [
805 if test $withval = no
806 then
807 # User doesn't want to link with libcrypto.
808 want_libcrypto=no
809 AC_MSG_RESULT(no)
810 elif test $withval = yes
811 then
812 # User wants to link with libcrypto but hasn't specified
813 # a directory.
814 want_libcrypto=yes
815 AC_MSG_RESULT(yes)
816 else
817 # User wants to link with libcrypto and has specified
818 # a directory, so use the provided value.
819 want_libcrypto=yes
820 libcrypto_root=$withval
821 AC_MSG_RESULT([yes, using the version installed in $withval])
822
823 #
824 # Put the subdirectories of the libcrypto root directory
825 # at the front of the header and library search path.
826 #
827 CFLAGS="-I$withval/include $CFLAGS"
828 LIBS="-L$withval/lib $LIBS"
829 fi
830 ],[
831 #
832 # Use libcrypto if it's present, otherwise don't; no directory
833 # was specified.
834 #
835 want_libcrypto=ifavailable
836 AC_MSG_RESULT([yes, if available])
837 ])
838 if test "$want_libcrypto" != "no"; then
839 #
840 # Don't check for libcrypto unless we have its headers;
841 # Apple, bless their pointy little heads, apparently ship
842 # libcrypto as a library, but not the header files, in
843 # El Capitan, probably because they don't want you writing
844 # nasty portable code that could run on other UN*Xes, they
845 # want you writing code that uses their Shiny New Crypto
846 # Library and that only runs on macOS.
847 #
848 AC_CHECK_HEADER(openssl/crypto.h,
849 [
850 AC_CHECK_LIB(crypto, DES_cbc_encrypt)
851 if test "$ac_cv_lib_crypto_DES_cbc_encrypt" = "yes"; then
852 AC_CHECK_HEADERS(openssl/evp.h)
853 #
854 # OK, then:
855 #
856 # 1) do we have EVP_CIPHER_CTX_new?
857 # If so, we use it to allocate an
858 # EVP_CIPHER_CTX, as EVP_CIPHER_CTX may be
859 # opaque; otherwise, we allocate it ourselves.
860 #
861 # 2) do we have EVP_DecryptInit_ex()?
862 # If so, we use it, because we need to be
863 # able to make two "initialize the cipher"
864 # calls, one with the cipher and key, and
865 # one with the IV, and, as of OpenSSL 1.1,
866 # You Can't Do That with EVP_DecryptInit(),
867 # because a call to EVP_DecryptInit() will
868 # unconditionally clear the context, and
869 # if you don't supply a cipher, it'll
870 # clear the cipher, rendering the context
871 # unusable and causing a crash.
872 #
873 AC_CHECK_FUNCS(EVP_CIPHER_CTX_new EVP_DecryptInit_ex)
874 fi
875 ])
876 fi
877
878 # Check for libcap-ng
879 AC_MSG_CHECKING(whether to use libcap-ng)
880 # Specify location for both includes and libraries.
881 want_libcap_ng=ifavailable
882 AC_ARG_WITH(cap_ng,
883 AS_HELP_STRING([--with-cap-ng],
884 [use libcap-ng @<:@default=yes, if available@:>@]),
885 [
886 if test $withval = no
887 then
888 want_libcap_ng=no
889 AC_MSG_RESULT(no)
890 elif test $withval = yes
891 then
892 want_libcap_ng=yes
893 AC_MSG_RESULT(yes)
894 fi
895 ],[
896 #
897 # Use libcap-ng if it's present, otherwise don't.
898 #
899 want_libcap_ng=ifavailable
900 AC_MSG_RESULT([yes, if available])
901 ])
902 if test "$want_libcap_ng" != "no"; then
903 AC_CHECK_LIB(cap-ng, capng_change_id)
904 AC_CHECK_HEADERS(cap-ng.h)
905 fi
906
907 dnl
908 dnl set additional include path if necessary
909 if test "$missing_includes" = "yes"; then
910 CPPFLAGS="$CPPFLAGS -I$srcdir/missing"
911 V_INCLS="$V_INCLS -I$srcdir/missing"
912 fi
913
914 AC_SUBST(V_CCOPT)
915 AC_SUBST(V_DEFS)
916 AC_SUBST(V_INCLS)
917 AC_SUBST(V_PCAPDEP)
918 AC_SUBST(LOCALSRC)
919 AC_SUBST(MAN_FILE_FORMATS)
920 AC_SUBST(MAN_MISC_INFO)
921
922 AC_PROG_INSTALL
923
924 AC_CONFIG_HEADERS([config.h])
925
926 AC_CONFIG_COMMANDS([.devel],[[if test -f .devel; then
927 echo timestamp > stamp-h
928 cat $srcdir/Makefile-devel-adds >> Makefile
929 make depend || exit 1
930 fi]])
931 AC_CONFIG_FILES([Makefile tcpdump.1])
932 AC_OUTPUT
933 exit 0
[mirror] the TCPdump network dissector