The Tcpdump Group git mirrors - tcpdump/blob - configure.in

   1 dnl @(#) $Header: /tcpdump/master/tcpdump/configure.in,v 1.150 2002-06-11 17:15:32 itojun Exp $ (LBL)
   2 dnl
   3 dnl Copyright (c) 1994, 1995, 1996, 1997
   4 dnl     The Regents of the University of California.  All rights reserved.
   5 dnl
   6 dnl Process this file with autoconf to produce a configure script.
   7 dnl
   8
   9 AC_REVISION($Revision: 1.150 $)
  10 AC_PREREQ(2.13)
  11 AC_INIT(tcpdump.c)
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_LBL_C_INIT(V_CCOPT, V_INCLS)
  16 AC_C_INLINE
  17 AC_C___ATTRIBUTE__
  18
  19 AC_CHECK_HEADERS(fcntl.h rpc/rpcent.h netinet/if_ether.h netdnet/dnetdb.h)
  20 AC_HEADER_TIME
  21
  22 case "$host_os" in
  23
  24 linux*)
  25         AC_MSG_CHECKING(Linux kernel version)
  26         if test "$cross_compiling" = yes; then
  27                 AC_CACHE_VAL(ac_cv_linux_vers,
  28                     ac_cv_linux_vers=unknown)
  29         else
  30                 AC_CACHE_VAL(ac_cv_linux_vers,
  31                     ac_cv_linux_vers=`uname -r 2>&1 | \
  32                         sed -n -e '$s/.* //' -e '$s/\..*//p'`)
  33         fi
  34         AC_MSG_RESULT($ac_cv_linux_vers)
  35         if test $ac_cv_linux_vers = unknown ; then
  36                 AC_MSG_ERROR(cannot determine linux version when cross-compiling)
  37         fi
  38         if test $ac_cv_linux_vers -lt 2 ; then
  39                 AC_MSG_ERROR(version 2 or higher required; see the INSTALL doc for more info)
  40         fi
  41         ;;
  42
  43 *)
  44         ;;
  45 esac
  46
  47
  48 AC_CHECK_HEADERS(smi.h)
  49 AC_CHECK_LIB(smi, smiInit)
  50 if test "$ac_cv_header_smi_h" = yes -a "$ac_cv_lib_smi_smiInit" = yes
  51 then
  52 AC_MSG_CHECKING([whether to enable libsmi])
  53         AC_TRY_RUN([ /* libsmi available check */
  54 #include <smi.h>
  55 main()
  56 {
  57   int current, revision, age, n;
  58   const int required = 2;
  59   if (smiInit(""))
  60     exit(1);
  61   if (strcmp(SMI_LIBRARY_VERSION, smi_library_version))
  62     exit(2);
  63   n = sscanf(smi_library_version, "%d:%d:%d", &current, &revision, &age);
  64   if (n != 3)
  65     exit(3);
  66   if (required < current - age || required > current)
  67     exit(4);
  68   exit(0);
  69 }
  70 ],
  71 [ AC_MSG_RESULT(yes)
  72   AC_DEFINE(LIBSMI)
  73   libsmi=yes],
  74 dnl autoconf documentation says that $? contains the exit value.
  75 dnl reality is that it does not.  We leave this in just in case
  76 dnl autoconf ever comes back to match the documentation.
  77 [ case $? in
  78   1) AC_MSG_RESULT(no - smiInit failed) ;;
  79   2) AC_MSG_RESULT(no - header/library version mismatch) ;;
  80   3) AC_MSG_RESULT(no - can't determine library version) ;;
  81   4) AC_MSG_RESULT(no - too old) ;;
  82   *) AC_MSG_RESULT(no) ;;
  83   esac
  84   libsmi=no],
  85 [ AC_MSG_RESULT(not when cross-compiling)
  86   libsmi=no]
  87 )
  88 fi
  89
  90 AC_MSG_CHECKING([whether to enable the possibly-buggy SMB printer])
  91 AC_ARG_ENABLE(smb,
  92 [  --enable-smb            enable possibly-buggy SMB printer [default=yes]
  93   --disable-smb           disable possibly-buggy SMB printer],,
  94    enableval=yes)
  95 case "$enableval" in
  96 yes)    AC_MSG_RESULT(yes)
  97         AC_WARN([The SMB printer may have exploitable buffer overflows!!!])
  98         AC_DEFINE(TCPDUMP_DO_SMB)
  99         LOCALSRC="print-smb.c smbutil.c $LOCALSRC"
 100         ;;
 101 *)      AC_MSG_RESULT(no)
 102         ;;
 103 esac
 104
 105 AC_MSG_CHECKING([whether to enable ipv6])
 106 AC_ARG_ENABLE(ipv6,
 107 [  --enable-ipv6           enable ipv6 (with ipv4) support
 108   --disable-ipv6          disable ipv6 support],
 109 [ case "$enableval" in
 110 yes)   AC_MSG_RESULT(yes)
 111        LOCALSRC="print-ip6.c print-ip6opts.c print-ripng.c print-icmp6.c print-frag6.c print-rt6.c print-ospf6.c print-dhcp6.c $LOCALSRC"
 112        AC_DEFINE(INET6)
 113        ipv6=yes
 114        ;;
 115 *)
 116        AC_MSG_RESULT(no)
 117        ipv6=no
 118        ;;
 119   esac ],
 120
 121   AC_TRY_RUN([ /* AF_INET6 available check */
 122 #include <sys/types.h>
 123 #include <sys/socket.h>
 124 main()
 125 {
 126  if (socket(AF_INET6, SOCK_STREAM, 0) < 0)
 127    exit(1);
 128  else
 129    exit(0);
 130 }
 131 ],
 132 [ AC_MSG_RESULT(yes)
 133   LOCALSRC="print-ip6.c print-ip6opts.c print-ripng.c print-icmp6.c print-frag6.c print-rt6.c print-ospf6.c print-dhcp6.c $LOCALSRC"
 134   AC_DEFINE(INET6)
 135   ipv6=yes],
 136 [ AC_MSG_RESULT(no)
 137   ipv6=no],
 138 [ AC_MSG_RESULT(no)
 139   ipv6=no]
 140 ))
 141
 142 ipv6type=unknown
 143 ipv6lib=none
 144 ipv6trylibc=no
 145
 146 if test "$ipv6" = "yes"; then
 147         AC_MSG_CHECKING([ipv6 stack type])
 148         for i in inria kame linux-glibc linux-libinet6 toshiba v6d zeta; do
 149                 case $i in
 150                 inria)
 151                         dnl http://www.kame.net/
 152                         AC_EGREP_CPP(yes, [dnl
 153 #include <netinet/in.h>
 154 #ifdef IPV6_INRIA_VERSION
 155 yes
 156 #endif],
 157                                 [ipv6type=$i;
 158                                 CFLAGS="-DINET6 $CFLAGS"])
 159                         ;;
 160                 kame)
 161                         dnl http://www.kame.net/
 162                         AC_EGREP_CPP(yes, [dnl
 163 #include <netinet/in.h>
 164 #ifdef __KAME__
 165 yes
 166 #endif],
 167                                 [ipv6type=$i;
 168                                 ipv6lib=inet6;
 169                                 ipv6libdir=/usr/local/v6/lib;
 170                                 ipv6trylibc=yes;
 171                                 CFLAGS="-DINET6 $CFLAGS"])
 172                         ;;
 173                 linux-glibc)
 174                         dnl http://www.v6.linux.or.jp/
 175                         AC_EGREP_CPP(yes, [dnl
 176 #include <features.h>
 177 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 178 yes
 179 #endif],
 180                                 [ipv6type=$i;
 181                                 CFLAGS="-DINET6 $CFLAGS"])
 182                         ;;
 183                 linux-libinet6)
 184                         dnl http://www.v6.linux.or.jp/
 185                         if test -d /usr/inet6 -o -f /usr/include/netinet/ip6.h; then
 186                                 ipv6type=$i
 187                                 ipv6lib=inet6
 188                                 ipv6libdir=/usr/inet6/lib
 189                                 ipv6trylibc=yes;
 190                                 CFLAGS="-DINET6 -I/usr/inet6/include $CFLAGS"
 191                         fi
 192                         ;;
 193                 toshiba)
 194                         AC_EGREP_CPP(yes, [dnl
 195 #include <sys/param.h>
 196 #ifdef _TOSHIBA_INET6
 197 yes
 198 #endif],
 199                                 [ipv6type=$i;
 200                                 ipv6lib=inet6;
 201                                 ipv6libdir=/usr/local/v6/lib;
 202                                 CFLAGS="-DINET6 $CFLAGS"])
 203                         ;;
 204                 v6d)
 205                         AC_EGREP_CPP(yes, [dnl
 206 #include </usr/local/v6/include/sys/v6config.h>
 207 #ifdef __V6D__
 208 yes
 209 #endif],
 210                                 [ipv6type=$i;
 211                                 ipv6lib=v6;
 212                                 ipv6libdir=/usr/local/v6/lib;
 213                                 CFLAGS="-I/usr/local/v6/include $CFLAGS"])
 214                         ;;
 215                 zeta)
 216                         AC_EGREP_CPP(yes, [dnl
 217 #include <sys/param.h>
 218 #ifdef _ZETA_MINAMI_INET6
 219 yes
 220 #endif],
 221                                 [ipv6type=$i;
 222                                 ipv6lib=inet6;
 223                                 ipv6libdir=/usr/local/v6/lib;
 224                                 CFLAGS="-DINET6 $CFLAGS"])
 225                         ;;
 226                 esac
 227                 if test "$ipv6type" != "unknown"; then
 228                         break
 229                 fi
 230         done
 231         AC_MSG_RESULT($ipv6type)
 232 fi
 233
 234 if test "$ipv6" = "yes" -a "$ipv6lib" != "none"; then
 235         if test -d $ipv6libdir -a -f $ipv6libdir/lib$ipv6lib.a; then
 236                 LIBS="-L$ipv6libdir -l$ipv6lib $LIBS"
 237                 echo "You have $ipv6lib library, using it"
 238         else
 239                 if test "$ipv6trylibc" = "yes"; then
 240                         echo "You do not have $ipv6lib library, using libc"
 241                 else
 242                         echo 'Fatal: no $ipv6lib library found.  cannot continue.'
 243                         echo "You need to fetch lib$ipv6lib.a from appropriate"
 244                         echo 'ipv6 kit and compile beforehand.'
 245                         exit 1
 246                 fi
 247         fi
 248 fi
 249
 250
 251 if test "$ipv6" = "yes"; then
 252         AC_SEARCH_LIBS(getaddrinfo, socket, [dnl
 253         AC_MSG_CHECKING(getaddrinfo bug)
 254         AC_CACHE_VAL(td_cv_buggygetaddrinfo, [AC_TRY_RUN([
 255 #include <sys/types.h>
 256 #include <netdb.h>
 257 #include <string.h>
 258 #include <sys/socket.h>
 259 #include <netinet/in.h>
 260
 261 main()
 262 {
 263   int passive, gaierr, inet4 = 0, inet6 = 0;
 264   struct addrinfo hints, *ai, *aitop;
 265   char straddr[INET6_ADDRSTRLEN], strport[16];
 266
 267   for (passive = 0; passive <= 1; passive++) {
 268     memset(&hints, 0, sizeof(hints));
 269     hints.ai_family = AF_UNSPEC;
 270     hints.ai_flags = passive ? AI_PASSIVE : 0;
 271     hints.ai_socktype = SOCK_STREAM;
 272     if ((gaierr = getaddrinfo(NULL, "54321", &hints, &aitop)) != 0) {
 273       (void)gai_strerror(gaierr);
 274       goto bad;
 275     }
 276     for (ai = aitop; ai; ai = ai->ai_next) {
 277       if (ai->ai_addr == NULL ||
 278           ai->ai_addrlen == 0 ||
 279           getnameinfo(ai->ai_addr, ai->ai_addrlen,
 280                       straddr, sizeof(straddr), strport, sizeof(strport),
 281                       NI_NUMERICHOST|NI_NUMERICSERV) != 0) {
 282         goto bad;
 283       }
 284       switch (ai->ai_family) {
 285       case AF_INET:
 286         if (strcmp(strport, "54321") != 0) {
 287           goto bad;
 288         }
 289         if (passive) {
 290           if (strcmp(straddr, "0.0.0.0") != 0) {
 291             goto bad;
 292           }
 293         } else {
 294           if (strcmp(straddr, "127.0.0.1") != 0) {
 295             goto bad;
 296           }
 297         }
 298         inet4++;
 299         break;
 300       case AF_INET6:
 301         if (strcmp(strport, "54321") != 0) {
 302           goto bad;
 303         }
 304         if (passive) {
 305           if (strcmp(straddr, "::") != 0) {
 306             goto bad;
 307           }
 308         } else {
 309           if (strcmp(straddr, "::1") != 0) {
 310             goto bad;
 311           }
 312         }
 313         inet6++;
 314         break;
 315       case AF_UNSPEC:
 316         goto bad;
 317         break;
 318 #ifdef AF_UNIX
 319       case AF_UNIX:
 320 #else
 321 #ifdef AF_LOCAL
 322       case AF_LOCAL:
 323 #endif
 324 #endif
 325       default:
 326         /* another family support? */
 327         break;
 328       }
 329     }
 330   }
 331
 332   /* supported family should be 2, unsupported family should be 0 */
 333   if (!(inet4 == 0 || inet4 == 2))
 334     goto bad;
 335   if (!(inet6 == 0 || inet6 == 2))
 336     goto bad;
 337
 338   if (aitop)
 339     freeaddrinfo(aitop);
 340   exit(0);
 341
 342  bad:
 343   if (aitop)
 344     freeaddrinfo(aitop);
 345   exit(1);
 346 }
 347 ],
 348         td_cv_buggygetaddrinfo=no,
 349         td_cv_buggygetaddrinfo=yes,
 350         td_cv_buggygetaddrinfo=yes)])
 351         if test "$td_cv_buggygetaddrinfo" = no; then
 352                 AC_MSG_RESULT(good)
 353         else
 354                 AC_MSG_RESULT(buggy)
 355         fi
 356
 357         if test "$td_cv_buggygetaddrinfo" = "yes"; then
 358                 if test "$ipv6type" != "linux"; then
 359                         echo 'Fatal: You must get working getaddrinfo() function.'
 360                         echo '       or you can specify "--disable-ipv6"'.
 361                         exit 1
 362                 else
 363                         echo 'Warning: getaddrinfo() implementation on your system seems be buggy.'
 364                         echo '         Better upgreade your system library to newest version'
 365                         echo '         of GNU C library (aka glibc).'
 366                 fi
 367         fi
 368         ])
 369         AC_REPLACE_FUNCS(getaddrinfo getnameinfo)
 370 fi
 371 dnl AC_TRY_COMPILE(inet_ntop inet_pton inet_aton)
 372 AC_MSG_CHECKING(for inet_ntop)
 373 AC_TRY_COMPILE([#include <sys/types.h>
 374 #include <sys/socket.h>
 375 #include <netinet/in.h>
 376 #include <arpa/inet.h>], [char src[4], dst[128];
 377 inet_ntop(AF_INET, src, dst, sizeof(dst));],
 378         [AC_MSG_RESULT(yes)], [AC_MSG_RESULT(no)
 379         AC_REPLACE_FUNCS(inet_ntop)])
 380 AC_MSG_CHECKING(for inet_pton)
 381 AC_TRY_COMPILE([#include <sys/types.h>
 382 #include <sys/socket.h>
 383 #include <netinet/in.h>
 384 #include <arpa/inet.h>], [char src[128], dst[4];
 385 inet_pton(AF_INET, src, dst);],
 386         [AC_MSG_RESULT(yes)], [AC_MSG_RESULT(no)
 387         AC_REPLACE_FUNCS(inet_pton)])
 388 AC_MSG_CHECKING(for inet_aton)
 389 AC_TRY_COMPILE([#include <sys/types.h>
 390 #include <netinet/in.h>
 391 #include <arpa/inet.h>], [char src[128];
 392 struct in_addr dst;
 393 inet_aton(src, &dst);],
 394         [AC_MSG_RESULT(yes)], [AC_MSG_RESULT(no)
 395         AC_REPLACE_FUNCS(inet_aton)])
 396
 397 dnl portability macros for getaddrinfo/getnameinfo
 398 dnl
 399 dnl Check for sa_len
 400 AC_CHECK_SA_LEN(ac_cv_sockaddr_has_sa_len)
 401 if test "$ac_cv_sockaddr_has_sa_len" = no; then
 402         missing_includes=yes
 403 fi
 404
 405 AC_CACHE_CHECK([for dnet_htoa declaration in netdnet/dnetdb.h],
 406 [td_cv_decl_netdnet_dnetdb_h_dnet_htoa],
 407 [AC_EGREP_HEADER(dnet_htoa, netdnet/dnetdb.h,
 408         td_cv_decl_netdnet_dnetdb_h_dnet_htoa=yes,
 409         td_cv_decl_netdnet_dnetdb_h_dnet_htoa=no)])
 410 if test "$td_cv_decl_netdnet_dnetdb_h_dnet_htoa" = yes; then
 411         AC_DEFINE(HAVE_NETDNET_DNETDB_H_DNET_HTOA)
 412 fi
 413
 414 dnl
 415 dnl check sizeof basic types.
 416 dnl They're very likely to be wrong for cross-compiling.
 417 AC_CHECK_SIZEOF(char, 1)
 418 AC_CHECK_SIZEOF(short, 2)
 419 AC_CHECK_SIZEOF(int, 4)
 420 AC_CHECK_SIZEOF(long, 4)
 421
 422 dnl
 423 dnl Checks for u_intXX_t
 424 dnl AC_CHECK_BITTYPES(ac_cv_bittypes)
 425 dnl if test "$ac_cv_bittypes" = no; then
 426 dnl     missing_includes=yes
 427 dnl fi
 428
 429 dnl
 430 dnl Checks for addrinfo structure
 431 AC_STRUCT_ADDRINFO(ac_cv_addrinfo)
 432 if test "$ac_cv_addrinfo" = no; then
 433         missing_includes=yes
 434 fi
 435
 436 dnl
 437 dnl Checks for NI_MAXSERV
 438 AC_NI_MAXSERV(ac_cv_maxserv)
 439 if test "$ac_cv_maxserv" = no; then
 440         missing_includes=yes
 441 fi
 442
 443 dnl
 444 dnl Checks for NI_NAMEREQD
 445 AC_NI_NAMEREQD(ac_cv_namereqd)
 446 if test "$ac_cv_namereqd" = no; then
 447         missing_includes=yes
 448 fi
 449
 450 dnl
 451 dnl Checks for sockaddr_storage structure
 452 AC_STRUCT_SA_STORAGE(ac_cv_sa_storage)
 453 if test "$ac_cv_sa_storage" = no; then
 454         missing_includes=yes
 455 fi
 456
 457 dnl
 458 dnl Checks for IN[6]ADDRSZ
 459 AC_CHECK_ADDRSZ(ac_cv_addrsz)
 460 if test "$ac_cv_addrsz" = no; then
 461         missing_includes=yes
 462 fi
 463
 464 dnl
 465 dnl Checks for RES_USE_INET6
 466 AC_CHECK_RES_USE_INET6(ac_cv_res_inet6)
 467 if test "$ac_cv_res_inet6" = no; then
 468         missing_includes=yes
 469 fi
 470
 471 dnl
 472 dnl Checks for res_state_ext structure
 473 AC_STRUCT_RES_STATE_EXT(ac_cv_res_state_ext)
 474 if test "$ac_cv_res_state_ext" = no; then
 475         missing_includes=yes
 476 fi
 477
 478 dnl
 479 dnl Checks if res_state structure has nsort member.
 480 AC_STRUCT_RES_STATE(ac_cv_res_state)
 481
 482 dnl
 483 dnl set additional include path if necessary
 484 if test "$missing_includes" = "yes"; then
 485         CPPFLAGS="$CPPFLAGS -I\$(srcdir)/missing"
 486         V_INCLS="$V_INCLS -I\$(srcdir)/missing"
 487 fi
 488
 489
 490 AC_REPLACE_FUNCS(vfprintf strcasecmp strlcat strlcpy strdup)
 491 AC_CHECK_FUNCS(ether_ntohost, [
 492     AC_CACHE_CHECK(for buggy ether_ntohost, ac_cv_buggy_ether_ntohost, [
 493         AC_TRY_RUN([
 494                 #include <netdb.h>
 495                 #include <sys/types.h>
 496                 #include <sys/param.h>
 497                 #include <sys/socket.h>
 498
 499                 int
 500                 main(int argc, char **argv)
 501                 {
 502                         u_char ea[6] = { 0xff, 0xff, 0xff, 0xff, 0xff };
 503                         char name[MAXHOSTNAMELEN];
 504
 505                         ether_ntohost(name, (struct ether_addr *)ea);
 506                         exit(0);
 507                 }
 508         ], [ac_cv_buggy_ether_ntohost=no],
 509            [ac_cv_buggy_ether_ntohost=yes],
 510            [ac_cv_buggy_ether_ntohost="not while cross-compiling"])])
 511     if test "$ac_cv_buggy_ether_ntohost" = "no"; then
 512         AC_DEFINE(USE_ETHER_NTOHOST)
 513     fi
 514 ])
 515 AC_CHECK_FUNCS(setlinebuf)
 516
 517 needsnprintf=no
 518 AC_CHECK_FUNCS(vsnprintf snprintf,,
 519         [needsnprintf=yes])
 520 if test $needsnprintf = yes; then
 521         LIBOBJS="$LIBOBJS snprintf.o"
 522 fi
 523
 524 AC_LBL_TYPE_SIGNAL
 525
 526 AC_SEARCH_LIBS(dnet_htoa, dnet, AC_DEFINE(HAVE_DNET_HTOA))
 527
 528 AC_CHECK_LIB(rpc, main)         dnl It's unclear why we might need -lrpc
 529
 530 dnl HP/UX may need -lnsl for getrpcbynumber.
 531 AC_SEARCH_LIBS(getrpcbynumber, nsl)
 532
 533 dnl AC_CHECK_LIB(z, uncompress)
 534 dnl AC_CHECK_HEADERS(zlib.h)
 535
 536 AC_LBL_LIBPCAP(V_PCAPDEP, V_INCLS)
 537
 538 AC_REPLACE_FUNCS(bpf_dump)      dnl moved to libpcap in 0.6
 539
 540 V_GROUP=0
 541 if test -f /etc/group -a ! -z "`grep '^wheel:' /etc/group`" ; then
 542         V_GROUP=wheel
 543 fi
 544 case "$host_os" in
 545
 546 aix*)
 547         dnl Workaround to enable certain features
 548         AC_DEFINE(_SUN)
 549         ;;
 550
 551 irix*)
 552         V_GROUP=sys
 553         ;;
 554
 555 osf*)
 556         V_GROUP=system
 557         ;;
 558
 559 solaris*)
 560         V_GROUP=sys
 561         ;;
 562 esac
 563
 564 if test -f /dev/bpf0 ; then
 565         V_GROUP=bpf
 566 fi
 567
 568 AC_LBL_CHECK_TYPE(u_int8_t, u_char)
 569 AC_LBL_CHECK_TYPE(int16_t, short)
 570 AC_LBL_CHECK_TYPE(u_int16_t, u_short)
 571 AC_LBL_CHECK_TYPE(int32_t, int)
 572 AC_LBL_CHECK_TYPE(u_int32_t, u_int)
 573
 574 AC_LBL_DEVEL(V_CCOPT)
 575
 576 AC_LBL_SOCKADDR_SA_LEN
 577
 578 AC_LBL_UNALIGNED_ACCESS
 579
 580 AC_VAR_H_ERRNO
 581
 582 AC_ARG_WITH(crypto, [  --without-crypto        disable crypto support],
 583         [], [
 584 AC_MSG_CHECKING(for SSLeay)
 585 ac_cv_ssleay_path=no
 586 incdir=no
 587 for dir in /usr/${host_alias} /usr /usr/local /usr/local/ssl /usr/pkg; do
 588         if test -d $dir/lib -a -f $dir/lib/libcrypto.a; then
 589                 ac_cv_ssleay_path=$dir
 590         fi
 591         if test -d $dir/include/openssl -a -f $dir/include/openssl/des.h; then
 592                 incdir="-I$dir/include"
 593         fi
 594         if test "$ac_cv_ssleay_path" != "no" -a "$incdir" != "no"; then
 595                 break;
 596         else
 597                 ac_cv_ssleay_path=no
 598                 incdir=no
 599         fi
 600 done
 601 AC_MSG_RESULT($ac_cv_ssleay_path)
 602 if test "$ac_cv_ssleay_path" != no; then
 603         V_INCLS="$V_INCLS $incdir"
 604         LDFLAGS="-L$dir/lib $LDFLAGS"
 605         if test -f $ac_cv_ssleay_path/lib/libRSAglue.a; then
 606                 LIBS="$LIBS -lRSAglue"
 607         fi
 608         if test -f $ac_cv_ssleay_path/lib/librsaref.a; then
 609                 LIBS="$LIBS -lrsaref"
 610         fi
 611         AC_CHECK_LIB(crypto, des_cbc_encrypt)
 612
 613         bak_CPPFLAGS=$CPPFLAGS
 614         CPPFLAGS="$CPPFLAGS $V_INCLS"
 615         AC_CHECK_HEADERS(openssl/cast.h)
 616
 617         if test "$ac_cv_header_openssl_cast_h" = "yes"; then
 618                 AC_MSG_CHECKING(for buggy CAST128)
 619                 AC_CACHE_VAL(td_cv_buggy_cast128, [AC_TRY_RUN(dnl
 620 [
 621 #include <openssl/cast.h>
 622 main()
 623 {
 624         unsigned char key[] = {0x01,0x23,0x45,0x67,0x12};
 625         unsigned char in[] = {0x01,0x23,0x45,0x67,0x89,0xAB,0xCD,0xEF};
 626         unsigned char out[sizeof(in)];
 627         unsigned char ok[] = {0x7A,0xC8,0x16,0xD1,0x6E,0x9B,0x30,0x2E};
 628         CAST_KEY ks;
 629         CAST_set_key(&ks, sizeof(key), key);
 630         CAST_ecb_encrypt(in, out, &ks, CAST_ENCRYPT);
 631         if (memcmp(out, ok, sizeof(ok)) != 0)
 632                 return 0;
 633         else
 634                 return 1;
 635 }],
 636                         [td_cv_buggy_cast128=yes],
 637                         [td_cv_buggy_cast128=no],
 638                         [td_cv_buggy_cast128="cross-compiling, assume yes"])])
 639                 AC_MSG_RESULT($td_cv_buggy_cast128)
 640                 if test "$td_cv_buggy_cast128" != no; then
 641                         echo "NOTE: SSLeay 0.9.0b has a bug in CAST128 en/decoding routine."
 642                         echo "disabling CAST128 support."
 643                         AC_DEFINE(HAVE_BUGGY_CAST128)
 644                 fi
 645         fi
 646
 647         CPPFLAGS=$bak_CPPFLAGS
 648 fi
 649 ])
 650 AC_CHECK_HEADERS(openssl/rc5.h)
 651
 652 AC_SUBST(V_CCOPT)
 653 AC_SUBST(V_GROUP)
 654 AC_SUBST(V_INCLS)
 655 AC_SUBST(V_PCAPDEP)
 656 AC_SUBST(LOCALSRC)
 657
 658 AC_PROG_INSTALL
 659
 660 AC_CONFIG_HEADER(config.h)
 661
 662 AC_OUTPUT_COMMANDS([if test -f .devel; then
 663         echo timestamp > stamp-h
 664         cat Makefile-devel-adds >> Makefile
 665         make depend
 666 fi])
 667 AC_OUTPUT(Makefile)
 668 exit 0