]> The Tcpdump Group git mirrors - tcpdump/blob - configure.ac
projects / tcpdump / blob


6d29d945bd30c29f1c7cd7a6f0dbd2202cb96cf1
[tcpdump] / configure.ac
1 dnl Copyright (c) 1994, 1995, 1996, 1997
2 dnl The Regents of the University of California. All rights reserved.
3 dnl
4 dnl Process this file with autoconf to produce a configure script.
5 dnl
6
7 #
8 # See
9 #
10 # https://ftp.gnu.org/gnu/config/README
11 #
12 # for the URLs to use to fetch new versions of config.guess and
13 # config.sub.
14 #
15
16 AC_PREREQ(2.64)
17 AC_INIT(tcpdump, m4_esyscmd_s([cat VERSION]))
18 AC_CONFIG_SRCDIR(tcpdump.c)
19
20 AC_CANONICAL_HOST
21
22 AC_LBL_C_INIT_BEFORE_CC(V_INCLS)
23 #
24 # Try to enable as many C99 features as we can.
25 # At minimum, we want C++/C99-style // comments.
26 #
27 AC_PROG_CC_C99
28 if test "$ac_cv_prog_cc_c99" = "no"; then
29 AC_MSG_WARN([The C compiler does not support C99; there may be compiler errors])
30 fi
31 AC_LBL_C_INIT(V_CCOPT, V_INCLS)
32 AC_LBL_C_INLINE
33
34 AC_CHECK_HEADERS(fcntl.h rpc/rpc.h rpc/rpcent.h net/if.h)
35 AC_CHECK_HEADERS(net/pfvar.h, , , [#include <sys/types.h>
36 #include <sys/socket.h>
37 #include <net/if.h>])
38 if test "$ac_cv_header_net_pfvar_h" = yes; then
39 AC_CHECK_HEADERS(net/if_pflog.h, , , [#include <sys/types.h>
40 #include <sys/socket.h>
41 #include <net/if.h>
42 #include <net/pfvar.h>])
43 if test "$ac_cv_header_net_if_pflog_h" = yes; then
44 LOCALSRC="print-pflog.c $LOCALSRC"
45 fi
46 fi
47
48 case "$host_os" in
49
50 darwin*)
51 AC_ARG_ENABLE(universal,
52 AS_HELP_STRING([--disable-universal],[don't build universal on macOS]))
53 if test "$enable_universal" != "no"; then
54 case "$host_os" in
55
56 darwin9.*)
57 #
58 # Leopard. Build for x86 and 32-bit PowerPC, with
59 # x86 first. (That's what Apple does.)
60 #
61 V_CCOPT="$V_CCOPT -arch i386 -arch ppc"
62 LDFLAGS="$LDFLAGS -arch i386 -arch ppc"
63 ;;
64
65 darwin10.*)
66 #
67 # Snow Leopard. Build for x86-64 and x86, with
68 # x86-64 first. (That's what Apple does.)
69 #
70 V_CCOPT="$V_CCOPT -arch x86_64 -arch i386"
71 LDFLAGS="$LDFLAGS -arch x86_64 -arch i386"
72 ;;
73 esac
74 fi
75 ;;
76 esac
77
78
79 AC_ARG_WITH([smi],
80 [AS_HELP_STRING([--with-smi],
81 [link with libsmi (allows to load MIBs on the fly to decode SNMP packets) [default=yes, if available]])],
82 [],
83 [with_smi=yes])
84
85 if test "x$with_smi" != "xno" ; then
86 AC_CHECK_HEADER(smi.h,
87 [
88 #
89 # OK, we found smi.h. Do we have libsmi with smiInit?
90 #
91 AC_CHECK_LIB(smi, smiInit,
92 [
93 #
94 # OK, we have libsmi with smiInit. Can we use it?
95 #
96 AC_MSG_CHECKING([whether to enable libsmi])
97 savedlibs="$LIBS"
98 LIBS="-lsmi $LIBS"
99 AC_TRY_RUN(
100 [
101 /* libsmi available check */
102 #include <smi.h>
103 main()
104 {
105 int current, revision, age, n;
106 const int required = 2;
107 if (smiInit(""))
108 exit(1);
109 if (strcmp(SMI_LIBRARY_VERSION, smi_library_version))
110 exit(2);
111 n = sscanf(smi_library_version, "%d:%d:%d", &current, &revision, &age);
112 if (n != 3)
113 exit(3);
114 if (required < current - age || required > current)
115 exit(4);
116 exit(0);
117 }
118 ],
119 [
120 AC_MSG_RESULT(yes)
121 AC_DEFINE(USE_LIBSMI, 1,
122 [Define if you enable support for libsmi])
123 ],
124 [
125 dnl autoconf documentation says that
126 dnl $? contains the exit value.
127 dnl reality is that it does not.
128 dnl We leave this in just in case
129 dnl autoconf ever comes back to
130 dnl match the documentation.
131 case $? in
132 1) AC_MSG_RESULT(no - smiInit failed) ;;
133 2) AC_MSG_RESULT(no - header/library version mismatch) ;;
134 3) AC_MSG_RESULT(no - can't determine library version) ;;
135 4) AC_MSG_RESULT(no - too old) ;;
136 *) AC_MSG_RESULT(no) ;;
137 esac
138 LIBS="$savedlibs"
139 ],
140 [
141 AC_MSG_RESULT(not when cross-compiling)
142 LIBS="$savedlibs"
143 ]
144 )
145 ])
146 ])
147 fi
148
149 AC_MSG_CHECKING([whether to enable the instrument functions code])
150 AC_ARG_ENABLE([instrument-functions],
151 [AS_HELP_STRING([--enable-instrument-functions],
152 [enable instrument functions code [default=no]])],
153 [],
154 [enableval=no])
155 case "$enableval" in
156 yes) AC_MSG_RESULT(yes)
157 AC_DEFINE(ENABLE_INSTRUMENT_FUNCTIONS, 1,
158 [define if you want to build the instrument functions code])
159 LOCALSRC="$LOCALSRC instrument-functions.c"
160 CFLAGS="$CFLAGS -finstrument-functions"
161 LDFLAGS="$LDFLAGS -Wl,--export-dynamic"
162 LIBS="$LIBS -ldl"
163 ;;
164 *) AC_MSG_RESULT(no)
165 ;;
166 esac
167
168 AC_MSG_CHECKING([whether to enable the possibly-buggy SMB printer])
169 AC_ARG_ENABLE([smb],
170 [AS_HELP_STRING([--enable-smb],
171 [enable possibly-buggy SMB printer [default=no]])],
172 [],
173 [enableval=no])
174 case "$enableval" in
175 yes) AC_MSG_RESULT(yes)
176 AC_DEFINE(ENABLE_SMB, 1,
177 [define if you want to build the possibly-buggy SMB printer])
178 LOCALSRC="print-smb.c smbutil.c $LOCALSRC"
179 ;;
180 *) AC_MSG_RESULT(no)
181 ;;
182 esac
183
184 AC_ARG_WITH(user, [ --with-user=USERNAME drop privileges by default to USERNAME])
185 AC_MSG_CHECKING([whether to drop root privileges by default])
186 if test ! -z "$with_user" ; then
187 AC_DEFINE_UNQUOTED(WITH_USER, "$withval",
188 [define if should drop privileges by default])
189 AC_MSG_RESULT(to \"$withval\")
190 else
191 AC_MSG_RESULT(no)
192 fi
193
194 AC_ARG_WITH(chroot, [ --with-chroot=DIRECTORY when dropping privileges, chroot to DIRECTORY])
195 AC_MSG_CHECKING([whether to chroot])
196 if test ! -z "$with_chroot" && test "$with_chroot" != "no" ; then
197 AC_DEFINE_UNQUOTED(WITH_CHROOT, "$withval",
198 [define if should chroot when dropping privileges])
199 AC_MSG_RESULT(to \"$withval\")
200 else
201 AC_MSG_RESULT(no)
202 fi
203
204 AC_ARG_WITH(sandbox-capsicum,
205 AS_HELP_STRING([--with-sandbox-capsicum],
206 [use Capsicum security functions @<:@default=yes, if available@:>@]))
207 #
208 # Check whether various functions are available. If any are, set
209 # ac_lbl_capsicum_function_seen to yes; if any are not, set
210 # ac_lbl_capsicum_function_not_seen to yes.
211 #
212 # We don't check cap_rights_init(), as it's a macro, wrapping another
213 # function, in at least some versions of FreeBSD, and AC_CHECK_FUNCS()
214 # doesn't handle that.
215 #
216 # All of the ones we check for must be available in order to enable
217 # capsicum sandboxing.
218 #
219 # XXX - do we need to check for all of them, or are there some that, if
220 # present, imply others are present?
221 #
222 if test -z "$with_sandbox_capsicum" || test "$with_sandbox_capsicum" != "no" ; then
223 #
224 # First, make sure we have the required header.
225 #
226 AC_CHECK_HEADER(sys/capsicum.h,
227 [
228 #
229 # We do; now make sure we have the required functions.
230 #
231 AC_CHECK_FUNCS(cap_enter cap_rights_limit cap_ioctls_limit openat,
232 ac_lbl_capsicum_function_seen=yes,
233 ac_lbl_capsicum_function_not_seen=yes)
234 ])
235 AC_CHECK_LIB(casper, cap_init, LIBS="$LIBS -lcasper")
236 AC_CHECK_LIB(cap_dns, cap_gethostbyaddr, LIBS="$LIBS -lcap_dns")
237 fi
238 AC_MSG_CHECKING([whether to sandbox using capsicum])
239 if test "x$ac_lbl_capsicum_function_seen" = "xyes" -a "x$ac_lbl_capsicum_function_not_seen" != "xyes"; then
240 AC_DEFINE(HAVE_CAPSICUM, 1, [capsicum support available])
241 AC_MSG_RESULT(yes)
242 else
243 AC_MSG_RESULT(no)
244 fi
245 AC_MSG_CHECKING([whether to sandbox using Casper library])
246 if test "x$ac_cv_lib_casper_cap_init" = "xyes" -a "x$ac_cv_lib_cap_dns_cap_gethostbyaddr" = "xyes"; then
247 AC_DEFINE(HAVE_CASPER, 1, [Casper support available])
248 AC_MSG_RESULT(yes)
249 else
250 AC_MSG_RESULT(no)
251 fi
252
253 #
254 # We must check this before checking whether to check the OS's IPv6,
255 # support because, on some platforms (such as SunOS 5.x), the test
256 # program requires the extra networking libraries.
257 #
258 AC_LBL_LIBRARY_NET
259
260 #
261 # Check whether AF_INET6 and struct in6_addr are defined.
262 # If they aren't both defined, we don't have sufficient OS
263 # support for IPv6, so we don't look for IPv6 support libraries,
264 # and we define AF_INET6 and struct in6_addr ourselves.
265 #
266 AC_MSG_CHECKING([whether the operating system supports IPv6])
267 AC_COMPILE_IFELSE(
268 [
269 AC_LANG_SOURCE(
270 [[
271 /* AF_INET6 available check */
272 #include <sys/types.h>
273 #ifdef _WIN32
274 #include <ws2tcpip.h>
275 #else
276 #include <sys/socket.h>
277 #include <netinet/in.h>
278 #endif
279 #ifdef AF_INET6
280 void
281 foo(struct in6_addr *addr)
282 {
283 memset(addr, 0, sizeof (struct in6_addr));
284 }
285 #else
286 #error "AF_INET6 not defined"
287 #endif
288 ]])
289 ],
290 [
291 AC_MSG_RESULT(yes)
292 AC_DEFINE(HAVE_OS_IPV6_SUPPORT, 1,
293 [define if the OS provides AF_INET6 and struct in6_addr])
294 ipv6=yes
295 ],
296 [
297 AC_MSG_RESULT(no)
298 ipv6=no
299 ]
300 )
301
302 ipv6type=unknown
303 ipv6lib=none
304 ipv6trylibc=no
305
306 if test "$ipv6" = "yes"; then
307 AC_MSG_CHECKING([ipv6 stack type])
308 for i in inria kame linux-glibc linux-libinet6 toshiba v6d zeta; do
309 case $i in
310 inria)
311 dnl http://www.kame.net/
312 AC_EGREP_CPP(yes,
313 [#include <netinet/in.h>
314 #ifdef IPV6_INRIA_VERSION
315 yes
316 #endif],
317 [ipv6type=$i])
318 ;;
319 kame)
320 dnl http://www.kame.net/
321 AC_EGREP_CPP(yes,
322 [#include <netinet/in.h>
323 #ifdef __KAME__
324 yes
325 #endif],
326 [ipv6type=$i;
327 ipv6lib=inet6;
328 ipv6libdir=/usr/local/v6/lib;
329 ipv6trylibc=yes])
330 ;;
331 linux-glibc)
332 dnl http://www.v6.linux.or.jp/
333 AC_EGREP_CPP(yes,
334 [#include <features.h>
335 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
336 yes
337 #endif],
338 [ipv6type=$i])
339 ;;
340 linux-libinet6)
341 dnl http://www.v6.linux.or.jp/
342 dnl
343 dnl This also matches Solaris 8 and Tru64 UNIX 5.1,
344 dnl and possibly other versions of those OSes
345 dnl
346 if test -d /usr/inet6 -o -f /usr/include/netinet/ip6.h; then
347 ipv6type=$i
348 ipv6lib=inet6
349 ipv6libdir=/usr/inet6/lib
350 ipv6trylibc=yes;
351 CFLAGS="-I/usr/inet6/include $CFLAGS"
352 fi
353 ;;
354 toshiba)
355 AC_EGREP_CPP(yes,
356 [#include <sys/param.h>
357 #ifdef _TOSHIBA_INET6
358 yes
359 #endif],
360 [ipv6type=$i;
361 ipv6lib=inet6;
362 ipv6libdir=/usr/local/v6/lib])
363 ;;
364 v6d)
365 AC_EGREP_CPP(yes,
366 [#include </usr/local/v6/include/sys/v6config.h>
367 #ifdef __V6D__
368 yes
369 #endif],
370 [ipv6type=$i;
371 ipv6lib=v6;
372 ipv6libdir=/usr/local/v6/lib;
373 CFLAGS="-I/usr/local/v6/include $CFLAGS"])
374 ;;
375 zeta)
376 AC_EGREP_CPP(yes,
377 [#include <sys/param.h>
378 #ifdef _ZETA_MINAMI_INET6
379 yes
380 #endif],
381 [ipv6type=$i;
382 ipv6lib=inet6;
383 ipv6libdir=/usr/local/v6/lib])
384 ;;
385 esac
386 if test "$ipv6type" != "unknown"; then
387 break
388 fi
389 done
390 AC_MSG_RESULT($ipv6type)
391 fi
392
393 if test "$ipv6" = "yes" -a "$ipv6lib" != "none"; then
394 if test -d $ipv6libdir -a -f $ipv6libdir/lib$ipv6lib.a; then
395 LIBS="-L$ipv6libdir -l$ipv6lib $LIBS"
396 echo "You have $ipv6lib library, using it"
397 else
398 if test "$ipv6trylibc" = "yes"; then
399 echo "You do not have $ipv6lib library, using libc"
400 else
401 echo 'Fatal: no $ipv6lib library found. cannot continue.'
402 echo "You need to fetch lib$ipv6lib.a from appropriate"
403 echo 'ipv6 kit and compile beforehand.'
404 exit 1
405 fi
406 fi
407 fi
408
409 AC_REPLACE_FUNCS(strlcat strlcpy strdup strsep getservent getopt_long)
410 AC_CHECK_FUNCS(fork vfork strftime)
411 AC_CHECK_FUNCS(setlinebuf)
412
413 #
414 # Make sure we have vsnprintf() and snprintf(); we require them.
415 #
416 AC_CHECK_FUNC(vsnprintf,,
417 AC_MSG_ERROR([vsnprintf() is required but wasn't found]))
418 AC_CHECK_FUNC(snprintf,,
419 AC_MSG_ERROR([snprintf() is required but wasn't found]))
420
421 #
422 # Define HAVE_NO_PRINTF_Z to make it possible to disable test cases that
423 # depend on %zu.
424 #
425 AC_MSG_CHECKING([whether printf(3) supports the z length modifier])
426 AC_RUN_IFELSE(
427 [
428 AC_LANG_SOURCE([[
429 #include <stdio.h>
430 #include <string.h>
431
432 int main()
433 {
434 char buf[100];
435 snprintf(buf, sizeof(buf), "%zu", sizeof(buf));
436 return strncmp(buf, "100", sizeof(buf)) ? 1 : 0;
437 }
438 ]])
439 ],
440 [
441 AC_MSG_RESULT(yes)
442 ],
443 [
444 AC_MSG_RESULT(no)
445 AC_DEFINE(HAVE_NO_PRINTF_Z, 1,
446 [Define to 1 if printf(3) does not support the z length modifier.])
447 ],
448 [
449 AC_MSG_RESULT(not while cross-compiling)
450 ]
451 )
452
453 AC_CHECK_LIB(rpc, main) dnl It's unclear why we might need -lrpc
454
455 dnl Some platforms may need -lnsl for getrpcbynumber.
456 AC_SEARCH_LIBS(getrpcbynumber, nsl,
457 AC_DEFINE(HAVE_GETRPCBYNUMBER, 1, [define if you have getrpcbynumber()]))
458
459 AC_LBL_LIBPCAP(V_PCAPDEP, V_INCLS)
460
461 #
462 # Check for these after AC_LBL_LIBPCAP, so we link with the appropriate
463 # libraries (e.g., "-lsocket -lnsl" on Solaris).
464 #
465 # You are in a twisty little maze of UN*Xes, all different.
466 # Some might not have ether_ntohost().
467 # Some might have it and declare it in <net/ethernet.h>.
468 # Some might have it and declare it in <netinet/ether.h>
469 # Some might have it and declare it in <sys/ethernet.h>.
470 # Some might have it and declare it in <arpa/inet.h>.
471 # Some might have it and declare it in <netinet/if_ether.h>.
472 # Some might have it and not declare it in any header file.
473 #
474 # Before you is a C compiler.
475 #
476 AC_CHECK_FUNCS(ether_ntohost, [
477 AC_CACHE_CHECK(for buggy ether_ntohost, ac_cv_buggy_ether_ntohost, [
478 AC_TRY_RUN([
479 #include <netdb.h>
480 #include <sys/types.h>
481 #include <sys/param.h>
482 #include <sys/socket.h>
483
484 int
485 main(int argc, char **argv)
486 {
487 u_char ea[6] = { 0xff, 0xff, 0xff, 0xff, 0xff };
488 char name[MAXHOSTNAMELEN];
489
490 ether_ntohost(name, (struct ether_addr *)ea);
491 exit(0);
492 }
493 ], [ac_cv_buggy_ether_ntohost=no],
494 [ac_cv_buggy_ether_ntohost=yes],
495 [ac_cv_buggy_ether_ntohost="not while cross-compiling"])])
496 if test "$ac_cv_buggy_ether_ntohost" = "no"; then
497 AC_DEFINE(USE_ETHER_NTOHOST, 1,
498 [define if you have ether_ntohost() and it works])
499 fi
500 ])
501 if test "$ac_cv_func_ether_ntohost" = yes -a \
502 "$ac_cv_buggy_ether_ntohost" = "no"; then
503 #
504 # OK, we have ether_ntohost(). Is it declared in <net/ethernet.h>?
505 #
506 # This test fails if we don't have <net/ethernet.h> or if we do
507 # but it doesn't declare ether_ntohost().
508 #
509 AC_CHECK_DECL(ether_ntohost,
510 [
511 AC_DEFINE(NET_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
512 [Define to 1 if net/ethernet.h declares `ether_ntohost'])
513 ],,
514 [
515 #include <net/ethernet.h>
516 ])
517 #
518 # Did that succeed?
519 #
520 if test "$ac_cv_have_decl_ether_ntohost" != yes; then
521 #
522 # No, how about <netinet/ether.h>, as on Linux?
523 #
524 # This test fails if we don't have <netinet/ether.h>
525 # or if we do but it doesn't declare ether_ntohost().
526 #
527 # Unset ac_cv_have_decl_ether_ntohost so we don't
528 # treat the previous failure as a cached value and
529 # suppress the next test.
530 #
531 unset ac_cv_have_decl_ether_ntohost
532 AC_CHECK_DECL(ether_ntohost,
533 [
534 AC_DEFINE(NETINET_ETHER_H_DECLARES_ETHER_NTOHOST,,
535 [Define to 1 if netinet/ether.h declares `ether_ntohost'])
536 ],,
537 [
538 #include <netinet/ether.h>
539 ])
540 fi
541 #
542 # Did that succeed?
543 #
544 if test "$ac_cv_have_decl_ether_ntohost" != yes; then
545 #
546 # No, how about <sys/ethernet.h>, as on Solaris 10
547 # and later?
548 #
549 # This test fails if we don't have <sys/ethernet.h>
550 # or if we do but it doesn't declare ether_ntohost().
551 #
552 # Unset ac_cv_have_decl_ether_ntohost so we don't
553 # treat the previous failure as a cached value and
554 # suppress the next test.
555 #
556 unset ac_cv_have_decl_ether_ntohost
557 AC_CHECK_DECL(ether_ntohost,
558 [
559 AC_DEFINE(SYS_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
560 [Define to 1 if sys/ethernet.h declares `ether_ntohost'])
561 ],,
562 [
563 #include <sys/ethernet.h>
564 ])
565 fi
566 #
567 # Did that succeed?
568 #
569 if test "$ac_cv_have_decl_ether_ntohost" != yes; then
570 #
571 # No, how about <arpa/inet.h>, as in AIX?
572 #
573 # This test fails if we don't have <arpa/inet.h>
574 # (if we have ether_ntohost(), we should have
575 # networking, and if we have networking, we should
576 # have <arpa/inet.h>) or if we do but it doesn't
577 # declare ether_ntohost().
578 #
579 # Unset ac_cv_have_decl_ether_ntohost so we don't
580 # treat the previous failure as a cached value and
581 # suppress the next test.
582 #
583 unset ac_cv_have_decl_ether_ntohost
584 AC_CHECK_DECL(ether_ntohost,
585 [
586 AC_DEFINE(ARPA_INET_H_DECLARES_ETHER_NTOHOST,,
587 [Define to 1 if arpa/inet.h declares `ether_ntohost'])
588 ],,
589 [
590 #include <arpa/inet.h>
591 ])
592 fi
593 #
594 # Did that succeed?
595 #
596 if test "$ac_cv_have_decl_ether_ntohost" != yes; then
597 #
598 # No, how about <netinet/if_ether.h>?
599 # On some platforms, it requires <net/if.h> and
600 # <netinet/in.h>, and we always include it with
601 # both of them, so test it with both of them.
602 #
603 # This test fails if we don't have <netinet/if_ether.h>
604 # and the headers we include before it, or if we do but
605 # <netinet/if_ether.h> doesn't declare ether_hostton().
606 #
607 # Unset ac_cv_have_decl_ether_ntohost so we don't
608 # treat the previous failure as a cached value and
609 # suppress the next test.
610 #
611 unset ac_cv_have_decl_ether_ntohost
612 AC_CHECK_DECL(ether_ntohost,
613 [
614 AC_DEFINE(NETINET_IF_ETHER_H_DECLARES_ETHER_NTOHOST,,
615 [Define to 1 if netinet/if_ether.h declares `ether_ntohost'])
616 ],,
617 [
618 #include <sys/types.h>
619 #include <sys/socket.h>
620 #include <net/if.h>
621 #include <netinet/in.h>
622 #include <netinet/if_ether.h>
623 ])
624 fi
625 #
626 # After all that, is ether_ntohost() declared?
627 #
628 if test "$ac_cv_have_decl_ether_ntohost" = yes; then
629 #
630 # Yes.
631 #
632 AC_DEFINE(HAVE_DECL_ETHER_NTOHOST, 1,
633 [Define to 1 if you have the declaration of `ether_ntohost'])
634 else
635 #
636 # No, we'll have to declare it ourselves.
637 # Do we have "struct ether_addr" if we include
638 # <netinet/if_ether.h>?
639 #
640 AC_CHECK_TYPES(struct ether_addr,,,
641 [
642 #include <sys/types.h>
643 #include <sys/socket.h>
644 #include <net/if.h>
645 #include <netinet/in.h>
646 #include <netinet/if_ether.h>
647 ])
648 fi
649 fi
650
651 dnl
652 dnl Check for "pcap_list_datalinks()" and use a substitute version if
653 dnl it's not present. If it is present, check for "pcap_free_datalinks()";
654 dnl if it's not present, we don't replace it for now. (We could do so
655 dnl on UN*X, but not on Windows, where hilarity ensues if a program
656 dnl built with one version of the MSVC support library tries to free
657 dnl something allocated by a library built with another version of
658 dnl the MSVC support library.)
659 dnl
660 AC_CHECK_FUNC(pcap_list_datalinks,
661 [
662 AC_DEFINE(HAVE_PCAP_LIST_DATALINKS, 1,
663 [define if libpcap has pcap_list_datalinks()])
664 AC_CHECK_FUNCS(pcap_free_datalinks)
665 ],
666 [
667 AC_LIBOBJ(datalinks)
668 ])
669
670 dnl
671 dnl Check for "pcap_datalink_name_to_val()", and use a substitute
672 dnl version if it's not present. If it is present, check for
673 dnl "pcap_datalink_val_to_description()", and if we don't have it,
674 dnl use a substitute version.
675 dnl
676 AC_CHECK_FUNC(pcap_datalink_name_to_val,
677 [
678 AC_DEFINE(HAVE_PCAP_DATALINK_NAME_TO_VAL, 1,
679 [define if libpcap has pcap_datalink_name_to_val()])
680 AC_CHECK_FUNC(pcap_datalink_val_to_description,
681 AC_DEFINE(HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION, 1,
682 [define if libpcap has pcap_datalink_val_to_description()]),
683 [
684 AC_LIBOBJ(dlnames)
685 ])
686 ],
687 [
688 AC_LIBOBJ(dlnames)
689 ])
690
691 dnl
692 dnl Check for "pcap_set_datalink()"; you can't substitute for it if
693 dnl it's absent (it has hooks into libpcap), so just define the
694 dnl HAVE_ value if it's there.
695 dnl
696 AC_CHECK_FUNCS(pcap_set_datalink)
697
698 dnl
699 dnl Check for "pcap_breakloop()"; you can't substitute for it if
700 dnl it's absent (it has hooks into the live capture routines),
701 dnl so just define the HAVE_ value if it's there.
702 dnl
703 AC_CHECK_FUNCS(pcap_breakloop)
704
705 #
706 # Do we have the new open API? Check for pcap_create, and assume that,
707 # if we do, we also have pcap_activate() and the other new routines
708 # introduced in libpcap 1.0.0.
709 #
710 AC_CHECK_FUNCS(pcap_create)
711 if test $ac_cv_func_pcap_create = "yes" ; then
712 #
713 # OK, do we have pcap_set_tstamp_type? If so, assume we have
714 # pcap_list_tstamp_types and pcap_free_tstamp_types as well.
715 #
716 AC_CHECK_FUNCS(pcap_set_tstamp_type)
717 #
718 # And do we have pcap_set_tstamp_precision? If so, we assume
719 # we also have pcap_open_offline_with_tstamp_precision.
720 #
721 AC_CHECK_FUNCS(pcap_set_tstamp_precision)
722 fi
723
724 #
725 # Check for a miscellaneous collection of functions which we use
726 # if we have them.
727 #
728 AC_CHECK_FUNCS(pcap_findalldevs)
729 if test $ac_cv_func_pcap_findalldevs = "yes" ; then
730 dnl Check for libpcap having pcap_findalldevs() but the pcap.h header
731 dnl not having pcap_if_t; some versions of Mac OS X shipped with pcap.h
732 dnl from 0.6 and libpcap 0.8, so that libpcap had pcap_findalldevs but
733 dnl pcap.h didn't have pcap_if_t.
734 savedcppflags="$CPPFLAGS"
735 CPPFLAGS="$CPPFLAGS $V_INCLS"
736 AC_CHECK_TYPES(pcap_if_t, , , [#include <pcap.h>])
737 CPPFLAGS="$savedcppflags"
738 fi
739 AC_CHECK_FUNCS(pcap_dump_flush pcap_lib_version)
740 if test $ac_cv_func_pcap_lib_version = "no" ; then
741 AC_MSG_CHECKING(whether pcap_version is defined by libpcap)
742 AC_TRY_LINK([],
743 [
744 extern char pcap_version[];
745
746 return (int)pcap_version;
747 ],
748 ac_lbl_cv_pcap_version_defined=yes,
749 ac_lbl_cv_pcap_version_defined=no)
750 if test "$ac_lbl_cv_pcap_version_defined" = yes ; then
751 AC_MSG_RESULT(yes)
752 AC_DEFINE(HAVE_PCAP_VERSION, 1, [define if libpcap has pcap_version])
753 else
754 AC_MSG_RESULT(no)
755 fi
756 fi
757 AC_CHECK_FUNCS(pcap_setdirection pcap_set_immediate_mode pcap_dump_ftell64)
758 AC_CHECK_FUNCS(pcap_open pcap_findalldevs_ex)
759 AC_REPLACE_FUNCS(pcap_dump_ftell)
760
761 #
762 # Check for special debugging functions
763 #
764 AC_CHECK_FUNCS(pcap_set_parser_debug)
765 if test "$ac_cv_func_pcap_set_parser_debug" = "no" ; then
766 #
767 # OK, we don't have pcap_set_parser_debug() to set the libpcap
768 # filter expression parser debug flag; can we directly set the
769 # flag?
770 AC_MSG_CHECKING(whether pcap_debug is defined by libpcap)
771 AC_TRY_LINK([],
772 [
773 extern int pcap_debug;
774
775 return pcap_debug;
776 ],
777 ac_lbl_cv_pcap_debug_defined=yes,
778 ac_lbl_cv_pcap_debug_defined=no)
779 if test "$ac_lbl_cv_pcap_debug_defined" = yes ; then
780 AC_MSG_RESULT(yes)
781 AC_DEFINE(HAVE_PCAP_DEBUG, 1, [define if libpcap has pcap_debug])
782 else
783 AC_MSG_RESULT(no)
784 #
785 # OK, what about "yydebug"?
786 #
787 AC_MSG_CHECKING(whether yydebug is defined by libpcap)
788 AC_TRY_LINK([],
789 [
790 extern int yydebug;
791
792 return yydebug;
793 ],
794 ac_lbl_cv_yydebug_defined=yes,
795 ac_lbl_cv_yydebug_defined=no)
796 if test "$ac_lbl_cv_yydebug_defined" = yes ; then
797 AC_MSG_RESULT(yes)
798 AC_DEFINE(HAVE_YYDEBUG, 1, [define if libpcap has yydebug])
799 else
800 AC_MSG_RESULT(no)
801 fi
802 fi
803 fi
804 AC_CHECK_FUNCS(pcap_set_optimizer_debug)
805 AC_REPLACE_FUNCS(bpf_dump) dnl moved to libpcap in 0.6
806
807 V_GROUP=0
808 if test -f /etc/group -a ! -z "`grep '^wheel:' /etc/group`" ; then
809 V_GROUP=wheel
810 fi
811 #
812 # Assume V7/BSD convention for man pages (file formats in section 5,
813 # miscellaneous info in section 7).
814 #
815 MAN_FILE_FORMATS=5
816 MAN_MISC_INFO=7
817 case "$host_os" in
818
819 aix*)
820 dnl Workaround to enable certain features
821 AC_DEFINE(_SUN,1,[define on AIX to get certain functions])
822 ;;
823
824 hpux*)
825 #
826 # Use System V conventions for man pages.
827 #
828 MAN_FILE_FORMATS=4
829 MAN_MISC_INFO=5
830 ;;
831
832 irix*)
833 V_GROUP=sys
834
835 #
836 # Use System V conventions for man pages.
837 #
838 MAN_FILE_FORMATS=4
839 MAN_MISC_INFO=5
840 ;;
841
842 osf*)
843 V_GROUP=system
844
845 #
846 # Use System V conventions for man pages.
847 #
848 MAN_FILE_FORMATS=4
849 MAN_MISC_INFO=5
850 ;;
851
852 solaris*)
853 V_GROUP=sys
854
855 #
856 # Use System V conventions for man pages.
857 #
858 MAN_FILE_FORMATS=4
859 MAN_MISC_INFO=5
860 ;;
861 esac
862
863 if test -f /dev/bpf0 ; then
864 V_GROUP=bpf
865 fi
866
867 #
868 # Make sure we have a definition for C99's uintptr_t (regardless of
869 # whether the environment is a C99 environment or not).
870 #
871 AC_TYPE_UINTPTR_T
872
873 #
874 # Check whether we have pcap/pcap-inttypes.h.
875 # If we do, we use that to get the C99 types defined.
876 #
877 savedcppflags="$CPPFLAGS"
878 CPPFLAGS="$CPPFLAGS $V_INCLS"
879 AC_CHECK_HEADERS(pcap/pcap-inttypes.h)
880 CPPFLAGS="$savedcppflags"
881
882 #
883 # Define the old BSD specified-width types in terms of the C99 types;
884 # we may need them with libpcap include files.
885 #
886 AC_CHECK_TYPE([u_int8_t], ,
887 [AC_DEFINE([u_int8_t], [uint8_t],
888 [Define to `uint8_t' if u_int8_t not defined.])],
889 [AC_INCLUDES_DEFAULT
890 #include <sys/types.h>
891 ])
892 AC_CHECK_TYPE([u_int16_t], ,
893 [AC_DEFINE([u_int16_t], [uint16_t],
894 [Define to `uint16_t' if u_int16_t not defined.])],
895 [AC_INCLUDES_DEFAULT
896 #include <sys/types.h>
897 ])
898 AC_CHECK_TYPE([u_int32_t], ,
899 [AC_DEFINE([u_int32_t], [uint32_t],
900 [Define to `uint32_t' if u_int32_t not defined.])],
901 [AC_INCLUDES_DEFAULT
902 #include <sys/types.h>
903 ])
904 AC_CHECK_TYPE([u_int64_t], ,
905 [AC_DEFINE([u_int64_t], [uint64_t],
906 [Define to `uint64_t' if u_int64_t not defined.])],
907 [AC_INCLUDES_DEFAULT
908 #include <sys/types.h>
909 ])
910
911 AC_PROG_RANLIB
912 AC_CHECK_TOOL([AR], [ar])
913
914 AC_LBL_DEVEL(V_CCOPT)
915
916 # Check for OpenSSL/libressl libcrypto
917 AC_MSG_CHECKING(whether to use OpenSSL/libressl libcrypto)
918 # Specify location for both includes and libraries.
919 want_libcrypto=ifavailable
920 AC_ARG_WITH(crypto,
921 AS_HELP_STRING([--with-crypto]@<:@=DIR@:>@,
922 [use OpenSSL/libressl libcrypto (located in directory DIR, if specified) @<:@default=yes, if available@:>@]),
923 [
924 if test $withval = no
925 then
926 # User doesn't want to link with libcrypto.
927 want_libcrypto=no
928 AC_MSG_RESULT(no)
929 elif test $withval = yes
930 then
931 # User wants to link with libcrypto but hasn't specified
932 # a directory.
933 want_libcrypto=yes
934 AC_MSG_RESULT(yes)
935 else
936 # User wants to link with libcrypto and has specified
937 # a directory, so use the provided value.
938 want_libcrypto=yes
939 libcrypto_root=$withval
940 AC_MSG_RESULT([yes, using the version installed in $withval])
941
942 #
943 # Put the subdirectories of the libcrypto root directory
944 # at the front of the header and library search path.
945 #
946 CFLAGS="-I$withval/include $CFLAGS"
947 LIBS="-L$withval/lib $LIBS"
948 fi
949 ],[
950 #
951 # Use libcrypto if it's present, otherwise don't; no directory
952 # was specified.
953 #
954 want_libcrypto=ifavailable
955 AC_MSG_RESULT([yes, if available])
956 ])
957 if test "$want_libcrypto" != "no"; then
958 #
959 # Don't check for libcrypto unless we have its headers;
960 # Apple, bless their pointy little heads, apparently ship
961 # libcrypto as a library, but not the header files, in
962 # El Capitan, probably because they don't want you writing
963 # nasty portable code that could run on other UN*Xes, they
964 # want you writing code that uses their Shiny New Crypto
965 # Library and that only runs on macOS.
966 #
967 AC_CHECK_HEADER(openssl/crypto.h,
968 [
969 AC_CHECK_LIB(crypto, DES_cbc_encrypt)
970 if test "$ac_cv_lib_crypto_DES_cbc_encrypt" = "yes"; then
971 AC_CHECK_HEADERS(openssl/evp.h)
972 #
973 # OK, then:
974 #
975 # 1) do we have EVP_CIPHER_CTX_new?
976 # If so, we use it to allocate an
977 # EVP_CIPHER_CTX, as EVP_CIPHER_CTX may be
978 # opaque; otherwise, we allocate it ourselves.
979 #
980 # 2) do we have EVP_DecryptInit_ex()?
981 # If so, we use it, because we need to be
982 # able to make two "initialize the cipher"
983 # calls, one with the cipher and key, and
984 # one with the IV, and, as of OpenSSL 1.1,
985 # You Can't Do That with EVP_DecryptInit(),
986 # because a call to EVP_DecryptInit() will
987 # unconditionally clear the context, and
988 # if you don't supply a cipher, it'll
989 # clear the cipher, rendering the context
990 # unusable and causing a crash.
991 #
992 AC_CHECK_FUNCS(EVP_CIPHER_CTX_new EVP_DecryptInit_ex)
993 fi
994 ])
995 fi
996
997 # Check for libcap-ng
998 AC_MSG_CHECKING(whether to use libcap-ng)
999 # Specify location for both includes and libraries.
1000 want_libcap_ng=ifavailable
1001 AC_ARG_WITH(cap_ng,
1002 AS_HELP_STRING([--with-cap-ng],
1003 [use libcap-ng @<:@default=yes, if available@:>@]),
1004 [
1005 if test $withval = no
1006 then
1007 want_libcap_ng=no
1008 AC_MSG_RESULT(no)
1009 elif test $withval = yes
1010 then
1011 want_libcap_ng=yes
1012 AC_MSG_RESULT(yes)
1013 fi
1014 ],[
1015 #
1016 # Use libcap-ng if it's present, otherwise don't.
1017 #
1018 want_libcap_ng=ifavailable
1019 AC_MSG_RESULT([yes, if available])
1020 ])
1021 if test "$want_libcap_ng" != "no"; then
1022 AC_CHECK_LIB(cap-ng, capng_change_id)
1023 AC_CHECK_HEADERS(cap-ng.h)
1024 fi
1025
1026 dnl
1027 dnl set additional include path if necessary
1028 if test "$missing_includes" = "yes"; then
1029 CPPFLAGS="$CPPFLAGS -I$srcdir/missing"
1030 V_INCLS="$V_INCLS -I$srcdir/missing"
1031 fi
1032
1033 AC_SUBST(V_CCOPT)
1034 AC_SUBST(V_DEFS)
1035 AC_SUBST(V_GROUP)
1036 AC_SUBST(V_INCLS)
1037 AC_SUBST(V_PCAPDEP)
1038 AC_SUBST(LOCALSRC)
1039 AC_SUBST(MAN_FILE_FORMATS)
1040 AC_SUBST(MAN_MISC_INFO)
1041
1042 AC_PROG_INSTALL
1043
1044 AC_CONFIG_HEADER(config.h)
1045
1046 AC_OUTPUT_COMMANDS([if test -f .devel; then
1047 echo timestamp > stamp-h
1048 cat $srcdir/Makefile-devel-adds >> Makefile
1049 make depend || exit 1
1050 fi])
1051 AC_OUTPUT(Makefile tcpdump.1)
1052 exit 0
[mirror] the TCPdump network dissector