]> The Tcpdump Group git mirrors - tcpdump/blob - aclocal.m4
projects / tcpdump / blob
summary | shortlog | log | commit | commitdiff | tree
history | raw | HEAD
EAP: add some more length checks.
[tcpdump] / aclocal.m4
1 dnl Copyright (c) 1995, 1996, 1997, 1998
2 dnl The Regents of the University of California. All rights reserved.
3 dnl
4 dnl Redistribution and use in source and binary forms, with or without
5 dnl modification, are permitted provided that: (1) source code distributions
6 dnl retain the above copyright notice and this paragraph in its entirety, (2)
7 dnl distributions including binary code include the above copyright notice and
8 dnl this paragraph in its entirety in the documentation or other materials
9 dnl provided with the distribution, and (3) all advertising materials mentioning
10 dnl features or use of this software display the following acknowledgement:
11 dnl ``This product includes software developed by the University of California,
12 dnl Lawrence Berkeley Laboratory and its contributors.'' Neither the name of
13 dnl the University nor the names of its contributors may be used to endorse
14 dnl or promote products derived from this software without specific prior
15 dnl written permission.
16 dnl THIS SOFTWARE IS PROVIDED ``AS IS'' AND WITHOUT ANY EXPRESS OR IMPLIED
17 dnl WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED WARRANTIES OF
18 dnl MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE.
19 dnl
20 dnl LBL autoconf macros
21 dnl
22
23 dnl
24 dnl Do whatever AC_LBL_C_INIT work is necessary before using AC_PROG_CC.
25 dnl
26 dnl It appears that newer versions of autoconf (2.64 and later) will,
27 dnl if you use AC_TRY_COMPILE in a macro, stick AC_PROG_CC at the
28 dnl beginning of the macro, even if the macro itself calls AC_PROG_CC.
29 dnl See the "Prerequisite Macros" and "Expanded Before Required" sections
30 dnl in the Autoconf documentation.
31 dnl
32 dnl This causes a steaming heap of fail in our case, as we were, in
33 dnl AC_LBL_C_INIT, doing the tests we now do in AC_LBL_C_INIT_BEFORE_CC,
34 dnl calling AC_PROG_CC, and then doing the tests we now do in
35 dnl AC_LBL_C_INIT. Now, we run AC_LBL_C_INIT_BEFORE_CC, AC_PROG_CC,
36 dnl and AC_LBL_C_INIT at the top level.
37 dnl
38 AC_DEFUN(AC_LBL_C_INIT_BEFORE_CC,
39 [
40 AC_BEFORE([$0], [AC_LBL_C_INIT])
41 AC_BEFORE([$0], [AC_PROG_CC])
42 AC_BEFORE([$0], [AC_LBL_FIXINCLUDES])
43 AC_BEFORE([$0], [AC_LBL_DEVEL])
44 AC_ARG_WITH(gcc, [ --without-gcc don't use gcc])
45 $1=""
46 if test "${srcdir}" != "." ; then
47 $1="-I$srcdir"
48 fi
49 if test "${CFLAGS+set}" = set; then
50 LBL_CFLAGS="$CFLAGS"
51 fi
52 if test -z "$CC" ; then
53 case "$host_os" in
54
55 bsdi*)
56 AC_CHECK_PROG(SHLICC2, shlicc2, yes, no)
57 if test $SHLICC2 = yes ; then
58 CC=shlicc2
59 export CC
60 fi
61 ;;
62 esac
63 fi
64 if test -z "$CC" -a "$with_gcc" = no ; then
65 CC=cc
66 export CC
67 fi
68 ])
69
70 dnl
71 dnl Determine which compiler we're using (cc or gcc)
72 dnl If using gcc, determine the version number
73 dnl If using cc:
74 dnl require that it support ansi prototypes
75 dnl use -O (AC_PROG_CC will use -g -O2 on gcc, so we don't need to
76 dnl do that ourselves for gcc)
77 dnl add -g flags, as appropriate
78 dnl explicitly specify /usr/local/include
79 dnl
80 dnl NOTE WELL: with newer versions of autoconf, "gcc" means any compiler
81 dnl that defines __GNUC__, which means clang, for example, counts as "gcc".
82 dnl
83 dnl usage:
84 dnl
85 dnl AC_LBL_C_INIT(copt, incls)
86 dnl
87 dnl results:
88 dnl
89 dnl $1 (copt set)
90 dnl $2 (incls set)
91 dnl CC
92 dnl LDFLAGS
93 dnl LBL_CFLAGS
94 dnl
95 AC_DEFUN(AC_LBL_C_INIT,
96 [
97 AC_BEFORE([$0], [AC_LBL_FIXINCLUDES])
98 AC_BEFORE([$0], [AC_LBL_DEVEL])
99 AC_BEFORE([$0], [AC_LBL_SHLIBS_INIT])
100 if test "$GCC" = yes ; then
101 #
102 # -Werror forces warnings to be errors.
103 #
104 ac_lbl_cc_force_warning_errors=-Werror
105 else
106 $2="$$2 -I/usr/local/include"
107 LDFLAGS="$LDFLAGS -L/usr/local/lib"
108
109 case "$host_os" in
110
111 darwin*)
112 #
113 # This is assumed either to be GCC or clang, both
114 # of which use -Werror to force warnings to be errors.
115 #
116 ac_lbl_cc_force_warning_errors=-Werror
117 ;;
118
119 hpux*)
120 #
121 # HP C, which is what we presume we're using, doesn't
122 # exit with a non-zero exit status if we hand it an
123 # invalid -W flag, can't be forced to do so even with
124 # +We, and doesn't handle GCC-style -W flags, so we
125 # don't want to try using GCC-style -W flags.
126 #
127 ac_lbl_cc_dont_try_gcc_dashW=yes
128 ;;
129
130 irix*)
131 #
132 # MIPS C, which is what we presume we're using, doesn't
133 # necessarily exit with a non-zero exit status if we
134 # hand it an invalid -W flag, can't be forced to do
135 # so, and doesn't handle GCC-style -W flags, so we
136 # don't want to try using GCC-style -W flags.
137 #
138 ac_lbl_cc_dont_try_gcc_dashW=yes
139 #
140 # It also, apparently, defaults to "char" being
141 # unsigned, unlike most other C implementations;
142 # I suppose we could say "signed char" whenever
143 # we want to guarantee a signed "char", but let's
144 # just force signed chars.
145 #
146 # -xansi is normally the default, but the
147 # configure script was setting it; perhaps -cckr
148 # was the default in the Old Days. (Then again,
149 # that would probably be for backwards compatibility
150 # in the days when ANSI C was Shiny and New, i.e.
151 # 1989 and the early '90's, so maybe we can just
152 # drop support for those compilers.)
153 #
154 # -g is equivalent to -g2, which turns off
155 # optimization; we choose -g3, which generates
156 # debugging information but doesn't turn off
157 # optimization (even if the optimization would
158 # cause inaccuracies in debugging).
159 #
160 $1="$$1 -xansi -signed -g3"
161 ;;
162
163 osf*)
164 #
165 # Presumed to be DEC OSF/1, Digital UNIX, or
166 # Tru64 UNIX.
167 #
168 # The DEC C compiler, which is what we presume we're
169 # using, doesn't exit with a non-zero exit status if we
170 # hand it an invalid -W flag, can't be forced to do
171 # so, and doesn't handle GCC-style -W flags, so we
172 # don't want to try using GCC-style -W flags.
173 #
174 ac_lbl_cc_dont_try_gcc_dashW=yes
175 #
176 # -g is equivalent to -g2, which turns off
177 # optimization; we choose -g3, which generates
178 # debugging information but doesn't turn off
179 # optimization (even if the optimization would
180 # cause inaccuracies in debugging).
181 #
182 $1="$$1 -g3"
183 ;;
184
185 solaris*)
186 #
187 # Assumed to be Sun C, which requires -errwarn to force
188 # warnings to be treated as errors.
189 #
190 ac_lbl_cc_force_warning_errors=-errwarn
191 ;;
192
193 ultrix*)
194 AC_MSG_CHECKING(that Ultrix $CC hacks const in prototypes)
195 AC_CACHE_VAL(ac_cv_lbl_cc_const_proto,
196 AC_TRY_COMPILE(
197 [#include <sys/types.h>],
198 [struct a { int b; };
199 void c(const struct a *)],
200 ac_cv_lbl_cc_const_proto=yes,
201 ac_cv_lbl_cc_const_proto=no))
202 AC_MSG_RESULT($ac_cv_lbl_cc_const_proto)
203 if test $ac_cv_lbl_cc_const_proto = no ; then
204 AC_DEFINE(const,[],
205 [to handle Ultrix compilers that don't support const in prototypes])
206 fi
207 ;;
208 esac
209 $1="$$1 -O"
210 fi
211 ])
212
213 dnl
214 dnl Check whether the compiler option specified as the second argument
215 dnl is supported by the compiler and, if so, add it to the macro
216 dnl specified as the first argument
217 dnl
218 AC_DEFUN(AC_LBL_CHECK_COMPILER_OPT,
219 [
220 AC_MSG_CHECKING([whether the compiler supports the $2 option])
221 save_CFLAGS="$CFLAGS"
222 CFLAGS="$CFLAGS $2"
223 #
224 # XXX - yes, this depends on the way AC_LANG_WERROR works,
225 # but no mechanism is provided to turn AC_LANG_WERROR on
226 # *and then turn it back off*, so that we *only* do it when
227 # testing compiler options - 15 years after somebody asked
228 # for it:
229 #
230 # https://autoconf.gnu.narkive.com/gTAVmfKD/how-to-cancel-flags-set-by-ac-lang-werror
231 #
232 save_ac_c_werror_flag="$ac_c_werror_flag"
233 ac_c_werror_flag=yes
234 #
235 # We use AC_LANG_SOURCE() so that we can control the complete
236 # content of the program being compiled. We do not, for example,
237 # want the default "int main()" that AC_LANG_PROGRAM() generates,
238 # as it will generate a warning with -Wold-style-definition, meaning
239 # that we would treat it as not working, as the test will fail if
240 # *any* error output, including a warning due to the flag we're
241 # testing, is generated; see
242 #
243 # https://www.postgresql.org/message-id/2192993.1591682589%40sss.pgh.pa.us
244 # https://www.postgresql.org/message-id/2192993.1591682589%40sss.pgh.pa.us
245 #
246 # This may, as per those two messages, be fixed in autoonf 2.70,
247 # but we only require 2.64 or newer for now.
248 #
249 AC_COMPILE_IFELSE(
250 [AC_LANG_SOURCE([[int main(void) { return 0; }]])],
251 [
252 AC_MSG_RESULT([yes])
253 CFLAGS="$save_CFLAGS"
254 $1="$$1 $2"
255 ],
256 [
257 AC_MSG_RESULT([no])
258 CFLAGS="$save_CFLAGS"
259 ])
260 ac_c_werror_flag="$save_ac_c_werror_flag"
261 ])
262
263 dnl
264 dnl Check whether the compiler supports an option to generate
265 dnl Makefile-style dependency lines
266 dnl
267 dnl GCC uses -M for this. Non-GCC compilers that support this
268 dnl use a variety of flags, including but not limited to -M.
269 dnl
270 dnl We test whether the flag in question is supported, as older
271 dnl versions of compilers might not support it.
272 dnl
273 dnl We don't try all the possible flags, just in case some flag means
274 dnl "generate dependencies" on one compiler but means something else
275 dnl on another compiler.
276 dnl
277 dnl Most compilers that support this send the output to the standard
278 dnl output by default. IBM's XLC, however, supports -M but sends
279 dnl the output to {sourcefile-basename}.u, and AIX has no /dev/stdout
280 dnl to work around that, so we don't bother with XLC.
281 dnl
282 AC_DEFUN(AC_LBL_CHECK_DEPENDENCY_GENERATION_OPT,
283 [
284 AC_MSG_CHECKING([whether the compiler supports generating dependencies])
285 if test "$GCC" = yes ; then
286 #
287 # GCC, or a compiler deemed to be GCC by AC_PROG_CC (even
288 # though it's not); we assume that, in this case, the flag
289 # would be -M.
290 #
291 ac_lbl_dependency_flag="-M"
292 else
293 #
294 # Not GCC or a compiler deemed to be GCC; what platform is
295 # this? (We're assuming that if the compiler isn't GCC
296 # it's the compiler from the vendor of the OS; that won't
297 # necessarily be true for x86 platforms, where it might be
298 # the Intel C compiler.)
299 #
300 case "$host_os" in
301
302 irix*|osf*|darwin*)
303 #
304 # MIPS C for IRIX, DEC C, and clang all use -M.
305 #
306 ac_lbl_dependency_flag="-M"
307 ;;
308
309 solaris*)
310 #
311 # Sun C uses -xM.
312 #
313 ac_lbl_dependency_flag="-xM"
314 ;;
315
316 hpux*)
317 #
318 # HP's older C compilers don't support this.
319 # HP's newer C compilers support this with
320 # either +M or +Make; the older compilers
321 # interpret +M as something completely
322 # different, so we use +Make so we don't
323 # think it works with the older compilers.
324 #
325 ac_lbl_dependency_flag="+Make"
326 ;;
327
328 *)
329 #
330 # Not one of the above; assume no support for
331 # generating dependencies.
332 #
333 ac_lbl_dependency_flag=""
334 ;;
335 esac
336 fi
337
338 #
339 # Is ac_lbl_dependency_flag defined and, if so, does the compiler
340 # complain about it?
341 #
342 # Note: clang doesn't seem to exit with an error status when handed
343 # an unknown non-warning error, even if you pass it
344 # -Werror=unknown-warning-option. However, it always supports
345 # -M, so the fact that this test always succeeds with clang
346 # isn't an issue.
347 #
348 if test ! -z "$ac_lbl_dependency_flag"; then
349 AC_LANG_CONFTEST(
350 [AC_LANG_SOURCE([[int main(void) { return 0; }]])])
351 if AC_RUN_LOG([eval "$CC $ac_lbl_dependency_flag conftest.c >/dev/null 2>&1"]); then
352 AC_MSG_RESULT([yes, with $ac_lbl_dependency_flag])
353 DEPENDENCY_CFLAG="$ac_lbl_dependency_flag"
354 MKDEP='${top_srcdir}/mkdep'
355 else
356 AC_MSG_RESULT([no])
357 #
358 # We can't run mkdep, so have "make depend" do
359 # nothing.
360 #
361 MKDEP=:
362 fi
363 rm -rf conftest*
364 else
365 AC_MSG_RESULT([no])
366 #
367 # We can't run mkdep, so have "make depend" do
368 # nothing.
369 #
370 MKDEP=:
371 fi
372 AC_SUBST(DEPENDENCY_CFLAG)
373 AC_SUBST(MKDEP)
374 ])
375
376 #
377 # Try compiling a sample of the type of code that appears in
378 # gencode.c with "inline", "__inline__", and "__inline".
379 #
380 # Autoconf's AC_C_INLINE, at least in autoconf 2.13, isn't good enough,
381 # as it just tests whether a function returning "int" can be inlined;
382 # at least some versions of HP's C compiler can inline that, but can't
383 # inline a function that returns a struct pointer.
384 #
385 # Make sure we use the V_CCOPT flags, because some of those might
386 # disable inlining.
387 #
388 AC_DEFUN(AC_LBL_C_INLINE,
389 [AC_MSG_CHECKING(for inline)
390 save_CFLAGS="$CFLAGS"
391 CFLAGS="$V_CCOPT"
392 AC_CACHE_VAL(ac_cv_lbl_inline, [
393 ac_cv_lbl_inline=""
394 ac_lbl_cc_inline=no
395 for ac_lbl_inline in inline __inline__ __inline
396 do
397 AC_TRY_COMPILE(
398 [#define inline $ac_lbl_inline
399 static inline struct iltest *foo(void);
400 struct iltest {
401 int iltest1;
402 int iltest2;
403 };
404
405 static inline struct iltest *
406 foo()
407 {
408 static struct iltest xxx;
409
410 return &xxx;
411 }],,ac_lbl_cc_inline=yes,)
412 if test "$ac_lbl_cc_inline" = yes ; then
413 break;
414 fi
415 done
416 if test "$ac_lbl_cc_inline" = yes ; then
417 ac_cv_lbl_inline=$ac_lbl_inline
418 fi])
419 CFLAGS="$save_CFLAGS"
420 if test ! -z "$ac_cv_lbl_inline" ; then
421 AC_MSG_RESULT($ac_cv_lbl_inline)
422 else
423 AC_MSG_RESULT(no)
424 fi
425 AC_DEFINE_UNQUOTED(inline, $ac_cv_lbl_inline, [Define as token for inline if inlining supported])])
426
427 dnl
428 dnl Use pfopen.c if available and pfopen() not in standard libraries
429 dnl Require libpcap
430 dnl Look for libpcap in directories under ..; those are local versions.
431 dnl Look for an installed libpcap if there is no local version or if
432 dnl the user said not to look for a local version.
433 dnl
434 dnl usage:
435 dnl
436 dnl AC_LBL_LIBPCAP(pcapdep, incls)
437 dnl
438 dnl results:
439 dnl
440 dnl $1 (pcapdep set)
441 dnl $2 (incls appended)
442 dnl LIBS
443 dnl LBL_LIBS
444 dnl
445 AC_DEFUN(AC_LBL_LIBPCAP,
446 [AC_REQUIRE([AC_LBL_LIBRARY_NET])
447 dnl
448 dnl save a copy before locating libpcap.a
449 dnl
450 LBL_LIBS="$LIBS"
451 pfopen=/usr/examples/packetfilter/pfopen.c
452 if test -f $pfopen ; then
453 AC_CHECK_FUNCS(pfopen)
454 if test $ac_cv_func_pfopen = "no" ; then
455 AC_MSG_RESULT(Using $pfopen)
456 LIBS="$LIBS $pfopen"
457 fi
458 fi
459 libpcap=FAIL
460 AC_MSG_CHECKING([whether to look for a local libpcap])
461 AC_ARG_ENABLE(local-libpcap,
462 AS_HELP_STRING([--disable-local-libpcap],
463 [don't look for a local libpcap @<:@default=check for a local libpcap@:>@]),,
464 enableval=yes)
465 case "$enableval" in
466
467 no)
468 AC_MSG_RESULT(no)
469 #
470 # Don't look for a local libpcap.
471 #
472 using_local_libpcap=no
473 ;;
474
475 *)
476 AC_MSG_RESULT(yes)
477 #
478 # Look for a local pcap library.
479 #
480 AC_MSG_CHECKING(for local pcap library)
481 lastdir=FAIL
482 places=`ls $srcdir/.. | sed -e 's,/$,,' -e "s,^,$srcdir/../," | \
483 egrep '/libpcap-[[0-9]]+\.[[0-9]]+(\.[[0-9]]*)?([[ab]][[0-9]]*|-PRE-GIT|rc.)?$'`
484 places2=`ls .. | sed -e 's,/$,,' -e "s,^,../," | \
485 egrep '/libpcap-[[0-9]]+\.[[0-9]]+(\.[[0-9]]*)?([[ab]][[0-9]]*|-PRE-GIT|rc.)?$'`
486 for dir in $places $srcdir/../libpcap ../libpcap $srcdir/libpcap $places2 ; do
487 basedir=`echo $dir | sed -e 's/[[ab]][[0-9]]*$//' | \
488 sed -e 's/-PRE-GIT$//' `
489 if test $lastdir = $basedir ; then
490 dnl skip alphas when an actual release is present
491 continue;
492 fi
493 lastdir=$dir
494 if test -r $dir/libpcap.a ; then
495 libpcap=$dir/libpcap.a
496 local_pcap_dir=$dir
497 dnl continue and select the last one that exists
498 fi
499 done
500 if test $libpcap = FAIL ; then
501 #
502 # We didn't find a local libpcap.
503 #
504 AC_MSG_RESULT(not found)
505 using_local_libpcap=no;
506 else
507 #
508 # We found a local libpcap.
509 #
510 AC_MSG_RESULT($libpcap)
511 using_local_libpcap=yes
512 fi
513 ;;
514 esac
515
516 if test $using_local_libpcap = no ; then
517 #
518 # We didn't find a local libpcap.
519 # Look for an installed pkg-config.
520 #
521 AC_PATH_TOOL(PKG_CONFIG, pkg-config)
522 if test -n "$PKG_CONFIG" ; then
523 #
524 # We have it. Are there .pc files for libpcap?
525 #
526 # --exists was introduced in pkg-config 0.4.0; that
527 # dates back to late 2000, so we won't worry about
528 # earlier releases that lack it.
529 #
530 AC_MSG_CHECKING(whether there are .pc files for libpcap)
531 if "$PKG_CONFIG" libpcap --exists ; then
532 #
533 # Yes, so we can use pkg-config to get configuration
534 # information for libpcap.
535 #
536 AC_MSG_RESULT(yes)
537 pkg_config_usable=yes
538 else
539 #
540 # No, so we can't use pkg-config to get configuration
541 # information for libpcap.
542 #
543 AC_MSG_RESULT(no)
544 pkg_config_usable=no
545 fi
546 else
547 #
548 # We don't have it, so we obviously can't use it.
549 #
550 pkg_config_usable=no
551 fi
552 if test "$pkg_config_usable" = "yes" ; then
553 #
554 # Found both - use pkg-config to get the include flags for
555 # libpcap and the flags to link with libpcap.
556 #
557 # Please read section 11.6 "Shell Substitutions"
558 # in the autoconf manual before doing anything
559 # to this that involves quoting. Especially note
560 # the statement "There is just no portable way to use
561 # double-quoted strings inside double-quoted back-quoted
562 # expressions (pfew!)."
563 #
564 cflags=`"$PKG_CONFIG" libpcap --cflags`
565 $2="$cflags $$2"
566 libpcap=`"$PKG_CONFIG" libpcap --libs`
567 else
568 #
569 # No pkg-config
570 # Look for an installed pcap-config.
571 #
572 AC_PATH_TOOL(PCAP_CONFIG, pcap-config)
573 if test -n "$PCAP_CONFIG" ; then
574 #
575 # Found - use it to get the include flags for
576 # libpcap and the flags to link with libpcap.
577 #
578 # If this is a vendor-supplied pcap-config, which
579 # we define as being "a pcap-config in /usr/bin
580 # or /usr/ccs/bin" (the latter is for Solaris and
581 # Sun/Oracle Studio), there are some issues. Work
582 # around them.
583 #
584 if test \( "$PCAP_CONFIG" = "/usr/bin/pcap-config" \) -o \
585 \( "$PCAP_CONFIG" = "/usr/ccs/bin/pcap-config" \) ; then
586 #
587 # It's vendor-supplied.
588 #
589 case "$host_os" in
590
591 darwin*)
592 #
593 # This is macOS or another Darwin-based OS.
594 #
595 # That means that /usr/bin/pcap-config it
596 # may provide -I/usr/local/include with --cflags
597 # and -L/usr/local/lib with --libs, rather than
598 # pointing to the OS-supplied library and
599 # Xcode-supplied headers. Remember that, so we
600 # ignore those values.
601 #
602 _broken_apple_pcap_config=yes
603 ;;
604
605 solaris*)
606 #
607 # This is Solaris 2 or later, i.e. SunOS 5.x.
608 #
609 # At least on Solaris 11; there's /usr/bin/pcap-config,
610 # which reports -L/usr/lib with --libs, causing
611 # the 32-bit libraries to be found, and there's
612 # /usr/bin/{64bitarch}/pcap-config, where {64bitarch}
613 # is a name for the 64-bit version of the instruction
614 # set, which reports -L /usr/lib/{64bitarch}, causing
615 # the 64-bit libraries to be found.
616 #
617 # So if we're building 64-bit targets, we replace
618 # PCAP_CONFIG with /usr/bin/{64bitarch}; we get
619 # {64bitarch} as the output of "isainfo -n".
620 #
621 # Are we building 32-bit or 64-bit? Get the
622 # size of void *, and check that.
623 #
624 AC_CHECK_SIZEOF([void *])
625 if test ac_cv_sizeof_void_p -eq 8 ; then
626 isainfo_output=`isainfo -n`
627 if test ! -z "$isainfo_output" ; then
628 #
629 # Success - change PCAP_CONFIG.
630 #
631 PCAP_CONFIG=`echo $PCAP_CONFIG | sed "s;/bin/;/bin/$isainfo_output/;"`
632 fi
633 fi
634 ;;
635 esac
636 fi
637 #
638 # Please read section 11.6 "Shell Substitutions"
639 # in the autoconf manual before doing anything
640 # to this that involves quoting. Especially note
641 # the statement "There is just no portable way to use
642 # double-quoted strings inside double-quoted back-quoted
643 # expressions (pfew!)."
644 #
645 cflags=`"$PCAP_CONFIG" --cflags`
646 #
647 # Work around macOS (and probably other Darwin) brokenness,
648 # by not adding /usr/local/include if it's from the broken
649 # Apple pcap-config.
650 #
651 if test "$_broken_apple_pcap_config" = "yes" ; then
652 #
653 # Strip -I/usr/local/include with sed.
654 #
655 cflags=`echo $cflags | sed 's;-I/usr/local/include;;'`
656 fi
657 $2="$cflags $$2"
658 libpcap=`"$PCAP_CONFIG" --libs`
659 #
660 # Work around macOS (and probably other Darwin) brokenness,
661 # by not adding /usr/local/lib if it's from the broken
662 # Apple pcap-config.
663 #
664 if test "$_broken_apple_pcap_config" = "yes" ; then
665 #
666 # Strip -L/usr/local/lib with sed.
667 #
668 libpcap=`echo $libpcap | sed 's;-L/usr/local/lib;;'`
669 fi
670 else
671 #
672 # Not found; look for an installed pcap.
673 #
674 AC_CHECK_LIB(pcap, main, libpcap="-lpcap")
675 if test $libpcap = FAIL ; then
676 AC_MSG_ERROR(see the INSTALL doc for more info)
677 fi
678 dnl
679 dnl Some versions of Red Hat Linux put "pcap.h" in
680 dnl "/usr/include/pcap"; had the LBL folks done so,
681 dnl that would have been a good idea, but for
682 dnl the Red Hat folks to do so just breaks source
683 dnl compatibility with other systems.
684 dnl
685 dnl We work around this by assuming that, as we didn't
686 dnl find a local libpcap, libpcap is in /usr/lib or
687 dnl /usr/local/lib and that the corresponding header
688 dnl file is under one of those directories; if we don't
689 dnl find it in either of those directories, we check to
690 dnl see if it's in a "pcap" subdirectory of them and,
691 dnl if so, add that subdirectory to the "-I" list.
692 dnl
693 dnl (We now also put pcap.h in /usr/include/pcap, but we
694 dnl leave behind a /usr/include/pcap.h that includes it,
695 dnl so you can still just include <pcap.h>.)
696 dnl
697 AC_MSG_CHECKING(for extraneous pcap header directories)
698 if test \( ! -r /usr/local/include/pcap.h \) -a \
699 \( ! -r /usr/include/pcap.h \); then
700 if test -r /usr/local/include/pcap/pcap.h; then
701 d="/usr/local/include/pcap"
702 elif test -r /usr/include/pcap/pcap.h; then
703 d="/usr/include/pcap"
704 fi
705 fi
706 if test -z "$d" ; then
707 AC_MSG_RESULT(not found)
708 else
709 $2="-I$d $$2"
710 AC_MSG_RESULT(found -- -I$d added)
711 fi
712 fi
713 fi
714 else
715 #
716 # We found a local libpcap. Add it to the dependencies for
717 # tcpdump.
718 #
719 $1=$libpcap
720
721 #
722 # Look for its pcap-config script.
723 #
724 AC_PATH_PROG(PCAP_CONFIG, pcap-config,, $local_pcap_dir)
725
726 if test -n "$PCAP_CONFIG"; then
727 #
728 # We don't want its --cflags or --libs output, because
729 # those presume it's installed. For the C compiler flags,
730 # we add the source directory for the local libpcap, so
731 # we pick up its header files.
732 #
733 # We do, however, want its additional libraries, as required
734 # when linking statically, because it makes calls to
735 # routines in those libraries, so we'll need to link with
736 # them, because we'll be linking statically with it.
737 #
738 $2="-I$local_pcap_dir $$2"
739 additional_libs=`"$PCAP_CONFIG" --static --additional-libs`
740 libpcap="$libpcap $additional_libs"
741 else
742 #
743 # It doesn't have a pcap-config script.
744 # Make sure it has a pcap.h file.
745 #
746 places=`ls $srcdir/.. | sed -e 's,/$,,' -e "s,^,$srcdir/../," | \
747 egrep '/libpcap-[[0-9]]*.[[0-9]]*(.[[0-9]]*)?([[ab]][[0-9]]*)?$'`
748 places2=`ls .. | sed -e 's,/$,,' -e "s,^,../," | \
749 egrep '/libpcap-[[0-9]]*.[[0-9]]*(.[[0-9]]*)?([[ab]][[0-9]]*)?$'`
750 pcapH=FAIL
751 if test -r $local_pcap_dir/pcap.h; then
752 pcapH=$local_pcap_dir
753 else
754 for dir in $places $srcdir/../libpcap ../libpcap $srcdir/libpcap $places2 ; do
755 if test -r $dir/pcap.h ; then
756 pcapH=$dir
757 fi
758 done
759 fi
760
761 if test $pcapH = FAIL ; then
762 AC_MSG_ERROR(cannot find pcap.h: see INSTALL)
763 fi
764
765 #
766 # Force the compiler to look for header files in the
767 # directory containing pcap.h.
768 #
769 $2="-I$pcapH $$2"
770 fi
771 fi
772
773 if test -z "$PKG_CONFIG" -a -z "$PCAP_CONFIG"; then
774 #
775 # We don't have pkg-config or pcap-config; find out any additional
776 # link flags we need. (If we have pkg-config or pcap-config, we
777 # assume it tells us what we need.)
778 #
779 case "$host_os" in
780
781 aix*)
782 #
783 # If libpcap is DLPI-based, we have to use /lib/pse.exp if
784 # present, as we use the STREAMS routines.
785 #
786 # (XXX - true only if we're linking with a static libpcap?)
787 #
788 pseexe="/lib/pse.exp"
789 AC_MSG_CHECKING(for $pseexe)
790 if test -f $pseexe ; then
791 AC_MSG_RESULT(yes)
792 LIBS="$LIBS -I:$pseexe"
793 fi
794
795 #
796 # If libpcap is BPF-based, we need "-lodm" and "-lcfg", as
797 # we use them to load the BPF module.
798 #
799 # (XXX - true only if we're linking with a static libpcap?)
800 #
801 LIBS="$LIBS -lodm -lcfg"
802 ;;
803
804 solaris*)
805 # libdlpi is needed for Solaris 11 and later.
806 AC_CHECK_LIB(dlpi, dlpi_walk, LIBS="$LIBS -ldlpi" LDFLAGS="-L/lib $LDFLAGS", ,-L/lib)
807 ;;
808 esac
809 fi
810
811 LIBS="$libpcap $LIBS"
812
813 dnl
814 dnl Check for "pcap_loop()", to make sure we found a working
815 dnl libpcap and have all the right other libraries with which
816 dnl to link. (Otherwise, the checks below will fail, not
817 dnl because the routines are missing from the library, but
818 dnl because we aren't linking properly with libpcap, and
819 dnl that will cause confusing errors at build time.)
820 dnl
821 AC_CHECK_FUNC(pcap_loop,,
822 [
823 AC_MSG_ERROR(
824 [This is a bug, please follow the guidelines in CONTRIBUTING and include the
825 config.log file in your report. If you have downloaded libpcap from
826 tcpdump.org, and built it yourself, please also include the config.log
827 file from the libpcap source directory, the Makefile from the libpcap
828 source directory, and the output of the make process for libpcap, as
829 this could be a problem with the libpcap that was built, and we will
830 not be able to determine why this is happening, and thus will not be
831 able to fix it, without that information, as we have not been able to
832 reproduce this problem ourselves.])
833 ])
834 ])
835
836 dnl
837 dnl If using gcc, make sure we have ANSI ioctl definitions
838 dnl
839 dnl usage:
840 dnl
841 dnl AC_LBL_FIXINCLUDES
842 dnl
843 AC_DEFUN(AC_LBL_FIXINCLUDES,
844 [if test "$GCC" = yes ; then
845 AC_MSG_CHECKING(for ANSI ioctl definitions)
846 AC_CACHE_VAL(ac_cv_lbl_gcc_fixincludes,
847 AC_TRY_COMPILE(
848 [/*
849 * This generates a "duplicate case value" when fixincludes
850 * has not be run.
851 */
852 # include <sys/types.h>
853 # include <sys/time.h>
854 # include <sys/ioctl.h>
855 # ifdef HAVE_SYS_IOCCOM_H
856 # include <sys/ioccom.h>
857 # endif],
858 [switch (0) {
859 case _IO('A', 1):;
860 case _IO('B', 1):;
861 }],
862 ac_cv_lbl_gcc_fixincludes=yes,
863 ac_cv_lbl_gcc_fixincludes=no))
864 AC_MSG_RESULT($ac_cv_lbl_gcc_fixincludes)
865 if test $ac_cv_lbl_gcc_fixincludes = no ; then
866 # Don't cache failure
867 unset ac_cv_lbl_gcc_fixincludes
868 AC_MSG_ERROR(see the INSTALL for more info)
869 fi
870 fi])
871
872 dnl
873 dnl Checks to see if union wait is used with WEXITSTATUS()
874 dnl
875 dnl usage:
876 dnl
877 dnl AC_LBL_UNION_WAIT
878 dnl
879 dnl results:
880 dnl
881 dnl DECLWAITSTATUS (defined)
882 dnl
883 AC_DEFUN(AC_LBL_UNION_WAIT,
884 [AC_MSG_CHECKING(if union wait is used)
885 AC_CACHE_VAL(ac_cv_lbl_union_wait,
886 AC_TRY_COMPILE([
887 # include <sys/types.h>
888 # include <sys/wait.h>],
889 [int status;
890 u_int i = WEXITSTATUS(status);
891 u_int j = waitpid(0, &status, 0);],
892 ac_cv_lbl_union_wait=no,
893 ac_cv_lbl_union_wait=yes))
894 AC_MSG_RESULT($ac_cv_lbl_union_wait)
895 if test $ac_cv_lbl_union_wait = yes ; then
896 AC_DEFINE(DECLWAITSTATUS,union wait,[type for wait])
897 else
898 AC_DEFINE(DECLWAITSTATUS,int,[type for wait])
899 fi])
900
901 dnl
902 dnl Checks to see if -R is used
903 dnl
904 dnl usage:
905 dnl
906 dnl AC_LBL_HAVE_RUN_PATH
907 dnl
908 dnl results:
909 dnl
910 dnl ac_cv_lbl_have_run_path (yes or no)
911 dnl
912 AC_DEFUN(AC_LBL_HAVE_RUN_PATH,
913 [AC_MSG_CHECKING(for ${CC-cc} -R)
914 AC_CACHE_VAL(ac_cv_lbl_have_run_path,
915 [echo 'main(){}' > conftest.c
916 ${CC-cc} -o conftest conftest.c -R/a1/b2/c3 >conftest.out 2>&1
917 if test ! -s conftest.out ; then
918 ac_cv_lbl_have_run_path=yes
919 else
920 ac_cv_lbl_have_run_path=no
921 fi
922 rm -f -r conftest*])
923 AC_MSG_RESULT($ac_cv_lbl_have_run_path)
924 ])
925
926 dnl
927 dnl Check whether a given format can be used to print 64-bit integers
928 dnl
929 AC_DEFUN(AC_LBL_CHECK_64BIT_FORMAT,
930 [
931 AC_MSG_CHECKING([whether %$1x can be used to format 64-bit integers])
932 AC_RUN_IFELSE(
933 [
934 AC_LANG_SOURCE(
935 [[
936 # ifdef HAVE_INTTYPES_H
937 #include <inttypes.h>
938 # endif
939 #include <stdio.h>
940 #include <sys/types.h>
941
942 main()
943 {
944 uint64_t t = 1;
945 char strbuf[16+1];
946 sprintf(strbuf, "%016$1x", t << 32);
947 if (strcmp(strbuf, "0000000100000000") == 0)
948 exit(0);
949 else
950 exit(1);
951 }
952 ]])
953 ],
954 [
955 AC_DEFINE(PRId64, "$1d", [define if the platform doesn't define PRId64])
956 AC_DEFINE(PRIo64, "$1o", [define if the platform doesn't define PRIo64])
957 AC_DEFINE(PRIx64, "$1x", [define if the platform doesn't define PRIu64])
958 AC_DEFINE(PRIu64, "$1u", [define if the platform doesn't define PRIx64])
959 AC_MSG_RESULT(yes)
960 ],
961 [
962 AC_MSG_RESULT(no)
963 $2
964 ])
965 ])
966
967 dnl
968 dnl If the file .devel exists:
969 dnl Add some warning flags if the compiler supports them
970 dnl If an os prototype include exists, symlink os-proto.h to it
971 dnl
972 dnl usage:
973 dnl
974 dnl AC_LBL_DEVEL(copt)
975 dnl
976 dnl results:
977 dnl
978 dnl $1 (copt appended)
979 dnl HAVE_OS_PROTO_H (defined)
980 dnl os-proto.h (symlinked)
981 dnl
982 AC_DEFUN(AC_LBL_DEVEL,
983 [rm -f os-proto.h
984 if test "${LBL_CFLAGS+set}" = set; then
985 $1="$$1 ${LBL_CFLAGS}"
986 fi
987 if test -f .devel ; then
988 #
989 # Skip all the warning option stuff on some compilers.
990 #
991 if test "$ac_lbl_cc_dont_try_gcc_dashW" != yes; then
992 AC_LBL_CHECK_COMPILER_OPT($1, -W)
993 AC_LBL_CHECK_COMPILER_OPT($1, -Wall)
994 AC_LBL_CHECK_COMPILER_OPT($1, -Wassign-enum)
995 AC_LBL_CHECK_COMPILER_OPT($1, -Wcast-qual)
996 AC_LBL_CHECK_COMPILER_OPT($1, -Wmissing-prototypes)
997 AC_LBL_CHECK_COMPILER_OPT($1, -Wmissing-variable-declarations)
998 AC_LBL_CHECK_COMPILER_OPT($1, -Wold-style-definition)
999 AC_LBL_CHECK_COMPILER_OPT($1, -Wpedantic)
1000 AC_LBL_CHECK_COMPILER_OPT($1, -Wpointer-arith)
1001 AC_LBL_CHECK_COMPILER_OPT($1, -Wpointer-sign)
1002 AC_LBL_CHECK_COMPILER_OPT($1, -Wshadow)
1003 AC_LBL_CHECK_COMPILER_OPT($1, -Wsign-compare)
1004 AC_LBL_CHECK_COMPILER_OPT($1, -Wstrict-prototypes)
1005 AC_LBL_CHECK_COMPILER_OPT($1, -Wunreachable-code-return)
1006 AC_LBL_CHECK_COMPILER_OPT($1, -Wused-but-marked-unused)
1007 AC_LBL_CHECK_COMPILER_OPT($1, -Wwrite-strings)
1008 fi
1009 AC_LBL_CHECK_DEPENDENCY_GENERATION_OPT()
1010 #
1011 # We used to set -n32 for IRIX 6 when not using GCC (presumed
1012 # to mean that we're using MIPS C or MIPSpro C); it specified
1013 # the "new" faster 32-bit ABI, introduced in IRIX 6.2. I'm
1014 # not sure why that would be something to do *only* with a
1015 # .devel file; why should the ABI for which we produce code
1016 # depend on .devel?
1017 #
1018 os=`echo $host_os | sed -e 's/\([[0-9]][[0-9]]*\)[[^0-9]].*$/\1/'`
1019 name="lbl/os-$os.h"
1020 if test -f $name ; then
1021 ln -s $name os-proto.h
1022 AC_DEFINE(HAVE_OS_PROTO_H, 1,
1023 [if there's an os_proto.h for this platform, to use additional prototypes])
1024 else
1025 AC_MSG_WARN(can't find $name)
1026 fi
1027 fi])
1028
1029 dnl
1030 dnl Improved version of AC_CHECK_LIB
1031 dnl
1032 dnl Thanks to John Hawkinson (jhawk@mit.edu)
1033 dnl
1034 dnl usage:
1035 dnl
1036 dnl AC_LBL_CHECK_LIB(LIBRARY, FUNCTION [, ACTION-IF-FOUND [,
1037 dnl ACTION-IF-NOT-FOUND [, OTHER-LIBRARIES]]])
1038 dnl
1039 dnl results:
1040 dnl
1041 dnl LIBS
1042 dnl
1043 dnl XXX - "AC_LBL_LIBRARY_NET" was redone to use "AC_SEARCH_LIBS"
1044 dnl rather than "AC_LBL_CHECK_LIB", so this isn't used any more.
1045 dnl We keep it around for reference purposes in case it's ever
1046 dnl useful in the future.
1047 dnl
1048
1049 define(AC_LBL_CHECK_LIB,
1050 [AC_MSG_CHECKING([for $2 in -l$1])
1051 dnl Use a cache variable name containing the library, function
1052 dnl name, and extra libraries to link with, because the test really is
1053 dnl for library $1 defining function $2, when linked with potinal
1054 dnl library $5, not just for library $1. Separate tests with the same
1055 dnl $1 and different $2's or $5's may have different results.
1056 ac_lib_var=`echo $1['_']$2['_']$5 | sed 'y%./+- %__p__%'`
1057 AC_CACHE_VAL(ac_cv_lbl_lib_$ac_lib_var,
1058 [ac_save_LIBS="$LIBS"
1059 LIBS="-l$1 $5 $LIBS"
1060 AC_TRY_LINK(dnl
1061 ifelse([$2], [main], , dnl Avoid conflicting decl of main.
1062 [/* Override any gcc2 internal prototype to avoid an error. */
1063 ]ifelse(AC_LANG, CPLUSPLUS, [#ifdef __cplusplus
1064 extern "C"
1065 #endif
1066 ])dnl
1067 [/* We use char because int might match the return type of a gcc2
1068 builtin and then its argument prototype would still apply. */
1069 char $2();
1070 ]),
1071 [$2()],
1072 eval "ac_cv_lbl_lib_$ac_lib_var=yes",
1073 eval "ac_cv_lbl_lib_$ac_lib_var=no")
1074 LIBS="$ac_save_LIBS"
1075 ])dnl
1076 if eval "test \"`echo '$ac_cv_lbl_lib_'$ac_lib_var`\" = yes"; then
1077 AC_MSG_RESULT(yes)
1078 ifelse([$3], ,
1079 [changequote(, )dnl
1080 ac_tr_lib=HAVE_LIB`echo $1 | sed -e 's/[^a-zA-Z0-9_]/_/g' \
1081 -e 'y/abcdefghijklmnopqrstuvwxyz/ABCDEFGHIJKLMNOPQRSTUVWXYZ/'`
1082 changequote([, ])dnl
1083 AC_DEFINE_UNQUOTED($ac_tr_lib)
1084 LIBS="-l$1 $LIBS"
1085 ], [$3])
1086 else
1087 AC_MSG_RESULT(no)
1088 ifelse([$4], , , [$4
1089 ])dnl
1090 fi
1091 ])
1092
1093 dnl
1094 dnl AC_LBL_LIBRARY_NET
1095 dnl
1096 dnl This test is for network applications that need socket() and
1097 dnl gethostbyname() -ish functions. Under Solaris, those applications
1098 dnl need to link with "-lsocket -lnsl". Under IRIX, they need to link
1099 dnl with "-lnsl" but should *not* link with "-lsocket" because
1100 dnl libsocket.a breaks a number of things (for instance:
1101 dnl gethostbyname() under IRIX 5.2, and snoop sockets under most
1102 dnl versions of IRIX).
1103 dnl
1104 dnl Unfortunately, many application developers are not aware of this,
1105 dnl and mistakenly write tests that cause -lsocket to be used under
1106 dnl IRIX. It is also easy to write tests that cause -lnsl to be used
1107 dnl under operating systems where neither are necessary (or useful),
1108 dnl such as SunOS 4.1.4, which uses -lnsl for TLI.
1109 dnl
1110 dnl This test exists so that every application developer does not test
1111 dnl this in a different, and subtly broken fashion.
1112
1113 dnl It has been argued that this test should be broken up into two
1114 dnl separate tests, one for the resolver libraries, and one for the
1115 dnl libraries necessary for using Sockets API. Unfortunately, the two
1116 dnl are carefully intertwined and allowing the autoconf user to use
1117 dnl them independently potentially results in unfortunate ordering
1118 dnl dependencies -- as such, such component macros would have to
1119 dnl carefully use indirection and be aware if the other components were
1120 dnl executed. Since other autoconf macros do not go to this trouble,
1121 dnl and almost no applications use sockets without the resolver, this
1122 dnl complexity has not been implemented.
1123 dnl
1124 dnl The check for libresolv is in case you are attempting to link
1125 dnl statically and happen to have a libresolv.a lying around (and no
1126 dnl libnsl.a).
1127 dnl
1128 AC_DEFUN(AC_LBL_LIBRARY_NET, [
1129 # Most operating systems have gethostbyname() in the default searched
1130 # libraries (i.e. libc):
1131 # Some OSes (eg. Solaris) place it in libnsl
1132 # Some strange OSes (SINIX) have it in libsocket:
1133 AC_SEARCH_LIBS(gethostbyname, nsl socket resolv)
1134 # Unfortunately libsocket sometimes depends on libnsl and
1135 # AC_SEARCH_LIBS isn't up to the task of handling dependencies like this.
1136 if test "$ac_cv_search_gethostbyname" = "no"
1137 then
1138 AC_CHECK_LIB(socket, gethostbyname,
1139 LIBS="-lsocket -lnsl $LIBS", , -lnsl)
1140 fi
1141 AC_SEARCH_LIBS(socket, socket, ,
1142 AC_CHECK_LIB(socket, socket, LIBS="-lsocket -lnsl $LIBS", , -lnsl))
1143 # DLPI needs putmsg under HPUX so test for -lstr while we're at it
1144 AC_SEARCH_LIBS(putmsg, str)
1145 ])
1146
1147 dnl Copyright (c) 1999 WIDE Project. All rights reserved.
1148 dnl
1149 dnl Redistribution and use in source and binary forms, with or without
1150 dnl modification, are permitted provided that the following conditions
1151 dnl are met:
1152 dnl 1. Redistributions of source code must retain the above copyright
1153 dnl notice, this list of conditions and the following disclaimer.
1154 dnl 2. Redistributions in binary form must reproduce the above copyright
1155 dnl notice, this list of conditions and the following disclaimer in the
1156 dnl documentation and/or other materials provided with the distribution.
1157 dnl 3. Neither the name of the project nor the names of its contributors
1158 dnl may be used to endorse or promote products derived from this software
1159 dnl without specific prior written permission.
1160 dnl
1161 dnl THIS SOFTWARE IS PROVIDED BY THE PROJECT AND CONTRIBUTORS ``AS IS'' AND
1162 dnl ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
1163 dnl IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
1164 dnl ARE DISCLAIMED. IN NO EVENT SHALL THE PROJECT OR CONTRIBUTORS BE LIABLE
1165 dnl FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
1166 dnl DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
1167 dnl OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
1168 dnl HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
1169 dnl LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
1170 dnl OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
1171 dnl SUCH DAMAGE.
1172
1173 AC_DEFUN(AC_LBL_SSLEAY,
1174 [
1175 #
1176 # Find the last component of $libdir; it's not necessarily
1177 # "lib" - it might be "lib64" on, for example, x86-64
1178 # Linux systems.
1179 #
1180 # We assume the directory in which we're looking for
1181 # libcrypto has a subdirectory with that as its name.
1182 #
1183 tmplib=`echo "$libdir" | sed 's,.*/,,'`
1184
1185 #
1186 # XXX - is there a better way to check if a given library is
1187 # in a given directory than checking each of the possible
1188 # shared library suffixes?
1189 #
1190 # Are there any other suffixes we need to look for? Do we
1191 # have to worry about ".so.{version}"?
1192 #
1193 # Or should we just look for "libcrypto.*"?
1194 #
1195 if test -d "$1/$tmplib" -a \( -f "$1/$tmplib/libcrypto.a" -o \
1196 -f "$1/$tmplib/libcrypto.so" -o \
1197 -f "$1/$tmplib/libcrypto.sl" -o \
1198 -f "$1/$tmplib/libcrypto.dylib" \); then
1199 ac_cv_ssleay_path="$1"
1200 fi
1201
1202 #
1203 # Make sure we have the headers as well.
1204 #
1205 if test -d "$1/include/openssl" -a -f "$1/include/openssl/des.h"; then
1206 incdir="-I$1/include"
1207 fi
1208 ])
[mirror] the TCPdump network dissector