The Tcpdump Group git mirrors - tcpdump/blob - configure.ac

   1 dnl Copyright (c) 1994, 1995, 1996, 1997
   2 dnl     The Regents of the University of California.  All rights reserved.
   3 dnl
   4 dnl Process this file with autoconf to produce a configure script.
   5 dnl
   6
   7 #
   8 # See
   9 #
  10 #       https://ftp.gnu.org/gnu/config/README
  11 #
  12 # for the URLs to use to fetch new versions of config.guess and
  13 # config.sub.
  14 #
  15
  16 AC_PREREQ([2.69])
  17 AC_INIT([tcpdump],[m4_esyscmd_s(cat VERSION)])
  18 AC_CONFIG_SRCDIR(tcpdump.c)
  19
  20 AC_CANONICAL_HOST
  21
  22 AC_LBL_C_INIT_BEFORE_CC(V_INCLS)
  23 #
  24 # Try to enable as many C99 features as we can.
  25 # At minimum, we want C++/C99-style // comments.
  26 #
  27 AC_PROG_CC_C99
  28 if test "$ac_cv_prog_cc_c99" = "no"; then
  29         AC_MSG_WARN([The C compiler does not support C99; there may be compiler errors])
  30 fi
  31 AC_LBL_C_INIT(V_CCOPT, V_INCLS)
  32 AC_C_INLINE
  33
  34 AC_CHECK_HEADERS(fcntl.h rpc/rpc.h rpc/rpcent.h net/if.h)
  35
  36 case "$host_os" in
  37
  38 darwin*)
  39         AC_ARG_ENABLE(universal,
  40         AS_HELP_STRING([--disable-universal],[don't build universal on macOS]))
  41         if test "$enable_universal" != "no"; then
  42                 case "$host_os" in
  43
  44                 darwin9.*)
  45                         #
  46                         # Leopard.  Build for x86 and 32-bit PowerPC, with
  47                         # x86 first.  (That's what Apple does.)
  48                         #
  49                         V_CCOPT="$V_CCOPT -arch i386 -arch ppc"
  50                         LDFLAGS="$LDFLAGS -arch i386 -arch ppc"
  51                         ;;
  52
  53                 darwin10.*)
  54                         #
  55                         # Snow Leopard.  Build for x86-64 and x86, with
  56                         # x86-64 first.  (That's what Apple does.)
  57                         #
  58                         V_CCOPT="$V_CCOPT -arch x86_64 -arch i386"
  59                         LDFLAGS="$LDFLAGS -arch x86_64 -arch i386"
  60                         ;;
  61                 esac
  62         fi
  63         ;;
  64 esac
  65
  66
  67 AC_ARG_WITH([smi],
  68    [AS_HELP_STRING([--with-smi],
  69      [link with libsmi (allows to load MIBs on the fly to decode SNMP packets) [default=yes, if available]])],
  70    [],
  71    [with_smi=yes])
  72
  73 if test "x$with_smi" != "xno" ; then
  74         AC_CHECK_HEADER(smi.h,
  75         [
  76                 #
  77                 # OK, we found smi.h.  Do we have libsmi with smiInit?
  78                 #
  79                 AC_CHECK_LIB(smi, smiInit,
  80                 [
  81                         #
  82                         # OK, we have libsmi with smiInit.  Can we use it?
  83                         #
  84                         AC_MSG_CHECKING([whether to enable libsmi])
  85                         savedlibs="$LIBS"
  86                         LIBS="-lsmi $LIBS"
  87                         AC_RUN_IFELSE([AC_LANG_SOURCE([[
  88 /* libsmi available check */
  89 #include <stdio.h>
  90 #include <stdlib.h>
  91 #include <string.h>
  92 #include <smi.h>
  93 int main()
  94 {
  95   int current, revision, age, n;
  96   const int required = 2;
  97   if (smiInit(""))
  98     exit(1);
  99   if (strcmp(SMI_LIBRARY_VERSION, smi_library_version))
 100     exit(2);
 101   n = sscanf(smi_library_version, "%d:%d:%d", &current, &revision, &age);
 102   if (n != 3)
 103     exit(3);
 104   if (required < current - age || required > current)
 105     exit(4);
 106   exit(0);
 107 }
 108                                 ]])
 109                                 ],
 110                                 [
 111                                         AC_MSG_RESULT(yes)
 112                                         AC_DEFINE(USE_LIBSMI, 1,
 113                                             [Define if you enable support for libsmi])
 114                                 ],
 115                                 [
 116                                         dnl autoconf documentation says that
 117                                         dnl $? contains the exit value.
 118                                         dnl reality is that it does not.
 119                                         dnl We leave this in just in case
 120                                         dnl autoconf ever comes back to
 121                                         dnl match the documentation.
 122                                         case $? in
 123                                           1) AC_MSG_RESULT(no - smiInit failed) ;;
 124                                           2) AC_MSG_RESULT(no - header/library version mismatch) ;;
 125                                           3) AC_MSG_RESULT(no - can't determine library version) ;;
 126                                           4) AC_MSG_RESULT(no - too old) ;;
 127                                           *) AC_MSG_RESULT(no) ;;
 128                                         esac
 129                                         LIBS="$savedlibs"
 130                                 ],
 131                                 [
 132                                         AC_MSG_RESULT(not when cross-compiling)
 133                                         LIBS="$savedlibs"
 134                                 ]
 135                         )
 136                 ])
 137         ])
 138 fi
 139
 140 AC_MSG_CHECKING([whether to enable the instrument functions code])
 141 AC_ARG_ENABLE([instrument-functions],
 142    [AS_HELP_STRING([--enable-instrument-functions],
 143      [enable instrument functions code [default=no]])],
 144    [],
 145    [enableval=no])
 146 case "$enableval" in
 147 yes)    AC_MSG_RESULT(yes)
 148         AC_CHECK_LIB([bfd], [bfd_init],
 149             [true],
 150             [AC_MSG_ERROR(
 151                [--enable-instrument-functions was given, but test for library libbfd failed. Please install the 'binutils-dev' package.])],
 152             [])
 153         AC_DEFINE(ENABLE_INSTRUMENT_FUNCTIONS, 1,
 154             [define if you want to build the instrument functions code])
 155         LOCALSRC="$LOCALSRC instrument-functions.c"
 156         # Add '-finstrument-functions' instrumentation option to generate
 157         # instrumentation calls for entry and exit to functions.
 158         # Try to avoid Address Space Layout Randomization (ALSR).
 159         CFLAGS="$CFLAGS -O0 -ggdb -finstrument-functions -fno-stack-protector -fno-pic"
 160         LDFLAGS="$LDFLAGS -O0 -ggdb -fno-stack-protector -no-pie"
 161         LIBS="$LIBS -lbfd"
 162         ;;
 163 *)      AC_MSG_RESULT(no)
 164         ;;
 165 esac
 166
 167 AC_MSG_CHECKING([whether to enable the possibly-buggy SMB printer])
 168 AC_ARG_ENABLE([smb],
 169    [AS_HELP_STRING([--enable-smb],
 170      [enable possibly-buggy SMB printer [default=no]])],
 171    [],
 172    [enableval=no])
 173 case "$enableval" in
 174 yes)    AC_MSG_RESULT(yes)
 175         AC_DEFINE(ENABLE_SMB, 1,
 176             [define if you want to build the possibly-buggy SMB printer])
 177         LOCALSRC="print-smb.c smbutil.c $LOCALSRC"
 178         ;;
 179 *)      AC_MSG_RESULT(no)
 180         ;;
 181 esac
 182
 183 AC_ARG_WITH(user, [  --with-user=USERNAME    drop privileges by default to USERNAME])
 184 AC_MSG_CHECKING([whether to drop root privileges by default])
 185 if test ! -z "$withval" && test "$withval" != "no" ; then
 186        if test "$withval" = "yes" ; then
 187            AC_MSG_ERROR([--with-user requires a username])
 188        fi
 189        AC_DEFINE_UNQUOTED(WITH_USER, "$withval",
 190            [define if should drop privileges by default])
 191        AC_MSG_RESULT([yes, to user "$withval"])
 192 else
 193        AC_MSG_RESULT(no)
 194 fi
 195
 196 AC_ARG_WITH(chroot, [  --with-chroot=DIRECTORY when dropping privileges, chroot to DIRECTORY])
 197 AC_MSG_CHECKING([whether to chroot])
 198 if test ! -z "$withval" && test "$withval" != "no" ; then
 199        if test "$withval" = "yes" ; then
 200            AC_MSG_ERROR([--with-chroot requires a directory])
 201        fi
 202        AC_DEFINE_UNQUOTED(WITH_CHROOT, "$withval",
 203            [define if should chroot when dropping privileges])
 204        AC_MSG_RESULT([yes, to directory "$withval"])
 205 else
 206        AC_MSG_RESULT(no)
 207 fi
 208
 209 AC_ARG_WITH(sandbox-capsicum,
 210         AS_HELP_STRING([--with-sandbox-capsicum],
 211                        [use Capsicum security functions @<:@default=yes, if available@:>@]))
 212 #
 213 # Check whether various functions are available.  If any are, set
 214 # ac_lbl_capsicum_function_seen to yes; if any are not, set
 215 # ac_lbl_capsicum_function_not_seen to yes.
 216 #
 217 # We don't check cap_rights_init(), as it's a macro, wrapping another
 218 # function, in at least some versions of FreeBSD, and AC_CHECK_FUNCS()
 219 # doesn't handle that.
 220 #
 221 # All of the ones we check for must be available in order to enable
 222 # capsicum sandboxing.
 223 #
 224 # XXX - do we need to check for all of them, or are there some that, if
 225 # present, imply others are present?
 226 #
 227 if test -z "$with_sandbox_capsicum" || test "$with_sandbox_capsicum" != "no" ; then
 228         #
 229         # First, make sure we have the required header.
 230         #
 231         AC_CHECK_HEADER(sys/capsicum.h,
 232         [
 233                 #
 234                 # We do; now make sure we have the required functions.
 235                 #
 236                 AC_CHECK_FUNCS(cap_enter cap_rights_limit cap_ioctls_limit openat,
 237                     ac_lbl_capsicum_function_seen=yes,
 238                     ac_lbl_capsicum_function_not_seen=yes)
 239         ])
 240         AC_CHECK_LIB(casper, cap_init, LIBS="$LIBS -lcasper")
 241         AC_CHECK_LIB(cap_dns, cap_gethostbyaddr, LIBS="$LIBS -lcap_dns")
 242 fi
 243 AC_MSG_CHECKING([whether to sandbox using capsicum])
 244 if test "x$ac_lbl_capsicum_function_seen" = "xyes" -a "x$ac_lbl_capsicum_function_not_seen" != "xyes"; then
 245         AC_DEFINE(HAVE_CAPSICUM, 1, [capsicum support available])
 246         AC_MSG_RESULT(yes)
 247 else
 248         AC_MSG_RESULT(no)
 249 fi
 250 AC_MSG_CHECKING([whether to sandbox using Casper library])
 251 if test "x$ac_cv_lib_casper_cap_init" = "xyes" -a "x$ac_cv_lib_cap_dns_cap_gethostbyaddr" = "xyes"; then
 252         AC_DEFINE(HAVE_CASPER, 1, [Casper support available])
 253         AC_MSG_RESULT(yes)
 254 else
 255         AC_MSG_RESULT(no)
 256 fi
 257
 258 #
 259 # We must check this before checking whether to check the OS's IPv6,
 260 # support because, on some platforms (such as SunOS 5.x), the test
 261 # program requires the extra networking libraries.
 262 #
 263 AC_LBL_LIBRARY_NET
 264
 265 #
 266 # Check whether AF_INET6 and struct in6_addr are defined.
 267 # If they aren't both defined, we don't have sufficient OS
 268 # support for IPv6, so we don't look for IPv6 support libraries,
 269 # and we define AF_INET6 and struct in6_addr ourselves.
 270 #
 271 AC_MSG_CHECKING([whether the operating system supports IPv6])
 272 AC_COMPILE_IFELSE(
 273     [
 274       AC_LANG_SOURCE(
 275         [[
 276 #include <string.h>
 277 /* AF_INET6 available check */
 278 #include <sys/types.h>
 279 #ifdef _WIN32
 280 #include <ws2tcpip.h>
 281 #else
 282 #include <sys/socket.h>
 283 #include <netinet/in.h>
 284 #endif
 285 #ifdef AF_INET6
 286 void
 287 foo(struct in6_addr *addr)
 288 {
 289  memset(addr, 0, sizeof (struct in6_addr));
 290 }
 291 #else
 292 #error "AF_INET6 not defined"
 293 #endif
 294         ]])
 295     ],
 296     [
 297         AC_MSG_RESULT(yes)
 298         AC_DEFINE(HAVE_OS_IPV6_SUPPORT, 1,
 299             [define if the OS provides AF_INET6 and struct in6_addr])
 300         ipv6=yes
 301     ],
 302     [
 303         AC_MSG_RESULT(no)
 304         ipv6=no
 305     ]
 306 )
 307
 308 ipv6type=unknown
 309 ipv6lib=none
 310 ipv6trylibc=no
 311
 312 if test "$ipv6" = "yes"; then
 313         AC_MSG_CHECKING([ipv6 stack type])
 314         for i in inria kame linux-glibc linux-libinet6 toshiba v6d zeta; do
 315                 case $i in
 316                 inria)
 317                         dnl http://www.kame.net/
 318                         AC_EGREP_CPP(yes,
 319 [#include <netinet/in.h>
 320 #ifdef IPV6_INRIA_VERSION
 321 yes
 322 #endif],
 323                                 [ipv6type=$i])
 324                         ;;
 325                 kame)
 326                         dnl http://www.kame.net/
 327                         AC_EGREP_CPP(yes,
 328 [#include <netinet/in.h>
 329 #ifdef __KAME__
 330 yes
 331 #endif],
 332                                 [ipv6type=$i;
 333                                 ipv6lib=inet6;
 334                                 ipv6libdir=/usr/local/v6/lib;
 335                                 ipv6trylibc=yes])
 336                         ;;
 337                 linux-glibc)
 338                         dnl http://www.v6.linux.or.jp/
 339                         AC_EGREP_CPP(yes,
 340 [#include <features.h>
 341 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 342 yes
 343 #endif],
 344                                 [ipv6type=$i])
 345                         ;;
 346                 linux-libinet6)
 347                         dnl http://www.v6.linux.or.jp/
 348                         dnl
 349                         dnl This also matches Solaris 8 and Tru64 UNIX 5.1,
 350                         dnl and possibly other versions of those OSes
 351                         dnl
 352                         if test -d /usr/inet6 -o -f /usr/include/netinet/ip6.h; then
 353                                 ipv6type=$i
 354                                 ipv6lib=inet6
 355                                 ipv6libdir=/usr/inet6/lib
 356                                 ipv6trylibc=yes;
 357                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 358                         fi
 359                         ;;
 360                 toshiba)
 361                         AC_EGREP_CPP(yes,
 362 [#include <sys/param.h>
 363 #ifdef _TOSHIBA_INET6
 364 yes
 365 #endif],
 366                                 [ipv6type=$i;
 367                                 ipv6lib=inet6;
 368                                 ipv6libdir=/usr/local/v6/lib])
 369                         ;;
 370                 v6d)
 371                         AC_EGREP_CPP(yes,
 372 [#include </usr/local/v6/include/sys/v6config.h>
 373 #ifdef __V6D__
 374 yes
 375 #endif],
 376                                 [ipv6type=$i;
 377                                 ipv6lib=v6;
 378                                 ipv6libdir=/usr/local/v6/lib;
 379                                 CFLAGS="-I/usr/local/v6/include $CFLAGS"])
 380                         ;;
 381                 zeta)
 382                         AC_EGREP_CPP(yes,
 383 [#include <sys/param.h>
 384 #ifdef _ZETA_MINAMI_INET6
 385 yes
 386 #endif],
 387                                 [ipv6type=$i;
 388                                 ipv6lib=inet6;
 389                                 ipv6libdir=/usr/local/v6/lib])
 390                         ;;
 391                 esac
 392                 if test "$ipv6type" != "unknown"; then
 393                         break
 394                 fi
 395         done
 396         AC_MSG_RESULT($ipv6type)
 397 fi
 398
 399 if test "$ipv6" = "yes" -a "$ipv6lib" != "none"; then
 400         if test -d $ipv6libdir -a -f $ipv6libdir/lib$ipv6lib.a; then
 401                 LIBS="-L$ipv6libdir -l$ipv6lib $LIBS"
 402                 echo "You have $ipv6lib library, using it"
 403         else
 404                 if test "$ipv6trylibc" = "yes"; then
 405                         echo "You do not have $ipv6lib library, using libc"
 406                 else
 407                         echo 'Fatal: no $ipv6lib library found.  cannot continue.'
 408                         echo "You need to fetch lib$ipv6lib.a from appropriate"
 409                         echo 'ipv6 kit and compile beforehand.'
 410                         exit 1
 411                 fi
 412         fi
 413 fi
 414
 415 AC_REPLACE_FUNCS(strlcat strlcpy strdup strsep getservent getopt_long)
 416 AC_CHECK_FUNCS(fork vfork)
 417 AC_CHECK_FUNCS(setlinebuf)
 418
 419 #
 420 # Make sure we have vsnprintf() and snprintf(); we require them.
 421 #
 422 AC_CHECK_FUNC(vsnprintf,,
 423     AC_MSG_ERROR([vsnprintf() is required but wasn't found]))
 424 AC_CHECK_FUNC(snprintf,,
 425     AC_MSG_ERROR([snprintf() is required but wasn't found]))
 426
 427 #
 428 # Define HAVE_NO_PRINTF_Z to make it possible to disable test cases that
 429 # depend on %zu.
 430 #
 431 AC_MSG_CHECKING([whether printf(3) supports the z length modifier])
 432 AC_RUN_IFELSE(
 433     [
 434         AC_LANG_SOURCE([[
 435 #include <stdio.h>
 436 #include <string.h>
 437
 438 int main()
 439 {
 440   char buf[100];
 441   snprintf(buf, sizeof(buf), "%zu", sizeof(buf));
 442   return strncmp(buf, "100", sizeof(buf)) ? 1 : 0;
 443 }
 444         ]])
 445     ],
 446     [
 447         AC_MSG_RESULT(yes)
 448     ],
 449     [
 450         AC_MSG_RESULT(no)
 451         AC_DEFINE(HAVE_NO_PRINTF_Z, 1,
 452             [Define to 1 if printf(3) does not support the z length modifier.])
 453     ],
 454     [
 455         AC_MSG_RESULT(not while cross-compiling)
 456     ]
 457 )
 458
 459 AC_CHECK_LIB(rpc, main)         dnl It's unclear why we might need -lrpc
 460
 461 dnl Some platforms may need -lnsl for getrpcbynumber.
 462 AC_SEARCH_LIBS(getrpcbynumber, nsl,
 463     AC_DEFINE(HAVE_GETRPCBYNUMBER, 1, [define if you have getrpcbynumber()]))
 464
 465 AC_LBL_LIBPCAP(V_PCAPDEP, V_INCLS)
 466
 467 #
 468 # Check for these after AC_LBL_LIBPCAP, so we link with the appropriate
 469 # libraries (e.g., "-lsocket -lnsl" on Solaris).
 470 #
 471 # You are in a twisty little maze of UN*Xes, all different.
 472 # Some might not have ether_ntohost().
 473 # Some might have it and declare it in <net/ethernet.h>.
 474 # Some might have it and declare it in <netinet/ether.h>
 475 # Some might have it and declare it in <sys/ethernet.h>.
 476 # Some might have it and declare it in <arpa/inet.h>.
 477 # Some might have it and declare it in <netinet/if_ether.h>.
 478 # Some might have it and not declare it in any header file.
 479 #
 480 # Before you is a C compiler.
 481 #
 482 AC_CHECK_FUNCS(ether_ntohost, [
 483     AC_CACHE_CHECK(for buggy ether_ntohost, ac_cv_buggy_ether_ntohost, [
 484         AC_RUN_IFELSE([AC_LANG_SOURCE([[
 485                 #include <netdb.h>
 486                 #include <netinet/ether.h>
 487                 #include <stdlib.h>
 488                 #include <sys/types.h>
 489                 #include <sys/param.h>
 490                 #include <sys/socket.h>
 491
 492                 int
 493                 main(int argc, char **argv)
 494                 {
 495                         u_char ea[6] = { 0xff, 0xff, 0xff, 0xff, 0xff };
 496                         char name[MAXHOSTNAMELEN];
 497
 498                         ether_ntohost(name, (struct ether_addr *)ea);
 499                         exit(0);
 500                 }
 501         ]])
 502         ], [ac_cv_buggy_ether_ntohost=no],
 503            [ac_cv_buggy_ether_ntohost=yes],
 504            [ac_cv_buggy_ether_ntohost="not while cross-compiling"])])
 505     if test "$ac_cv_buggy_ether_ntohost" = "no"; then
 506         AC_DEFINE(USE_ETHER_NTOHOST, 1,
 507             [define if you have ether_ntohost() and it works])
 508     fi
 509 ])
 510 if test "$ac_cv_func_ether_ntohost" = yes -a \
 511     "$ac_cv_buggy_ether_ntohost" = "no"; then
 512         #
 513         # OK, we have ether_ntohost().  Is it declared in <net/ethernet.h>?
 514         #
 515         # This test fails if we don't have <net/ethernet.h> or if we do
 516         # but it doesn't declare ether_ntohost().
 517         #
 518         AC_CHECK_DECL(ether_ntohost,
 519             [
 520                 AC_DEFINE(NET_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
 521                     [Define to 1 if net/ethernet.h declares `ether_ntohost'])
 522             ],,
 523             [
 524 #include <net/ethernet.h>
 525             ])
 526         #
 527         # Did that succeed?
 528         #
 529         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 530                 #
 531                 # No, how about <netinet/ether.h>, as on Linux?
 532                 #
 533                 # This test fails if we don't have <netinet/ether.h>
 534                 # or if we do but it doesn't declare ether_ntohost().
 535                 #
 536                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 537                 # treat the previous failure as a cached value and
 538                 # suppress the next test.
 539                 #
 540                 unset ac_cv_have_decl_ether_ntohost
 541                 AC_CHECK_DECL(ether_ntohost,
 542                     [
 543                         AC_DEFINE(NETINET_ETHER_H_DECLARES_ETHER_NTOHOST,,
 544                             [Define to 1 if netinet/ether.h declares `ether_ntohost'])
 545                     ],,
 546                     [
 547 #include <netinet/ether.h>
 548                     ])
 549         fi
 550         #
 551         # Did that succeed?
 552         #
 553         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 554                 #
 555                 # No, how about <sys/ethernet.h>, as on Solaris 10
 556                 # and later?
 557                 #
 558                 # This test fails if we don't have <sys/ethernet.h>
 559                 # or if we do but it doesn't declare ether_ntohost().
 560                 #
 561                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 562                 # treat the previous failure as a cached value and
 563                 # suppress the next test.
 564                 #
 565                 unset ac_cv_have_decl_ether_ntohost
 566                 AC_CHECK_DECL(ether_ntohost,
 567                     [
 568                         AC_DEFINE(SYS_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
 569                             [Define to 1 if sys/ethernet.h declares `ether_ntohost'])
 570                     ],,
 571                     [
 572 #include <sys/ethernet.h>
 573                     ])
 574         fi
 575         #
 576         # Did that succeed?
 577         #
 578         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 579                 #
 580                 # No, how about <arpa/inet.h>, as in AIX?
 581                 #
 582                 # This test fails if we don't have <arpa/inet.h>
 583                 # (if we have ether_ntohost(), we should have
 584                 # networking, and if we have networking, we should
 585                 # have <arpa/inet.h>) or if we do but it doesn't
 586                 # declare ether_ntohost().
 587                 #
 588                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 589                 # treat the previous failure as a cached value and
 590                 # suppress the next test.
 591                 #
 592                 unset ac_cv_have_decl_ether_ntohost
 593                 AC_CHECK_DECL(ether_ntohost,
 594                     [
 595                         AC_DEFINE(ARPA_INET_H_DECLARES_ETHER_NTOHOST,,
 596                             [Define to 1 if arpa/inet.h declares `ether_ntohost'])
 597                     ],,
 598                     [
 599 #include <arpa/inet.h>
 600                     ])
 601         fi
 602         #
 603         # Did that succeed?
 604         #
 605         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 606                 #
 607                 # No, how about <netinet/if_ether.h>?
 608                 # On some platforms, it requires <net/if.h> and
 609                 # <netinet/in.h>, and we always include it with
 610                 # both of them, so test it with both of them.
 611                 #
 612                 # This test fails if we don't have <netinet/if_ether.h>
 613                 # and the headers we include before it, or if we do but
 614                 # <netinet/if_ether.h> doesn't declare ether_hostton().
 615                 #
 616                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 617                 # treat the previous failure as a cached value and
 618                 # suppress the next test.
 619                 #
 620                 unset ac_cv_have_decl_ether_ntohost
 621                 AC_CHECK_DECL(ether_ntohost,
 622                     [
 623                         AC_DEFINE(NETINET_IF_ETHER_H_DECLARES_ETHER_NTOHOST,,
 624                             [Define to 1 if netinet/if_ether.h declares `ether_ntohost'])
 625                     ],,
 626                     [
 627 #include <sys/types.h>
 628 #include <sys/socket.h>
 629 #include <net/if.h>
 630 #include <netinet/in.h>
 631 #include <netinet/if_ether.h>
 632                     ])
 633         fi
 634         #
 635         # After all that, is ether_ntohost() declared?
 636         #
 637         if test "$ac_cv_have_decl_ether_ntohost" = yes; then
 638                 #
 639                 # Yes.
 640                 #
 641                 AC_DEFINE(HAVE_DECL_ETHER_NTOHOST, 1,
 642                     [Define to 1 if you have the declaration of `ether_ntohost'])
 643         else
 644                 #
 645                 # No, we'll have to declare it ourselves.
 646                 # Do we have "struct ether_addr" if we include
 647                 # <netinet/if_ether.h>?
 648                 #
 649                 AC_CHECK_TYPES(struct ether_addr,,,
 650                     [
 651                         #include <sys/types.h>
 652                         #include <sys/socket.h>
 653                         #include <net/if.h>
 654                         #include <netinet/in.h>
 655                         #include <netinet/if_ether.h>
 656                     ])
 657         fi
 658 fi
 659
 660 dnl
 661 dnl Check for "pcap_list_datalinks()" and use a substitute version if
 662 dnl it's not present.  If it is present, check for "pcap_free_datalinks()";
 663 dnl if it's not present, we don't replace it for now.  (We could do so
 664 dnl on UN*X, but not on Windows, where hilarity ensues if a program
 665 dnl built with one version of the MSVC support library tries to free
 666 dnl something allocated by a library built with another version of
 667 dnl the MSVC support library.)
 668 dnl
 669 AC_CHECK_FUNC(pcap_list_datalinks,
 670         [
 671             AC_DEFINE(HAVE_PCAP_LIST_DATALINKS, 1,
 672                 [define if libpcap has pcap_list_datalinks()])
 673             AC_CHECK_FUNCS(pcap_free_datalinks)
 674         ],
 675         [
 676             AC_LIBOBJ(datalinks)
 677         ])
 678
 679 dnl
 680 dnl Check for "pcap_datalink_name_to_val()", and use a substitute
 681 dnl version if it's not present.  If it is present, check for
 682 dnl "pcap_datalink_val_to_description()", and if we don't have it,
 683 dnl use a substitute version.
 684 dnl
 685 AC_CHECK_FUNC(pcap_datalink_name_to_val,
 686         [
 687             AC_DEFINE(HAVE_PCAP_DATALINK_NAME_TO_VAL, 1,
 688                 [define if libpcap has pcap_datalink_name_to_val()])
 689             AC_CHECK_FUNC(pcap_datalink_val_to_description,
 690                 AC_DEFINE(HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION, 1,
 691                     [define if libpcap has pcap_datalink_val_to_description()]),
 692                 [
 693                     AC_LIBOBJ(dlnames)
 694                 ])
 695         ],
 696         [
 697             AC_LIBOBJ(dlnames)
 698         ])
 699
 700 dnl
 701 dnl Check for "pcap_set_datalink()"; you can't substitute for it if
 702 dnl it's absent (it has hooks into libpcap), so just define the
 703 dnl HAVE_ value if it's there.
 704 dnl
 705 AC_CHECK_FUNCS(pcap_set_datalink)
 706
 707 dnl
 708 dnl Check for "pcap_breakloop()"; you can't substitute for it if
 709 dnl it's absent (it has hooks into the live capture routines),
 710 dnl so just define the HAVE_ value if it's there.
 711 dnl
 712 AC_CHECK_FUNCS(pcap_breakloop)
 713
 714 #
 715 # Do we have the new open API?  Check for pcap_create, and assume that,
 716 # if we do, we also have pcap_activate() and the other new routines
 717 # introduced in libpcap 1.0.0.
 718 #
 719 AC_CHECK_FUNCS(pcap_create)
 720 if test $ac_cv_func_pcap_create = "yes" ; then
 721         #
 722         # OK, do we have pcap_set_tstamp_type?  If so, assume we have
 723         # pcap_list_tstamp_types and pcap_free_tstamp_types as well.
 724         #
 725         AC_CHECK_FUNCS(pcap_set_tstamp_type)
 726         #
 727         # And do we have pcap_set_tstamp_precision?  If so, we assume
 728         # we also have pcap_open_offline_with_tstamp_precision.
 729         #
 730         AC_CHECK_FUNCS(pcap_set_tstamp_precision)
 731 fi
 732
 733 #
 734 # Check for a miscellaneous collection of functions which we use
 735 # if we have them.
 736 #
 737 AC_CHECK_FUNCS(pcap_findalldevs)
 738 if test $ac_cv_func_pcap_findalldevs = "yes" ; then
 739 dnl Check for libpcap having pcap_findalldevs() but the pcap.h header
 740 dnl not having pcap_if_t; some versions of Mac OS X shipped with pcap.h
 741 dnl from 0.6 and libpcap 0.8, so that libpcap had pcap_findalldevs but
 742 dnl pcap.h didn't have pcap_if_t.
 743     savedcppflags="$CPPFLAGS"
 744     CPPFLAGS="$CPPFLAGS $V_INCLS"
 745     AC_CHECK_TYPES(pcap_if_t, , , [#include <pcap.h>])
 746     CPPFLAGS="$savedcppflags"
 747 fi
 748 AC_CHECK_FUNCS(pcap_dump_flush pcap_lib_version)
 749 if test $ac_cv_func_pcap_lib_version = "no" ; then
 750     AC_MSG_CHECKING(whether pcap_version is defined by libpcap)
 751     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
 752         extern char pcap_version[];
 753
 754         return (int)pcap_version;
 755        ]])
 756        ],
 757        [ac_lbl_cv_pcap_version_defined=yes],
 758        [ac_lbl_cv_pcap_version_defined=no])
 759     if test "$ac_lbl_cv_pcap_version_defined" = yes ; then
 760         AC_MSG_RESULT(yes)
 761         AC_DEFINE(HAVE_PCAP_VERSION, 1, [define if libpcap has pcap_version])
 762     else
 763         AC_MSG_RESULT(no)
 764     fi
 765 fi
 766 AC_CHECK_FUNCS(pcap_setdirection pcap_set_immediate_mode pcap_dump_ftell64)
 767 AC_CHECK_FUNCS(pcap_open pcap_findalldevs_ex)
 768 AC_REPLACE_FUNCS(pcap_dump_ftell)
 769
 770 #
 771 # Check for special debugging functions
 772 #
 773 AC_CHECK_FUNCS(pcap_set_parser_debug)
 774 if test "$ac_cv_func_pcap_set_parser_debug" = "no" ; then
 775         #
 776         # OK, we don't have pcap_set_parser_debug() to set the libpcap
 777         # filter expression parser debug flag; can we directly set the
 778         # flag?
 779         AC_MSG_CHECKING(whether pcap_debug is defined by libpcap)
 780         AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
 781                 extern int pcap_debug;
 782
 783                 return pcap_debug;
 784            ]])
 785            ],
 786            [ac_lbl_cv_pcap_debug_defined=yes],
 787            [ac_lbl_cv_pcap_debug_defined=no])
 788         if test "$ac_lbl_cv_pcap_debug_defined" = yes ; then
 789                 AC_MSG_RESULT(yes)
 790                 AC_DEFINE(HAVE_PCAP_DEBUG, 1, [define if libpcap has pcap_debug])
 791         else
 792                 AC_MSG_RESULT(no)
 793                 #
 794                 # OK, what about "yydebug"?
 795                 #
 796                 AC_MSG_CHECKING(whether yydebug is defined by libpcap)
 797                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
 798                         extern int yydebug;
 799
 800                         return yydebug;
 801                    ]])
 802                    ],
 803                    [ac_lbl_cv_yydebug_defined=yes],
 804                    [ac_lbl_cv_yydebug_defined=no])
 805                 if test "$ac_lbl_cv_yydebug_defined" = yes ; then
 806                         AC_MSG_RESULT(yes)
 807                         AC_DEFINE(HAVE_YYDEBUG, 1, [define if libpcap has yydebug])
 808                 else
 809                         AC_MSG_RESULT(no)
 810                 fi
 811         fi
 812 fi
 813 AC_CHECK_FUNCS(pcap_set_optimizer_debug)
 814 AC_REPLACE_FUNCS(bpf_dump)      dnl moved to libpcap in 0.6
 815
 816 V_GROUP=0
 817 if test -f /etc/group -a ! -z "`grep '^wheel:' /etc/group`" ; then
 818         V_GROUP=wheel
 819 fi
 820 #
 821 # Assume V7/BSD convention for man pages (file formats in section 5,
 822 # miscellaneous info in section 7).
 823 #
 824 MAN_FILE_FORMATS=5
 825 MAN_MISC_INFO=7
 826 case "$host_os" in
 827
 828 aix*)
 829         dnl Workaround to enable certain features
 830         AC_DEFINE(_SUN,1,[define on AIX to get certain functions])
 831         ;;
 832
 833 hpux*)
 834         #
 835         # Use System V conventions for man pages.
 836         #
 837         MAN_FILE_FORMATS=4
 838         MAN_MISC_INFO=5
 839         ;;
 840
 841 irix*)
 842         V_GROUP=sys
 843
 844         #
 845         # Use System V conventions for man pages.
 846         #
 847         MAN_FILE_FORMATS=4
 848         MAN_MISC_INFO=5
 849         ;;
 850
 851 osf*)
 852         V_GROUP=system
 853
 854         #
 855         # Use System V conventions for man pages.
 856         #
 857         MAN_FILE_FORMATS=4
 858         MAN_MISC_INFO=5
 859         ;;
 860
 861 solaris*)
 862         V_GROUP=sys
 863
 864         #
 865         # Use System V conventions for man pages.
 866         #
 867         MAN_FILE_FORMATS=4
 868         MAN_MISC_INFO=5
 869         ;;
 870 esac
 871
 872 if test -f /dev/bpf0 ; then
 873         V_GROUP=bpf
 874 fi
 875
 876 #
 877 # Make sure we have a definition for C99's uintptr_t (regardless of
 878 # whether the environment is a C99 environment or not).
 879 #
 880 AC_TYPE_UINTPTR_T
 881
 882 #
 883 # Check whether we have pcap/pcap-inttypes.h.
 884 # If we do, we use that to get the C99 types defined.
 885 #
 886 savedcppflags="$CPPFLAGS"
 887 CPPFLAGS="$CPPFLAGS $V_INCLS"
 888 AC_CHECK_HEADERS(pcap/pcap-inttypes.h)
 889 CPPFLAGS="$savedcppflags"
 890
 891 #
 892 # Define the old BSD specified-width types in terms of the C99 types;
 893 # we may need them with libpcap include files.
 894 #
 895 AC_CHECK_TYPE([u_int8_t], ,
 896         [AC_DEFINE([u_int8_t], [uint8_t],
 897         [Define to `uint8_t' if u_int8_t not defined.])],
 898         [AC_INCLUDES_DEFAULT
 899 #include <sys/types.h>
 900 ])
 901 AC_CHECK_TYPE([u_int16_t], ,
 902         [AC_DEFINE([u_int16_t], [uint16_t],
 903         [Define to `uint16_t' if u_int16_t not defined.])],
 904         [AC_INCLUDES_DEFAULT
 905 #include <sys/types.h>
 906 ])
 907 AC_CHECK_TYPE([u_int32_t], ,
 908         [AC_DEFINE([u_int32_t], [uint32_t],
 909         [Define to `uint32_t' if u_int32_t not defined.])],
 910         [AC_INCLUDES_DEFAULT
 911 #include <sys/types.h>
 912 ])
 913 AC_CHECK_TYPE([u_int64_t], ,
 914         [AC_DEFINE([u_int64_t], [uint64_t],
 915         [Define to `uint64_t' if u_int64_t not defined.])],
 916         [AC_INCLUDES_DEFAULT
 917 #include <sys/types.h>
 918 ])
 919
 920 AC_PROG_RANLIB
 921 AC_CHECK_TOOL([AR], [ar])
 922
 923 AC_LBL_DEVEL(V_CCOPT)
 924
 925 # Check for OpenSSL/libressl libcrypto
 926 AC_MSG_CHECKING(whether to use OpenSSL/libressl libcrypto)
 927 # Specify location for both includes and libraries.
 928 want_libcrypto=ifavailable
 929 AC_ARG_WITH(crypto,
 930     AS_HELP_STRING([--with-crypto]@<:@=DIR@:>@,
 931                    [use OpenSSL/libressl libcrypto (located in directory DIR, if specified) @<:@default=yes, if available@:>@]),
 932 [
 933         if test $withval = no
 934         then
 935                 # User doesn't want to link with libcrypto.
 936                 want_libcrypto=no
 937                 AC_MSG_RESULT(no)
 938         elif test $withval = yes
 939         then
 940                 # User wants to link with libcrypto but hasn't specified
 941                 # a directory.
 942                 want_libcrypto=yes
 943                 AC_MSG_RESULT(yes)
 944         else
 945                 # User wants to link with libcrypto and has specified
 946                 # a directory, so use the provided value.
 947                 want_libcrypto=yes
 948                 libcrypto_root=$withval
 949                 AC_MSG_RESULT([yes, using the version installed in $withval])
 950
 951                 #
 952                 # Put the subdirectories of the libcrypto root directory
 953                 # at the front of the header and library search path.
 954                 #
 955                 CFLAGS="-I$withval/include $CFLAGS"
 956                 LIBS="-L$withval/lib $LIBS"
 957         fi
 958 ],[
 959         #
 960         # Use libcrypto if it's present, otherwise don't; no directory
 961         # was specified.
 962         #
 963         want_libcrypto=ifavailable
 964         AC_MSG_RESULT([yes, if available])
 965 ])
 966 if test "$want_libcrypto" != "no"; then
 967         #
 968         # Don't check for libcrypto unless we have its headers;
 969         # Apple, bless their pointy little heads, apparently ship
 970         # libcrypto as a library, but not the header files, in
 971         # El Capitan, probably because they don't want you writing
 972         # nasty portable code that could run on other UN*Xes, they
 973         # want you writing code that uses their Shiny New Crypto
 974         # Library and that only runs on macOS.
 975         #
 976         AC_CHECK_HEADER(openssl/crypto.h,
 977         [
 978                 AC_CHECK_LIB(crypto, DES_cbc_encrypt)
 979                 if test "$ac_cv_lib_crypto_DES_cbc_encrypt" = "yes"; then
 980                         AC_CHECK_HEADERS(openssl/evp.h)
 981                         #
 982                         # OK, then:
 983                         #
 984                         # 1) do we have EVP_CIPHER_CTX_new?
 985                         # If so, we use it to allocate an
 986                         # EVP_CIPHER_CTX, as EVP_CIPHER_CTX may be
 987                         # opaque; otherwise, we allocate it ourselves.
 988                         #
 989                         # 2) do we have EVP_DecryptInit_ex()?
 990                         # If so, we use it, because we need to be
 991                         # able to make two "initialize the cipher"
 992                         # calls, one with the cipher and key, and
 993                         # one with the IV, and, as of OpenSSL 1.1,
 994                         # You Can't Do That with EVP_DecryptInit(),
 995                         # because a call to EVP_DecryptInit() will
 996                         # unconditionally clear the context, and
 997                         # if you don't supply a cipher, it'll
 998                         # clear the cipher, rendering the context
 999                         # unusable and causing a crash.
1000                         #
1001                         AC_CHECK_FUNCS(EVP_CIPHER_CTX_new EVP_DecryptInit_ex)
1002                 fi
1003         ])
1004 fi
1005
1006 # Check for libcap-ng
1007 AC_MSG_CHECKING(whether to use libcap-ng)
1008 # Specify location for both includes and libraries.
1009 want_libcap_ng=ifavailable
1010 AC_ARG_WITH(cap_ng,
1011     AS_HELP_STRING([--with-cap-ng],
1012                    [use libcap-ng @<:@default=yes, if available@:>@]),
1013 [
1014         if test $withval = no
1015         then
1016                 want_libcap_ng=no
1017                 AC_MSG_RESULT(no)
1018         elif test $withval = yes
1019         then
1020                 want_libcap_ng=yes
1021                 AC_MSG_RESULT(yes)
1022         fi
1023 ],[
1024         #
1025         # Use libcap-ng if it's present, otherwise don't.
1026         #
1027         want_libcap_ng=ifavailable
1028         AC_MSG_RESULT([yes, if available])
1029 ])
1030 if test "$want_libcap_ng" != "no"; then
1031         AC_CHECK_LIB(cap-ng, capng_change_id)
1032         AC_CHECK_HEADERS(cap-ng.h)
1033 fi
1034
1035 dnl
1036 dnl set additional include path if necessary
1037 if test "$missing_includes" = "yes"; then
1038         CPPFLAGS="$CPPFLAGS -I$srcdir/missing"
1039         V_INCLS="$V_INCLS -I$srcdir/missing"
1040 fi
1041
1042 AC_SUBST(V_CCOPT)
1043 AC_SUBST(V_DEFS)
1044 AC_SUBST(V_GROUP)
1045 AC_SUBST(V_INCLS)
1046 AC_SUBST(V_PCAPDEP)
1047 AC_SUBST(LOCALSRC)
1048 AC_SUBST(MAN_FILE_FORMATS)
1049 AC_SUBST(MAN_MISC_INFO)
1050
1051 AC_PROG_INSTALL
1052
1053 AC_CONFIG_HEADERS([config.h])
1054
1055 AC_CONFIG_COMMANDS([.devel],[[if test -f .devel; then
1056         echo timestamp > stamp-h
1057         cat $srcdir/Makefile-devel-adds >> Makefile
1058         make depend || exit 1
1059 fi]])
1060 AC_CONFIG_FILES([Makefile tcpdump.1])
1061 AC_OUTPUT
1062 exit 0