The Tcpdump Group git mirrors - tcpdump/blob - configure.ac

   1 dnl Copyright (c) 1994, 1995, 1996, 1997
   2 dnl     The Regents of the University of California.  All rights reserved.
   3 dnl
   4 dnl Process this file with autoconf to produce a configure script.
   5 dnl
   6
   7 #
   8 # See
   9 #
  10 #       https://ftp.gnu.org/gnu/config/README
  11 #
  12 # for the URLs to use to fetch new versions of config.guess and
  13 # config.sub.
  14 #
  15
  16 AC_PREREQ(2.64)
  17 AC_INIT(tcpdump, m4_esyscmd_s([cat VERSION]))
  18 AC_CONFIG_SRCDIR(tcpdump.c)
  19
  20 AC_CANONICAL_HOST
  21
  22 AC_LBL_C_INIT_BEFORE_CC(V_INCLS)
  23 #
  24 # Try to enable as many C99 features as we can.
  25 # At minimum, we want C++/C99-style // comments.
  26 #
  27 AC_PROG_CC_C99
  28 if test "$ac_cv_prog_cc_c99" = "no"; then
  29         AC_MSG_WARN([The C compiler does not support C99; there may be compiler errors])
  30 fi
  31 AC_LBL_C_INIT(V_CCOPT, V_INCLS)
  32 AC_LBL_C_INLINE
  33
  34 AC_CHECK_HEADERS(fcntl.h rpc/rpc.h rpc/rpcent.h net/if.h)
  35 AC_CHECK_HEADERS(net/pfvar.h, , , [#include <sys/types.h>
  36 #include <sys/socket.h>
  37 #include <net/if.h>])
  38 if test "$ac_cv_header_net_pfvar_h" = yes; then
  39         AC_CHECK_HEADERS(net/if_pflog.h, , , [#include <sys/types.h>
  40         #include <sys/socket.h>
  41         #include <net/if.h>
  42         #include <net/pfvar.h>])
  43         if test "$ac_cv_header_net_if_pflog_h" = yes; then
  44                 LOCALSRC="print-pflog.c $LOCALSRC"
  45         fi
  46 fi
  47
  48 case "$host_os" in
  49
  50 darwin*)
  51         AC_ARG_ENABLE(universal,
  52         AS_HELP_STRING([--disable-universal],[don't build universal on macOS]))
  53         if test "$enable_universal" != "no"; then
  54                 case "$host_os" in
  55
  56                 darwin9.*)
  57                         #
  58                         # Leopard.  Build for x86 and 32-bit PowerPC, with
  59                         # x86 first.  (That's what Apple does.)
  60                         #
  61                         V_CCOPT="$V_CCOPT -arch i386 -arch ppc"
  62                         LDFLAGS="$LDFLAGS -arch i386 -arch ppc"
  63                         ;;
  64
  65                 darwin10.*)
  66                         #
  67                         # Snow Leopard.  Build for x86-64 and x86, with
  68                         # x86-64 first.  (That's what Apple does.)
  69                         #
  70                         V_CCOPT="$V_CCOPT -arch x86_64 -arch i386"
  71                         LDFLAGS="$LDFLAGS -arch x86_64 -arch i386"
  72                         ;;
  73                 esac
  74         fi
  75         ;;
  76 esac
  77
  78
  79 AC_ARG_WITH([smi],
  80    [AS_HELP_STRING([--with-smi],
  81      [link with libsmi (allows to load MIBs on the fly to decode SNMP packets) [default=yes, if available]])],
  82    [],
  83    [with_smi=yes])
  84
  85 if test "x$with_smi" != "xno" ; then
  86         AC_CHECK_HEADER(smi.h,
  87         [
  88                 #
  89                 # OK, we found smi.h.  Do we have libsmi with smiInit?
  90                 #
  91                 AC_CHECK_LIB(smi, smiInit,
  92                 [
  93                         #
  94                         # OK, we have libsmi with smiInit.  Can we use it?
  95                         #
  96                         AC_MSG_CHECKING([whether to enable libsmi])
  97                         savedlibs="$LIBS"
  98                         LIBS="-lsmi $LIBS"
  99                         AC_TRY_RUN(
 100                                 [
 101 /* libsmi available check */
 102 #include <smi.h>
 103 main()
 104 {
 105   int current, revision, age, n;
 106   const int required = 2;
 107   if (smiInit(""))
 108     exit(1);
 109   if (strcmp(SMI_LIBRARY_VERSION, smi_library_version))
 110     exit(2);
 111   n = sscanf(smi_library_version, "%d:%d:%d", &current, &revision, &age);
 112   if (n != 3)
 113     exit(3);
 114   if (required < current - age || required > current)
 115     exit(4);
 116   exit(0);
 117 }
 118                                 ],
 119                                 [
 120                                         AC_MSG_RESULT(yes)
 121                                         AC_DEFINE(USE_LIBSMI, 1,
 122                                             [Define if you enable support for libsmi])
 123                                 ],
 124                                 [
 125                                         dnl autoconf documentation says that
 126                                         dnl $? contains the exit value.
 127                                         dnl reality is that it does not.
 128                                         dnl We leave this in just in case
 129                                         dnl autoconf ever comes back to
 130                                         dnl match the documentation.
 131                                         case $? in
 132                                           1) AC_MSG_RESULT(no - smiInit failed) ;;
 133                                           2) AC_MSG_RESULT(no - header/library version mismatch) ;;
 134                                           3) AC_MSG_RESULT(no - can't determine library version) ;;
 135                                           4) AC_MSG_RESULT(no - too old) ;;
 136                                           *) AC_MSG_RESULT(no) ;;
 137                                         esac
 138                                         LIBS="$savedlibs"
 139                                 ],
 140                                 [
 141                                         AC_MSG_RESULT(not when cross-compiling)
 142                                         LIBS="$savedlibs"
 143                                 ]
 144                         )
 145                 ])
 146         ])
 147 fi
 148
 149 AC_MSG_CHECKING([whether to enable the instrument functions code])
 150 AC_ARG_ENABLE([instrument-functions],
 151    [AS_HELP_STRING([--enable-instrument-functions],
 152      [enable instrument functions code [default=no]])],
 153    [],
 154    [enableval=no])
 155 case "$enableval" in
 156 yes)    AC_MSG_RESULT(yes)
 157         AC_CHECK_LIB([bfd], [bfd_init],
 158             [true],
 159             [AC_MSG_ERROR(
 160                [--enable-instrument-functions was given, but test for library libbfd failed. Please install the 'binutils-dev' package.])],
 161             [])
 162         AC_DEFINE(ENABLE_INSTRUMENT_FUNCTIONS, 1,
 163             [define if you want to build the instrument functions code])
 164         LOCALSRC="$LOCALSRC instrument-functions.c"
 165         # Add '-finstrument-functions' instrumentation option to generate
 166         # instrumentation calls for entry and exit to functions.
 167         # Try to avoid Address Space Layout Randomization (ALSR).
 168         CFLAGS="$CFLAGS -O0 -ggdb -finstrument-functions -fno-stack-protector -fno-pic"
 169         LDFLAGS="$LDFLAGS -O0 -ggdb -fno-stack-protector -no-pie"
 170         LIBS="$LIBS -lbfd"
 171         ;;
 172 *)      AC_MSG_RESULT(no)
 173         ;;
 174 esac
 175
 176 AC_MSG_CHECKING([whether to enable the possibly-buggy SMB printer])
 177 AC_ARG_ENABLE([smb],
 178    [AS_HELP_STRING([--enable-smb],
 179      [enable possibly-buggy SMB printer [default=no]])],
 180    [],
 181    [enableval=no])
 182 case "$enableval" in
 183 yes)    AC_MSG_RESULT(yes)
 184         AC_DEFINE(ENABLE_SMB, 1,
 185             [define if you want to build the possibly-buggy SMB printer])
 186         LOCALSRC="print-smb.c smbutil.c $LOCALSRC"
 187         ;;
 188 *)      AC_MSG_RESULT(no)
 189         ;;
 190 esac
 191
 192 AC_ARG_WITH(user, [  --with-user=USERNAME    drop privileges by default to USERNAME])
 193 AC_MSG_CHECKING([whether to drop root privileges by default])
 194 if test ! -z "$with_user" ; then
 195        AC_DEFINE_UNQUOTED(WITH_USER, "$withval",
 196            [define if should drop privileges by default])
 197        AC_MSG_RESULT(to \"$withval\")
 198 else
 199        AC_MSG_RESULT(no)
 200 fi
 201
 202 AC_ARG_WITH(chroot, [  --with-chroot=DIRECTORY when dropping privileges, chroot to DIRECTORY])
 203 AC_MSG_CHECKING([whether to chroot])
 204 if test ! -z "$with_chroot" && test "$with_chroot" != "no" ; then
 205        AC_DEFINE_UNQUOTED(WITH_CHROOT, "$withval",
 206            [define if should chroot when dropping privileges])
 207        AC_MSG_RESULT(to \"$withval\")
 208 else
 209        AC_MSG_RESULT(no)
 210 fi
 211
 212 AC_ARG_WITH(sandbox-capsicum,
 213         AS_HELP_STRING([--with-sandbox-capsicum],
 214                        [use Capsicum security functions @<:@default=yes, if available@:>@]))
 215 #
 216 # Check whether various functions are available.  If any are, set
 217 # ac_lbl_capsicum_function_seen to yes; if any are not, set
 218 # ac_lbl_capsicum_function_not_seen to yes.
 219 #
 220 # We don't check cap_rights_init(), as it's a macro, wrapping another
 221 # function, in at least some versions of FreeBSD, and AC_CHECK_FUNCS()
 222 # doesn't handle that.
 223 #
 224 # All of the ones we check for must be available in order to enable
 225 # capsicum sandboxing.
 226 #
 227 # XXX - do we need to check for all of them, or are there some that, if
 228 # present, imply others are present?
 229 #
 230 if test -z "$with_sandbox_capsicum" || test "$with_sandbox_capsicum" != "no" ; then
 231         #
 232         # First, make sure we have the required header.
 233         #
 234         AC_CHECK_HEADER(sys/capsicum.h,
 235         [
 236                 #
 237                 # We do; now make sure we have the required functions.
 238                 #
 239                 AC_CHECK_FUNCS(cap_enter cap_rights_limit cap_ioctls_limit openat,
 240                     ac_lbl_capsicum_function_seen=yes,
 241                     ac_lbl_capsicum_function_not_seen=yes)
 242         ])
 243         AC_CHECK_LIB(casper, cap_init, LIBS="$LIBS -lcasper")
 244         AC_CHECK_LIB(cap_dns, cap_gethostbyaddr, LIBS="$LIBS -lcap_dns")
 245 fi
 246 AC_MSG_CHECKING([whether to sandbox using capsicum])
 247 if test "x$ac_lbl_capsicum_function_seen" = "xyes" -a "x$ac_lbl_capsicum_function_not_seen" != "xyes"; then
 248         AC_DEFINE(HAVE_CAPSICUM, 1, [capsicum support available])
 249         AC_MSG_RESULT(yes)
 250 else
 251         AC_MSG_RESULT(no)
 252 fi
 253 AC_MSG_CHECKING([whether to sandbox using Casper library])
 254 if test "x$ac_cv_lib_casper_cap_init" = "xyes" -a "x$ac_cv_lib_cap_dns_cap_gethostbyaddr" = "xyes"; then
 255         AC_DEFINE(HAVE_CASPER, 1, [Casper support available])
 256         AC_MSG_RESULT(yes)
 257 else
 258         AC_MSG_RESULT(no)
 259 fi
 260
 261 #
 262 # We must check this before checking whether to check the OS's IPv6,
 263 # support because, on some platforms (such as SunOS 5.x), the test
 264 # program requires the extra networking libraries.
 265 #
 266 AC_LBL_LIBRARY_NET
 267
 268 #
 269 # Check whether AF_INET6 and struct in6_addr are defined.
 270 # If they aren't both defined, we don't have sufficient OS
 271 # support for IPv6, so we don't look for IPv6 support libraries,
 272 # and we define AF_INET6 and struct in6_addr ourselves.
 273 #
 274 AC_MSG_CHECKING([whether the operating system supports IPv6])
 275 AC_COMPILE_IFELSE(
 276     [
 277       AC_LANG_SOURCE(
 278         [[
 279 /* AF_INET6 available check */
 280 #include <sys/types.h>
 281 #ifdef _WIN32
 282 #include <ws2tcpip.h>
 283 #else
 284 #include <sys/socket.h>
 285 #include <netinet/in.h>
 286 #endif
 287 #ifdef AF_INET6
 288 void
 289 foo(struct in6_addr *addr)
 290 {
 291  memset(addr, 0, sizeof (struct in6_addr));
 292 }
 293 #else
 294 #error "AF_INET6 not defined"
 295 #endif
 296         ]])
 297     ],
 298     [
 299         AC_MSG_RESULT(yes)
 300         AC_DEFINE(HAVE_OS_IPV6_SUPPORT, 1,
 301             [define if the OS provides AF_INET6 and struct in6_addr])
 302         ipv6=yes
 303     ],
 304     [
 305         AC_MSG_RESULT(no)
 306         ipv6=no
 307     ]
 308 )
 309
 310 ipv6type=unknown
 311 ipv6lib=none
 312 ipv6trylibc=no
 313
 314 if test "$ipv6" = "yes"; then
 315         AC_MSG_CHECKING([ipv6 stack type])
 316         for i in inria kame linux-glibc linux-libinet6 toshiba v6d zeta; do
 317                 case $i in
 318                 inria)
 319                         dnl http://www.kame.net/
 320                         AC_EGREP_CPP(yes,
 321 [#include <netinet/in.h>
 322 #ifdef IPV6_INRIA_VERSION
 323 yes
 324 #endif],
 325                                 [ipv6type=$i])
 326                         ;;
 327                 kame)
 328                         dnl http://www.kame.net/
 329                         AC_EGREP_CPP(yes,
 330 [#include <netinet/in.h>
 331 #ifdef __KAME__
 332 yes
 333 #endif],
 334                                 [ipv6type=$i;
 335                                 ipv6lib=inet6;
 336                                 ipv6libdir=/usr/local/v6/lib;
 337                                 ipv6trylibc=yes])
 338                         ;;
 339                 linux-glibc)
 340                         dnl http://www.v6.linux.or.jp/
 341                         AC_EGREP_CPP(yes,
 342 [#include <features.h>
 343 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 344 yes
 345 #endif],
 346                                 [ipv6type=$i])
 347                         ;;
 348                 linux-libinet6)
 349                         dnl http://www.v6.linux.or.jp/
 350                         dnl
 351                         dnl This also matches Solaris 8 and Tru64 UNIX 5.1,
 352                         dnl and possibly other versions of those OSes
 353                         dnl
 354                         if test -d /usr/inet6 -o -f /usr/include/netinet/ip6.h; then
 355                                 ipv6type=$i
 356                                 ipv6lib=inet6
 357                                 ipv6libdir=/usr/inet6/lib
 358                                 ipv6trylibc=yes;
 359                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 360                         fi
 361                         ;;
 362                 toshiba)
 363                         AC_EGREP_CPP(yes,
 364 [#include <sys/param.h>
 365 #ifdef _TOSHIBA_INET6
 366 yes
 367 #endif],
 368                                 [ipv6type=$i;
 369                                 ipv6lib=inet6;
 370                                 ipv6libdir=/usr/local/v6/lib])
 371                         ;;
 372                 v6d)
 373                         AC_EGREP_CPP(yes,
 374 [#include </usr/local/v6/include/sys/v6config.h>
 375 #ifdef __V6D__
 376 yes
 377 #endif],
 378                                 [ipv6type=$i;
 379                                 ipv6lib=v6;
 380                                 ipv6libdir=/usr/local/v6/lib;
 381                                 CFLAGS="-I/usr/local/v6/include $CFLAGS"])
 382                         ;;
 383                 zeta)
 384                         AC_EGREP_CPP(yes,
 385 [#include <sys/param.h>
 386 #ifdef _ZETA_MINAMI_INET6
 387 yes
 388 #endif],
 389                                 [ipv6type=$i;
 390                                 ipv6lib=inet6;
 391                                 ipv6libdir=/usr/local/v6/lib])
 392                         ;;
 393                 esac
 394                 if test "$ipv6type" != "unknown"; then
 395                         break
 396                 fi
 397         done
 398         AC_MSG_RESULT($ipv6type)
 399 fi
 400
 401 if test "$ipv6" = "yes" -a "$ipv6lib" != "none"; then
 402         if test -d $ipv6libdir -a -f $ipv6libdir/lib$ipv6lib.a; then
 403                 LIBS="-L$ipv6libdir -l$ipv6lib $LIBS"
 404                 echo "You have $ipv6lib library, using it"
 405         else
 406                 if test "$ipv6trylibc" = "yes"; then
 407                         echo "You do not have $ipv6lib library, using libc"
 408                 else
 409                         echo 'Fatal: no $ipv6lib library found.  cannot continue.'
 410                         echo "You need to fetch lib$ipv6lib.a from appropriate"
 411                         echo 'ipv6 kit and compile beforehand.'
 412                         exit 1
 413                 fi
 414         fi
 415 fi
 416
 417 AC_REPLACE_FUNCS(strlcat strlcpy strdup strsep getservent getopt_long)
 418 AC_CHECK_FUNCS(fork vfork strftime)
 419 AC_CHECK_FUNCS(setlinebuf)
 420
 421 #
 422 # Make sure we have vsnprintf() and snprintf(); we require them.
 423 #
 424 AC_CHECK_FUNC(vsnprintf,,
 425     AC_MSG_ERROR([vsnprintf() is required but wasn't found]))
 426 AC_CHECK_FUNC(snprintf,,
 427     AC_MSG_ERROR([snprintf() is required but wasn't found]))
 428
 429 #
 430 # Define HAVE_NO_PRINTF_Z to make it possible to disable test cases that
 431 # depend on %zu.
 432 #
 433 AC_MSG_CHECKING([whether printf(3) supports the z length modifier])
 434 AC_RUN_IFELSE(
 435     [
 436         AC_LANG_SOURCE([[
 437 #include <stdio.h>
 438 #include <string.h>
 439
 440 int main()
 441 {
 442   char buf[100];
 443   snprintf(buf, sizeof(buf), "%zu", sizeof(buf));
 444   return strncmp(buf, "100", sizeof(buf)) ? 1 : 0;
 445 }
 446         ]])
 447     ],
 448     [
 449         AC_MSG_RESULT(yes)
 450     ],
 451     [
 452         AC_MSG_RESULT(no)
 453         AC_DEFINE(HAVE_NO_PRINTF_Z, 1,
 454             [Define to 1 if printf(3) does not support the z length modifier.])
 455     ],
 456     [
 457         AC_MSG_RESULT(not while cross-compiling)
 458     ]
 459 )
 460
 461 AC_CHECK_LIB(rpc, main)         dnl It's unclear why we might need -lrpc
 462
 463 dnl Some platforms may need -lnsl for getrpcbynumber.
 464 AC_SEARCH_LIBS(getrpcbynumber, nsl,
 465     AC_DEFINE(HAVE_GETRPCBYNUMBER, 1, [define if you have getrpcbynumber()]))
 466
 467 AC_LBL_LIBPCAP(V_PCAPDEP, V_INCLS)
 468
 469 #
 470 # Check for these after AC_LBL_LIBPCAP, so we link with the appropriate
 471 # libraries (e.g., "-lsocket -lnsl" on Solaris).
 472 #
 473 # You are in a twisty little maze of UN*Xes, all different.
 474 # Some might not have ether_ntohost().
 475 # Some might have it and declare it in <net/ethernet.h>.
 476 # Some might have it and declare it in <netinet/ether.h>
 477 # Some might have it and declare it in <sys/ethernet.h>.
 478 # Some might have it and declare it in <arpa/inet.h>.
 479 # Some might have it and declare it in <netinet/if_ether.h>.
 480 # Some might have it and not declare it in any header file.
 481 #
 482 # Before you is a C compiler.
 483 #
 484 AC_CHECK_FUNCS(ether_ntohost, [
 485     AC_CACHE_CHECK(for buggy ether_ntohost, ac_cv_buggy_ether_ntohost, [
 486         AC_TRY_RUN([
 487                 #include <netdb.h>
 488                 #include <sys/types.h>
 489                 #include <sys/param.h>
 490                 #include <sys/socket.h>
 491
 492                 int
 493                 main(int argc, char **argv)
 494                 {
 495                         u_char ea[6] = { 0xff, 0xff, 0xff, 0xff, 0xff };
 496                         char name[MAXHOSTNAMELEN];
 497
 498                         ether_ntohost(name, (struct ether_addr *)ea);
 499                         exit(0);
 500                 }
 501         ], [ac_cv_buggy_ether_ntohost=no],
 502            [ac_cv_buggy_ether_ntohost=yes],
 503            [ac_cv_buggy_ether_ntohost="not while cross-compiling"])])
 504     if test "$ac_cv_buggy_ether_ntohost" = "no"; then
 505         AC_DEFINE(USE_ETHER_NTOHOST, 1,
 506             [define if you have ether_ntohost() and it works])
 507     fi
 508 ])
 509 if test "$ac_cv_func_ether_ntohost" = yes -a \
 510     "$ac_cv_buggy_ether_ntohost" = "no"; then
 511         #
 512         # OK, we have ether_ntohost().  Is it declared in <net/ethernet.h>?
 513         #
 514         # This test fails if we don't have <net/ethernet.h> or if we do
 515         # but it doesn't declare ether_ntohost().
 516         #
 517         AC_CHECK_DECL(ether_ntohost,
 518             [
 519                 AC_DEFINE(NET_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
 520                     [Define to 1 if net/ethernet.h declares `ether_ntohost'])
 521             ],,
 522             [
 523 #include <net/ethernet.h>
 524             ])
 525         #
 526         # Did that succeed?
 527         #
 528         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 529                 #
 530                 # No, how about <netinet/ether.h>, as on Linux?
 531                 #
 532                 # This test fails if we don't have <netinet/ether.h>
 533                 # or if we do but it doesn't declare ether_ntohost().
 534                 #
 535                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 536                 # treat the previous failure as a cached value and
 537                 # suppress the next test.
 538                 #
 539                 unset ac_cv_have_decl_ether_ntohost
 540                 AC_CHECK_DECL(ether_ntohost,
 541                     [
 542                         AC_DEFINE(NETINET_ETHER_H_DECLARES_ETHER_NTOHOST,,
 543                             [Define to 1 if netinet/ether.h declares `ether_ntohost'])
 544                     ],,
 545                     [
 546 #include <netinet/ether.h>
 547                     ])
 548         fi
 549         #
 550         # Did that succeed?
 551         #
 552         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 553                 #
 554                 # No, how about <sys/ethernet.h>, as on Solaris 10
 555                 # and later?
 556                 #
 557                 # This test fails if we don't have <sys/ethernet.h>
 558                 # or if we do but it doesn't declare ether_ntohost().
 559                 #
 560                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 561                 # treat the previous failure as a cached value and
 562                 # suppress the next test.
 563                 #
 564                 unset ac_cv_have_decl_ether_ntohost
 565                 AC_CHECK_DECL(ether_ntohost,
 566                     [
 567                         AC_DEFINE(SYS_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
 568                             [Define to 1 if sys/ethernet.h declares `ether_ntohost'])
 569                     ],,
 570                     [
 571 #include <sys/ethernet.h>
 572                     ])
 573         fi
 574         #
 575         # Did that succeed?
 576         #
 577         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 578                 #
 579                 # No, how about <arpa/inet.h>, as in AIX?
 580                 #
 581                 # This test fails if we don't have <arpa/inet.h>
 582                 # (if we have ether_ntohost(), we should have
 583                 # networking, and if we have networking, we should
 584                 # have <arpa/inet.h>) or if we do but it doesn't
 585                 # declare ether_ntohost().
 586                 #
 587                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 588                 # treat the previous failure as a cached value and
 589                 # suppress the next test.
 590                 #
 591                 unset ac_cv_have_decl_ether_ntohost
 592                 AC_CHECK_DECL(ether_ntohost,
 593                     [
 594                         AC_DEFINE(ARPA_INET_H_DECLARES_ETHER_NTOHOST,,
 595                             [Define to 1 if arpa/inet.h declares `ether_ntohost'])
 596                     ],,
 597                     [
 598 #include <arpa/inet.h>
 599                     ])
 600         fi
 601         #
 602         # Did that succeed?
 603         #
 604         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 605                 #
 606                 # No, how about <netinet/if_ether.h>?
 607                 # On some platforms, it requires <net/if.h> and
 608                 # <netinet/in.h>, and we always include it with
 609                 # both of them, so test it with both of them.
 610                 #
 611                 # This test fails if we don't have <netinet/if_ether.h>
 612                 # and the headers we include before it, or if we do but
 613                 # <netinet/if_ether.h> doesn't declare ether_hostton().
 614                 #
 615                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 616                 # treat the previous failure as a cached value and
 617                 # suppress the next test.
 618                 #
 619                 unset ac_cv_have_decl_ether_ntohost
 620                 AC_CHECK_DECL(ether_ntohost,
 621                     [
 622                         AC_DEFINE(NETINET_IF_ETHER_H_DECLARES_ETHER_NTOHOST,,
 623                             [Define to 1 if netinet/if_ether.h declares `ether_ntohost'])
 624                     ],,
 625                     [
 626 #include <sys/types.h>
 627 #include <sys/socket.h>
 628 #include <net/if.h>
 629 #include <netinet/in.h>
 630 #include <netinet/if_ether.h>
 631                     ])
 632         fi
 633         #
 634         # After all that, is ether_ntohost() declared?
 635         #
 636         if test "$ac_cv_have_decl_ether_ntohost" = yes; then
 637                 #
 638                 # Yes.
 639                 #
 640                 AC_DEFINE(HAVE_DECL_ETHER_NTOHOST, 1,
 641                     [Define to 1 if you have the declaration of `ether_ntohost'])
 642         else
 643                 #
 644                 # No, we'll have to declare it ourselves.
 645                 # Do we have "struct ether_addr" if we include
 646                 # <netinet/if_ether.h>?
 647                 #
 648                 AC_CHECK_TYPES(struct ether_addr,,,
 649                     [
 650                         #include <sys/types.h>
 651                         #include <sys/socket.h>
 652                         #include <net/if.h>
 653                         #include <netinet/in.h>
 654                         #include <netinet/if_ether.h>
 655                     ])
 656         fi
 657 fi
 658
 659 dnl
 660 dnl Check for "pcap_list_datalinks()" and use a substitute version if
 661 dnl it's not present.  If it is present, check for "pcap_free_datalinks()";
 662 dnl if it's not present, we don't replace it for now.  (We could do so
 663 dnl on UN*X, but not on Windows, where hilarity ensues if a program
 664 dnl built with one version of the MSVC support library tries to free
 665 dnl something allocated by a library built with another version of
 666 dnl the MSVC support library.)
 667 dnl
 668 AC_CHECK_FUNC(pcap_list_datalinks,
 669         [
 670             AC_DEFINE(HAVE_PCAP_LIST_DATALINKS, 1,
 671                 [define if libpcap has pcap_list_datalinks()])
 672             AC_CHECK_FUNCS(pcap_free_datalinks)
 673         ],
 674         [
 675             AC_LIBOBJ(datalinks)
 676         ])
 677
 678 dnl
 679 dnl Check for "pcap_datalink_name_to_val()", and use a substitute
 680 dnl version if it's not present.  If it is present, check for
 681 dnl "pcap_datalink_val_to_description()", and if we don't have it,
 682 dnl use a substitute version.
 683 dnl
 684 AC_CHECK_FUNC(pcap_datalink_name_to_val,
 685         [
 686             AC_DEFINE(HAVE_PCAP_DATALINK_NAME_TO_VAL, 1,
 687                 [define if libpcap has pcap_datalink_name_to_val()])
 688             AC_CHECK_FUNC(pcap_datalink_val_to_description,
 689                 AC_DEFINE(HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION, 1,
 690                     [define if libpcap has pcap_datalink_val_to_description()]),
 691                 [
 692                     AC_LIBOBJ(dlnames)
 693                 ])
 694         ],
 695         [
 696             AC_LIBOBJ(dlnames)
 697         ])
 698
 699 dnl
 700 dnl Check for "pcap_set_datalink()"; you can't substitute for it if
 701 dnl it's absent (it has hooks into libpcap), so just define the
 702 dnl HAVE_ value if it's there.
 703 dnl
 704 AC_CHECK_FUNCS(pcap_set_datalink)
 705
 706 dnl
 707 dnl Check for "pcap_breakloop()"; you can't substitute for it if
 708 dnl it's absent (it has hooks into the live capture routines),
 709 dnl so just define the HAVE_ value if it's there.
 710 dnl
 711 AC_CHECK_FUNCS(pcap_breakloop)
 712
 713 #
 714 # Do we have the new open API?  Check for pcap_create, and assume that,
 715 # if we do, we also have pcap_activate() and the other new routines
 716 # introduced in libpcap 1.0.0.
 717 #
 718 AC_CHECK_FUNCS(pcap_create)
 719 if test $ac_cv_func_pcap_create = "yes" ; then
 720         #
 721         # OK, do we have pcap_set_tstamp_type?  If so, assume we have
 722         # pcap_list_tstamp_types and pcap_free_tstamp_types as well.
 723         #
 724         AC_CHECK_FUNCS(pcap_set_tstamp_type)
 725         #
 726         # And do we have pcap_set_tstamp_precision?  If so, we assume
 727         # we also have pcap_open_offline_with_tstamp_precision.
 728         #
 729         AC_CHECK_FUNCS(pcap_set_tstamp_precision)
 730 fi
 731
 732 #
 733 # Check for a miscellaneous collection of functions which we use
 734 # if we have them.
 735 #
 736 AC_CHECK_FUNCS(pcap_findalldevs)
 737 if test $ac_cv_func_pcap_findalldevs = "yes" ; then
 738 dnl Check for libpcap having pcap_findalldevs() but the pcap.h header
 739 dnl not having pcap_if_t; some versions of Mac OS X shipped with pcap.h
 740 dnl from 0.6 and libpcap 0.8, so that libpcap had pcap_findalldevs but
 741 dnl pcap.h didn't have pcap_if_t.
 742     savedcppflags="$CPPFLAGS"
 743     CPPFLAGS="$CPPFLAGS $V_INCLS"
 744     AC_CHECK_TYPES(pcap_if_t, , , [#include <pcap.h>])
 745     CPPFLAGS="$savedcppflags"
 746 fi
 747 AC_CHECK_FUNCS(pcap_dump_flush pcap_lib_version)
 748 if test $ac_cv_func_pcap_lib_version = "no" ; then
 749     AC_MSG_CHECKING(whether pcap_version is defined by libpcap)
 750     AC_TRY_LINK([],
 751        [
 752         extern char pcap_version[];
 753
 754         return (int)pcap_version;
 755        ],
 756        ac_lbl_cv_pcap_version_defined=yes,
 757        ac_lbl_cv_pcap_version_defined=no)
 758     if test "$ac_lbl_cv_pcap_version_defined" = yes ; then
 759         AC_MSG_RESULT(yes)
 760         AC_DEFINE(HAVE_PCAP_VERSION, 1, [define if libpcap has pcap_version])
 761     else
 762         AC_MSG_RESULT(no)
 763     fi
 764 fi
 765 AC_CHECK_FUNCS(pcap_setdirection pcap_set_immediate_mode pcap_dump_ftell64)
 766 AC_CHECK_FUNCS(pcap_open pcap_findalldevs_ex)
 767 AC_REPLACE_FUNCS(pcap_dump_ftell)
 768
 769 #
 770 # Check for special debugging functions
 771 #
 772 AC_CHECK_FUNCS(pcap_set_parser_debug)
 773 if test "$ac_cv_func_pcap_set_parser_debug" = "no" ; then
 774         #
 775         # OK, we don't have pcap_set_parser_debug() to set the libpcap
 776         # filter expression parser debug flag; can we directly set the
 777         # flag?
 778         AC_MSG_CHECKING(whether pcap_debug is defined by libpcap)
 779         AC_TRY_LINK([],
 780            [
 781                 extern int pcap_debug;
 782
 783                 return pcap_debug;
 784            ],
 785            ac_lbl_cv_pcap_debug_defined=yes,
 786            ac_lbl_cv_pcap_debug_defined=no)
 787         if test "$ac_lbl_cv_pcap_debug_defined" = yes ; then
 788                 AC_MSG_RESULT(yes)
 789                 AC_DEFINE(HAVE_PCAP_DEBUG, 1, [define if libpcap has pcap_debug])
 790         else
 791                 AC_MSG_RESULT(no)
 792                 #
 793                 # OK, what about "yydebug"?
 794                 #
 795                 AC_MSG_CHECKING(whether yydebug is defined by libpcap)
 796                 AC_TRY_LINK([],
 797                    [
 798                         extern int yydebug;
 799
 800                         return yydebug;
 801                    ],
 802                    ac_lbl_cv_yydebug_defined=yes,
 803                    ac_lbl_cv_yydebug_defined=no)
 804                 if test "$ac_lbl_cv_yydebug_defined" = yes ; then
 805                         AC_MSG_RESULT(yes)
 806                         AC_DEFINE(HAVE_YYDEBUG, 1, [define if libpcap has yydebug])
 807                 else
 808                         AC_MSG_RESULT(no)
 809                 fi
 810         fi
 811 fi
 812 AC_CHECK_FUNCS(pcap_set_optimizer_debug)
 813 AC_REPLACE_FUNCS(bpf_dump)      dnl moved to libpcap in 0.6
 814
 815 V_GROUP=0
 816 if test -f /etc/group -a ! -z "`grep '^wheel:' /etc/group`" ; then
 817         V_GROUP=wheel
 818 fi
 819 #
 820 # Assume V7/BSD convention for man pages (file formats in section 5,
 821 # miscellaneous info in section 7).
 822 #
 823 MAN_FILE_FORMATS=5
 824 MAN_MISC_INFO=7
 825 case "$host_os" in
 826
 827 aix*)
 828         dnl Workaround to enable certain features
 829         AC_DEFINE(_SUN,1,[define on AIX to get certain functions])
 830         ;;
 831
 832 hpux*)
 833         #
 834         # Use System V conventions for man pages.
 835         #
 836         MAN_FILE_FORMATS=4
 837         MAN_MISC_INFO=5
 838         ;;
 839
 840 irix*)
 841         V_GROUP=sys
 842
 843         #
 844         # Use System V conventions for man pages.
 845         #
 846         MAN_FILE_FORMATS=4
 847         MAN_MISC_INFO=5
 848         ;;
 849
 850 osf*)
 851         V_GROUP=system
 852
 853         #
 854         # Use System V conventions for man pages.
 855         #
 856         MAN_FILE_FORMATS=4
 857         MAN_MISC_INFO=5
 858         ;;
 859
 860 solaris*)
 861         V_GROUP=sys
 862
 863         #
 864         # Use System V conventions for man pages.
 865         #
 866         MAN_FILE_FORMATS=4
 867         MAN_MISC_INFO=5
 868         ;;
 869 esac
 870
 871 if test -f /dev/bpf0 ; then
 872         V_GROUP=bpf
 873 fi
 874
 875 #
 876 # Make sure we have a definition for C99's uintptr_t (regardless of
 877 # whether the environment is a C99 environment or not).
 878 #
 879 AC_TYPE_UINTPTR_T
 880
 881 #
 882 # Check whether we have pcap/pcap-inttypes.h.
 883 # If we do, we use that to get the C99 types defined.
 884 #
 885 savedcppflags="$CPPFLAGS"
 886 CPPFLAGS="$CPPFLAGS $V_INCLS"
 887 AC_CHECK_HEADERS(pcap/pcap-inttypes.h)
 888 CPPFLAGS="$savedcppflags"
 889
 890 #
 891 # Define the old BSD specified-width types in terms of the C99 types;
 892 # we may need them with libpcap include files.
 893 #
 894 AC_CHECK_TYPE([u_int8_t], ,
 895         [AC_DEFINE([u_int8_t], [uint8_t],
 896         [Define to `uint8_t' if u_int8_t not defined.])],
 897         [AC_INCLUDES_DEFAULT
 898 #include <sys/types.h>
 899 ])
 900 AC_CHECK_TYPE([u_int16_t], ,
 901         [AC_DEFINE([u_int16_t], [uint16_t],
 902         [Define to `uint16_t' if u_int16_t not defined.])],
 903         [AC_INCLUDES_DEFAULT
 904 #include <sys/types.h>
 905 ])
 906 AC_CHECK_TYPE([u_int32_t], ,
 907         [AC_DEFINE([u_int32_t], [uint32_t],
 908         [Define to `uint32_t' if u_int32_t not defined.])],
 909         [AC_INCLUDES_DEFAULT
 910 #include <sys/types.h>
 911 ])
 912 AC_CHECK_TYPE([u_int64_t], ,
 913         [AC_DEFINE([u_int64_t], [uint64_t],
 914         [Define to `uint64_t' if u_int64_t not defined.])],
 915         [AC_INCLUDES_DEFAULT
 916 #include <sys/types.h>
 917 ])
 918
 919 AC_PROG_RANLIB
 920 AC_CHECK_TOOL([AR], [ar])
 921
 922 AC_LBL_DEVEL(V_CCOPT)
 923
 924 # Check for OpenSSL/libressl libcrypto
 925 AC_MSG_CHECKING(whether to use OpenSSL/libressl libcrypto)
 926 # Specify location for both includes and libraries.
 927 want_libcrypto=ifavailable
 928 AC_ARG_WITH(crypto,
 929     AS_HELP_STRING([--with-crypto]@<:@=DIR@:>@,
 930                    [use OpenSSL/libressl libcrypto (located in directory DIR, if specified) @<:@default=yes, if available@:>@]),
 931 [
 932         if test $withval = no
 933         then
 934                 # User doesn't want to link with libcrypto.
 935                 want_libcrypto=no
 936                 AC_MSG_RESULT(no)
 937         elif test $withval = yes
 938         then
 939                 # User wants to link with libcrypto but hasn't specified
 940                 # a directory.
 941                 want_libcrypto=yes
 942                 AC_MSG_RESULT(yes)
 943         else
 944                 # User wants to link with libcrypto and has specified
 945                 # a directory, so use the provided value.
 946                 want_libcrypto=yes
 947                 libcrypto_root=$withval
 948                 AC_MSG_RESULT([yes, using the version installed in $withval])
 949
 950                 #
 951                 # Put the subdirectories of the libcrypto root directory
 952                 # at the front of the header and library search path.
 953                 #
 954                 CFLAGS="-I$withval/include $CFLAGS"
 955                 LIBS="-L$withval/lib $LIBS"
 956         fi
 957 ],[
 958         #
 959         # Use libcrypto if it's present, otherwise don't; no directory
 960         # was specified.
 961         #
 962         want_libcrypto=ifavailable
 963         AC_MSG_RESULT([yes, if available])
 964 ])
 965 if test "$want_libcrypto" != "no"; then
 966         #
 967         # Don't check for libcrypto unless we have its headers;
 968         # Apple, bless their pointy little heads, apparently ship
 969         # libcrypto as a library, but not the header files, in
 970         # El Capitan, probably because they don't want you writing
 971         # nasty portable code that could run on other UN*Xes, they
 972         # want you writing code that uses their Shiny New Crypto
 973         # Library and that only runs on macOS.
 974         #
 975         AC_CHECK_HEADER(openssl/crypto.h,
 976         [
 977                 AC_CHECK_LIB(crypto, DES_cbc_encrypt)
 978                 if test "$ac_cv_lib_crypto_DES_cbc_encrypt" = "yes"; then
 979                         AC_CHECK_HEADERS(openssl/evp.h)
 980                         #
 981                         # OK, then:
 982                         #
 983                         # 1) do we have EVP_CIPHER_CTX_new?
 984                         # If so, we use it to allocate an
 985                         # EVP_CIPHER_CTX, as EVP_CIPHER_CTX may be
 986                         # opaque; otherwise, we allocate it ourselves.
 987                         #
 988                         # 2) do we have EVP_DecryptInit_ex()?
 989                         # If so, we use it, because we need to be
 990                         # able to make two "initialize the cipher"
 991                         # calls, one with the cipher and key, and
 992                         # one with the IV, and, as of OpenSSL 1.1,
 993                         # You Can't Do That with EVP_DecryptInit(),
 994                         # because a call to EVP_DecryptInit() will
 995                         # unconditionally clear the context, and
 996                         # if you don't supply a cipher, it'll
 997                         # clear the cipher, rendering the context
 998                         # unusable and causing a crash.
 999                         #
1000                         AC_CHECK_FUNCS(EVP_CIPHER_CTX_new EVP_DecryptInit_ex)
1001                 fi
1002         ])
1003 fi
1004
1005 # Check for libcap-ng
1006 AC_MSG_CHECKING(whether to use libcap-ng)
1007 # Specify location for both includes and libraries.
1008 want_libcap_ng=ifavailable
1009 AC_ARG_WITH(cap_ng,
1010     AS_HELP_STRING([--with-cap-ng],
1011                    [use libcap-ng @<:@default=yes, if available@:>@]),
1012 [
1013         if test $withval = no
1014         then
1015                 want_libcap_ng=no
1016                 AC_MSG_RESULT(no)
1017         elif test $withval = yes
1018         then
1019                 want_libcap_ng=yes
1020                 AC_MSG_RESULT(yes)
1021         fi
1022 ],[
1023         #
1024         # Use libcap-ng if it's present, otherwise don't.
1025         #
1026         want_libcap_ng=ifavailable
1027         AC_MSG_RESULT([yes, if available])
1028 ])
1029 if test "$want_libcap_ng" != "no"; then
1030         AC_CHECK_LIB(cap-ng, capng_change_id)
1031         AC_CHECK_HEADERS(cap-ng.h)
1032 fi
1033
1034 dnl
1035 dnl set additional include path if necessary
1036 if test "$missing_includes" = "yes"; then
1037         CPPFLAGS="$CPPFLAGS -I$srcdir/missing"
1038         V_INCLS="$V_INCLS -I$srcdir/missing"
1039 fi
1040
1041 AC_SUBST(V_CCOPT)
1042 AC_SUBST(V_DEFS)
1043 AC_SUBST(V_GROUP)
1044 AC_SUBST(V_INCLS)
1045 AC_SUBST(V_PCAPDEP)
1046 AC_SUBST(LOCALSRC)
1047 AC_SUBST(MAN_FILE_FORMATS)
1048 AC_SUBST(MAN_MISC_INFO)
1049
1050 AC_PROG_INSTALL
1051
1052 AC_CONFIG_HEADER(config.h)
1053
1054 AC_OUTPUT_COMMANDS([if test -f .devel; then
1055         echo timestamp > stamp-h
1056         cat $srcdir/Makefile-devel-adds >> Makefile
1057         make depend || exit 1
1058 fi])
1059 AC_OUTPUT(Makefile tcpdump.1)
1060 exit 0