The Tcpdump Group git mirrors - tcpdump/blob - configure.ac

   1 dnl Copyright (c) 1994, 1995, 1996, 1997
   2 dnl     The Regents of the University of California.  All rights reserved.
   3 dnl
   4 dnl Process this file with autoconf to produce a configure script.
   5 dnl
   6
   7 #
   8 # See
   9 #
  10 #       https://ftp.gnu.org/gnu/config/README
  11 #
  12 # for the URLs to use to fetch new versions of config.guess and
  13 # config.sub.
  14 #
  15
  16 AC_PREREQ([2.69])
  17 AC_INIT([tcpdump],[m4_esyscmd_s(cat VERSION)])
  18 AC_CONFIG_SRCDIR(tcpdump.c)
  19
  20 AC_CANONICAL_HOST
  21
  22 AC_LBL_C_INIT_BEFORE_CC(V_INCLS)
  23 #
  24 # Try to enable as many C99 features as we can.
  25 # At minimum, we want C++/C99-style // comments.
  26 #
  27 AC_PROG_CC_C99
  28 if test "$ac_cv_prog_cc_c99" = "no"; then
  29         AC_MSG_WARN([The C compiler does not support C99; there may be compiler errors])
  30 fi
  31 AC_LBL_C_INIT(V_CCOPT, V_INCLS)
  32 AC_C_INLINE
  33
  34 AC_CHECK_HEADERS(fcntl.h rpc/rpc.h rpc/rpcent.h net/if.h)
  35
  36 case "$host_os" in
  37
  38 darwin*)
  39         AC_ARG_ENABLE(universal,
  40         AS_HELP_STRING([--disable-universal],[don't build universal on macOS]))
  41         if test "$enable_universal" != "no"; then
  42                 case "$host_os" in
  43
  44                 darwin9.*)
  45                         #
  46                         # Leopard.  Build for x86 and 32-bit PowerPC, with
  47                         # x86 first.  (That's what Apple does.)
  48                         #
  49                         V_CCOPT="$V_CCOPT -arch i386 -arch ppc"
  50                         LDFLAGS="$LDFLAGS -arch i386 -arch ppc"
  51                         ;;
  52
  53                 darwin10.*)
  54                         #
  55                         # Snow Leopard.  Build for x86-64 and x86, with
  56                         # x86-64 first.  (That's what Apple does.)
  57                         #
  58                         V_CCOPT="$V_CCOPT -arch x86_64 -arch i386"
  59                         LDFLAGS="$LDFLAGS -arch x86_64 -arch i386"
  60                         ;;
  61                 esac
  62         fi
  63         ;;
  64 esac
  65
  66 AC_ARG_WITH([smi],
  67    [AS_HELP_STRING([--with-smi],
  68      [link with libsmi (allows to load MIBs on the fly to decode SNMP packets) [default=yes, if available]])],
  69    [],
  70    [with_smi=yes])
  71
  72 if test "x$with_smi" != "xno" ; then
  73         AC_CHECK_HEADER(smi.h,
  74         [
  75                 #
  76                 # OK, we found smi.h.  Do we have libsmi with smiInit?
  77                 #
  78                 AC_CHECK_LIB(smi, smiInit,
  79                 [
  80                         #
  81                         # OK, we have libsmi with smiInit.  Can we use it?
  82                         #
  83                         AC_MSG_CHECKING([whether to enable libsmi])
  84                         savedlibs="$LIBS"
  85                         LIBS="-lsmi $LIBS"
  86                         AC_RUN_IFELSE([AC_LANG_SOURCE([[
  87 /* libsmi available check */
  88 #include <stdio.h>
  89 #include <stdlib.h>
  90 #include <string.h>
  91 #include <smi.h>
  92 int main()
  93 {
  94   int current, revision, age, n;
  95   const int required = 2;
  96   if (smiInit(""))
  97     exit(1);
  98   if (strcmp(SMI_LIBRARY_VERSION, smi_library_version))
  99     exit(2);
 100   n = sscanf(smi_library_version, "%d:%d:%d", &current, &revision, &age);
 101   if (n != 3)
 102     exit(3);
 103   if (required < current - age || required > current)
 104     exit(4);
 105   exit(0);
 106 }
 107                                 ]])
 108                                 ],
 109                                 [
 110                                         AC_MSG_RESULT(yes)
 111                                         AC_DEFINE(USE_LIBSMI, 1,
 112                                             [Define if you enable support for libsmi])
 113                                 ],
 114                                 [
 115                                         dnl autoconf documentation says that
 116                                         dnl $? contains the exit value.
 117                                         dnl reality is that it does not.
 118                                         dnl We leave this in just in case
 119                                         dnl autoconf ever comes back to
 120                                         dnl match the documentation.
 121                                         case $? in
 122                                           1) AC_MSG_RESULT(no - smiInit failed) ;;
 123                                           2) AC_MSG_RESULT(no - header/library version mismatch) ;;
 124                                           3) AC_MSG_RESULT(no - can't determine library version) ;;
 125                                           4) AC_MSG_RESULT(no - too old) ;;
 126                                           *) AC_MSG_RESULT(no) ;;
 127                                         esac
 128                                         LIBS="$savedlibs"
 129                                 ],
 130                                 [
 131                                         AC_MSG_RESULT(not when cross-compiling)
 132                                         LIBS="$savedlibs"
 133                                 ]
 134                         )
 135                 ])
 136         ])
 137 fi
 138
 139 AC_MSG_CHECKING([whether to enable the instrument functions code])
 140 AC_ARG_ENABLE([instrument-functions],
 141    [AS_HELP_STRING([--enable-instrument-functions],
 142      [enable instrument functions code [default=no]])],
 143    [],
 144    [enableval=no])
 145 case "$enableval" in
 146 yes)    AC_MSG_RESULT(yes)
 147         AC_CHECK_LIB([bfd], [bfd_init],
 148             [true],
 149             [AC_MSG_ERROR(
 150                [--enable-instrument-functions was given, but test for library libbfd failed. Please install the 'binutils-dev' package.])],
 151             [])
 152         AC_DEFINE(ENABLE_INSTRUMENT_FUNCTIONS, 1,
 153             [define if you want to build the instrument functions code])
 154         LOCALSRC="$LOCALSRC instrument-functions.c"
 155         # Add '-finstrument-functions' instrumentation option to generate
 156         # instrumentation calls for entry and exit to functions.
 157         # Try to avoid Address Space Layout Randomization (ALSR).
 158         CFLAGS="$CFLAGS -O0 -ggdb -finstrument-functions -fno-stack-protector -fno-pic"
 159         LDFLAGS="$LDFLAGS -O0 -ggdb -fno-stack-protector -no-pie"
 160         LIBS="$LIBS -lbfd"
 161         ;;
 162 *)      AC_MSG_RESULT(no)
 163         ;;
 164 esac
 165
 166 AC_MSG_CHECKING([whether to enable the possibly-buggy SMB printer])
 167 AC_ARG_ENABLE([smb],
 168    [AS_HELP_STRING([--enable-smb],
 169      [enable possibly-buggy SMB printer [default=no]])],
 170    [],
 171    [enableval=no])
 172 case "$enableval" in
 173 yes)    AC_MSG_RESULT(yes)
 174         AC_DEFINE(ENABLE_SMB, 1,
 175             [define if you want to build the possibly-buggy SMB printer])
 176         LOCALSRC="print-smb.c smbutil.c $LOCALSRC"
 177         ;;
 178 *)      AC_MSG_RESULT(no)
 179         ;;
 180 esac
 181
 182 AC_MSG_CHECKING([whether to drop root privileges by default])
 183 AC_ARG_WITH(
 184         [user],
 185         [AS_HELP_STRING([--with-user=USERNAME],
 186                 [drop privileges by default to USERNAME]
 187         )],
 188         [],
 189         [withval=no])
 190 AS_CASE(["$withval"],
 191         [no], [AC_MSG_RESULT(no)],
 192         [''|yes], [AC_MSG_ERROR([--with-user requires a username])],
 193         [
 194                 AC_DEFINE_UNQUOTED(WITH_USER, "$withval",
 195                     [define if should drop privileges by default])
 196                 AC_MSG_RESULT([yes, to user "$withval"])
 197         ]
 198 )
 199
 200 AC_MSG_CHECKING([whether to chroot])
 201 AC_ARG_WITH(
 202         [chroot],
 203         [AS_HELP_STRING([--with-chroot=DIRECTORY],
 204                 [when dropping privileges, chroot to DIRECTORY]
 205         )],
 206         [],
 207         [withval=no]
 208 )
 209 AS_CASE(["$withval"],
 210         [no], [AC_MSG_RESULT(no)],
 211         [''|yes], [AC_MSG_ERROR([--with-chroot requires a directory])],
 212         [
 213                 AC_DEFINE_UNQUOTED(WITH_CHROOT, "$withval",
 214                     [define if should chroot when dropping privileges])
 215                 AC_MSG_RESULT([yes, to directory "$withval"])
 216         ]
 217 )
 218
 219 AC_ARG_WITH(sandbox-capsicum,
 220         AS_HELP_STRING([--with-sandbox-capsicum],
 221                        [use Capsicum security functions @<:@default=yes, if available@:>@]))
 222 #
 223 # Check whether various functions are available.  If any are, set
 224 # ac_lbl_capsicum_function_seen to yes; if any are not, set
 225 # ac_lbl_capsicum_function_not_seen to yes.
 226 #
 227 # We don't check cap_rights_init(), as it's a macro, wrapping another
 228 # function, in at least some versions of FreeBSD, and AC_CHECK_FUNCS()
 229 # doesn't handle that.
 230 #
 231 # All of the ones we check for must be available in order to enable
 232 # capsicum sandboxing.
 233 #
 234 # XXX - do we need to check for all of them, or are there some that, if
 235 # present, imply others are present?
 236 #
 237 if test -z "$with_sandbox_capsicum" || test "$with_sandbox_capsicum" != "no" ; then
 238         #
 239         # First, make sure we have the required header.
 240         #
 241         AC_CHECK_HEADER(sys/capsicum.h,
 242         [
 243                 #
 244                 # We do; now make sure we have the required functions.
 245                 #
 246                 AC_CHECK_FUNCS(cap_enter cap_rights_limit cap_ioctls_limit openat,
 247                     ac_lbl_capsicum_function_seen=yes,
 248                     ac_lbl_capsicum_function_not_seen=yes)
 249         ])
 250         AC_CHECK_LIB(casper, cap_init, LIBS="$LIBS -lcasper")
 251         AC_CHECK_LIB(cap_dns, cap_gethostbyaddr, LIBS="$LIBS -lcap_dns")
 252 fi
 253 AC_MSG_CHECKING([whether to sandbox using capsicum])
 254 if test "x$ac_lbl_capsicum_function_seen" = "xyes" -a "x$ac_lbl_capsicum_function_not_seen" != "xyes"; then
 255         AC_DEFINE(HAVE_CAPSICUM, 1, [capsicum support available])
 256         AC_MSG_RESULT(yes)
 257 else
 258         AC_MSG_RESULT(no)
 259 fi
 260 AC_MSG_CHECKING([whether to sandbox using Casper library])
 261 if test "x$ac_cv_lib_casper_cap_init" = "xyes" -a "x$ac_cv_lib_cap_dns_cap_gethostbyaddr" = "xyes"; then
 262         AC_DEFINE(HAVE_CASPER, 1, [Casper support available])
 263         AC_MSG_RESULT(yes)
 264 else
 265         AC_MSG_RESULT(no)
 266 fi
 267
 268 #
 269 # We must check this before checking whether to check the OS's IPv6,
 270 # support because, on some platforms (such as SunOS 5.x), the test
 271 # program requires the extra networking libraries.
 272 #
 273 AC_LBL_LIBRARY_NET
 274
 275 AC_REPLACE_FUNCS(strlcat strlcpy strsep getservent getopt_long)
 276 AC_CHECK_FUNCS(fork vfork)
 277 AC_CHECK_FUNCS(setlinebuf)
 278
 279 #
 280 # Make sure we have snprintf(); we require it.
 281 #
 282 AC_CHECK_FUNC(snprintf,,
 283     AC_MSG_ERROR([snprintf() is required but wasn't found]))
 284
 285 #
 286 # It became apparent at some point that using a suitable C99 compiler does not
 287 # automatically mean snprintf(3) implementation in the libc supports all the
 288 # modifiers and specifiers used in the project, so let's test that before the
 289 # build, not after.
 290 #
 291 # Testing the sizeof_t length modifier takes making an snprintf() call and
 292 # comparing the actual result with the expected result.  If this fails, it will
 293 # most likely happen at run time, not compile time.
 294 #
 295 # Testing the 64-bit conversion specifiers in addition to that requires the
 296 # <inttypes.h> header to be present and the macros to be defined, so if this
 297 # fails, it will more likely happen at compile time.
 298 #
 299 AC_MSG_CHECKING([whether snprintf is suitable])
 300 AC_RUN_IFELSE(
 301     [
 302         AC_LANG_SOURCE([[
 303 #include <stdio.h>
 304 #include <string.h>
 305 #include <inttypes.h>
 306 #include <sys/types.h>
 307
 308 int main()
 309 {
 310   char buf[100];
 311   uint64_t t = (uint64_t)1 << 32;
 312
 313   snprintf(buf, sizeof(buf), "%zu", sizeof(buf));
 314   if (strncmp(buf, "100", sizeof(buf)))
 315     return 1;
 316
 317   snprintf(buf, sizeof(buf), "%zd", -sizeof(buf));
 318   if (strncmp(buf, "-100", sizeof(buf)))
 319     return 2;
 320
 321   snprintf(buf, sizeof(buf), "%" PRId64, -t);
 322   if (strncmp(buf, "-4294967296", sizeof(buf)))
 323     return 3;
 324
 325   snprintf(buf, sizeof(buf), "0o%" PRIo64, t);
 326   if (strncmp(buf, "0o40000000000", sizeof(buf)))
 327     return 4;
 328
 329   snprintf(buf, sizeof(buf), "0x%" PRIx64, t);
 330   if (strncmp(buf, "0x100000000", sizeof(buf)))
 331     return 5;
 332
 333   snprintf(buf, sizeof(buf), "%" PRIu64, t);
 334   if (strncmp(buf, "4294967296", sizeof(buf)))
 335     return 6;
 336
 337   return 0;
 338 }
 339         ]])
 340     ],
 341     [
 342         AC_MSG_RESULT(yes)
 343     ],
 344     [
 345         AC_MSG_RESULT(no)
 346         AC_MSG_ERROR(
 347 [The snprintf(3) implementation in this libc is not suitable,
 348 tcpdump would not work correctly even if it managed to compile.])
 349     ],
 350     [
 351         AC_MSG_RESULT(not while cross-compiling)
 352     ]
 353 )
 354
 355 AC_CHECK_LIB(rpc, main)         dnl It's unclear why we might need -lrpc
 356
 357 dnl Some platforms may need -lnsl for getrpcbynumber.
 358 AC_SEARCH_LIBS(getrpcbynumber, nsl,
 359     AC_DEFINE(HAVE_GETRPCBYNUMBER, 1, [define if you have getrpcbynumber()]))
 360
 361 AC_LBL_LIBPCAP(V_PCAPDEP, V_INCLS)
 362
 363 #
 364 # Check for these after AC_LBL_LIBPCAP, so we link with the appropriate
 365 # libraries (e.g., "-lsocket -lnsl" on Solaris).
 366 #
 367 # You are in a twisty little maze of UN*Xes, all different.
 368 # Some might not have ether_ntohost().
 369 # Some might have it and declare it in <net/ethernet.h>.
 370 # Some might have it and declare it in <netinet/ether.h>
 371 # Some might have it and declare it in <sys/ethernet.h>.
 372 # Some might have it and declare it in <arpa/inet.h>.
 373 # Some might have it and declare it in <netinet/if_ether.h>.
 374 # Some might have it and not declare it in any header file.
 375 #
 376 # Before you is a C compiler.
 377 #
 378 AC_CHECK_FUNCS(ether_ntohost, [
 379     AC_CACHE_CHECK(for buggy ether_ntohost, ac_cv_buggy_ether_ntohost, [
 380         AC_RUN_IFELSE([AC_LANG_SOURCE([[
 381                 #include <netdb.h>
 382                 #include <netinet/ether.h>
 383                 #include <stdlib.h>
 384                 #include <sys/types.h>
 385                 #include <sys/param.h>
 386                 #include <sys/socket.h>
 387
 388                 int
 389                 main(int argc, char **argv)
 390                 {
 391                         u_char ea[6] = { 0xff, 0xff, 0xff, 0xff, 0xff };
 392                         char name[MAXHOSTNAMELEN];
 393
 394                         ether_ntohost(name, (struct ether_addr *)ea);
 395                         exit(0);
 396                 }
 397         ]])
 398         ], [ac_cv_buggy_ether_ntohost=no],
 399            [ac_cv_buggy_ether_ntohost=yes],
 400            [ac_cv_buggy_ether_ntohost="not while cross-compiling"])])
 401     if test "$ac_cv_buggy_ether_ntohost" = "no"; then
 402         AC_DEFINE(USE_ETHER_NTOHOST, 1,
 403             [define if you have ether_ntohost() and it works])
 404     fi
 405 ])
 406 if test "$ac_cv_func_ether_ntohost" = yes -a \
 407     "$ac_cv_buggy_ether_ntohost" = "no"; then
 408         #
 409         # OK, we have ether_ntohost().  Is it declared in <net/ethernet.h>?
 410         #
 411         # This test fails if we don't have <net/ethernet.h> or if we do
 412         # but it doesn't declare ether_ntohost().
 413         #
 414         AC_CHECK_DECL(ether_ntohost,
 415             [
 416                 AC_DEFINE(NET_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
 417                     [Define to 1 if net/ethernet.h declares `ether_ntohost'])
 418             ],,
 419             [
 420 #include <net/ethernet.h>
 421             ])
 422         #
 423         # Did that succeed?
 424         #
 425         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 426                 #
 427                 # No, how about <netinet/ether.h>, as on Linux?
 428                 #
 429                 # This test fails if we don't have <netinet/ether.h>
 430                 # or if we do but it doesn't declare ether_ntohost().
 431                 #
 432                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 433                 # treat the previous failure as a cached value and
 434                 # suppress the next test.
 435                 #
 436                 unset ac_cv_have_decl_ether_ntohost
 437                 AC_CHECK_DECL(ether_ntohost,
 438                     [
 439                         AC_DEFINE(NETINET_ETHER_H_DECLARES_ETHER_NTOHOST,,
 440                             [Define to 1 if netinet/ether.h declares `ether_ntohost'])
 441                     ],,
 442                     [
 443 #include <netinet/ether.h>
 444                     ])
 445         fi
 446         #
 447         # Did that succeed?
 448         #
 449         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 450                 #
 451                 # No, how about <sys/ethernet.h>, as on Solaris 10
 452                 # and later?
 453                 #
 454                 # This test fails if we don't have <sys/ethernet.h>
 455                 # or if we do but it doesn't declare ether_ntohost().
 456                 #
 457                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 458                 # treat the previous failure as a cached value and
 459                 # suppress the next test.
 460                 #
 461                 unset ac_cv_have_decl_ether_ntohost
 462                 AC_CHECK_DECL(ether_ntohost,
 463                     [
 464                         AC_DEFINE(SYS_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
 465                             [Define to 1 if sys/ethernet.h declares `ether_ntohost'])
 466                     ],,
 467                     [
 468 #include <sys/ethernet.h>
 469                     ])
 470         fi
 471         #
 472         # Did that succeed?
 473         #
 474         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 475                 #
 476                 # No, how about <arpa/inet.h>, as in AIX?
 477                 #
 478                 # This test fails if we don't have <arpa/inet.h>
 479                 # (if we have ether_ntohost(), we should have
 480                 # networking, and if we have networking, we should
 481                 # have <arpa/inet.h>) or if we do but it doesn't
 482                 # declare ether_ntohost().
 483                 #
 484                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 485                 # treat the previous failure as a cached value and
 486                 # suppress the next test.
 487                 #
 488                 unset ac_cv_have_decl_ether_ntohost
 489                 AC_CHECK_DECL(ether_ntohost,
 490                     [
 491                         AC_DEFINE(ARPA_INET_H_DECLARES_ETHER_NTOHOST,,
 492                             [Define to 1 if arpa/inet.h declares `ether_ntohost'])
 493                     ],,
 494                     [
 495 #include <arpa/inet.h>
 496                     ])
 497         fi
 498         #
 499         # Did that succeed?
 500         #
 501         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 502                 #
 503                 # No, how about <netinet/if_ether.h>?
 504                 # On some platforms, it requires <net/if.h> and
 505                 # <netinet/in.h>, and we always include it with
 506                 # both of them, so test it with both of them.
 507                 #
 508                 # This test fails if we don't have <netinet/if_ether.h>
 509                 # and the headers we include before it, or if we do but
 510                 # <netinet/if_ether.h> doesn't declare ether_hostton().
 511                 #
 512                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 513                 # treat the previous failure as a cached value and
 514                 # suppress the next test.
 515                 #
 516                 unset ac_cv_have_decl_ether_ntohost
 517                 AC_CHECK_DECL(ether_ntohost,
 518                     [
 519                         AC_DEFINE(NETINET_IF_ETHER_H_DECLARES_ETHER_NTOHOST,,
 520                             [Define to 1 if netinet/if_ether.h declares `ether_ntohost'])
 521                     ],,
 522                     [
 523 #include <sys/types.h>
 524 #include <sys/socket.h>
 525 #include <net/if.h>
 526 #include <netinet/in.h>
 527 #include <netinet/if_ether.h>
 528                     ])
 529         fi
 530         #
 531         # After all that, is ether_ntohost() declared?
 532         #
 533         if test "$ac_cv_have_decl_ether_ntohost" = yes; then
 534                 #
 535                 # Yes.
 536                 #
 537                 AC_DEFINE(HAVE_DECL_ETHER_NTOHOST, 1,
 538                     [Define to 1 if you have the declaration of `ether_ntohost'])
 539         else
 540                 #
 541                 # No, we'll have to declare it ourselves.
 542                 # Do we have "struct ether_addr" if we include
 543                 # <netinet/if_ether.h>?
 544                 #
 545                 AC_CHECK_TYPES(struct ether_addr,,,
 546                     [
 547                         #include <sys/types.h>
 548                         #include <sys/socket.h>
 549                         #include <net/if.h>
 550                         #include <netinet/in.h>
 551                         #include <netinet/if_ether.h>
 552                     ])
 553         fi
 554 fi
 555
 556 dnl
 557 dnl Check for "pcap_list_datalinks()" and use a substitute version if
 558 dnl it's not present.  If it is present, check for "pcap_free_datalinks()";
 559 dnl if it's not present, we don't replace it for now.  (We could do so
 560 dnl on UN*X, but not on Windows, where hilarity ensues if a program
 561 dnl built with one version of the MSVC support library tries to free
 562 dnl something allocated by a library built with another version of
 563 dnl the MSVC support library.)
 564 dnl
 565 AC_CHECK_FUNC(pcap_list_datalinks,
 566         [
 567             AC_DEFINE(HAVE_PCAP_LIST_DATALINKS, 1,
 568                 [define if libpcap has pcap_list_datalinks()])
 569             AC_CHECK_FUNCS(pcap_free_datalinks)
 570         ],
 571         [
 572             AC_LIBOBJ(datalinks)
 573         ])
 574
 575 dnl
 576 dnl Check for "pcap_datalink_name_to_val()", and use a substitute
 577 dnl version if it's not present.  If it is present, check for
 578 dnl "pcap_datalink_val_to_description()", and if we don't have it,
 579 dnl use a substitute version.
 580 dnl
 581 AC_CHECK_FUNC(pcap_datalink_name_to_val,
 582         [
 583             AC_DEFINE(HAVE_PCAP_DATALINK_NAME_TO_VAL, 1,
 584                 [define if libpcap has pcap_datalink_name_to_val()])
 585             AC_CHECK_FUNC(pcap_datalink_val_to_description,
 586                 AC_DEFINE(HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION, 1,
 587                     [define if libpcap has pcap_datalink_val_to_description()]),
 588                 [
 589                     AC_LIBOBJ(dlnames)
 590                 ])
 591         ],
 592         [
 593             AC_LIBOBJ(dlnames)
 594         ])
 595
 596 dnl
 597 dnl Check for "pcap_set_datalink()"; you can't substitute for it if
 598 dnl it's absent (it has hooks into libpcap), so just define the
 599 dnl HAVE_ value if it's there.
 600 dnl
 601 AC_CHECK_FUNCS(pcap_set_datalink)
 602
 603 dnl
 604 dnl Check for "pcap_breakloop()"; you can't substitute for it if
 605 dnl it's absent (it has hooks into the live capture routines),
 606 dnl so just define the HAVE_ value if it's there.
 607 dnl
 608 AC_CHECK_FUNCS(pcap_breakloop)
 609
 610 #
 611 # Do we have the new open API?  Check for pcap_create, and assume that,
 612 # if we do, we also have pcap_activate() and the other new routines
 613 # introduced in libpcap 1.0.0.
 614 #
 615 AC_CHECK_FUNCS(pcap_create)
 616 if test $ac_cv_func_pcap_create = "yes" ; then
 617         #
 618         # OK, do we have pcap_set_tstamp_type?  If so, assume we have
 619         # pcap_list_tstamp_types and pcap_free_tstamp_types as well.
 620         #
 621         AC_CHECK_FUNCS(pcap_set_tstamp_type)
 622         #
 623         # And do we have pcap_set_tstamp_precision?  If so, we assume
 624         # we also have pcap_open_offline_with_tstamp_precision.
 625         #
 626         AC_CHECK_FUNCS(pcap_set_tstamp_precision)
 627 fi
 628
 629 #
 630 # Check for a miscellaneous collection of functions which we use
 631 # if we have them.
 632 #
 633 AC_CHECK_FUNCS(pcap_findalldevs)
 634 AC_CHECK_FUNCS(pcap_dump_flush pcap_lib_version)
 635 if test $ac_cv_func_pcap_lib_version = "no" ; then
 636     AC_MSG_CHECKING(whether pcap_version is defined by libpcap)
 637     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
 638         extern char pcap_version[];
 639
 640         return (int)pcap_version;
 641        ]])
 642        ],
 643        [ac_lbl_cv_pcap_version_defined=yes],
 644        [ac_lbl_cv_pcap_version_defined=no])
 645     if test "$ac_lbl_cv_pcap_version_defined" = yes ; then
 646         AC_MSG_RESULT(yes)
 647         AC_DEFINE(HAVE_PCAP_VERSION, 1, [define if libpcap has pcap_version])
 648     else
 649         AC_MSG_RESULT(no)
 650     fi
 651 fi
 652 AC_CHECK_FUNCS(pcap_setdirection pcap_set_immediate_mode pcap_dump_ftell64)
 653 AC_CHECK_FUNCS(pcap_open pcap_findalldevs_ex)
 654 AC_REPLACE_FUNCS(pcap_dump_ftell)
 655
 656 #
 657 # Check for special debugging functions
 658 #
 659 AC_CHECK_FUNCS(pcap_set_parser_debug)
 660 if test "$ac_cv_func_pcap_set_parser_debug" = "no" ; then
 661         #
 662         # OK, we don't have pcap_set_parser_debug() to set the libpcap
 663         # filter expression parser debug flag; can we directly set the
 664         # flag?
 665         AC_MSG_CHECKING(whether pcap_debug is defined by libpcap)
 666         AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
 667                 extern int pcap_debug;
 668
 669                 return pcap_debug;
 670            ]])
 671            ],
 672            [ac_lbl_cv_pcap_debug_defined=yes],
 673            [ac_lbl_cv_pcap_debug_defined=no])
 674         if test "$ac_lbl_cv_pcap_debug_defined" = yes ; then
 675                 AC_MSG_RESULT(yes)
 676                 AC_DEFINE(HAVE_PCAP_DEBUG, 1, [define if libpcap has pcap_debug])
 677         else
 678                 AC_MSG_RESULT(no)
 679                 #
 680                 # OK, what about "yydebug"?
 681                 #
 682                 AC_MSG_CHECKING(whether yydebug is defined by libpcap)
 683                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
 684                         extern int yydebug;
 685
 686                         return yydebug;
 687                    ]])
 688                    ],
 689                    [ac_lbl_cv_yydebug_defined=yes],
 690                    [ac_lbl_cv_yydebug_defined=no])
 691                 if test "$ac_lbl_cv_yydebug_defined" = yes ; then
 692                         AC_MSG_RESULT(yes)
 693                         AC_DEFINE(HAVE_YYDEBUG, 1, [define if libpcap has yydebug])
 694                 else
 695                         AC_MSG_RESULT(no)
 696                 fi
 697         fi
 698 fi
 699 AC_CHECK_FUNCS(pcap_set_optimizer_debug)
 700 AC_REPLACE_FUNCS(bpf_dump)      dnl moved to libpcap in 0.6
 701
 702 V_GROUP=0
 703 if test -f /etc/group -a ! -z "`grep '^wheel:' /etc/group`" ; then
 704         V_GROUP=wheel
 705 fi
 706 #
 707 # Assume V7/BSD convention for man pages (file formats in section 5,
 708 # miscellaneous info in section 7).
 709 #
 710 MAN_FILE_FORMATS=5
 711 MAN_MISC_INFO=7
 712 case "$host_os" in
 713
 714 aix*)
 715         dnl Workaround to enable certain features
 716         AC_DEFINE(_SUN,1,[define on AIX to get certain functions])
 717         ;;
 718
 719 hpux*)
 720         #
 721         # Use System V conventions for man pages.
 722         #
 723         MAN_FILE_FORMATS=4
 724         MAN_MISC_INFO=5
 725         ;;
 726
 727 solaris*)
 728         V_GROUP=sys
 729
 730         #
 731         # Use System V conventions for man pages.
 732         #
 733         MAN_FILE_FORMATS=4
 734         MAN_MISC_INFO=5
 735         ;;
 736 esac
 737
 738 if test -f /dev/bpf0 ; then
 739         V_GROUP=bpf
 740 fi
 741
 742 #
 743 # Make sure we have a definition for C99's uintptr_t (regardless of
 744 # whether the environment is a C99 environment or not).
 745 #
 746 AC_TYPE_UINTPTR_T
 747
 748 savedcppflags="$CPPFLAGS"
 749 CPPFLAGS="$CPPFLAGS $V_INCLS"
 750
 751 #
 752 # Check whether we have pcap/pcap-inttypes.h.
 753 # If we do, we use that to get the C99 types defined.
 754 #
 755 AC_CHECK_HEADERS(pcap/pcap-inttypes.h)
 756
 757 #
 758 # At compile time HAVE_PCAP_FINDALLDEVS depends on HAVE_PCAP_IF_T.
 759 #
 760 AC_CHECK_TYPES(pcap_if_t, , , [#include <pcap.h>])
 761
 762 CPPFLAGS="$savedcppflags"
 763
 764 #
 765 # Define the old BSD specified-width types in terms of the C99 types;
 766 # we may need them with libpcap include files.
 767 #
 768 AC_CHECK_TYPE([u_int8_t], ,
 769         [AC_DEFINE([u_int8_t], [uint8_t],
 770         [Define to `uint8_t' if u_int8_t not defined.])],
 771         [AC_INCLUDES_DEFAULT
 772 #include <sys/types.h>
 773 ])
 774 AC_CHECK_TYPE([u_int16_t], ,
 775         [AC_DEFINE([u_int16_t], [uint16_t],
 776         [Define to `uint16_t' if u_int16_t not defined.])],
 777         [AC_INCLUDES_DEFAULT
 778 #include <sys/types.h>
 779 ])
 780 AC_CHECK_TYPE([u_int32_t], ,
 781         [AC_DEFINE([u_int32_t], [uint32_t],
 782         [Define to `uint32_t' if u_int32_t not defined.])],
 783         [AC_INCLUDES_DEFAULT
 784 #include <sys/types.h>
 785 ])
 786 AC_CHECK_TYPE([u_int64_t], ,
 787         [AC_DEFINE([u_int64_t], [uint64_t],
 788         [Define to `uint64_t' if u_int64_t not defined.])],
 789         [AC_INCLUDES_DEFAULT
 790 #include <sys/types.h>
 791 ])
 792
 793 AC_PROG_RANLIB
 794 AC_CHECK_TOOL([AR], [ar])
 795
 796 AC_LBL_DEVEL(V_CCOPT)
 797
 798 # Check for OpenSSL/libressl libcrypto
 799 AC_MSG_CHECKING(whether to use OpenSSL/libressl libcrypto)
 800 # Specify location for both includes and libraries.
 801 want_libcrypto=ifavailable
 802 AC_ARG_WITH(crypto,
 803     AS_HELP_STRING([--with-crypto]@<:@=DIR@:>@,
 804                    [use OpenSSL/libressl libcrypto (located in directory DIR, if specified) @<:@default=yes, if available@:>@]),
 805 [
 806         if test $withval = no
 807         then
 808                 # User doesn't want to link with libcrypto.
 809                 want_libcrypto=no
 810                 AC_MSG_RESULT(no)
 811         elif test $withval = yes
 812         then
 813                 # User wants to link with libcrypto but hasn't specified
 814                 # a directory.
 815                 want_libcrypto=yes
 816                 AC_MSG_RESULT(yes)
 817         else
 818                 # User wants to link with libcrypto and has specified
 819                 # a directory, so use the provided value.
 820                 want_libcrypto=yes
 821                 libcrypto_root=$withval
 822                 AC_MSG_RESULT([yes, using the version installed in $withval])
 823
 824                 #
 825                 # Put the subdirectories of the libcrypto root directory
 826                 # at the front of the header and library search path.
 827                 #
 828                 CFLAGS="-I$withval/include $CFLAGS"
 829                 LIBS="-L$withval/lib $LIBS"
 830         fi
 831 ],[
 832         #
 833         # Use libcrypto if it's present, otherwise don't; no directory
 834         # was specified.
 835         #
 836         want_libcrypto=ifavailable
 837         AC_MSG_RESULT([yes, if available])
 838 ])
 839 if test "$want_libcrypto" != "no"; then
 840         #
 841         # Don't check for libcrypto unless we have its headers;
 842         # Apple, bless their pointy little heads, apparently ship
 843         # libcrypto as a library, but not the header files, in
 844         # El Capitan, probably because they don't want you writing
 845         # nasty portable code that could run on other UN*Xes, they
 846         # want you writing code that uses their Shiny New Crypto
 847         # Library and that only runs on macOS.
 848         #
 849         AC_CHECK_HEADER(openssl/crypto.h,
 850         [
 851                 AC_CHECK_LIB(crypto, DES_cbc_encrypt)
 852                 if test "$ac_cv_lib_crypto_DES_cbc_encrypt" = "yes"; then
 853                         AC_CHECK_HEADERS(openssl/evp.h)
 854                         #
 855                         # OK, then:
 856                         #
 857                         # 1) do we have EVP_CIPHER_CTX_new?
 858                         # If so, we use it to allocate an
 859                         # EVP_CIPHER_CTX, as EVP_CIPHER_CTX may be
 860                         # opaque; otherwise, we allocate it ourselves.
 861                         #
 862                         # 2) do we have EVP_DecryptInit_ex()?
 863                         # If so, we use it, because we need to be
 864                         # able to make two "initialize the cipher"
 865                         # calls, one with the cipher and key, and
 866                         # one with the IV, and, as of OpenSSL 1.1,
 867                         # You Can't Do That with EVP_DecryptInit(),
 868                         # because a call to EVP_DecryptInit() will
 869                         # unconditionally clear the context, and
 870                         # if you don't supply a cipher, it'll
 871                         # clear the cipher, rendering the context
 872                         # unusable and causing a crash.
 873                         #
 874                         AC_CHECK_FUNCS(EVP_CIPHER_CTX_new EVP_DecryptInit_ex)
 875                 fi
 876         ])
 877 fi
 878
 879 # Check for libcap-ng
 880 AC_MSG_CHECKING(whether to use libcap-ng)
 881 # Specify location for both includes and libraries.
 882 want_libcap_ng=ifavailable
 883 AC_ARG_WITH(cap_ng,
 884     AS_HELP_STRING([--with-cap-ng],
 885                    [use libcap-ng @<:@default=yes, if available@:>@]),
 886 [
 887         if test $withval = no
 888         then
 889                 want_libcap_ng=no
 890                 AC_MSG_RESULT(no)
 891         elif test $withval = yes
 892         then
 893                 want_libcap_ng=yes
 894                 AC_MSG_RESULT(yes)
 895         fi
 896 ],[
 897         #
 898         # Use libcap-ng if it's present, otherwise don't.
 899         #
 900         want_libcap_ng=ifavailable
 901         AC_MSG_RESULT([yes, if available])
 902 ])
 903 if test "$want_libcap_ng" != "no"; then
 904         AC_CHECK_LIB(cap-ng, capng_change_id)
 905         AC_CHECK_HEADERS(cap-ng.h)
 906 fi
 907
 908 dnl
 909 dnl set additional include path if necessary
 910 if test "$missing_includes" = "yes"; then
 911         CPPFLAGS="$CPPFLAGS -I$srcdir/missing"
 912         V_INCLS="$V_INCLS -I$srcdir/missing"
 913 fi
 914
 915 AC_SUBST(V_CCOPT)
 916 AC_SUBST(V_DEFS)
 917 AC_SUBST(V_GROUP)
 918 AC_SUBST(V_INCLS)
 919 AC_SUBST(V_PCAPDEP)
 920 AC_SUBST(LOCALSRC)
 921 AC_SUBST(MAN_FILE_FORMATS)
 922 AC_SUBST(MAN_MISC_INFO)
 923
 924 AC_PROG_INSTALL
 925
 926 AC_CONFIG_HEADERS([config.h])
 927
 928 AC_CONFIG_COMMANDS([.devel],[[if test -f .devel; then
 929         echo timestamp > stamp-h
 930         cat $srcdir/Makefile-devel-adds >> Makefile
 931         make depend || exit 1
 932 fi]])
 933 AC_CONFIG_FILES([Makefile tcpdump.1])
 934 AC_OUTPUT
 935 exit 0