The Tcpdump Group git mirrors - tcpdump/blob - CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.6)
   2
   3 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/Modules)
   4
   5 project(tcpdump)
   6
   7 #
   8 # Try to enable as many C99 features as we can.
   9 # At minimum, we want C++/C99-style // comments.
  10 #
  11 # Newer versions of compilers might default to supporting C99, but older
  12 # versions may require a special flag.
  13 #
  14 # Prior to CMake 3.1, setting CMAKE_C_STANDARD will not have any effect,
  15 # so, unless and until we require CMake 3.1 or later, we have to do it
  16 # ourselves on pre-3.1 CMake, so we just do it ourselves on all versions
  17 # of CMake.
  18 #
  19 # Note: with CMake 3.1 through 3.5, the only compilers for which CMake
  20 # handles CMAKE_C_STANDARD are GCC and Clang.  3.6 adds support only
  21 # for Intel C; 3.9 adds support for PGI C, Sun C, and IBM XL C, and
  22 # 3.10 adds support for Cray C and IAR C, but no version of CMake has
  23 # support for HP C.  Therefore, even if we use CMAKE_C_STANDARD with
  24 # compilers for which CMake supports it, we may still have to do it
  25 # ourselves on other compilers.
  26 #
  27 # See the CMake documentation for the CMAKE_<LANG>_COMPILER_ID variables
  28 # for a list of compiler IDs.
  29 #
  30 # We don't worry about MSVC; it doesn't have such a flag - either it
  31 # doesn't support the C99 features we need at all, or it supports them
  32 # regardless of the compiler flag.
  33 #
  34 # XXX - this just tests whether the option works and adds it if it does.
  35 # We don't test whether it's necessary in order to get the C99 features
  36 # that we use; if we ever have a user who tries to compile with a compiler
  37 # that can't be made to support those features, we can add a test to make
  38 # sure we actually *have* C99 support.
  39 #
  40 include(CheckCCompilerFlag)
  41 macro(check_and_add_compiler_option _option)
  42     message(STATUS "Checking C compiler flag ${_option}")
  43     string(REPLACE "=" "-" _temp_option_variable ${_option})
  44     string(REGEX REPLACE "^-" "" _option_variable ${_temp_option_variable})
  45     check_c_compiler_flag("${_option}" ${_option_variable})
  46     if(${${_option_variable}})
  47         set(C_ADDITIONAL_FLAGS "${C_ADDITIONAL_FLAGS} ${_option}")
  48     endif()
  49 endmacro()
  50
  51 set(C_ADDITIONAL_FLAGS "")
  52 if(CMAKE_C_COMPILER_ID MATCHES "GNU" OR
  53    CMAKE_C_COMPILER_ID MATCHES "Clang")
  54     check_and_add_compiler_option("-std=gnu99")
  55 elseif(CMAKE_C_COMPILER_ID MATCHES "XL")
  56     #
  57     # We want support for extensions picked up for GNU C compatibility,
  58     # so we use -qlanglvl=extc99.
  59     #
  60     check_and_add_compiler_option("-qlanglvl=extc99")
  61 elseif(CMAKE_C_COMPILER_ID MATCHES "HP")
  62     check_and_add_compiler_option("-AC99")
  63 elseif(CMAKE_C_COMPILER_ID MATCHES "Sun")
  64     check_and_add_compiler_option("-xc99")
  65 elseif(CMAKE_C_COMPILER_ID MATCHES "Intel")
  66     check_and_add_compiler_option("-c99")
  67 endif()
  68
  69 set(LIBRARY_NAME netdissect)
  70
  71 ###################################################################
  72 #   Parameters
  73 ###################################################################
  74
  75 option(WITH_SMI "Build with libsmi, if available" ON)
  76 option(WITH_CRYPTO "Build with OpenSSL/libressl libcrypto, if available" ON)
  77 option(WITH_CAPSICUM "Build with Capsicum security functions, if available" ON)
  78 option(WITH_CAP_NG "Use libcap-ng, if available" ON)
  79 option(ENABLE_SMB "Build with the SMB dissector" ON)
  80
  81 #
  82 # String parameters.  Neither of them are set, initially; only if the
  83 # user explicitly configures them are they set.
  84 #
  85 # WITH_CHROOT is STRING, not PATH, as the directory need not exist
  86 # when CMake is run.
  87 #
  88 set(WITH_CHROOT CACHE STRING
  89     "Directory to which to chroot when dropping privileges")
  90 set(WITH_USER CACHE STRING
  91     "User to whom to set the UID when dropping privileges")
  92
  93 #
  94 # By default, build universal with the appropriate set of architectures
  95 # for the OS on which we're doing the build.
  96 #
  97 if(APPLE AND "${CMAKE_OSX_ARCHITECTURES}" STREQUAL "")
  98     #
  99     # Get the major version of Darwin.
 100     #
 101     string(REGEX MATCH "^([0-9]+)" SYSTEM_VERSION_MAJOR "${CMAKE_SYSTEM_VERSION}")
 102
 103     if(SYSTEM_VERSION_MAJOR EQUAL 9)
 104         #
 105         # Leopard.  Build for x86 and 32-bit PowerPC, with
 106         # x86 first.  (That's what Apple does.)
 107         #
 108         set(CMAKE_OSX_ARCHITECTURES "i386;ppc")
 109     elseif(SYSTEM_VERSION_MAJOR EQUAL 10)
 110         #
 111         # Snow Leopard.  Build for x86-64 and x86, with
 112         # x86-64 first.  (That's what Apple does.)
 113         #
 114         set(CMAKE_OSX_ARCHITECTURES "x86_64;i386")
 115     endif()
 116 endif()
 117
 118 ###################################################################
 119 #   Versioning
 120 ###################################################################
 121
 122 # Get, parse, format and set tcpdump's version string from
 123 # [tcpdump_root]/VERSION for later use.
 124
 125 # Get MAJOR, MINOR, PATCH & SUFFIX
 126 file(STRINGS ${tcpdump_SOURCE_DIR}/VERSION
 127     PACKAGE_VERSION
 128     LIMIT_COUNT 1 # Read only the first line
 129 )
 130
 131 ######################################
 132 # Project settings
 133 ######################################
 134
 135 add_definitions(-DHAVE_CONFIG_H)
 136
 137 include_directories(
 138     ${CMAKE_CURRENT_BINARY_DIR}
 139     ${tcpdump_SOURCE_DIR}
 140 )
 141
 142 if(MSVC)
 143     add_definitions(-D__STDC__)
 144     add_definitions(-D_CRT_SECURE_NO_WARNINGS)
 145 endif(MSVC)
 146
 147 if(MSVC)
 148     if (USE_STATIC_RT)
 149         MESSAGE(STATUS "Use STATIC runtime")
 150         set(NAME_RT MT)
 151         set (CMAKE_CXX_FLAGS_MINSIZEREL     "${CMAKE_CXX_FLAGS_MINSIZEREL} /MT")
 152         set (CMAKE_CXX_FLAGS_RELWITHDEBINFO "${CMAKE_CXX_FLAGS_RELWITHDEBINFO} /MT")
 153         set (CMAKE_CXX_FLAGS_RELEASE        "${CMAKE_CXX_FLAGS_RELEASE} /MT")
 154         set (CMAKE_CXX_FLAGS_DEBUG          "${CMAKE_CXX_FLAGS_DEBUG} /MTd")
 155
 156         set (CMAKE_C_FLAGS_MINSIZEREL       "${CMAKE_C_FLAGS_MINSIZEREL} /MT")
 157         set (CMAKE_C_FLAGS_RELWITHDEBINFO   "${CMAKE_C_FLAGS_RELWITHDEBINFO} /MT")
 158         set (CMAKE_C_FLAGS_RELEASE          "${CMAKE_C_FLAGS_RELEASE} /MT")
 159         set (CMAKE_C_FLAGS_DEBUG            "${CMAKE_C_FLAGS_DEBUG} /MTd")
 160     else (USE_STATIC_RT)
 161         MESSAGE(STATUS "Use DYNAMIC runtime")
 162         set(NAME_RT MD)
 163         set (CMAKE_CXX_FLAGS_MINSIZEREL     "${CMAKE_CXX_FLAGS_MINSIZEREL} /MD")
 164         set (CMAKE_CXX_FLAGS_RELWITHDEBINFO "${CMAKE_CXX_FLAGS_RELWITHDEBINFO} /MD")
 165         set (CMAKE_CXX_FLAGS_RELEASE        "${CMAKE_CXX_FLAGS_RELEASE} /MD")
 166         set (CMAKE_CXX_FLAGS_DEBUG          "${CMAKE_CXX_FLAGS_DEBUG} /MDd")
 167
 168         set (CMAKE_C_FLAGS_MINSIZEREL       "${CMAKE_C_FLAGS_MINSIZEREL} /MD")
 169         set (CMAKE_C_FLAGS_RELWITHDEBINFO   "${CMAKE_C_FLAGS_RELWITHDEBINFO} /MD")
 170         set (CMAKE_C_FLAGS_RELEASE          "${CMAKE_C_FLAGS_RELEASE} /MD")
 171         set (CMAKE_C_FLAGS_DEBUG            "${CMAKE_C_FLAGS_DEBUG} /MDd")
 172    endif (USE_STATIC_RT)
 173 endif(MSVC)
 174
 175 ###################################################################
 176 #   Detect available platform features
 177 ###################################################################
 178
 179 include(CMakePushCheckState)
 180 include(CheckIncludeFile)
 181 include(CheckIncludeFiles)
 182 include(CheckFunctionExists)
 183 include(CheckLibraryExists)
 184 include(CheckSymbolExists)
 185 include(CheckStructHasMember)
 186 include(CheckVariableExists)
 187 include(CheckTypeSize)
 188
 189 #
 190 # Header files.
 191 #
 192 check_include_file(fcntl.h HAVE_FCNTL_H)
 193 check_include_file(rpc/rpc.h HAVE_RPC_RPC_H)
 194 if(HAVE_RPC_RPC_H)
 195     check_include_files("rpc/rpc.h;rpc/rpcent.h" HAVE_RPC_RPCENT_H)
 196 endif(HAVE_RPC_RPC_H)
 197 if(NOT WIN32)
 198     check_include_files("sys/types.h;sys/socket.h;net/if.h;net/pfvar.h" HAVE_NET_PFVAR_H)
 199     if(HAVE_NET_PFVAR_H)
 200         check_include_files("sys/types.h;sys/socket.h;net/if.h;net/pfvar.h;net/if_pflog.h" HAVE_NET_IF_PFLOG_H)
 201         if(HAVE_NET_IF_PFLOG_H)
 202             set(LOCALSRC print-pflog.c ${LOCALSRC})
 203         endif(HAVE_NET_IF_PFLOG_H)
 204     endif(HAVE_NET_PFVAR_H)
 205 endif(NOT WIN32)
 206
 207 #
 208 # Functions.
 209 #
 210 check_function_exists(strlcat HAVE_STRLCAT)
 211 check_function_exists(strlcpy HAVE_STRLCPY)
 212 check_function_exists(strdup HAVE_STRDUP)
 213 check_function_exists(strsep HAVE_STRSEP)
 214
 215 #
 216 # Find library needed for gethostbyaddr.
 217 # NOTE: if you hand check_library_exists as its last argument a variable
 218 # that's been set, it skips the test, so we need different variables.
 219 #
 220 set(TCPDUMP_LINK_LIBRARIES "")
 221 if(WIN32)
 222     #
 223     # We need winsock2.h and ws2tcpip.h.
 224     #
 225     cmake_push_check_state()
 226     set(CMAKE_REQUIRED_LIBRARIES ws2_32)
 227     check_symbol_exists(gethostbyaddr "winsock2.h;ws2tcpip.h" LIBWS2_32_HAS_GETHOSTBYADDR)
 228     cmake_pop_check_state()
 229     if(LIBWS2_32_HAS_GETHOSTBYADDR)
 230         set(TCPDUMP_LINK_LIBRARIES ws2_32 ${TCPDUMP_LINK_LIBRARIES})
 231     else(LIBWS2_32_HAS_GETHOSTBYADDR)
 232         message(FATAL_ERROR "gethostbyaddr is required, but wasn't found")
 233     endif(LIBWS2_32_HAS_GETHOSTBYADDR)
 234 else(WIN32)
 235     check_function_exists(gethostbyaddr STDLIBS_HAVE_GETHOSTBYADDR)
 236     if(NOT STDLIBS_HAVE_GETHOSTBYADDR)
 237         check_library_exists(socket gethostbyaddr "" LIBSOCKET_HAS_GETHOSTBYADDR)
 238         if(LIBSOCKET_HAS_GETHOSTBYADDR)
 239             set(TCPDUMP_LINK_LIBRARIES ${TCPDUMP_LINK_LIBRARIES} socket)
 240         else(LIBSOCKET_HAS_GETHOSTBYADDR)
 241             check_library_exists(nsl gethostbyaddr "" LIBNSL_HAS_GETHOSTBYADDR)
 242             if(LIBNSL_HAS_GETHOSTBYADDR)
 243                 set(TCPDUMP_LINK_LIBRARIES ${TCPDUMP_LINK_LIBRARIES} nsl)
 244             else(LIBNSL_HAS_GETHOSTBYADDR)
 245                 message(FATAL_ERROR "gethostbyaddr is required, but wasn't found")
 246             endif(LIBNSL_HAS_GETHOSTBYADDR)
 247         endif(LIBSOCKET_HAS_GETHOSTBYADDR)
 248     endif(NOT STDLIBS_HAVE_GETHOSTBYADDR)
 249 endif(WIN32)
 250
 251 #
 252 # This may require additional libraries.
 253 #
 254 cmake_push_check_state()
 255 set(CMAKE_REQUIRED_LIBRARIES ${TCPDUMP_LINK_LIBRARIES})
 256 check_function_exists(getservent STDLIBS_HAVE_GETSERVENT)
 257 if(STDLIBS_HAVE_GETSERVENT)
 258     set(HAVE_GETSERVENT TRUE)
 259 else(STDLIBS_HAVE_GETSERVENT)
 260     #
 261     # Some platforms may need -lsocket for getservent.
 262     #
 263     set(CMAKE_REQUIRED_LIBRARIES socket ${TCPDUMP_LINK_LIBRARIES})
 264     check_function_exists(getservent LIBSOCKET_HAS_GETSERVENT)
 265     if(LIBSOCKET_HAS_GETSERVENT)
 266         set(HAVE_GETSERVENT TRUE)
 267         set(TCPDUMP_LINK_LIBRARIES socket ${TCPDUMP_LINK_LIBRARIES})
 268     endif(LIBSOCKET_HAS_GETSERVENT)
 269 endif(STDLIBS_HAVE_GETSERVENT)
 270 cmake_pop_check_state()
 271
 272 check_function_exists(getopt_long HAVE_GETOPT_LONG)
 273 #
 274 # For Windows, either
 275 #
 276 #   1) we're using VS 2015, in which case we have both snprintf()
 277 #      and vsnprintf(), and they behave in a C99-compliant fashion,
 278 #      so we use them
 279 #
 280 # or
 281 #
 282 #   2) we're not, and we don't have snprintf(), and we either don't
 283 #      have vsnprintf() or we have one that *doesn't* behave in a
 284 #      C99-compliant fashion, but we *do* have _snprintf_s() and
 285 #      _vsnprintf_s(), so we wrap them with #defines
 286 #
 287 # and we test for both of them at compile time, so we don't need to
 288 # check for snprintf() or vsnprintf() here.
 289 #
 290 # XXX - do we need to care about UN*Xes that don't have snprintf()
 291 # or vsnprintf() any more?
 292 #
 293 # We also don't need to waste time checking for fork() or vfork().
 294 #
 295 if(NOT WIN32)
 296   check_function_exists(vsnprintf HAVE_VSNPRINTF)
 297   check_function_exists(snprintf HAVE_SNPRINTF)
 298   check_function_exists(fork HAVE_FORK)
 299   check_function_exists(vfork HAVE_VFORK)
 300 endif(NOT WIN32)
 301 check_function_exists(strftime HAVE_STRFTIME)
 302 check_function_exists(setlinebuf HAVE_SETLINEBUF)
 303
 304 #
 305 # Some platforms may need -lnsl for getrpcbynumber.
 306 #
 307 cmake_push_check_state()
 308 set(CMAKE_REQUIRED_LIBRARIES ${TCPDUMP_LINK_LIBRARIES})
 309 check_function_exists(getrpcbynumber STDLIBS_HAVE_GETRPCBYNUMBER)
 310 if(STDLIBS_HAVE_GETRPCBYNUMBER)
 311     set(HAVE_GETRPCBYNUMBER TRUE)
 312 else(STDLIBS_HAVE_GETRPCBYNUMBER)
 313     set(CMAKE_REQUIRED_LIBRARIES ${TCPDUMP_LINK_LIBRARIES} nsl)
 314     check_function_exists(getrpcbynumber LIBNSL_HAS_GETRPCBYNUMBER)
 315     if(LIBNSL_HAS_GETRPCBYNUMBER)
 316         set(HAVE_GETRPCBYNUMBER TRUE)
 317         set(TCPDUMP_LINK_LIBRARIES ${TCPDUMP_LINK_LIBRARIES} nsl)
 318     endif(LIBNSL_HAS_GETRPCBYNUMBER)
 319 endif(STDLIBS_HAVE_GETRPCBYNUMBER)
 320 cmake_pop_check_state()
 321
 322 #
 323 # This requires the libraries we require, as ether_ntohost might be
 324 # in one of those libraries.  That means we have to do this after
 325 # we check for those libraries.
 326 #
 327 # You are in a twisty little maze of UN*Xes, all different.
 328 # Some might not have ether_ntohost().
 329 # Some might have it and declare it in <net/ethernet.h>.
 330 # Some might have it and declare it in <netinet/ether.h>
 331 # Some might have it and declare it in <sys/ethernet.h>.
 332 # Some might have it and declare it in <arpa/inet.h>.
 333 # Some might have it and declare it in <netinet/if_ether.h>.
 334 # Some might have it and not declare it in any header file.
 335 #
 336 # Before you is a C compiler.
 337 #
 338 cmake_push_check_state()
 339 set(CMAKE_REQUIRED_LIBRARIES ${TCPDUMP_LINK_LIBRARIES})
 340 check_function_exists(ether_ntohost HAVE_ETHER_NTOHOST)
 341 if(HAVE_ETHER_NTOHOST)
 342     #
 343     # OK, we have ether_ntohost().  We don't check whether it's buggy,
 344     # as we assume any system that has CMake is likely to be new enough
 345     # that, if it has ether_ntohost(), whatever bug is checked for in
 346     # autotools is fixed; we just decide to use it.
 347     #
 348     set(USE_ETHER_NTOHOST TRUE)
 349
 350     #
 351     # Is it declared in <net/ethernet.h>?
 352     #
 353     # This test fails if we don't have <net/ethernet.h> or if we do
 354     # but it doesn't declare ether_ntohost().
 355     #
 356     check_symbol_exists(ether_ntohost net/ethernet.h NET_ETHERNET_H_DECLARES_ETHER_NTOHOST)
 357     if(NET_ETHERNET_H_DECLARES_ETHER_NTOHOST)
 358         #
 359         # Yes - we have it declared.
 360         #
 361         set(HAVE_DECL_ETHER_NTOHOST TRUE)
 362     endif()
 363     #
 364     # Did that succeed?
 365     #
 366     if(NOT HAVE_DECL_ETHER_NTOHOST)
 367         #
 368         # No - how about <netinet/ether.h>, as on Linux?
 369         #
 370         # This test fails if we don't have <netinet/ether.h>
 371         # or if we do but it doesn't declare ether_ntohost().
 372         #
 373         check_symbol_exists(ether_ntohost netinet/ether.h NETINET_ETHER_H_DECLARES_ETHER_NTOHOST)
 374         if(NETINET_ETHER_H_DECLARES_ETHER_NTOHOST)
 375             #
 376             # Yes - we have it declared.
 377             #
 378             set(HAVE_DECL_ETHER_NTOHOST TRUE)
 379         endif()
 380     endif()
 381     #
 382     # Did that succeed?
 383     #
 384     if(NOT HAVE_DECL_ETHER_NTOHOST)
 385         #
 386         # No - how about <sys/ethernet.h>, as on Solaris 10 and later?
 387         #
 388         # This test fails if we don't have <sys/ethernet.h>
 389         # or if we do but it doesn't declare ether_ntohost().
 390         #
 391         check_symbol_exists(ether_ntohost sys/ethernet.h SYS_ETHERNET_H_DECLARES_ETHER_NTOHOST)
 392         if(SYS_ETHERNET_H_DECLARES_ETHER_NTOHOST)
 393             #
 394             # Yes - we have it declared.
 395             #
 396             set(HAVE_DECL_ETHER_NTOHOST TRUE)
 397         endif()
 398     endif()
 399     #
 400     # Did that succeed?
 401     #
 402     if(NOT HAVE_DECL_ETHER_NTOHOST)
 403         #
 404         # No, how about <arpa/inet.h>, as on AIX?
 405         #
 406         # This test fails if we don't have <arpa/inet.h>
 407         # or if we do but it doesn't declare ether_ntohost().
 408         #
 409         check_symbol_exists(ether_ntohost arpa/inet.h ARPA_INET_H_DECLARES_ETHER_NTOHOST)
 410         if(ARPA_INET_H_DECLARES_ETHER_NTOHOST)
 411             #
 412             # Yes - we have it declared.
 413             #
 414             set(HAVE_DECL_ETHER_NTOHOST TRUE)
 415         endif()
 416     endif()
 417     #
 418     # Did that succeed?
 419     #
 420     if(NOT HAVE_DECL_ETHER_NTOHOST)
 421         #
 422         # No, how about <netinet/if_ether.h>?
 423         # On some platforms, it requires <net/if.h> and
 424         # <netinet/in.h>, and we always include it with
 425         # both of them, so test it with both of them.
 426         #
 427         # This test fails if we don't have <netinet/if_ether.h>
 428         # and the headers we include before it, or if we do but
 429         # <netinet/if_ether.h> doesn't declare ether_ntohost().
 430         #
 431         check_symbol_exists(ether_ntohost "sys/types.h;sys/socket.h;net/if.h;netinet/in.h;netinet/if_ether.h" NETINET_IF_ETHER_H_DECLARES_ETHER_NTOHOST)
 432         if(NETINET_IF_ETHER_H_DECLARES_ETHER_NTOHOST)
 433             #
 434             # Yes - we have it declared.
 435             #
 436             set(HAVE_DECL_ETHER_NTOHOST TRUE)
 437         endif()
 438     endif()
 439     #
 440     # After all that, is ether_ntohost() declared?
 441     #
 442     if(NOT HAVE_DECL_ETHER_NTOHOST)
 443         #
 444         # No, we'll have to declare it ourselves.
 445         # Do we have "struct ether_addr" if we include<netinet/if_ether.h>?
 446         #
 447         check_struct_has_member("struct ether_addr" octet "sys/types.h;sys/socket.h;net/if.h;netinet/in.h;netinet/if_ether.h" HAVE_STRUCT_ETHER_ADDR)
 448     endif()
 449 endif()
 450 cmake_pop_check_state()
 451
 452 check_function_exists(dnet_htoa STDLIBS_HAVE_DNET_HTOA)
 453 if(STDLIBS_HAVE_DNET_HTOA)
 454     set(HAVE_DNET_HTOA TRUE)
 455 else(STDLIBS_HAVE_DNET_HTOA)
 456     check_library_exists(dnet dnet_htoa "" HAVE_DNET_HTOA)
 457     if(HAVE_DNET_HTOA)
 458         set(TCPDUMP_LINK_LIBRARIES dnet ${TCPDUMP_LINK_LIBRARIES})
 459     endif(HAVE_DNET_HTOA)
 460 endif(STDLIBS_HAVE_DNET_HTOA)
 461 if(HAVE_DNET_HTOA)
 462     #
 463     # OK, we have dnet_htoa().  Do we have netdnet/dnetdb.h?
 464     #
 465     check_include_files("sys/types.h;netdnet/dnetdb.h" HAVE_NETDNET_DNETDB_H)
 466     if(HAVE_NETDNET_DNETDB_H)
 467         #
 468         # Yes.  Does it declare dnet_htoa()?
 469         #
 470         cmake_push_check_state()
 471         set(CMAKE_REQUIRED_LIBRARIES dnet)
 472         check_symbol_exists(dnet_htoa "sys/types.h;netdnet/dnetdb.h" NETDNET_DNETDB_H_DECLARES_DNET_HTOA)
 473         cmake_pop_check_state()
 474     endif(HAVE_NETDNET_DNETDB_H)
 475
 476     #
 477     # Do we have netdnet/dn.h?
 478     #
 479     check_include_file(netdnet/dn.h HAVE_NETDNET_DN_H)
 480     if(HAVE_NETDNET_DN_H)
 481         #
 482         # Yes.  Does it declare struct dn_naddr?
 483         #
 484         cmake_push_check_state()
 485         set(CMAKE_EXTRA_INCLUDE_FILES netdnet/dn.h)
 486         check_type_size("struct dn_naddr" STRUCT_DN_NADDR)
 487         cmake_pop_check_state()
 488     endif(HAVE_NETDNET_DN_H)
 489 endif(HAVE_DNET_HTOA)
 490
 491 #
 492 # Data types.
 493 #
 494 # XXX - there's no check_struct() macro that's like check_struct_has_member()
 495 # except that it only checks for the existence of the structure type,
 496 # so we use check_struct_has_member() and look for ss_family.
 497 #
 498
 499 #
 500 # Check for IPv6 support.
 501 # We just check for AF_INET6 and struct in6_addr.
 502 #
 503 cmake_push_check_state()
 504 if(WIN32)
 505     set(CMAKE_EXTRA_INCLUDE_FILES sys/types.h ws2tcpip.h)
 506     check_symbol_exists(AF_INET6 "sys/types.h;ws2tcpip.h" HAVE_AF_INET6)
 507 else(WIN32)
 508     set(CMAKE_EXTRA_INCLUDE_FILES sys/types.h sys/socket.h netinet/in.h)
 509     check_symbol_exists(AF_INET6 "sys/types.h;sys/socket.h;netinet/in.h" HAVE_AF_INET6)
 510 endif(WIN32)
 511 check_type_size("struct in6_addr" HAVE_STRUCT_IN6_ADDR)
 512 cmake_pop_check_state()
 513 if(HAVE_AF_INET6 AND HAVE_STRUCT_IN6_ADDR)
 514     set(HAVE_OS_IPV6_SUPPORT TRUE)
 515 endif(HAVE_AF_INET6 AND HAVE_STRUCT_IN6_ADDR)
 516
 517 ######################################
 518 # External dependencies
 519 ######################################
 520
 521 #
 522 # libpcap/WinPcap.
 523 # First, find it.
 524 #
 525 find_package(PCAP REQUIRED)
 526 include_directories(${PCAP_INCLUDE_DIRS})
 527
 528 cmake_push_check_state()
 529
 530 #
 531 # Now check headers.
 532 #
 533 set(CMAKE_REQUIRED_INCLUDES ${PCAP_INCLUDE_DIRS})
 534
 535 #
 536 # Check whether we have pcap/pcap-inttypes.h.
 537 # If we do, we use that to get the C99 types defined.
 538 #
 539 check_include_file(pcap/pcap-inttypes.h HAVE_PCAP_PCAP_INTTYPES_H)
 540
 541 #
 542 # Check for some headers introduced in later versions of libpcap
 543 # and used by some printers.
 544 #
 545 # Those headers might use the {u_}intN_t types, so we must include
 546 # netdissect-stdinc.h first.
 547 #
 548 set(CMAKE_EXTRA_INCLUDE_FILES netdissect-stdinc.h)
 549 check_include_file(pcap/bluetooth.h HAVE_PCAP_BLUETOOTH_H)
 550 check_include_file(pcap/nflog.h HAVE_PCAP_NFLOG_H)
 551 cmake_pop_check_state()
 552
 553 #
 554 # Check for various functions in libpcap/WinPcap.
 555 #
 556 cmake_push_check_state()
 557 set(CMAKE_REQUIRED_LIBRARIES ${PCAP_LIBRARIES})
 558
 559 #
 560 # Check for "pcap_list_datalinks()" and use a substitute version if
 561 # it's not present.  If it is present, check for "pcap_free_datalinks()";
 562 # if it's not present, we don't replace it for now.  (We could do so
 563 # on UN*X, but not on Windows, where hilarity ensues if a program
 564 # built with one version of the MSVC support library tries to free
 565 # something allocated by a library built with another version of
 566 # the MSVC support library.)
 567 #
 568 check_function_exists(pcap_list_datalinks HAVE_PCAP_LIST_DATALINKS)
 569 if(HAVE_PCAP_LIST_DATALINKS)
 570     check_function_exists(pcap_free_datalinks HAVE_PCAP_FREE_DATALINKS)
 571 endif(HAVE_PCAP_LIST_DATALINKS)
 572
 573 #
 574 # Check for "pcap_datalink_name_to_val()", and use a substitute
 575 # version if it's not present.  If it is present, check for
 576 # "pcap_datalink_val_to_description()", and if we don't have it,
 577 # use a substitute version.
 578 #
 579 check_function_exists(pcap_datalink_name_to_val HAVE_PCAP_DATALINK_NAME_TO_VAL)
 580 if(HAVE_PCAP_DATALINK_NAME_TO_VAL)
 581     check_function_exists(pcap_datalink_val_to_description HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION)
 582 endif(HAVE_PCAP_DATALINK_NAME_TO_VAL)
 583
 584 #
 585 # Check for "pcap_set_datalink()"; you can't substitute for it if
 586 # it's absent (it has hooks into libpcap), so just define the
 587 # HAVE_ value if it's there.
 588 #
 589 check_function_exists(pcap_set_datalink HAVE_PCAP_SET_DATALINK)
 590
 591 #
 592 # Check for "pcap_breakloop()"; you can't substitute for it if
 593 # it's absent (it has hooks into the live capture routines),
 594 # so just define the HAVE_ value if it's there.
 595 #
 596 check_function_exists(pcap_breakloop HAVE_PCAP_BREAKLOOP)
 597
 598 #
 599 # Check for "pcap_dump_ftell()"; we use a substitute version
 600 # if it's not present.
 601 #
 602 check_function_exists(pcap_dump_ftell HAVE_PCAP_DUMP_FTELL)
 603
 604 #
 605 # Do we have the new open API?  Check for pcap_create() and for
 606 # pcap_statustostr(), and assume that, if we have both of them,
 607 # we also have pcap_activate() and the other new routines
 608 # introduced in libpcap 1.0.0.  (We check for pcap_statustostr()
 609 # as well, because WinPcap 4.1.3 screwed up and exported pcap_create()
 610 # but not other routines such as pcap_statustostr(), even though it
 611 # defined them and even though you really want pcap_statustostr() to
 612 # get strings corresponding to some of the status returns from the
 613 # new routines.)
 614 #
 615 check_function_exists(pcap_statustostr HAVE_PCAP_STATUSTOSTR)
 616 #
 617 # If we don't have pcap_statustostr(), don't check for pcap_create(),
 618 # so we pretend we don't have it.
 619 #
 620 if(HAVE_PCAP_STATUSTOSTR)
 621     check_function_exists(pcap_create HAVE_PCAP_CREATE)
 622 endif(HAVE_PCAP_STATUSTOSTR)
 623 if(HAVE_PCAP_CREATE)
 624     #
 625     # OK, do we have pcap_set_tstamp_type?  If so, assume we have
 626     # pcap_list_tstamp_types and pcap_free_tstamp_types as well.
 627     #
 628     check_function_exists(pcap_set_tstamp_type HAVE_PCAP_SET_TSTAMP_TYPE)
 629
 630     #
 631     # And do we have pcap_set_tstamp_precision?  If so, we assume
 632     # we also have pcap_open_offline_with_tstamp_precision.
 633     #
 634     check_function_exists(pcap_set_tstamp_precision HAVE_PCAP_SET_TSTAMP_PRECISION)
 635 endif(HAVE_PCAP_CREATE)
 636
 637 #
 638 # Check for a miscellaneous collection of functions which we use
 639 # if we have them.
 640 #
 641 check_function_exists(pcap_findalldevs HAVE_PCAP_FINDALLDEVS)
 642 if(HAVE_PCAP_FINDALLDEVS)
 643     #
 644     # Check for libpcap having pcap_findalldevs() but the pcap.h header
 645     # not having pcap_if_t; some versions of Mac OS X shipped with pcap.h
 646     # from 0.6 and libpcap 0.8, so that libpcap had pcap_findalldevs but
 647     # pcap.h didn't have pcap_if_t.
 648     #
 649     cmake_push_check_state()
 650     set(CMAKE_REQUIRED_INCLUDES ${PCAP_INCLUDE_DIRS})
 651     set(CMAKE_EXTRA_INCLUDE_FILES pcap.h)
 652     check_type_size(pcap_if_t PCAP_IF_T)
 653     cmake_pop_check_state()
 654 endif(HAVE_PCAP_FINDALLDEVS)
 655 check_function_exists(pcap_dump_flush HAVE_PCAP_DUMP_FLUSH)
 656 check_function_exists(pcap_lib_version HAVE_PCAP_LIB_VERSION)
 657 if(NOT HAVE_PCAP_LIB_VERSION)
 658     # Check for the pcap_version string variable and set HAVE_PCAP_VERSION
 659 endif(NOT HAVE_PCAP_LIB_VERSION)
 660 check_function_exists(pcap_setdirection HAVE_PCAP_SETDIRECTION)
 661 check_function_exists(pcap_set_immediate_mode HAVE_PCAP_SET_IMMEDIATE_MODE)
 662 check_function_exists(pcap_dump_ftell64 HAVE_PCAP_DUMP_FTELL64)
 663 check_function_exists(pcap_open HAVE_PCAP_OPEN)
 664 check_function_exists(pcap_findalldevs_ex HAVE_PCAP_FINDALLDEVS_EX)
 665
 666 #
 667 # On Windows, check for pcap_wsockinit(); if we don't have it, check for
 668 # wsockinit().
 669 #
 670 if(WIN32)
 671     check_function_exists(pcap_wsockinit HAVE_PCAP_WSOCKINIT)
 672     if(NOT HAVE_PCAP_WSOCKINIT)
 673         check_function_exists(wsockinit HAVE_WSOCKINIT)
 674     endif(NOT HAVE_PCAP_WSOCKINIT)
 675 endif(WIN32)
 676
 677 #
 678 # Check for special debugging functions
 679 #
 680 check_function_exists(pcap_set_parser_debug HAVE_PCAP_SET_PARSER_DEBUG)
 681 if(NOT HAVE_PCAP_SET_PARSER_DEBUG)
 682     # Check whether libpcap defines pcap_debug or yydebug
 683     check_variable_exists(pcap_debug HAVE_PCAP_DEBUG)
 684     if(NOT HAVE_PCAP_DEBUG)
 685         check_variable_exists(yydebug HAVE_YYDEBUG)
 686     endif(NOT HAVE_PCAP_DEBUG)
 687 endif(NOT HAVE_PCAP_SET_PARSER_DEBUG)
 688
 689 check_function_exists(pcap_set_optimizer_debug HAVE_PCAP_SET_OPTIMIZER_DEBUG)
 690 check_function_exists(bpf_dump HAVE_BPF_DUMP)
 691
 692 cmake_pop_check_state()
 693
 694 #
 695 # We have libpcap.
 696 #
 697 include_directories(SYSTEM ${PCAP_INCLUDE_DIRS})
 698 set(TCPDUMP_LINK_LIBRARIES ${PCAP_LIBRARIES} ${TCPDUMP_LINK_LIBRARIES})
 699
 700 #
 701 # Optional libraries.
 702 #
 703
 704 #
 705 # libsmi.
 706 #
 707 if(WITH_SMI)
 708     find_package(SMI)
 709     if(SMI_FOUND)
 710         include_directories(SYSTEM ${SMI_INCLUDE_DIRS})
 711         set(TCPDUMP_LINK_LIBRARIES ${TCPDUMP_LINK_LIBRARIES} ${SMI_LIBRARIES})
 712         set(USE_LIBSMI ON)
 713     endif(SMI_FOUND)
 714 endif(WITH_SMI)
 715
 716 #
 717 # OpenSSL/libressl libcrypto.
 718 #
 719 if(WITH_CRYPTO)
 720     find_package(CRYPTO)
 721     if(CRYPTO_FOUND)
 722         #
 723         # Check for some functions.
 724         #
 725         cmake_push_check_state()
 726         set(CMAKE_REQUIRED_LIBRARIES crypto)
 727
 728         #
 729         # 1) do we have EVP_CIPHER_CTX_new?
 730         # If so, we use it to allocate an EVP_CIPHER_CTX, as
 731         # EVP_CIPHER_CTX may be opaque; otherwise, we allocate
 732         # it ourselves.
 733         #
 734         check_function_exists(EVP_CIPHER_CTX_new HAVE_EVP_CIPHER_CTX_NEW)
 735
 736         #
 737         # 2) do we have EVP_CipherInit_ex()?
 738         # If so, we use it, because we need to be able to make two
 739         # "initialize the cipher" calls, one with the cipher and key,
 740         # and one with the IV, and, as of OpenSSL 1.1, You Can't Do That
 741         # with EVP_CipherInit(), because a call to EVP_CipherInit() will
 742         # unconditionally clear the context, and if you don't supply a
 743         # cipher, it'll clear the cipher, rendering the context unusable
 744         # and causing a crash.
 745         #
 746         check_function_exists(EVP_CipherInit_ex HAVE_EVP_CIPHERINIT_EX)
 747
 748         cmake_pop_check_state()
 749
 750         #
 751         # We have libcrypto.
 752         #
 753         include_directories(SYSTEM ${CRYPTO_INCLUDE_DIRS})
 754         set(TCPDUMP_LINK_LIBRARIES ${TCPDUMP_LINK_LIBRARIES} ${CRYPTO_LIBRARIES})
 755         set(HAVE_LIBCRYPTO ON)
 756     endif(CRYPTO_FOUND)
 757 endif(WITH_CRYPTO)
 758
 759 #
 760 # Capsicum sandboxing.
 761 # Some of this is in the system library, some of it is in other libraries.
 762 #
 763 if(WITH_CAPSICUM)
 764     check_function_exists(cap_enter HAVE_CAP_ENTER)
 765     check_function_exists(cap_rights_limit HAVE_CAP_RIGHTS_LIMIT)
 766     check_function_exists(cap_ioctls_limit HAVE_CAP_IOCTLS_LIMIT)
 767     check_function_exists(openat HAVE_OPENAT)
 768     if(HAVE_CAP_ENTER AND HAVE_CAP_RIGHTS_LIMIT AND
 769        HAVE_CAP_IOCTLS_LIMIT AND HAVE_OPENAT)
 770         #
 771         # OK, we have the functions we need to support Capsicum.
 772         #
 773         set(HAVE_CAPSICUM TRUE)
 774
 775         #
 776         # OK, can we use Casper?
 777         #
 778         check_library_exists(casper cap_init "" HAVE_CAP_INIT)
 779         if(HAVE_CAP_INIT)
 780             cmake_push_check_state()
 781             set(CMAKE_REQUIRED_LIBRARIES casper)
 782             check_library_exists(cap_dns cap_gethostbyaddr "" HAVE_CAP_GETHOSTBYADDR)
 783             cmake_pop_check_state()
 784             if(HAVE_CAP_GETHOSTBYADDR)
 785                 set(HAVE_CASPER TRUE)
 786                 set(TCPDUMP_LINK_LIBRARIES ${TCPDUMP_LINK_LIBRARIES} casper cap_dns)
 787             endif(HAVE_CAP_GETHOSTBYADDR)
 788         endif(HAVE_CAP_INIT)
 789     endif(HAVE_CAP_ENTER AND HAVE_CAP_RIGHTS_LIMIT AND
 790           HAVE_CAP_IOCTLS_LIMIT AND HAVE_OPENAT)
 791 endif(WITH_CAPSICUM)
 792
 793 #
 794 # libcap-ng.
 795 #
 796 if(WITH_CAP_NG)
 797     check_include_file(cap-ng.h HAVE_CAP_NG_H)
 798     check_library_exists(cap-ng capng_change_id "" HAVE_LIBCAP_NG)
 799     if(HAVE_LIBCAP_NG)
 800         set(TCPDUMP_LINK_LIBRARIES ${TCPDUMP_LINK_LIBRARIES} cap-ng)
 801     endif(HAVE_LIBCAP_NG)
 802 endif(WITH_CAP_NG)
 803
 804 ###################################################################
 805 #   Warning options
 806 ###################################################################
 807
 808 #
 809 # Check and add warning options if we have a .devel file.
 810 #
 811 if(EXISTS ${CMAKE_SOURCE_DIR}/.devel OR EXISTS ${CMAKE_BINARY_DIR}/.devel)
 812     #
 813     # Warning options.
 814     #
 815     if(MSVC AND NOT ${CMAKE_C_COMPILER} MATCHES "clang*")
 816         #
 817         # MSVC, with Microsoft's front end and code generator.
 818         # "MSVC" is also set for Microsoft's compiler with a Clang
 819         # front end and their code generator ("Clang/C2"), so we
 820         # check for clang.exe and treat that differently.
 821         #
 822         check_and_add_compiler_option(-Wall)
 823         #
 824         # Disable some pointless warnings that /Wall turns on.
 825         #
 826         # Unfortunately, MSVC does not appear to have an equivalent
 827         # to "__attribute__((unused))" to mark a particular function
 828         # parameter as being known to be unused, so that the compiler
 829         # won't warn about it (for example, the function might have
 830         # that parameter because a pointer to it is being used, and
 831         # the signature of that function includes that parameter).
 832         # C++ lets you give a parameter a type but no name, but C
 833         # doesn't have that.
 834         #
 835         check_and_add_compiler_option(-wd4100)
 836         #
 837         # In theory, we care whether somebody uses f() rather than
 838         # f(void) to declare a function with no arguments, but, in
 839         # practice, there are places in the Windows header files
 840         # that appear to do that, so we squelch that warning.
 841         #
 842         check_and_add_compiler_option(-wd4255)
 843         #
 844         # Windows FD_SET() generates this, so we suppress it.
 845         #
 846         check_and_add_compiler_option(-wd4548)
 847         #
 848         # Perhaps testing something #defined to be 0 with #ifdef is an
 849         # error, and it should be tested with #if, but perhaps it's
 850         # not, and Microsoft does that in its headers, so we squelch
 851         # that warning.
 852         #
 853         check_and_add_compiler_option(-wd4574)
 854         #
 855         # The Windows headers also test not-defined values in #if, so
 856         # we don't want warnings about that, either.
 857         #
 858         check_and_add_compiler_option(-wd4668)
 859         #
 860         # We do *not* care whether some function is, or isn't, going to be
 861         # expanded inline.
 862         #
 863         check_and_add_compiler_option(-wd4710)
 864         check_and_add_compiler_option(-wd4711)
 865         #
 866         # We do *not* care whether we're adding padding bytes after
 867         # structure members.
 868         #
 869         check_and_add_compiler_option(-wd4820)
 870     else()
 871         #
 872         # Other compilers, including MSVC with a Clang front end and
 873         # Microsoft's code generator.  We currently treat them as if
 874         # they might support GCC-style -W options.
 875         #
 876         check_and_add_compiler_option(-Wall)
 877         check_and_add_compiler_option(-Wmissing-prototypes)
 878         check_and_add_compiler_option(-Wstrict-prototypes)
 879         check_and_add_compiler_option(-Wwrite-strings)
 880         check_and_add_compiler_option(-Wpointer-arith)
 881         check_and_add_compiler_option(-Wcast-qual)
 882         check_and_add_compiler_option(-Wshadow)
 883         check_and_add_compiler_option(-Wdeclaration-after-statement)
 884         check_and_add_compiler_option(-Wpedantic)
 885         check_and_add_compiler_option(-Wold-style-definition)
 886         check_and_add_compiler_option(-Wused-but-marked-unused)
 887         check_and_add_compiler_option(-W)
 888         check_and_add_compiler_option(-Wassign-enum)
 889     endif()
 890 endif()
 891
 892 ######################################
 893 # Input files
 894 ######################################
 895
 896 if(ENABLE_SMB)
 897     #
 898     # We allow the SMB dissector to be omitted.
 899     #
 900     set(LOCALSRC ${LOCALSRC}
 901         print-smb.c
 902         smbutil.c)
 903 endif(ENABLE_SMB)
 904
 905 set(NETDISSECT_SOURCE_LIST_C
 906     addrtoname.c
 907     addrtostr.c
 908     af.c
 909     ascii_strcasecmp.c
 910     checksum.c
 911     cpack.c
 912     gmpls.c
 913     gmt2local.c
 914     in_cksum.c
 915     ipproto.c
 916     l2vpn.c
 917     machdep.c
 918     netdissect.c
 919     netdissect-alloc.c
 920     nlpid.c
 921     oui.c
 922     parsenfsfh.c
 923     print.c
 924     print-802_11.c
 925     print-802_15_4.c
 926     print-ah.c
 927     print-ahcp.c
 928     print-aodv.c
 929     print-aoe.c
 930     print-ap1394.c
 931     print-arcnet.c
 932     print-arp.c
 933     print-ascii.c
 934     print-atalk.c
 935     print-atm.c
 936     print-babel.c
 937     print-beep.c
 938     print-bfd.c
 939     print-bgp.c
 940     print-bootp.c
 941     print-bt.c
 942     print-calm-fast.c
 943     print-carp.c
 944     print-cdp.c
 945     print-cfm.c
 946     print-chdlc.c
 947     print-cip.c
 948     print-cnfp.c
 949     print-dccp.c
 950     print-decnet.c
 951     print-dhcp6.c
 952     print-domain.c
 953     print-dtp.c
 954     print-dvmrp.c
 955     print-eap.c
 956     print-egp.c
 957     print-eigrp.c
 958     print-enc.c
 959     print-esp.c
 960     print-ether.c
 961     print-fddi.c
 962     print-forces.c
 963     print-fr.c
 964     print-frag6.c
 965     print-ftp.c
 966     print-geneve.c
 967     print-geonet.c
 968     print-gre.c
 969     print-hncp.c
 970     print-hsrp.c
 971     print-http.c
 972     print-icmp.c
 973     print-icmp6.c
 974     print-igmp.c
 975     print-igrp.c
 976     print-ip.c
 977     print-ip6.c
 978     print-ip6opts.c
 979     print-ipcomp.c
 980     print-ipfc.c
 981     print-ipnet.c
 982     print-ipx.c
 983     print-isakmp.c
 984     print-isoclns.c
 985     print-juniper.c
 986     print-krb.c
 987     print-l2tp.c
 988     print-lane.c
 989     print-ldp.c
 990     print-lisp.c
 991     print-llc.c
 992     print-lldp.c
 993     print-lmp.c
 994     print-loopback.c
 995     print-lspping.c
 996     print-lwapp.c
 997     print-lwres.c
 998     print-m3ua.c
 999     print-medsa.c
1000     print-mobile.c
1001     print-mobility.c
1002     print-mpcp.c
1003     print-mpls.c
1004     print-mptcp.c
1005     print-msdp.c
1006     print-msnlb.c
1007     print-nflog.c
1008     print-nfs.c
1009     print-nsh.c
1010     print-ntp.c
1011     print-null.c
1012     print-olsr.c
1013     print-openflow-1.0.c
1014     print-openflow.c
1015     print-ospf.c
1016     print-ospf6.c
1017     print-otv.c
1018     print-pgm.c
1019     print-pim.c
1020     print-pktap.c
1021     print-ppi.c
1022     print-ppp.c
1023     print-pppoe.c
1024     print-pptp.c
1025     print-radius.c
1026     print-raw.c
1027     print-resp.c
1028     print-rip.c
1029     print-ripng.c
1030     print-rpki-rtr.c
1031     print-rrcp.c
1032     print-rsvp.c
1033     print-rt6.c
1034     print-rtsp.c
1035     print-rx.c
1036     print-sctp.c
1037     print-sflow.c
1038     print-sip.c
1039     print-sl.c
1040     print-sll.c
1041     print-slow.c
1042     print-smtp.c
1043     print-snmp.c
1044     print-stp.c
1045     print-sunatm.c
1046     print-sunrpc.c
1047     print-symantec.c
1048     print-syslog.c
1049     print-tcp.c
1050     print-telnet.c
1051     print-tftp.c
1052     print-timed.c
1053     print-tipc.c
1054     print-token.c
1055     print-udld.c
1056     print-udp.c
1057     print-usb.c
1058     print-vjc.c
1059     print-vqp.c
1060     print-vrrp.c
1061     print-vtp.c
1062     print-vxlan.c
1063     print-vxlan-gpe.c
1064     print-wb.c
1065     print-zephyr.c
1066     print-zeromq.c
1067     ${LOCALSRC}
1068     signature.c
1069     strtoaddr.c
1070     util-print.c
1071 )
1072
1073 #
1074 # Replace missing functions
1075 #
1076 foreach(FUNC strlcat strlcpy strdup strsep getservent getopt_long)
1077     string(TOUPPER ${FUNC} FUNC_UPPERCASE)
1078     set(HAVE_FUNC_UPPERCASE HAVE_${FUNC_UPPERCASE})
1079     if(NOT ${HAVE_FUNC_UPPERCASE})
1080         set(NETDISSECT_SOURCE_LIST_C ${NETDISSECT_SOURCE_LIST_C} missing/${FUNC}.c)
1081     endif()
1082 endforeach()
1083 if(NOT WIN32)
1084     if(NOT HAVE_VSNPRINTF OR NOT HAVE_SNPRINTF)
1085         set(NETDISSECT_SOURCE_LIST_C ${NETDISSECT_SOURCE_LIST_C} missing/snprintf.c)
1086     endif(NOT HAVE_VSNPRINTF OR NOT HAVE_SNPRINTF)
1087 endif(NOT WIN32)
1088
1089 add_library(netdissect STATIC
1090     ${NETDISSECT_SOURCE_LIST_C}
1091 )
1092 if(NOT C_ADDITIONAL_FLAGS STREQUAL "")
1093     set_target_properties(netdissect PROPERTIES COMPILE_FLAGS ${C_ADDITIONAL_FLAGS})
1094 endif()
1095
1096 set(TCPDUMP_SOURCE_LIST_C tcpdump.c)
1097
1098 if(NOT HAVE_BPF_DUMP)
1099     set(TCPDUMP_SOURCE_LIST_C ${TCPDUMP_SOURCE_LIST_C} bpf_dump.c)
1100 endif(NOT HAVE_BPF_DUMP)
1101 if(NOT HAVE_PCAP_DUMP_FTELL)
1102     set(TCPDUMP_SOURCE_LIST_C ${TCPDUMP_SOURCE_LIST_C} missing/pcap_dump_ftell.c)
1103 endif(NOT HAVE_PCAP_DUMP_FTELL)
1104
1105 if(NOT HAVE_PCAP_LIST_DATALINKS)
1106     set(TCPDUMP_SOURCE_LIST_C ${TCPDUMP_SOURCE_LIST_C} missing/datalinks.c)
1107 endif(NOT HAVE_PCAP_LIST_DATALINKS)
1108
1109 if((NOT HAVE_PCAP_DATALINK_NAME_TO_VAL) OR (NOT HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION))
1110     set(TCPDUMP_SOURCE_LIST_C ${TCPDUMP_SOURCE_LIST_C} missing/dlnames.c)
1111 endif((NOT HAVE_PCAP_DATALINK_NAME_TO_VAL) OR (NOT HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION))
1112
1113 set(PROJECT_SOURCE_LIST_C ${NETDISSECT_SOURCE_LIST_C} ${TCPDUMP_SOURCE_LIST_C})
1114
1115 file(GLOB PROJECT_SOURCE_LIST_H
1116     *.h
1117 )
1118
1119 source_group("Source Files" FILES ${PROJECT_SOURCE_LIST_C})
1120 source_group("Header Files" FILES ${PROJECT_SOURCE_LIST_H})
1121
1122 ######################################
1123 # Register targets
1124 ######################################
1125
1126 add_executable(tcpdump ${TCPDUMP_SOURCE_LIST_C})
1127 if(NOT C_ADDITIONAL_FLAGS STREQUAL "")
1128     set_target_properties(tcpdump PROPERTIES COMPILE_FLAGS ${C_ADDITIONAL_FLAGS})
1129 endif()
1130 target_link_libraries(tcpdump netdissect ${TCPDUMP_LINK_LIBRARIES})
1131
1132 ######################################
1133 # Write out the config.h file
1134 ######################################
1135
1136 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/cmakeconfig.h.in ${CMAKE_CURRENT_BINARY_DIR}/config.h)
1137
1138 ######################################
1139 # Install tcpdump and man pages
1140 ######################################
1141
1142 #
1143 # "Define GNU standard installation directories", which actually
1144 # are also defined, to some degree, by autotools, and at least
1145 # some of which are general UN*X conventions.
1146 #
1147 include(GNUInstallDirs)
1148
1149 set(MAN1_EXPAND tcpdump.1.in)
1150
1151 if(WIN32)
1152     # XXX TODO where to install on Windows?
1153 else(WIN32)
1154     install(TARGETS tcpdump DESTINATION sbin)
1155 endif(WIN32)
1156
1157 # On UN*X, and on Windows when not using MSVC, process man pages and
1158 # arrange that they be installed.
1159 if(NOT MSVC)
1160     #
1161     # Man pages.
1162     #
1163     # For each section of the manual for which we have man pages
1164     # that require macro expansion, do the expansion.
1165     #
1166     set(MAN1 "")
1167     foreach(TEMPLATE_MANPAGE ${MAN1_EXPAND})
1168         string(REPLACE ".in" "" MANPAGE ${TEMPLATE_MANPAGE})
1169         configure_file(${CMAKE_SOURCE_DIR}/${TEMPLATE_MANPAGE} ${CMAKE_CURRENT_BINARY_DIR}/${MANPAGE} @ONLY)
1170         set(MAN1 ${MAN1} ${CMAKE_CURRENT_BINARY_DIR}/${MANPAGE})
1171     endforeach(TEMPLATE_MANPAGE)
1172     install(FILES ${MAN1} DESTINATION ${CMAKE_INSTALL_MANDIR}/man1)
1173 endif(NOT MSVC)
1174
1175 # uninstall target
1176 configure_file(
1177     "${CMAKE_CURRENT_SOURCE_DIR}/cmake_uninstall.cmake.in"
1178     "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
1179     IMMEDIATE @ONLY)
1180
1181 add_custom_target(uninstall
1182     COMMAND ${CMAKE_COMMAND} -P ${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake)
1183
1184 #
1185 # Tcpdump tests
1186 #
1187 add_custom_target(check
1188     COMMAND ./TESTrun.sh
1189     WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/tests)