The Tcpdump Group git mirrors - tcpdump/blob - configure.ac

   1 dnl Copyright (c) 1994, 1995, 1996, 1997
   2 dnl     The Regents of the University of California.  All rights reserved.
   3 dnl
   4 dnl Process this file with autoconf to produce a configure script.
   5 dnl
   6
   7 #
   8 # See
   9 #
  10 #       https://ftp.gnu.org/gnu/config/README
  11 #
  12 # for the URLs to use to fetch new versions of config.guess and
  13 # config.sub.
  14 #
  15
  16 AC_PREREQ([2.69])
  17 AC_INIT([tcpdump],[m4_esyscmd_s(cat VERSION)])
  18 AC_CONFIG_SRCDIR(tcpdump.c)
  19
  20 AC_CANONICAL_HOST
  21
  22 AC_LBL_C_INIT_BEFORE_CC(V_INCLS)
  23 #
  24 # Try to enable as many C99 features as we can.
  25 # At minimum, we want C++/C99-style // comments.
  26 #
  27 AC_PROG_CC_C99
  28 if test "$ac_cv_prog_cc_c99" = "no"; then
  29         AC_MSG_WARN([The C compiler does not support C99; there may be compiler errors])
  30 fi
  31 AC_LBL_C_INIT(V_CCOPT, V_INCLS)
  32 AC_LBL_C_INLINE
  33
  34 AC_CHECK_HEADERS(fcntl.h rpc/rpc.h rpc/rpcent.h net/if.h)
  35
  36 case "$host_os" in
  37
  38 darwin*)
  39         AC_ARG_ENABLE(universal,
  40         AS_HELP_STRING([--disable-universal],[don't build universal on macOS]))
  41         if test "$enable_universal" != "no"; then
  42                 case "$host_os" in
  43
  44                 darwin9.*)
  45                         #
  46                         # Leopard.  Build for x86 and 32-bit PowerPC, with
  47                         # x86 first.  (That's what Apple does.)
  48                         #
  49                         V_CCOPT="$V_CCOPT -arch i386 -arch ppc"
  50                         LDFLAGS="$LDFLAGS -arch i386 -arch ppc"
  51                         ;;
  52
  53                 darwin10.*)
  54                         #
  55                         # Snow Leopard.  Build for x86-64 and x86, with
  56                         # x86-64 first.  (That's what Apple does.)
  57                         #
  58                         V_CCOPT="$V_CCOPT -arch x86_64 -arch i386"
  59                         LDFLAGS="$LDFLAGS -arch x86_64 -arch i386"
  60                         ;;
  61                 esac
  62         fi
  63         ;;
  64 esac
  65
  66
  67 AC_ARG_WITH([smi],
  68    [AS_HELP_STRING([--with-smi],
  69      [link with libsmi (allows to load MIBs on the fly to decode SNMP packets) [default=yes, if available]])],
  70    [],
  71    [with_smi=yes])
  72
  73 if test "x$with_smi" != "xno" ; then
  74         AC_CHECK_HEADER(smi.h,
  75         [
  76                 #
  77                 # OK, we found smi.h.  Do we have libsmi with smiInit?
  78                 #
  79                 AC_CHECK_LIB(smi, smiInit,
  80                 [
  81                         #
  82                         # OK, we have libsmi with smiInit.  Can we use it?
  83                         #
  84                         AC_MSG_CHECKING([whether to enable libsmi])
  85                         savedlibs="$LIBS"
  86                         LIBS="-lsmi $LIBS"
  87                         AC_RUN_IFELSE([AC_LANG_SOURCE([[
  88 /* libsmi available check */
  89 #include <stdio.h>
  90 #include <stdlib.h>
  91 #include <string.h>
  92 #include <smi.h>
  93 int main()
  94 {
  95   int current, revision, age, n;
  96   const int required = 2;
  97   if (smiInit(""))
  98     exit(1);
  99   if (strcmp(SMI_LIBRARY_VERSION, smi_library_version))
 100     exit(2);
 101   n = sscanf(smi_library_version, "%d:%d:%d", &current, &revision, &age);
 102   if (n != 3)
 103     exit(3);
 104   if (required < current - age || required > current)
 105     exit(4);
 106   exit(0);
 107 }
 108                                 ]])
 109                                 ],
 110                                 [
 111                                         AC_MSG_RESULT(yes)
 112                                         AC_DEFINE(USE_LIBSMI, 1,
 113                                             [Define if you enable support for libsmi])
 114                                 ],
 115                                 [
 116                                         dnl autoconf documentation says that
 117                                         dnl $? contains the exit value.
 118                                         dnl reality is that it does not.
 119                                         dnl We leave this in just in case
 120                                         dnl autoconf ever comes back to
 121                                         dnl match the documentation.
 122                                         case $? in
 123                                           1) AC_MSG_RESULT(no - smiInit failed) ;;
 124                                           2) AC_MSG_RESULT(no - header/library version mismatch) ;;
 125                                           3) AC_MSG_RESULT(no - can't determine library version) ;;
 126                                           4) AC_MSG_RESULT(no - too old) ;;
 127                                           *) AC_MSG_RESULT(no) ;;
 128                                         esac
 129                                         LIBS="$savedlibs"
 130                                 ],
 131                                 [
 132                                         AC_MSG_RESULT(not when cross-compiling)
 133                                         LIBS="$savedlibs"
 134                                 ]
 135                         )
 136                 ])
 137         ])
 138 fi
 139
 140 AC_MSG_CHECKING([whether to enable the possibly-buggy SMB printer])
 141 AC_ARG_ENABLE([smb],
 142    [AS_HELP_STRING([--enable-smb],
 143      [enable possibly-buggy SMB printer [default=no]])],
 144    [],
 145    [enableval=no])
 146 case "$enableval" in
 147 yes)    AC_MSG_RESULT(yes)
 148         AC_DEFINE(ENABLE_SMB, 1,
 149             [define if you want to build the possibly-buggy SMB printer])
 150         LOCALSRC="print-smb.c smbutil.c $LOCALSRC"
 151         ;;
 152 *)      AC_MSG_RESULT(no)
 153         ;;
 154 esac
 155
 156 AC_ARG_WITH(user, [  --with-user=USERNAME    drop privileges by default to USERNAME])
 157 AC_MSG_CHECKING([whether to drop root privileges by default])
 158 if test ! -z "$withval" && test "$withval" != "no" ; then
 159        if test "$withval" = "yes" ; then
 160            AC_MSG_ERROR([--with-user requires a username])
 161        fi
 162        AC_DEFINE_UNQUOTED(WITH_USER, "$withval",
 163            [define if should drop privileges by default])
 164        AC_MSG_RESULT([yes, to user "$withval"])
 165 else
 166        AC_MSG_RESULT(no)
 167 fi
 168
 169 AC_ARG_WITH(chroot, [  --with-chroot=DIRECTORY when dropping privileges, chroot to DIRECTORY])
 170 AC_MSG_CHECKING([whether to chroot])
 171 if test ! -z "$withval" && test "$withval" != "no" ; then
 172        if test "$withval" = "yes" ; then
 173            AC_MSG_ERROR([--with-chroot requires a directory])
 174        fi
 175        AC_DEFINE_UNQUOTED(WITH_CHROOT, "$withval",
 176            [define if should chroot when dropping privileges])
 177        AC_MSG_RESULT([yes, to directory "$withval"])
 178 else
 179        AC_MSG_RESULT(no)
 180 fi
 181
 182 AC_ARG_WITH(sandbox-capsicum,
 183         AS_HELP_STRING([--with-sandbox-capsicum],
 184                        [use Capsicum security functions @<:@default=yes, if available@:>@]))
 185 #
 186 # Check whether various functions are available.  If any are, set
 187 # ac_lbl_capsicum_function_seen to yes; if any are not, set
 188 # ac_lbl_capsicum_function_not_seen to yes.
 189 #
 190 # We don't check cap_rights_init(), as it's a macro, wrapping another
 191 # function, in at least some versions of FreeBSD, and AC_CHECK_FUNCS()
 192 # doesn't handle that.
 193 #
 194 # All of the ones we check for must be available in order to enable
 195 # capsicum sandboxing.
 196 #
 197 # XXX - do we need to check for all of them, or are there some that, if
 198 # present, imply others are present?
 199 #
 200 if test -z "$with_sandbox_capsicum" || test "$with_sandbox_capsicum" != "no" ; then
 201         #
 202         # First, make sure we have the required header.
 203         #
 204         AC_CHECK_HEADER(sys/capsicum.h,
 205         [
 206                 #
 207                 # We do; now make sure we have the required functions.
 208                 #
 209                 AC_CHECK_FUNCS(cap_enter cap_rights_limit cap_ioctls_limit openat,
 210                     ac_lbl_capsicum_function_seen=yes,
 211                     ac_lbl_capsicum_function_not_seen=yes)
 212         ])
 213         AC_CHECK_LIB(casper, cap_init, LIBS="$LIBS -lcasper")
 214         AC_CHECK_LIB(cap_dns, cap_gethostbyaddr, LIBS="$LIBS -lcap_dns")
 215 fi
 216 AC_MSG_CHECKING([whether to sandbox using capsicum])
 217 if test "x$ac_lbl_capsicum_function_seen" = "xyes" -a "x$ac_lbl_capsicum_function_not_seen" != "xyes"; then
 218         AC_DEFINE(HAVE_CAPSICUM, 1, [capsicum support available])
 219         AC_MSG_RESULT(yes)
 220 else
 221         AC_MSG_RESULT(no)
 222 fi
 223 AC_MSG_CHECKING([whether to sandbox using Casper library])
 224 if test "x$ac_cv_lib_casper_cap_init" = "xyes" -a "x$ac_cv_lib_cap_dns_cap_gethostbyaddr" = "xyes"; then
 225         AC_DEFINE(HAVE_CASPER, 1, [Casper support available])
 226         AC_MSG_RESULT(yes)
 227 else
 228         AC_MSG_RESULT(no)
 229 fi
 230
 231 #
 232 # We must check this before checking whether to check the OS's IPv6,
 233 # support because, on some platforms (such as SunOS 5.x), the test
 234 # program requires the extra networking libraries.
 235 #
 236 AC_LBL_LIBRARY_NET
 237
 238 #
 239 # Check whether AF_INET6 and struct in6_addr are defined.
 240 # If they aren't both defined, we don't have sufficient OS
 241 # support for IPv6, so we don't look for IPv6 support libraries,
 242 # and we define AF_INET6 and struct in6_addr ourselves.
 243 #
 244 AC_MSG_CHECKING([whether the operating system supports IPv6])
 245 AC_COMPILE_IFELSE(
 246     [
 247       AC_LANG_SOURCE(
 248         [[
 249 #include <string.h>
 250 /* AF_INET6 available check */
 251 #include <sys/types.h>
 252 #ifdef _WIN32
 253 #include <ws2tcpip.h>
 254 #else
 255 #include <sys/socket.h>
 256 #include <netinet/in.h>
 257 #endif
 258 #ifdef AF_INET6
 259 void
 260 foo(struct in6_addr *addr)
 261 {
 262  memset(addr, 0, sizeof (struct in6_addr));
 263 }
 264 #else
 265 #error "AF_INET6 not defined"
 266 #endif
 267         ]])
 268     ],
 269     [
 270         AC_MSG_RESULT(yes)
 271         AC_DEFINE(HAVE_OS_IPV6_SUPPORT, 1,
 272             [define if the OS provides AF_INET6 and struct in6_addr])
 273         ipv6=yes
 274     ],
 275     [
 276         AC_MSG_RESULT(no)
 277         ipv6=no
 278     ]
 279 )
 280
 281 ipv6type=unknown
 282 ipv6lib=none
 283 ipv6trylibc=no
 284
 285 if test "$ipv6" = "yes"; then
 286         AC_MSG_CHECKING([ipv6 stack type])
 287         for i in inria kame linux-glibc linux-libinet6 toshiba v6d zeta; do
 288                 case $i in
 289                 inria)
 290                         dnl http://www.kame.net/
 291                         AC_EGREP_CPP(yes,
 292 [#include <netinet/in.h>
 293 #ifdef IPV6_INRIA_VERSION
 294 yes
 295 #endif],
 296                                 [ipv6type=$i])
 297                         ;;
 298                 kame)
 299                         dnl http://www.kame.net/
 300                         AC_EGREP_CPP(yes,
 301 [#include <netinet/in.h>
 302 #ifdef __KAME__
 303 yes
 304 #endif],
 305                                 [ipv6type=$i;
 306                                 ipv6lib=inet6;
 307                                 ipv6libdir=/usr/local/v6/lib;
 308                                 ipv6trylibc=yes])
 309                         ;;
 310                 linux-glibc)
 311                         dnl http://www.v6.linux.or.jp/
 312                         AC_EGREP_CPP(yes,
 313 [#include <features.h>
 314 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 315 yes
 316 #endif],
 317                                 [ipv6type=$i])
 318                         ;;
 319                 linux-libinet6)
 320                         dnl http://www.v6.linux.or.jp/
 321                         dnl
 322                         dnl This also matches Solaris 8 and Tru64 UNIX 5.1,
 323                         dnl and possibly other versions of those OSes
 324                         dnl
 325                         if test -d /usr/inet6 -o -f /usr/include/netinet/ip6.h; then
 326                                 ipv6type=$i
 327                                 ipv6lib=inet6
 328                                 ipv6libdir=/usr/inet6/lib
 329                                 ipv6trylibc=yes;
 330                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 331                         fi
 332                         ;;
 333                 toshiba)
 334                         AC_EGREP_CPP(yes,
 335 [#include <sys/param.h>
 336 #ifdef _TOSHIBA_INET6
 337 yes
 338 #endif],
 339                                 [ipv6type=$i;
 340                                 ipv6lib=inet6;
 341                                 ipv6libdir=/usr/local/v6/lib])
 342                         ;;
 343                 v6d)
 344                         AC_EGREP_CPP(yes,
 345 [#include </usr/local/v6/include/sys/v6config.h>
 346 #ifdef __V6D__
 347 yes
 348 #endif],
 349                                 [ipv6type=$i;
 350                                 ipv6lib=v6;
 351                                 ipv6libdir=/usr/local/v6/lib;
 352                                 CFLAGS="-I/usr/local/v6/include $CFLAGS"])
 353                         ;;
 354                 zeta)
 355                         AC_EGREP_CPP(yes,
 356 [#include <sys/param.h>
 357 #ifdef _ZETA_MINAMI_INET6
 358 yes
 359 #endif],
 360                                 [ipv6type=$i;
 361                                 ipv6lib=inet6;
 362                                 ipv6libdir=/usr/local/v6/lib])
 363                         ;;
 364                 esac
 365                 if test "$ipv6type" != "unknown"; then
 366                         break
 367                 fi
 368         done
 369         AC_MSG_RESULT($ipv6type)
 370 fi
 371
 372 if test "$ipv6" = "yes" -a "$ipv6lib" != "none"; then
 373         if test -d $ipv6libdir -a -f $ipv6libdir/lib$ipv6lib.a; then
 374                 LIBS="-L$ipv6libdir -l$ipv6lib $LIBS"
 375                 echo "You have $ipv6lib library, using it"
 376         else
 377                 if test "$ipv6trylibc" = "yes"; then
 378                         echo "You do not have $ipv6lib library, using libc"
 379                 else
 380                         echo 'Fatal: no $ipv6lib library found.  cannot continue.'
 381                         echo "You need to fetch lib$ipv6lib.a from appropriate"
 382                         echo 'ipv6 kit and compile beforehand.'
 383                         exit 1
 384                 fi
 385         fi
 386 fi
 387
 388 AC_REPLACE_FUNCS(strlcat strlcpy strdup strsep getservent getopt_long)
 389 AC_CHECK_FUNCS(fork vfork)
 390 AC_CHECK_FUNCS(setlinebuf)
 391
 392 #
 393 # Make sure we have snprintf(); we require it.
 394 #
 395 AC_CHECK_FUNC(snprintf,,
 396     AC_MSG_ERROR([snprintf() is required but wasn't found]))
 397
 398 #
 399 # It became apparent at some point that using a suitable C99 compiler does not
 400 # automatically mean snprintf(3) implementation in the libc supports all the
 401 # modifiers and specifiers used in the project, so let's test that before the
 402 # build, not after.
 403 #
 404 # Testing the sizeof_t length modifier takes making an snprintf() call and
 405 # comparing the actual result with the expected result.  If this fails, it will
 406 # most likely happen at run time, not compile time.
 407 #
 408 # Testing the 64-bit conversion specifiers in addition to that requires the
 409 # <inttypes.h> header to be present and the macros to be defined, so if this
 410 # fails, it will more likely happen at compile time.
 411 #
 412 AC_MSG_CHECKING([whether snprintf is suitable])
 413 AC_RUN_IFELSE(
 414     [
 415         AC_LANG_SOURCE([[
 416 #include <stdio.h>
 417 #include <string.h>
 418 #include <inttypes.h>
 419 #include <sys/types.h>
 420
 421 int main()
 422 {
 423   char buf[100];
 424   uint64_t t = (uint64_t)1 << 32;
 425
 426   snprintf(buf, sizeof(buf), "%zu", sizeof(buf));
 427   if (strncmp(buf, "100", sizeof(buf)))
 428     return 1;
 429
 430   snprintf(buf, sizeof(buf), "%zd", -sizeof(buf));
 431   if (strncmp(buf, "-100", sizeof(buf)))
 432     return 2;
 433
 434   snprintf(buf, sizeof(buf), "%" PRId64, -t);
 435   if (strncmp(buf, "-4294967296", sizeof(buf)))
 436     return 3;
 437
 438   snprintf(buf, sizeof(buf), "0o%" PRIo64, t);
 439   if (strncmp(buf, "0o40000000000", sizeof(buf)))
 440     return 4;
 441
 442   snprintf(buf, sizeof(buf), "0x%" PRIx64, t);
 443   if (strncmp(buf, "0x100000000", sizeof(buf)))
 444     return 5;
 445
 446   snprintf(buf, sizeof(buf), "%" PRIu64, t);
 447   if (strncmp(buf, "4294967296", sizeof(buf)))
 448     return 6;
 449
 450   return 0;
 451 }
 452         ]])
 453     ],
 454     [
 455         AC_MSG_RESULT(yes)
 456     ],
 457     [
 458         AC_MSG_RESULT(no)
 459         AC_MSG_ERROR(
 460 [The snprintf(3) implementation in this libc is not suitable,
 461 tcpdump would not work correctly even if it managed to compile.])
 462     ],
 463     [
 464         AC_MSG_RESULT(not while cross-compiling)
 465     ]
 466 )
 467
 468 AC_CHECK_LIB(rpc, main)         dnl It's unclear why we might need -lrpc
 469
 470 dnl Some platforms may need -lnsl for getrpcbynumber.
 471 AC_SEARCH_LIBS(getrpcbynumber, nsl,
 472     AC_DEFINE(HAVE_GETRPCBYNUMBER, 1, [define if you have getrpcbynumber()]))
 473
 474 AC_LBL_LIBPCAP(V_PCAPDEP, V_INCLS)
 475
 476 #
 477 # Check for these after AC_LBL_LIBPCAP, so we link with the appropriate
 478 # libraries (e.g., "-lsocket -lnsl" on Solaris).
 479 #
 480 # You are in a twisty little maze of UN*Xes, all different.
 481 # Some might not have ether_ntohost().
 482 # Some might have it and declare it in <net/ethernet.h>.
 483 # Some might have it and declare it in <netinet/ether.h>
 484 # Some might have it and declare it in <sys/ethernet.h>.
 485 # Some might have it and declare it in <arpa/inet.h>.
 486 # Some might have it and declare it in <netinet/if_ether.h>.
 487 # Some might have it and not declare it in any header file.
 488 #
 489 # Before you is a C compiler.
 490 #
 491 AC_CHECK_FUNCS(ether_ntohost, [
 492     AC_CACHE_CHECK(for buggy ether_ntohost, ac_cv_buggy_ether_ntohost, [
 493         AC_RUN_IFELSE([AC_LANG_SOURCE([[
 494                 #include <netdb.h>
 495                 #include <netinet/ether.h>
 496                 #include <stdlib.h>
 497                 #include <sys/types.h>
 498                 #include <sys/param.h>
 499                 #include <sys/socket.h>
 500
 501                 int
 502                 main(int argc, char **argv)
 503                 {
 504                         u_char ea[6] = { 0xff, 0xff, 0xff, 0xff, 0xff };
 505                         char name[MAXHOSTNAMELEN];
 506
 507                         ether_ntohost(name, (struct ether_addr *)ea);
 508                         exit(0);
 509                 }
 510         ]])
 511         ], [ac_cv_buggy_ether_ntohost=no],
 512            [ac_cv_buggy_ether_ntohost=yes],
 513            [ac_cv_buggy_ether_ntohost="not while cross-compiling"])])
 514     if test "$ac_cv_buggy_ether_ntohost" = "no"; then
 515         AC_DEFINE(USE_ETHER_NTOHOST, 1,
 516             [define if you have ether_ntohost() and it works])
 517     fi
 518 ])
 519 if test "$ac_cv_func_ether_ntohost" = yes -a \
 520     "$ac_cv_buggy_ether_ntohost" = "no"; then
 521         #
 522         # OK, we have ether_ntohost().  Is it declared in <net/ethernet.h>?
 523         #
 524         # This test fails if we don't have <net/ethernet.h> or if we do
 525         # but it doesn't declare ether_ntohost().
 526         #
 527         AC_CHECK_DECL(ether_ntohost,
 528             [
 529                 AC_DEFINE(NET_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
 530                     [Define to 1 if net/ethernet.h declares `ether_ntohost'])
 531             ],,
 532             [
 533 #include <net/ethernet.h>
 534             ])
 535         #
 536         # Did that succeed?
 537         #
 538         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 539                 #
 540                 # No, how about <netinet/ether.h>, as on Linux?
 541                 #
 542                 # This test fails if we don't have <netinet/ether.h>
 543                 # or if we do but it doesn't declare ether_ntohost().
 544                 #
 545                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 546                 # treat the previous failure as a cached value and
 547                 # suppress the next test.
 548                 #
 549                 unset ac_cv_have_decl_ether_ntohost
 550                 AC_CHECK_DECL(ether_ntohost,
 551                     [
 552                         AC_DEFINE(NETINET_ETHER_H_DECLARES_ETHER_NTOHOST,,
 553                             [Define to 1 if netinet/ether.h declares `ether_ntohost'])
 554                     ],,
 555                     [
 556 #include <netinet/ether.h>
 557                     ])
 558         fi
 559         #
 560         # Did that succeed?
 561         #
 562         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 563                 #
 564                 # No, how about <sys/ethernet.h>, as on Solaris 10
 565                 # and later?
 566                 #
 567                 # This test fails if we don't have <sys/ethernet.h>
 568                 # or if we do but it doesn't declare ether_ntohost().
 569                 #
 570                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 571                 # treat the previous failure as a cached value and
 572                 # suppress the next test.
 573                 #
 574                 unset ac_cv_have_decl_ether_ntohost
 575                 AC_CHECK_DECL(ether_ntohost,
 576                     [
 577                         AC_DEFINE(SYS_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
 578                             [Define to 1 if sys/ethernet.h declares `ether_ntohost'])
 579                     ],,
 580                     [
 581 #include <sys/ethernet.h>
 582                     ])
 583         fi
 584         #
 585         # Did that succeed?
 586         #
 587         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 588                 #
 589                 # No, how about <arpa/inet.h>, as in AIX?
 590                 #
 591                 # This test fails if we don't have <arpa/inet.h>
 592                 # (if we have ether_ntohost(), we should have
 593                 # networking, and if we have networking, we should
 594                 # have <arpa/inet.h>) or if we do but it doesn't
 595                 # declare ether_ntohost().
 596                 #
 597                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 598                 # treat the previous failure as a cached value and
 599                 # suppress the next test.
 600                 #
 601                 unset ac_cv_have_decl_ether_ntohost
 602                 AC_CHECK_DECL(ether_ntohost,
 603                     [
 604                         AC_DEFINE(ARPA_INET_H_DECLARES_ETHER_NTOHOST,,
 605                             [Define to 1 if arpa/inet.h declares `ether_ntohost'])
 606                     ],,
 607                     [
 608 #include <arpa/inet.h>
 609                     ])
 610         fi
 611         #
 612         # Did that succeed?
 613         #
 614         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 615                 #
 616                 # No, how about <netinet/if_ether.h>?
 617                 # On some platforms, it requires <net/if.h> and
 618                 # <netinet/in.h>, and we always include it with
 619                 # both of them, so test it with both of them.
 620                 #
 621                 # This test fails if we don't have <netinet/if_ether.h>
 622                 # and the headers we include before it, or if we do but
 623                 # <netinet/if_ether.h> doesn't declare ether_hostton().
 624                 #
 625                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 626                 # treat the previous failure as a cached value and
 627                 # suppress the next test.
 628                 #
 629                 unset ac_cv_have_decl_ether_ntohost
 630                 AC_CHECK_DECL(ether_ntohost,
 631                     [
 632                         AC_DEFINE(NETINET_IF_ETHER_H_DECLARES_ETHER_NTOHOST,,
 633                             [Define to 1 if netinet/if_ether.h declares `ether_ntohost'])
 634                     ],,
 635                     [
 636 #include <sys/types.h>
 637 #include <sys/socket.h>
 638 #include <net/if.h>
 639 #include <netinet/in.h>
 640 #include <netinet/if_ether.h>
 641                     ])
 642         fi
 643         #
 644         # After all that, is ether_ntohost() declared?
 645         #
 646         if test "$ac_cv_have_decl_ether_ntohost" = yes; then
 647                 #
 648                 # Yes.
 649                 #
 650                 AC_DEFINE(HAVE_DECL_ETHER_NTOHOST, 1,
 651                     [Define to 1 if you have the declaration of `ether_ntohost'])
 652         else
 653                 #
 654                 # No, we'll have to declare it ourselves.
 655                 # Do we have "struct ether_addr" if we include
 656                 # <netinet/if_ether.h>?
 657                 #
 658                 AC_CHECK_TYPES(struct ether_addr,,,
 659                     [
 660                         #include <sys/types.h>
 661                         #include <sys/socket.h>
 662                         #include <net/if.h>
 663                         #include <netinet/in.h>
 664                         #include <netinet/if_ether.h>
 665                     ])
 666         fi
 667 fi
 668
 669 dnl
 670 dnl Check for "pcap_list_datalinks()" and use a substitute version if
 671 dnl it's not present.  If it is present, check for "pcap_free_datalinks()";
 672 dnl if it's not present, we don't replace it for now.  (We could do so
 673 dnl on UN*X, but not on Windows, where hilarity ensues if a program
 674 dnl built with one version of the MSVC support library tries to free
 675 dnl something allocated by a library built with another version of
 676 dnl the MSVC support library.)
 677 dnl
 678 AC_CHECK_FUNC(pcap_list_datalinks,
 679         [
 680             AC_DEFINE(HAVE_PCAP_LIST_DATALINKS, 1,
 681                 [define if libpcap has pcap_list_datalinks()])
 682             AC_CHECK_FUNCS(pcap_free_datalinks)
 683         ],
 684         [
 685             AC_LIBOBJ(datalinks)
 686         ])
 687
 688 dnl
 689 dnl Check for "pcap_datalink_name_to_val()", and use a substitute
 690 dnl version if it's not present.  If it is present, check for
 691 dnl "pcap_datalink_val_to_description()", and if we don't have it,
 692 dnl use a substitute version.
 693 dnl
 694 AC_CHECK_FUNC(pcap_datalink_name_to_val,
 695         [
 696             AC_DEFINE(HAVE_PCAP_DATALINK_NAME_TO_VAL, 1,
 697                 [define if libpcap has pcap_datalink_name_to_val()])
 698             AC_CHECK_FUNC(pcap_datalink_val_to_description,
 699                 AC_DEFINE(HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION, 1,
 700                     [define if libpcap has pcap_datalink_val_to_description()]),
 701                 [
 702                     AC_LIBOBJ(dlnames)
 703                 ])
 704         ],
 705         [
 706             AC_LIBOBJ(dlnames)
 707         ])
 708
 709 dnl
 710 dnl Check for "pcap_set_datalink()"; you can't substitute for it if
 711 dnl it's absent (it has hooks into libpcap), so just define the
 712 dnl HAVE_ value if it's there.
 713 dnl
 714 AC_CHECK_FUNCS(pcap_set_datalink)
 715
 716 dnl
 717 dnl Check for "pcap_breakloop()"; you can't substitute for it if
 718 dnl it's absent (it has hooks into the live capture routines),
 719 dnl so just define the HAVE_ value if it's there.
 720 dnl
 721 AC_CHECK_FUNCS(pcap_breakloop)
 722
 723 #
 724 # Do we have the new open API?  Check for pcap_create, and assume that,
 725 # if we do, we also have pcap_activate() and the other new routines
 726 # introduced in libpcap 1.0.0.
 727 #
 728 AC_CHECK_FUNCS(pcap_create)
 729 if test $ac_cv_func_pcap_create = "yes" ; then
 730         #
 731         # OK, do we have pcap_set_tstamp_type?  If so, assume we have
 732         # pcap_list_tstamp_types and pcap_free_tstamp_types as well.
 733         #
 734         AC_CHECK_FUNCS(pcap_set_tstamp_type)
 735         #
 736         # And do we have pcap_set_tstamp_precision?  If so, we assume
 737         # we also have pcap_open_offline_with_tstamp_precision.
 738         #
 739         AC_CHECK_FUNCS(pcap_set_tstamp_precision)
 740 fi
 741
 742 #
 743 # Check for a miscellaneous collection of functions which we use
 744 # if we have them.
 745 #
 746 AC_CHECK_FUNCS(pcap_findalldevs)
 747 if test $ac_cv_func_pcap_findalldevs = "yes" ; then
 748 dnl Check for libpcap having pcap_findalldevs() but the pcap.h header
 749 dnl not having pcap_if_t; some versions of Mac OS X shipped with pcap.h
 750 dnl from 0.6 and libpcap 0.8, so that libpcap had pcap_findalldevs but
 751 dnl pcap.h didn't have pcap_if_t.
 752     savedcppflags="$CPPFLAGS"
 753     CPPFLAGS="$CPPFLAGS $V_INCLS"
 754     AC_CHECK_TYPES(pcap_if_t, , , [#include <pcap.h>])
 755     CPPFLAGS="$savedcppflags"
 756 fi
 757 AC_CHECK_FUNCS(pcap_dump_flush pcap_lib_version)
 758 if test $ac_cv_func_pcap_lib_version = "no" ; then
 759     AC_MSG_CHECKING(whether pcap_version is defined by libpcap)
 760     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
 761         extern char pcap_version[];
 762
 763         return (int)pcap_version;
 764        ]])
 765        ],
 766        [ac_lbl_cv_pcap_version_defined=yes],
 767        [ac_lbl_cv_pcap_version_defined=no])
 768     if test "$ac_lbl_cv_pcap_version_defined" = yes ; then
 769         AC_MSG_RESULT(yes)
 770         AC_DEFINE(HAVE_PCAP_VERSION, 1, [define if libpcap has pcap_version])
 771     else
 772         AC_MSG_RESULT(no)
 773     fi
 774 fi
 775 AC_CHECK_FUNCS(pcap_setdirection pcap_set_immediate_mode pcap_dump_ftell64)
 776 AC_CHECK_FUNCS(pcap_open pcap_findalldevs_ex)
 777 AC_REPLACE_FUNCS(pcap_dump_ftell)
 778
 779 #
 780 # Check for special debugging functions
 781 #
 782 AC_CHECK_FUNCS(pcap_set_parser_debug)
 783 if test "$ac_cv_func_pcap_set_parser_debug" = "no" ; then
 784         #
 785         # OK, we don't have pcap_set_parser_debug() to set the libpcap
 786         # filter expression parser debug flag; can we directly set the
 787         # flag?
 788         AC_MSG_CHECKING(whether pcap_debug is defined by libpcap)
 789         AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
 790                 extern int pcap_debug;
 791
 792                 return pcap_debug;
 793            ]])
 794            ],
 795            [ac_lbl_cv_pcap_debug_defined=yes],
 796            [ac_lbl_cv_pcap_debug_defined=no])
 797         if test "$ac_lbl_cv_pcap_debug_defined" = yes ; then
 798                 AC_MSG_RESULT(yes)
 799                 AC_DEFINE(HAVE_PCAP_DEBUG, 1, [define if libpcap has pcap_debug])
 800         else
 801                 AC_MSG_RESULT(no)
 802                 #
 803                 # OK, what about "yydebug"?
 804                 #
 805                 AC_MSG_CHECKING(whether yydebug is defined by libpcap)
 806                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[
 807                         extern int yydebug;
 808
 809                         return yydebug;
 810                    ]])
 811                    ],
 812                    [ac_lbl_cv_yydebug_defined=yes],
 813                    [ac_lbl_cv_yydebug_defined=no])
 814                 if test "$ac_lbl_cv_yydebug_defined" = yes ; then
 815                         AC_MSG_RESULT(yes)
 816                         AC_DEFINE(HAVE_YYDEBUG, 1, [define if libpcap has yydebug])
 817                 else
 818                         AC_MSG_RESULT(no)
 819                 fi
 820         fi
 821 fi
 822 AC_CHECK_FUNCS(pcap_set_optimizer_debug)
 823 AC_REPLACE_FUNCS(bpf_dump)      dnl moved to libpcap in 0.6
 824
 825 V_GROUP=0
 826 if test -f /etc/group -a ! -z "`grep '^wheel:' /etc/group`" ; then
 827         V_GROUP=wheel
 828 fi
 829 #
 830 # Assume V7/BSD convention for man pages (file formats in section 5,
 831 # miscellaneous info in section 7).
 832 #
 833 MAN_FILE_FORMATS=5
 834 MAN_MISC_INFO=7
 835 case "$host_os" in
 836
 837 aix*)
 838         dnl Workaround to enable certain features
 839         AC_DEFINE(_SUN,1,[define on AIX to get certain functions])
 840         ;;
 841
 842 hpux*)
 843         #
 844         # Use System V conventions for man pages.
 845         #
 846         MAN_FILE_FORMATS=4
 847         MAN_MISC_INFO=5
 848         ;;
 849
 850 irix*)
 851         V_GROUP=sys
 852
 853         #
 854         # Use System V conventions for man pages.
 855         #
 856         MAN_FILE_FORMATS=4
 857         MAN_MISC_INFO=5
 858         ;;
 859
 860 osf*)
 861         V_GROUP=system
 862
 863         #
 864         # Use System V conventions for man pages.
 865         #
 866         MAN_FILE_FORMATS=4
 867         MAN_MISC_INFO=5
 868         ;;
 869
 870 solaris*)
 871         V_GROUP=sys
 872
 873         #
 874         # Use System V conventions for man pages.
 875         #
 876         MAN_FILE_FORMATS=4
 877         MAN_MISC_INFO=5
 878         ;;
 879 esac
 880
 881 if test -f /dev/bpf0 ; then
 882         V_GROUP=bpf
 883 fi
 884
 885 #
 886 # Make sure we have a definition for C99's uintptr_t (regardless of
 887 # whether the environment is a C99 environment or not).
 888 #
 889 AC_TYPE_UINTPTR_T
 890
 891 #
 892 # Check whether we have pcap/pcap-inttypes.h.
 893 # If we do, we use that to get the C99 types defined.
 894 #
 895 savedcppflags="$CPPFLAGS"
 896 CPPFLAGS="$CPPFLAGS $V_INCLS"
 897 AC_CHECK_HEADERS(pcap/pcap-inttypes.h)
 898 CPPFLAGS="$savedcppflags"
 899
 900 #
 901 # Define the old BSD specified-width types in terms of the C99 types;
 902 # we may need them with libpcap include files.
 903 #
 904 AC_CHECK_TYPE([u_int8_t], ,
 905         [AC_DEFINE([u_int8_t], [uint8_t],
 906         [Define to `uint8_t' if u_int8_t not defined.])],
 907         [AC_INCLUDES_DEFAULT
 908 #include <sys/types.h>
 909 ])
 910 AC_CHECK_TYPE([u_int16_t], ,
 911         [AC_DEFINE([u_int16_t], [uint16_t],
 912         [Define to `uint16_t' if u_int16_t not defined.])],
 913         [AC_INCLUDES_DEFAULT
 914 #include <sys/types.h>
 915 ])
 916 AC_CHECK_TYPE([u_int32_t], ,
 917         [AC_DEFINE([u_int32_t], [uint32_t],
 918         [Define to `uint32_t' if u_int32_t not defined.])],
 919         [AC_INCLUDES_DEFAULT
 920 #include <sys/types.h>
 921 ])
 922 AC_CHECK_TYPE([u_int64_t], ,
 923         [AC_DEFINE([u_int64_t], [uint64_t],
 924         [Define to `uint64_t' if u_int64_t not defined.])],
 925         [AC_INCLUDES_DEFAULT
 926 #include <sys/types.h>
 927 ])
 928
 929 AC_PROG_RANLIB
 930 AC_CHECK_TOOL([AR], [ar])
 931
 932 AC_LBL_DEVEL(V_CCOPT)
 933
 934 # Check for OpenSSL/libressl libcrypto
 935 AC_MSG_CHECKING(whether to use OpenSSL/libressl libcrypto)
 936 # Specify location for both includes and libraries.
 937 want_libcrypto=ifavailable
 938 AC_ARG_WITH(crypto,
 939     AS_HELP_STRING([--with-crypto]@<:@=DIR@:>@,
 940                    [use OpenSSL/libressl libcrypto (located in directory DIR, if specified) @<:@default=yes, if available@:>@]),
 941 [
 942         if test $withval = no
 943         then
 944                 # User doesn't want to link with libcrypto.
 945                 want_libcrypto=no
 946                 AC_MSG_RESULT(no)
 947         elif test $withval = yes
 948         then
 949                 # User wants to link with libcrypto but hasn't specified
 950                 # a directory.
 951                 want_libcrypto=yes
 952                 AC_MSG_RESULT(yes)
 953         else
 954                 # User wants to link with libcrypto and has specified
 955                 # a directory, so use the provided value.
 956                 want_libcrypto=yes
 957                 libcrypto_root=$withval
 958                 AC_MSG_RESULT([yes, using the version installed in $withval])
 959
 960                 #
 961                 # Put the subdirectories of the libcrypto root directory
 962                 # at the front of the header and library search path.
 963                 #
 964                 CFLAGS="-I$withval/include $CFLAGS"
 965                 LIBS="-L$withval/lib $LIBS"
 966         fi
 967 ],[
 968         #
 969         # Use libcrypto if it's present, otherwise don't; no directory
 970         # was specified.
 971         #
 972         want_libcrypto=ifavailable
 973         AC_MSG_RESULT([yes, if available])
 974 ])
 975 if test "$want_libcrypto" != "no"; then
 976         #
 977         # Don't check for libcrypto unless we have its headers;
 978         # Apple, bless their pointy little heads, apparently ship
 979         # libcrypto as a library, but not the header files, in
 980         # El Capitan, probably because they don't want you writing
 981         # nasty portable code that could run on other UN*Xes, they
 982         # want you writing code that uses their Shiny New Crypto
 983         # Library and that only runs on macOS.
 984         #
 985         AC_CHECK_HEADER(openssl/crypto.h,
 986         [
 987                 AC_CHECK_LIB(crypto, DES_cbc_encrypt)
 988                 if test "$ac_cv_lib_crypto_DES_cbc_encrypt" = "yes"; then
 989                         AC_CHECK_HEADERS(openssl/evp.h)
 990                         #
 991                         # OK, then:
 992                         #
 993                         # 1) do we have EVP_CIPHER_CTX_new?
 994                         # If so, we use it to allocate an
 995                         # EVP_CIPHER_CTX, as EVP_CIPHER_CTX may be
 996                         # opaque; otherwise, we allocate it ourselves.
 997                         #
 998                         # 2) do we have EVP_DecryptInit_ex()?
 999                         # If so, we use it, because we need to be
1000                         # able to make two "initialize the cipher"
1001                         # calls, one with the cipher and key, and
1002                         # one with the IV, and, as of OpenSSL 1.1,
1003                         # You Can't Do That with EVP_DecryptInit(),
1004                         # because a call to EVP_DecryptInit() will
1005                         # unconditionally clear the context, and
1006                         # if you don't supply a cipher, it'll
1007                         # clear the cipher, rendering the context
1008                         # unusable and causing a crash.
1009                         #
1010                         AC_CHECK_FUNCS(EVP_CIPHER_CTX_new EVP_DecryptInit_ex)
1011                 fi
1012         ])
1013 fi
1014
1015 # Check for libcap-ng
1016 AC_MSG_CHECKING(whether to use libcap-ng)
1017 # Specify location for both includes and libraries.
1018 want_libcap_ng=ifavailable
1019 AC_ARG_WITH(cap_ng,
1020     AS_HELP_STRING([--with-cap-ng],
1021                    [use libcap-ng @<:@default=yes, if available@:>@]),
1022 [
1023         if test $withval = no
1024         then
1025                 want_libcap_ng=no
1026                 AC_MSG_RESULT(no)
1027         elif test $withval = yes
1028         then
1029                 want_libcap_ng=yes
1030                 AC_MSG_RESULT(yes)
1031         fi
1032 ],[
1033         #
1034         # Use libcap-ng if it's present, otherwise don't.
1035         #
1036         want_libcap_ng=ifavailable
1037         AC_MSG_RESULT([yes, if available])
1038 ])
1039 if test "$want_libcap_ng" != "no"; then
1040         AC_CHECK_LIB(cap-ng, capng_change_id)
1041         AC_CHECK_HEADERS(cap-ng.h)
1042 fi
1043
1044 dnl
1045 dnl set additional include path if necessary
1046 if test "$missing_includes" = "yes"; then
1047         CPPFLAGS="$CPPFLAGS -I$srcdir/missing"
1048         V_INCLS="$V_INCLS -I$srcdir/missing"
1049 fi
1050
1051 AC_SUBST(V_CCOPT)
1052 AC_SUBST(V_DEFS)
1053 AC_SUBST(V_GROUP)
1054 AC_SUBST(V_INCLS)
1055 AC_SUBST(V_PCAPDEP)
1056 AC_SUBST(LOCALSRC)
1057 AC_SUBST(MAN_FILE_FORMATS)
1058 AC_SUBST(MAN_MISC_INFO)
1059
1060 AC_PROG_INSTALL
1061
1062 AC_CONFIG_HEADER(config.h)
1063
1064 AC_CONFIG_COMMANDS([.devel],[[if test -f .devel; then
1065         echo timestamp > stamp-h
1066         cat $srcdir/Makefile-devel-adds >> Makefile
1067         make depend || exit 1
1068 fi]],[[]])
1069 AC_CONFIG_FILES([Makefile tcpdump.1])
1070 AC_OUTPUT
1071 exit 0