The Tcpdump Group git mirrors - tcpdump/blob - aclocal.m4

   1 dnl @(#) $Header: /tcpdump/master/tcpdump/aclocal.m4,v 1.98 2003-11-04 07:29:15 guy Exp $ (LBL)
   2 dnl
   3 dnl Copyright (c) 1995, 1996, 1997, 1998
   4 dnl     The Regents of the University of California.  All rights reserved.
   5 dnl
   6 dnl Redistribution and use in source and binary forms, with or without
   7 dnl modification, are permitted provided that: (1) source code distributions
   8 dnl retain the above copyright notice and this paragraph in its entirety, (2)
   9 dnl distributions including binary code include the above copyright notice and
  10 dnl this paragraph in its entirety in the documentation or other materials
  11 dnl provided with the distribution, and (3) all advertising materials mentioning
  12 dnl features or use of this software display the following acknowledgement:
  13 dnl ``This product includes software developed by the University of California,
  14 dnl Lawrence Berkeley Laboratory and its contributors.'' Neither the name of
  15 dnl the University nor the names of its contributors may be used to endorse
  16 dnl or promote products derived from this software without specific prior
  17 dnl written permission.
  18 dnl THIS SOFTWARE IS PROVIDED ``AS IS'' AND WITHOUT ANY EXPRESS OR IMPLIED
  19 dnl WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED WARRANTIES OF
  20 dnl MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE.
  21 dnl
  22 dnl LBL autoconf macros
  23 dnl
  24
  25 dnl
  26 dnl Determine which compiler we're using (cc or gcc)
  27 dnl If using gcc, determine the version number
  28 dnl If using cc, require that it support ansi prototypes
  29 dnl If using gcc, use -O2 (otherwise use -O)
  30 dnl If using cc, explicitly specify /usr/local/include
  31 dnl
  32 dnl usage:
  33 dnl
  34 dnl     AC_LBL_C_INIT(copt, incls)
  35 dnl
  36 dnl results:
  37 dnl
  38 dnl     $1 (copt set)
  39 dnl     $2 (incls set)
  40 dnl     CC
  41 dnl     LDFLAGS
  42 dnl     ac_cv_lbl_gcc_vers
  43 dnl     LBL_CFLAGS
  44 dnl
  45 AC_DEFUN(AC_LBL_C_INIT,
  46     [AC_PREREQ(2.12)
  47     AC_BEFORE([$0], [AC_PROG_CC])
  48     AC_BEFORE([$0], [AC_LBL_FIXINCLUDES])
  49     AC_BEFORE([$0], [AC_LBL_DEVEL])
  50     AC_ARG_WITH(gcc, [  --without-gcc           don't use gcc])
  51     $1="-O"
  52     $2=""
  53     if test "${srcdir}" != "." ; then
  54             $2="-I\$(srcdir)"
  55     fi
  56     if test "${CFLAGS+set}" = set; then
  57             LBL_CFLAGS="$CFLAGS"
  58     fi
  59     if test -z "$CC" ; then
  60             case "$host_os" in
  61
  62             bsdi*)
  63                     AC_CHECK_PROG(SHLICC2, shlicc2, yes, no)
  64                     if test $SHLICC2 = yes ; then
  65                             CC=shlicc2
  66                             export CC
  67                     fi
  68                     ;;
  69             esac
  70     fi
  71     if test -z "$CC" -a "$with_gcc" = no ; then
  72             CC=cc
  73             export CC
  74     fi
  75     AC_PROG_CC
  76     if test "$GCC" = yes ; then
  77             if test "$SHLICC2" = yes ; then
  78                     ac_cv_lbl_gcc_vers=2
  79                     $1="-O2"
  80             else
  81                     AC_MSG_CHECKING(gcc version)
  82                     AC_CACHE_VAL(ac_cv_lbl_gcc_vers,
  83                         ac_cv_lbl_gcc_vers=`$CC -v 2>&1 | \
  84                             sed -e '/^gcc version /!d' \
  85                                 -e 's/^gcc version //' \
  86                                 -e 's/ .*//' -e 's/^[[[^0-9]]]*//' \
  87                                 -e 's/\..*//'`)
  88                     AC_MSG_RESULT($ac_cv_lbl_gcc_vers)
  89                     if test $ac_cv_lbl_gcc_vers -gt 1 ; then
  90                             $1="-O2"
  91                     fi
  92             fi
  93     else
  94             AC_MSG_CHECKING(that $CC handles ansi prototypes)
  95             AC_CACHE_VAL(ac_cv_lbl_cc_ansi_prototypes,
  96                 AC_TRY_COMPILE(
  97                     [#include <sys/types.h>],
  98                     [int frob(int, char *)],
  99                     ac_cv_lbl_cc_ansi_prototypes=yes,
 100                     ac_cv_lbl_cc_ansi_prototypes=no))
 101             AC_MSG_RESULT($ac_cv_lbl_cc_ansi_prototypes)
 102             if test $ac_cv_lbl_cc_ansi_prototypes = no ; then
 103                     case "$host_os" in
 104
 105                     hpux*)
 106                             AC_MSG_CHECKING(for HP-UX ansi compiler ($CC -Aa -D_HPUX_SOURCE))
 107                             savedcflags="$CFLAGS"
 108                             CFLAGS="-Aa -D_HPUX_SOURCE $CFLAGS"
 109                             AC_CACHE_VAL(ac_cv_lbl_cc_hpux_cc_aa,
 110                                 AC_TRY_COMPILE(
 111                                     [#include <sys/types.h>],
 112                                     [int frob(int, char *)],
 113                                     ac_cv_lbl_cc_hpux_cc_aa=yes,
 114                                     ac_cv_lbl_cc_hpux_cc_aa=no))
 115                             AC_MSG_RESULT($ac_cv_lbl_cc_hpux_cc_aa)
 116                             if test $ac_cv_lbl_cc_hpux_cc_aa = no ; then
 117                                     AC_MSG_ERROR(see the INSTALL doc for more info)
 118                             fi
 119                             CFLAGS="$savedcflags"
 120                             V_CCOPT="-Aa $V_CCOPT"
 121                             AC_DEFINE(_HPUX_SOURCE)
 122                             ;;
 123
 124                     *)
 125                             AC_MSG_ERROR(see the INSTALL doc for more info)
 126                             ;;
 127                     esac
 128             fi
 129             $2="$$2 -I/usr/local/include"
 130             LDFLAGS="$LDFLAGS -L/usr/local/lib"
 131
 132             case "$host_os" in
 133
 134             irix*)
 135                     V_CCOPT="$V_CCOPT -xansi -signed -O"
 136                     ;;
 137
 138             osf*)
 139                     V_CCOPT="$V_CCOPT -std1 -O"
 140                     ;;
 141
 142             ultrix*)
 143                     AC_MSG_CHECKING(that Ultrix $CC hacks const in prototypes)
 144                     AC_CACHE_VAL(ac_cv_lbl_cc_const_proto,
 145                         AC_TRY_COMPILE(
 146                             [#include <sys/types.h>],
 147                             [struct a { int b; };
 148                             void c(const struct a *)],
 149                             ac_cv_lbl_cc_const_proto=yes,
 150                             ac_cv_lbl_cc_const_proto=no))
 151                     AC_MSG_RESULT($ac_cv_lbl_cc_const_proto)
 152                     if test $ac_cv_lbl_cc_const_proto = no ; then
 153                             AC_DEFINE(const,)
 154                     fi
 155                     ;;
 156             esac
 157     fi
 158 ])
 159
 160 #
 161 # Try compiling a sample of the type of code that appears in
 162 # gencode.c with "inline", "__inline__", and "__inline".
 163 #
 164 # Autoconf's AC_C_INLINE, at least in autoconf 2.13, isn't good enough,
 165 # as it just tests whether a function returning "int" can be inlined;
 166 # at least some versions of HP's C compiler can inline that, but can't
 167 # inline a function that returns a struct pointer.
 168 #
 169 AC_DEFUN(AC_LBL_C_INLINE,
 170     [AC_MSG_CHECKING(for inline)
 171     AC_CACHE_VAL(ac_cv_lbl_inline, [
 172         ac_cv_lbl_inline=""
 173         ac_lbl_cc_inline=no
 174         for ac_lbl_inline in inline __inline__ __inline
 175         do
 176             AC_TRY_COMPILE(
 177                 [#define inline $ac_lbl_inline
 178                 static inline struct iltest *foo(void);
 179                 struct iltest {
 180                     int iltest1;
 181                     int iltest2;
 182                 };
 183
 184                 static inline struct iltest *
 185                 foo()
 186                 {
 187                     static struct iltest xxx;
 188
 189                     return &xxx;
 190                 }],,ac_lbl_cc_inline=yes,)
 191             if test "$ac_lbl_cc_inline" = yes ; then
 192                 break;
 193             fi
 194         done
 195         if test "$ac_lbl_cc_inline" = yes ; then
 196             ac_cv_lbl_inline=$ac_lbl_inline
 197         fi])
 198     if test ! -z "$ac_cv_lbl_inline" ; then
 199         AC_MSG_RESULT($ac_cv_lbl_inline)
 200     else
 201         AC_MSG_RESULT(no)
 202     fi
 203     AC_DEFINE_UNQUOTED(inline, $ac_cv_lbl_inline, [Define as token for inline if inlining supported])])
 204
 205 dnl
 206 dnl Use pfopen.c if available and pfopen() not in standard libraries
 207 dnl Require libpcap
 208 dnl Look for libpcap in ..
 209 dnl Use the installed libpcap if there is no local version
 210 dnl
 211 dnl usage:
 212 dnl
 213 dnl     AC_LBL_LIBPCAP(pcapdep, incls)
 214 dnl
 215 dnl results:
 216 dnl
 217 dnl     $1 (pcapdep set)
 218 dnl     $2 (incls appended)
 219 dnl     LIBS
 220 dnl     LBL_LIBS
 221 dnl
 222 AC_DEFUN(AC_LBL_LIBPCAP,
 223     [AC_REQUIRE([AC_LBL_LIBRARY_NET])
 224     dnl
 225     dnl save a copy before locating libpcap.a
 226     dnl
 227     LBL_LIBS="$LIBS"
 228     pfopen=/usr/examples/packetfilter/pfopen.c
 229     if test -f $pfopen ; then
 230             AC_CHECK_FUNCS(pfopen)
 231             if test $ac_cv_func_pfopen = "no" ; then
 232                     AC_MSG_RESULT(Using $pfopen)
 233                     LIBS="$LIBS $pfopen"
 234             fi
 235     fi
 236     AC_MSG_CHECKING(for local pcap library)
 237     libpcap=FAIL
 238     lastdir=FAIL
 239     places=`ls $srcdir/.. | sed -e 's,/$,,' -e "s,^,$srcdir/../," | \
 240         egrep '/libpcap-[[0-9]]*.[[0-9]]*(.[[0-9]]*)?([[ab]][[0-9]]*)?$'`
 241     for dir in $places $srcdir/../libpcap $srcdir/libpcap ; do
 242             basedir=`echo $dir | sed -e 's/[[ab]][[0-9]]*$//'`
 243             if test $lastdir = $basedir ; then
 244                     dnl skip alphas when an actual release is present
 245                     continue;
 246             fi
 247             lastdir=$dir
 248             if test -r $dir/libpcap.a ; then
 249                     libpcap=$dir/libpcap.a
 250                     d=$dir
 251                     dnl continue and select the last one that exists
 252             fi
 253     done
 254     if test $libpcap = FAIL ; then
 255             AC_MSG_RESULT(not found)
 256             AC_CHECK_LIB(pcap, main, libpcap="-lpcap")
 257             if test $libpcap = FAIL ; then
 258                     AC_MSG_ERROR(see the INSTALL doc for more info)
 259             fi
 260             dnl
 261             dnl Good old Red Hat Linux puts "pcap.h" in
 262             dnl "/usr/include/pcap"; had the LBL folks done so,
 263             dnl that would have been a good idea, but for
 264             dnl the Red Hat folks to do so just breaks source
 265             dnl compatibility with other systems.
 266             dnl
 267             dnl We work around this by assuming that, as we didn't
 268             dnl find a local libpcap, libpcap is in /usr/lib or
 269             dnl /usr/local/lib and that the corresponding header
 270             dnl file is under one of those directories; if we don't
 271             dnl find it in either of those directories, we check to
 272             dnl see if it's in a "pcap" subdirectory of them and,
 273             dnl if so, add that subdirectory to the "-I" list.
 274             dnl
 275             AC_MSG_CHECKING(for extraneous pcap header directories)
 276             if test \( ! -r /usr/local/include/pcap.h \) -a \
 277                         \( ! -r /usr/include/pcap.h \); then
 278                 if test -r /usr/local/include/pcap/pcap.h; then
 279                     d="/usr/local/include/pcap"
 280                 elif test -r /usr/include/pcap/pcap.h; then
 281                     d="/usr/include/pcap"
 282                 fi
 283             fi
 284             if test -z "$d" ; then
 285                 AC_MSG_RESULT(not found)
 286             else
 287                 $2="-I$d $$2"
 288                 AC_MSG_RESULT(found -- -I$d added)
 289             fi
 290     else
 291             $1=$libpcap
 292             places=`ls $srcdir/.. | sed -e 's,/$,,' -e "s,^,$srcdir/../," | \
 293                         egrep '/libpcap-[[0-9]]*.[[0-9]]*(.[[0-9]]*)?([[ab]][[0-9]]*)?$'`
 294             if test -r $d/pcap.h; then
 295                     $2="-I$d $$2"
 296             elif test -r $places/pcap.h; then
 297                     $2="-I$places $$2"
 298             else
 299                     AC_MSG_ERROR(cannot find pcap.h, see INSTALL)
 300             fi
 301             AC_MSG_RESULT($libpcap)
 302     fi
 303     LIBS="$libpcap $LIBS"
 304     case "$host_os" in
 305
 306     aix*)
 307             pseexe="/lib/pse.exp"
 308             AC_MSG_CHECKING(for $pseexe)
 309             if test -f $pseexe ; then
 310                     AC_MSG_RESULT(yes)
 311                     LIBS="$LIBS -I:$pseexe"
 312             fi
 313             #
 314             # We need "-lodm" and "-lcfg", as libpcap requires them on
 315             # AIX, and we just build a static libpcap.a and thus can't
 316             # arrange that when you link with libpcap you automatically
 317             # link with those libraries.
 318             #
 319             LIBS="$LIBS -lodm -lcfg"
 320             ;;
 321     esac
 322
 323     dnl
 324     dnl Check for "pcap_list_datalinks()", "pcap_set_datalink()",
 325     dnl and "pcap_datalink_name_to_val()", and use substitute versions
 326     dnl if they're not present
 327     dnl
 328     AC_CHECK_FUNC(pcap_list_datalinks,
 329         AC_DEFINE(HAVE_PCAP_LIST_DATALINKS),
 330         LIBOBJS="$LIBOBJS datalinks.o")
 331     AC_CHECK_FUNC(pcap_set_datalink,
 332         AC_DEFINE(HAVE_PCAP_SET_DATALINK))
 333     AC_CHECK_FUNC(pcap_datalink_name_to_val,
 334         AC_DEFINE(HAVE_PCAP_DATALINK_NAME_TO_VAL),
 335         LIBOBJS="$LIBOBJS dlnames.o")
 336
 337     dnl
 338     dnl Check for "pcap_breakloop()"; you can't substitute for it if
 339     dnl it's absent (it has hooks into the live capture routines),
 340     dnl so just define the HAVE_ value if it's there.
 341     dnl
 342     AC_CHECK_FUNCS(pcap_breakloop)
 343 ])
 344
 345 dnl
 346 dnl Define RETSIGTYPE and RETSIGVAL
 347 dnl
 348 dnl usage:
 349 dnl
 350 dnl     AC_LBL_TYPE_SIGNAL
 351 dnl
 352 dnl results:
 353 dnl
 354 dnl     RETSIGTYPE (defined)
 355 dnl     RETSIGVAL (defined)
 356 dnl
 357 AC_DEFUN(AC_LBL_TYPE_SIGNAL,
 358     [AC_BEFORE([$0], [AC_LBL_LIBPCAP])
 359     AC_TYPE_SIGNAL
 360     if test "$ac_cv_type_signal" = void ; then
 361             AC_DEFINE(RETSIGVAL,)
 362     else
 363             AC_DEFINE(RETSIGVAL,(0))
 364     fi
 365     case "$host_os" in
 366
 367     irix*)
 368             AC_DEFINE(_BSD_SIGNALS)
 369             ;;
 370
 371     *)
 372             dnl prefer sigaction() to sigset()
 373             AC_CHECK_FUNCS(sigaction)
 374             if test $ac_cv_func_sigaction = no ; then
 375                     AC_CHECK_FUNCS(sigset)
 376             fi
 377             ;;
 378     esac])
 379
 380 dnl
 381 dnl If using gcc, make sure we have ANSI ioctl definitions
 382 dnl
 383 dnl usage:
 384 dnl
 385 dnl     AC_LBL_FIXINCLUDES
 386 dnl
 387 AC_DEFUN(AC_LBL_FIXINCLUDES,
 388     [if test "$GCC" = yes ; then
 389             AC_MSG_CHECKING(for ANSI ioctl definitions)
 390             AC_CACHE_VAL(ac_cv_lbl_gcc_fixincludes,
 391                 AC_TRY_COMPILE(
 392                     [/*
 393                      * This generates a "duplicate case value" when fixincludes
 394                      * has not be run.
 395                      */
 396 #               include <sys/types.h>
 397 #               include <sys/time.h>
 398 #               include <sys/ioctl.h>
 399 #               ifdef HAVE_SYS_IOCCOM_H
 400 #               include <sys/ioccom.h>
 401 #               endif],
 402                     [switch (0) {
 403                     case _IO('A', 1):;
 404                     case _IO('B', 1):;
 405                     }],
 406                     ac_cv_lbl_gcc_fixincludes=yes,
 407                     ac_cv_lbl_gcc_fixincludes=no))
 408             AC_MSG_RESULT($ac_cv_lbl_gcc_fixincludes)
 409             if test $ac_cv_lbl_gcc_fixincludes = no ; then
 410                     # Don't cache failure
 411                     unset ac_cv_lbl_gcc_fixincludes
 412                     AC_MSG_ERROR(see the INSTALL for more info)
 413             fi
 414     fi])
 415
 416 dnl
 417 dnl Check for flex, default to lex
 418 dnl Require flex 2.4 or higher
 419 dnl Check for bison, default to yacc
 420 dnl Default to lex/yacc if both flex and bison are not available
 421 dnl Define the yy prefix string if using flex and bison
 422 dnl
 423 dnl usage:
 424 dnl
 425 dnl     AC_LBL_LEX_AND_YACC(lex, yacc, yyprefix)
 426 dnl
 427 dnl results:
 428 dnl
 429 dnl     $1 (lex set)
 430 dnl     $2 (yacc appended)
 431 dnl     $3 (optional flex and bison -P prefix)
 432 dnl
 433 AC_DEFUN(AC_LBL_LEX_AND_YACC,
 434     [AC_ARG_WITH(flex, [  --without-flex          don't use flex])
 435     AC_ARG_WITH(bison, [  --without-bison         don't use bison])
 436     if test "$with_flex" = no ; then
 437             $1=lex
 438     else
 439             AC_CHECK_PROGS($1, flex, lex)
 440     fi
 441     if test "$$1" = flex ; then
 442             # The -V flag was added in 2.4
 443             AC_MSG_CHECKING(for flex 2.4 or higher)
 444             AC_CACHE_VAL(ac_cv_lbl_flex_v24,
 445                 if flex -V >/dev/null 2>&1; then
 446                         ac_cv_lbl_flex_v24=yes
 447                 else
 448                         ac_cv_lbl_flex_v24=no
 449                 fi)
 450             AC_MSG_RESULT($ac_cv_lbl_flex_v24)
 451             if test $ac_cv_lbl_flex_v24 = no ; then
 452                     s="2.4 or higher required"
 453                     AC_MSG_WARN(ignoring obsolete flex executable ($s))
 454                     $1=lex
 455             fi
 456     fi
 457     if test "$with_bison" = no ; then
 458             $2=yacc
 459     else
 460             AC_CHECK_PROGS($2, bison, yacc)
 461     fi
 462     if test "$$2" = bison ; then
 463             $2="$$2 -y"
 464     fi
 465     if test "$$1" != lex -a "$$2" = yacc -o "$$1" = lex -a "$$2" != yacc ; then
 466             AC_MSG_WARN(don't have both flex and bison; reverting to lex/yacc)
 467             $1=lex
 468             $2=yacc
 469     fi
 470     if test "$$1" = flex -a -n "$3" ; then
 471             $1="$$1 -P$3"
 472             $2="$$2 -p $3"
 473     fi])
 474
 475 dnl
 476 dnl Checks to see if union wait is used with WEXITSTATUS()
 477 dnl
 478 dnl usage:
 479 dnl
 480 dnl     AC_LBL_UNION_WAIT
 481 dnl
 482 dnl results:
 483 dnl
 484 dnl     DECLWAITSTATUS (defined)
 485 dnl
 486 AC_DEFUN(AC_LBL_UNION_WAIT,
 487     [AC_MSG_CHECKING(if union wait is used)
 488     AC_CACHE_VAL(ac_cv_lbl_union_wait,
 489         AC_TRY_COMPILE([
 490 #       include <sys/types.h>
 491 #       include <sys/wait.h>],
 492             [int status;
 493             u_int i = WEXITSTATUS(status);
 494             u_int j = waitpid(0, &status, 0);],
 495             ac_cv_lbl_union_wait=no,
 496             ac_cv_lbl_union_wait=yes))
 497     AC_MSG_RESULT($ac_cv_lbl_union_wait)
 498     if test $ac_cv_lbl_union_wait = yes ; then
 499             AC_DEFINE(DECLWAITSTATUS,union wait)
 500     else
 501             AC_DEFINE(DECLWAITSTATUS,int)
 502     fi])
 503
 504 dnl
 505 dnl Checks to see if the sockaddr struct has the 4.4 BSD sa_len member
 506 dnl
 507 dnl usage:
 508 dnl
 509 dnl     AC_LBL_SOCKADDR_SA_LEN
 510 dnl
 511 dnl results:
 512 dnl
 513 dnl     HAVE_SOCKADDR_SA_LEN (defined)
 514 dnl
 515 AC_DEFUN(AC_LBL_SOCKADDR_SA_LEN,
 516     [AC_MSG_CHECKING(if sockaddr struct has sa_len member)
 517     AC_CACHE_VAL(ac_cv_lbl_sockaddr_has_sa_len,
 518         AC_TRY_COMPILE([
 519 #       include <sys/types.h>
 520 #       include <sys/socket.h>],
 521         [u_int i = sizeof(((struct sockaddr *)0)->sa_len)],
 522         ac_cv_lbl_sockaddr_has_sa_len=yes,
 523         ac_cv_lbl_sockaddr_has_sa_len=no))
 524     AC_MSG_RESULT($ac_cv_lbl_sockaddr_has_sa_len)
 525     if test $ac_cv_lbl_sockaddr_has_sa_len = yes ; then
 526             AC_DEFINE(HAVE_SOCKADDR_SA_LEN)
 527     fi])
 528
 529 dnl
 530 dnl Checks to see if -R is used
 531 dnl
 532 dnl usage:
 533 dnl
 534 dnl     AC_LBL_HAVE_RUN_PATH
 535 dnl
 536 dnl results:
 537 dnl
 538 dnl     ac_cv_lbl_have_run_path (yes or no)
 539 dnl
 540 AC_DEFUN(AC_LBL_HAVE_RUN_PATH,
 541     [AC_MSG_CHECKING(for ${CC-cc} -R)
 542     AC_CACHE_VAL(ac_cv_lbl_have_run_path,
 543         [echo 'main(){}' > conftest.c
 544         ${CC-cc} -o conftest conftest.c -R/a1/b2/c3 >conftest.out 2>&1
 545         if test ! -s conftest.out ; then
 546                 ac_cv_lbl_have_run_path=yes
 547         else
 548                 ac_cv_lbl_have_run_path=no
 549         fi
 550         rm -f conftest*])
 551     AC_MSG_RESULT($ac_cv_lbl_have_run_path)
 552     ])
 553
 554 dnl
 555 dnl Due to the stupid way it's implemented, AC_CHECK_TYPE is nearly useless.
 556 dnl
 557 dnl usage:
 558 dnl
 559 dnl     AC_LBL_CHECK_TYPE
 560 dnl
 561 dnl results:
 562 dnl
 563 dnl     int32_t (defined)
 564 dnl     u_int32_t (defined)
 565 dnl
 566 AC_DEFUN(AC_LBL_CHECK_TYPE,
 567     [AC_MSG_CHECKING(for $1 using $CC)
 568     AC_CACHE_VAL(ac_cv_lbl_have_$1,
 569         AC_TRY_COMPILE([
 570 #       include "confdefs.h"
 571 #       include <sys/types.h>
 572 #       if STDC_HEADERS
 573 #       include <stdlib.h>
 574 #       include <stddef.h>
 575 #       endif],
 576         [$1 i],
 577         ac_cv_lbl_have_$1=yes,
 578         ac_cv_lbl_have_$1=no))
 579     AC_MSG_RESULT($ac_cv_lbl_have_$1)
 580     if test $ac_cv_lbl_have_$1 = no ; then
 581             AC_DEFINE($1, $2)
 582     fi])
 583
 584 dnl
 585 dnl Checks to see if unaligned memory accesses fail
 586 dnl
 587 dnl usage:
 588 dnl
 589 dnl     AC_LBL_UNALIGNED_ACCESS
 590 dnl
 591 dnl results:
 592 dnl
 593 dnl     LBL_ALIGN (DEFINED)
 594 dnl
 595 AC_DEFUN(AC_LBL_UNALIGNED_ACCESS,
 596     [AC_MSG_CHECKING(if unaligned accesses fail)
 597     AC_CACHE_VAL(ac_cv_lbl_unaligned_fail,
 598         [case "$host_cpu" in
 599
 600         #
 601         # These are CPU types where:
 602         #
 603         #       the CPU faults on an unaligned access, but at least some
 604         #       OSes that support that CPU catch the fault and simulate
 605         #       the unaligned access (e.g., Alpha/{Digital,Tru64} UNIX) -
 606         #       the simulation is slow, so we don't want to use it;
 607         #
 608         #       the CPU, I infer (from the old
 609         #
 610         # XXX: should also check that they don't do weird things (like on arm)
 611         #
 612         #       comment) doesn't fault on unaligned accesses, but doesn't
 613         #       do a normal unaligned fetch, either (e.g., presumably, ARM);
 614         #
 615         #       for whatever reason, the test program doesn't work
 616         #       (this has been claimed to be the case for several of those
 617         #       CPUs - I don't know what the problem is; the problem
 618         #       was reported as "the test program dumps core" for SuperH,
 619         #       but that's what the test program is *supposed* to do -
 620         #       it dumps core before it writes anything, so the test
 621         #       for an empty output file should find an empty output
 622         #       file and conclude that unaligned accesses don't work).
 623         #
 624         # This run-time test won't work if you're cross-compiling, so
 625         # in order to support cross-compiling for a particular CPU,
 626         # we have to wire in the list of CPU types anyway, as far as
 627         # I know, so perhaps we should just have a set of CPUs on
 628         # which we know it doesn't work, a set of CPUs on which we
 629         # know it does work, and have the script just fail on other
 630         # cpu types and update it when such a failure occurs.
 631         #
 632         alpha*|arm*|hp*|mips*|sh*|sparc*|ia64)
 633                 ac_cv_lbl_unaligned_fail=yes
 634                 ;;
 635
 636         *)
 637                 cat >conftest.c <<EOF
 638 #               include <sys/types.h>
 639 #               include <sys/wait.h>
 640 #               include <stdio.h>
 641                 unsigned char a[[5]] = { 1, 2, 3, 4, 5 };
 642                 main() {
 643                 unsigned int i;
 644                 pid_t pid;
 645                 int status;
 646                 /* avoid "core dumped" message */
 647                 pid = fork();
 648                 if (pid <  0)
 649                         exit(2);
 650                 if (pid > 0) {
 651                         /* parent */
 652                         pid = waitpid(pid, &status, 0);
 653                         if (pid < 0)
 654                                 exit(3);
 655                         exit(!WIFEXITED(status));
 656                 }
 657                 /* child */
 658                 i = *(unsigned int *)&a[[1]];
 659                 printf("%d\n", i);
 660                 exit(0);
 661                 }
 662 EOF
 663                 ${CC-cc} -o conftest $CFLAGS $CPPFLAGS $LDFLAGS \
 664                     conftest.c $LIBS >/dev/null 2>&1
 665                 if test ! -x conftest ; then
 666                         dnl failed to compile for some reason
 667                         ac_cv_lbl_unaligned_fail=yes
 668                 else
 669                         ./conftest >conftest.out
 670                         if test ! -s conftest.out ; then
 671                                 ac_cv_lbl_unaligned_fail=yes
 672                         else
 673                                 ac_cv_lbl_unaligned_fail=no
 674                         fi
 675                 fi
 676                 rm -f conftest* core core.conftest
 677                 ;;
 678         esac])
 679     AC_MSG_RESULT($ac_cv_lbl_unaligned_fail)
 680     if test $ac_cv_lbl_unaligned_fail = yes ; then
 681             AC_DEFINE(LBL_ALIGN)
 682     fi])
 683
 684 dnl
 685 dnl If using gcc and the file .devel exists:
 686 dnl     Compile with -g (if supported) and -Wall
 687 dnl     If using gcc 2 or later, do extra prototype checking and some other
 688 dnl     checks
 689 dnl     If an os prototype include exists, symlink os-proto.h to it
 690 dnl
 691 dnl usage:
 692 dnl
 693 dnl     AC_LBL_DEVEL(copt)
 694 dnl
 695 dnl results:
 696 dnl
 697 dnl     $1 (copt appended)
 698 dnl     HAVE_OS_PROTO_H (defined)
 699 dnl     os-proto.h (symlinked)
 700 dnl
 701 AC_DEFUN(AC_LBL_DEVEL,
 702     [rm -f os-proto.h
 703     if test "${LBL_CFLAGS+set}" = set; then
 704             $1="$$1 ${LBL_CFLAGS}"
 705     fi
 706     if test -f .devel ; then
 707             if test "$GCC" = yes ; then
 708                     if test "${LBL_CFLAGS+set}" != set; then
 709                             if test "$ac_cv_prog_cc_g" = yes ; then
 710                                     $1="-g $$1"
 711                             fi
 712                             $1="$$1 -Wall"
 713                             if test $ac_cv_lbl_gcc_vers -gt 1 ; then
 714                                     $1="$$1 -Wmissing-prototypes -Wstrict-prototypes -Wwrite-strings -W"
 715                             fi
 716                     fi
 717             else
 718                     case "$host_os" in
 719
 720                     irix6*)
 721                             V_CCOPT="$V_CCOPT -n32"
 722                             ;;
 723
 724                     *)
 725                             ;;
 726                     esac
 727             fi
 728             os=`echo $host_os | sed -e 's/\([[0-9]][[0-9]]*\)[[^0-9]].*$/\1/'`
 729             name="lbl/os-$os.h"
 730             if test -f $name ; then
 731                     ln -s $name os-proto.h
 732                     AC_DEFINE(HAVE_OS_PROTO_H)
 733             else
 734                     AC_MSG_WARN(can't find $name)
 735             fi
 736     fi])
 737
 738 dnl
 739 dnl Improved version of AC_CHECK_LIB
 740 dnl
 741 dnl Thanks to John Hawkinson (jhawk@mit.edu)
 742 dnl
 743 dnl usage:
 744 dnl
 745 dnl     AC_LBL_CHECK_LIB(LIBRARY, FUNCTION [, ACTION-IF-FOUND [,
 746 dnl         ACTION-IF-NOT-FOUND [, OTHER-LIBRARIES]]])
 747 dnl
 748 dnl results:
 749 dnl
 750 dnl     LIBS
 751 dnl
 752 dnl XXX - "AC_LBL_LIBRARY_NET" was redone to use "AC_SEARCH_LIBS"
 753 dnl rather than "AC_LBL_CHECK_LIB", so this isn't used any more.
 754 dnl We keep it around for reference purposes in case it's ever
 755 dnl useful in the future.
 756 dnl
 757
 758 define(AC_LBL_CHECK_LIB,
 759 [AC_MSG_CHECKING([for $2 in -l$1])
 760 dnl Use a cache variable name containing the library, function
 761 dnl name, and extra libraries to link with, because the test really is
 762 dnl for library $1 defining function $2, when linked with potinal
 763 dnl library $5, not just for library $1.  Separate tests with the same
 764 dnl $1 and different $2's or $5's may have different results.
 765 ac_lib_var=`echo $1['_']$2['_']$5 | sed 'y%./+- %__p__%'`
 766 AC_CACHE_VAL(ac_cv_lbl_lib_$ac_lib_var,
 767 [ac_save_LIBS="$LIBS"
 768 LIBS="-l$1 $5 $LIBS"
 769 AC_TRY_LINK(dnl
 770 ifelse([$2], [main], , dnl Avoid conflicting decl of main.
 771 [/* Override any gcc2 internal prototype to avoid an error.  */
 772 ]ifelse(AC_LANG, CPLUSPLUS, [#ifdef __cplusplus
 773 extern "C"
 774 #endif
 775 ])dnl
 776 [/* We use char because int might match the return type of a gcc2
 777     builtin and then its argument prototype would still apply.  */
 778 char $2();
 779 ]),
 780             [$2()],
 781             eval "ac_cv_lbl_lib_$ac_lib_var=yes",
 782             eval "ac_cv_lbl_lib_$ac_lib_var=no")
 783 LIBS="$ac_save_LIBS"
 784 ])dnl
 785 if eval "test \"`echo '$ac_cv_lbl_lib_'$ac_lib_var`\" = yes"; then
 786   AC_MSG_RESULT(yes)
 787   ifelse([$3], ,
 788 [changequote(, )dnl
 789   ac_tr_lib=HAVE_LIB`echo $1 | sed -e 's/[^a-zA-Z0-9_]/_/g' \
 790     -e 'y/abcdefghijklmnopqrstuvwxyz/ABCDEFGHIJKLMNOPQRSTUVWXYZ/'`
 791 changequote([, ])dnl
 792   AC_DEFINE_UNQUOTED($ac_tr_lib)
 793   LIBS="-l$1 $LIBS"
 794 ], [$3])
 795 else
 796   AC_MSG_RESULT(no)
 797 ifelse([$4], , , [$4
 798 ])dnl
 799 fi
 800 ])
 801
 802 dnl
 803 dnl AC_LBL_LIBRARY_NET
 804 dnl
 805 dnl This test is for network applications that need socket() and
 806 dnl gethostbyname() -ish functions.  Under Solaris, those applications
 807 dnl need to link with "-lsocket -lnsl".  Under IRIX, they need to link
 808 dnl with "-lnsl" but should *not* link with "-lsocket" because
 809 dnl libsocket.a breaks a number of things (for instance:
 810 dnl gethostbyname() under IRIX 5.2, and snoop sockets under most
 811 dnl versions of IRIX).
 812 dnl
 813 dnl Unfortunately, many application developers are not aware of this,
 814 dnl and mistakenly write tests that cause -lsocket to be used under
 815 dnl IRIX.  It is also easy to write tests that cause -lnsl to be used
 816 dnl under operating systems where neither are necessary (or useful),
 817 dnl such as SunOS 4.1.4, which uses -lnsl for TLI.
 818 dnl
 819 dnl This test exists so that every application developer does not test
 820 dnl this in a different, and subtly broken fashion.
 821
 822 dnl It has been argued that this test should be broken up into two
 823 dnl seperate tests, one for the resolver libraries, and one for the
 824 dnl libraries necessary for using Sockets API. Unfortunately, the two
 825 dnl are carefully intertwined and allowing the autoconf user to use
 826 dnl them independantly potentially results in unfortunate ordering
 827 dnl dependancies -- as such, such component macros would have to
 828 dnl carefully use indirection and be aware if the other components were
 829 dnl executed. Since other autoconf macros do not go to this trouble,
 830 dnl and almost no applications use sockets without the resolver, this
 831 dnl complexity has not been implemented.
 832 dnl
 833 dnl The check for libresolv is in case you are attempting to link
 834 dnl statically and happen to have a libresolv.a lying around (and no
 835 dnl libnsl.a).
 836 dnl
 837 AC_DEFUN(AC_LBL_LIBRARY_NET, [
 838     # Most operating systems have gethostbyname() in the default searched
 839     # libraries (i.e. libc):
 840     # Some OSes (eg. Solaris) place it in libnsl
 841     # Some strange OSes (SINIX) have it in libsocket:
 842     AC_SEARCH_LIBS(gethostbyname, nsl socket resolv)
 843     # Unfortunately libsocket sometimes depends on libnsl and
 844     # AC_SEARCH_LIBS isn't up to the task of handling dependencies like this.
 845     if test "$ac_cv_search_gethostbyname" = "no"
 846     then
 847         AC_CHECK_LIB(socket, gethostbyname,
 848                      LIBS="-lsocket -lnsl $LIBS", , -lnsl)
 849     fi
 850     AC_SEARCH_LIBS(socket, socket, ,
 851         AC_CHECK_LIB(socket, socket, LIBS="-lsocket -lnsl $LIBS", , -lnsl))
 852     # DLPI needs putmsg under HPUX so test for -lstr while we're at it
 853     AC_SEARCH_LIBS(putmsg, str)
 854     ])
 855
 856 dnl Copyright (c) 1999 WIDE Project. All rights reserved.
 857 dnl
 858 dnl Redistribution and use in source and binary forms, with or without
 859 dnl modification, are permitted provided that the following conditions
 860 dnl are met:
 861 dnl 1. Redistributions of source code must retain the above copyright
 862 dnl    notice, this list of conditions and the following disclaimer.
 863 dnl 2. Redistributions in binary form must reproduce the above copyright
 864 dnl    notice, this list of conditions and the following disclaimer in the
 865 dnl    documentation and/or other materials provided with the distribution.
 866 dnl 3. Neither the name of the project nor the names of its contributors
 867 dnl    may be used to endorse or promote products derived from this software
 868 dnl    without specific prior written permission.
 869 dnl
 870 dnl THIS SOFTWARE IS PROVIDED BY THE PROJECT AND CONTRIBUTORS ``AS IS'' AND
 871 dnl ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
 872 dnl IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
 873 dnl ARE DISCLAIMED.  IN NO EVENT SHALL THE PROJECT OR CONTRIBUTORS BE LIABLE
 874 dnl FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
 875 dnl DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
 876 dnl OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
 877 dnl HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
 878 dnl LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
 879 dnl OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
 880 dnl SUCH DAMAGE.
 881
 882 dnl
 883 dnl Checks to see if AF_INET6 is defined
 884 AC_DEFUN(AC_CHECK_AF_INET6, [
 885         AC_MSG_CHECKING(for AF_INET6)
 886         AC_CACHE_VAL($1,
 887         AC_TRY_COMPILE([
 888 #               include <sys/types.h>
 889 #               include <sys/socket.h>],
 890                 [int a = AF_INET6],
 891                 $1=yes,
 892                 $1=no))
 893         AC_MSG_RESULT($$1)
 894                 if test $$1 = yes ; then
 895                         AC_DEFINE(HAVE_AF_INET6)
 896         fi
 897 ])
 898
 899 dnl
 900 dnl Checks to see if the sockaddr struct has the 4.4 BSD sa_len member
 901 dnl borrowed from LBL libpcap
 902 AC_DEFUN(AC_CHECK_SA_LEN, [
 903         AC_MSG_CHECKING(if sockaddr struct has sa_len member)
 904         AC_CACHE_VAL($1,
 905         AC_TRY_COMPILE([
 906 #               include <sys/types.h>
 907 #               include <sys/socket.h>],
 908                 [u_int i = sizeof(((struct sockaddr *)0)->sa_len)],
 909                 $1=yes,
 910                 $1=no))
 911         AC_MSG_RESULT($$1)
 912                 if test $$1 = yes ; then
 913                         AC_DEFINE(HAVE_SOCKADDR_SA_LEN)
 914         fi
 915 ])
 916
 917 dnl
 918 dnl Checks for portable prototype declaration macro
 919 AC_DEFUN(AC_CHECK_PORTABLE_PROTO,  [
 920         AC_MSG_CHECKING(for __P)
 921         AC_CACHE_VAL($1,
 922         AC_TRY_COMPILE([
 923 #               include <unistd.h>],
 924                 [int f __P(())],
 925                 $1=yes,
 926                 $1=no))
 927         AC_MSG_RESULT($$1)
 928         if test $$1 = yes; then
 929                 AC_DEFINE(HAVE_PORTABLE_PROTOTYPE)
 930         fi
 931 ])
 932
 933 dnl checks for u_intXX_t
 934 AC_DEFUN(AC_CHECK_BITTYPES, [
 935         $1=yes
 936 dnl check for u_int8_t
 937         AC_MSG_CHECKING(for u_int8_t)
 938         AC_CACHE_VAL(ac_cv_u_int8_t,
 939         AC_TRY_COMPILE([
 940 #               include <sys/types.h>],
 941                 [u_int8_t i],
 942                 ac_cv_u_int8_t=yes,
 943                 ac_cv_u_int8_t=no))
 944         AC_MSG_RESULT($ac_cv_u_int8_t)
 945         if test $ac_cv_u_int8_t = yes; then
 946                 AC_DEFINE(HAVE_U_INT8_T)
 947         else
 948                 $1=no
 949         fi
 950 dnl check for u_int16_t
 951         AC_MSG_CHECKING(for u_int16_t)
 952         AC_CACHE_VAL(ac_cv_u_int16_t,
 953         AC_TRY_COMPILE([
 954 #               include <sys/types.h>],
 955                 [u_int16_t i],
 956                 ac_cv_u_int16_t=yes,
 957                 ac_cv_u_int16_t=no))
 958         AC_MSG_RESULT($ac_cv_u_int16_t)
 959         if test $ac_cv_u_int16_t = yes; then
 960                 AC_DEFINE(HAVE_U_INT16_T)
 961         else
 962                 $1=no
 963         fi
 964 dnl check for u_int32_t
 965         AC_MSG_CHECKING(for u_int32_t)
 966         AC_CACHE_VAL(ac_cv_u_int32_t,
 967         AC_TRY_COMPILE([
 968 #               include <sys/types.h>],
 969                 [u_int32_t i],
 970                 ac_cv_u_int32_t=yes,
 971                 ac_cv_u_int32_t=no))
 972         AC_MSG_RESULT($ac_cv_u_int32_t)
 973         if test $ac_cv_u_int32_t = yes; then
 974                 AC_DEFINE(HAVE_U_INT32_T)
 975         else
 976                 $1=no
 977         fi
 978 ])
 979
 980 dnl
 981 dnl Checks for addrinfo structure
 982 AC_DEFUN(AC_STRUCT_ADDRINFO, [
 983         AC_MSG_CHECKING(for addrinfo)
 984         AC_CACHE_VAL($1,
 985         AC_TRY_COMPILE([
 986 #               include <netdb.h>],
 987                 [struct addrinfo a],
 988                 $1=yes,
 989                 $1=no))
 990         AC_MSG_RESULT($$1)
 991         if test $$1 = yes; then
 992                 AC_DEFINE(HAVE_ADDRINFO)
 993         else
 994                 AC_DEFINE(NEED_ADDRINFO_H)
 995         fi
 996 ])
 997
 998 dnl
 999 dnl Checks for NI_MAXSERV
1000 AC_DEFUN(AC_NI_MAXSERV, [
1001         AC_MSG_CHECKING(for NI_MAXSERV)
1002         AC_CACHE_VAL($1,
1003         AC_EGREP_CPP(yes, [#include <netdb.h>
1004 #ifdef NI_MAXSERV
1005 yes
1006 #endif],
1007                 $1=yes,
1008                 $1=no))
1009         AC_MSG_RESULT($$1)
1010         if test $$1 != yes; then
1011                 AC_DEFINE(NEED_ADDRINFO_H)
1012         fi
1013 ])
1014
1015 dnl
1016 dnl Checks for NI_NAMEREQD
1017 AC_DEFUN(AC_NI_NAMEREQD, [
1018         AC_MSG_CHECKING(for NI_NAMEREQD)
1019         AC_CACHE_VAL($1,
1020         AC_EGREP_CPP(yes, [#include <netdb.h>
1021 #ifdef NI_NOFQDN
1022 yes
1023 #endif],
1024                 $1=yes,
1025                 $1=no))
1026         AC_MSG_RESULT($$1)
1027         if test $$1 != yes; then
1028                 AC_DEFINE(NEED_ADDRINFO_H)
1029         fi
1030 ])
1031
1032 dnl
1033 dnl Checks for sockaddr_storage structure
1034 AC_DEFUN(AC_STRUCT_SA_STORAGE, [
1035         AC_MSG_CHECKING(for sockaddr_storage)
1036         AC_CACHE_VAL($1,
1037         AC_TRY_COMPILE([
1038 #               include <sys/types.h>
1039 #               include <sys/socket.h>],
1040                 [struct sockaddr_storage s],
1041                 $1=yes,
1042                 $1=no))
1043         AC_MSG_RESULT($$1)
1044         if test $$1 = yes; then
1045                 AC_DEFINE(HAVE_SOCKADDR_STORAGE)
1046         fi
1047 ])
1048
1049 dnl
1050 dnl Checks for macro of IP address size
1051 AC_DEFUN(AC_CHECK_ADDRSZ, [
1052         $1=yes
1053 dnl check for INADDRSZ
1054         AC_MSG_CHECKING(for INADDRSZ)
1055         AC_CACHE_VAL(ac_cv_inaddrsz,
1056         AC_TRY_COMPILE([
1057 #               include <arpa/nameser.h>],
1058                 [int a = INADDRSZ],
1059                 ac_cv_inaddrsz=yes,
1060                 ac_cv_inaddrsz=no))
1061         AC_MSG_RESULT($ac_cv_inaddrsz)
1062         if test $ac_cv_inaddrsz = yes; then
1063                 AC_DEFINE(HAVE_INADDRSZ)
1064         else
1065                 $1=no
1066         fi
1067 dnl check for IN6ADDRSZ
1068         AC_MSG_CHECKING(for IN6ADDRSZ)
1069         AC_CACHE_VAL(ac_cv_in6addrsz,
1070         AC_TRY_COMPILE([
1071 #               include <arpa/nameser.h>],
1072                 [int a = IN6ADDRSZ],
1073                 ac_cv_in6addrsz=yes,
1074                 ac_cv_in6addrsz=no))
1075         AC_MSG_RESULT($ac_cv_in6addrsz)
1076         if test $ac_cv_in6addrsz = yes; then
1077                 AC_DEFINE(HAVE_IN6ADDRSZ)
1078         else
1079                 $1=no
1080         fi
1081 ])
1082
1083 dnl
1084 dnl check for RES_USE_INET6
1085 AC_DEFUN(AC_CHECK_RES_USE_INET6, [
1086         AC_MSG_CHECKING(for RES_USE_INET6)
1087         AC_CACHE_VAL($1,
1088         AC_TRY_COMPILE([
1089 #               include <sys/types.h>
1090 #               include <netinet/in.h>
1091 #               include <resolv.h>],
1092                 [int a = RES_USE_INET6],
1093                 $1=yes,
1094                 $1=no))
1095         AC_MSG_RESULT($$1)
1096         if test $$1 = yes; then
1097                 AC_DEFINE(HAVE_RES_USE_INET6)
1098         fi
1099 ])
1100
1101 dnl
1102 dnl check for AAAA
1103 AC_DEFUN(AC_CHECK_AAAA, [
1104         AC_MSG_CHECKING(for AAAA)
1105         AC_CACHE_VAL($1,
1106         AC_TRY_COMPILE([
1107 #               include <sys/types.h>
1108 #               include <arpa/nameser.h>],
1109                 [int a = T_AAAA],
1110                 $1=yes,
1111                 $1=no))
1112         AC_MSG_RESULT($$1)
1113         if test $$1 = yes; then
1114                 AC_DEFINE(HAVE_AAAA)
1115         fi
1116 ])
1117
1118 dnl
1119 dnl check for struct res_state_ext
1120 AC_DEFUN(AC_STRUCT_RES_STATE_EXT, [
1121         AC_MSG_CHECKING(for res_state_ext)
1122         AC_CACHE_VAL($1,
1123         AC_TRY_COMPILE([
1124 #               include <sys/types.h>
1125 #               include <netinet/in.h>
1126 #               include <netinet6/in6.h>
1127 #               include <resolv.h>],
1128                 [struct __res_state_ext e],
1129                 $1=yes,
1130                 $1=no))
1131         AC_MSG_RESULT($$1)
1132         if test $$1 = yes; then
1133                 AC_DEFINE(HAVE_RES_STATE_EXT)
1134         fi
1135 ])
1136
1137 dnl
1138 dnl check for struct res_state_ext
1139 AC_DEFUN(AC_STRUCT_RES_STATE, [
1140         AC_MSG_CHECKING(for nsort in res_state)
1141         AC_CACHE_VAL($1,
1142         AC_TRY_COMPILE([
1143 #               include <sys/types.h>
1144 #               include <netinet/in.h>
1145 #               include <netinet6/in6.h>
1146 #               include <resolv.h>],
1147                 [struct __res_state e; e.nsort = 0],
1148                 $1=yes,
1149                 $1=no))
1150         AC_MSG_RESULT($$1)
1151         if test $$1 = yes; then
1152                 AC_DEFINE(HAVE_NEW_RES_STATE)
1153         fi
1154 ])
1155
1156 dnl
1157 dnl check for h_errno
1158 AC_DEFUN(AC_VAR_H_ERRNO, [
1159         AC_MSG_CHECKING(for h_errno)
1160         AC_CACHE_VAL(ac_cv_var_h_errno,
1161         AC_TRY_COMPILE([
1162 #               include <sys/types.h>
1163 #               include <netdb.h>],
1164                 [int foo = h_errno;],
1165                 ac_cv_var_h_errno=yes,
1166                 ac_cv_var_h_errno=no))
1167         AC_MSG_RESULT($ac_cv_var_h_errno)
1168         if test "$ac_cv_var_h_errno" = "yes"; then
1169                 AC_DEFINE(HAVE_H_ERRNO)
1170         fi
1171 ])
1172
1173 dnl
1174 dnl Test for __attribute__
1175 dnl
1176
1177 AC_DEFUN(AC_C___ATTRIBUTE__, [
1178 AC_MSG_CHECKING(for __attribute__)
1179 AC_CACHE_VAL(ac_cv___attribute__, [
1180 AC_TRY_COMPILE([
1181 #include <stdlib.h>
1182 ],
1183 [
1184 static void foo(void) __attribute__ ((noreturn));
1185
1186 static void
1187 foo(void)
1188 {
1189   exit(1);
1190 }
1191 ],
1192 ac_cv___attribute__=yes,
1193 ac_cv___attribute__=no)])
1194 if test "$ac_cv___attribute__" = "yes"; then
1195   AC_DEFINE(HAVE___ATTRIBUTE__, 1, [define if your compiler has __attribute__])
1196 fi
1197 AC_MSG_RESULT($ac_cv___attribute__)
1198 ])