The Tcpdump Group git mirrors - tcpdump/blob - configure.ac

   1 dnl Copyright (c) 1994, 1995, 1996, 1997
   2 dnl     The Regents of the University of California.  All rights reserved.
   3 dnl
   4 dnl Process this file with autoconf to produce a configure script.
   5 dnl
   6
   7 #
   8 # See
   9 #
  10 #       https://ftp.gnu.org/gnu/config/README
  11 #
  12 # for the URLs to use to fetch new versions of config.guess and
  13 # config.sub.
  14 #
  15
  16 AC_PREREQ([2.69])
  17 AC_INIT([tcpdump],[m4_esyscmd_s(cat VERSION)])
  18 AC_CONFIG_SRCDIR(tcpdump.c)
  19
  20 AC_CANONICAL_HOST
  21
  22 AC_LBL_C_INIT_BEFORE_CC(V_INCLS)
  23 #
  24 # Try to enable as many C99 features as we can.
  25 # At minimum, we want C++/C99-style // comments.
  26 #
  27 AC_PROG_CC_C99
  28 if test "$ac_cv_prog_cc_c99" = "no"; then
  29         AC_MSG_WARN([The C compiler does not support C99; there may be compiler errors])
  30 fi
  31 AC_LBL_C_INIT(V_CCOPT, V_INCLS)
  32 AC_C_INLINE
  33
  34 AC_CHECK_HEADERS(fcntl.h rpc/rpc.h rpc/rpcent.h net/if.h)
  35
  36 case "$host_os" in
  37
  38 darwin*)
  39         AC_ARG_ENABLE(universal,
  40         AS_HELP_STRING([--disable-universal],[don't build universal on macOS]))
  41         if test "$enable_universal" != "no"; then
  42                 case "$host_os" in
  43
  44                 darwin9.*)
  45                         #
  46                         # Leopard.  Build for x86 and 32-bit PowerPC, with
  47                         # x86 first.  (That's what Apple does.)
  48                         #
  49                         V_CCOPT="$V_CCOPT -arch i386 -arch ppc"
  50                         LDFLAGS="$LDFLAGS -arch i386 -arch ppc"
  51                         ;;
  52
  53                 darwin10.*)
  54                         #
  55                         # Snow Leopard.  Build for x86-64 and x86, with
  56                         # x86-64 first.  (That's what Apple does.)
  57                         #
  58                         V_CCOPT="$V_CCOPT -arch x86_64 -arch i386"
  59                         LDFLAGS="$LDFLAGS -arch x86_64 -arch i386"
  60                         ;;
  61                 esac
  62         fi
  63         ;;
  64 esac
  65
  66 AC_ARG_WITH([smi],
  67    [AS_HELP_STRING([--with-smi],
  68      [link with libsmi (allows to load MIBs on the fly to decode SNMP packets) [default=yes, if available]])],
  69    [],
  70    [with_smi=yes])
  71
  72 if test "x$with_smi" != "xno" ; then
  73         AC_CHECK_HEADER(smi.h,
  74         [
  75                 #
  76                 # OK, we found smi.h.  Do we have libsmi with smiInit?
  77                 #
  78                 AC_CHECK_LIB(smi, smiInit,
  79                 [
  80                         #
  81                         # OK, we have libsmi with smiInit.  Can we use it?
  82                         #
  83                         AC_MSG_CHECKING([whether to enable libsmi])
  84                         savedlibs="$LIBS"
  85                         LIBS="-lsmi $LIBS"
  86                         AC_RUN_IFELSE([AC_LANG_SOURCE([[
  87 /* libsmi available check */
  88 #include <stdio.h>
  89 #include <stdlib.h>
  90 #include <string.h>
  91 #include <smi.h>
  92 int main()
  93 {
  94   int current, revision, age, n;
  95   const int required = 2;
  96   if (smiInit(""))
  97     exit(1);
  98   if (strcmp(SMI_LIBRARY_VERSION, smi_library_version))
  99     exit(2);
 100   n = sscanf(smi_library_version, "%d:%d:%d", &current, &revision, &age);
 101   if (n != 3)
 102     exit(3);
 103   if (required < current - age || required > current)
 104     exit(4);
 105   exit(0);
 106 }
 107                                 ]])
 108                                 ],
 109                                 [
 110                                         AC_MSG_RESULT(yes)
 111                                         AC_DEFINE(USE_LIBSMI, 1,
 112                                             [Define if you enable support for libsmi])
 113                                 ],
 114                                 [
 115                                         dnl autoconf documentation says that
 116                                         dnl $? contains the exit value.
 117                                         dnl reality is that it does not.
 118                                         dnl We leave this in just in case
 119                                         dnl autoconf ever comes back to
 120                                         dnl match the documentation.
 121                                         case $? in
 122                                           1) AC_MSG_RESULT(no - smiInit failed) ;;
 123                                           2) AC_MSG_RESULT(no - header/library version mismatch) ;;
 124                                           3) AC_MSG_RESULT(no - can't determine library version) ;;
 125                                           4) AC_MSG_RESULT(no - too old) ;;
 126                                           *) AC_MSG_RESULT(no) ;;
 127                                         esac
 128                                         LIBS="$savedlibs"
 129                                 ],
 130                                 [
 131                                         AC_MSG_RESULT(not when cross-compiling)
 132                                         LIBS="$savedlibs"
 133                                 ]
 134                         )
 135                 ])
 136         ])
 137 fi
 138
 139 AC_MSG_CHECKING([whether to enable the instrument functions code])
 140 AC_ARG_ENABLE([instrument-functions],
 141    [AS_HELP_STRING([--enable-instrument-functions],
 142      [enable instrument functions code [default=no]])],
 143    [],
 144    [enableval=no])
 145 case "$enableval" in
 146 yes)    AC_MSG_RESULT(yes)
 147         AC_CHECK_LIB([bfd], [bfd_init],
 148             [true],
 149             [AC_MSG_ERROR(
 150                [--enable-instrument-functions was given, but test for library libbfd failed. Please install the 'binutils-dev' package.])],
 151             [])
 152         AC_DEFINE(ENABLE_INSTRUMENT_FUNCTIONS, 1,
 153             [define if you want to build the instrument functions code])
 154         LOCALSRC="$LOCALSRC instrument-functions.c"
 155         # Add '-finstrument-functions' instrumentation option to generate
 156         # instrumentation calls for entry and exit to functions.
 157         # Try to avoid Address Space Layout Randomization (ALSR).
 158         CFLAGS="$CFLAGS -O0 -ggdb -finstrument-functions -fno-stack-protector -fno-pic"
 159         LDFLAGS="$LDFLAGS -O0 -ggdb -fno-stack-protector -no-pie"
 160         LIBS="$LIBS -lbfd"
 161         ;;
 162 *)      AC_MSG_RESULT(no)
 163         ;;
 164 esac
 165
 166 AC_MSG_CHECKING([whether to enable the possibly-buggy SMB printer])
 167 AC_ARG_ENABLE([smb],
 168    [AS_HELP_STRING([--enable-smb],
 169      [enable possibly-buggy SMB printer [default=no]])],
 170    [],
 171    [enableval=no])
 172 case "$enableval" in
 173 yes)    AC_MSG_RESULT(yes)
 174         AC_DEFINE(ENABLE_SMB, 1,
 175             [define if you want to build the possibly-buggy SMB printer])
 176         LOCALSRC="print-smb.c smbutil.c $LOCALSRC"
 177         ;;
 178 *)      AC_MSG_RESULT(no)
 179         ;;
 180 esac
 181
 182 AC_ARG_WITH(user, [  --with-user=USERNAME    drop privileges by default to USERNAME])
 183 AC_MSG_CHECKING([whether to drop root privileges by default])
 184 if test ! -z "$withval" && test "$withval" != "no" ; then
 185        if test "$withval" = "yes" ; then
 186            AC_MSG_ERROR([--with-user requires a username])
 187        fi
 188        AC_DEFINE_UNQUOTED(WITH_USER, "$withval",
 189            [define if should drop privileges by default])
 190        AC_MSG_RESULT([yes, to user "$withval"])
 191 else
 192        AC_MSG_RESULT(no)
 193 fi
 194
 195 AC_ARG_WITH(chroot, [  --with-chroot=DIRECTORY when dropping privileges, chroot to DIRECTORY])
 196 AC_MSG_CHECKING([whether to chroot])
 197 if test ! -z "$withval" && test "$withval" != "no" ; then
 198        if test "$withval" = "yes" ; then
 199            AC_MSG_ERROR([--with-chroot requires a directory])
 200        fi
 201        AC_DEFINE_UNQUOTED(WITH_CHROOT, "$withval",
 202            [define if should chroot when dropping privileges])
 203        AC_MSG_RESULT([yes, to directory "$withval"])
 204 else
 205        AC_MSG_RESULT(no)
 206 fi
 207
 208 AC_ARG_WITH(sandbox-capsicum,
 209         AS_HELP_STRING([--with-sandbox-capsicum],
 210                        [use Capsicum security functions @<:@default=yes, if available@:>@]))
 211 #
 212 # Check whether various functions are available.  If any are, set
 213 # ac_lbl_capsicum_function_seen to yes; if any are not, set
 214 # ac_lbl_capsicum_function_not_seen to yes.
 215 #
 216 # We don't check cap_rights_init(), as it's a macro, wrapping another
 217 # function, in at least some versions of FreeBSD, and AC_CHECK_FUNCS()
 218 # doesn't handle that.
 219 #
 220 # All of the ones we check for must be available in order to enable
 221 # capsicum sandboxing.
 222 #
 223 # XXX - do we need to check for all of them, or are there some that, if
 224 # present, imply others are present?
 225 #
 226 if test -z "$with_sandbox_capsicum" || test "$with_sandbox_capsicum" != "no" ; then
 227         #
 228         # First, make sure we have the required header.
 229         #
 230         AC_CHECK_HEADER(sys/capsicum.h,
 231         [
 232                 #
 233                 # We do; now make sure we have the required functions.
 234                 #
 235                 AC_CHECK_FUNCS(cap_enter cap_rights_limit cap_ioctls_limit openat,
 236                     ac_lbl_capsicum_function_seen=yes,
 237                     ac_lbl_capsicum_function_not_seen=yes)
 238         ])
 239         AC_CHECK_LIB(casper, cap_init, LIBS="$LIBS -lcasper")
 240         AC_CHECK_LIB(cap_dns, cap_gethostbyaddr, LIBS="$LIBS -lcap_dns")
 241 fi
 242 AC_MSG_CHECKING([whether to sandbox using capsicum])
 243 if test "x$ac_lbl_capsicum_function_seen" = "xyes" -a "x$ac_lbl_capsicum_function_not_seen" != "xyes"; then
 244         AC_DEFINE(HAVE_CAPSICUM, 1, [capsicum support available])
 245         AC_MSG_RESULT(yes)
 246 else
 247         AC_MSG_RESULT(no)
 248 fi
 249 AC_MSG_CHECKING([whether to sandbox using Casper library])
 250 if test "x$ac_cv_lib_casper_cap_init" = "xyes" -a "x$ac_cv_lib_cap_dns_cap_gethostbyaddr" = "xyes"; then
 251         AC_DEFINE(HAVE_CASPER, 1, [Casper support available])
 252         AC_MSG_RESULT(yes)
 253 else
 254         AC_MSG_RESULT(no)
 255 fi
 256
 257 #
 258 # We must check this before checking whether to check the OS's IPv6,
 259 # support because, on some platforms (such as SunOS 5.x), the test
 260 # program requires the extra networking libraries.
 261 #
 262 AC_LBL_LIBRARY_NET
 263
 264 #
 265 # Check whether AF_INET6 and struct in6_addr are defined.
 266 # If they aren't both defined, we don't have sufficient OS
 267 # support for IPv6, so we don't look for IPv6 support libraries,
 268 # and we define AF_INET6 and struct in6_addr ourselves.
 269 #
 270 AC_MSG_CHECKING([whether the operating system supports IPv6])
 271 AC_COMPILE_IFELSE(
 272     [
 273       AC_LANG_SOURCE(
 274         [[
 275 #include <string.h>
 276 /* AF_INET6 available check */
 277 #include <sys/types.h>
 278 #ifdef _WIN32
 279 #include <ws2tcpip.h>
 280 #else
 281 #include <sys/socket.h>
 282 #include <netinet/in.h>
 283 #endif
 284 #ifdef AF_INET6
 285 void
 286 foo(struct in6_addr *addr)
 287 {
 288  memset(addr, 0, sizeof (struct in6_addr));
 289 }
 290 #else
 291 #error "AF_INET6 not defined"
 292 #endif
 293         ]])
 294     ],
 295     [
 296         AC_MSG_RESULT(yes)
 297         AC_DEFINE(HAVE_OS_IPV6_SUPPORT, 1,
 298             [define if the OS provides AF_INET6 and struct in6_addr])
 299         ipv6=yes
 300     ],
 301     [
 302         AC_MSG_RESULT(no)
 303         ipv6=no
 304     ]
 305 )
 306
 307 ipv6type=unknown
 308 ipv6lib=none
 309 ipv6trylibc=no
 310
 311 if test "$ipv6" = "yes"; then
 312         # Apparently, only on Linux by this point the configure script knows
 313         # what the C preprocessor and the extended regexp grep commands are.
 314         # On other OSes the first call to AC_EGREP_CPP() induces a search for
 315         # these tools, which prints three lines in the middle of the IPv6
 316         # detection message and distorts it.  Resolve these dependencies
 317         # beforehand to prevent that.
 318         AC_PROG_CPP
 319         AC_PROG_EGREP
 320
 321         AC_MSG_CHECKING([ipv6 stack type])
 322         for i in inria kame linux-glibc linux-libinet6 toshiba v6d zeta; do
 323                 case $i in
 324                 inria)
 325                         dnl http://www.kame.net/
 326                         AC_EGREP_CPP(yes,
 327 [#include <netinet/in.h>
 328 #ifdef IPV6_INRIA_VERSION
 329 yes
 330 #endif],
 331                                 [ipv6type=$i])
 332                         ;;
 333                 kame)
 334                         dnl http://www.kame.net/
 335                         AC_EGREP_CPP(yes,
 336 [#include <netinet/in.h>
 337 #ifdef __KAME__
 338 yes
 339 #endif],
 340                                 [ipv6type=$i;
 341                                 ipv6lib=inet6;
 342                                 ipv6libdir=/usr/local/v6/lib;
 343                                 ipv6trylibc=yes])
 344                         ;;
 345                 linux-glibc)
 346                         dnl http://www.v6.linux.or.jp/
 347                         AC_EGREP_CPP(yes,
 348 [#include <features.h>
 349 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 350 yes
 351 #endif],
 352                                 [ipv6type=$i])
 353                         ;;
 354                 linux-libinet6)
 355                         dnl http://www.v6.linux.or.jp/
 356                         dnl
 357                         dnl This also matches Solaris 8 and Tru64 UNIX 5.1,
 358                         dnl and possibly other versions of those OSes
 359                         dnl
 360                         if test -d /usr/inet6 -o -f /usr/include/netinet/ip6.h; then
 361                                 ipv6type=$i
 362                                 ipv6lib=inet6
 363                                 ipv6libdir=/usr/inet6/lib
 364                                 ipv6trylibc=yes;
 365                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 366                         fi
 367                         ;;
 368                 toshiba)
 369                         AC_EGREP_CPP(yes,
 370 [#include <sys/param.h>
 371 #ifdef _TOSHIBA_INET6
 372 yes
 373 #endif],
 374                                 [ipv6type=$i;
 375                                 ipv6lib=inet6;
 376                                 ipv6libdir=/usr/local/v6/lib])
 377                         ;;
 378                 v6d)
 379                         AC_EGREP_CPP(yes,
 380 [#include </usr/local/v6/include/sys/v6config.h>
 381 #ifdef __V6D__
 382 yes
 383 #endif],
 384                                 [ipv6type=$i;
 385                                 ipv6lib=v6;
 386                                 ipv6libdir=/usr/local/v6/lib;
 387                                 CFLAGS="-I/usr/local/v6/include $CFLAGS"])
 388                         ;;
 389                 zeta)
 390                         AC_EGREP_CPP(yes,
 391 [#include <sys/param.h>
 392 #ifdef _ZETA_MINAMI_INET6
 393 yes
 394 #endif],
 395                                 [ipv6type=$i;
 396                                 ipv6lib=inet6;
 397                                 ipv6libdir=/usr/local/v6/lib])
 398                         ;;
 399                 esac
 400                 if test "$ipv6type" != "unknown"; then
 401                         break
 402                 fi
 403         done
 404         AC_MSG_RESULT($ipv6type)
 405 fi
 406
 407 if test "$ipv6" = "yes" -a "$ipv6lib" != "none"; then
 408         if test -d $ipv6libdir -a -f $ipv6libdir/lib$ipv6lib.a; then
 409                 LIBS="-L$ipv6libdir -l$ipv6lib $LIBS"
 410                 echo "You have $ipv6lib library, using it"
 411         else
 412                 if test "$ipv6trylibc" = "yes"; then
 413                         echo "You do not have $ipv6lib library, using libc"
 414                 else
 415                         echo 'Fatal: no $ipv6lib library found.  cannot continue.'
 416                         echo "You need to fetch lib$ipv6lib.a from appropriate"
 417                         echo 'ipv6 kit and compile beforehand.'
 418                         exit 1
 419                 fi
 420         fi
 421 fi
 422
 423 AC_REPLACE_FUNCS(strlcat strlcpy strdup strsep getservent getopt_long)
 424 AC_CHECK_FUNCS(fork vfork)
 425 AC_CHECK_FUNCS(setlinebuf)
 426
 427 #
 428 # Make sure we have vsnprintf() and snprintf(); we require them.
 429 #
 430 AC_CHECK_FUNC(vsnprintf,,
 431     AC_MSG_ERROR([vsnprintf() is required but wasn't found]))
 432 AC_CHECK_FUNC(snprintf,,
 433     AC_MSG_ERROR([snprintf() is required but wasn't found]))
 434
 435 #
 436 # Define HAVE_NO_PRINTF_Z to make it possible to disable test cases that
 437 # depend on %zu.
 438 #
 439 AC_MSG_CHECKING([whether printf(3) supports the z length modifier])
 440 AC_RUN_IFELSE(
 441     [
 442         AC_LANG_SOURCE([[
 443 #include <stdio.h>
 444 #include <string.h>
 445
 446 int main()
 447 {
 448   char buf[100];
 449   snprintf(buf, sizeof(buf), "%zu", sizeof(buf));
 450   return strncmp(buf, "100", sizeof(buf)) ? 1 : 0;
 451 }
 452         ]])
 453     ],
 454     [
 455         AC_MSG_RESULT(yes)
 456     ],
 457     [
 458         AC_MSG_RESULT(no)
 459         AC_DEFINE(HAVE_NO_PRINTF_Z, 1,
 460             [Define to 1 if printf(3) does not support the z length modifier.])
 461     ],
 462     [
 463         AC_MSG_RESULT(not while cross-compiling)
 464     ]
 465 )
 466
 467 AC_CHECK_LIB(rpc, main)         dnl It's unclear why we might need -lrpc
 468
 469 dnl Some platforms may need -lnsl for getrpcbynumber.
 470 AC_SEARCH_LIBS(getrpcbynumber, nsl,
 471     AC_DEFINE(HAVE_GETRPCBYNUMBER, 1, [define if you have getrpcbynumber()]))
 472
 473 AC_LBL_LIBPCAP(V_PCAPDEP, V_INCLS)
 474
 475 #
 476 # Check for these after AC_LBL_LIBPCAP, so we link with the appropriate
 477 # libraries (e.g., "-lsocket -lnsl" on Solaris).
 478 #
 479 # You are in a twisty little maze of UN*Xes, all different.
 480 # Some might not have ether_ntohost().
 481 # Some might have it and declare it in <net/ethernet.h>.
 482 # Some might have it and declare it in <netinet/ether.h>
 483 # Some might have it and declare it in <sys/ethernet.h>.
 484 # Some might have it and declare it in <arpa/inet.h>.
 485 # Some might have it and declare it in <netinet/if_ether.h>.
 486 # Some might have it and not declare it in any header file.
 487 #
 488 # Before you is a C compiler.
 489 #
 490 AC_CHECK_FUNCS(ether_ntohost, [
 491     AC_CACHE_CHECK(for buggy ether_ntohost, ac_cv_buggy_ether_ntohost, [
 492         AC_RUN_IFELSE([AC_LANG_SOURCE([[
 493                 #include <netdb.h>
 494                 #include <netinet/ether.h>
 495                 #include <stdlib.h>
 496                 #include <sys/types.h>
 497                 #include <sys/param.h>
 498                 #include <sys/socket.h>
 499
 500                 int
 501                 main(int argc, char **argv)
 502                 {
 503                         u_char ea[6] = { 0xff, 0xff, 0xff, 0xff, 0xff };
 504                         char name[MAXHOSTNAMELEN];
 505
 506                         ether_ntohost(name, (struct ether_addr *)ea);
 507                         exit(0);
 508                 }
 509         ]])
 510         ], [ac_cv_buggy_ether_ntohost=no],
 511            [ac_cv_buggy_ether_ntohost=yes],
 512            [ac_cv_buggy_ether_ntohost="not while cross-compiling"])])
 513     if test "$ac_cv_buggy_ether_ntohost" = "no"; then
 514         AC_DEFINE(USE_ETHER_NTOHOST, 1,
 515             [define if you have ether_ntohost() and it works])
 516     fi
 517 ])
 518 if test "$ac_cv_func_ether_ntohost" = yes -a \
 519     "$ac_cv_buggy_ether_ntohost" = "no"; then
 520         #
 521         # OK, we have ether_ntohost().  Is it declared in <net/ethernet.h>?
 522         #
 523         # This test fails if we don't have <net/ethernet.h> or if we do
 524         # but it doesn't declare ether_ntohost().
 525         #
 526         AC_CHECK_DECL(ether_ntohost,
 527             [
 528                 AC_DEFINE(NET_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
 529                     [Define to 1 if net/ethernet.h declares `ether_ntohost'])
 530             ],,
 531             [
 532 #include <net/ethernet.h>
 533             ])
 534         #
 535         # Did that succeed?
 536         #
 537         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 538                 #
 539                 # No, how about <netinet/ether.h>, as on Linux?
 540                 #
 541                 # This test fails if we don't have <netinet/ether.h>
 542                 # or if we do but it doesn't declare ether_ntohost().
 543                 #
 544                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 545                 # treat the previous failure as a cached value and
 546                 # suppress the next test.
 547                 #
 548                 unset ac_cv_have_decl_ether_ntohost
 549                 AC_CHECK_DECL(ether_ntohost,
 550                     [
 551                         AC_DEFINE(NETINET_ETHER_H_DECLARES_ETHER_NTOHOST,,
 552                             [Define to 1 if netinet/ether.h declares `ether_ntohost'])
 553                     ],,
 554                     [
 555 #include <netinet/ether.h>
 556                     ])
 557         fi
 558         #
 559         # Did that succeed?
 560         #
 561         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 562                 #
 563                 # No, how about <sys/ethernet.h>, as on Solaris 10
 564                 # and later?
 565                 #
 566                 # This test fails if we don't have <sys/ethernet.h>
 567                 # or if we do but it doesn't declare ether_ntohost().
 568                 #
 569                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 570                 # treat the previous failure as a cached value and
 571                 # suppress the next test.
 572                 #
 573                 unset ac_cv_have_decl_ether_ntohost
 574                 AC_CHECK_DECL(ether_ntohost,
 575                     [
 576                         AC_DEFINE(SYS_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
 577                             [Define to 1 if sys/ethernet.h declares `ether_ntohost'])
 578                     ],,
 579                     [
 580 #include <sys/ethernet.h>
 581                     ])
 582         fi
 583         #
 584         # Did that succeed?
 585         #
 586         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 587                 #
 588                 # No, how about <arpa/inet.h>, as in AIX?
 589                 #
 590                 # This test fails if we don't have <arpa/inet.h>
 591                 # (if we have ether_ntohost(), we should have
 592                 # networking, and if we have networking, we should
 593                 # have <arpa/inet.h>) or if we do but it doesn't
 594                 # declare ether_ntohost().
 595                 #
 596                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 597                 # treat the previous failure as a cached value and
 598                 # suppress the next test.
 599                 #
 600                 unset ac_cv_have_decl_ether_ntohost
 601                 AC_CHECK_DECL(ether_ntohost,
 602                     [
 603                         AC_DEFINE(ARPA_INET_H_DECLARES_ETHER_NTOHOST,,
 604                             [Define to 1 if arpa/inet.h declares `ether_ntohost'])
 605                     ],,
 606                     [
 607 #include <arpa/inet.h>
 608                     ])
 609         fi
 610         #
 611         # Did that succeed?
 612         #
 613         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 614                 #
 615                 # No, how about <netinet/if_ether.h>?
 616                 # On some platforms, it requires <net/if.h> and
 617                 # <netinet/in.h>, and we always include it with
 618                 # both of them, so test it with both of them.
 619                 #
 620                 # This test fails if we don't have <netinet/if_ether.h>
 621                 # and the headers we include before it, or if we do but
 622                 # <netinet/if_ether.h> doesn't declare ether_hostton().
 623                 #
 624                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 625                 # treat the previous failure as a cached value and
 626                 # suppress the next test.
 627                 #
 628                 unset ac_cv_have_decl_ether_ntohost
 629                 AC_CHECK_DECL(ether_ntohost,
 630                     [
 631                         AC_DEFINE(NETINET_IF_ETHER_H_DECLARES_ETHER_NTOHOST,,
 632                             [Define to 1 if netinet/if_ether.h declares `ether_ntohost'])
 633                     ],,
 634                     [
 635 #include <sys/types.h>
 636 #include <sys/socket.h>
 637 #include <net/if.h>
 638 #include <netinet/in.h>
 639 #include <netinet/if_ether.h>
 640                     ])
 641         fi
 642         #
 643         # After all that, is ether_ntohost() declared?
 644         #
 645         if test "$ac_cv_have_decl_ether_ntohost" = yes; then
 646                 #
 647                 # Yes.
 648                 #
 649                 AC_DEFINE(HAVE_DECL_ETHER_NTOHOST, 1,
 650                     [Define to 1 if you have the declaration of `ether_ntohost'])
 651         else
 652                 #
 653                 # No, we'll have to declare it ourselves.
 654                 # Do we have "struct ether_addr" if we include
 655                 # <netinet/if_ether.h>?
 656                 #
 657                 AC_CHECK_TYPES(struct ether_addr,,,
 658                     [
 659                         #include <sys/types.h>
 660                         #include <sys/socket.h>
 661                         #include <net/if.h>
 662                         #include <netinet/in.h>
 663                         #include <netinet/if_ether.h>
 664                     ])
 665         fi
 666 fi
 667
 668 dnl
 669 dnl Check for "pcap_list_datalinks()" and use a substitute version if
 670 dnl it's not present.  If it is present, check for "pcap_free_datalinks()";
 671 dnl if it's not present, we don't replace it for now.  (We could do so
 672 dnl on UN*X, but not on Windows, where hilarity ensues if a program
 673 dnl built with one version of the MSVC support library tries to free
 674 dnl something allocated by a library built with another version of
 675 dnl the MSVC support library.)
 676 dnl
 677 AC_CHECK_FUNC(pcap_list_datalinks,
 678         [
 679             AC_DEFINE(HAVE_PCAP_LIST_DATALINKS, 1,
 680                 [define if libpcap has pcap_list_datalinks()])
 681             AC_CHECK_FUNCS(pcap_free_datalinks)
 682         ],
 683         [
 684             AC_LIBOBJ(datalinks)
 685         ])
 686
 687 dnl
 688 dnl Check for "pcap_datalink_name_to_val()", and use a substitute
 689 dnl version if it's not present.  If it is present, check for
 690 dnl "pcap_datalink_val_to_description()", and if we don't have it,
 691 dnl use a substitute version.
 692 dnl
 693 AC_CHECK_FUNC(pcap_datalink_name_to_val,
 694         [
 695             AC_DEFINE(HAVE_PCAP_DATALINK_NAME_TO_VAL, 1,
 696                 [define if libpcap has pcap_datalink_name_to_val()])
 697             AC_CHECK_FUNC(pcap_datalink_val_to_description,
 698                 AC_DEFINE(HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION, 1,
 699                     [define if libpcap has pcap_datalink_val_to_description()]),
 700                 [
 701                     AC_LIBOBJ(dlnames)
 702                 ])
 703         ],
 704         [
 705             AC_LIBOBJ(dlnames)
 706         ])
 707
 708 dnl
 709 dnl Check for "pcap_set_datalink()"; you can't substitute for it if
 710 dnl it's absent (it has hooks into libpcap), so just define the
 711 dnl HAVE_ value if it's there.
 712 dnl
 713 AC_CHECK_FUNCS(pcap_set_datalink)
 714
 715 dnl
 716 dnl Check for "pcap_breakloop()"; you can't substitute for it if
 717 dnl it's absent (it has hooks into the live capture routines),
 718 dnl so just define the HAVE_ value if it's there.
 719 dnl
 720 AC_CHECK_FUNCS(pcap_breakloop)
 721
 722 #
 723 # Do we have the new open API?  Check for pcap_create, and assume that,
 724 # if we do, we also have pcap_activate() and the other new routines
 725 # introduced in libpcap 1.0.0.
 726 #
 727 AC_CHECK_FUNCS(pcap_create)
 728 if test $ac_cv_func_pcap_create = "yes" ; then
 729         #
 730         # OK, do we have pcap_set_tstamp_type?  If so, assume we have
 731         # pcap_list_tstamp_types and pcap_free_tstamp_types as well.
 732         #
 733         AC_CHECK_FUNCS(pcap_set_tstamp_type)
 734         #
 735         # And do we have pcap_set_tstamp_precision?  If so, we assume
 736         # we also have pcap_open_offline_with_tstamp_precision.
 737         #
 738         AC_CHECK_FUNCS(pcap_set_tstamp_precision)
 739 fi
 740
 741 #
 742 # Check for a miscellaneous collection of functions which we use
 743 # if we have them.
 744 #
 745 AC_CHECK_FUNCS(pcap_findalldevs)
 746 if test $ac_cv_func_pcap_findalldevs = "yes" ; then
 747 dnl Check for libpcap having pcap_findalldevs() but the pcap.h header
 748 dnl not having pcap_if_t; some versions of Mac OS X shipped with pcap.h
 749 dnl from 0.6 and libpcap 0.8, so that libpcap had pcap_findalldevs but
 750 dnl pcap.h didn't have pcap_if_t.
 751     savedcppflags="$CPPFLAGS"
 752     CPPFLAGS="$CPPFLAGS $V_INCLS"
 753     AC_CHECK_TYPES(pcap_if_t, , , [#include <pcap.h>])
 754     CPPFLAGS="$savedcppflags"
 755 fi
 756 AC_CHECK_FUNCS(pcap_dump_flush pcap_lib_version)
 757 if test $ac_cv_func_pcap_lib_version = "no" ; then
 758     AC_MSG_CHECKING(whether pcap_version is defined by libpcap)
 759     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
 760         extern char pcap_version[];
 761
 762         return (int)pcap_version;
 763        ]])
 764        ],
 765        [ac_lbl_cv_pcap_version_defined=yes],
 766        [ac_lbl_cv_pcap_version_defined=no])
 767     if test "$ac_lbl_cv_pcap_version_defined" = yes ; then
 768         AC_MSG_RESULT(yes)
 769         AC_DEFINE(HAVE_PCAP_VERSION, 1, [define if libpcap has pcap_version])
 770     else
 771         AC_MSG_RESULT(no)
 772     fi
 773 fi
 774 AC_CHECK_FUNCS(pcap_setdirection pcap_set_immediate_mode pcap_dump_ftell64)
 775 AC_CHECK_FUNCS(pcap_open pcap_findalldevs_ex)
 776 AC_REPLACE_FUNCS(pcap_dump_ftell)
 777
 778 #
 779 # Check for special debugging functions
 780 #
 781 AC_CHECK_FUNCS(pcap_set_parser_debug)
 782 if test "$ac_cv_func_pcap_set_parser_debug" = "no" ; then
 783         #
 784         # OK, we don't have pcap_set_parser_debug() to set the libpcap
 785         # filter expression parser debug flag; can we directly set the
 786         # flag?
 787         AC_MSG_CHECKING(whether pcap_debug is defined by libpcap)
 788         AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
 789                 extern int pcap_debug;
 790
 791                 return pcap_debug;
 792            ]])
 793            ],
 794            [ac_lbl_cv_pcap_debug_defined=yes],
 795            [ac_lbl_cv_pcap_debug_defined=no])
 796         if test "$ac_lbl_cv_pcap_debug_defined" = yes ; then
 797                 AC_MSG_RESULT(yes)
 798                 AC_DEFINE(HAVE_PCAP_DEBUG, 1, [define if libpcap has pcap_debug])
 799         else
 800                 AC_MSG_RESULT(no)
 801                 #
 802                 # OK, what about "yydebug"?
 803                 #
 804                 AC_MSG_CHECKING(whether yydebug is defined by libpcap)
 805                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
 806                         extern int yydebug;
 807
 808                         return yydebug;
 809                    ]])
 810                    ],
 811                    [ac_lbl_cv_yydebug_defined=yes],
 812                    [ac_lbl_cv_yydebug_defined=no])
 813                 if test "$ac_lbl_cv_yydebug_defined" = yes ; then
 814                         AC_MSG_RESULT(yes)
 815                         AC_DEFINE(HAVE_YYDEBUG, 1, [define if libpcap has yydebug])
 816                 else
 817                         AC_MSG_RESULT(no)
 818                 fi
 819         fi
 820 fi
 821 AC_CHECK_FUNCS(pcap_set_optimizer_debug)
 822 AC_REPLACE_FUNCS(bpf_dump)      dnl moved to libpcap in 0.6
 823
 824 V_GROUP=0
 825 if test -f /etc/group -a ! -z "`grep '^wheel:' /etc/group`" ; then
 826         V_GROUP=wheel
 827 fi
 828 #
 829 # Assume V7/BSD convention for man pages (file formats in section 5,
 830 # miscellaneous info in section 7).
 831 #
 832 MAN_FILE_FORMATS=5
 833 MAN_MISC_INFO=7
 834 case "$host_os" in
 835
 836 aix*)
 837         dnl Workaround to enable certain features
 838         AC_DEFINE(_SUN,1,[define on AIX to get certain functions])
 839         ;;
 840
 841 hpux*)
 842         #
 843         # Use System V conventions for man pages.
 844         #
 845         MAN_FILE_FORMATS=4
 846         MAN_MISC_INFO=5
 847         ;;
 848
 849 irix*)
 850         V_GROUP=sys
 851
 852         #
 853         # Use System V conventions for man pages.
 854         #
 855         MAN_FILE_FORMATS=4
 856         MAN_MISC_INFO=5
 857         ;;
 858
 859 osf*)
 860         V_GROUP=system
 861
 862         #
 863         # Use System V conventions for man pages.
 864         #
 865         MAN_FILE_FORMATS=4
 866         MAN_MISC_INFO=5
 867         ;;
 868
 869 solaris*)
 870         V_GROUP=sys
 871
 872         #
 873         # Use System V conventions for man pages.
 874         #
 875         MAN_FILE_FORMATS=4
 876         MAN_MISC_INFO=5
 877         ;;
 878 esac
 879
 880 if test -f /dev/bpf0 ; then
 881         V_GROUP=bpf
 882 fi
 883
 884 #
 885 # Make sure we have a definition for C99's uintptr_t (regardless of
 886 # whether the environment is a C99 environment or not).
 887 #
 888 AC_TYPE_UINTPTR_T
 889
 890 #
 891 # Check whether we have pcap/pcap-inttypes.h.
 892 # If we do, we use that to get the C99 types defined.
 893 #
 894 savedcppflags="$CPPFLAGS"
 895 CPPFLAGS="$CPPFLAGS $V_INCLS"
 896 AC_CHECK_HEADERS(pcap/pcap-inttypes.h)
 897 CPPFLAGS="$savedcppflags"
 898
 899 #
 900 # Define the old BSD specified-width types in terms of the C99 types;
 901 # we may need them with libpcap include files.
 902 #
 903 AC_CHECK_TYPE([u_int8_t], ,
 904         [AC_DEFINE([u_int8_t], [uint8_t],
 905         [Define to `uint8_t' if u_int8_t not defined.])],
 906         [AC_INCLUDES_DEFAULT
 907 #include <sys/types.h>
 908 ])
 909 AC_CHECK_TYPE([u_int16_t], ,
 910         [AC_DEFINE([u_int16_t], [uint16_t],
 911         [Define to `uint16_t' if u_int16_t not defined.])],
 912         [AC_INCLUDES_DEFAULT
 913 #include <sys/types.h>
 914 ])
 915 AC_CHECK_TYPE([u_int32_t], ,
 916         [AC_DEFINE([u_int32_t], [uint32_t],
 917         [Define to `uint32_t' if u_int32_t not defined.])],
 918         [AC_INCLUDES_DEFAULT
 919 #include <sys/types.h>
 920 ])
 921 AC_CHECK_TYPE([u_int64_t], ,
 922         [AC_DEFINE([u_int64_t], [uint64_t],
 923         [Define to `uint64_t' if u_int64_t not defined.])],
 924         [AC_INCLUDES_DEFAULT
 925 #include <sys/types.h>
 926 ])
 927
 928 AC_PROG_RANLIB
 929 AC_CHECK_TOOL([AR], [ar])
 930
 931 AC_LBL_DEVEL(V_CCOPT)
 932
 933 # Check for OpenSSL/libressl libcrypto
 934 AC_MSG_CHECKING(whether to use OpenSSL/libressl libcrypto)
 935 # Specify location for both includes and libraries.
 936 want_libcrypto=ifavailable
 937 AC_ARG_WITH(crypto,
 938     AS_HELP_STRING([--with-crypto]@<:@=DIR@:>@,
 939                    [use OpenSSL/libressl libcrypto (located in directory DIR, if specified) @<:@default=yes, if available@:>@]),
 940 [
 941         if test $withval = no
 942         then
 943                 # User doesn't want to link with libcrypto.
 944                 want_libcrypto=no
 945                 AC_MSG_RESULT(no)
 946         elif test $withval = yes
 947         then
 948                 # User wants to link with libcrypto but hasn't specified
 949                 # a directory.
 950                 want_libcrypto=yes
 951                 AC_MSG_RESULT(yes)
 952         else
 953                 # User wants to link with libcrypto and has specified
 954                 # a directory, so use the provided value.
 955                 want_libcrypto=yes
 956                 libcrypto_root=$withval
 957                 AC_MSG_RESULT([yes, using the version installed in $withval])
 958
 959                 #
 960                 # Put the subdirectories of the libcrypto root directory
 961                 # at the front of the header and library search path.
 962                 #
 963                 CFLAGS="-I$withval/include $CFLAGS"
 964                 LIBS="-L$withval/lib $LIBS"
 965         fi
 966 ],[
 967         #
 968         # Use libcrypto if it's present, otherwise don't; no directory
 969         # was specified.
 970         #
 971         want_libcrypto=ifavailable
 972         AC_MSG_RESULT([yes, if available])
 973 ])
 974 if test "$want_libcrypto" != "no"; then
 975         #
 976         # Don't check for libcrypto unless we have its headers;
 977         # Apple, bless their pointy little heads, apparently ship
 978         # libcrypto as a library, but not the header files, in
 979         # El Capitan, probably because they don't want you writing
 980         # nasty portable code that could run on other UN*Xes, they
 981         # want you writing code that uses their Shiny New Crypto
 982         # Library and that only runs on macOS.
 983         #
 984         AC_CHECK_HEADER(openssl/crypto.h,
 985         [
 986                 AC_CHECK_LIB(crypto, DES_cbc_encrypt)
 987                 if test "$ac_cv_lib_crypto_DES_cbc_encrypt" = "yes"; then
 988                         AC_CHECK_HEADERS(openssl/evp.h)
 989                         #
 990                         # OK, then:
 991                         #
 992                         # 1) do we have EVP_CIPHER_CTX_new?
 993                         # If so, we use it to allocate an
 994                         # EVP_CIPHER_CTX, as EVP_CIPHER_CTX may be
 995                         # opaque; otherwise, we allocate it ourselves.
 996                         #
 997                         # 2) do we have EVP_DecryptInit_ex()?
 998                         # If so, we use it, because we need to be
 999                         # able to make two "initialize the cipher"
1000                         # calls, one with the cipher and key, and
1001                         # one with the IV, and, as of OpenSSL 1.1,
1002                         # You Can't Do That with EVP_DecryptInit(),
1003                         # because a call to EVP_DecryptInit() will
1004                         # unconditionally clear the context, and
1005                         # if you don't supply a cipher, it'll
1006                         # clear the cipher, rendering the context
1007                         # unusable and causing a crash.
1008                         #
1009                         AC_CHECK_FUNCS(EVP_CIPHER_CTX_new EVP_DecryptInit_ex)
1010                 fi
1011         ])
1012 fi
1013
1014 # Check for libcap-ng
1015 AC_MSG_CHECKING(whether to use libcap-ng)
1016 # Specify location for both includes and libraries.
1017 want_libcap_ng=ifavailable
1018 AC_ARG_WITH(cap_ng,
1019     AS_HELP_STRING([--with-cap-ng],
1020                    [use libcap-ng @<:@default=yes, if available@:>@]),
1021 [
1022         if test $withval = no
1023         then
1024                 want_libcap_ng=no
1025                 AC_MSG_RESULT(no)
1026         elif test $withval = yes
1027         then
1028                 want_libcap_ng=yes
1029                 AC_MSG_RESULT(yes)
1030         fi
1031 ],[
1032         #
1033         # Use libcap-ng if it's present, otherwise don't.
1034         #
1035         want_libcap_ng=ifavailable
1036         AC_MSG_RESULT([yes, if available])
1037 ])
1038 if test "$want_libcap_ng" != "no"; then
1039         AC_CHECK_LIB(cap-ng, capng_change_id)
1040         AC_CHECK_HEADERS(cap-ng.h)
1041 fi
1042
1043 dnl
1044 dnl set additional include path if necessary
1045 if test "$missing_includes" = "yes"; then
1046         CPPFLAGS="$CPPFLAGS -I$srcdir/missing"
1047         V_INCLS="$V_INCLS -I$srcdir/missing"
1048 fi
1049
1050 AC_SUBST(V_CCOPT)
1051 AC_SUBST(V_DEFS)
1052 AC_SUBST(V_GROUP)
1053 AC_SUBST(V_INCLS)
1054 AC_SUBST(V_PCAPDEP)
1055 AC_SUBST(LOCALSRC)
1056 AC_SUBST(MAN_FILE_FORMATS)
1057 AC_SUBST(MAN_MISC_INFO)
1058
1059 AC_PROG_INSTALL
1060
1061 AC_CONFIG_HEADERS([config.h])
1062
1063 AC_CONFIG_COMMANDS([.devel],[[if test -f .devel; then
1064         echo timestamp > stamp-h
1065         cat $srcdir/Makefile-devel-adds >> Makefile
1066         make depend || exit 1
1067 fi]])
1068 AC_CONFIG_FILES([Makefile tcpdump.1])
1069 AC_OUTPUT
1070 exit 0