]> The Tcpdump Group git mirrors - tcpdump/blob - configure.ac
projects / tcpdump / blob


64cc182f4972f83adf7ee5801c7f032d0a557011
[tcpdump] / configure.ac
1 dnl Copyright (c) 1994, 1995, 1996, 1997
2 dnl The Regents of the University of California. All rights reserved.
3 dnl
4 dnl Process this file with autoconf to produce a configure script.
5 dnl
6
7 #
8 # See
9 #
10 # https://ftp.gnu.org/gnu/config/README
11 #
12 # for the URLs to use to fetch new versions of config.guess and
13 # config.sub.
14 #
15
16 AC_PREREQ([2.69])
17 AC_INIT([tcpdump],[m4_esyscmd_s(cat VERSION)])
18 AC_CONFIG_SRCDIR(tcpdump.c)
19
20 AC_CANONICAL_HOST
21
22 AC_LBL_C_INIT_BEFORE_CC(V_INCLS)
23 #
24 # Try to enable as many C99 features as we can.
25 # At minimum, we want C++/C99-style // comments.
26 #
27 AC_PROG_CC_C99
28 if test "$ac_cv_prog_cc_c99" = "no"; then
29 AC_MSG_WARN([The C compiler does not support C99; there may be compiler errors])
30 fi
31 AC_LBL_C_INIT(V_CCOPT, V_INCLS)
32 AC_C_INLINE
33
34 AC_CHECK_HEADERS(fcntl.h rpc/rpc.h rpc/rpcent.h net/if.h)
35
36 case "$host_os" in
37
38 darwin*)
39 AC_ARG_ENABLE(universal,
40 AS_HELP_STRING([--disable-universal],[don't build universal on macOS]))
41 if test "$enable_universal" != "no"; then
42 case "$host_os" in
43
44 darwin9.*)
45 #
46 # Leopard. Build for x86 and 32-bit PowerPC, with
47 # x86 first. (That's what Apple does.)
48 #
49 V_CCOPT="$V_CCOPT -arch i386 -arch ppc"
50 LDFLAGS="$LDFLAGS -arch i386 -arch ppc"
51 ;;
52
53 darwin10.*)
54 #
55 # Snow Leopard. Build for x86-64 and x86, with
56 # x86-64 first. (That's what Apple does.)
57 #
58 V_CCOPT="$V_CCOPT -arch x86_64 -arch i386"
59 LDFLAGS="$LDFLAGS -arch x86_64 -arch i386"
60 ;;
61 esac
62 fi
63 ;;
64 esac
65
66 AC_ARG_WITH([smi],
67 [AS_HELP_STRING([--with-smi],
68 [link with libsmi (allows to load MIBs on the fly to decode SNMP packets) [default=yes, if available]])],
69 [],
70 [with_smi=yes])
71
72 if test "x$with_smi" != "xno" ; then
73 AC_CHECK_HEADER(smi.h,
74 [
75 #
76 # OK, we found smi.h. Do we have libsmi with smiInit?
77 #
78 AC_CHECK_LIB(smi, smiInit,
79 [
80 #
81 # OK, we have libsmi with smiInit. Can we use it?
82 #
83 AC_MSG_CHECKING([whether to enable libsmi])
84 savedlibs="$LIBS"
85 LIBS="-lsmi $LIBS"
86 AC_RUN_IFELSE([AC_LANG_SOURCE([[
87 /* libsmi available check */
88 #include <stdio.h>
89 #include <stdlib.h>
90 #include <string.h>
91 #include <smi.h>
92 int main()
93 {
94 int current, revision, age, n;
95 const int required = 2;
96 if (smiInit(""))
97 exit(1);
98 if (strcmp(SMI_LIBRARY_VERSION, smi_library_version))
99 exit(2);
100 n = sscanf(smi_library_version, "%d:%d:%d", &current, &revision, &age);
101 if (n != 3)
102 exit(3);
103 if (required < current - age || required > current)
104 exit(4);
105 exit(0);
106 }
107 ]])
108 ],
109 [
110 AC_MSG_RESULT(yes)
111 AC_DEFINE(USE_LIBSMI, 1,
112 [Define if you enable support for libsmi])
113 ],
114 [
115 dnl autoconf documentation says that
116 dnl $? contains the exit value.
117 dnl reality is that it does not.
118 dnl We leave this in just in case
119 dnl autoconf ever comes back to
120 dnl match the documentation.
121 case $? in
122 1) AC_MSG_RESULT(no - smiInit failed) ;;
123 2) AC_MSG_RESULT(no - header/library version mismatch) ;;
124 3) AC_MSG_RESULT(no - can't determine library version) ;;
125 4) AC_MSG_RESULT(no - too old) ;;
126 *) AC_MSG_RESULT(no) ;;
127 esac
128 LIBS="$savedlibs"
129 ],
130 [
131 AC_MSG_RESULT(not when cross-compiling)
132 LIBS="$savedlibs"
133 ]
134 )
135 ])
136 ])
137 fi
138
139 AC_MSG_CHECKING([whether to enable the instrument functions code])
140 AC_ARG_ENABLE([instrument-functions],
141 [AS_HELP_STRING([--enable-instrument-functions],
142 [enable instrument functions code [default=no]])],
143 [],
144 [enableval=no])
145 case "$enableval" in
146 yes) AC_MSG_RESULT(yes)
147 AC_CHECK_LIB([bfd], [bfd_init],
148 [true],
149 [AC_MSG_ERROR(
150 [--enable-instrument-functions was given, but test for library libbfd failed. Please install the 'binutils-dev' package.])],
151 [])
152 AC_DEFINE(ENABLE_INSTRUMENT_FUNCTIONS, 1,
153 [define if you want to build the instrument functions code])
154 LOCALSRC="$LOCALSRC instrument-functions.c"
155 # Add '-finstrument-functions' instrumentation option to generate
156 # instrumentation calls for entry and exit to functions.
157 # Try to avoid Address Space Layout Randomization (ALSR).
158 CFLAGS="$CFLAGS -O0 -ggdb -finstrument-functions -fno-stack-protector -fno-pic"
159 LDFLAGS="$LDFLAGS -O0 -ggdb -fno-stack-protector -no-pie"
160 LIBS="$LIBS -lbfd"
161 ;;
162 *) AC_MSG_RESULT(no)
163 ;;
164 esac
165
166 AC_MSG_CHECKING([whether to enable the possibly-buggy SMB printer])
167 AC_ARG_ENABLE([smb],
168 [AS_HELP_STRING([--enable-smb],
169 [enable possibly-buggy SMB printer [default=no]])],
170 [],
171 [enableval=no])
172 case "$enableval" in
173 yes) AC_MSG_RESULT(yes)
174 AC_DEFINE(ENABLE_SMB, 1,
175 [define if you want to build the possibly-buggy SMB printer])
176 LOCALSRC="print-smb.c smbutil.c $LOCALSRC"
177 ;;
178 *) AC_MSG_RESULT(no)
179 ;;
180 esac
181
182 AC_ARG_WITH(user, [ --with-user=USERNAME drop privileges by default to USERNAME])
183 AC_MSG_CHECKING([whether to drop root privileges by default])
184 if test ! -z "$withval" && test "$withval" != "no" ; then
185 if test "$withval" = "yes" ; then
186 AC_MSG_ERROR([--with-user requires a username])
187 fi
188 AC_DEFINE_UNQUOTED(WITH_USER, "$withval",
189 [define if should drop privileges by default])
190 AC_MSG_RESULT([yes, to user "$withval"])
191 else
192 AC_MSG_RESULT(no)
193 fi
194
195 AC_ARG_WITH(chroot, [ --with-chroot=DIRECTORY when dropping privileges, chroot to DIRECTORY])
196 AC_MSG_CHECKING([whether to chroot])
197 if test ! -z "$withval" && test "$withval" != "no" ; then
198 if test "$withval" = "yes" ; then
199 AC_MSG_ERROR([--with-chroot requires a directory])
200 fi
201 AC_DEFINE_UNQUOTED(WITH_CHROOT, "$withval",
202 [define if should chroot when dropping privileges])
203 AC_MSG_RESULT([yes, to directory "$withval"])
204 else
205 AC_MSG_RESULT(no)
206 fi
207
208 AC_ARG_WITH(sandbox-capsicum,
209 AS_HELP_STRING([--with-sandbox-capsicum],
210 [use Capsicum security functions @<:@default=yes, if available@:>@]))
211 #
212 # Check whether various functions are available. If any are, set
213 # ac_lbl_capsicum_function_seen to yes; if any are not, set
214 # ac_lbl_capsicum_function_not_seen to yes.
215 #
216 # We don't check cap_rights_init(), as it's a macro, wrapping another
217 # function, in at least some versions of FreeBSD, and AC_CHECK_FUNCS()
218 # doesn't handle that.
219 #
220 # All of the ones we check for must be available in order to enable
221 # capsicum sandboxing.
222 #
223 # XXX - do we need to check for all of them, or are there some that, if
224 # present, imply others are present?
225 #
226 if test -z "$with_sandbox_capsicum" || test "$with_sandbox_capsicum" != "no" ; then
227 #
228 # First, make sure we have the required header.
229 #
230 AC_CHECK_HEADER(sys/capsicum.h,
231 [
232 #
233 # We do; now make sure we have the required functions.
234 #
235 AC_CHECK_FUNCS(cap_enter cap_rights_limit cap_ioctls_limit openat,
236 ac_lbl_capsicum_function_seen=yes,
237 ac_lbl_capsicum_function_not_seen=yes)
238 ])
239 AC_CHECK_LIB(casper, cap_init, LIBS="$LIBS -lcasper")
240 AC_CHECK_LIB(cap_dns, cap_gethostbyaddr, LIBS="$LIBS -lcap_dns")
241 fi
242 AC_MSG_CHECKING([whether to sandbox using capsicum])
243 if test "x$ac_lbl_capsicum_function_seen" = "xyes" -a "x$ac_lbl_capsicum_function_not_seen" != "xyes"; then
244 AC_DEFINE(HAVE_CAPSICUM, 1, [capsicum support available])
245 AC_MSG_RESULT(yes)
246 else
247 AC_MSG_RESULT(no)
248 fi
249 AC_MSG_CHECKING([whether to sandbox using Casper library])
250 if test "x$ac_cv_lib_casper_cap_init" = "xyes" -a "x$ac_cv_lib_cap_dns_cap_gethostbyaddr" = "xyes"; then
251 AC_DEFINE(HAVE_CASPER, 1, [Casper support available])
252 AC_MSG_RESULT(yes)
253 else
254 AC_MSG_RESULT(no)
255 fi
256
257 #
258 # We must check this before checking whether to check the OS's IPv6,
259 # support because, on some platforms (such as SunOS 5.x), the test
260 # program requires the extra networking libraries.
261 #
262 AC_LBL_LIBRARY_NET
263
264 #
265 # Check whether AF_INET6 and struct in6_addr are defined.
266 # If they aren't both defined, we don't have sufficient OS
267 # support for IPv6, so we don't look for IPv6 support libraries,
268 # and we define AF_INET6 and struct in6_addr ourselves.
269 #
270 AC_MSG_CHECKING([whether the operating system supports IPv6])
271 AC_COMPILE_IFELSE(
272 [
273 AC_LANG_SOURCE(
274 [[
275 #include <string.h>
276 /* AF_INET6 available check */
277 #include <sys/types.h>
278 #ifdef _WIN32
279 #include <ws2tcpip.h>
280 #else
281 #include <sys/socket.h>
282 #include <netinet/in.h>
283 #endif
284 #ifdef AF_INET6
285 void
286 foo(struct in6_addr *addr)
287 {
288 memset(addr, 0, sizeof (struct in6_addr));
289 }
290 #else
291 #error "AF_INET6 not defined"
292 #endif
293 ]])
294 ],
295 [
296 AC_MSG_RESULT(yes)
297 AC_DEFINE(HAVE_OS_IPV6_SUPPORT, 1,
298 [define if the OS provides AF_INET6 and struct in6_addr])
299 ipv6=yes
300 ],
301 [
302 AC_MSG_RESULT(no)
303 ipv6=no
304 ]
305 )
306
307 ipv6type=unknown
308 ipv6lib=none
309 ipv6trylibc=no
310
311 if test "$ipv6" = "yes"; then
312 # Apparently, only on Linux by this point the configure script knows
313 # what the C preprocessor and the extended regexp grep commands are.
314 # On other OSes the first call to AC_EGREP_CPP() induces a search for
315 # these tools, which prints three lines in the middle of the IPv6
316 # detection message and distorts it. Resolve these dependencies
317 # beforehand to prevent that.
318 AC_PROG_CPP
319 AC_PROG_EGREP
320
321 AC_MSG_CHECKING([ipv6 stack type])
322 for i in inria kame linux-glibc linux-libinet6 toshiba v6d zeta; do
323 case $i in
324 inria)
325 dnl http://www.kame.net/
326 AC_EGREP_CPP(yes,
327 [#include <netinet/in.h>
328 #ifdef IPV6_INRIA_VERSION
329 yes
330 #endif],
331 [ipv6type=$i])
332 ;;
333 kame)
334 dnl http://www.kame.net/
335 AC_EGREP_CPP(yes,
336 [#include <netinet/in.h>
337 #ifdef __KAME__
338 yes
339 #endif],
340 [ipv6type=$i;
341 ipv6lib=inet6;
342 ipv6libdir=/usr/local/v6/lib;
343 ipv6trylibc=yes])
344 ;;
345 linux-glibc)
346 dnl http://www.v6.linux.or.jp/
347 AC_EGREP_CPP(yes,
348 [#include <features.h>
349 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
350 yes
351 #endif],
352 [ipv6type=$i])
353 ;;
354 linux-libinet6)
355 dnl http://www.v6.linux.or.jp/
356 dnl
357 dnl This also matches Solaris 8 and Tru64 UNIX 5.1,
358 dnl and possibly other versions of those OSes
359 dnl
360 if test -d /usr/inet6 -o -f /usr/include/netinet/ip6.h; then
361 ipv6type=$i
362 ipv6lib=inet6
363 ipv6libdir=/usr/inet6/lib
364 ipv6trylibc=yes;
365 CFLAGS="-I/usr/inet6/include $CFLAGS"
366 fi
367 ;;
368 toshiba)
369 AC_EGREP_CPP(yes,
370 [#include <sys/param.h>
371 #ifdef _TOSHIBA_INET6
372 yes
373 #endif],
374 [ipv6type=$i;
375 ipv6lib=inet6;
376 ipv6libdir=/usr/local/v6/lib])
377 ;;
378 v6d)
379 AC_EGREP_CPP(yes,
380 [#include </usr/local/v6/include/sys/v6config.h>
381 #ifdef __V6D__
382 yes
383 #endif],
384 [ipv6type=$i;
385 ipv6lib=v6;
386 ipv6libdir=/usr/local/v6/lib;
387 CFLAGS="-I/usr/local/v6/include $CFLAGS"])
388 ;;
389 zeta)
390 AC_EGREP_CPP(yes,
391 [#include <sys/param.h>
392 #ifdef _ZETA_MINAMI_INET6
393 yes
394 #endif],
395 [ipv6type=$i;
396 ipv6lib=inet6;
397 ipv6libdir=/usr/local/v6/lib])
398 ;;
399 esac
400 if test "$ipv6type" != "unknown"; then
401 break
402 fi
403 done
404 AC_MSG_RESULT($ipv6type)
405 fi
406
407 if test "$ipv6" = "yes" -a "$ipv6lib" != "none"; then
408 if test -d $ipv6libdir -a -f $ipv6libdir/lib$ipv6lib.a; then
409 LIBS="-L$ipv6libdir -l$ipv6lib $LIBS"
410 echo "You have $ipv6lib library, using it"
411 else
412 if test "$ipv6trylibc" = "yes"; then
413 echo "You do not have $ipv6lib library, using libc"
414 else
415 echo 'Fatal: no $ipv6lib library found. cannot continue.'
416 echo "You need to fetch lib$ipv6lib.a from appropriate"
417 echo 'ipv6 kit and compile beforehand.'
418 exit 1
419 fi
420 fi
421 fi
422
423 AC_REPLACE_FUNCS(strlcat strlcpy strdup strsep getservent getopt_long)
424 AC_CHECK_FUNCS(fork vfork)
425 AC_CHECK_FUNCS(setlinebuf)
426
427 #
428 # Make sure we have snprintf(); we require it.
429 #
430 AC_CHECK_FUNC(snprintf,,
431 AC_MSG_ERROR([snprintf() is required but wasn't found]))
432
433 #
434 # It became apparent at some point that using a suitable C99 compiler does not
435 # automatically mean snprintf(3) implementation in the libc supports all the
436 # modifiers and specifiers used in the project, so let's test that before the
437 # build, not after.
438 #
439 # Testing the sizeof_t length modifier takes making an snprintf() call and
440 # comparing the actual result with the expected result. If this fails, it will
441 # most likely happen at run time, not compile time.
442 #
443 # Testing the 64-bit conversion specifiers in addition to that requires the
444 # <inttypes.h> header to be present and the macros to be defined, so if this
445 # fails, it will more likely happen at compile time.
446 #
447 AC_MSG_CHECKING([whether snprintf is suitable])
448 AC_RUN_IFELSE(
449 [
450 AC_LANG_SOURCE([[
451 #include <stdio.h>
452 #include <string.h>
453 #include <inttypes.h>
454 #include <sys/types.h>
455
456 int main()
457 {
458 char buf[100];
459 uint64_t t = (uint64_t)1 << 32;
460
461 snprintf(buf, sizeof(buf), "%zu", sizeof(buf));
462 if (strncmp(buf, "100", sizeof(buf)))
463 return 1;
464
465 snprintf(buf, sizeof(buf), "%zd", -sizeof(buf));
466 if (strncmp(buf, "-100", sizeof(buf)))
467 return 2;
468
469 snprintf(buf, sizeof(buf), "%" PRId64, -t);
470 if (strncmp(buf, "-4294967296", sizeof(buf)))
471 return 3;
472
473 snprintf(buf, sizeof(buf), "0o%" PRIo64, t);
474 if (strncmp(buf, "0o40000000000", sizeof(buf)))
475 return 4;
476
477 snprintf(buf, sizeof(buf), "0x%" PRIx64, t);
478 if (strncmp(buf, "0x100000000", sizeof(buf)))
479 return 5;
480
481 snprintf(buf, sizeof(buf), "%" PRIu64, t);
482 if (strncmp(buf, "4294967296", sizeof(buf)))
483 return 6;
484
485 return 0;
486 }
487 ]])
488 ],
489 [
490 AC_MSG_RESULT(yes)
491 ],
492 [
493 AC_MSG_RESULT(no)
494 AC_MSG_ERROR(
495 [The snprintf(3) implementation in this libc is not suitable,
496 tcpdump would not work correctly even if it managed to compile.])
497 ],
498 [
499 AC_MSG_RESULT(not while cross-compiling)
500 ]
501 )
502
503 AC_CHECK_LIB(rpc, main) dnl It's unclear why we might need -lrpc
504
505 dnl Some platforms may need -lnsl for getrpcbynumber.
506 AC_SEARCH_LIBS(getrpcbynumber, nsl,
507 AC_DEFINE(HAVE_GETRPCBYNUMBER, 1, [define if you have getrpcbynumber()]))
508
509 AC_LBL_LIBPCAP(V_PCAPDEP, V_INCLS)
510
511 #
512 # Check for these after AC_LBL_LIBPCAP, so we link with the appropriate
513 # libraries (e.g., "-lsocket -lnsl" on Solaris).
514 #
515 # You are in a twisty little maze of UN*Xes, all different.
516 # Some might not have ether_ntohost().
517 # Some might have it and declare it in <net/ethernet.h>.
518 # Some might have it and declare it in <netinet/ether.h>
519 # Some might have it and declare it in <sys/ethernet.h>.
520 # Some might have it and declare it in <arpa/inet.h>.
521 # Some might have it and declare it in <netinet/if_ether.h>.
522 # Some might have it and not declare it in any header file.
523 #
524 # Before you is a C compiler.
525 #
526 AC_CHECK_FUNCS(ether_ntohost, [
527 AC_CACHE_CHECK(for buggy ether_ntohost, ac_cv_buggy_ether_ntohost, [
528 AC_RUN_IFELSE([AC_LANG_SOURCE([[
529 #include <netdb.h>
530 #include <netinet/ether.h>
531 #include <stdlib.h>
532 #include <sys/types.h>
533 #include <sys/param.h>
534 #include <sys/socket.h>
535
536 int
537 main(int argc, char **argv)
538 {
539 u_char ea[6] = { 0xff, 0xff, 0xff, 0xff, 0xff };
540 char name[MAXHOSTNAMELEN];
541
542 ether_ntohost(name, (struct ether_addr *)ea);
543 exit(0);
544 }
545 ]])
546 ], [ac_cv_buggy_ether_ntohost=no],
547 [ac_cv_buggy_ether_ntohost=yes],
548 [ac_cv_buggy_ether_ntohost="not while cross-compiling"])])
549 if test "$ac_cv_buggy_ether_ntohost" = "no"; then
550 AC_DEFINE(USE_ETHER_NTOHOST, 1,
551 [define if you have ether_ntohost() and it works])
552 fi
553 ])
554 if test "$ac_cv_func_ether_ntohost" = yes -a \
555 "$ac_cv_buggy_ether_ntohost" = "no"; then
556 #
557 # OK, we have ether_ntohost(). Is it declared in <net/ethernet.h>?
558 #
559 # This test fails if we don't have <net/ethernet.h> or if we do
560 # but it doesn't declare ether_ntohost().
561 #
562 AC_CHECK_DECL(ether_ntohost,
563 [
564 AC_DEFINE(NET_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
565 [Define to 1 if net/ethernet.h declares `ether_ntohost'])
566 ],,
567 [
568 #include <net/ethernet.h>
569 ])
570 #
571 # Did that succeed?
572 #
573 if test "$ac_cv_have_decl_ether_ntohost" != yes; then
574 #
575 # No, how about <netinet/ether.h>, as on Linux?
576 #
577 # This test fails if we don't have <netinet/ether.h>
578 # or if we do but it doesn't declare ether_ntohost().
579 #
580 # Unset ac_cv_have_decl_ether_ntohost so we don't
581 # treat the previous failure as a cached value and
582 # suppress the next test.
583 #
584 unset ac_cv_have_decl_ether_ntohost
585 AC_CHECK_DECL(ether_ntohost,
586 [
587 AC_DEFINE(NETINET_ETHER_H_DECLARES_ETHER_NTOHOST,,
588 [Define to 1 if netinet/ether.h declares `ether_ntohost'])
589 ],,
590 [
591 #include <netinet/ether.h>
592 ])
593 fi
594 #
595 # Did that succeed?
596 #
597 if test "$ac_cv_have_decl_ether_ntohost" != yes; then
598 #
599 # No, how about <sys/ethernet.h>, as on Solaris 10
600 # and later?
601 #
602 # This test fails if we don't have <sys/ethernet.h>
603 # or if we do but it doesn't declare ether_ntohost().
604 #
605 # Unset ac_cv_have_decl_ether_ntohost so we don't
606 # treat the previous failure as a cached value and
607 # suppress the next test.
608 #
609 unset ac_cv_have_decl_ether_ntohost
610 AC_CHECK_DECL(ether_ntohost,
611 [
612 AC_DEFINE(SYS_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
613 [Define to 1 if sys/ethernet.h declares `ether_ntohost'])
614 ],,
615 [
616 #include <sys/ethernet.h>
617 ])
618 fi
619 #
620 # Did that succeed?
621 #
622 if test "$ac_cv_have_decl_ether_ntohost" != yes; then
623 #
624 # No, how about <arpa/inet.h>, as in AIX?
625 #
626 # This test fails if we don't have <arpa/inet.h>
627 # (if we have ether_ntohost(), we should have
628 # networking, and if we have networking, we should
629 # have <arpa/inet.h>) or if we do but it doesn't
630 # declare ether_ntohost().
631 #
632 # Unset ac_cv_have_decl_ether_ntohost so we don't
633 # treat the previous failure as a cached value and
634 # suppress the next test.
635 #
636 unset ac_cv_have_decl_ether_ntohost
637 AC_CHECK_DECL(ether_ntohost,
638 [
639 AC_DEFINE(ARPA_INET_H_DECLARES_ETHER_NTOHOST,,
640 [Define to 1 if arpa/inet.h declares `ether_ntohost'])
641 ],,
642 [
643 #include <arpa/inet.h>
644 ])
645 fi
646 #
647 # Did that succeed?
648 #
649 if test "$ac_cv_have_decl_ether_ntohost" != yes; then
650 #
651 # No, how about <netinet/if_ether.h>?
652 # On some platforms, it requires <net/if.h> and
653 # <netinet/in.h>, and we always include it with
654 # both of them, so test it with both of them.
655 #
656 # This test fails if we don't have <netinet/if_ether.h>
657 # and the headers we include before it, or if we do but
658 # <netinet/if_ether.h> doesn't declare ether_hostton().
659 #
660 # Unset ac_cv_have_decl_ether_ntohost so we don't
661 # treat the previous failure as a cached value and
662 # suppress the next test.
663 #
664 unset ac_cv_have_decl_ether_ntohost
665 AC_CHECK_DECL(ether_ntohost,
666 [
667 AC_DEFINE(NETINET_IF_ETHER_H_DECLARES_ETHER_NTOHOST,,
668 [Define to 1 if netinet/if_ether.h declares `ether_ntohost'])
669 ],,
670 [
671 #include <sys/types.h>
672 #include <sys/socket.h>
673 #include <net/if.h>
674 #include <netinet/in.h>
675 #include <netinet/if_ether.h>
676 ])
677 fi
678 #
679 # After all that, is ether_ntohost() declared?
680 #
681 if test "$ac_cv_have_decl_ether_ntohost" = yes; then
682 #
683 # Yes.
684 #
685 AC_DEFINE(HAVE_DECL_ETHER_NTOHOST, 1,
686 [Define to 1 if you have the declaration of `ether_ntohost'])
687 else
688 #
689 # No, we'll have to declare it ourselves.
690 # Do we have "struct ether_addr" if we include
691 # <netinet/if_ether.h>?
692 #
693 AC_CHECK_TYPES(struct ether_addr,,,
694 [
695 #include <sys/types.h>
696 #include <sys/socket.h>
697 #include <net/if.h>
698 #include <netinet/in.h>
699 #include <netinet/if_ether.h>
700 ])
701 fi
702 fi
703
704 dnl
705 dnl Check for "pcap_list_datalinks()" and use a substitute version if
706 dnl it's not present. If it is present, check for "pcap_free_datalinks()";
707 dnl if it's not present, we don't replace it for now. (We could do so
708 dnl on UN*X, but not on Windows, where hilarity ensues if a program
709 dnl built with one version of the MSVC support library tries to free
710 dnl something allocated by a library built with another version of
711 dnl the MSVC support library.)
712 dnl
713 AC_CHECK_FUNC(pcap_list_datalinks,
714 [
715 AC_DEFINE(HAVE_PCAP_LIST_DATALINKS, 1,
716 [define if libpcap has pcap_list_datalinks()])
717 AC_CHECK_FUNCS(pcap_free_datalinks)
718 ],
719 [
720 AC_LIBOBJ(datalinks)
721 ])
722
723 dnl
724 dnl Check for "pcap_datalink_name_to_val()", and use a substitute
725 dnl version if it's not present. If it is present, check for
726 dnl "pcap_datalink_val_to_description()", and if we don't have it,
727 dnl use a substitute version.
728 dnl
729 AC_CHECK_FUNC(pcap_datalink_name_to_val,
730 [
731 AC_DEFINE(HAVE_PCAP_DATALINK_NAME_TO_VAL, 1,
732 [define if libpcap has pcap_datalink_name_to_val()])
733 AC_CHECK_FUNC(pcap_datalink_val_to_description,
734 AC_DEFINE(HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION, 1,
735 [define if libpcap has pcap_datalink_val_to_description()]),
736 [
737 AC_LIBOBJ(dlnames)
738 ])
739 ],
740 [
741 AC_LIBOBJ(dlnames)
742 ])
743
744 dnl
745 dnl Check for "pcap_set_datalink()"; you can't substitute for it if
746 dnl it's absent (it has hooks into libpcap), so just define the
747 dnl HAVE_ value if it's there.
748 dnl
749 AC_CHECK_FUNCS(pcap_set_datalink)
750
751 dnl
752 dnl Check for "pcap_breakloop()"; you can't substitute for it if
753 dnl it's absent (it has hooks into the live capture routines),
754 dnl so just define the HAVE_ value if it's there.
755 dnl
756 AC_CHECK_FUNCS(pcap_breakloop)
757
758 #
759 # Do we have the new open API? Check for pcap_create, and assume that,
760 # if we do, we also have pcap_activate() and the other new routines
761 # introduced in libpcap 1.0.0.
762 #
763 AC_CHECK_FUNCS(pcap_create)
764 if test $ac_cv_func_pcap_create = "yes" ; then
765 #
766 # OK, do we have pcap_set_tstamp_type? If so, assume we have
767 # pcap_list_tstamp_types and pcap_free_tstamp_types as well.
768 #
769 AC_CHECK_FUNCS(pcap_set_tstamp_type)
770 #
771 # And do we have pcap_set_tstamp_precision? If so, we assume
772 # we also have pcap_open_offline_with_tstamp_precision.
773 #
774 AC_CHECK_FUNCS(pcap_set_tstamp_precision)
775 fi
776
777 #
778 # Check for a miscellaneous collection of functions which we use
779 # if we have them.
780 #
781 AC_CHECK_FUNCS(pcap_findalldevs)
782 if test $ac_cv_func_pcap_findalldevs = "yes" ; then
783 dnl Check for libpcap having pcap_findalldevs() but the pcap.h header
784 dnl not having pcap_if_t; some versions of Mac OS X shipped with pcap.h
785 dnl from 0.6 and libpcap 0.8, so that libpcap had pcap_findalldevs but
786 dnl pcap.h didn't have pcap_if_t.
787 savedcppflags="$CPPFLAGS"
788 CPPFLAGS="$CPPFLAGS $V_INCLS"
789 AC_CHECK_TYPES(pcap_if_t, , , [#include <pcap.h>])
790 CPPFLAGS="$savedcppflags"
791 fi
792 AC_CHECK_FUNCS(pcap_dump_flush pcap_lib_version)
793 if test $ac_cv_func_pcap_lib_version = "no" ; then
794 AC_MSG_CHECKING(whether pcap_version is defined by libpcap)
795 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
796 extern char pcap_version[];
797
798 return (int)pcap_version;
799 ]])
800 ],
801 [ac_lbl_cv_pcap_version_defined=yes],
802 [ac_lbl_cv_pcap_version_defined=no])
803 if test "$ac_lbl_cv_pcap_version_defined" = yes ; then
804 AC_MSG_RESULT(yes)
805 AC_DEFINE(HAVE_PCAP_VERSION, 1, [define if libpcap has pcap_version])
806 else
807 AC_MSG_RESULT(no)
808 fi
809 fi
810 AC_CHECK_FUNCS(pcap_setdirection pcap_set_immediate_mode pcap_dump_ftell64)
811 AC_CHECK_FUNCS(pcap_open pcap_findalldevs_ex)
812 AC_REPLACE_FUNCS(pcap_dump_ftell)
813
814 #
815 # Check for special debugging functions
816 #
817 AC_CHECK_FUNCS(pcap_set_parser_debug)
818 if test "$ac_cv_func_pcap_set_parser_debug" = "no" ; then
819 #
820 # OK, we don't have pcap_set_parser_debug() to set the libpcap
821 # filter expression parser debug flag; can we directly set the
822 # flag?
823 AC_MSG_CHECKING(whether pcap_debug is defined by libpcap)
824 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
825 extern int pcap_debug;
826
827 return pcap_debug;
828 ]])
829 ],
830 [ac_lbl_cv_pcap_debug_defined=yes],
831 [ac_lbl_cv_pcap_debug_defined=no])
832 if test "$ac_lbl_cv_pcap_debug_defined" = yes ; then
833 AC_MSG_RESULT(yes)
834 AC_DEFINE(HAVE_PCAP_DEBUG, 1, [define if libpcap has pcap_debug])
835 else
836 AC_MSG_RESULT(no)
837 #
838 # OK, what about "yydebug"?
839 #
840 AC_MSG_CHECKING(whether yydebug is defined by libpcap)
841 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
842 extern int yydebug;
843
844 return yydebug;
845 ]])
846 ],
847 [ac_lbl_cv_yydebug_defined=yes],
848 [ac_lbl_cv_yydebug_defined=no])
849 if test "$ac_lbl_cv_yydebug_defined" = yes ; then
850 AC_MSG_RESULT(yes)
851 AC_DEFINE(HAVE_YYDEBUG, 1, [define if libpcap has yydebug])
852 else
853 AC_MSG_RESULT(no)
854 fi
855 fi
856 fi
857 AC_CHECK_FUNCS(pcap_set_optimizer_debug)
858 AC_REPLACE_FUNCS(bpf_dump) dnl moved to libpcap in 0.6
859
860 V_GROUP=0
861 if test -f /etc/group -a ! -z "`grep '^wheel:' /etc/group`" ; then
862 V_GROUP=wheel
863 fi
864 #
865 # Assume V7/BSD convention for man pages (file formats in section 5,
866 # miscellaneous info in section 7).
867 #
868 MAN_FILE_FORMATS=5
869 MAN_MISC_INFO=7
870 case "$host_os" in
871
872 aix*)
873 dnl Workaround to enable certain features
874 AC_DEFINE(_SUN,1,[define on AIX to get certain functions])
875 ;;
876
877 hpux*)
878 #
879 # Use System V conventions for man pages.
880 #
881 MAN_FILE_FORMATS=4
882 MAN_MISC_INFO=5
883 ;;
884
885 irix*)
886 V_GROUP=sys
887
888 #
889 # Use System V conventions for man pages.
890 #
891 MAN_FILE_FORMATS=4
892 MAN_MISC_INFO=5
893 ;;
894
895 osf*)
896 V_GROUP=system
897
898 #
899 # Use System V conventions for man pages.
900 #
901 MAN_FILE_FORMATS=4
902 MAN_MISC_INFO=5
903 ;;
904
905 solaris*)
906 V_GROUP=sys
907
908 #
909 # Use System V conventions for man pages.
910 #
911 MAN_FILE_FORMATS=4
912 MAN_MISC_INFO=5
913 ;;
914 esac
915
916 if test -f /dev/bpf0 ; then
917 V_GROUP=bpf
918 fi
919
920 #
921 # Make sure we have a definition for C99's uintptr_t (regardless of
922 # whether the environment is a C99 environment or not).
923 #
924 AC_TYPE_UINTPTR_T
925
926 #
927 # Check whether we have pcap/pcap-inttypes.h.
928 # If we do, we use that to get the C99 types defined.
929 #
930 savedcppflags="$CPPFLAGS"
931 CPPFLAGS="$CPPFLAGS $V_INCLS"
932 AC_CHECK_HEADERS(pcap/pcap-inttypes.h)
933 CPPFLAGS="$savedcppflags"
934
935 #
936 # Define the old BSD specified-width types in terms of the C99 types;
937 # we may need them with libpcap include files.
938 #
939 AC_CHECK_TYPE([u_int8_t], ,
940 [AC_DEFINE([u_int8_t], [uint8_t],
941 [Define to `uint8_t' if u_int8_t not defined.])],
942 [AC_INCLUDES_DEFAULT
943 #include <sys/types.h>
944 ])
945 AC_CHECK_TYPE([u_int16_t], ,
946 [AC_DEFINE([u_int16_t], [uint16_t],
947 [Define to `uint16_t' if u_int16_t not defined.])],
948 [AC_INCLUDES_DEFAULT
949 #include <sys/types.h>
950 ])
951 AC_CHECK_TYPE([u_int32_t], ,
952 [AC_DEFINE([u_int32_t], [uint32_t],
953 [Define to `uint32_t' if u_int32_t not defined.])],
954 [AC_INCLUDES_DEFAULT
955 #include <sys/types.h>
956 ])
957 AC_CHECK_TYPE([u_int64_t], ,
958 [AC_DEFINE([u_int64_t], [uint64_t],
959 [Define to `uint64_t' if u_int64_t not defined.])],
960 [AC_INCLUDES_DEFAULT
961 #include <sys/types.h>
962 ])
963
964 AC_PROG_RANLIB
965 AC_CHECK_TOOL([AR], [ar])
966
967 AC_LBL_DEVEL(V_CCOPT)
968
969 # Check for OpenSSL/libressl libcrypto
970 AC_MSG_CHECKING(whether to use OpenSSL/libressl libcrypto)
971 # Specify location for both includes and libraries.
972 want_libcrypto=ifavailable
973 AC_ARG_WITH(crypto,
974 AS_HELP_STRING([--with-crypto]@<:@=DIR@:>@,
975 [use OpenSSL/libressl libcrypto (located in directory DIR, if specified) @<:@default=yes, if available@:>@]),
976 [
977 if test $withval = no
978 then
979 # User doesn't want to link with libcrypto.
980 want_libcrypto=no
981 AC_MSG_RESULT(no)
982 elif test $withval = yes
983 then
984 # User wants to link with libcrypto but hasn't specified
985 # a directory.
986 want_libcrypto=yes
987 AC_MSG_RESULT(yes)
988 else
989 # User wants to link with libcrypto and has specified
990 # a directory, so use the provided value.
991 want_libcrypto=yes
992 libcrypto_root=$withval
993 AC_MSG_RESULT([yes, using the version installed in $withval])
994
995 #
996 # Put the subdirectories of the libcrypto root directory
997 # at the front of the header and library search path.
998 #
999 CFLAGS="-I$withval/include $CFLAGS"
1000 LIBS="-L$withval/lib $LIBS"
1001 fi
1002 ],[
1003 #
1004 # Use libcrypto if it's present, otherwise don't; no directory
1005 # was specified.
1006 #
1007 want_libcrypto=ifavailable
1008 AC_MSG_RESULT([yes, if available])
1009 ])
1010 if test "$want_libcrypto" != "no"; then
1011 #
1012 # Don't check for libcrypto unless we have its headers;
1013 # Apple, bless their pointy little heads, apparently ship
1014 # libcrypto as a library, but not the header files, in
1015 # El Capitan, probably because they don't want you writing
1016 # nasty portable code that could run on other UN*Xes, they
1017 # want you writing code that uses their Shiny New Crypto
1018 # Library and that only runs on macOS.
1019 #
1020 AC_CHECK_HEADER(openssl/crypto.h,
1021 [
1022 AC_CHECK_LIB(crypto, DES_cbc_encrypt)
1023 if test "$ac_cv_lib_crypto_DES_cbc_encrypt" = "yes"; then
1024 AC_CHECK_HEADERS(openssl/evp.h)
1025 #
1026 # OK, then:
1027 #
1028 # 1) do we have EVP_CIPHER_CTX_new?
1029 # If so, we use it to allocate an
1030 # EVP_CIPHER_CTX, as EVP_CIPHER_CTX may be
1031 # opaque; otherwise, we allocate it ourselves.
1032 #
1033 # 2) do we have EVP_DecryptInit_ex()?
1034 # If so, we use it, because we need to be
1035 # able to make two "initialize the cipher"
1036 # calls, one with the cipher and key, and
1037 # one with the IV, and, as of OpenSSL 1.1,
1038 # You Can't Do That with EVP_DecryptInit(),
1039 # because a call to EVP_DecryptInit() will
1040 # unconditionally clear the context, and
1041 # if you don't supply a cipher, it'll
1042 # clear the cipher, rendering the context
1043 # unusable and causing a crash.
1044 #
1045 AC_CHECK_FUNCS(EVP_CIPHER_CTX_new EVP_DecryptInit_ex)
1046 fi
1047 ])
1048 fi
1049
1050 # Check for libcap-ng
1051 AC_MSG_CHECKING(whether to use libcap-ng)
1052 # Specify location for both includes and libraries.
1053 want_libcap_ng=ifavailable
1054 AC_ARG_WITH(cap_ng,
1055 AS_HELP_STRING([--with-cap-ng],
1056 [use libcap-ng @<:@default=yes, if available@:>@]),
1057 [
1058 if test $withval = no
1059 then
1060 want_libcap_ng=no
1061 AC_MSG_RESULT(no)
1062 elif test $withval = yes
1063 then
1064 want_libcap_ng=yes
1065 AC_MSG_RESULT(yes)
1066 fi
1067 ],[
1068 #
1069 # Use libcap-ng if it's present, otherwise don't.
1070 #
1071 want_libcap_ng=ifavailable
1072 AC_MSG_RESULT([yes, if available])
1073 ])
1074 if test "$want_libcap_ng" != "no"; then
1075 AC_CHECK_LIB(cap-ng, capng_change_id)
1076 AC_CHECK_HEADERS(cap-ng.h)
1077 fi
1078
1079 dnl
1080 dnl set additional include path if necessary
1081 if test "$missing_includes" = "yes"; then
1082 CPPFLAGS="$CPPFLAGS -I$srcdir/missing"
1083 V_INCLS="$V_INCLS -I$srcdir/missing"
1084 fi
1085
1086 AC_SUBST(V_CCOPT)
1087 AC_SUBST(V_DEFS)
1088 AC_SUBST(V_GROUP)
1089 AC_SUBST(V_INCLS)
1090 AC_SUBST(V_PCAPDEP)
1091 AC_SUBST(LOCALSRC)
1092 AC_SUBST(MAN_FILE_FORMATS)
1093 AC_SUBST(MAN_MISC_INFO)
1094
1095 AC_PROG_INSTALL
1096
1097 AC_CONFIG_HEADERS([config.h])
1098
1099 AC_CONFIG_COMMANDS([.devel],[[if test -f .devel; then
1100 echo timestamp > stamp-h
1101 cat $srcdir/Makefile-devel-adds >> Makefile
1102 make depend || exit 1
1103 fi]])
1104 AC_CONFIG_FILES([Makefile tcpdump.1])
1105 AC_OUTPUT
1106 exit 0
[mirror] the TCPdump network dissector