The Tcpdump Group git mirrors - tcpdump/blob - configure.ac

   1 dnl Copyright (c) 1994, 1995, 1996, 1997
   2 dnl     The Regents of the University of California.  All rights reserved.
   3 dnl
   4 dnl Process this file with autoconf to produce a configure script.
   5 dnl
   6
   7 #
   8 # See
   9 #
  10 #       https://ftp.gnu.org/gnu/config/README
  11 #
  12 # for the URLs to use to fetch new versions of config.guess and
  13 # config.sub.
  14 #
  15
  16 AC_PREREQ(2.64)
  17 AC_INIT(tcpdump, m4_esyscmd_s([cat VERSION]))
  18 AC_CONFIG_SRCDIR(tcpdump.c)
  19
  20 AC_CANONICAL_HOST
  21
  22 AC_LBL_C_INIT_BEFORE_CC(V_INCLS)
  23 #
  24 # Try to enable as many C99 features as we can.
  25 # At minimum, we want C++/C99-style // comments.
  26 #
  27 AC_PROG_CC_C99
  28 if test "$ac_cv_prog_cc_c99" = "no"; then
  29         AC_MSG_WARN([The C compiler does not support C99; there may be compiler errors])
  30 fi
  31 AC_LBL_C_INIT(V_CCOPT, V_INCLS)
  32 AC_LBL_C_INLINE
  33
  34 AC_CHECK_HEADERS(fcntl.h rpc/rpc.h rpc/rpcent.h net/if.h)
  35 AC_CHECK_HEADERS(net/pfvar.h, , , [#include <sys/types.h>
  36 #include <sys/socket.h>
  37 #include <net/if.h>])
  38 if test "$ac_cv_header_net_pfvar_h" = yes; then
  39         AC_CHECK_HEADERS(net/if_pflog.h, , , [#include <sys/types.h>
  40         #include <sys/socket.h>
  41         #include <net/if.h>
  42         #include <net/pfvar.h>])
  43         if test "$ac_cv_header_net_if_pflog_h" = yes; then
  44                 LOCALSRC="print-pflog.c $LOCALSRC"
  45         fi
  46 fi
  47
  48 case "$host_os" in
  49
  50 darwin*)
  51         AC_ARG_ENABLE(universal,
  52         AS_HELP_STRING([--disable-universal],[don't build universal on macOS]))
  53         if test "$enable_universal" != "no"; then
  54                 case "$host_os" in
  55
  56                 darwin9.*)
  57                         #
  58                         # Leopard.  Build for x86 and 32-bit PowerPC, with
  59                         # x86 first.  (That's what Apple does.)
  60                         #
  61                         V_CCOPT="$V_CCOPT -arch i386 -arch ppc"
  62                         LDFLAGS="$LDFLAGS -arch i386 -arch ppc"
  63                         ;;
  64
  65                 darwin10.*)
  66                         #
  67                         # Snow Leopard.  Build for x86-64 and x86, with
  68                         # x86-64 first.  (That's what Apple does.)
  69                         #
  70                         V_CCOPT="$V_CCOPT -arch x86_64 -arch i386"
  71                         LDFLAGS="$LDFLAGS -arch x86_64 -arch i386"
  72                         ;;
  73                 esac
  74         fi
  75         ;;
  76 esac
  77
  78
  79 AC_ARG_WITH([smi],
  80    [AS_HELP_STRING([--with-smi],
  81      [link with libsmi (allows to load MIBs on the fly to decode SNMP packets) [default=yes, if available]])],
  82    [],
  83    [with_smi=yes])
  84
  85 if test "x$with_smi" != "xno" ; then
  86         AC_CHECK_HEADER(smi.h,
  87         [
  88                 #
  89                 # OK, we found smi.h.  Do we have libsmi with smiInit?
  90                 #
  91                 AC_CHECK_LIB(smi, smiInit,
  92                 [
  93                         #
  94                         # OK, we have libsmi with smiInit.  Can we use it?
  95                         #
  96                         AC_MSG_CHECKING([whether to enable libsmi])
  97                         savedlibs="$LIBS"
  98                         LIBS="-lsmi $LIBS"
  99                         AC_TRY_RUN(
 100                                 [
 101 /* libsmi available check */
 102 #include <smi.h>
 103 main()
 104 {
 105   int current, revision, age, n;
 106   const int required = 2;
 107   if (smiInit(""))
 108     exit(1);
 109   if (strcmp(SMI_LIBRARY_VERSION, smi_library_version))
 110     exit(2);
 111   n = sscanf(smi_library_version, "%d:%d:%d", &current, &revision, &age);
 112   if (n != 3)
 113     exit(3);
 114   if (required < current - age || required > current)
 115     exit(4);
 116   exit(0);
 117 }
 118                                 ],
 119                                 [
 120                                         AC_MSG_RESULT(yes)
 121                                         AC_DEFINE(USE_LIBSMI, 1,
 122                                             [Define if you enable support for libsmi])
 123                                 ],
 124                                 [
 125                                         dnl autoconf documentation says that
 126                                         dnl $? contains the exit value.
 127                                         dnl reality is that it does not.
 128                                         dnl We leave this in just in case
 129                                         dnl autoconf ever comes back to
 130                                         dnl match the documentation.
 131                                         case $? in
 132                                           1) AC_MSG_RESULT(no - smiInit failed) ;;
 133                                           2) AC_MSG_RESULT(no - header/library version mismatch) ;;
 134                                           3) AC_MSG_RESULT(no - can't determine library version) ;;
 135                                           4) AC_MSG_RESULT(no - too old) ;;
 136                                           *) AC_MSG_RESULT(no) ;;
 137                                         esac
 138                                         LIBS="$savedlibs"
 139                                 ],
 140                                 [
 141                                         AC_MSG_RESULT(not when cross-compiling)
 142                                         LIBS="$savedlibs"
 143                                 ]
 144                         )
 145                 ])
 146         ])
 147 fi
 148
 149 AC_MSG_CHECKING([whether to enable the instrument functions code])
 150 AC_ARG_ENABLE([instrument-functions],
 151    [AS_HELP_STRING([--enable-instrument-functions],
 152      [enable instrument functions code [default=no]])],
 153    [],
 154    [enableval=no])
 155 case "$enableval" in
 156 yes)    AC_MSG_RESULT(yes)
 157         AC_DEFINE(ENABLE_INSTRUMENT_FUNCTIONS, 1,
 158             [define if you want to build the instrument functions code])
 159         LOCALSRC="$LOCALSRC instrument-functions.c"
 160         # Add '-finstrument-functions' instrumentation option to generate
 161         # instrumentation calls for entry and exit to functions.
 162         # Try to avoid Address Space Layout Randomization (ALSR).
 163         CFLAGS="$CFLAGS -finstrument-functions -fno-stack-protector -fno-pic"
 164         LDFLAGS="$LDFLAGS -fno-stack-protector -no-pie"
 165         ;;
 166 *)      AC_MSG_RESULT(no)
 167         ;;
 168 esac
 169
 170 AC_MSG_CHECKING([whether to enable the possibly-buggy SMB printer])
 171 AC_ARG_ENABLE([smb],
 172    [AS_HELP_STRING([--enable-smb],
 173      [enable possibly-buggy SMB printer [default=no]])],
 174    [],
 175    [enableval=no])
 176 case "$enableval" in
 177 yes)    AC_MSG_RESULT(yes)
 178         AC_DEFINE(ENABLE_SMB, 1,
 179             [define if you want to build the possibly-buggy SMB printer])
 180         LOCALSRC="print-smb.c smbutil.c $LOCALSRC"
 181         ;;
 182 *)      AC_MSG_RESULT(no)
 183         ;;
 184 esac
 185
 186 AC_ARG_WITH(user, [  --with-user=USERNAME    drop privileges by default to USERNAME])
 187 AC_MSG_CHECKING([whether to drop root privileges by default])
 188 if test ! -z "$with_user" ; then
 189        AC_DEFINE_UNQUOTED(WITH_USER, "$withval",
 190            [define if should drop privileges by default])
 191        AC_MSG_RESULT(to \"$withval\")
 192 else
 193        AC_MSG_RESULT(no)
 194 fi
 195
 196 AC_ARG_WITH(chroot, [  --with-chroot=DIRECTORY when dropping privileges, chroot to DIRECTORY])
 197 AC_MSG_CHECKING([whether to chroot])
 198 if test ! -z "$with_chroot" && test "$with_chroot" != "no" ; then
 199        AC_DEFINE_UNQUOTED(WITH_CHROOT, "$withval",
 200            [define if should chroot when dropping privileges])
 201        AC_MSG_RESULT(to \"$withval\")
 202 else
 203        AC_MSG_RESULT(no)
 204 fi
 205
 206 AC_ARG_WITH(sandbox-capsicum,
 207         AS_HELP_STRING([--with-sandbox-capsicum],
 208                        [use Capsicum security functions @<:@default=yes, if available@:>@]))
 209 #
 210 # Check whether various functions are available.  If any are, set
 211 # ac_lbl_capsicum_function_seen to yes; if any are not, set
 212 # ac_lbl_capsicum_function_not_seen to yes.
 213 #
 214 # We don't check cap_rights_init(), as it's a macro, wrapping another
 215 # function, in at least some versions of FreeBSD, and AC_CHECK_FUNCS()
 216 # doesn't handle that.
 217 #
 218 # All of the ones we check for must be available in order to enable
 219 # capsicum sandboxing.
 220 #
 221 # XXX - do we need to check for all of them, or are there some that, if
 222 # present, imply others are present?
 223 #
 224 if test -z "$with_sandbox_capsicum" || test "$with_sandbox_capsicum" != "no" ; then
 225         #
 226         # First, make sure we have the required header.
 227         #
 228         AC_CHECK_HEADER(sys/capsicum.h,
 229         [
 230                 #
 231                 # We do; now make sure we have the required functions.
 232                 #
 233                 AC_CHECK_FUNCS(cap_enter cap_rights_limit cap_ioctls_limit openat,
 234                     ac_lbl_capsicum_function_seen=yes,
 235                     ac_lbl_capsicum_function_not_seen=yes)
 236         ])
 237         AC_CHECK_LIB(casper, cap_init, LIBS="$LIBS -lcasper")
 238         AC_CHECK_LIB(cap_dns, cap_gethostbyaddr, LIBS="$LIBS -lcap_dns")
 239 fi
 240 AC_MSG_CHECKING([whether to sandbox using capsicum])
 241 if test "x$ac_lbl_capsicum_function_seen" = "xyes" -a "x$ac_lbl_capsicum_function_not_seen" != "xyes"; then
 242         AC_DEFINE(HAVE_CAPSICUM, 1, [capsicum support available])
 243         AC_MSG_RESULT(yes)
 244 else
 245         AC_MSG_RESULT(no)
 246 fi
 247 AC_MSG_CHECKING([whether to sandbox using Casper library])
 248 if test "x$ac_cv_lib_casper_cap_init" = "xyes" -a "x$ac_cv_lib_cap_dns_cap_gethostbyaddr" = "xyes"; then
 249         AC_DEFINE(HAVE_CASPER, 1, [Casper support available])
 250         AC_MSG_RESULT(yes)
 251 else
 252         AC_MSG_RESULT(no)
 253 fi
 254
 255 #
 256 # We must check this before checking whether to check the OS's IPv6,
 257 # support because, on some platforms (such as SunOS 5.x), the test
 258 # program requires the extra networking libraries.
 259 #
 260 AC_LBL_LIBRARY_NET
 261
 262 #
 263 # Check whether AF_INET6 and struct in6_addr are defined.
 264 # If they aren't both defined, we don't have sufficient OS
 265 # support for IPv6, so we don't look for IPv6 support libraries,
 266 # and we define AF_INET6 and struct in6_addr ourselves.
 267 #
 268 AC_MSG_CHECKING([whether the operating system supports IPv6])
 269 AC_COMPILE_IFELSE(
 270     [
 271       AC_LANG_SOURCE(
 272         [[
 273 /* AF_INET6 available check */
 274 #include <sys/types.h>
 275 #ifdef _WIN32
 276 #include <ws2tcpip.h>
 277 #else
 278 #include <sys/socket.h>
 279 #include <netinet/in.h>
 280 #endif
 281 #ifdef AF_INET6
 282 void
 283 foo(struct in6_addr *addr)
 284 {
 285  memset(addr, 0, sizeof (struct in6_addr));
 286 }
 287 #else
 288 #error "AF_INET6 not defined"
 289 #endif
 290         ]])
 291     ],
 292     [
 293         AC_MSG_RESULT(yes)
 294         AC_DEFINE(HAVE_OS_IPV6_SUPPORT, 1,
 295             [define if the OS provides AF_INET6 and struct in6_addr])
 296         ipv6=yes
 297     ],
 298     [
 299         AC_MSG_RESULT(no)
 300         ipv6=no
 301     ]
 302 )
 303
 304 ipv6type=unknown
 305 ipv6lib=none
 306 ipv6trylibc=no
 307
 308 if test "$ipv6" = "yes"; then
 309         AC_MSG_CHECKING([ipv6 stack type])
 310         for i in inria kame linux-glibc linux-libinet6 toshiba v6d zeta; do
 311                 case $i in
 312                 inria)
 313                         dnl http://www.kame.net/
 314                         AC_EGREP_CPP(yes,
 315 [#include <netinet/in.h>
 316 #ifdef IPV6_INRIA_VERSION
 317 yes
 318 #endif],
 319                                 [ipv6type=$i])
 320                         ;;
 321                 kame)
 322                         dnl http://www.kame.net/
 323                         AC_EGREP_CPP(yes,
 324 [#include <netinet/in.h>
 325 #ifdef __KAME__
 326 yes
 327 #endif],
 328                                 [ipv6type=$i;
 329                                 ipv6lib=inet6;
 330                                 ipv6libdir=/usr/local/v6/lib;
 331                                 ipv6trylibc=yes])
 332                         ;;
 333                 linux-glibc)
 334                         dnl http://www.v6.linux.or.jp/
 335                         AC_EGREP_CPP(yes,
 336 [#include <features.h>
 337 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 338 yes
 339 #endif],
 340                                 [ipv6type=$i])
 341                         ;;
 342                 linux-libinet6)
 343                         dnl http://www.v6.linux.or.jp/
 344                         dnl
 345                         dnl This also matches Solaris 8 and Tru64 UNIX 5.1,
 346                         dnl and possibly other versions of those OSes
 347                         dnl
 348                         if test -d /usr/inet6 -o -f /usr/include/netinet/ip6.h; then
 349                                 ipv6type=$i
 350                                 ipv6lib=inet6
 351                                 ipv6libdir=/usr/inet6/lib
 352                                 ipv6trylibc=yes;
 353                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 354                         fi
 355                         ;;
 356                 toshiba)
 357                         AC_EGREP_CPP(yes,
 358 [#include <sys/param.h>
 359 #ifdef _TOSHIBA_INET6
 360 yes
 361 #endif],
 362                                 [ipv6type=$i;
 363                                 ipv6lib=inet6;
 364                                 ipv6libdir=/usr/local/v6/lib])
 365                         ;;
 366                 v6d)
 367                         AC_EGREP_CPP(yes,
 368 [#include </usr/local/v6/include/sys/v6config.h>
 369 #ifdef __V6D__
 370 yes
 371 #endif],
 372                                 [ipv6type=$i;
 373                                 ipv6lib=v6;
 374                                 ipv6libdir=/usr/local/v6/lib;
 375                                 CFLAGS="-I/usr/local/v6/include $CFLAGS"])
 376                         ;;
 377                 zeta)
 378                         AC_EGREP_CPP(yes,
 379 [#include <sys/param.h>
 380 #ifdef _ZETA_MINAMI_INET6
 381 yes
 382 #endif],
 383                                 [ipv6type=$i;
 384                                 ipv6lib=inet6;
 385                                 ipv6libdir=/usr/local/v6/lib])
 386                         ;;
 387                 esac
 388                 if test "$ipv6type" != "unknown"; then
 389                         break
 390                 fi
 391         done
 392         AC_MSG_RESULT($ipv6type)
 393 fi
 394
 395 if test "$ipv6" = "yes" -a "$ipv6lib" != "none"; then
 396         if test -d $ipv6libdir -a -f $ipv6libdir/lib$ipv6lib.a; then
 397                 LIBS="-L$ipv6libdir -l$ipv6lib $LIBS"
 398                 echo "You have $ipv6lib library, using it"
 399         else
 400                 if test "$ipv6trylibc" = "yes"; then
 401                         echo "You do not have $ipv6lib library, using libc"
 402                 else
 403                         echo 'Fatal: no $ipv6lib library found.  cannot continue.'
 404                         echo "You need to fetch lib$ipv6lib.a from appropriate"
 405                         echo 'ipv6 kit and compile beforehand.'
 406                         exit 1
 407                 fi
 408         fi
 409 fi
 410
 411 AC_REPLACE_FUNCS(strlcat strlcpy strdup strsep getservent getopt_long)
 412 AC_CHECK_FUNCS(fork vfork strftime)
 413 AC_CHECK_FUNCS(setlinebuf)
 414
 415 #
 416 # Make sure we have vsnprintf() and snprintf(); we require them.
 417 #
 418 AC_CHECK_FUNC(vsnprintf,,
 419     AC_MSG_ERROR([vsnprintf() is required but wasn't found]))
 420 AC_CHECK_FUNC(snprintf,,
 421     AC_MSG_ERROR([snprintf() is required but wasn't found]))
 422
 423 #
 424 # Define HAVE_NO_PRINTF_Z to make it possible to disable test cases that
 425 # depend on %zu.
 426 #
 427 AC_MSG_CHECKING([whether printf(3) supports the z length modifier])
 428 AC_RUN_IFELSE(
 429     [
 430         AC_LANG_SOURCE([[
 431 #include <stdio.h>
 432 #include <string.h>
 433
 434 int main()
 435 {
 436   char buf[100];
 437   snprintf(buf, sizeof(buf), "%zu", sizeof(buf));
 438   return strncmp(buf, "100", sizeof(buf)) ? 1 : 0;
 439 }
 440         ]])
 441     ],
 442     [
 443         AC_MSG_RESULT(yes)
 444     ],
 445     [
 446         AC_MSG_RESULT(no)
 447         AC_DEFINE(HAVE_NO_PRINTF_Z, 1,
 448             [Define to 1 if printf(3) does not support the z length modifier.])
 449     ],
 450     [
 451         AC_MSG_RESULT(not while cross-compiling)
 452     ]
 453 )
 454
 455 AC_CHECK_LIB(rpc, main)         dnl It's unclear why we might need -lrpc
 456
 457 dnl Some platforms may need -lnsl for getrpcbynumber.
 458 AC_SEARCH_LIBS(getrpcbynumber, nsl,
 459     AC_DEFINE(HAVE_GETRPCBYNUMBER, 1, [define if you have getrpcbynumber()]))
 460
 461 AC_LBL_LIBPCAP(V_PCAPDEP, V_INCLS)
 462
 463 #
 464 # Check for these after AC_LBL_LIBPCAP, so we link with the appropriate
 465 # libraries (e.g., "-lsocket -lnsl" on Solaris).
 466 #
 467 # You are in a twisty little maze of UN*Xes, all different.
 468 # Some might not have ether_ntohost().
 469 # Some might have it and declare it in <net/ethernet.h>.
 470 # Some might have it and declare it in <netinet/ether.h>
 471 # Some might have it and declare it in <sys/ethernet.h>.
 472 # Some might have it and declare it in <arpa/inet.h>.
 473 # Some might have it and declare it in <netinet/if_ether.h>.
 474 # Some might have it and not declare it in any header file.
 475 #
 476 # Before you is a C compiler.
 477 #
 478 AC_CHECK_FUNCS(ether_ntohost, [
 479     AC_CACHE_CHECK(for buggy ether_ntohost, ac_cv_buggy_ether_ntohost, [
 480         AC_TRY_RUN([
 481                 #include <netdb.h>
 482                 #include <sys/types.h>
 483                 #include <sys/param.h>
 484                 #include <sys/socket.h>
 485
 486                 int
 487                 main(int argc, char **argv)
 488                 {
 489                         u_char ea[6] = { 0xff, 0xff, 0xff, 0xff, 0xff };
 490                         char name[MAXHOSTNAMELEN];
 491
 492                         ether_ntohost(name, (struct ether_addr *)ea);
 493                         exit(0);
 494                 }
 495         ], [ac_cv_buggy_ether_ntohost=no],
 496            [ac_cv_buggy_ether_ntohost=yes],
 497            [ac_cv_buggy_ether_ntohost="not while cross-compiling"])])
 498     if test "$ac_cv_buggy_ether_ntohost" = "no"; then
 499         AC_DEFINE(USE_ETHER_NTOHOST, 1,
 500             [define if you have ether_ntohost() and it works])
 501     fi
 502 ])
 503 if test "$ac_cv_func_ether_ntohost" = yes -a \
 504     "$ac_cv_buggy_ether_ntohost" = "no"; then
 505         #
 506         # OK, we have ether_ntohost().  Is it declared in <net/ethernet.h>?
 507         #
 508         # This test fails if we don't have <net/ethernet.h> or if we do
 509         # but it doesn't declare ether_ntohost().
 510         #
 511         AC_CHECK_DECL(ether_ntohost,
 512             [
 513                 AC_DEFINE(NET_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
 514                     [Define to 1 if net/ethernet.h declares `ether_ntohost'])
 515             ],,
 516             [
 517 #include <net/ethernet.h>
 518             ])
 519         #
 520         # Did that succeed?
 521         #
 522         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 523                 #
 524                 # No, how about <netinet/ether.h>, as on Linux?
 525                 #
 526                 # This test fails if we don't have <netinet/ether.h>
 527                 # or if we do but it doesn't declare ether_ntohost().
 528                 #
 529                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 530                 # treat the previous failure as a cached value and
 531                 # suppress the next test.
 532                 #
 533                 unset ac_cv_have_decl_ether_ntohost
 534                 AC_CHECK_DECL(ether_ntohost,
 535                     [
 536                         AC_DEFINE(NETINET_ETHER_H_DECLARES_ETHER_NTOHOST,,
 537                             [Define to 1 if netinet/ether.h declares `ether_ntohost'])
 538                     ],,
 539                     [
 540 #include <netinet/ether.h>
 541                     ])
 542         fi
 543         #
 544         # Did that succeed?
 545         #
 546         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 547                 #
 548                 # No, how about <sys/ethernet.h>, as on Solaris 10
 549                 # and later?
 550                 #
 551                 # This test fails if we don't have <sys/ethernet.h>
 552                 # or if we do but it doesn't declare ether_ntohost().
 553                 #
 554                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 555                 # treat the previous failure as a cached value and
 556                 # suppress the next test.
 557                 #
 558                 unset ac_cv_have_decl_ether_ntohost
 559                 AC_CHECK_DECL(ether_ntohost,
 560                     [
 561                         AC_DEFINE(SYS_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
 562                             [Define to 1 if sys/ethernet.h declares `ether_ntohost'])
 563                     ],,
 564                     [
 565 #include <sys/ethernet.h>
 566                     ])
 567         fi
 568         #
 569         # Did that succeed?
 570         #
 571         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 572                 #
 573                 # No, how about <arpa/inet.h>, as in AIX?
 574                 #
 575                 # This test fails if we don't have <arpa/inet.h>
 576                 # (if we have ether_ntohost(), we should have
 577                 # networking, and if we have networking, we should
 578                 # have <arpa/inet.h>) or if we do but it doesn't
 579                 # declare ether_ntohost().
 580                 #
 581                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 582                 # treat the previous failure as a cached value and
 583                 # suppress the next test.
 584                 #
 585                 unset ac_cv_have_decl_ether_ntohost
 586                 AC_CHECK_DECL(ether_ntohost,
 587                     [
 588                         AC_DEFINE(ARPA_INET_H_DECLARES_ETHER_NTOHOST,,
 589                             [Define to 1 if arpa/inet.h declares `ether_ntohost'])
 590                     ],,
 591                     [
 592 #include <arpa/inet.h>
 593                     ])
 594         fi
 595         #
 596         # Did that succeed?
 597         #
 598         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 599                 #
 600                 # No, how about <netinet/if_ether.h>?
 601                 # On some platforms, it requires <net/if.h> and
 602                 # <netinet/in.h>, and we always include it with
 603                 # both of them, so test it with both of them.
 604                 #
 605                 # This test fails if we don't have <netinet/if_ether.h>
 606                 # and the headers we include before it, or if we do but
 607                 # <netinet/if_ether.h> doesn't declare ether_hostton().
 608                 #
 609                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 610                 # treat the previous failure as a cached value and
 611                 # suppress the next test.
 612                 #
 613                 unset ac_cv_have_decl_ether_ntohost
 614                 AC_CHECK_DECL(ether_ntohost,
 615                     [
 616                         AC_DEFINE(NETINET_IF_ETHER_H_DECLARES_ETHER_NTOHOST,,
 617                             [Define to 1 if netinet/if_ether.h declares `ether_ntohost'])
 618                     ],,
 619                     [
 620 #include <sys/types.h>
 621 #include <sys/socket.h>
 622 #include <net/if.h>
 623 #include <netinet/in.h>
 624 #include <netinet/if_ether.h>
 625                     ])
 626         fi
 627         #
 628         # After all that, is ether_ntohost() declared?
 629         #
 630         if test "$ac_cv_have_decl_ether_ntohost" = yes; then
 631                 #
 632                 # Yes.
 633                 #
 634                 AC_DEFINE(HAVE_DECL_ETHER_NTOHOST, 1,
 635                     [Define to 1 if you have the declaration of `ether_ntohost'])
 636         else
 637                 #
 638                 # No, we'll have to declare it ourselves.
 639                 # Do we have "struct ether_addr" if we include
 640                 # <netinet/if_ether.h>?
 641                 #
 642                 AC_CHECK_TYPES(struct ether_addr,,,
 643                     [
 644                         #include <sys/types.h>
 645                         #include <sys/socket.h>
 646                         #include <net/if.h>
 647                         #include <netinet/in.h>
 648                         #include <netinet/if_ether.h>
 649                     ])
 650         fi
 651 fi
 652
 653 dnl
 654 dnl Check for "pcap_list_datalinks()" and use a substitute version if
 655 dnl it's not present.  If it is present, check for "pcap_free_datalinks()";
 656 dnl if it's not present, we don't replace it for now.  (We could do so
 657 dnl on UN*X, but not on Windows, where hilarity ensues if a program
 658 dnl built with one version of the MSVC support library tries to free
 659 dnl something allocated by a library built with another version of
 660 dnl the MSVC support library.)
 661 dnl
 662 AC_CHECK_FUNC(pcap_list_datalinks,
 663         [
 664             AC_DEFINE(HAVE_PCAP_LIST_DATALINKS, 1,
 665                 [define if libpcap has pcap_list_datalinks()])
 666             AC_CHECK_FUNCS(pcap_free_datalinks)
 667         ],
 668         [
 669             AC_LIBOBJ(datalinks)
 670         ])
 671
 672 dnl
 673 dnl Check for "pcap_datalink_name_to_val()", and use a substitute
 674 dnl version if it's not present.  If it is present, check for
 675 dnl "pcap_datalink_val_to_description()", and if we don't have it,
 676 dnl use a substitute version.
 677 dnl
 678 AC_CHECK_FUNC(pcap_datalink_name_to_val,
 679         [
 680             AC_DEFINE(HAVE_PCAP_DATALINK_NAME_TO_VAL, 1,
 681                 [define if libpcap has pcap_datalink_name_to_val()])
 682             AC_CHECK_FUNC(pcap_datalink_val_to_description,
 683                 AC_DEFINE(HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION, 1,
 684                     [define if libpcap has pcap_datalink_val_to_description()]),
 685                 [
 686                     AC_LIBOBJ(dlnames)
 687                 ])
 688         ],
 689         [
 690             AC_LIBOBJ(dlnames)
 691         ])
 692
 693 dnl
 694 dnl Check for "pcap_set_datalink()"; you can't substitute for it if
 695 dnl it's absent (it has hooks into libpcap), so just define the
 696 dnl HAVE_ value if it's there.
 697 dnl
 698 AC_CHECK_FUNCS(pcap_set_datalink)
 699
 700 dnl
 701 dnl Check for "pcap_breakloop()"; you can't substitute for it if
 702 dnl it's absent (it has hooks into the live capture routines),
 703 dnl so just define the HAVE_ value if it's there.
 704 dnl
 705 AC_CHECK_FUNCS(pcap_breakloop)
 706
 707 #
 708 # Do we have the new open API?  Check for pcap_create, and assume that,
 709 # if we do, we also have pcap_activate() and the other new routines
 710 # introduced in libpcap 1.0.0.
 711 #
 712 AC_CHECK_FUNCS(pcap_create)
 713 if test $ac_cv_func_pcap_create = "yes" ; then
 714         #
 715         # OK, do we have pcap_set_tstamp_type?  If so, assume we have
 716         # pcap_list_tstamp_types and pcap_free_tstamp_types as well.
 717         #
 718         AC_CHECK_FUNCS(pcap_set_tstamp_type)
 719         #
 720         # And do we have pcap_set_tstamp_precision?  If so, we assume
 721         # we also have pcap_open_offline_with_tstamp_precision.
 722         #
 723         AC_CHECK_FUNCS(pcap_set_tstamp_precision)
 724 fi
 725
 726 #
 727 # Check for a miscellaneous collection of functions which we use
 728 # if we have them.
 729 #
 730 AC_CHECK_FUNCS(pcap_findalldevs)
 731 if test $ac_cv_func_pcap_findalldevs = "yes" ; then
 732 dnl Check for libpcap having pcap_findalldevs() but the pcap.h header
 733 dnl not having pcap_if_t; some versions of Mac OS X shipped with pcap.h
 734 dnl from 0.6 and libpcap 0.8, so that libpcap had pcap_findalldevs but
 735 dnl pcap.h didn't have pcap_if_t.
 736     savedcppflags="$CPPFLAGS"
 737     CPPFLAGS="$CPPFLAGS $V_INCLS"
 738     AC_CHECK_TYPES(pcap_if_t, , , [#include <pcap.h>])
 739     CPPFLAGS="$savedcppflags"
 740 fi
 741 AC_CHECK_FUNCS(pcap_dump_flush pcap_lib_version)
 742 if test $ac_cv_func_pcap_lib_version = "no" ; then
 743     AC_MSG_CHECKING(whether pcap_version is defined by libpcap)
 744     AC_TRY_LINK([],
 745        [
 746         extern char pcap_version[];
 747
 748         return (int)pcap_version;
 749        ],
 750        ac_lbl_cv_pcap_version_defined=yes,
 751        ac_lbl_cv_pcap_version_defined=no)
 752     if test "$ac_lbl_cv_pcap_version_defined" = yes ; then
 753         AC_MSG_RESULT(yes)
 754         AC_DEFINE(HAVE_PCAP_VERSION, 1, [define if libpcap has pcap_version])
 755     else
 756         AC_MSG_RESULT(no)
 757     fi
 758 fi
 759 AC_CHECK_FUNCS(pcap_setdirection pcap_set_immediate_mode pcap_dump_ftell64)
 760 AC_CHECK_FUNCS(pcap_open pcap_findalldevs_ex)
 761 AC_REPLACE_FUNCS(pcap_dump_ftell)
 762
 763 #
 764 # Check for special debugging functions
 765 #
 766 AC_CHECK_FUNCS(pcap_set_parser_debug)
 767 if test "$ac_cv_func_pcap_set_parser_debug" = "no" ; then
 768         #
 769         # OK, we don't have pcap_set_parser_debug() to set the libpcap
 770         # filter expression parser debug flag; can we directly set the
 771         # flag?
 772         AC_MSG_CHECKING(whether pcap_debug is defined by libpcap)
 773         AC_TRY_LINK([],
 774            [
 775                 extern int pcap_debug;
 776
 777                 return pcap_debug;
 778            ],
 779            ac_lbl_cv_pcap_debug_defined=yes,
 780            ac_lbl_cv_pcap_debug_defined=no)
 781         if test "$ac_lbl_cv_pcap_debug_defined" = yes ; then
 782                 AC_MSG_RESULT(yes)
 783                 AC_DEFINE(HAVE_PCAP_DEBUG, 1, [define if libpcap has pcap_debug])
 784         else
 785                 AC_MSG_RESULT(no)
 786                 #
 787                 # OK, what about "yydebug"?
 788                 #
 789                 AC_MSG_CHECKING(whether yydebug is defined by libpcap)
 790                 AC_TRY_LINK([],
 791                    [
 792                         extern int yydebug;
 793
 794                         return yydebug;
 795                    ],
 796                    ac_lbl_cv_yydebug_defined=yes,
 797                    ac_lbl_cv_yydebug_defined=no)
 798                 if test "$ac_lbl_cv_yydebug_defined" = yes ; then
 799                         AC_MSG_RESULT(yes)
 800                         AC_DEFINE(HAVE_YYDEBUG, 1, [define if libpcap has yydebug])
 801                 else
 802                         AC_MSG_RESULT(no)
 803                 fi
 804         fi
 805 fi
 806 AC_CHECK_FUNCS(pcap_set_optimizer_debug)
 807 AC_REPLACE_FUNCS(bpf_dump)      dnl moved to libpcap in 0.6
 808
 809 V_GROUP=0
 810 if test -f /etc/group -a ! -z "`grep '^wheel:' /etc/group`" ; then
 811         V_GROUP=wheel
 812 fi
 813 #
 814 # Assume V7/BSD convention for man pages (file formats in section 5,
 815 # miscellaneous info in section 7).
 816 #
 817 MAN_FILE_FORMATS=5
 818 MAN_MISC_INFO=7
 819 case "$host_os" in
 820
 821 aix*)
 822         dnl Workaround to enable certain features
 823         AC_DEFINE(_SUN,1,[define on AIX to get certain functions])
 824         ;;
 825
 826 hpux*)
 827         #
 828         # Use System V conventions for man pages.
 829         #
 830         MAN_FILE_FORMATS=4
 831         MAN_MISC_INFO=5
 832         ;;
 833
 834 irix*)
 835         V_GROUP=sys
 836
 837         #
 838         # Use System V conventions for man pages.
 839         #
 840         MAN_FILE_FORMATS=4
 841         MAN_MISC_INFO=5
 842         ;;
 843
 844 osf*)
 845         V_GROUP=system
 846
 847         #
 848         # Use System V conventions for man pages.
 849         #
 850         MAN_FILE_FORMATS=4
 851         MAN_MISC_INFO=5
 852         ;;
 853
 854 solaris*)
 855         V_GROUP=sys
 856
 857         #
 858         # Use System V conventions for man pages.
 859         #
 860         MAN_FILE_FORMATS=4
 861         MAN_MISC_INFO=5
 862         ;;
 863 esac
 864
 865 if test -f /dev/bpf0 ; then
 866         V_GROUP=bpf
 867 fi
 868
 869 #
 870 # Make sure we have a definition for C99's uintptr_t (regardless of
 871 # whether the environment is a C99 environment or not).
 872 #
 873 AC_TYPE_UINTPTR_T
 874
 875 #
 876 # Check whether we have pcap/pcap-inttypes.h.
 877 # If we do, we use that to get the C99 types defined.
 878 #
 879 savedcppflags="$CPPFLAGS"
 880 CPPFLAGS="$CPPFLAGS $V_INCLS"
 881 AC_CHECK_HEADERS(pcap/pcap-inttypes.h)
 882 CPPFLAGS="$savedcppflags"
 883
 884 #
 885 # Define the old BSD specified-width types in terms of the C99 types;
 886 # we may need them with libpcap include files.
 887 #
 888 AC_CHECK_TYPE([u_int8_t], ,
 889         [AC_DEFINE([u_int8_t], [uint8_t],
 890         [Define to `uint8_t' if u_int8_t not defined.])],
 891         [AC_INCLUDES_DEFAULT
 892 #include <sys/types.h>
 893 ])
 894 AC_CHECK_TYPE([u_int16_t], ,
 895         [AC_DEFINE([u_int16_t], [uint16_t],
 896         [Define to `uint16_t' if u_int16_t not defined.])],
 897         [AC_INCLUDES_DEFAULT
 898 #include <sys/types.h>
 899 ])
 900 AC_CHECK_TYPE([u_int32_t], ,
 901         [AC_DEFINE([u_int32_t], [uint32_t],
 902         [Define to `uint32_t' if u_int32_t not defined.])],
 903         [AC_INCLUDES_DEFAULT
 904 #include <sys/types.h>
 905 ])
 906 AC_CHECK_TYPE([u_int64_t], ,
 907         [AC_DEFINE([u_int64_t], [uint64_t],
 908         [Define to `uint64_t' if u_int64_t not defined.])],
 909         [AC_INCLUDES_DEFAULT
 910 #include <sys/types.h>
 911 ])
 912
 913 AC_PROG_RANLIB
 914 AC_CHECK_TOOL([AR], [ar])
 915
 916 AC_LBL_DEVEL(V_CCOPT)
 917
 918 # Check for OpenSSL/libressl libcrypto
 919 AC_MSG_CHECKING(whether to use OpenSSL/libressl libcrypto)
 920 # Specify location for both includes and libraries.
 921 want_libcrypto=ifavailable
 922 AC_ARG_WITH(crypto,
 923     AS_HELP_STRING([--with-crypto]@<:@=DIR@:>@,
 924                    [use OpenSSL/libressl libcrypto (located in directory DIR, if specified) @<:@default=yes, if available@:>@]),
 925 [
 926         if test $withval = no
 927         then
 928                 # User doesn't want to link with libcrypto.
 929                 want_libcrypto=no
 930                 AC_MSG_RESULT(no)
 931         elif test $withval = yes
 932         then
 933                 # User wants to link with libcrypto but hasn't specified
 934                 # a directory.
 935                 want_libcrypto=yes
 936                 AC_MSG_RESULT(yes)
 937         else
 938                 # User wants to link with libcrypto and has specified
 939                 # a directory, so use the provided value.
 940                 want_libcrypto=yes
 941                 libcrypto_root=$withval
 942                 AC_MSG_RESULT([yes, using the version installed in $withval])
 943
 944                 #
 945                 # Put the subdirectories of the libcrypto root directory
 946                 # at the front of the header and library search path.
 947                 #
 948                 CFLAGS="-I$withval/include $CFLAGS"
 949                 LIBS="-L$withval/lib $LIBS"
 950         fi
 951 ],[
 952         #
 953         # Use libcrypto if it's present, otherwise don't; no directory
 954         # was specified.
 955         #
 956         want_libcrypto=ifavailable
 957         AC_MSG_RESULT([yes, if available])
 958 ])
 959 if test "$want_libcrypto" != "no"; then
 960         #
 961         # Don't check for libcrypto unless we have its headers;
 962         # Apple, bless their pointy little heads, apparently ship
 963         # libcrypto as a library, but not the header files, in
 964         # El Capitan, probably because they don't want you writing
 965         # nasty portable code that could run on other UN*Xes, they
 966         # want you writing code that uses their Shiny New Crypto
 967         # Library and that only runs on macOS.
 968         #
 969         AC_CHECK_HEADER(openssl/crypto.h,
 970         [
 971                 AC_CHECK_LIB(crypto, DES_cbc_encrypt)
 972                 if test "$ac_cv_lib_crypto_DES_cbc_encrypt" = "yes"; then
 973                         AC_CHECK_HEADERS(openssl/evp.h)
 974                         #
 975                         # OK, then:
 976                         #
 977                         # 1) do we have EVP_CIPHER_CTX_new?
 978                         # If so, we use it to allocate an
 979                         # EVP_CIPHER_CTX, as EVP_CIPHER_CTX may be
 980                         # opaque; otherwise, we allocate it ourselves.
 981                         #
 982                         # 2) do we have EVP_DecryptInit_ex()?
 983                         # If so, we use it, because we need to be
 984                         # able to make two "initialize the cipher"
 985                         # calls, one with the cipher and key, and
 986                         # one with the IV, and, as of OpenSSL 1.1,
 987                         # You Can't Do That with EVP_DecryptInit(),
 988                         # because a call to EVP_DecryptInit() will
 989                         # unconditionally clear the context, and
 990                         # if you don't supply a cipher, it'll
 991                         # clear the cipher, rendering the context
 992                         # unusable and causing a crash.
 993                         #
 994                         AC_CHECK_FUNCS(EVP_CIPHER_CTX_new EVP_DecryptInit_ex)
 995                 fi
 996         ])
 997 fi
 998
 999 # Check for libcap-ng
1000 AC_MSG_CHECKING(whether to use libcap-ng)
1001 # Specify location for both includes and libraries.
1002 want_libcap_ng=ifavailable
1003 AC_ARG_WITH(cap_ng,
1004     AS_HELP_STRING([--with-cap-ng],
1005                    [use libcap-ng @<:@default=yes, if available@:>@]),
1006 [
1007         if test $withval = no
1008         then
1009                 want_libcap_ng=no
1010                 AC_MSG_RESULT(no)
1011         elif test $withval = yes
1012         then
1013                 want_libcap_ng=yes
1014                 AC_MSG_RESULT(yes)
1015         fi
1016 ],[
1017         #
1018         # Use libcap-ng if it's present, otherwise don't.
1019         #
1020         want_libcap_ng=ifavailable
1021         AC_MSG_RESULT([yes, if available])
1022 ])
1023 if test "$want_libcap_ng" != "no"; then
1024         AC_CHECK_LIB(cap-ng, capng_change_id)
1025         AC_CHECK_HEADERS(cap-ng.h)
1026 fi
1027
1028 dnl
1029 dnl set additional include path if necessary
1030 if test "$missing_includes" = "yes"; then
1031         CPPFLAGS="$CPPFLAGS -I$srcdir/missing"
1032         V_INCLS="$V_INCLS -I$srcdir/missing"
1033 fi
1034
1035 AC_SUBST(V_CCOPT)
1036 AC_SUBST(V_DEFS)
1037 AC_SUBST(V_GROUP)
1038 AC_SUBST(V_INCLS)
1039 AC_SUBST(V_PCAPDEP)
1040 AC_SUBST(LOCALSRC)
1041 AC_SUBST(MAN_FILE_FORMATS)
1042 AC_SUBST(MAN_MISC_INFO)
1043
1044 AC_PROG_INSTALL
1045
1046 AC_CONFIG_HEADER(config.h)
1047
1048 AC_OUTPUT_COMMANDS([if test -f .devel; then
1049         echo timestamp > stamp-h
1050         cat $srcdir/Makefile-devel-adds >> Makefile
1051         make depend || exit 1
1052 fi])
1053 AC_OUTPUT(Makefile tcpdump.1)
1054 exit 0