The Tcpdump Group git mirrors - tcpdump/blob - configure.ac

   1 dnl Copyright (c) 1994, 1995, 1996, 1997
   2 dnl     The Regents of the University of California.  All rights reserved.
   3 dnl
   4 dnl Process this file with autoconf to produce a configure script.
   5 dnl
   6
   7 #
   8 # See
   9 #
  10 #       https://ftp.gnu.org/gnu/config/README
  11 #
  12 # for the URLs to use to fetch new versions of config.guess and
  13 # config.sub.
  14 #
  15
  16 AC_PREREQ(2.64)
  17 AC_INIT(tcpdump, m4_esyscmd_s([cat VERSION]))
  18 AC_CONFIG_SRCDIR(tcpdump.c)
  19
  20 AC_CANONICAL_HOST
  21
  22 AC_LBL_C_INIT_BEFORE_CC(V_INCLS)
  23 #
  24 # Try to enable as many C99 features as we can.
  25 # At minimum, we want C++/C99-style // comments.
  26 #
  27 AC_PROG_CC_C99
  28 if test "$ac_cv_prog_cc_c99" = "no"; then
  29         AC_MSG_WARN([The C compiler does not support C99; there may be compiler errors])
  30 fi
  31 AC_LBL_C_INIT(V_CCOPT, V_INCLS)
  32 AC_LBL_C_INLINE
  33
  34 AC_CHECK_HEADERS(fcntl.h rpc/rpc.h rpc/rpcent.h net/if.h)
  35 AC_CHECK_HEADERS(net/pfvar.h, , , [#include <sys/types.h>
  36 #include <sys/socket.h>
  37 #include <net/if.h>])
  38 if test "$ac_cv_header_net_pfvar_h" = yes; then
  39         AC_CHECK_HEADERS(net/if_pflog.h, , , [#include <sys/types.h>
  40         #include <sys/socket.h>
  41         #include <net/if.h>
  42         #include <net/pfvar.h>])
  43         if test "$ac_cv_header_net_if_pflog_h" = yes; then
  44                 LOCALSRC="print-pflog.c $LOCALSRC"
  45         fi
  46 fi
  47
  48 case "$host_os" in
  49
  50 darwin*)
  51         AC_ARG_ENABLE(universal,
  52         AC_HELP_STRING([--disable-universal],[don't build universal on macOS]))
  53         if test "$enable_universal" != "no"; then
  54                 case "$host_os" in
  55
  56                 darwin9.*)
  57                         #
  58                         # Leopard.  Build for x86 and 32-bit PowerPC, with
  59                         # x86 first.  (That's what Apple does.)
  60                         #
  61                         V_CCOPT="$V_CCOPT -arch i386 -arch ppc"
  62                         LDFLAGS="$LDFLAGS -arch i386 -arch ppc"
  63                         ;;
  64
  65                 darwin10.*)
  66                         #
  67                         # Snow Leopard.  Build for x86-64 and x86, with
  68                         # x86-64 first.  (That's what Apple does.)
  69                         #
  70                         V_CCOPT="$V_CCOPT -arch x86_64 -arch i386"
  71                         LDFLAGS="$LDFLAGS -arch x86_64 -arch i386"
  72                         ;;
  73                 esac
  74         fi
  75         ;;
  76 esac
  77
  78
  79 AC_ARG_WITH(smi,
  80 [  --with-smi              link with libsmi (allows to load MIBs on the fly to decode SNMP packets. [default=yes]
  81   --without-smi           don't link with libsmi],,
  82    with_smi=yes)
  83
  84 if test "x$with_smi" != "xno" ; then
  85         AC_CHECK_HEADER(smi.h,
  86         [
  87                 #
  88                 # OK, we found smi.h.  Do we have libsmi with smiInit?
  89                 #
  90                 AC_CHECK_LIB(smi, smiInit,
  91                 [
  92                         #
  93                         # OK, we have libsmi with smiInit.  Can we use it?
  94                         #
  95                         AC_MSG_CHECKING([whether to enable libsmi])
  96                         savedlibs="$LIBS"
  97                         LIBS="-lsmi $LIBS"
  98                         AC_TRY_RUN(
  99                                 [
 100 /* libsmi available check */
 101 #include <smi.h>
 102 main()
 103 {
 104   int current, revision, age, n;
 105   const int required = 2;
 106   if (smiInit(""))
 107     exit(1);
 108   if (strcmp(SMI_LIBRARY_VERSION, smi_library_version))
 109     exit(2);
 110   n = sscanf(smi_library_version, "%d:%d:%d", &current, &revision, &age);
 111   if (n != 3)
 112     exit(3);
 113   if (required < current - age || required > current)
 114     exit(4);
 115   exit(0);
 116 }
 117                                 ],
 118                                 [
 119                                         AC_MSG_RESULT(yes)
 120                                         AC_DEFINE(USE_LIBSMI, 1,
 121                                             [Define if you enable support for libsmi])
 122                                 ],
 123                                 [
 124                                         dnl autoconf documentation says that
 125                                         dnl $? contains the exit value.
 126                                         dnl reality is that it does not.
 127                                         dnl We leave this in just in case
 128                                         dnl autoconf ever comes back to
 129                                         dnl match the documentation.
 130                                         case $? in
 131                                           1) AC_MSG_RESULT(no - smiInit failed) ;;
 132                                           2) AC_MSG_RESULT(no - header/library version mismatch) ;;
 133                                           3) AC_MSG_RESULT(no - can't determine library version) ;;
 134                                           4) AC_MSG_RESULT(no - too old) ;;
 135                                           *) AC_MSG_RESULT(no) ;;
 136                                         esac
 137                                         LIBS="$savedlibs"
 138                                 ],
 139                                 [
 140                                         AC_MSG_RESULT(not when cross-compiling)
 141                                         LIBS="$savedlibs"
 142                                 ]
 143                         )
 144                 ])
 145         ])
 146 fi
 147
 148 AC_MSG_CHECKING([whether to enable the possibly-buggy SMB printer])
 149 AC_ARG_ENABLE(smb,
 150 [  --enable-smb            enable possibly-buggy SMB printer [default=no]
 151   --disable-smb           disable possibly-buggy SMB printer],,
 152    enableval=no)
 153 case "$enableval" in
 154 yes)    AC_MSG_RESULT(yes)
 155         AC_DEFINE(ENABLE_SMB, 1,
 156             [define if you want to build the possibly-buggy SMB printer])
 157         LOCALSRC="print-smb.c smbutil.c $LOCALSRC"
 158         ;;
 159 *)      AC_MSG_RESULT(no)
 160         ;;
 161 esac
 162
 163 AC_ARG_WITH(user, [  --with-user=USERNAME    drop privileges by default to USERNAME])
 164 AC_MSG_CHECKING([whether to drop root privileges by default])
 165 if test ! -z "$with_user" ; then
 166        AC_DEFINE_UNQUOTED(WITH_USER, "$withval",
 167            [define if should drop privileges by default])
 168        AC_MSG_RESULT(to \"$withval\")
 169 else
 170        AC_MSG_RESULT(no)
 171 fi
 172
 173 AC_ARG_WITH(chroot, [  --with-chroot=DIRECTORY when dropping privileges, chroot to DIRECTORY])
 174 AC_MSG_CHECKING([whether to chroot])
 175 if test ! -z "$with_chroot" && test "$with_chroot" != "no" ; then
 176        AC_DEFINE_UNQUOTED(WITH_CHROOT, "$withval",
 177            [define if should chroot when dropping privileges])
 178        AC_MSG_RESULT(to \"$withval\")
 179 else
 180        AC_MSG_RESULT(no)
 181 fi
 182
 183 AC_ARG_WITH(sandbox-capsicum,
 184         AS_HELP_STRING([--with-sandbox-capsicum],
 185                        [use Capsicum security functions @<:@default=yes, if available@:>@]))
 186 #
 187 # Check whether various functions are available.  If any are, set
 188 # ac_lbl_capsicum_function_seen to yes; if any are not, set
 189 # ac_lbl_capsicum_function_not_seen to yes.
 190 #
 191 # We don't check cap_rights_init(), as it's a macro, wrapping another
 192 # function, in at least some versions of FreeBSD, and AC_CHECK_FUNCS()
 193 # doesn't handle that.
 194 #
 195 # All of the ones we check for must be available in order to enable
 196 # capsicum sandboxing.
 197 #
 198 # XXX - do we need to check for all of them, or are there some that, if
 199 # present, imply others are present?
 200 #
 201 if test -z "$with_sandbox_capsicum" || test "$with_sandbox_capsicum" != "no" ; then
 202         #
 203         # First, make sure we have the required header.
 204         #
 205         AC_CHECK_HEADER(sys/capsicum.h,
 206         [
 207                 #
 208                 # We do; now make sure we have the required functions.
 209                 #
 210                 AC_CHECK_FUNCS(cap_enter cap_rights_limit cap_ioctls_limit openat,
 211                     ac_lbl_capsicum_function_seen=yes,
 212                     ac_lbl_capsicum_function_not_seen=yes)
 213         ])
 214         AC_CHECK_LIB(casper, cap_init, LIBS="$LIBS -lcasper")
 215         AC_CHECK_LIB(cap_dns, cap_gethostbyaddr, LIBS="$LIBS -lcap_dns")
 216 fi
 217 AC_MSG_CHECKING([whether to sandbox using capsicum])
 218 if test "x$ac_lbl_capsicum_function_seen" = "xyes" -a "x$ac_lbl_capsicum_function_not_seen" != "xyes"; then
 219         AC_DEFINE(HAVE_CAPSICUM, 1, [capsicum support available])
 220         AC_MSG_RESULT(yes)
 221 else
 222         AC_MSG_RESULT(no)
 223 fi
 224 AC_MSG_CHECKING([whether to sandbox using Casper library])
 225 if test "x$ac_cv_lib_casper_cap_init" = "xyes" -a "x$ac_cv_lib_cap_dns_cap_gethostbyaddr" = "xyes"; then
 226         AC_DEFINE(HAVE_CASPER, 1, [Casper support available])
 227         AC_MSG_RESULT(yes)
 228 else
 229         AC_MSG_RESULT(no)
 230 fi
 231
 232 #
 233 # We must check this before checking whether to check the OS's IPv6,
 234 # support because, on some platforms (such as SunOS 5.x), the test
 235 # program requires the extra networking libraries.
 236 #
 237 AC_LBL_LIBRARY_NET
 238
 239 #
 240 # Check whether AF_INET6 and struct in6_addr are defined.
 241 # If they aren't both defined, we don't have sufficient OS
 242 # support for IPv6, so we don't look for IPv6 support libraries,
 243 # and we define AF_INET6 and struct in6_addr ourselves.
 244 #
 245 AC_MSG_CHECKING([whether the operating system supports IPv6])
 246 AC_COMPILE_IFELSE(
 247     [
 248       AC_LANG_SOURCE(
 249         [[
 250 /* AF_INET6 available check */
 251 #include <sys/types.h>
 252 #ifdef _WIN32
 253 #include <ws2tcpip.h>
 254 #else
 255 #include <sys/socket.h>
 256 #include <netinet/in.h>
 257 #endif
 258 #ifdef AF_INET6
 259 void
 260 foo(struct in6_addr *addr)
 261 {
 262  memset(addr, 0, sizeof (struct in6_addr));
 263 }
 264 #else
 265 #error "AF_INET6 not defined"
 266 #endif
 267         ]])
 268     ],
 269     [
 270         AC_MSG_RESULT(yes)
 271         AC_DEFINE(HAVE_OS_IPV6_SUPPORT, 1,
 272             [define if the OS provides AF_INET6 and struct in6_addr])
 273         ipv6=yes
 274     ],
 275     [
 276         AC_MSG_RESULT(no)
 277         ipv6=no
 278     ]
 279 )
 280
 281 ipv6type=unknown
 282 ipv6lib=none
 283 ipv6trylibc=no
 284
 285 if test "$ipv6" = "yes"; then
 286         AC_MSG_CHECKING([ipv6 stack type])
 287         for i in inria kame linux-glibc linux-libinet6 toshiba v6d zeta; do
 288                 case $i in
 289                 inria)
 290                         dnl http://www.kame.net/
 291                         AC_EGREP_CPP(yes,
 292 [#include <netinet/in.h>
 293 #ifdef IPV6_INRIA_VERSION
 294 yes
 295 #endif],
 296                                 [ipv6type=$i])
 297                         ;;
 298                 kame)
 299                         dnl http://www.kame.net/
 300                         AC_EGREP_CPP(yes,
 301 [#include <netinet/in.h>
 302 #ifdef __KAME__
 303 yes
 304 #endif],
 305                                 [ipv6type=$i;
 306                                 ipv6lib=inet6;
 307                                 ipv6libdir=/usr/local/v6/lib;
 308                                 ipv6trylibc=yes])
 309                         ;;
 310                 linux-glibc)
 311                         dnl http://www.v6.linux.or.jp/
 312                         AC_EGREP_CPP(yes,
 313 [#include <features.h>
 314 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 315 yes
 316 #endif],
 317                                 [ipv6type=$i])
 318                         ;;
 319                 linux-libinet6)
 320                         dnl http://www.v6.linux.or.jp/
 321                         dnl
 322                         dnl This also matches Solaris 8 and Tru64 UNIX 5.1,
 323                         dnl and possibly other versions of those OSes
 324                         dnl
 325                         if test -d /usr/inet6 -o -f /usr/include/netinet/ip6.h; then
 326                                 ipv6type=$i
 327                                 ipv6lib=inet6
 328                                 ipv6libdir=/usr/inet6/lib
 329                                 ipv6trylibc=yes;
 330                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 331                         fi
 332                         ;;
 333                 toshiba)
 334                         AC_EGREP_CPP(yes,
 335 [#include <sys/param.h>
 336 #ifdef _TOSHIBA_INET6
 337 yes
 338 #endif],
 339                                 [ipv6type=$i;
 340                                 ipv6lib=inet6;
 341                                 ipv6libdir=/usr/local/v6/lib])
 342                         ;;
 343                 v6d)
 344                         AC_EGREP_CPP(yes,
 345 [#include </usr/local/v6/include/sys/v6config.h>
 346 #ifdef __V6D__
 347 yes
 348 #endif],
 349                                 [ipv6type=$i;
 350                                 ipv6lib=v6;
 351                                 ipv6libdir=/usr/local/v6/lib;
 352                                 CFLAGS="-I/usr/local/v6/include $CFLAGS"])
 353                         ;;
 354                 zeta)
 355                         AC_EGREP_CPP(yes,
 356 [#include <sys/param.h>
 357 #ifdef _ZETA_MINAMI_INET6
 358 yes
 359 #endif],
 360                                 [ipv6type=$i;
 361                                 ipv6lib=inet6;
 362                                 ipv6libdir=/usr/local/v6/lib])
 363                         ;;
 364                 esac
 365                 if test "$ipv6type" != "unknown"; then
 366                         break
 367                 fi
 368         done
 369         AC_MSG_RESULT($ipv6type)
 370 fi
 371
 372 if test "$ipv6" = "yes" -a "$ipv6lib" != "none"; then
 373         if test -d $ipv6libdir -a -f $ipv6libdir/lib$ipv6lib.a; then
 374                 LIBS="-L$ipv6libdir -l$ipv6lib $LIBS"
 375                 echo "You have $ipv6lib library, using it"
 376         else
 377                 if test "$ipv6trylibc" = "yes"; then
 378                         echo "You do not have $ipv6lib library, using libc"
 379                 else
 380                         echo 'Fatal: no $ipv6lib library found.  cannot continue.'
 381                         echo "You need to fetch lib$ipv6lib.a from appropriate"
 382                         echo 'ipv6 kit and compile beforehand.'
 383                         exit 1
 384                 fi
 385         fi
 386 fi
 387
 388 AC_REPLACE_FUNCS(strlcat strlcpy strdup strsep getservent getopt_long)
 389 AC_CHECK_FUNCS(fork vfork strftime)
 390 AC_CHECK_FUNCS(setlinebuf)
 391
 392 #
 393 # Make sure we have vsnprintf() and snprintf(); we require them.
 394 #
 395 AC_CHECK_FUNC(vsnprintf,,
 396     AC_MSG_ERROR([vsnprintf() is required but wasn't found]))
 397 AC_CHECK_FUNC(snprintf,,
 398     AC_MSG_ERROR([snprintf() is required but wasn't found]))
 399
 400 #
 401 # Define HAVE_NO_PRINTF_Z to make it possible to disable test cases that
 402 # depend on %zu.
 403 #
 404 AC_MSG_CHECKING([whether printf(3) supports the z length modifier])
 405 AC_RUN_IFELSE(
 406     [
 407         AC_LANG_SOURCE([[
 408 #include <stdio.h>
 409 #include <string.h>
 410
 411 int main()
 412 {
 413   char buf[100];
 414   snprintf(buf, sizeof(buf), "%zu", sizeof(buf));
 415   return strncmp(buf, "100", sizeof(buf)) ? 1 : 0;
 416 }
 417         ]])
 418     ],
 419     [
 420         AC_MSG_RESULT(yes)
 421     ],
 422     [
 423         AC_MSG_RESULT(no)
 424         AC_DEFINE(HAVE_NO_PRINTF_Z, 1,
 425             [Define to 1 if printf(3) does not support the z length modifier.])
 426     ]
 427 )
 428
 429 AC_CHECK_LIB(rpc, main)         dnl It's unclear why we might need -lrpc
 430
 431 dnl Some platforms may need -lnsl for getrpcbynumber.
 432 AC_SEARCH_LIBS(getrpcbynumber, nsl,
 433     AC_DEFINE(HAVE_GETRPCBYNUMBER, 1, [define if you have getrpcbynumber()]))
 434
 435 AC_LBL_LIBPCAP(V_PCAPDEP, V_INCLS)
 436
 437 #
 438 # Check for these after AC_LBL_LIBPCAP, so we link with the appropriate
 439 # libraries (e.g., "-lsocket -lnsl" on Solaris).
 440 #
 441 # You are in a twisty little maze of UN*Xes, all different.
 442 # Some might not have ether_ntohost().
 443 # Some might have it and declare it in <net/ethernet.h>.
 444 # Some might have it and declare it in <netinet/ether.h>
 445 # Some might have it and declare it in <sys/ethernet.h>.
 446 # Some might have it and declare it in <arpa/inet.h>.
 447 # Some might have it and declare it in <netinet/if_ether.h>.
 448 # Some might have it and not declare it in any header file.
 449 #
 450 # Before you is a C compiler.
 451 #
 452 AC_CHECK_FUNCS(ether_ntohost, [
 453     AC_CACHE_CHECK(for buggy ether_ntohost, ac_cv_buggy_ether_ntohost, [
 454         AC_TRY_RUN([
 455                 #include <netdb.h>
 456                 #include <sys/types.h>
 457                 #include <sys/param.h>
 458                 #include <sys/socket.h>
 459
 460                 int
 461                 main(int argc, char **argv)
 462                 {
 463                         u_char ea[6] = { 0xff, 0xff, 0xff, 0xff, 0xff };
 464                         char name[MAXHOSTNAMELEN];
 465
 466                         ether_ntohost(name, (struct ether_addr *)ea);
 467                         exit(0);
 468                 }
 469         ], [ac_cv_buggy_ether_ntohost=no],
 470            [ac_cv_buggy_ether_ntohost=yes],
 471            [ac_cv_buggy_ether_ntohost="not while cross-compiling"])])
 472     if test "$ac_cv_buggy_ether_ntohost" = "no"; then
 473         AC_DEFINE(USE_ETHER_NTOHOST, 1,
 474             [define if you have ether_ntohost() and it works])
 475     fi
 476 ])
 477 if test "$ac_cv_func_ether_ntohost" = yes -a \
 478     "$ac_cv_buggy_ether_ntohost" = "no"; then
 479         #
 480         # OK, we have ether_ntohost().  Is it declared in <net/ethernet.h>?
 481         #
 482         # This test fails if we don't have <net/ethernet.h> or if we do
 483         # but it doesn't declare ether_ntohost().
 484         #
 485         AC_CHECK_DECL(ether_ntohost,
 486             [
 487                 AC_DEFINE(NET_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
 488                     [Define to 1 if net/ethernet.h declares `ether_ntohost'])
 489             ],,
 490             [
 491 #include <net/ethernet.h>
 492             ])
 493         #
 494         # Did that succeed?
 495         #
 496         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 497                 #
 498                 # No, how about <netinet/ether.h>, as on Linux?
 499                 #
 500                 # This test fails if we don't have <netinet/ether.h>
 501                 # or if we do but it doesn't declare ether_ntohost().
 502                 #
 503                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 504                 # treat the previous failure as a cached value and
 505                 # suppress the next test.
 506                 #
 507                 unset ac_cv_have_decl_ether_ntohost
 508                 AC_CHECK_DECL(ether_ntohost,
 509                     [
 510                         AC_DEFINE(NETINET_ETHER_H_DECLARES_ETHER_NTOHOST,,
 511                             [Define to 1 if netinet/ether.h declares `ether_ntohost'])
 512                     ],,
 513                     [
 514 #include <netinet/ether.h>
 515                     ])
 516         fi
 517         #
 518         # Did that succeed?
 519         #
 520         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 521                 #
 522                 # No, how about <sys/ethernet.h>, as on Solaris 10
 523                 # and later?
 524                 #
 525                 # This test fails if we don't have <sys/ethernet.h>
 526                 # or if we do but it doesn't declare ether_ntohost().
 527                 #
 528                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 529                 # treat the previous failure as a cached value and
 530                 # suppress the next test.
 531                 #
 532                 unset ac_cv_have_decl_ether_ntohost
 533                 AC_CHECK_DECL(ether_ntohost,
 534                     [
 535                         AC_DEFINE(SYS_ETHERNET_H_DECLARES_ETHER_NTOHOST,,
 536                             [Define to 1 if sys/ethernet.h declares `ether_ntohost'])
 537                     ],,
 538                     [
 539 #include <sys/ethernet.h>
 540                     ])
 541         fi
 542         #
 543         # Did that succeed?
 544         #
 545         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 546                 #
 547                 # No, how about <arpa/inet.h>, as in AIX?
 548                 #
 549                 # This test fails if we don't have <arpa/inet.h>
 550                 # (if we have ether_ntohost(), we should have
 551                 # networking, and if we have networking, we should
 552                 # have <arpa/inet.h>) or if we do but it doesn't
 553                 # declare ether_ntohost().
 554                 #
 555                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 556                 # treat the previous failure as a cached value and
 557                 # suppress the next test.
 558                 #
 559                 unset ac_cv_have_decl_ether_ntohost
 560                 AC_CHECK_DECL(ether_ntohost,
 561                     [
 562                         AC_DEFINE(ARPA_INET_H_DECLARES_ETHER_NTOHOST,,
 563                             [Define to 1 if arpa/inet.h declares `ether_ntohost'])
 564                     ],,
 565                     [
 566 #include <arpa/inet.h>
 567                     ])
 568         fi
 569         #
 570         # Did that succeed?
 571         #
 572         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 573                 #
 574                 # No, how about <netinet/if_ether.h>?
 575                 # On some platforms, it requires <net/if.h> and
 576                 # <netinet/in.h>, and we always include it with
 577                 # both of them, so test it with both of them.
 578                 #
 579                 # This test fails if we don't have <netinet/if_ether.h>
 580                 # and the headers we include before it, or if we do but
 581                 # <netinet/if_ether.h> doesn't declare ether_hostton().
 582                 #
 583                 # Unset ac_cv_have_decl_ether_ntohost so we don't
 584                 # treat the previous failure as a cached value and
 585                 # suppress the next test.
 586                 #
 587                 unset ac_cv_have_decl_ether_ntohost
 588                 AC_CHECK_DECL(ether_ntohost,
 589                     [
 590                         AC_DEFINE(NETINET_IF_ETHER_H_DECLARES_ETHER_NTOHOST,,
 591                             [Define to 1 if netinet/if_ether.h declares `ether_ntohost'])
 592                     ],,
 593                     [
 594 #include <sys/types.h>
 595 #include <sys/socket.h>
 596 #include <net/if.h>
 597 #include <netinet/in.h>
 598 #include <netinet/if_ether.h>
 599                     ])
 600         fi
 601         #
 602         # After all that, is ether_ntohost() declared?
 603         #
 604         if test "$ac_cv_have_decl_ether_ntohost" = yes; then
 605                 #
 606                 # Yes.
 607                 #
 608                 AC_DEFINE(HAVE_DECL_ETHER_NTOHOST, 1,
 609                     [Define to 1 if you have the declaration of `ether_ntohost'])
 610         else
 611                 #
 612                 # No, we'll have to declare it ourselves.
 613                 # Do we have "struct ether_addr" if we include
 614                 # <netinet/if_ether.h>?
 615                 #
 616                 AC_CHECK_TYPES(struct ether_addr,,,
 617                     [
 618                         #include <sys/types.h>
 619                         #include <sys/socket.h>
 620                         #include <net/if.h>
 621                         #include <netinet/in.h>
 622                         #include <netinet/if_ether.h>
 623                     ])
 624         fi
 625 fi
 626
 627 dnl
 628 dnl Check for "pcap_list_datalinks()" and use a substitute version if
 629 dnl it's not present.  If it is present, check for "pcap_free_datalinks()";
 630 dnl if it's not present, we don't replace it for now.  (We could do so
 631 dnl on UN*X, but not on Windows, where hilarity ensues if a program
 632 dnl built with one version of the MSVC support library tries to free
 633 dnl something allocated by a library built with another version of
 634 dnl the MSVC support library.)
 635 dnl
 636 AC_CHECK_FUNC(pcap_list_datalinks,
 637         [
 638             AC_DEFINE(HAVE_PCAP_LIST_DATALINKS, 1,
 639                 [define if libpcap has pcap_list_datalinks()])
 640             AC_CHECK_FUNCS(pcap_free_datalinks)
 641         ],
 642         [
 643             AC_LIBOBJ(datalinks)
 644         ])
 645
 646 dnl
 647 dnl Check for "pcap_datalink_name_to_val()", and use a substitute
 648 dnl version if it's not present.  If it is present, check for
 649 dnl "pcap_datalink_val_to_description()", and if we don't have it,
 650 dnl use a substitute version.
 651 dnl
 652 AC_CHECK_FUNC(pcap_datalink_name_to_val,
 653         [
 654             AC_DEFINE(HAVE_PCAP_DATALINK_NAME_TO_VAL, 1,
 655                 [define if libpcap has pcap_datalink_name_to_val()])
 656             AC_CHECK_FUNC(pcap_datalink_val_to_description,
 657                 AC_DEFINE(HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION, 1,
 658                     [define if libpcap has pcap_datalink_val_to_description()]),
 659                 [
 660                     AC_LIBOBJ(dlnames)
 661                 ])
 662         ],
 663         [
 664             AC_LIBOBJ(dlnames)
 665         ])
 666
 667 dnl
 668 dnl Check for "pcap_set_datalink()"; you can't substitute for it if
 669 dnl it's absent (it has hooks into libpcap), so just define the
 670 dnl HAVE_ value if it's there.
 671 dnl
 672 AC_CHECK_FUNCS(pcap_set_datalink)
 673
 674 dnl
 675 dnl Check for "pcap_breakloop()"; you can't substitute for it if
 676 dnl it's absent (it has hooks into the live capture routines),
 677 dnl so just define the HAVE_ value if it's there.
 678 dnl
 679 AC_CHECK_FUNCS(pcap_breakloop)
 680
 681 #
 682 # Do we have the new open API?  Check for pcap_create, and assume that,
 683 # if we do, we also have pcap_activate() and the other new routines
 684 # introduced in libpcap 1.0.0.
 685 #
 686 AC_CHECK_FUNCS(pcap_create)
 687 if test $ac_cv_func_pcap_create = "yes" ; then
 688         #
 689         # OK, do we have pcap_set_tstamp_type?  If so, assume we have
 690         # pcap_list_tstamp_types and pcap_free_tstamp_types as well.
 691         #
 692         AC_CHECK_FUNCS(pcap_set_tstamp_type)
 693         #
 694         # And do we have pcap_set_tstamp_precision?  If so, we assume
 695         # we also have pcap_open_offline_with_tstamp_precision.
 696         #
 697         AC_CHECK_FUNCS(pcap_set_tstamp_precision)
 698 fi
 699
 700 #
 701 # Check for a miscellaneous collection of functions which we use
 702 # if we have them.
 703 #
 704 AC_CHECK_FUNCS(pcap_findalldevs)
 705 if test $ac_cv_func_pcap_findalldevs = "yes" ; then
 706 dnl Check for libpcap having pcap_findalldevs() but the pcap.h header
 707 dnl not having pcap_if_t; some versions of Mac OS X shipped with pcap.h
 708 dnl from 0.6 and libpcap 0.8, so that libpcap had pcap_findalldevs but
 709 dnl pcap.h didn't have pcap_if_t.
 710     savedcppflags="$CPPFLAGS"
 711     CPPFLAGS="$CPPFLAGS $V_INCLS"
 712     AC_CHECK_TYPES(pcap_if_t, , , [#include <pcap.h>])
 713     CPPFLAGS="$savedcppflags"
 714 fi
 715 AC_CHECK_FUNCS(pcap_dump_flush pcap_lib_version)
 716 if test $ac_cv_func_pcap_lib_version = "no" ; then
 717     AC_MSG_CHECKING(whether pcap_version is defined by libpcap)
 718     AC_TRY_LINK([],
 719        [
 720         extern char pcap_version[];
 721
 722         return (int)pcap_version;
 723        ],
 724        ac_lbl_cv_pcap_version_defined=yes,
 725        ac_lbl_cv_pcap_version_defined=no)
 726     if test "$ac_lbl_cv_pcap_version_defined" = yes ; then
 727         AC_MSG_RESULT(yes)
 728         AC_DEFINE(HAVE_PCAP_VERSION, 1, [define if libpcap has pcap_version])
 729     else
 730         AC_MSG_RESULT(no)
 731     fi
 732 fi
 733 AC_CHECK_FUNCS(pcap_setdirection pcap_set_immediate_mode pcap_dump_ftell64)
 734 AC_CHECK_FUNCS(pcap_open pcap_findalldevs_ex)
 735 AC_REPLACE_FUNCS(pcap_dump_ftell)
 736
 737 #
 738 # Check for special debugging functions
 739 #
 740 AC_CHECK_FUNCS(pcap_set_parser_debug)
 741 if test "$ac_cv_func_pcap_set_parser_debug" = "no" ; then
 742         #
 743         # OK, we don't have pcap_set_parser_debug() to set the libpcap
 744         # filter expression parser debug flag; can we directly set the
 745         # flag?
 746         AC_MSG_CHECKING(whether pcap_debug is defined by libpcap)
 747         AC_TRY_LINK([],
 748            [
 749                 extern int pcap_debug;
 750
 751                 return pcap_debug;
 752            ],
 753            ac_lbl_cv_pcap_debug_defined=yes,
 754            ac_lbl_cv_pcap_debug_defined=no)
 755         if test "$ac_lbl_cv_pcap_debug_defined" = yes ; then
 756                 AC_MSG_RESULT(yes)
 757                 AC_DEFINE(HAVE_PCAP_DEBUG, 1, [define if libpcap has pcap_debug])
 758         else
 759                 AC_MSG_RESULT(no)
 760                 #
 761                 # OK, what about "yydebug"?
 762                 #
 763                 AC_MSG_CHECKING(whether yydebug is defined by libpcap)
 764                 AC_TRY_LINK([],
 765                    [
 766                         extern int yydebug;
 767
 768                         return yydebug;
 769                    ],
 770                    ac_lbl_cv_yydebug_defined=yes,
 771                    ac_lbl_cv_yydebug_defined=no)
 772                 if test "$ac_lbl_cv_yydebug_defined" = yes ; then
 773                         AC_MSG_RESULT(yes)
 774                         AC_DEFINE(HAVE_YYDEBUG, 1, [define if libpcap has yydebug])
 775                 else
 776                         AC_MSG_RESULT(no)
 777                 fi
 778         fi
 779 fi
 780 AC_CHECK_FUNCS(pcap_set_optimizer_debug)
 781 AC_REPLACE_FUNCS(bpf_dump)      dnl moved to libpcap in 0.6
 782
 783 V_GROUP=0
 784 if test -f /etc/group -a ! -z "`grep '^wheel:' /etc/group`" ; then
 785         V_GROUP=wheel
 786 fi
 787 #
 788 # Assume V7/BSD convention for man pages (file formats in section 5,
 789 # miscellaneous info in section 7).
 790 #
 791 MAN_FILE_FORMATS=5
 792 MAN_MISC_INFO=7
 793 case "$host_os" in
 794
 795 aix*)
 796         dnl Workaround to enable certain features
 797         AC_DEFINE(_SUN,1,[define on AIX to get certain functions])
 798         ;;
 799
 800 hpux*)
 801         #
 802         # Use System V conventions for man pages.
 803         #
 804         MAN_FILE_FORMATS=4
 805         MAN_MISC_INFO=5
 806         ;;
 807
 808 irix*)
 809         V_GROUP=sys
 810
 811         #
 812         # Use System V conventions for man pages.
 813         #
 814         MAN_FILE_FORMATS=4
 815         MAN_MISC_INFO=5
 816         ;;
 817
 818 osf*)
 819         V_GROUP=system
 820
 821         #
 822         # Use System V conventions for man pages.
 823         #
 824         MAN_FILE_FORMATS=4
 825         MAN_MISC_INFO=5
 826         ;;
 827
 828 solaris*)
 829         V_GROUP=sys
 830
 831         #
 832         # Use System V conventions for man pages.
 833         #
 834         MAN_FILE_FORMATS=4
 835         MAN_MISC_INFO=5
 836         ;;
 837 esac
 838
 839 if test -f /dev/bpf0 ; then
 840         V_GROUP=bpf
 841 fi
 842
 843 #
 844 # Make sure we have a definition for C99's uintptr_t (regardless of
 845 # whether the environment is a C99 environment or not).
 846 #
 847 AC_TYPE_UINTPTR_T
 848
 849 #
 850 # Check whether we have pcap/pcap-inttypes.h.
 851 # If we do, we use that to get the C99 types defined.
 852 #
 853 savedcppflags="$CPPFLAGS"
 854 CPPFLAGS="$CPPFLAGS $V_INCLS"
 855 AC_CHECK_HEADERS(pcap/pcap-inttypes.h)
 856 CPPFLAGS="$savedcppflags"
 857
 858 #
 859 # Define the old BSD specified-width types in terms of the C99 types;
 860 # we may need them with libpcap include files.
 861 #
 862 AC_CHECK_TYPE([u_int8_t], ,
 863         [AC_DEFINE([u_int8_t], [uint8_t],
 864         [Define to `uint8_t' if u_int8_t not defined.])],
 865         [AC_INCLUDES_DEFAULT
 866 #include <sys/types.h>
 867 ])
 868 AC_CHECK_TYPE([u_int16_t], ,
 869         [AC_DEFINE([u_int16_t], [uint16_t],
 870         [Define to `uint16_t' if u_int16_t not defined.])],
 871         [AC_INCLUDES_DEFAULT
 872 #include <sys/types.h>
 873 ])
 874 AC_CHECK_TYPE([u_int32_t], ,
 875         [AC_DEFINE([u_int32_t], [uint32_t],
 876         [Define to `uint32_t' if u_int32_t not defined.])],
 877         [AC_INCLUDES_DEFAULT
 878 #include <sys/types.h>
 879 ])
 880 AC_CHECK_TYPE([u_int64_t], ,
 881         [AC_DEFINE([u_int64_t], [uint64_t],
 882         [Define to `uint64_t' if u_int64_t not defined.])],
 883         [AC_INCLUDES_DEFAULT
 884 #include <sys/types.h>
 885 ])
 886
 887 AC_PROG_RANLIB
 888 AC_CHECK_TOOL([AR], [ar])
 889
 890 AC_LBL_DEVEL(V_CCOPT)
 891
 892 # Check for OpenSSL/libressl libcrypto
 893 AC_MSG_CHECKING(whether to use OpenSSL/libressl libcrypto)
 894 # Specify location for both includes and libraries.
 895 want_libcrypto=ifavailable
 896 AC_ARG_WITH(crypto,
 897     AS_HELP_STRING([--with-crypto]@<:@=DIR@:>@,
 898                    [use OpenSSL/libressl libcrypto (located in directory DIR, if specified) @<:@default=yes, if available@:>@]),
 899 [
 900         if test $withval = no
 901         then
 902                 # User doesn't want to link with libcrypto.
 903                 want_libcrypto=no
 904                 AC_MSG_RESULT(no)
 905         elif test $withval = yes
 906         then
 907                 # User wants to link with libcrypto but hasn't specified
 908                 # a directory.
 909                 want_libcrypto=yes
 910                 AC_MSG_RESULT(yes)
 911         else
 912                 # User wants to link with libcrypto and has specified
 913                 # a directory, so use the provided value.
 914                 want_libcrypto=yes
 915                 libcrypto_root=$withval
 916                 AC_MSG_RESULT([yes, using the version installed in $withval])
 917
 918                 #
 919                 # Put the subdirectories of the libcrypto root directory
 920                 # at the front of the header and library search path.
 921                 #
 922                 CFLAGS="-I$withval/include $CFLAGS"
 923                 LIBS="-L$withval/lib $LIBS"
 924         fi
 925 ],[
 926         #
 927         # Use libcrypto if it's present, otherwise don't; no directory
 928         # was specified.
 929         #
 930         want_libcrypto=ifavailable
 931         AC_MSG_RESULT([yes, if available])
 932 ])
 933 if test "$want_libcrypto" != "no"; then
 934         #
 935         # Don't check for libcrypto unless we have its headers;
 936         # Apple, bless their pointy little heads, apparently ship
 937         # libcrypto as a library, but not the header files, in
 938         # El Capitan, probably because they don't want you writing
 939         # nasty portable code that could run on other UN*Xes, they
 940         # want you writing code that uses their Shiny New Crypto
 941         # Library and that only runs on macOS.
 942         #
 943         AC_CHECK_HEADER(openssl/crypto.h,
 944         [
 945                 AC_CHECK_LIB(crypto, DES_cbc_encrypt)
 946                 if test "$ac_cv_lib_crypto_DES_cbc_encrypt" = "yes"; then
 947                         AC_CHECK_HEADERS(openssl/evp.h)
 948                         #
 949                         # OK, then:
 950                         #
 951                         # 1) do we have EVP_CIPHER_CTX_new?
 952                         # If so, we use it to allocate an
 953                         # EVP_CIPHER_CTX, as EVP_CIPHER_CTX may be
 954                         # opaque; otherwise, we allocate it ourselves.
 955                         #
 956                         # 2) do we have EVP_DecryptInit_ex()?
 957                         # If so, we use it, because we need to be
 958                         # able to make two "initialize the cipher"
 959                         # calls, one with the cipher and key, and
 960                         # one with the IV, and, as of OpenSSL 1.1,
 961                         # You Can't Do That with EVP_DecryptInit(),
 962                         # because a call to EVP_DecryptInit() will
 963                         # unconditionally clear the context, and
 964                         # if you don't supply a cipher, it'll
 965                         # clear the cipher, rendering the context
 966                         # unusable and causing a crash.
 967                         #
 968                         AC_CHECK_FUNCS(EVP_CIPHER_CTX_new EVP_DecryptInit_ex)
 969                 fi
 970         ])
 971 fi
 972
 973 # Check for libcap-ng
 974 AC_MSG_CHECKING(whether to use libcap-ng)
 975 # Specify location for both includes and libraries.
 976 want_libcap_ng=ifavailable
 977 AC_ARG_WITH(cap_ng,
 978     AS_HELP_STRING([--with-cap-ng],
 979                    [use libcap-ng @<:@default=yes, if available@:>@]),
 980 [
 981         if test $withval = no
 982         then
 983                 want_libcap_ng=no
 984                 AC_MSG_RESULT(no)
 985         elif test $withval = yes
 986         then
 987                 want_libcap_ng=yes
 988                 AC_MSG_RESULT(yes)
 989         fi
 990 ],[
 991         #
 992         # Use libcap-ng if it's present, otherwise don't.
 993         #
 994         want_libcap_ng=ifavailable
 995         AC_MSG_RESULT([yes, if available])
 996 ])
 997 if test "$want_libcap_ng" != "no"; then
 998         AC_CHECK_LIB(cap-ng, capng_change_id)
 999         AC_CHECK_HEADERS(cap-ng.h)
1000 fi
1001
1002 dnl
1003 dnl set additional include path if necessary
1004 if test "$missing_includes" = "yes"; then
1005         CPPFLAGS="$CPPFLAGS -I$srcdir/missing"
1006         V_INCLS="$V_INCLS -I$srcdir/missing"
1007 fi
1008
1009 AC_SUBST(V_CCOPT)
1010 AC_SUBST(V_DEFS)
1011 AC_SUBST(V_GROUP)
1012 AC_SUBST(V_INCLS)
1013 AC_SUBST(V_PCAPDEP)
1014 AC_SUBST(LOCALSRC)
1015 AC_SUBST(MAN_FILE_FORMATS)
1016 AC_SUBST(MAN_MISC_INFO)
1017
1018 AC_PROG_INSTALL
1019
1020 AC_CONFIG_HEADER(config.h)
1021
1022 AC_OUTPUT_COMMANDS([if test -f .devel; then
1023         echo timestamp > stamp-h
1024         cat $srcdir/Makefile-devel-adds >> Makefile
1025         make depend || exit 1
1026 fi])
1027 AC_OUTPUT(Makefile tcpdump.1)
1028 exit 0