The Tcpdump Group git mirrors - tcpdump/blob - configure.ac

   1 dnl Copyright (c) 1994, 1995, 1996, 1997
   2 dnl     The Regents of the University of California.  All rights reserved.
   3 dnl
   4 dnl Process this file with autoconf to produce a configure script.
   5 dnl
   6
   7 #
   8 # See
   9 #
  10 #       http://ftp.gnu.org/gnu/config/README
  11 #
  12 # for the URLs to use to fetch new versions of config.guess and
  13 # config.sub.
  14 #
  15
  16 AC_PREREQ(2.64)
  17 AC_INIT(tcpdump, m4_esyscmd_s([cat VERSION]))
  18 AC_CONFIG_SRCDIR(tcpdump.c)
  19
  20 AC_CANONICAL_HOST
  21
  22 AC_LBL_C_INIT_BEFORE_CC(V_INCLS)
  23 #
  24 # Try to enable as many C99 features as we can.
  25 # At minimum, we want C++/C99-style // comments.
  26 #
  27 AC_PROG_CC_C99
  28 if test "$ac_cv_prog_cc_c99" = "no"; then
  29         AC_MSG_WARN([The C compiler does not support C99; there may be compiler errors])
  30 fi
  31 AC_LBL_C_INIT(V_CCOPT, V_INCLS)
  32 AC_LBL_C_INLINE
  33
  34 AC_CHECK_HEADERS(fcntl.h rpc/rpc.h rpc/rpcent.h net/if.h)
  35 AC_CHECK_HEADERS(net/pfvar.h, , , [#include <sys/types.h>
  36 #include <sys/socket.h>
  37 #include <net/if.h>])
  38 if test "$ac_cv_header_net_pfvar_h" = yes; then
  39         AC_CHECK_HEADERS(net/if_pflog.h, , , [#include <sys/types.h>
  40         #include <sys/socket.h>
  41         #include <net/if.h>
  42         #include <net/pfvar.h>])
  43         if test "$ac_cv_header_net_if_pflog_h" = yes; then
  44                 LOCALSRC="print-pflog.c $LOCALSRC"
  45         fi
  46 fi
  47
  48 case "$host_os" in
  49
  50 darwin*)
  51         AC_ARG_ENABLE(universal,
  52         AC_HELP_STRING([--disable-universal],[don't build universal on macOS]))
  53         if test "$enable_universal" != "no"; then
  54                 case "$host_os" in
  55
  56                 darwin9.*)
  57                         #
  58                         # Leopard.  Build for x86 and 32-bit PowerPC, with
  59                         # x86 first.  (That's what Apple does.)
  60                         #
  61                         V_CCOPT="$V_CCOPT -arch i386 -arch ppc"
  62                         LDFLAGS="$LDFLAGS -arch i386 -arch ppc"
  63                         ;;
  64
  65                 darwin10.*)
  66                         #
  67                         # Snow Leopard.  Build for x86-64 and x86, with
  68                         # x86-64 first.  (That's what Apple does.)
  69                         #
  70                         V_CCOPT="$V_CCOPT -arch x86_64 -arch i386"
  71                         LDFLAGS="$LDFLAGS -arch x86_64 -arch i386"
  72                         ;;
  73                 esac
  74         fi
  75         ;;
  76 esac
  77
  78
  79 AC_ARG_WITH(smi,
  80 [  --with-smi              link with libsmi (allows to load MIBs on the fly to decode SNMP packets. [default=yes]
  81   --without-smi           don't link with libsmi],,
  82    with_smi=yes)
  83
  84 if test "x$with_smi" != "xno" ; then
  85         AC_CHECK_HEADER(smi.h,
  86         [
  87                 #
  88                 # OK, we found smi.h.  Do we have libsmi with smiInit?
  89                 #
  90                 AC_CHECK_LIB(smi, smiInit,
  91                 [
  92                         #
  93                         # OK, we have libsmi with smiInit.  Can we use it?
  94                         #
  95                         AC_MSG_CHECKING([whether to enable libsmi])
  96                         savedlibs="$LIBS"
  97                         LIBS="-lsmi $LIBS"
  98                         AC_TRY_RUN(
  99                                 [
 100 /* libsmi available check */
 101 #include <smi.h>
 102 main()
 103 {
 104   int current, revision, age, n;
 105   const int required = 2;
 106   if (smiInit(""))
 107     exit(1);
 108   if (strcmp(SMI_LIBRARY_VERSION, smi_library_version))
 109     exit(2);
 110   n = sscanf(smi_library_version, "%d:%d:%d", &current, &revision, &age);
 111   if (n != 3)
 112     exit(3);
 113   if (required < current - age || required > current)
 114     exit(4);
 115   exit(0);
 116 }
 117                                 ],
 118                                 [
 119                                         AC_MSG_RESULT(yes)
 120                                         AC_DEFINE(USE_LIBSMI, 1,
 121                                             [Define if you enable support for libsmi])
 122                                 ],
 123                                 [
 124                                         dnl autoconf documentation says that
 125                                         dnl $? contains the exit value.
 126                                         dnl reality is that it does not.
 127                                         dnl We leave this in just in case
 128                                         dnl autoconf ever comes back to
 129                                         dnl match the documentation.
 130                                         case $? in
 131                                           1) AC_MSG_RESULT(no - smiInit failed) ;;
 132                                           2) AC_MSG_RESULT(no - header/library version mismatch) ;;
 133                                           3) AC_MSG_RESULT(no - can't determine library version) ;;
 134                                           4) AC_MSG_RESULT(no - too old) ;;
 135                                           *) AC_MSG_RESULT(no) ;;
 136                                         esac
 137                                         LIBS="$savedlibs"
 138                                 ],
 139                                 [
 140                                         AC_MSG_RESULT(not when cross-compiling)
 141                                         LIBS="$savedlibs"
 142                                 ]
 143                         )
 144                 ])
 145         ])
 146 fi
 147
 148 AC_MSG_CHECKING([whether to enable the possibly-buggy SMB printer])
 149 AC_ARG_ENABLE(smb,
 150 [  --enable-smb            enable possibly-buggy SMB printer [default=yes]
 151   --disable-smb           disable possibly-buggy SMB printer],,
 152    enableval=yes)
 153 case "$enableval" in
 154 yes)    AC_MSG_RESULT(yes)
 155         AC_DEFINE(ENABLE_SMB, 1,
 156             [define if you want to build the possibly-buggy SMB printer])
 157         LOCALSRC="print-smb.c smbutil.c $LOCALSRC"
 158         ;;
 159 *)      AC_MSG_RESULT(no)
 160         ;;
 161 esac
 162
 163 AC_ARG_WITH(user, [  --with-user=USERNAME    drop privileges by default to USERNAME])
 164 AC_MSG_CHECKING([whether to drop root privileges by default])
 165 if test ! -z "$with_user" ; then
 166        AC_DEFINE_UNQUOTED(WITH_USER, "$withval",
 167            [define if should drop privileges by default])
 168        AC_MSG_RESULT(to \"$withval\")
 169 else
 170        AC_MSG_RESULT(no)
 171 fi
 172
 173 AC_ARG_WITH(chroot, [  --with-chroot=DIRECTORY when dropping privileges, chroot to DIRECTORY])
 174 AC_MSG_CHECKING([whether to chroot])
 175 if test ! -z "$with_chroot" && test "$with_chroot" != "no" ; then
 176        AC_DEFINE_UNQUOTED(WITH_CHROOT, "$withval",
 177            [define if should chroot when dropping privileges])
 178        AC_MSG_RESULT(to \"$withval\")
 179 else
 180        AC_MSG_RESULT(no)
 181 fi
 182
 183 AC_ARG_WITH(sandbox-capsicum,
 184         AS_HELP_STRING([--with-sandbox-capsicum],
 185                        [use Capsicum security functions @<:@default=yes, if available@:>@]))
 186 #
 187 # Check whether various functions are available.  If any are, set
 188 # ac_lbl_capsicum_function_seen to yes; if any are not, set
 189 # ac_lbl_capsicum_function_not_seen to yes.
 190 #
 191 # We don't check cap_rights_init(), as it's a macro, wrapping another
 192 # function, in at least some versions of FreeBSD, and AC_CHECK_FUNCS()
 193 # doesn't handle that.
 194 #
 195 # All of the ones we check for must be available in order to enable
 196 # capsicum sandboxing.
 197 #
 198 # XXX - do we need to check for all of them, or are there some that, if
 199 # present, imply others are present?
 200 #
 201 if test ! -z "$with_sandbox_capsicum" && test "$with_sandbox_capsicum" != "no" ; then
 202         #
 203         # First, make sure we have the required header.
 204         #
 205         AC_CHECK_HEADER(sys/capsicum.h,
 206         [
 207                 #
 208                 # We do; now make sure we have the required functions.
 209                 #
 210                 AC_CHECK_FUNCS(cap_enter cap_rights_limit cap_ioctls_limit openat,
 211                     ac_lbl_capsicum_function_seen=yes,
 212                     ac_lbl_capsicum_function_not_seen=yes)
 213         ])
 214         AC_CHECK_LIB(casper, cap_init, LIBS="$LIBS -lcasper")
 215         AC_CHECK_LIB(cap_dns, cap_gethostbyaddr, LIBS="$LIBS -lcap_dns")
 216 fi
 217 AC_MSG_CHECKING([whether to sandbox using capsicum])
 218 if test "x$ac_lbl_capsicum_function_seen" = "xyes" -a "x$ac_lbl_capsicum_function_not_seen" != "xyes"; then
 219         AC_DEFINE(HAVE_CAPSICUM, 1, [capsicum support available])
 220         AC_MSG_RESULT(yes)
 221 else
 222         AC_MSG_RESULT(no)
 223 fi
 224 AC_MSG_CHECKING([whether to sandbox using Casper library])
 225 if test "x$ac_cv_lib_casper_cap_init" = "xyes" -a "x$ac_cv_lib_cap_dns_cap_gethostbyaddr" = "xyes"; then
 226         AC_DEFINE(HAVE_CASPER, 1, [Casper support available])
 227         AC_MSG_RESULT(yes)
 228 else
 229         AC_MSG_RESULT(no)
 230 fi
 231
 232 #
 233 # We must check this before checking whether to check the OS's IPv6,
 234 # support because, on some platforms (such as SunOS 5.x), the test
 235 # program requires the extra networking libraries.
 236 #
 237 AC_LBL_LIBRARY_NET
 238
 239 #
 240 # Check whether AF_INET6 and struct in6_addr are defined.
 241 # If they aren't both defined, we don't have sufficient OS
 242 # support for IPv6, so we don't look for IPv6 support libraries,
 243 # and we define AF_INET6 and struct in6_addr ourselves.
 244 #
 245 AC_MSG_CHECKING([whether the operating system supports IPv6])
 246 AC_COMPILE_IFELSE(
 247     [
 248       AC_LANG_SOURCE(
 249         [[
 250 /* AF_INET6 available check */
 251 #include <sys/types.h>
 252 #ifdef _WIN32
 253 #include <ws2tcpip.h>
 254 #else
 255 #include <sys/socket.h>
 256 #include <netinet/in.h>
 257 #endif
 258 #ifdef AF_INET6
 259 void
 260 foo(struct in6_addr *addr)
 261 {
 262  memset(addr, 0, sizeof (struct in6_addr));
 263 }
 264 #else
 265 #error "AF_INET6 not defined"
 266 #endif
 267         ]])
 268     ],
 269     [
 270         AC_MSG_RESULT(yes)
 271         AC_DEFINE(HAVE_OS_IPV6_SUPPORT, 1,
 272             [define if the OS provides AF_INET6 and struct in6_addr])
 273         ipv6=yes
 274     ],
 275     [
 276         AC_MSG_RESULT(no)
 277         ipv6=no
 278     ]
 279 )
 280
 281 ipv6type=unknown
 282 ipv6lib=none
 283 ipv6trylibc=no
 284
 285 if test "$ipv6" = "yes"; then
 286         AC_MSG_CHECKING([ipv6 stack type])
 287         for i in inria kame linux-glibc linux-libinet6 toshiba v6d zeta; do
 288                 case $i in
 289                 inria)
 290                         dnl http://www.kame.net/
 291                         AC_EGREP_CPP(yes,
 292 [#include <netinet/in.h>
 293 #ifdef IPV6_INRIA_VERSION
 294 yes
 295 #endif],
 296                                 [ipv6type=$i])
 297                         ;;
 298                 kame)
 299                         dnl http://www.kame.net/
 300                         AC_EGREP_CPP(yes,
 301 [#include <netinet/in.h>
 302 #ifdef __KAME__
 303 yes
 304 #endif],
 305                                 [ipv6type=$i;
 306                                 ipv6lib=inet6;
 307                                 ipv6libdir=/usr/local/v6/lib;
 308                                 ipv6trylibc=yes])
 309                         ;;
 310                 linux-glibc)
 311                         dnl http://www.v6.linux.or.jp/
 312                         AC_EGREP_CPP(yes,
 313 [#include <features.h>
 314 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 315 yes
 316 #endif],
 317                                 [ipv6type=$i])
 318                         ;;
 319                 linux-libinet6)
 320                         dnl http://www.v6.linux.or.jp/
 321                         dnl
 322                         dnl This also matches Solaris 8 and Tru64 UNIX 5.1,
 323                         dnl and possibly other versions of those OSes
 324                         dnl
 325                         if test -d /usr/inet6 -o -f /usr/include/netinet/ip6.h; then
 326                                 ipv6type=$i
 327                                 ipv6lib=inet6
 328                                 ipv6libdir=/usr/inet6/lib
 329                                 ipv6trylibc=yes;
 330                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 331                         fi
 332                         ;;
 333                 toshiba)
 334                         AC_EGREP_CPP(yes,
 335 [#include <sys/param.h>
 336 #ifdef _TOSHIBA_INET6
 337 yes
 338 #endif],
 339                                 [ipv6type=$i;
 340                                 ipv6lib=inet6;
 341                                 ipv6libdir=/usr/local/v6/lib])
 342                         ;;
 343                 v6d)
 344                         AC_EGREP_CPP(yes,
 345 [#include </usr/local/v6/include/sys/v6config.h>
 346 #ifdef __V6D__
 347 yes
 348 #endif],
 349                                 [ipv6type=$i;
 350                                 ipv6lib=v6;
 351                                 ipv6libdir=/usr/local/v6/lib;
 352                                 CFLAGS="-I/usr/local/v6/include $CFLAGS"])
 353                         ;;
 354                 zeta)
 355                         AC_EGREP_CPP(yes,
 356 [#include <sys/param.h>
 357 #ifdef _ZETA_MINAMI_INET6
 358 yes
 359 #endif],
 360                                 [ipv6type=$i;
 361                                 ipv6lib=inet6;
 362                                 ipv6libdir=/usr/local/v6/lib])
 363                         ;;
 364                 esac
 365                 if test "$ipv6type" != "unknown"; then
 366                         break
 367                 fi
 368         done
 369         AC_MSG_RESULT($ipv6type)
 370 fi
 371
 372 if test "$ipv6" = "yes" -a "$ipv6lib" != "none"; then
 373         if test -d $ipv6libdir -a -f $ipv6libdir/lib$ipv6lib.a; then
 374                 LIBS="-L$ipv6libdir -l$ipv6lib $LIBS"
 375                 echo "You have $ipv6lib library, using it"
 376         else
 377                 if test "$ipv6trylibc" = "yes"; then
 378                         echo "You do not have $ipv6lib library, using libc"
 379                 else
 380                         echo 'Fatal: no $ipv6lib library found.  cannot continue.'
 381                         echo "You need to fetch lib$ipv6lib.a from appropriate"
 382                         echo 'ipv6 kit and compile beforehand.'
 383                         exit 1
 384                 fi
 385         fi
 386 fi
 387
 388 AC_SEARCH_LIBS(dnet_htoa, dnet,
 389 [
 390         AC_DEFINE(HAVE_DNET_HTOA, 1,
 391             [define if you have the dnet_htoa function])
 392         #
 393         # OK, we have dnet_htoa().  Do we have netdnet/dnetdb.h?
 394         #
 395         AC_CHECK_HEADERS(netdnet/dnetdb.h)
 396         if test "$ac_cv_header_netdnet_dnetdb_h" = "yes"; then
 397                 #
 398                 # Yes.  Does it declare dnet_htoa()?
 399                 #
 400                 AC_CHECK_DECL(dnet_htoa,
 401                 [
 402                         # Yes.
 403                         AC_DEFINE(NETDNET_DNETDB_H_DECLARES_DNET_HTOA,,
 404                             [Define to 1 if netenet/dnetdb.h declares `dnet_htoa'])
 405                 ],,
 406                 [
 407 AC_INCLUDES_DEFAULT
 408 #include <netdnet/dnetdb.h>
 409                 ])
 410         fi
 411
 412         #
 413         # Do we have netdnet/dn.h?
 414         #
 415         AC_CHECK_HEADERS(netdnet/dn.h)
 416         if test "$ac_cv_header_netdnet_dn_h" = "yes"; then
 417                 #
 418                 # Yes.  Does it declare struct dn_naddr?
 419                 #
 420                 AC_CHECK_TYPES(struct dn_naddr,,,
 421                 [
 422 #include <netdnet/dn.h>
 423                 ])
 424         fi
 425 ])
 426
 427 AC_REPLACE_FUNCS(strlcat strlcpy strdup strsep getservent getopt_long)
 428 AC_CHECK_FUNCS(fork vfork strftime)
 429 AC_CHECK_FUNCS(setlinebuf)
 430
 431 #
 432 # Make sure we have vsnprintf() and snprintf(); we require them.
 433 #
 434 AC_CHECK_FUNC(vsnprintf,,
 435     AC_MSG_ERROR([vsnprintf() is required but wasn't found]))
 436 AC_CHECK_FUNC(snprintf,,
 437     AC_MSG_ERROR([snprintf() is required but wasn't found]))
 438
 439 AC_CHECK_LIB(rpc, main)         dnl It's unclear why we might need -lrpc
 440
 441 dnl Some platforms may need -lnsl for getrpcbynumber.
 442 AC_SEARCH_LIBS(getrpcbynumber, nsl,
 443     AC_DEFINE(HAVE_GETRPCBYNUMBER, 1, [define if you have getrpcbynumber()]))
 444
 445 AC_LBL_LIBPCAP(V_PCAPDEP, V_INCLS)
 446
 447 #
 448 # Check for these after AC_LBL_LIBPCAP, so we link with the appropriate
 449 # libraries (e.g., "-lsocket -lnsl" on Solaris).
 450 #
 451 # You are in a twisty little maze of UN*Xes, all different.
 452 # Some might not have ether_ntohost().
 453 # Some might have it and declare it in <net/ethernet.h>.
 454 # Some might have it and declare it in <netinet/ether.h>
 455 # Some might have it and declare it in <sys/ethernet.h>.
 456 # Some might have it and declare it in <arpa/inet.h>.
 457 # Some might have it and declare it in <netinet/if_ether.h>.
 458 # Some might have it and not declare it in any header file.
 459 #
 460 # Before you is a C compiler.
 461 #
 462 AC_CHECK_FUNCS(ether_ntohost, [
 463     AC_CACHE_CHECK(for buggy ether_ntohost, ac_cv_buggy_ether_ntohost, [
 464         AC_TRY_RUN([
 465                 #include <netdb.h>
 466                 #include <sys/types.h>
 467                 #include <sys/param.h>
 468                 #include <sys/socket.h>
 469
 470                 int
 471                 main(int argc, char **argv)
 472                 {
 473                         u_char ea[6] = { 0xff, 0xff, 0xff, 0xff, 0xff };
 474                         char name[MAXHOSTNAMELEN];
 475
 476                         ether_ntohost(name, (struct ether_addr *)ea);
 477                         exit(0);
 478                 }
 479         ], [ac_cv_buggy_ether_ntohost=no],
 480            [ac_cv_buggy_ether_ntohost=yes],
 481            [ac_cv_buggy_ether_ntohost="not while cross-compiling"])])
 482     if test "$ac_cv_buggy_ether_ntohost" = "no"; then
 483         AC_DEFINE(USE_ETHER_NTOHOST, 1,
 484             [define if you have ether_ntohost() and it works])
 485     fi
 486 ])
 487 if test "$ac_cv_func_ether_ntohost" = yes -a \
 488     "$ac_cv_buggy_ether_ntohost" = "no"; then
 489         #
 490         # OK, we have ether_ntohost().  Is it declared in <net/ethernet.h>?
 491         #
 492         # This test fails if we don't have <net/ethernet.h> or if we do
 493         # but it doesn't declare ether_ntohost().
 494         #
 495         AC_CHECK_DECL(ether_ntohost,
 496             [
 497                 AC_DEFINE(NET_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
 498                     [Define to 1 if net/ethernet.h declares `ether_ntohost'])
 499             ],,
 500             [
 501 #include <net/ethernet.h>
 502             ])
 503         #
 504         # Did that succeed?
 505         #
 506         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 507                 #
 508                 # No, how about <netinet/ether.h>, as on Linux?
 509                 #
 510                 # This test fails if we don't have <netinet/ether.h>
 511                 # or if we do but it doesn't declare ether_ntohost().
 512                 #
 513                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 514                 # treat the previous failure as a cached value and
 515                 # suppress the next test.
 516                 #
 517                 unset ac_cv_have_decl_ether_ntohost
 518                 AC_CHECK_DECL(ether_ntohost,
 519                     [
 520                         AC_DEFINE(NETINET_ETHER_H_DECLARES_ETHER_NTOHOST,,
 521                             [Define to 1 if netinet/ether.h declares `ether_ntohost'])
 522                     ],,
 523                     [
 524 #include <netinet/ether.h>
 525                     ])
 526         fi
 527         #
 528         # Did that succeed?
 529         #
 530         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 531                 #
 532                 # No, how about <sys/ethernet.h>, as on Solaris 10
 533                 # and later?
 534                 #
 535                 # This test fails if we don't have <sys/ethernet.h>
 536                 # or if we do but it doesn't declare ether_ntohost().
 537                 #
 538                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 539                 # treat the previous failure as a cached value and
 540                 # suppress the next test.
 541                 #
 542                 unset ac_cv_have_decl_ether_ntohost
 543                 AC_CHECK_DECL(ether_ntohost,
 544                     [
 545                         AC_DEFINE(SYS_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
 546                             [Define to 1 if sys/ethernet.h declares `ether_ntohost'])
 547                     ],,
 548                     [
 549 #include <sys/ethernet.h>
 550                     ])
 551         fi
 552         #
 553         # Did that succeed?
 554         #
 555         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 556                 #
 557                 # No, how about <arpa/inet.h>, as in AIX?
 558                 #
 559                 # This test fails if we don't have <arpa/inet.h>
 560                 # (if we have ether_ntohost(), we should have
 561                 # networking, and if we have networking, we should
 562                 # have <arpa/inet.h>) or if we do but it doesn't
 563                 # declare ether_ntohost().
 564                 #
 565                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 566                 # treat the previous failure as a cached value and
 567                 # suppress the next test.
 568                 #
 569                 unset ac_cv_have_decl_ether_ntohost
 570                 AC_CHECK_DECL(ether_ntohost,
 571                     [
 572                         AC_DEFINE(ARPA_INET_H_DECLARES_ETHER_NTOHOST,,
 573                             [Define to 1 if arpa/inet.h declares `ether_ntohost'])
 574                     ],,
 575                     [
 576 #include <arpa/inet.h>
 577                     ])
 578         fi
 579         #
 580         # Did that succeed?
 581         #
 582         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 583                 #
 584                 # No, how about <netinet/if_ether.h>?
 585                 # On some platforms, it requires <net/if.h> and
 586                 # <netinet/in.h>, and we always include it with
 587                 # both of them, so test it with both of them.
 588                 #
 589                 # This test fails if we don't have <netinet/if_ether.h>
 590                 # and the headers we include before it, or if we do but
 591                 # <netinet/if_ether.h> doesn't declare ether_hostton().
 592                 #
 593                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 594                 # treat the previous failure as a cached value and
 595                 # suppress the next test.
 596                 #
 597                 unset ac_cv_have_decl_ether_ntohost
 598                 AC_CHECK_DECL(ether_ntohost,
 599                     [
 600                         AC_DEFINE(NETINET_IF_ETHER_H_DECLARES_ETHER_NTOHOST,,
 601                             [Define to 1 if netinet/if_ether.h declares `ether_ntohost'])
 602                     ],,
 603                     [
 604 #include <sys/types.h>
 605 #include <sys/socket.h>
 606 #include <net/if.h>
 607 #include <netinet/in.h>
 608 #include <netinet/if_ether.h>
 609                     ])
 610         fi
 611         #
 612         # After all that, is ether_ntohost() declared?
 613         #
 614         if test "$ac_cv_have_decl_ether_ntohost" = yes; then
 615                 #
 616                 # Yes.
 617                 #
 618                 AC_DEFINE(HAVE_DECL_ETHER_NTOHOST, 1,
 619                     [Define to 1 if you have the declaration of `ether_ntohost'])
 620         else
 621                 #
 622                 # No, we'll have to declare it ourselves.
 623                 # Do we have "struct ether_addr" if we include
 624                 # <netinet/if_ether.h>?
 625                 #
 626                 AC_CHECK_TYPES(struct ether_addr,,,
 627                     [
 628                         #include <sys/types.h>
 629                         #include <sys/socket.h>
 630                         #include <net/if.h>
 631                         #include <netinet/in.h>
 632                         #include <netinet/if_ether.h>
 633                     ])
 634         fi
 635 fi
 636
 637 dnl
 638 dnl Check for "pcap_list_datalinks()" and use a substitute version if
 639 dnl it's not present.  If it is present, check for "pcap_free_datalinks()";
 640 dnl if it's not present, we don't replace it for now.  (We could do so
 641 dnl on UN*X, but not on Windows, where hilarity ensues if a program
 642 dnl built with one version of the MSVC support library tries to free
 643 dnl something allocated by a library built with another version of
 644 dnl the MSVC support library.)
 645 dnl
 646 AC_CHECK_FUNC(pcap_list_datalinks,
 647         [
 648             AC_DEFINE(HAVE_PCAP_LIST_DATALINKS, 1,
 649                 [define if libpcap has pcap_list_datalinks()])
 650             AC_CHECK_FUNCS(pcap_free_datalinks)
 651         ],
 652         [
 653             AC_LIBOBJ(datalinks)
 654         ])
 655
 656 dnl
 657 dnl Check for "pcap_datalink_name_to_val()", and use a substitute
 658 dnl version if it's not present.  If it is present, check for
 659 dnl "pcap_datalink_val_to_description()", and if we don't have it,
 660 dnl use a substitute version.
 661 dnl
 662 AC_CHECK_FUNC(pcap_datalink_name_to_val,
 663         [
 664             AC_DEFINE(HAVE_PCAP_DATALINK_NAME_TO_VAL, 1,
 665                 [define if libpcap has pcap_datalink_name_to_val()])
 666             AC_CHECK_FUNC(pcap_datalink_val_to_description,
 667                 AC_DEFINE(HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION, 1,
 668                     [define if libpcap has pcap_datalink_val_to_description()]),
 669                 [
 670                     AC_LIBOBJ(dlnames)
 671                 ])
 672         ],
 673         [
 674             AC_LIBOBJ(dlnames)
 675         ])
 676
 677 dnl
 678 dnl Check for "pcap_set_datalink()"; you can't substitute for it if
 679 dnl it's absent (it has hooks into libpcap), so just define the
 680 dnl HAVE_ value if it's there.
 681 dnl
 682 AC_CHECK_FUNCS(pcap_set_datalink)
 683
 684 dnl
 685 dnl Check for "pcap_breakloop()"; you can't substitute for it if
 686 dnl it's absent (it has hooks into the live capture routines),
 687 dnl so just define the HAVE_ value if it's there.
 688 dnl
 689 AC_CHECK_FUNCS(pcap_breakloop)
 690
 691 #
 692 # Do we have the new open API?  Check for pcap_create, and assume that,
 693 # if we do, we also have pcap_activate() and the other new routines
 694 # introduced in libpcap 1.0.0.
 695 #
 696 AC_CHECK_FUNCS(pcap_create)
 697 if test $ac_cv_func_pcap_create = "yes" ; then
 698         #
 699         # OK, do we have pcap_set_tstamp_type?  If so, assume we have
 700         # pcap_list_tstamp_types and pcap_free_tstamp_types as well.
 701         #
 702         AC_CHECK_FUNCS(pcap_set_tstamp_type)
 703         #
 704         # And do we have pcap_set_tstamp_precision?  If so, we assume
 705         # we also have pcap_open_offline_with_tstamp_precision.
 706         #
 707         AC_CHECK_FUNCS(pcap_set_tstamp_precision)
 708 fi
 709
 710 #
 711 # Check for a miscellaneous collection of functions which we use
 712 # if we have them.
 713 #
 714 AC_CHECK_FUNCS(pcap_findalldevs)
 715 if test $ac_cv_func_pcap_findalldevs = "yes" ; then
 716 dnl Check for libpcap having pcap_findalldevs() but the pcap.h header
 717 dnl not having pcap_if_t; some versions of Mac OS X shipped with pcap.h
 718 dnl from 0.6 and libpcap 0.8, so that libpcap had pcap_findalldevs but
 719 dnl pcap.h didn't have pcap_if_t.
 720     savedcppflags="$CPPFLAGS"
 721     CPPFLAGS="$CPPFLAGS $V_INCLS"
 722     AC_CHECK_TYPES(pcap_if_t, , , [#include <pcap.h>])
 723     CPPFLAGS="$savedcppflags"
 724 fi
 725 AC_CHECK_FUNCS(pcap_dump_flush pcap_lib_version)
 726 if test $ac_cv_func_pcap_lib_version = "no" ; then
 727     AC_MSG_CHECKING(whether pcap_version is defined by libpcap)
 728     AC_TRY_LINK([],
 729        [
 730         extern char pcap_version[];
 731
 732         return (int)pcap_version;
 733        ],
 734        ac_lbl_cv_pcap_version_defined=yes,
 735        ac_lbl_cv_pcap_version_defined=no)
 736     if test "$ac_lbl_cv_pcap_version_defined" = yes ; then
 737         AC_MSG_RESULT(yes)
 738         AC_DEFINE(HAVE_PCAP_VERSION, 1, [define if libpcap has pcap_version])
 739     else
 740         AC_MSG_RESULT(no)
 741     fi
 742 fi
 743 AC_CHECK_FUNCS(pcap_setdirection pcap_set_immediate_mode pcap_dump_ftell64)
 744 AC_CHECK_FUNCS(pcap_open pcap_findalldevs_ex)
 745 AC_REPLACE_FUNCS(pcap_dump_ftell)
 746
 747 #
 748 # Check for special debugging functions
 749 #
 750 AC_CHECK_FUNCS(pcap_set_parser_debug)
 751 if test "$ac_cv_func_pcap_set_parser_debug" = "no" ; then
 752         #
 753         # OK, we don't have pcap_set_parser_debug() to set the libpcap
 754         # filter expression parser debug flag; can we directly set the
 755         # flag?
 756         AC_MSG_CHECKING(whether pcap_debug is defined by libpcap)
 757         AC_TRY_LINK([],
 758            [
 759                 extern int pcap_debug;
 760
 761                 return pcap_debug;
 762            ],
 763            ac_lbl_cv_pcap_debug_defined=yes,
 764            ac_lbl_cv_pcap_debug_defined=no)
 765         if test "$ac_lbl_cv_pcap_debug_defined" = yes ; then
 766                 AC_MSG_RESULT(yes)
 767                 AC_DEFINE(HAVE_PCAP_DEBUG, 1, [define if libpcap has pcap_debug])
 768         else
 769                 AC_MSG_RESULT(no)
 770                 #
 771                 # OK, what about "yydebug"?
 772                 #
 773                 AC_MSG_CHECKING(whether yydebug is defined by libpcap)
 774                 AC_TRY_LINK([],
 775                    [
 776                         extern int yydebug;
 777
 778                         return yydebug;
 779                    ],
 780                    ac_lbl_cv_yydebug_defined=yes,
 781                    ac_lbl_cv_yydebug_defined=no)
 782                 if test "$ac_lbl_cv_yydebug_defined" = yes ; then
 783                         AC_MSG_RESULT(yes)
 784                         AC_DEFINE(HAVE_YYDEBUG, 1, [define if libpcap has yydebug])
 785                 else
 786                         AC_MSG_RESULT(no)
 787                 fi
 788         fi
 789 fi
 790 AC_CHECK_FUNCS(pcap_set_optimizer_debug)
 791 AC_REPLACE_FUNCS(bpf_dump)      dnl moved to libpcap in 0.6
 792
 793 V_GROUP=0
 794 if test -f /etc/group -a ! -z "`grep '^wheel:' /etc/group`" ; then
 795         V_GROUP=wheel
 796 fi
 797 #
 798 # Assume V7/BSD convention for man pages (file formats in section 5,
 799 # miscellaneous info in section 7).
 800 #
 801 MAN_FILE_FORMATS=5
 802 MAN_MISC_INFO=7
 803 case "$host_os" in
 804
 805 aix*)
 806         dnl Workaround to enable certain features
 807         AC_DEFINE(_SUN,1,[define on AIX to get certain functions])
 808         ;;
 809
 810 hpux*)
 811         #
 812         # Use System V conventions for man pages.
 813         #
 814         MAN_FILE_FORMATS=4
 815         MAN_MISC_INFO=5
 816         ;;
 817
 818 irix*)
 819         V_GROUP=sys
 820
 821         #
 822         # Use System V conventions for man pages.
 823         #
 824         MAN_FILE_FORMATS=4
 825         MAN_MISC_INFO=5
 826         ;;
 827
 828 osf*)
 829         V_GROUP=system
 830
 831         #
 832         # Use System V conventions for man pages.
 833         #
 834         MAN_FILE_FORMATS=4
 835         MAN_MISC_INFO=5
 836         ;;
 837
 838 solaris*)
 839         V_GROUP=sys
 840
 841         #
 842         # Use System V conventions for man pages.
 843         #
 844         MAN_FILE_FORMATS=4
 845         MAN_MISC_INFO=5
 846         ;;
 847 esac
 848
 849 if test -f /dev/bpf0 ; then
 850         V_GROUP=bpf
 851 fi
 852
 853 #
 854 # Make sure we have a definition for C99's uintptr_t (regardless of
 855 # whether the environment is a C99 environment or not).
 856 #
 857 AC_TYPE_UINTPTR_T
 858
 859 #
 860 # Check whether we have pcap/pcap-inttypes.h.
 861 # If we do, we use that to get the C99 types defined.
 862 #
 863 savedcppflags="$CPPFLAGS"
 864 CPPFLAGS="$CPPFLAGS $V_INCLS"
 865 AC_CHECK_HEADERS(pcap/pcap-inttypes.h)
 866 CPPFLAGS="$savedcppflags"
 867
 868 #
 869 # Define the old BSD specified-width types in terms of the C99 types;
 870 # we may need them with libpcap include files.
 871 #
 872 AC_CHECK_TYPE([u_int8_t], ,
 873         [AC_DEFINE([u_int8_t], [uint8_t],
 874         [Define to `uint8_t' if u_int8_t not defined.])],
 875         [AC_INCLUDES_DEFAULT
 876 #include <sys/types.h>
 877 ])
 878 AC_CHECK_TYPE([u_int16_t], ,
 879         [AC_DEFINE([u_int16_t], [uint16_t],
 880         [Define to `uint16_t' if u_int16_t not defined.])],
 881         [AC_INCLUDES_DEFAULT
 882 #include <sys/types.h>
 883 ])
 884 AC_CHECK_TYPE([u_int32_t], ,
 885         [AC_DEFINE([u_int32_t], [uint32_t],
 886         [Define to `uint32_t' if u_int32_t not defined.])],
 887         [AC_INCLUDES_DEFAULT
 888 #include <sys/types.h>
 889 ])
 890 AC_CHECK_TYPE([u_int64_t], ,
 891         [AC_DEFINE([u_int64_t], [uint64_t],
 892         [Define to `uint64_t' if u_int64_t not defined.])],
 893         [AC_INCLUDES_DEFAULT
 894 #include <sys/types.h>
 895 ])
 896
 897 AC_PROG_RANLIB
 898 AC_CHECK_TOOL([AR], [ar])
 899
 900 AC_LBL_DEVEL(V_CCOPT)
 901
 902 # Check for OpenSSL/libressl libcrypto
 903 AC_MSG_CHECKING(whether to use OpenSSL/libressl libcrypto)
 904 # Specify location for both includes and libraries.
 905 want_libcrypto=ifavailable
 906 AC_ARG_WITH(crypto,
 907     AS_HELP_STRING([--with-crypto]@<:@=DIR@:>@,
 908                    [use OpenSSL/libressl libcrypto (located in directory DIR, if specified) @<:@default=yes, if available@:>@]),
 909 [
 910         if test $withval = no
 911         then
 912                 # User doesn't want to link with libcrypto.
 913                 want_libcrypto=no
 914                 AC_MSG_RESULT(no)
 915         elif test $withval = yes
 916         then
 917                 # User wants to link with libcrypto but hasn't specified
 918                 # a directory.
 919                 want_libcrypto=yes
 920                 AC_MSG_RESULT(yes)
 921         else
 922                 # User wants to link with libcrypto and has specified
 923                 # a directory, so use the provided value.
 924                 want_libcrypto=yes
 925                 libcrypto_root=$withval
 926                 AC_MSG_RESULT([yes, using the version installed in $withval])
 927
 928                 #
 929                 # Put the subdirectories of the libcrypto root directory
 930                 # at the front of the header and library search path.
 931                 #
 932                 CFLAGS="-I$withval/include $CFLAGS"
 933                 LIBS="-L$withval/lib $LIBS"
 934         fi
 935 ],[
 936         #
 937         # Use libcrypto if it's present, otherwise don't; no directory
 938         # was specified.
 939         #
 940         want_libcrypto=ifavailable
 941         AC_MSG_RESULT([yes, if available])
 942 ])
 943 if test "$want_libcrypto" != "no"; then
 944         #
 945         # Don't check for libcrypto unless we have its headers;
 946         # Apple, bless their pointy little heads, apparently ship
 947         # libcrypto as a library, but not the header files, in
 948         # El Capitan, probably because they don't want you writing
 949         # nasty portable code that could run on other UN*Xes, they
 950         # want you writing code that uses their Shiny New Crypto
 951         # Library and that only runs on macOS.
 952         #
 953         AC_CHECK_HEADER(openssl/crypto.h,
 954         [
 955                 AC_CHECK_LIB(crypto, DES_cbc_encrypt)
 956                 if test "$ac_cv_lib_crypto_DES_cbc_encrypt" = "yes"; then
 957                         AC_CHECK_HEADERS(openssl/evp.h)
 958                         #
 959                         # OK, then:
 960                         #
 961                         # 1) do we have EVP_CIPHER_CTX_new?
 962                         # If so, we use it to allocate an
 963                         # EVP_CIPHER_CTX, as EVP_CIPHER_CTX may be
 964                         # opaque; otherwise, we allocate it ourselves.
 965                         #
 966                         # 2) do we have EVP_CipherInit_ex()?
 967                         # If so, we use it, because we need to be
 968                         # able to make two "initialize the cipher"
 969                         # calls, one with the cipher and key, and
 970                         # one with the IV, and, as of OpenSSL 1.1,
 971                         # You Can't Do That with EVP_CipherInit(),
 972                         # because a call to EVP_CipherInit() will
 973                         # unconditionally clear the context, and
 974                         # if you don't supply a cipher, it'll
 975                         # clear the cipher, rendering the context
 976                         # unusable and causing a crash.
 977                         #
 978                         AC_CHECK_FUNCS(EVP_CIPHER_CTX_new EVP_CipherInit_ex)
 979                 fi
 980         ])
 981 fi
 982
 983 # Check for libcap-ng
 984 AC_MSG_CHECKING(whether to use libcap-ng)
 985 # Specify location for both includes and libraries.
 986 want_libcap_ng=ifavailable
 987 AC_ARG_WITH(cap_ng,
 988     AS_HELP_STRING([--with-cap-ng],
 989                    [use libcap-ng @<:@default=yes, if available@:>@]),
 990 [
 991         if test $withval = no
 992         then
 993                 want_libcap_ng=no
 994                 AC_MSG_RESULT(no)
 995         elif test $withval = yes
 996         then
 997                 want_libcap_ng=yes
 998                 AC_MSG_RESULT(yes)
 999         fi
1000 ],[
1001         #
1002         # Use libcap-ng if it's present, otherwise don't.
1003         #
1004         want_libcap_ng=ifavailable
1005         AC_MSG_RESULT([yes, if available])
1006 ])
1007 if test "$want_libcap_ng" != "no"; then
1008         AC_CHECK_LIB(cap-ng, capng_change_id)
1009         AC_CHECK_HEADERS(cap-ng.h)
1010 fi
1011
1012 dnl
1013 dnl set additional include path if necessary
1014 if test "$missing_includes" = "yes"; then
1015         CPPFLAGS="$CPPFLAGS -I$srcdir/missing"
1016         V_INCLS="$V_INCLS -I$srcdir/missing"
1017 fi
1018
1019 AC_SUBST(V_CCOPT)
1020 AC_SUBST(V_DEFS)
1021 AC_SUBST(V_GROUP)
1022 AC_SUBST(V_INCLS)
1023 AC_SUBST(V_PCAPDEP)
1024 AC_SUBST(LOCALSRC)
1025 AC_SUBST(MAN_FILE_FORMATS)
1026 AC_SUBST(MAN_MISC_INFO)
1027
1028 AC_PROG_INSTALL
1029
1030 AC_CONFIG_HEADER(config.h)
1031
1032 AC_OUTPUT_COMMANDS([if test -f .devel; then
1033         echo timestamp > stamp-h
1034         cat Makefile-devel-adds >> Makefile
1035         make depend
1036 fi])
1037 AC_OUTPUT(Makefile tcpdump.1)
1038 exit 0