]> The Tcpdump Group git mirrors - tcpdump/blob - aclocal.m4
projects / tcpdump / blob
summary | shortlog | log | commit | commitdiff | tree
history | raw | HEAD
add boundary, infinite loop checks
[tcpdump] / aclocal.m4
1 dnl @(#) $Header: /tcpdump/master/tcpdump/aclocal.m4,v 1.110 2005-04-21 03:50:29 guy Exp $ (LBL)
2 dnl
3 dnl Copyright (c) 1995, 1996, 1997, 1998
4 dnl The Regents of the University of California. All rights reserved.
5 dnl
6 dnl Redistribution and use in source and binary forms, with or without
7 dnl modification, are permitted provided that: (1) source code distributions
8 dnl retain the above copyright notice and this paragraph in its entirety, (2)
9 dnl distributions including binary code include the above copyright notice and
10 dnl this paragraph in its entirety in the documentation or other materials
11 dnl provided with the distribution, and (3) all advertising materials mentioning
12 dnl features or use of this software display the following acknowledgement:
13 dnl ``This product includes software developed by the University of California,
14 dnl Lawrence Berkeley Laboratory and its contributors.'' Neither the name of
15 dnl the University nor the names of its contributors may be used to endorse
16 dnl or promote products derived from this software without specific prior
17 dnl written permission.
18 dnl THIS SOFTWARE IS PROVIDED ``AS IS'' AND WITHOUT ANY EXPRESS OR IMPLIED
19 dnl WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED WARRANTIES OF
20 dnl MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE.
21 dnl
22 dnl LBL autoconf macros
23 dnl
24
25 dnl
26 dnl Determine which compiler we're using (cc or gcc)
27 dnl If using gcc, determine the version number
28 dnl If using cc, require that it support ansi prototypes
29 dnl If using gcc, use -O2 (otherwise use -O)
30 dnl If using cc, explicitly specify /usr/local/include
31 dnl
32 dnl usage:
33 dnl
34 dnl AC_LBL_C_INIT(copt, incls)
35 dnl
36 dnl results:
37 dnl
38 dnl $1 (copt set)
39 dnl $2 (incls set)
40 dnl CC
41 dnl LDFLAGS
42 dnl ac_cv_lbl_gcc_vers
43 dnl LBL_CFLAGS
44 dnl
45 AC_DEFUN(AC_LBL_C_INIT,
46 [AC_PREREQ(2.12)
47 AC_BEFORE([$0], [AC_PROG_CC])
48 AC_BEFORE([$0], [AC_LBL_FIXINCLUDES])
49 AC_BEFORE([$0], [AC_LBL_DEVEL])
50 AC_ARG_WITH(gcc, [ --without-gcc don't use gcc])
51 $1="-O"
52 $2=""
53 if test "${srcdir}" != "." ; then
54 $2="-I\$(srcdir)"
55 fi
56 if test "${CFLAGS+set}" = set; then
57 LBL_CFLAGS="$CFLAGS"
58 fi
59 if test -z "$CC" ; then
60 case "$host_os" in
61
62 bsdi*)
63 AC_CHECK_PROG(SHLICC2, shlicc2, yes, no)
64 if test $SHLICC2 = yes ; then
65 CC=shlicc2
66 export CC
67 fi
68 ;;
69 esac
70 fi
71 if test -z "$CC" -a "$with_gcc" = no ; then
72 CC=cc
73 export CC
74 fi
75 AC_PROG_CC
76 if test "$GCC" = yes ; then
77 if test "$SHLICC2" = yes ; then
78 ac_cv_lbl_gcc_vers=2
79 $1="-O2"
80 else
81 AC_MSG_CHECKING(gcc version)
82 AC_CACHE_VAL(ac_cv_lbl_gcc_vers,
83 ac_cv_lbl_gcc_vers=`$CC -v 2>&1 | \
84 sed -e '/^gcc version /!d' \
85 -e 's/^gcc version //' \
86 -e 's/ .*//' -e 's/^[[[^0-9]]]*//' \
87 -e 's/\..*//'`)
88 AC_MSG_RESULT($ac_cv_lbl_gcc_vers)
89 if test $ac_cv_lbl_gcc_vers -gt 1 ; then
90 $1="-O2"
91 fi
92 fi
93 else
94 AC_MSG_CHECKING(that $CC handles ansi prototypes)
95 AC_CACHE_VAL(ac_cv_lbl_cc_ansi_prototypes,
96 AC_TRY_COMPILE(
97 [#include <sys/types.h>],
98 [int frob(int, char *)],
99 ac_cv_lbl_cc_ansi_prototypes=yes,
100 ac_cv_lbl_cc_ansi_prototypes=no))
101 AC_MSG_RESULT($ac_cv_lbl_cc_ansi_prototypes)
102 if test $ac_cv_lbl_cc_ansi_prototypes = no ; then
103 case "$host_os" in
104
105 hpux*)
106 AC_MSG_CHECKING(for HP-UX ansi compiler ($CC -Aa -D_HPUX_SOURCE))
107 savedcflags="$CFLAGS"
108 CFLAGS="-Aa -D_HPUX_SOURCE $CFLAGS"
109 AC_CACHE_VAL(ac_cv_lbl_cc_hpux_cc_aa,
110 AC_TRY_COMPILE(
111 [#include <sys/types.h>],
112 [int frob(int, char *)],
113 ac_cv_lbl_cc_hpux_cc_aa=yes,
114 ac_cv_lbl_cc_hpux_cc_aa=no))
115 AC_MSG_RESULT($ac_cv_lbl_cc_hpux_cc_aa)
116 if test $ac_cv_lbl_cc_hpux_cc_aa = no ; then
117 AC_MSG_ERROR(see the INSTALL doc for more info)
118 fi
119 CFLAGS="$savedcflags"
120 V_CCOPT="-Aa $V_CCOPT"
121 AC_DEFINE(_HPUX_SOURCE)
122 ;;
123
124 *)
125 AC_MSG_ERROR(see the INSTALL doc for more info)
126 ;;
127 esac
128 fi
129 $2="$$2 -I/usr/local/include"
130 LDFLAGS="$LDFLAGS -L/usr/local/lib"
131
132 case "$host_os" in
133
134 irix*)
135 V_CCOPT="$V_CCOPT -xansi -signed -O"
136 ;;
137
138 osf*)
139 V_CCOPT="$V_CCOPT -std1 -O"
140 ;;
141
142 ultrix*)
143 AC_MSG_CHECKING(that Ultrix $CC hacks const in prototypes)
144 AC_CACHE_VAL(ac_cv_lbl_cc_const_proto,
145 AC_TRY_COMPILE(
146 [#include <sys/types.h>],
147 [struct a { int b; };
148 void c(const struct a *)],
149 ac_cv_lbl_cc_const_proto=yes,
150 ac_cv_lbl_cc_const_proto=no))
151 AC_MSG_RESULT($ac_cv_lbl_cc_const_proto)
152 if test $ac_cv_lbl_cc_const_proto = no ; then
153 AC_DEFINE(const,)
154 fi
155 ;;
156 esac
157 fi
158 ])
159
160
161 #
162 # Try compiling a sample of the type of code that appears in
163 # gencode.c with "inline", "__inline__", and "__inline".
164 #
165 # Autoconf's AC_C_INLINE, at least in autoconf 2.13, isn't good enough,
166 # as it just tests whether a function returning "int" can be inlined;
167 # at least some versions of HP's C compiler can inline that, but can't
168 # inline a function that returns a struct pointer.
169 #
170 AC_DEFUN(AC_LBL_C_INLINE,
171 [AC_MSG_CHECKING(for inline)
172 AC_CACHE_VAL(ac_cv_lbl_inline, [
173 ac_cv_lbl_inline=""
174 ac_lbl_cc_inline=no
175 for ac_lbl_inline in inline __inline__ __inline
176 do
177 AC_TRY_COMPILE(
178 [#define inline $ac_lbl_inline
179 static inline struct iltest *foo(void);
180 struct iltest {
181 int iltest1;
182 int iltest2;
183 };
184
185 static inline struct iltest *
186 foo()
187 {
188 static struct iltest xxx;
189
190 return &xxx;
191 }],,ac_lbl_cc_inline=yes,)
192 if test "$ac_lbl_cc_inline" = yes ; then
193 break;
194 fi
195 done
196 if test "$ac_lbl_cc_inline" = yes ; then
197 ac_cv_lbl_inline=$ac_lbl_inline
198 fi])
199 if test ! -z "$ac_cv_lbl_inline" ; then
200 AC_MSG_RESULT($ac_cv_lbl_inline)
201 else
202 AC_MSG_RESULT(no)
203 fi
204 AC_DEFINE_UNQUOTED(inline, $ac_cv_lbl_inline, [Define as token for inline if inlining supported])])
205
206 dnl
207 dnl Use pfopen.c if available and pfopen() not in standard libraries
208 dnl Require libpcap
209 dnl Look for libpcap in ..
210 dnl Use the installed libpcap if there is no local version
211 dnl
212 dnl usage:
213 dnl
214 dnl AC_LBL_LIBPCAP(pcapdep, incls)
215 dnl
216 dnl results:
217 dnl
218 dnl $1 (pcapdep set)
219 dnl $2 (incls appended)
220 dnl LIBS
221 dnl LBL_LIBS
222 dnl
223 AC_DEFUN(AC_LBL_LIBPCAP,
224 [AC_REQUIRE([AC_LBL_LIBRARY_NET])
225 dnl
226 dnl save a copy before locating libpcap.a
227 dnl
228 LBL_LIBS="$LIBS"
229 pfopen=/usr/examples/packetfilter/pfopen.c
230 if test -f $pfopen ; then
231 AC_CHECK_FUNCS(pfopen)
232 if test $ac_cv_func_pfopen = "no" ; then
233 AC_MSG_RESULT(Using $pfopen)
234 LIBS="$LIBS $pfopen"
235 fi
236 fi
237 AC_MSG_CHECKING(for local pcap library)
238 libpcap=FAIL
239 lastdir=FAIL
240 places=`ls $srcdir/.. | sed -e 's,/$,,' -e "s,^,$srcdir/../," | \
241 egrep '/libpcap-[[0-9]]*.[[0-9]]*(.[[0-9]]*)?([[ab]][[0-9]]*)?$'`
242 for dir in $places $srcdir/../libpcap $srcdir/libpcap ; do
243 basedir=`echo $dir | sed -e 's/[[ab]][[0-9]]*$//'`
244 if test $lastdir = $basedir ; then
245 dnl skip alphas when an actual release is present
246 continue;
247 fi
248 lastdir=$dir
249 if test -r $dir/libpcap.a ; then
250 libpcap=$dir/libpcap.a
251 d=$dir
252 dnl continue and select the last one that exists
253 fi
254 done
255 if test $libpcap = FAIL ; then
256 AC_MSG_RESULT(not found)
257 AC_CHECK_LIB(pcap, main, libpcap="-lpcap")
258 if test $libpcap = FAIL ; then
259 AC_MSG_ERROR(see the INSTALL doc for more info)
260 fi
261 dnl
262 dnl Good old Red Hat Linux puts "pcap.h" in
263 dnl "/usr/include/pcap"; had the LBL folks done so,
264 dnl that would have been a good idea, but for
265 dnl the Red Hat folks to do so just breaks source
266 dnl compatibility with other systems.
267 dnl
268 dnl We work around this by assuming that, as we didn't
269 dnl find a local libpcap, libpcap is in /usr/lib or
270 dnl /usr/local/lib and that the corresponding header
271 dnl file is under one of those directories; if we don't
272 dnl find it in either of those directories, we check to
273 dnl see if it's in a "pcap" subdirectory of them and,
274 dnl if so, add that subdirectory to the "-I" list.
275 dnl
276 AC_MSG_CHECKING(for extraneous pcap header directories)
277 if test \( ! -r /usr/local/include/pcap.h \) -a \
278 \( ! -r /usr/include/pcap.h \); then
279 if test -r /usr/local/include/pcap/pcap.h; then
280 d="/usr/local/include/pcap"
281 elif test -r /usr/include/pcap/pcap.h; then
282 d="/usr/include/pcap"
283 fi
284 fi
285 if test -z "$d" ; then
286 AC_MSG_RESULT(not found)
287 else
288 $2="-I$d $$2"
289 AC_MSG_RESULT(found -- -I$d added)
290 fi
291 else
292 $1=$libpcap
293 places=`ls $srcdir/.. | sed -e 's,/$,,' -e "s,^,$srcdir/../," | \
294 egrep '/libpcap-[[0-9]]*.[[0-9]]*(.[[0-9]]*)?([[ab]][[0-9]]*)?$'`
295 if test -r $d/pcap.h; then
296 $2="-I$d $$2"
297 elif test -r $places/pcap.h; then
298 $2="-I$places $$2"
299 else
300 AC_MSG_ERROR(cannot find pcap.h, see INSTALL)
301 fi
302 AC_MSG_RESULT($libpcap)
303 fi
304 LIBS="$libpcap $LIBS"
305 case "$host_os" in
306
307 aix*)
308 pseexe="/lib/pse.exp"
309 AC_MSG_CHECKING(for $pseexe)
310 if test -f $pseexe ; then
311 AC_MSG_RESULT(yes)
312 LIBS="$LIBS -I:$pseexe"
313 fi
314 #
315 # We need "-lodm" and "-lcfg", as libpcap requires them on
316 # AIX, and we just build a static libpcap.a and thus can't
317 # arrange that when you link with libpcap you automatically
318 # link with those libraries.
319 #
320 LIBS="$LIBS -lodm -lcfg"
321 ;;
322 esac
323
324 dnl
325 dnl Check for "pcap_list_datalinks()", "pcap_set_datalink()",
326 dnl and "pcap_datalink_name_to_val()", and use substitute versions
327 dnl if they're not present
328 dnl
329 AC_CHECK_FUNC(pcap_list_datalinks,
330 AC_DEFINE(HAVE_PCAP_LIST_DATALINKS),
331 AC_LIBOBJ(datalinks))
332 AC_CHECK_FUNC(pcap_set_datalink,
333 AC_DEFINE(HAVE_PCAP_SET_DATALINK))
334 AC_CHECK_FUNC(pcap_datalink_name_to_val,
335 [
336 AC_DEFINE(HAVE_PCAP_DATALINK_NAME_TO_VAL)
337 AC_CHECK_FUNC(pcap_datalink_val_to_description,
338 AC_DEFINE(HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION),
339 AC_LIBOBJ(dlnames))
340 ],
341 AC_LIBOBJ(dlnames))
342
343 dnl
344 dnl Check for "pcap_breakloop()"; you can't substitute for it if
345 dnl it's absent (it has hooks into the live capture routines),
346 dnl so just define the HAVE_ value if it's there.
347 dnl
348 AC_CHECK_FUNCS(pcap_breakloop)
349 ])
350
351 dnl
352 dnl Define RETSIGTYPE and RETSIGVAL
353 dnl
354 dnl usage:
355 dnl
356 dnl AC_LBL_TYPE_SIGNAL
357 dnl
358 dnl results:
359 dnl
360 dnl RETSIGTYPE (defined)
361 dnl RETSIGVAL (defined)
362 dnl
363 AC_DEFUN(AC_LBL_TYPE_SIGNAL,
364 [AC_BEFORE([$0], [AC_LBL_LIBPCAP])
365 AC_TYPE_SIGNAL
366 if test "$ac_cv_type_signal" = void ; then
367 AC_DEFINE(RETSIGVAL,)
368 else
369 AC_DEFINE(RETSIGVAL,(0))
370 fi
371 case "$host_os" in
372
373 irix*)
374 AC_DEFINE(_BSD_SIGNALS)
375 ;;
376
377 *)
378 dnl prefer sigaction() to sigset()
379 AC_CHECK_FUNCS(sigaction)
380 if test $ac_cv_func_sigaction = no ; then
381 AC_CHECK_FUNCS(sigset)
382 fi
383 ;;
384 esac])
385
386 dnl
387 dnl If using gcc, make sure we have ANSI ioctl definitions
388 dnl
389 dnl usage:
390 dnl
391 dnl AC_LBL_FIXINCLUDES
392 dnl
393 AC_DEFUN(AC_LBL_FIXINCLUDES,
394 [if test "$GCC" = yes ; then
395 AC_MSG_CHECKING(for ANSI ioctl definitions)
396 AC_CACHE_VAL(ac_cv_lbl_gcc_fixincludes,
397 AC_TRY_COMPILE(
398 [/*
399 * This generates a "duplicate case value" when fixincludes
400 * has not be run.
401 */
402 # include <sys/types.h>
403 # include <sys/time.h>
404 # include <sys/ioctl.h>
405 # ifdef HAVE_SYS_IOCCOM_H
406 # include <sys/ioccom.h>
407 # endif],
408 [switch (0) {
409 case _IO('A', 1):;
410 case _IO('B', 1):;
411 }],
412 ac_cv_lbl_gcc_fixincludes=yes,
413 ac_cv_lbl_gcc_fixincludes=no))
414 AC_MSG_RESULT($ac_cv_lbl_gcc_fixincludes)
415 if test $ac_cv_lbl_gcc_fixincludes = no ; then
416 # Don't cache failure
417 unset ac_cv_lbl_gcc_fixincludes
418 AC_MSG_ERROR(see the INSTALL for more info)
419 fi
420 fi])
421
422 dnl
423 dnl Check for flex, default to lex
424 dnl Require flex 2.4 or higher
425 dnl Check for bison, default to yacc
426 dnl Default to lex/yacc if both flex and bison are not available
427 dnl Define the yy prefix string if using flex and bison
428 dnl
429 dnl usage:
430 dnl
431 dnl AC_LBL_LEX_AND_YACC(lex, yacc, yyprefix)
432 dnl
433 dnl results:
434 dnl
435 dnl $1 (lex set)
436 dnl $2 (yacc appended)
437 dnl $3 (optional flex and bison -P prefix)
438 dnl
439 AC_DEFUN(AC_LBL_LEX_AND_YACC,
440 [AC_ARG_WITH(flex, [ --without-flex don't use flex])
441 AC_ARG_WITH(bison, [ --without-bison don't use bison])
442 if test "$with_flex" = no ; then
443 $1=lex
444 else
445 AC_CHECK_PROGS($1, flex, lex)
446 fi
447 if test "$$1" = flex ; then
448 # The -V flag was added in 2.4
449 AC_MSG_CHECKING(for flex 2.4 or higher)
450 AC_CACHE_VAL(ac_cv_lbl_flex_v24,
451 if flex -V >/dev/null 2>&1; then
452 ac_cv_lbl_flex_v24=yes
453 else
454 ac_cv_lbl_flex_v24=no
455 fi)
456 AC_MSG_RESULT($ac_cv_lbl_flex_v24)
457 if test $ac_cv_lbl_flex_v24 = no ; then
458 s="2.4 or higher required"
459 AC_MSG_WARN(ignoring obsolete flex executable ($s))
460 $1=lex
461 fi
462 fi
463 if test "$with_bison" = no ; then
464 $2=yacc
465 else
466 AC_CHECK_PROGS($2, bison, yacc)
467 fi
468 if test "$$2" = bison ; then
469 $2="$$2 -y"
470 fi
471 if test "$$1" != lex -a "$$2" = yacc -o "$$1" = lex -a "$$2" != yacc ; then
472 AC_MSG_WARN(don't have both flex and bison; reverting to lex/yacc)
473 $1=lex
474 $2=yacc
475 fi
476 if test "$$1" = flex -a -n "$3" ; then
477 $1="$$1 -P$3"
478 $2="$$2 -p $3"
479 fi])
480
481 dnl
482 dnl Checks to see if union wait is used with WEXITSTATUS()
483 dnl
484 dnl usage:
485 dnl
486 dnl AC_LBL_UNION_WAIT
487 dnl
488 dnl results:
489 dnl
490 dnl DECLWAITSTATUS (defined)
491 dnl
492 AC_DEFUN(AC_LBL_UNION_WAIT,
493 [AC_MSG_CHECKING(if union wait is used)
494 AC_CACHE_VAL(ac_cv_lbl_union_wait,
495 AC_TRY_COMPILE([
496 # include <sys/types.h>
497 # include <sys/wait.h>],
498 [int status;
499 u_int i = WEXITSTATUS(status);
500 u_int j = waitpid(0, &status, 0);],
501 ac_cv_lbl_union_wait=no,
502 ac_cv_lbl_union_wait=yes))
503 AC_MSG_RESULT($ac_cv_lbl_union_wait)
504 if test $ac_cv_lbl_union_wait = yes ; then
505 AC_DEFINE(DECLWAITSTATUS,union wait)
506 else
507 AC_DEFINE(DECLWAITSTATUS,int)
508 fi])
509
510 dnl
511 dnl Checks to see if the sockaddr struct has the 4.4 BSD sa_len member
512 dnl
513 dnl usage:
514 dnl
515 dnl AC_LBL_SOCKADDR_SA_LEN
516 dnl
517 dnl results:
518 dnl
519 dnl HAVE_SOCKADDR_SA_LEN (defined)
520 dnl
521 AC_DEFUN(AC_LBL_SOCKADDR_SA_LEN,
522 [AC_MSG_CHECKING(if sockaddr struct has sa_len member)
523 AC_CACHE_VAL(ac_cv_lbl_sockaddr_has_sa_len,
524 AC_TRY_COMPILE([
525 # include <sys/types.h>
526 # include <sys/socket.h>],
527 [u_int i = sizeof(((struct sockaddr *)0)->sa_len)],
528 ac_cv_lbl_sockaddr_has_sa_len=yes,
529 ac_cv_lbl_sockaddr_has_sa_len=no))
530 AC_MSG_RESULT($ac_cv_lbl_sockaddr_has_sa_len)
531 if test $ac_cv_lbl_sockaddr_has_sa_len = yes ; then
532 AC_DEFINE(HAVE_SOCKADDR_SA_LEN)
533 fi])
534
535 dnl
536 dnl Checks to see if -R is used
537 dnl
538 dnl usage:
539 dnl
540 dnl AC_LBL_HAVE_RUN_PATH
541 dnl
542 dnl results:
543 dnl
544 dnl ac_cv_lbl_have_run_path (yes or no)
545 dnl
546 AC_DEFUN(AC_LBL_HAVE_RUN_PATH,
547 [AC_MSG_CHECKING(for ${CC-cc} -R)
548 AC_CACHE_VAL(ac_cv_lbl_have_run_path,
549 [echo 'main(){}' > conftest.c
550 ${CC-cc} -o conftest conftest.c -R/a1/b2/c3 >conftest.out 2>&1
551 if test ! -s conftest.out ; then
552 ac_cv_lbl_have_run_path=yes
553 else
554 ac_cv_lbl_have_run_path=no
555 fi
556 rm -f conftest*])
557 AC_MSG_RESULT($ac_cv_lbl_have_run_path)
558 ])
559
560 dnl
561 dnl Check whether a given format can be used to print 64-bit integers
562 dnl
563 AC_DEFUN(AC_LBL_CHECK_64BIT_FORMAT,
564 [
565 AC_MSG_CHECKING([whether %$1x can be used to format 64-bit integers])
566 AC_RUN_IFELSE(
567 [
568 AC_LANG_SOURCE(
569 [[
570 # ifdef HAVE_INTTYPES_H
571 #include <inttypes.h>
572 # endif
573 # ifdef HAVE_SYS_BITYPES_H
574 #include <sys/bitypes.h>
575 # endif
576 #include <stdio.h>
577 #include <sys/types.h>
578
579 main()
580 {
581 u_int64_t t = 1;
582 char strbuf[16+1];
583 sprintf(strbuf, "%016$1x", t << 32);
584 if (strcmp(strbuf, "0000000100000000") == 0)
585 exit(0);
586 else
587 exit(1);
588 }
589 ]])
590 ],
591 [
592 AC_DEFINE(PRId64, "$1d")
593 AC_DEFINE(PRIo64, "$1o")
594 AC_DEFINE(PRIx64, "$1x")
595 AC_DEFINE(PRIu64, "$1u")
596 AC_MSG_RESULT(yes)
597 ],
598 [
599 AC_MSG_RESULT(no)
600 $2
601 ])
602 ])
603
604 dnl
605 dnl Checks to see if unaligned memory accesses fail
606 dnl
607 dnl usage:
608 dnl
609 dnl AC_LBL_UNALIGNED_ACCESS
610 dnl
611 dnl results:
612 dnl
613 dnl LBL_ALIGN (DEFINED)
614 dnl
615 AC_DEFUN(AC_LBL_UNALIGNED_ACCESS,
616 [AC_MSG_CHECKING(if unaligned accesses fail)
617 AC_CACHE_VAL(ac_cv_lbl_unaligned_fail,
618 [case "$host_cpu" in
619
620 #
621 # These are CPU types where:
622 #
623 # the CPU faults on an unaligned access, but at least some
624 # OSes that support that CPU catch the fault and simulate
625 # the unaligned access (e.g., Alpha/{Digital,Tru64} UNIX) -
626 # the simulation is slow, so we don't want to use it;
627 #
628 # the CPU, I infer (from the old
629 #
630 # XXX: should also check that they don't do weird things (like on arm)
631 #
632 # comment) doesn't fault on unaligned accesses, but doesn't
633 # do a normal unaligned fetch, either (e.g., presumably, ARM);
634 #
635 # for whatever reason, the test program doesn't work
636 # (this has been claimed to be the case for several of those
637 # CPUs - I don't know what the problem is; the problem
638 # was reported as "the test program dumps core" for SuperH,
639 # but that's what the test program is *supposed* to do -
640 # it dumps core before it writes anything, so the test
641 # for an empty output file should find an empty output
642 # file and conclude that unaligned accesses don't work).
643 #
644 # This run-time test won't work if you're cross-compiling, so
645 # in order to support cross-compiling for a particular CPU,
646 # we have to wire in the list of CPU types anyway, as far as
647 # I know, so perhaps we should just have a set of CPUs on
648 # which we know it doesn't work, a set of CPUs on which we
649 # know it does work, and have the script just fail on other
650 # cpu types and update it when such a failure occurs.
651 #
652 alpha*|arm*|hp*|mips*|sh*|sparc*|ia64|nv1)
653 ac_cv_lbl_unaligned_fail=yes
654 ;;
655
656 *)
657 cat >conftest.c <<EOF
658 # include <sys/types.h>
659 # include <sys/wait.h>
660 # include <stdio.h>
661 unsigned char a[[5]] = { 1, 2, 3, 4, 5 };
662 main() {
663 unsigned int i;
664 pid_t pid;
665 int status;
666 /* avoid "core dumped" message */
667 pid = fork();
668 if (pid < 0)
669 exit(2);
670 if (pid > 0) {
671 /* parent */
672 pid = waitpid(pid, &status, 0);
673 if (pid < 0)
674 exit(3);
675 exit(!WIFEXITED(status));
676 }
677 /* child */
678 i = *(unsigned int *)&a[[1]];
679 printf("%d\n", i);
680 exit(0);
681 }
682 EOF
683 ${CC-cc} -o conftest $CFLAGS $CPPFLAGS $LDFLAGS \
684 conftest.c $LIBS >/dev/null 2>&1
685 if test ! -x conftest ; then
686 dnl failed to compile for some reason
687 ac_cv_lbl_unaligned_fail=yes
688 else
689 ./conftest >conftest.out
690 if test ! -s conftest.out ; then
691 ac_cv_lbl_unaligned_fail=yes
692 else
693 ac_cv_lbl_unaligned_fail=no
694 fi
695 fi
696 rm -f conftest* core core.conftest
697 ;;
698 esac])
699 AC_MSG_RESULT($ac_cv_lbl_unaligned_fail)
700 if test $ac_cv_lbl_unaligned_fail = yes ; then
701 AC_DEFINE(LBL_ALIGN)
702 fi])
703
704 dnl
705 dnl If using gcc and the file .devel exists:
706 dnl Compile with -g (if supported) and -Wall
707 dnl If using gcc 2 or later, do extra prototype checking and some other
708 dnl checks
709 dnl If an os prototype include exists, symlink os-proto.h to it
710 dnl
711 dnl usage:
712 dnl
713 dnl AC_LBL_DEVEL(copt)
714 dnl
715 dnl results:
716 dnl
717 dnl $1 (copt appended)
718 dnl HAVE_OS_PROTO_H (defined)
719 dnl os-proto.h (symlinked)
720 dnl
721 AC_DEFUN(AC_LBL_DEVEL,
722 [rm -f os-proto.h
723 if test "${LBL_CFLAGS+set}" = set; then
724 $1="$$1 ${LBL_CFLAGS}"
725 fi
726 if test -f .devel ; then
727 if test "$GCC" = yes ; then
728 if test "${LBL_CFLAGS+set}" != set; then
729 if test "$ac_cv_prog_cc_g" = yes ; then
730 $1="-g $$1"
731 fi
732 $1="$$1 -Wall"
733 if test $ac_cv_lbl_gcc_vers -gt 1 ; then
734 $1="$$1 -Wmissing-prototypes -Wstrict-prototypes -Wwrite-strings -W"
735 fi
736 fi
737 else
738 case "$host_os" in
739
740 irix6*)
741 V_CCOPT="$V_CCOPT -n32"
742 ;;
743
744 *)
745 ;;
746 esac
747 fi
748 os=`echo $host_os | sed -e 's/\([[0-9]][[0-9]]*\)[[^0-9]].*$/\1/'`
749 name="lbl/os-$os.h"
750 if test -f $name ; then
751 ln -s $name os-proto.h
752 AC_DEFINE(HAVE_OS_PROTO_H)
753 else
754 AC_MSG_WARN(can't find $name)
755 fi
756 fi])
757
758 dnl
759 dnl Improved version of AC_CHECK_LIB
760 dnl
761 dnl Thanks to John Hawkinson (jhawk@mit.edu)
762 dnl
763 dnl usage:
764 dnl
765 dnl AC_LBL_CHECK_LIB(LIBRARY, FUNCTION [, ACTION-IF-FOUND [,
766 dnl ACTION-IF-NOT-FOUND [, OTHER-LIBRARIES]]])
767 dnl
768 dnl results:
769 dnl
770 dnl LIBS
771 dnl
772 dnl XXX - "AC_LBL_LIBRARY_NET" was redone to use "AC_SEARCH_LIBS"
773 dnl rather than "AC_LBL_CHECK_LIB", so this isn't used any more.
774 dnl We keep it around for reference purposes in case it's ever
775 dnl useful in the future.
776 dnl
777
778 define(AC_LBL_CHECK_LIB,
779 [AC_MSG_CHECKING([for $2 in -l$1])
780 dnl Use a cache variable name containing the library, function
781 dnl name, and extra libraries to link with, because the test really is
782 dnl for library $1 defining function $2, when linked with potinal
783 dnl library $5, not just for library $1. Separate tests with the same
784 dnl $1 and different $2's or $5's may have different results.
785 ac_lib_var=`echo $1['_']$2['_']$5 | sed 'y%./+- %__p__%'`
786 AC_CACHE_VAL(ac_cv_lbl_lib_$ac_lib_var,
787 [ac_save_LIBS="$LIBS"
788 LIBS="-l$1 $5 $LIBS"
789 AC_TRY_LINK(dnl
790 ifelse([$2], [main], , dnl Avoid conflicting decl of main.
791 [/* Override any gcc2 internal prototype to avoid an error. */
792 ]ifelse(AC_LANG, CPLUSPLUS, [#ifdef __cplusplus
793 extern "C"
794 #endif
795 ])dnl
796 [/* We use char because int might match the return type of a gcc2
797 builtin and then its argument prototype would still apply. */
798 char $2();
799 ]),
800 [$2()],
801 eval "ac_cv_lbl_lib_$ac_lib_var=yes",
802 eval "ac_cv_lbl_lib_$ac_lib_var=no")
803 LIBS="$ac_save_LIBS"
804 ])dnl
805 if eval "test \"`echo '$ac_cv_lbl_lib_'$ac_lib_var`\" = yes"; then
806 AC_MSG_RESULT(yes)
807 ifelse([$3], ,
808 [changequote(, )dnl
809 ac_tr_lib=HAVE_LIB`echo $1 | sed -e 's/[^a-zA-Z0-9_]/_/g' \
810 -e 'y/abcdefghijklmnopqrstuvwxyz/ABCDEFGHIJKLMNOPQRSTUVWXYZ/'`
811 changequote([, ])dnl
812 AC_DEFINE_UNQUOTED($ac_tr_lib)
813 LIBS="-l$1 $LIBS"
814 ], [$3])
815 else
816 AC_MSG_RESULT(no)
817 ifelse([$4], , , [$4
818 ])dnl
819 fi
820 ])
821
822 dnl
823 dnl AC_LBL_LIBRARY_NET
824 dnl
825 dnl This test is for network applications that need socket() and
826 dnl gethostbyname() -ish functions. Under Solaris, those applications
827 dnl need to link with "-lsocket -lnsl". Under IRIX, they need to link
828 dnl with "-lnsl" but should *not* link with "-lsocket" because
829 dnl libsocket.a breaks a number of things (for instance:
830 dnl gethostbyname() under IRIX 5.2, and snoop sockets under most
831 dnl versions of IRIX).
832 dnl
833 dnl Unfortunately, many application developers are not aware of this,
834 dnl and mistakenly write tests that cause -lsocket to be used under
835 dnl IRIX. It is also easy to write tests that cause -lnsl to be used
836 dnl under operating systems where neither are necessary (or useful),
837 dnl such as SunOS 4.1.4, which uses -lnsl for TLI.
838 dnl
839 dnl This test exists so that every application developer does not test
840 dnl this in a different, and subtly broken fashion.
841
842 dnl It has been argued that this test should be broken up into two
843 dnl seperate tests, one for the resolver libraries, and one for the
844 dnl libraries necessary for using Sockets API. Unfortunately, the two
845 dnl are carefully intertwined and allowing the autoconf user to use
846 dnl them independantly potentially results in unfortunate ordering
847 dnl dependancies -- as such, such component macros would have to
848 dnl carefully use indirection and be aware if the other components were
849 dnl executed. Since other autoconf macros do not go to this trouble,
850 dnl and almost no applications use sockets without the resolver, this
851 dnl complexity has not been implemented.
852 dnl
853 dnl The check for libresolv is in case you are attempting to link
854 dnl statically and happen to have a libresolv.a lying around (and no
855 dnl libnsl.a).
856 dnl
857 AC_DEFUN(AC_LBL_LIBRARY_NET, [
858 # Most operating systems have gethostbyname() in the default searched
859 # libraries (i.e. libc):
860 # Some OSes (eg. Solaris) place it in libnsl
861 # Some strange OSes (SINIX) have it in libsocket:
862 AC_SEARCH_LIBS(gethostbyname, nsl socket resolv)
863 # Unfortunately libsocket sometimes depends on libnsl and
864 # AC_SEARCH_LIBS isn't up to the task of handling dependencies like this.
865 if test "$ac_cv_search_gethostbyname" = "no"
866 then
867 AC_CHECK_LIB(socket, gethostbyname,
868 LIBS="-lsocket -lnsl $LIBS", , -lnsl)
869 fi
870 AC_SEARCH_LIBS(socket, socket, ,
871 AC_CHECK_LIB(socket, socket, LIBS="-lsocket -lnsl $LIBS", , -lnsl))
872 # DLPI needs putmsg under HPUX so test for -lstr while we're at it
873 AC_SEARCH_LIBS(putmsg, str)
874 ])
875
876 dnl Copyright (c) 1999 WIDE Project. All rights reserved.
877 dnl
878 dnl Redistribution and use in source and binary forms, with or without
879 dnl modification, are permitted provided that the following conditions
880 dnl are met:
881 dnl 1. Redistributions of source code must retain the above copyright
882 dnl notice, this list of conditions and the following disclaimer.
883 dnl 2. Redistributions in binary form must reproduce the above copyright
884 dnl notice, this list of conditions and the following disclaimer in the
885 dnl documentation and/or other materials provided with the distribution.
886 dnl 3. Neither the name of the project nor the names of its contributors
887 dnl may be used to endorse or promote products derived from this software
888 dnl without specific prior written permission.
889 dnl
890 dnl THIS SOFTWARE IS PROVIDED BY THE PROJECT AND CONTRIBUTORS ``AS IS'' AND
891 dnl ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
892 dnl IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
893 dnl ARE DISCLAIMED. IN NO EVENT SHALL THE PROJECT OR CONTRIBUTORS BE LIABLE
894 dnl FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
895 dnl DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
896 dnl OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
897 dnl HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
898 dnl LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
899 dnl OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
900 dnl SUCH DAMAGE.
901
902 dnl
903 dnl Checks to see if AF_INET6 is defined
904 AC_DEFUN(AC_CHECK_AF_INET6, [
905 AC_MSG_CHECKING(for AF_INET6)
906 AC_CACHE_VAL($1,
907 AC_TRY_COMPILE([
908 # include <sys/types.h>
909 # include <sys/socket.h>],
910 [int a = AF_INET6],
911 $1=yes,
912 $1=no))
913 AC_MSG_RESULT($$1)
914 if test $$1 = yes ; then
915 AC_DEFINE(HAVE_AF_INET6)
916 fi
917 ])
918
919 dnl
920 dnl Checks to see if the sockaddr struct has the 4.4 BSD sa_len member
921 dnl borrowed from LBL libpcap
922 AC_DEFUN(AC_CHECK_SA_LEN, [
923 AC_MSG_CHECKING(if sockaddr struct has sa_len member)
924 AC_CACHE_VAL($1,
925 AC_TRY_COMPILE([
926 # include <sys/types.h>
927 # include <sys/socket.h>],
928 [u_int i = sizeof(((struct sockaddr *)0)->sa_len)],
929 $1=yes,
930 $1=no))
931 AC_MSG_RESULT($$1)
932 if test $$1 = yes ; then
933 AC_DEFINE(HAVE_SOCKADDR_SA_LEN)
934 fi
935 ])
936
937 dnl
938 dnl Checks for portable prototype declaration macro
939 AC_DEFUN(AC_CHECK_PORTABLE_PROTO, [
940 AC_MSG_CHECKING(for __P)
941 AC_CACHE_VAL($1,
942 AC_TRY_COMPILE([
943 # include <unistd.h>],
944 [int f __P(())],
945 $1=yes,
946 $1=no))
947 AC_MSG_RESULT($$1)
948 if test $$1 = yes; then
949 AC_DEFINE(HAVE_PORTABLE_PROTOTYPE)
950 fi
951 ])
952
953 dnl checks for u_intXX_t
954 AC_DEFUN(AC_CHECK_BITTYPES, [
955 $1=yes
956 dnl check for u_int8_t
957 AC_MSG_CHECKING(for u_int8_t)
958 AC_CACHE_VAL(ac_cv_u_int8_t,
959 AC_TRY_COMPILE([
960 # include <sys/types.h>],
961 [u_int8_t i],
962 ac_cv_u_int8_t=yes,
963 ac_cv_u_int8_t=no))
964 AC_MSG_RESULT($ac_cv_u_int8_t)
965 if test $ac_cv_u_int8_t = yes; then
966 AC_DEFINE(HAVE_U_INT8_T)
967 else
968 $1=no
969 fi
970 dnl check for u_int16_t
971 AC_MSG_CHECKING(for u_int16_t)
972 AC_CACHE_VAL(ac_cv_u_int16_t,
973 AC_TRY_COMPILE([
974 # include <sys/types.h>],
975 [u_int16_t i],
976 ac_cv_u_int16_t=yes,
977 ac_cv_u_int16_t=no))
978 AC_MSG_RESULT($ac_cv_u_int16_t)
979 if test $ac_cv_u_int16_t = yes; then
980 AC_DEFINE(HAVE_U_INT16_T)
981 else
982 $1=no
983 fi
984 dnl check for u_int32_t
985 AC_MSG_CHECKING(for u_int32_t)
986 AC_CACHE_VAL(ac_cv_u_int32_t,
987 AC_TRY_COMPILE([
988 # include <sys/types.h>],
989 [u_int32_t i],
990 ac_cv_u_int32_t=yes,
991 ac_cv_u_int32_t=no))
992 AC_MSG_RESULT($ac_cv_u_int32_t)
993 if test $ac_cv_u_int32_t = yes; then
994 AC_DEFINE(HAVE_U_INT32_T)
995 else
996 $1=no
997 fi
998 dnl check for u_int64_t
999 AC_MSG_CHECKING(for u_int64_t)
1000 AC_CACHE_VAL(ac_cv_u_int64_t,
1001 AC_TRY_COMPILE([
1002 # include <sys/types.h>],
1003 [u_int64_t i],
1004 ac_cv_u_int64_t=yes,
1005 ac_cv_u_int64_t=no))
1006 AC_MSG_RESULT($ac_cv_u_int64_t)
1007 if test $ac_cv_u_int64_t = yes; then
1008 AC_DEFINE(HAVE_U_INT64_T)
1009 else
1010 $1=no
1011 fi
1012 ])
1013
1014 dnl
1015 dnl Checks for addrinfo structure
1016 AC_DEFUN(AC_STRUCT_ADDRINFO, [
1017 AC_MSG_CHECKING(for addrinfo)
1018 AC_CACHE_VAL($1,
1019 AC_TRY_COMPILE([
1020 # include <netdb.h>],
1021 [struct addrinfo a],
1022 $1=yes,
1023 $1=no))
1024 AC_MSG_RESULT($$1)
1025 if test $$1 = yes; then
1026 AC_DEFINE(HAVE_ADDRINFO)
1027 else
1028 AC_DEFINE(NEED_ADDRINFO_H)
1029 fi
1030 ])
1031
1032 dnl
1033 dnl Checks for NI_MAXSERV
1034 AC_DEFUN(AC_NI_MAXSERV, [
1035 AC_MSG_CHECKING(for NI_MAXSERV)
1036 AC_CACHE_VAL($1,
1037 AC_EGREP_CPP(yes, [#include <netdb.h>
1038 #ifdef NI_MAXSERV
1039 yes
1040 #endif],
1041 $1=yes,
1042 $1=no))
1043 AC_MSG_RESULT($$1)
1044 if test $$1 != yes; then
1045 AC_DEFINE(NEED_ADDRINFO_H)
1046 fi
1047 ])
1048
1049 dnl
1050 dnl Checks for NI_NAMEREQD
1051 AC_DEFUN(AC_NI_NAMEREQD, [
1052 AC_MSG_CHECKING(for NI_NAMEREQD)
1053 AC_CACHE_VAL($1,
1054 AC_EGREP_CPP(yes, [#include <netdb.h>
1055 #ifdef NI_NOFQDN
1056 yes
1057 #endif],
1058 $1=yes,
1059 $1=no))
1060 AC_MSG_RESULT($$1)
1061 if test $$1 != yes; then
1062 AC_DEFINE(NEED_ADDRINFO_H)
1063 fi
1064 ])
1065
1066 dnl
1067 dnl Checks for sockaddr_storage structure
1068 AC_DEFUN(AC_STRUCT_SA_STORAGE, [
1069 AC_MSG_CHECKING(for sockaddr_storage)
1070 AC_CACHE_VAL($1,
1071 AC_TRY_COMPILE([
1072 # include <sys/types.h>
1073 # include <sys/socket.h>],
1074 [struct sockaddr_storage s],
1075 $1=yes,
1076 $1=no))
1077 AC_MSG_RESULT($$1)
1078 if test $$1 = yes; then
1079 AC_DEFINE(HAVE_SOCKADDR_STORAGE)
1080 fi
1081 ])
1082
1083 dnl
1084 dnl Checks for macro of IP address size
1085 AC_DEFUN(AC_CHECK_ADDRSZ, [
1086 $1=yes
1087 dnl check for INADDRSZ
1088 AC_MSG_CHECKING(for INADDRSZ)
1089 AC_CACHE_VAL(ac_cv_inaddrsz,
1090 AC_TRY_COMPILE([
1091 # include <arpa/nameser.h>],
1092 [int a = INADDRSZ],
1093 ac_cv_inaddrsz=yes,
1094 ac_cv_inaddrsz=no))
1095 AC_MSG_RESULT($ac_cv_inaddrsz)
1096 if test $ac_cv_inaddrsz = yes; then
1097 AC_DEFINE(HAVE_INADDRSZ)
1098 else
1099 $1=no
1100 fi
1101 dnl check for IN6ADDRSZ
1102 AC_MSG_CHECKING(for IN6ADDRSZ)
1103 AC_CACHE_VAL(ac_cv_in6addrsz,
1104 AC_TRY_COMPILE([
1105 # include <arpa/nameser.h>],
1106 [int a = IN6ADDRSZ],
1107 ac_cv_in6addrsz=yes,
1108 ac_cv_in6addrsz=no))
1109 AC_MSG_RESULT($ac_cv_in6addrsz)
1110 if test $ac_cv_in6addrsz = yes; then
1111 AC_DEFINE(HAVE_IN6ADDRSZ)
1112 else
1113 $1=no
1114 fi
1115 ])
1116
1117 dnl
1118 dnl check for RES_USE_INET6
1119 AC_DEFUN(AC_CHECK_RES_USE_INET6, [
1120 AC_MSG_CHECKING(for RES_USE_INET6)
1121 AC_CACHE_VAL($1,
1122 AC_TRY_COMPILE([
1123 # include <sys/types.h>
1124 # include <netinet/in.h>
1125 # include <resolv.h>],
1126 [int a = RES_USE_INET6],
1127 $1=yes,
1128 $1=no))
1129 AC_MSG_RESULT($$1)
1130 if test $$1 = yes; then
1131 AC_DEFINE(HAVE_RES_USE_INET6)
1132 fi
1133 ])
1134
1135 dnl
1136 dnl check for AAAA
1137 AC_DEFUN(AC_CHECK_AAAA, [
1138 AC_MSG_CHECKING(for AAAA)
1139 AC_CACHE_VAL($1,
1140 AC_TRY_COMPILE([
1141 # include <sys/types.h>
1142 # include <arpa/nameser.h>],
1143 [int a = T_AAAA],
1144 $1=yes,
1145 $1=no))
1146 AC_MSG_RESULT($$1)
1147 if test $$1 = yes; then
1148 AC_DEFINE(HAVE_AAAA)
1149 fi
1150 ])
1151
1152 dnl
1153 dnl check for struct res_state_ext
1154 AC_DEFUN(AC_STRUCT_RES_STATE_EXT, [
1155 AC_MSG_CHECKING(for res_state_ext)
1156 AC_CACHE_VAL($1,
1157 AC_TRY_COMPILE([
1158 # include <sys/types.h>
1159 # include <netinet/in.h>
1160 # include <netinet6/in6.h>
1161 # include <resolv.h>],
1162 [struct __res_state_ext e],
1163 $1=yes,
1164 $1=no))
1165 AC_MSG_RESULT($$1)
1166 if test $$1 = yes; then
1167 AC_DEFINE(HAVE_RES_STATE_EXT)
1168 fi
1169 ])
1170
1171 dnl
1172 dnl check for struct res_state_ext
1173 AC_DEFUN(AC_STRUCT_RES_STATE, [
1174 AC_MSG_CHECKING(for nsort in res_state)
1175 AC_CACHE_VAL($1,
1176 AC_TRY_COMPILE([
1177 # include <sys/types.h>
1178 # include <netinet/in.h>
1179 # include <netinet6/in6.h>
1180 # include <resolv.h>],
1181 [struct __res_state e; e.nsort = 0],
1182 $1=yes,
1183 $1=no))
1184 AC_MSG_RESULT($$1)
1185 if test $$1 = yes; then
1186 AC_DEFINE(HAVE_NEW_RES_STATE)
1187 fi
1188 ])
1189
1190 dnl
1191 dnl check for h_errno
1192 AC_DEFUN(AC_VAR_H_ERRNO, [
1193 AC_MSG_CHECKING(for h_errno)
1194 AC_CACHE_VAL(ac_cv_var_h_errno,
1195 AC_TRY_COMPILE([
1196 # include <sys/types.h>
1197 # include <netdb.h>],
1198 [int foo = h_errno;],
1199 ac_cv_var_h_errno=yes,
1200 ac_cv_var_h_errno=no))
1201 AC_MSG_RESULT($ac_cv_var_h_errno)
1202 if test "$ac_cv_var_h_errno" = "yes"; then
1203 AC_DEFINE(HAVE_H_ERRNO)
1204 fi
1205 ])
1206
1207 dnl
1208 dnl Test for __attribute__
1209 dnl
1210
1211 AC_DEFUN(AC_C___ATTRIBUTE__, [
1212 AC_MSG_CHECKING(for __attribute__)
1213 AC_CACHE_VAL(ac_cv___attribute__, [
1214 AC_COMPILE_IFELSE(
1215 AC_LANG_SOURCE([[
1216 #include <stdlib.h>
1217
1218 static void foo(void) __attribute__ ((noreturn));
1219
1220 static void
1221 foo(void)
1222 {
1223 exit(1);
1224 }
1225
1226 int
1227 main(int argc, char **argv)
1228 {
1229 foo();
1230 }
1231 ]]),
1232 ac_cv___attribute__=yes,
1233 ac_cv___attribute__=no)])
1234 if test "$ac_cv___attribute__" = "yes"; then
1235 AC_DEFINE(HAVE___ATTRIBUTE__, 1, [define if your compiler has __attribute__])
1236 V_DEFS="$V_DEFS -D_U_=\"__attribute__((unused))\""
1237 else
1238 V_DEFS="$V_DEFS -D_U_=\"\""
1239 fi
1240 AC_MSG_RESULT($ac_cv___attribute__)
1241 ])
[mirror] the TCPdump network dissector