The Tcpdump Group git mirrors - tcpdump/blob - CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.6)
   2
   3 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/Modules)
   4
   5 project(tcpdump)
   6
   7 #
   8 # Try to enable as many C99 features as we can.
   9 # At minimum, we want C++/C99-style // comments.
  10 #
  11 # Newer versions of compilers might default to supporting C99, but older
  12 # versions may require a special flag.
  13 #
  14 # Prior to CMake 3.1, setting CMAKE_C_STANDARD will not have any effect,
  15 # so, unless and until we require CMake 3.1 or later, we have to do it
  16 # ourselves on pre-3.1 CMake, so we just do it ourselves on all versions
  17 # of CMake.
  18 #
  19 # Note: with CMake 3.1 through 3.5, the only compilers for which CMake
  20 # handles CMAKE_C_STANDARD are GCC and Clang.  3.6 adds support only
  21 # for Intel C; 3.9 adds support for PGI C, Sun C, and IBM XL C, and
  22 # 3.10 adds support for Cray C and IAR C, but no version of CMake has
  23 # support for HP C.  Therefore, even if we use CMAKE_C_STANDARD with
  24 # compilers for which CMake supports it, we may still have to do it
  25 # ourselves on other compilers.
  26 #
  27 # See the CMake documentation for the CMAKE_<LANG>_COMPILER_ID variables
  28 # for a list of compiler IDs.
  29 #
  30 # We don't worry about MSVC; it doesn't have such a flag - either it
  31 # doesn't support the C99 features we need at all, or it supports them
  32 # regardless of the compiler flag.
  33 #
  34 # XXX - this just tests whether the option works and adds it if it does.
  35 # We don't test whether it's necessary in order to get the C99 features
  36 # that we use; if we ever have a user who tries to compile with a compiler
  37 # that can't be made to support those features, we can add a test to make
  38 # sure we actually *have* C99 support.
  39 #
  40 include(CheckCCompilerFlag)
  41 macro(check_and_add_compiler_option _option)
  42     message(STATUS "Checking C compiler flag ${_option}")
  43     string(REPLACE "=" "-" _temp_option_variable ${_option})
  44     string(REGEX REPLACE "^-" "" _option_variable ${_temp_option_variable})
  45     check_c_compiler_flag("${_option}" ${_option_variable})
  46     if(${${_option_variable}})
  47         set(C_ADDITIONAL_FLAGS "${C_ADDITIONAL_FLAGS} ${_option}")
  48     endif()
  49 endmacro()
  50
  51 set(C_ADDITIONAL_FLAGS "")
  52 if(CMAKE_C_COMPILER_ID MATCHES "GNU" OR
  53    CMAKE_C_COMPILER_ID MATCHES "Clang")
  54     check_and_add_compiler_option("-std=gnu99")
  55 elseif(CMAKE_C_COMPILER_ID MATCHES "XL")
  56     #
  57     # We want support for extensions picked up for GNU C compatibility,
  58     # so we use -qlanglvl=extc99.
  59     #
  60     check_and_add_compiler_option("-qlanglvl=extc99")
  61 elseif(CMAKE_C_COMPILER_ID MATCHES "HP")
  62     check_and_add_compiler_option("-AC99")
  63 elseif(CMAKE_C_COMPILER_ID MATCHES "Sun")
  64     check_and_add_compiler_option("-xc99")
  65 elseif(CMAKE_C_COMPILER_ID MATCHES "Intel")
  66     check_and_add_compiler_option("-c99")
  67 endif()
  68
  69 #
  70 # Treat source files as being in UTF-8 with MSVC.
  71 # We assume that UTF-8 source is OK with other compilers.
  72 #
  73 if(MSVC AND NOT ${CMAKE_C_COMPILER} MATCHES "clang*")
  74     set(C_ADDITIONAL_FLAGS "${C_ADDITIONAL_FLAGS} /utf-8")
  75 endif(MSVC AND NOT ${CMAKE_C_COMPILER} MATCHES "clang*")
  76
  77 set(LIBRARY_NAME netdissect)
  78
  79 ###################################################################
  80 #   Parameters
  81 ###################################################################
  82
  83 option(WITH_SMI "Build with libsmi, if available" ON)
  84 option(WITH_CRYPTO "Build with OpenSSL/libressl libcrypto, if available" ON)
  85 option(WITH_CAPSICUM "Build with Capsicum security functions, if available" ON)
  86 option(WITH_CAP_NG "Use libcap-ng, if available" ON)
  87 option(ENABLE_SMB "Build with the SMB dissector" ON)
  88
  89 #
  90 # String parameters.  Neither of them are set, initially; only if the
  91 # user explicitly configures them are they set.
  92 #
  93 # WITH_CHROOT is STRING, not PATH, as the directory need not exist
  94 # when CMake is run.
  95 #
  96 set(WITH_CHROOT CACHE STRING
  97     "Directory to which to chroot when dropping privileges")
  98 set(WITH_USER CACHE STRING
  99     "User to whom to set the UID when dropping privileges")
 100
 101 #
 102 # By default, build universal with the appropriate set of architectures
 103 # for the OS on which we're doing the build.
 104 #
 105 if(APPLE AND "${CMAKE_OSX_ARCHITECTURES}" STREQUAL "")
 106     #
 107     # Get the major version of Darwin.
 108     #
 109     string(REGEX MATCH "^([0-9]+)" SYSTEM_VERSION_MAJOR "${CMAKE_SYSTEM_VERSION}")
 110
 111     if(SYSTEM_VERSION_MAJOR EQUAL 9)
 112         #
 113         # Leopard.  Build for x86 and 32-bit PowerPC, with
 114         # x86 first.  (That's what Apple does.)
 115         #
 116         set(CMAKE_OSX_ARCHITECTURES "i386;ppc")
 117     elseif(SYSTEM_VERSION_MAJOR EQUAL 10)
 118         #
 119         # Snow Leopard.  Build for x86-64 and x86, with
 120         # x86-64 first.  (That's what Apple does.)
 121         #
 122         set(CMAKE_OSX_ARCHITECTURES "x86_64;i386")
 123     endif()
 124 endif()
 125
 126 ###################################################################
 127 #   Versioning
 128 ###################################################################
 129
 130 # Get, parse, format and set tcpdump's version string from
 131 # [tcpdump_root]/VERSION for later use.
 132
 133 # Get MAJOR, MINOR, PATCH & SUFFIX
 134 file(STRINGS ${tcpdump_SOURCE_DIR}/VERSION
 135     PACKAGE_VERSION
 136     LIMIT_COUNT 1 # Read only the first line
 137 )
 138
 139 ######################################
 140 # Project settings
 141 ######################################
 142
 143 add_definitions(-DHAVE_CONFIG_H)
 144
 145 include_directories(
 146     ${CMAKE_CURRENT_BINARY_DIR}
 147     ${tcpdump_SOURCE_DIR}
 148 )
 149
 150 if(MSVC)
 151     add_definitions(-D__STDC__)
 152     add_definitions(-D_CRT_SECURE_NO_WARNINGS)
 153 endif(MSVC)
 154
 155 if(MSVC)
 156     if (USE_STATIC_RT)
 157         MESSAGE(STATUS "Use STATIC runtime")
 158         set(NAME_RT MT)
 159         set (CMAKE_CXX_FLAGS_MINSIZEREL     "${CMAKE_CXX_FLAGS_MINSIZEREL} /MT")
 160         set (CMAKE_CXX_FLAGS_RELWITHDEBINFO "${CMAKE_CXX_FLAGS_RELWITHDEBINFO} /MT")
 161         set (CMAKE_CXX_FLAGS_RELEASE        "${CMAKE_CXX_FLAGS_RELEASE} /MT")
 162         set (CMAKE_CXX_FLAGS_DEBUG          "${CMAKE_CXX_FLAGS_DEBUG} /MTd")
 163
 164         set (CMAKE_C_FLAGS_MINSIZEREL       "${CMAKE_C_FLAGS_MINSIZEREL} /MT")
 165         set (CMAKE_C_FLAGS_RELWITHDEBINFO   "${CMAKE_C_FLAGS_RELWITHDEBINFO} /MT")
 166         set (CMAKE_C_FLAGS_RELEASE          "${CMAKE_C_FLAGS_RELEASE} /MT")
 167         set (CMAKE_C_FLAGS_DEBUG            "${CMAKE_C_FLAGS_DEBUG} /MTd")
 168     else (USE_STATIC_RT)
 169         MESSAGE(STATUS "Use DYNAMIC runtime")
 170         set(NAME_RT MD)
 171         set (CMAKE_CXX_FLAGS_MINSIZEREL     "${CMAKE_CXX_FLAGS_MINSIZEREL} /MD")
 172         set (CMAKE_CXX_FLAGS_RELWITHDEBINFO "${CMAKE_CXX_FLAGS_RELWITHDEBINFO} /MD")
 173         set (CMAKE_CXX_FLAGS_RELEASE        "${CMAKE_CXX_FLAGS_RELEASE} /MD")
 174         set (CMAKE_CXX_FLAGS_DEBUG          "${CMAKE_CXX_FLAGS_DEBUG} /MDd")
 175
 176         set (CMAKE_C_FLAGS_MINSIZEREL       "${CMAKE_C_FLAGS_MINSIZEREL} /MD")
 177         set (CMAKE_C_FLAGS_RELWITHDEBINFO   "${CMAKE_C_FLAGS_RELWITHDEBINFO} /MD")
 178         set (CMAKE_C_FLAGS_RELEASE          "${CMAKE_C_FLAGS_RELEASE} /MD")
 179         set (CMAKE_C_FLAGS_DEBUG            "${CMAKE_C_FLAGS_DEBUG} /MDd")
 180    endif (USE_STATIC_RT)
 181 endif(MSVC)
 182
 183 ###################################################################
 184 #   Detect available platform features
 185 ###################################################################
 186
 187 include(CMakePushCheckState)
 188 include(CheckIncludeFile)
 189 include(CheckIncludeFiles)
 190 include(CheckFunctionExists)
 191 include(CheckLibraryExists)
 192 include(CheckSymbolExists)
 193 include(CheckStructHasMember)
 194 include(CheckVariableExists)
 195 include(CheckTypeSize)
 196
 197 #
 198 # Header files.
 199 #
 200 check_include_file(fcntl.h HAVE_FCNTL_H)
 201 check_include_file(rpc/rpc.h HAVE_RPC_RPC_H)
 202 check_include_file(net/if.h HAVE_NET_IF_H)
 203 if(HAVE_RPC_RPC_H)
 204     check_include_files("rpc/rpc.h;rpc/rpcent.h" HAVE_RPC_RPCENT_H)
 205 endif(HAVE_RPC_RPC_H)
 206 if(NOT WIN32)
 207     check_include_files("sys/types.h;sys/socket.h;net/if.h;net/pfvar.h" HAVE_NET_PFVAR_H)
 208     if(HAVE_NET_PFVAR_H)
 209         check_include_files("sys/types.h;sys/socket.h;net/if.h;net/pfvar.h;net/if_pflog.h" HAVE_NET_IF_PFLOG_H)
 210         if(HAVE_NET_IF_PFLOG_H)
 211             set(LOCALSRC print-pflog.c ${LOCALSRC})
 212         endif(HAVE_NET_IF_PFLOG_H)
 213     endif(HAVE_NET_PFVAR_H)
 214 endif(NOT WIN32)
 215
 216 #
 217 # Functions.
 218 #
 219 check_function_exists(strlcat HAVE_STRLCAT)
 220 check_function_exists(strlcpy HAVE_STRLCPY)
 221 check_function_exists(strdup HAVE_STRDUP)
 222 check_function_exists(strsep HAVE_STRSEP)
 223
 224 #
 225 # Find library needed for gethostbyaddr.
 226 # NOTE: if you hand check_library_exists as its last argument a variable
 227 # that's been set, it skips the test, so we need different variables.
 228 #
 229 set(TCPDUMP_LINK_LIBRARIES "")
 230 if(WIN32)
 231     #
 232     # We need winsock2.h and ws2tcpip.h.
 233     #
 234     cmake_push_check_state()
 235     set(CMAKE_REQUIRED_LIBRARIES ws2_32)
 236     check_symbol_exists(gethostbyaddr "winsock2.h;ws2tcpip.h" LIBWS2_32_HAS_GETHOSTBYADDR)
 237     cmake_pop_check_state()
 238     if(LIBWS2_32_HAS_GETHOSTBYADDR)
 239         set(TCPDUMP_LINK_LIBRARIES ws2_32 ${TCPDUMP_LINK_LIBRARIES})
 240     else(LIBWS2_32_HAS_GETHOSTBYADDR)
 241         message(FATAL_ERROR "gethostbyaddr is required, but wasn't found")
 242     endif(LIBWS2_32_HAS_GETHOSTBYADDR)
 243 else(WIN32)
 244     check_function_exists(gethostbyaddr STDLIBS_HAVE_GETHOSTBYADDR)
 245     if(NOT STDLIBS_HAVE_GETHOSTBYADDR)
 246         check_library_exists(socket gethostbyaddr "" LIBSOCKET_HAS_GETHOSTBYADDR)
 247         if(LIBSOCKET_HAS_GETHOSTBYADDR)
 248             set(TCPDUMP_LINK_LIBRARIES ${TCPDUMP_LINK_LIBRARIES} socket)
 249         else(LIBSOCKET_HAS_GETHOSTBYADDR)
 250             check_library_exists(nsl gethostbyaddr "" LIBNSL_HAS_GETHOSTBYADDR)
 251             if(LIBNSL_HAS_GETHOSTBYADDR)
 252                 set(TCPDUMP_LINK_LIBRARIES ${TCPDUMP_LINK_LIBRARIES} nsl)
 253             else(LIBNSL_HAS_GETHOSTBYADDR)
 254                 message(FATAL_ERROR "gethostbyaddr is required, but wasn't found")
 255             endif(LIBNSL_HAS_GETHOSTBYADDR)
 256         endif(LIBSOCKET_HAS_GETHOSTBYADDR)
 257     endif(NOT STDLIBS_HAVE_GETHOSTBYADDR)
 258 endif(WIN32)
 259
 260 #
 261 # This may require additional libraries.
 262 #
 263 cmake_push_check_state()
 264 set(CMAKE_REQUIRED_LIBRARIES ${TCPDUMP_LINK_LIBRARIES})
 265 check_function_exists(getservent STDLIBS_HAVE_GETSERVENT)
 266 if(STDLIBS_HAVE_GETSERVENT)
 267     set(HAVE_GETSERVENT TRUE)
 268 else(STDLIBS_HAVE_GETSERVENT)
 269     #
 270     # Some platforms may need -lsocket for getservent.
 271     #
 272     set(CMAKE_REQUIRED_LIBRARIES socket ${TCPDUMP_LINK_LIBRARIES})
 273     check_function_exists(getservent LIBSOCKET_HAS_GETSERVENT)
 274     if(LIBSOCKET_HAS_GETSERVENT)
 275         set(HAVE_GETSERVENT TRUE)
 276         set(TCPDUMP_LINK_LIBRARIES socket ${TCPDUMP_LINK_LIBRARIES})
 277     endif(LIBSOCKET_HAS_GETSERVENT)
 278 endif(STDLIBS_HAVE_GETSERVENT)
 279 cmake_pop_check_state()
 280
 281 #
 282 # Make sure we have vsnprintf() and snprintf(); we require them.
 283 #
 284 check_function_exists(vsnprintf HAVE_VSNPRINTF)
 285 if(NOT HAVE_VSNPRINTF)
 286     message(FATAL_ERROR "vsnprintf() is required but wasn't found")
 287 endif(NOT HAVE_VSNPRINTF)
 288 check_function_exists(snprintf HAVE_SNPRINTF)
 289 if(NOT HAVE_SNPRINTF)
 290     message(FATAL_ERROR "snprintf() is required but wasn't found")
 291 endif()
 292
 293 check_function_exists(getopt_long HAVE_GETOPT_LONG)
 294 check_function_exists(strftime HAVE_STRFTIME)
 295 check_function_exists(setlinebuf HAVE_SETLINEBUF)
 296 #
 297 # For Windows,  don't need to waste time checking for fork() or vfork().
 298 #
 299 if(NOT WIN32)
 300   check_function_exists(fork HAVE_FORK)
 301   check_function_exists(vfork HAVE_VFORK)
 302 endif(NOT WIN32)
 303
 304 #
 305 # Some platforms may need -lnsl for getrpcbynumber.
 306 #
 307 cmake_push_check_state()
 308 set(CMAKE_REQUIRED_LIBRARIES ${TCPDUMP_LINK_LIBRARIES})
 309 check_function_exists(getrpcbynumber STDLIBS_HAVE_GETRPCBYNUMBER)
 310 if(STDLIBS_HAVE_GETRPCBYNUMBER)
 311     set(HAVE_GETRPCBYNUMBER TRUE)
 312 else(STDLIBS_HAVE_GETRPCBYNUMBER)
 313     set(CMAKE_REQUIRED_LIBRARIES ${TCPDUMP_LINK_LIBRARIES} nsl)
 314     check_function_exists(getrpcbynumber LIBNSL_HAS_GETRPCBYNUMBER)
 315     if(LIBNSL_HAS_GETRPCBYNUMBER)
 316         set(HAVE_GETRPCBYNUMBER TRUE)
 317         set(TCPDUMP_LINK_LIBRARIES ${TCPDUMP_LINK_LIBRARIES} nsl)
 318     endif(LIBNSL_HAS_GETRPCBYNUMBER)
 319 endif(STDLIBS_HAVE_GETRPCBYNUMBER)
 320 cmake_pop_check_state()
 321
 322 #
 323 # This requires the libraries we require, as ether_ntohost might be
 324 # in one of those libraries.  That means we have to do this after
 325 # we check for those libraries.
 326 #
 327 # You are in a twisty little maze of UN*Xes, all different.
 328 # Some might not have ether_ntohost().
 329 # Some might have it and declare it in <net/ethernet.h>.
 330 # Some might have it and declare it in <netinet/ether.h>
 331 # Some might have it and declare it in <sys/ethernet.h>.
 332 # Some might have it and declare it in <arpa/inet.h>.
 333 # Some might have it and declare it in <netinet/if_ether.h>.
 334 # Some might have it and not declare it in any header file.
 335 #
 336 # Before you is a C compiler.
 337 #
 338 cmake_push_check_state()
 339 set(CMAKE_REQUIRED_LIBRARIES ${TCPDUMP_LINK_LIBRARIES})
 340 check_function_exists(ether_ntohost HAVE_ETHER_NTOHOST)
 341 if(HAVE_ETHER_NTOHOST)
 342     #
 343     # OK, we have ether_ntohost().  We don't check whether it's buggy,
 344     # as we assume any system that has CMake is likely to be new enough
 345     # that, if it has ether_ntohost(), whatever bug is checked for in
 346     # autotools is fixed; we just decide to use it.
 347     #
 348     set(USE_ETHER_NTOHOST TRUE)
 349
 350     #
 351     # Is it declared in <net/ethernet.h>?
 352     #
 353     # This test fails if we don't have <net/ethernet.h> or if we do
 354     # but it doesn't declare ether_ntohost().
 355     #
 356     check_symbol_exists(ether_ntohost net/ethernet.h NET_ETHERNET_H_DECLARES_ETHER_NTOHOST)
 357     if(NET_ETHERNET_H_DECLARES_ETHER_NTOHOST)
 358         #
 359         # Yes - we have it declared.
 360         #
 361         set(HAVE_DECL_ETHER_NTOHOST TRUE)
 362     endif()
 363     #
 364     # Did that succeed?
 365     #
 366     if(NOT HAVE_DECL_ETHER_NTOHOST)
 367         #
 368         # No - how about <netinet/ether.h>, as on Linux?
 369         #
 370         # This test fails if we don't have <netinet/ether.h>
 371         # or if we do but it doesn't declare ether_ntohost().
 372         #
 373         check_symbol_exists(ether_ntohost netinet/ether.h NETINET_ETHER_H_DECLARES_ETHER_NTOHOST)
 374         if(NETINET_ETHER_H_DECLARES_ETHER_NTOHOST)
 375             #
 376             # Yes - we have it declared.
 377             #
 378             set(HAVE_DECL_ETHER_NTOHOST TRUE)
 379         endif()
 380     endif()
 381     #
 382     # Did that succeed?
 383     #
 384     if(NOT HAVE_DECL_ETHER_NTOHOST)
 385         #
 386         # No - how about <sys/ethernet.h>, as on Solaris 10 and later?
 387         #
 388         # This test fails if we don't have <sys/ethernet.h>
 389         # or if we do but it doesn't declare ether_ntohost().
 390         #
 391         check_symbol_exists(ether_ntohost sys/ethernet.h SYS_ETHERNET_H_DECLARES_ETHER_NTOHOST)
 392         if(SYS_ETHERNET_H_DECLARES_ETHER_NTOHOST)
 393             #
 394             # Yes - we have it declared.
 395             #
 396             set(HAVE_DECL_ETHER_NTOHOST TRUE)
 397         endif()
 398     endif()
 399     #
 400     # Did that succeed?
 401     #
 402     if(NOT HAVE_DECL_ETHER_NTOHOST)
 403         #
 404         # No, how about <arpa/inet.h>, as on AIX?
 405         #
 406         # This test fails if we don't have <arpa/inet.h>
 407         # or if we do but it doesn't declare ether_ntohost().
 408         #
 409         check_symbol_exists(ether_ntohost arpa/inet.h ARPA_INET_H_DECLARES_ETHER_NTOHOST)
 410         if(ARPA_INET_H_DECLARES_ETHER_NTOHOST)
 411             #
 412             # Yes - we have it declared.
 413             #
 414             set(HAVE_DECL_ETHER_NTOHOST TRUE)
 415         endif()
 416     endif()
 417     #
 418     # Did that succeed?
 419     #
 420     if(NOT HAVE_DECL_ETHER_NTOHOST)
 421         #
 422         # No, how about <netinet/if_ether.h>?
 423         # On some platforms, it requires <net/if.h> and
 424         # <netinet/in.h>, and we always include it with
 425         # both of them, so test it with both of them.
 426         #
 427         # This test fails if we don't have <netinet/if_ether.h>
 428         # and the headers we include before it, or if we do but
 429         # <netinet/if_ether.h> doesn't declare ether_ntohost().
 430         #
 431         check_symbol_exists(ether_ntohost "sys/types.h;sys/socket.h;net/if.h;netinet/in.h;netinet/if_ether.h" NETINET_IF_ETHER_H_DECLARES_ETHER_NTOHOST)
 432         if(NETINET_IF_ETHER_H_DECLARES_ETHER_NTOHOST)
 433             #
 434             # Yes - we have it declared.
 435             #
 436             set(HAVE_DECL_ETHER_NTOHOST TRUE)
 437         endif()
 438     endif()
 439     #
 440     # After all that, is ether_ntohost() declared?
 441     #
 442     if(NOT HAVE_DECL_ETHER_NTOHOST)
 443         #
 444         # No, we'll have to declare it ourselves.
 445         # Do we have "struct ether_addr" if we include<netinet/if_ether.h>?
 446         #
 447         check_struct_has_member("struct ether_addr" octet "sys/types.h;sys/socket.h;net/if.h;netinet/in.h;netinet/if_ether.h" HAVE_STRUCT_ETHER_ADDR)
 448     endif()
 449 endif()
 450 cmake_pop_check_state()
 451
 452 check_function_exists(dnet_htoa STDLIBS_HAVE_DNET_HTOA)
 453 if(STDLIBS_HAVE_DNET_HTOA)
 454     set(HAVE_DNET_HTOA TRUE)
 455 else(STDLIBS_HAVE_DNET_HTOA)
 456     check_library_exists(dnet dnet_htoa "" HAVE_DNET_HTOA)
 457     if(HAVE_DNET_HTOA)
 458         set(TCPDUMP_LINK_LIBRARIES dnet ${TCPDUMP_LINK_LIBRARIES})
 459     endif(HAVE_DNET_HTOA)
 460 endif(STDLIBS_HAVE_DNET_HTOA)
 461 if(HAVE_DNET_HTOA)
 462     #
 463     # OK, we have dnet_htoa().  Do we have netdnet/dnetdb.h?
 464     #
 465     check_include_files("sys/types.h;netdnet/dnetdb.h" HAVE_NETDNET_DNETDB_H)
 466     if(HAVE_NETDNET_DNETDB_H)
 467         #
 468         # Yes.  Does it declare dnet_htoa()?
 469         #
 470         cmake_push_check_state()
 471         set(CMAKE_REQUIRED_LIBRARIES dnet)
 472         check_symbol_exists(dnet_htoa "sys/types.h;netdnet/dnetdb.h" NETDNET_DNETDB_H_DECLARES_DNET_HTOA)
 473         cmake_pop_check_state()
 474     endif(HAVE_NETDNET_DNETDB_H)
 475
 476     #
 477     # Do we have netdnet/dn.h?
 478     #
 479     check_include_file(netdnet/dn.h HAVE_NETDNET_DN_H)
 480     if(HAVE_NETDNET_DN_H)
 481         #
 482         # Yes.  Does it declare struct dn_naddr?
 483         #
 484         cmake_push_check_state()
 485         set(CMAKE_EXTRA_INCLUDE_FILES netdnet/dn.h)
 486         check_type_size("struct dn_naddr" STRUCT_DN_NADDR)
 487         cmake_pop_check_state()
 488     endif(HAVE_NETDNET_DN_H)
 489 endif(HAVE_DNET_HTOA)
 490
 491 #
 492 # Data types.
 493 #
 494 # XXX - there's no check_struct() macro that's like check_struct_has_member()
 495 # except that it only checks for the existence of the structure type,
 496 # so we use check_struct_has_member() and look for ss_family.
 497 #
 498
 499 #
 500 # Check for IPv6 support.
 501 # We just check for AF_INET6 and struct in6_addr.
 502 #
 503 cmake_push_check_state()
 504 if(WIN32)
 505     set(CMAKE_EXTRA_INCLUDE_FILES sys/types.h ws2tcpip.h)
 506     check_symbol_exists(AF_INET6 "sys/types.h;ws2tcpip.h" HAVE_AF_INET6)
 507 else(WIN32)
 508     set(CMAKE_EXTRA_INCLUDE_FILES sys/types.h sys/socket.h netinet/in.h)
 509     check_symbol_exists(AF_INET6 "sys/types.h;sys/socket.h;netinet/in.h" HAVE_AF_INET6)
 510 endif(WIN32)
 511 check_type_size("struct in6_addr" HAVE_STRUCT_IN6_ADDR)
 512 cmake_pop_check_state()
 513 if(HAVE_AF_INET6 AND HAVE_STRUCT_IN6_ADDR)
 514     set(HAVE_OS_IPV6_SUPPORT TRUE)
 515 endif(HAVE_AF_INET6 AND HAVE_STRUCT_IN6_ADDR)
 516
 517 ######################################
 518 # External dependencies
 519 ######################################
 520
 521 #
 522 # libpcap/WinPcap/Npcap.
 523 # First, find it.
 524 #
 525 find_package(PCAP REQUIRED)
 526 include_directories(${PCAP_INCLUDE_DIRS})
 527
 528 cmake_push_check_state()
 529
 530 #
 531 # Now check headers.
 532 #
 533 set(CMAKE_REQUIRED_INCLUDES ${PCAP_INCLUDE_DIRS})
 534
 535 #
 536 # Check whether we have pcap/pcap-inttypes.h.
 537 # If we do, we use that to get the C99 types defined.
 538 #
 539 check_include_file(pcap/pcap-inttypes.h HAVE_PCAP_PCAP_INTTYPES_H)
 540
 541 #
 542 # Check for various functions in libpcap/WinPcap/Npcap.
 543 #
 544 cmake_push_check_state()
 545 set(CMAKE_REQUIRED_LIBRARIES ${PCAP_LIBRARIES})
 546
 547 #
 548 # Check for "pcap_list_datalinks()" and use a substitute version if
 549 # it's not present.  If it is present, check for "pcap_free_datalinks()";
 550 # if it's not present, we don't replace it for now.  (We could do so
 551 # on UN*X, but not on Windows, where hilarity ensues if a program
 552 # built with one version of the MSVC support library tries to free
 553 # something allocated by a library built with another version of
 554 # the MSVC support library.)
 555 #
 556 check_function_exists(pcap_list_datalinks HAVE_PCAP_LIST_DATALINKS)
 557 if(HAVE_PCAP_LIST_DATALINKS)
 558     check_function_exists(pcap_free_datalinks HAVE_PCAP_FREE_DATALINKS)
 559 endif(HAVE_PCAP_LIST_DATALINKS)
 560
 561 #
 562 # Check for "pcap_datalink_name_to_val()", and use a substitute
 563 # version if it's not present.  If it is present, check for
 564 # "pcap_datalink_val_to_description()", and if we don't have it,
 565 # use a substitute version.
 566 #
 567 check_function_exists(pcap_datalink_name_to_val HAVE_PCAP_DATALINK_NAME_TO_VAL)
 568 if(HAVE_PCAP_DATALINK_NAME_TO_VAL)
 569     check_function_exists(pcap_datalink_val_to_description HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION)
 570 endif(HAVE_PCAP_DATALINK_NAME_TO_VAL)
 571
 572 #
 573 # Check for "pcap_set_datalink()"; you can't substitute for it if
 574 # it's absent (it has hooks into libpcap), so just define the
 575 # HAVE_ value if it's there.
 576 #
 577 check_function_exists(pcap_set_datalink HAVE_PCAP_SET_DATALINK)
 578
 579 #
 580 # Check for "pcap_breakloop()"; you can't substitute for it if
 581 # it's absent (it has hooks into the live capture routines),
 582 # so just define the HAVE_ value if it's there.
 583 #
 584 check_function_exists(pcap_breakloop HAVE_PCAP_BREAKLOOP)
 585
 586 #
 587 # Check for "pcap_dump_ftell()"; we use a substitute version
 588 # if it's not present.
 589 #
 590 check_function_exists(pcap_dump_ftell HAVE_PCAP_DUMP_FTELL)
 591
 592 #
 593 # Do we have the new open API?  Check for pcap_create() and for
 594 # pcap_statustostr(), and assume that, if we have both of them,
 595 # we also have pcap_activate() and the other new routines
 596 # introduced in libpcap 1.0.0.  (We check for pcap_statustostr()
 597 # as well, because WinPcap 4.1.3 screwed up and exported pcap_create()
 598 # but not other routines such as pcap_statustostr(), even though it
 599 # defined them and even though you really want pcap_statustostr() to
 600 # get strings corresponding to some of the status returns from the
 601 # new routines.)
 602 #
 603 check_function_exists(pcap_statustostr HAVE_PCAP_STATUSTOSTR)
 604 #
 605 # If we don't have pcap_statustostr(), don't check for pcap_create(),
 606 # so we pretend we don't have it.
 607 #
 608 if(HAVE_PCAP_STATUSTOSTR)
 609     check_function_exists(pcap_create HAVE_PCAP_CREATE)
 610 endif(HAVE_PCAP_STATUSTOSTR)
 611 if(HAVE_PCAP_CREATE)
 612     #
 613     # OK, do we have pcap_set_tstamp_type?  If so, assume we have
 614     # pcap_list_tstamp_types and pcap_free_tstamp_types as well.
 615     #
 616     check_function_exists(pcap_set_tstamp_type HAVE_PCAP_SET_TSTAMP_TYPE)
 617
 618     #
 619     # And do we have pcap_set_tstamp_precision?  If so, we assume
 620     # we also have pcap_open_offline_with_tstamp_precision.
 621     #
 622     check_function_exists(pcap_set_tstamp_precision HAVE_PCAP_SET_TSTAMP_PRECISION)
 623 endif(HAVE_PCAP_CREATE)
 624
 625 #
 626 # Check for a miscellaneous collection of functions which we use
 627 # if we have them.
 628 #
 629 check_function_exists(pcap_findalldevs HAVE_PCAP_FINDALLDEVS)
 630 if(HAVE_PCAP_FINDALLDEVS)
 631     #
 632     # Check for libpcap having pcap_findalldevs() but the pcap.h header
 633     # not having pcap_if_t; some versions of Mac OS X shipped with pcap.h
 634     # from 0.6 and libpcap 0.8, so that libpcap had pcap_findalldevs but
 635     # pcap.h didn't have pcap_if_t.
 636     #
 637     cmake_push_check_state()
 638     set(CMAKE_REQUIRED_INCLUDES ${PCAP_INCLUDE_DIRS})
 639     set(CMAKE_EXTRA_INCLUDE_FILES pcap.h)
 640     check_type_size(pcap_if_t PCAP_IF_T)
 641     cmake_pop_check_state()
 642 endif(HAVE_PCAP_FINDALLDEVS)
 643 check_function_exists(pcap_dump_flush HAVE_PCAP_DUMP_FLUSH)
 644 check_function_exists(pcap_lib_version HAVE_PCAP_LIB_VERSION)
 645 if(NOT HAVE_PCAP_LIB_VERSION)
 646     # Check for the pcap_version string variable and set HAVE_PCAP_VERSION
 647 endif(NOT HAVE_PCAP_LIB_VERSION)
 648 check_function_exists(pcap_setdirection HAVE_PCAP_SETDIRECTION)
 649 check_function_exists(pcap_set_immediate_mode HAVE_PCAP_SET_IMMEDIATE_MODE)
 650 check_function_exists(pcap_dump_ftell64 HAVE_PCAP_DUMP_FTELL64)
 651 check_function_exists(pcap_open HAVE_PCAP_OPEN)
 652 check_function_exists(pcap_findalldevs_ex HAVE_PCAP_FINDALLDEVS_EX)
 653
 654 #
 655 # On Windows, check for pcap_wsockinit(); if we don't have it, check for
 656 # wsockinit().
 657 #
 658 if(WIN32)
 659     check_function_exists(pcap_wsockinit HAVE_PCAP_WSOCKINIT)
 660     if(NOT HAVE_PCAP_WSOCKINIT)
 661         check_function_exists(wsockinit HAVE_WSOCKINIT)
 662     endif(NOT HAVE_PCAP_WSOCKINIT)
 663 endif(WIN32)
 664
 665 #
 666 # Check for special debugging functions
 667 #
 668 check_function_exists(pcap_set_parser_debug HAVE_PCAP_SET_PARSER_DEBUG)
 669 if(NOT HAVE_PCAP_SET_PARSER_DEBUG)
 670     # Check whether libpcap defines pcap_debug or yydebug
 671     check_variable_exists(pcap_debug HAVE_PCAP_DEBUG)
 672     if(NOT HAVE_PCAP_DEBUG)
 673         check_variable_exists(yydebug HAVE_YYDEBUG)
 674     endif(NOT HAVE_PCAP_DEBUG)
 675 endif(NOT HAVE_PCAP_SET_PARSER_DEBUG)
 676
 677 check_function_exists(pcap_set_optimizer_debug HAVE_PCAP_SET_OPTIMIZER_DEBUG)
 678 check_function_exists(bpf_dump HAVE_BPF_DUMP)
 679
 680 cmake_pop_check_state()
 681
 682 #
 683 # We have libpcap.
 684 #
 685 include_directories(SYSTEM ${PCAP_INCLUDE_DIRS})
 686 set(TCPDUMP_LINK_LIBRARIES ${PCAP_LIBRARIES} ${TCPDUMP_LINK_LIBRARIES})
 687
 688 #
 689 # Optional libraries.
 690 #
 691
 692 #
 693 # libsmi.
 694 #
 695 if(WITH_SMI)
 696     find_package(SMI)
 697     if(SMI_FOUND)
 698         include_directories(SYSTEM ${SMI_INCLUDE_DIRS})
 699         set(TCPDUMP_LINK_LIBRARIES ${TCPDUMP_LINK_LIBRARIES} ${SMI_LIBRARIES})
 700         set(USE_LIBSMI ON)
 701     endif(SMI_FOUND)
 702 endif(WITH_SMI)
 703
 704 #
 705 # OpenSSL/libressl libcrypto.
 706 #
 707 if(WITH_CRYPTO)
 708     find_package(CRYPTO)
 709     if(CRYPTO_FOUND)
 710         #
 711         # Check for some headers and functions.
 712         #
 713         cmake_push_check_state()
 714         set(CMAKE_REQUIRED_LIBRARIES crypto)
 715
 716         check_include_file(openssl/evp.h HAVE_OPENSSL_EVP_H)
 717
 718         #
 719         # 1) do we have EVP_CIPHER_CTX_new?
 720         # If so, we use it to allocate an EVP_CIPHER_CTX, as
 721         # EVP_CIPHER_CTX may be opaque; otherwise, we allocate
 722         # it ourselves.
 723         #
 724         check_function_exists(EVP_CIPHER_CTX_new HAVE_EVP_CIPHER_CTX_NEW)
 725
 726         #
 727         # 2) do we have EVP_CipherInit_ex()?
 728         # If so, we use it, because we need to be able to make two
 729         # "initialize the cipher" calls, one with the cipher and key,
 730         # and one with the IV, and, as of OpenSSL 1.1, You Can't Do That
 731         # with EVP_CipherInit(), because a call to EVP_CipherInit() will
 732         # unconditionally clear the context, and if you don't supply a
 733         # cipher, it'll clear the cipher, rendering the context unusable
 734         # and causing a crash.
 735         #
 736         check_function_exists(EVP_CipherInit_ex HAVE_EVP_CIPHERINIT_EX)
 737
 738         cmake_pop_check_state()
 739
 740         #
 741         # We have libcrypto.
 742         #
 743         include_directories(SYSTEM ${CRYPTO_INCLUDE_DIRS})
 744         set(TCPDUMP_LINK_LIBRARIES ${TCPDUMP_LINK_LIBRARIES} ${CRYPTO_LIBRARIES})
 745         set(HAVE_LIBCRYPTO ON)
 746     endif(CRYPTO_FOUND)
 747 endif(WITH_CRYPTO)
 748
 749 #
 750 # Capsicum sandboxing.
 751 # Some of this is in the system library, some of it is in other libraries.
 752 #
 753 if(WITH_CAPSICUM)
 754     check_include_files("sys/capsicum.h" HAVE_SYS_CAPSICUM_H)
 755     if(HAVE_SYS_CAPSICUM_H)
 756         check_function_exists(cap_enter HAVE_CAP_ENTER)
 757         check_function_exists(cap_rights_limit HAVE_CAP_RIGHTS_LIMIT)
 758         check_function_exists(cap_ioctls_limit HAVE_CAP_IOCTLS_LIMIT)
 759         check_function_exists(openat HAVE_OPENAT)
 760         if(HAVE_CAP_ENTER AND HAVE_CAP_RIGHTS_LIMIT AND
 761            HAVE_CAP_IOCTLS_LIMIT AND HAVE_OPENAT)
 762             #
 763             # OK, we have the functions we need to support Capsicum.
 764             #
 765             set(HAVE_CAPSICUM TRUE)
 766
 767             #
 768             # OK, can we use Casper?
 769             #
 770             check_library_exists(casper cap_init "" HAVE_CAP_INIT)
 771             if(HAVE_CAP_INIT)
 772                 cmake_push_check_state()
 773                 set(CMAKE_REQUIRED_LIBRARIES casper)
 774                 check_library_exists(cap_dns cap_gethostbyaddr "" HAVE_CAP_GETHOSTBYADDR)
 775                 cmake_pop_check_state()
 776                 if(HAVE_CAP_GETHOSTBYADDR)
 777                     set(HAVE_CASPER TRUE)
 778                     set(TCPDUMP_LINK_LIBRARIES ${TCPDUMP_LINK_LIBRARIES} casper cap_dns)
 779                 endif(HAVE_CAP_GETHOSTBYADDR)
 780             endif(HAVE_CAP_INIT)
 781         endif(HAVE_CAP_ENTER AND HAVE_CAP_RIGHTS_LIMIT AND
 782               HAVE_CAP_IOCTLS_LIMIT AND HAVE_OPENAT)
 783     endif(HAVE_SYS_CAPSICUM_H)
 784 endif(WITH_CAPSICUM)
 785
 786 #
 787 # libcap-ng.
 788 #
 789 if(WITH_CAP_NG)
 790     check_include_file(cap-ng.h HAVE_CAP_NG_H)
 791     check_library_exists(cap-ng capng_change_id "" HAVE_LIBCAP_NG)
 792     if(HAVE_LIBCAP_NG)
 793         set(TCPDUMP_LINK_LIBRARIES ${TCPDUMP_LINK_LIBRARIES} cap-ng)
 794     endif(HAVE_LIBCAP_NG)
 795 endif(WITH_CAP_NG)
 796
 797 ###################################################################
 798 #   Warning options
 799 ###################################################################
 800
 801 #
 802 # Check and add warning options if we have a .devel file.
 803 #
 804 if(EXISTS ${CMAKE_SOURCE_DIR}/.devel OR EXISTS ${CMAKE_BINARY_DIR}/.devel)
 805     #
 806     # Warning options.
 807     #
 808     if(MSVC AND NOT ${CMAKE_C_COMPILER} MATCHES "clang*")
 809         #
 810         # MSVC, with Microsoft's front end and code generator.
 811         # "MSVC" is also set for Microsoft's compiler with a Clang
 812         # front end and their code generator ("Clang/C2"), so we
 813         # check for clang.exe and treat that differently.
 814         #
 815         check_and_add_compiler_option(-Wall)
 816         #
 817         # Disable some pointless warnings that /Wall turns on.
 818         #
 819         # Unfortunately, MSVC does not appear to have an equivalent
 820         # to "__attribute__((unused))" to mark a particular function
 821         # parameter as being known to be unused, so that the compiler
 822         # won't warn about it (for example, the function might have
 823         # that parameter because a pointer to it is being used, and
 824         # the signature of that function includes that parameter).
 825         # C++ lets you give a parameter a type but no name, but C
 826         # doesn't have that.
 827         #
 828         check_and_add_compiler_option(-wd4100)
 829         #
 830         # In theory, we care whether somebody uses f() rather than
 831         # f(void) to declare a function with no arguments, but, in
 832         # practice, there are places in the Windows header files
 833         # that appear to do that, so we squelch that warning.
 834         #
 835         check_and_add_compiler_option(-wd4255)
 836         #
 837         # Windows FD_SET() generates this, so we suppress it.
 838         #
 839         check_and_add_compiler_option(-wd4548)
 840         #
 841         # Perhaps testing something #defined to be 0 with #ifdef is an
 842         # error, and it should be tested with #if, but perhaps it's
 843         # not, and Microsoft does that in its headers, so we squelch
 844         # that warning.
 845         #
 846         check_and_add_compiler_option(-wd4574)
 847         #
 848         # The Windows headers also test not-defined values in #if, so
 849         # we don't want warnings about that, either.
 850         #
 851         check_and_add_compiler_option(-wd4668)
 852         #
 853         # We do *not* care whether some function is, or isn't, going to be
 854         # expanded inline.
 855         #
 856         check_and_add_compiler_option(-wd4710)
 857         check_and_add_compiler_option(-wd4711)
 858         #
 859         # We do *not* care whether we're adding padding bytes after
 860         # structure members.
 861         #
 862         check_and_add_compiler_option(-wd4820)
 863         #
 864         # We do *not* care about every single place the compiler would
 865         # have inserted Spectre mitigation if only we had told it to
 866         # do so with /Qspectre.  I guess the theory is that it's seeing
 867         # bounds checks that would prevent out-of-bounds loads and that
 868         # those out-of-bounds loads could be done speculatively and that
 869         # the Spectre attack could detect the value of the out-of-bounds
 870         # data *if* it's within our address space, but unless I'm
 871         # missing something I don't see that as being any form of
 872         # security hole.
 873         #
 874         # XXX - add /Qspectre if that is really worth doing.
 875         #
 876         check_and_add_compiler_option(-wd5045)
 877         #
 878         # We do *not* care whether a structure had padding added at
 879         # the end because of __declspec(align) - *we* don't use
 880         # __declspec(align), because the only structures whose layout
 881         # we precisely specify are those that get overlayed on packet
 882         # data, and in those every element is an array of octets so
 883         # that we have full control over the size and aligmnet, and,
 884         # apparently, jmp_buf has such a declaration on x86, meaning
 885         # that everything that includes netdissect.h, i.e. almost every
 886         # file in tcpdump, gets a warning.
 887         #
 888         check_and_add_compiler_option(-wd4324)
 889     else()
 890         #
 891         # Other compilers, including MSVC with a Clang front end and
 892         # Microsoft's code generator.  We currently treat them as if
 893         # they might support GCC-style -W options.
 894         #
 895         check_and_add_compiler_option(-W)
 896         check_and_add_compiler_option(-Wall)
 897         check_and_add_compiler_option(-Wassign-enum)
 898         check_and_add_compiler_option(-Wcast-qual)
 899         check_and_add_compiler_option(-Wmissing-prototypes)
 900         check_and_add_compiler_option(-Wold-style-definition)
 901         check_and_add_compiler_option(-Wpedantic)
 902         check_and_add_compiler_option(-Wpointer-arith)
 903         check_and_add_compiler_option(-Wpointer-sign)
 904         check_and_add_compiler_option(-Wshadow)
 905         check_and_add_compiler_option(-Wsign-compare)
 906         check_and_add_compiler_option(-Wstrict-prototypes)
 907         check_and_add_compiler_option(-Wunreachable-code-return)
 908         check_and_add_compiler_option(-Wused-but-marked-unused)
 909         check_and_add_compiler_option(-Wwrite-strings)
 910     endif()
 911 endif()
 912
 913 ######################################
 914 # Input files
 915 ######################################
 916
 917 if(ENABLE_SMB)
 918     #
 919     # We allow the SMB dissector to be omitted.
 920     #
 921     set(LOCALSRC ${LOCALSRC}
 922         print-smb.c
 923         smbutil.c)
 924 endif(ENABLE_SMB)
 925
 926 set(NETDISSECT_SOURCE_LIST_C
 927     addrtoname.c
 928     addrtostr.c
 929     af.c
 930     ascii_strcasecmp.c
 931     checksum.c
 932     cpack.c
 933     gmpls.c
 934     in_cksum.c
 935     ipproto.c
 936     l2vpn.c
 937     machdep.c
 938     netdissect.c
 939     netdissect-alloc.c
 940     nlpid.c
 941     oui.c
 942     parsenfsfh.c
 943     print.c
 944     print-802_11.c
 945     print-802_15_4.c
 946     print-ah.c
 947     print-ahcp.c
 948     print-aodv.c
 949     print-aoe.c
 950     print-ap1394.c
 951     print-arcnet.c
 952     print-arista.c
 953     print-arp.c
 954     print-ascii.c
 955     print-atalk.c
 956     print-atm.c
 957     print-babel.c
 958     print-beep.c
 959     print-bfd.c
 960     print-bgp.c
 961     print-bootp.c
 962     print-brcmtag.c
 963     print-bt.c
 964     print-calm-fast.c
 965     print-carp.c
 966     print-cdp.c
 967     print-cfm.c
 968     print-chdlc.c
 969     print-cip.c
 970     print-cnfp.c
 971     print-dccp.c
 972     print-decnet.c
 973     print-dhcp6.c
 974     print-domain.c
 975     print-dsa.c
 976     print-dtp.c
 977     print-dvmrp.c
 978     print-eap.c
 979     print-egp.c
 980     print-eigrp.c
 981     print-enc.c
 982     print-esp.c
 983     print-ether.c
 984     print-fddi.c
 985     print-forces.c
 986     print-fr.c
 987     print-frag6.c
 988     print-ftp.c
 989     print-geneve.c
 990     print-geonet.c
 991     print-gre.c
 992     print-hncp.c
 993     print-hsrp.c
 994     print-http.c
 995     print-icmp.c
 996     print-icmp6.c
 997     print-igmp.c
 998     print-igrp.c
 999     print-ip.c
1000     print-ip-demux.c
1001     print-ip6.c
1002     print-ip6opts.c
1003     print-ipcomp.c
1004     print-ipfc.c
1005     print-ipnet.c
1006     print-ipoib.c
1007     print-ipx.c
1008     print-isakmp.c
1009     print-isoclns.c
1010     print-juniper.c
1011     print-krb.c
1012     print-l2tp.c
1013     print-lane.c
1014     print-ldp.c
1015     print-lisp.c
1016     print-llc.c
1017     print-lldp.c
1018     print-lmp.c
1019     print-loopback.c
1020     print-lspping.c
1021     print-lwapp.c
1022     print-lwres.c
1023     print-m3ua.c
1024     print-mobile.c
1025     print-mobility.c
1026     print-mpcp.c
1027     print-mpls.c
1028     print-mptcp.c
1029     print-msdp.c
1030     print-msnlb.c
1031     print-nflog.c
1032     print-nfs.c
1033     print-nsh.c
1034     print-ntp.c
1035     print-null.c
1036     print-olsr.c
1037     print-openflow-1.0.c
1038     print-openflow.c
1039     print-ospf.c
1040     print-ospf6.c
1041     print-otv.c
1042     print-pgm.c
1043     print-pim.c
1044     print-pktap.c
1045     print-ppi.c
1046     print-ppp.c
1047     print-pppoe.c
1048     print-pptp.c
1049     print-radius.c
1050     print-raw.c
1051     print-resp.c
1052     print-rip.c
1053     print-ripng.c
1054     print-rpki-rtr.c
1055     print-rrcp.c
1056     print-rsvp.c
1057     print-rt6.c
1058     print-rtsp.c
1059     print-rx.c
1060     print-sctp.c
1061     print-sflow.c
1062     print-sip.c
1063     print-sl.c
1064     print-sll.c
1065     print-slow.c
1066     print-smtp.c
1067     print-snmp.c
1068     print-ssh.c
1069     print-stp.c
1070     print-sunatm.c
1071     print-sunrpc.c
1072     print-symantec.c
1073     print-syslog.c
1074     print-tcp.c
1075     print-telnet.c
1076     print-tftp.c
1077     print-timed.c
1078     print-tipc.c
1079     print-token.c
1080     print-udld.c
1081     print-udp.c
1082     print-usb.c
1083     print-vjc.c
1084     print-vqp.c
1085     print-vrrp.c
1086     print-vsock.c
1087     print-vtp.c
1088     print-vxlan.c
1089     print-vxlan-gpe.c
1090     print-wb.c
1091     print-zep.c
1092     print-zephyr.c
1093     print-zeromq.c
1094     ${LOCALSRC}
1095     signature.c
1096     strtoaddr.c
1097     util-print.c
1098 )
1099
1100 #
1101 # Replace missing functions
1102 #
1103 foreach(FUNC strlcat strlcpy strdup strsep getservent getopt_long)
1104     string(TOUPPER ${FUNC} FUNC_UPPERCASE)
1105     set(HAVE_FUNC_UPPERCASE HAVE_${FUNC_UPPERCASE})
1106     if(NOT ${HAVE_FUNC_UPPERCASE})
1107         set(NETDISSECT_SOURCE_LIST_C ${NETDISSECT_SOURCE_LIST_C} missing/${FUNC}.c)
1108     endif()
1109 endforeach()
1110
1111 add_library(netdissect STATIC
1112     ${NETDISSECT_SOURCE_LIST_C}
1113 )
1114 if(NOT C_ADDITIONAL_FLAGS STREQUAL "")
1115     set_target_properties(netdissect PROPERTIES COMPILE_FLAGS ${C_ADDITIONAL_FLAGS})
1116 endif()
1117
1118 set(TCPDUMP_SOURCE_LIST_C tcpdump.c)
1119
1120 if(NOT HAVE_BPF_DUMP)
1121     set(TCPDUMP_SOURCE_LIST_C ${TCPDUMP_SOURCE_LIST_C} bpf_dump.c)
1122 endif(NOT HAVE_BPF_DUMP)
1123 if(NOT HAVE_PCAP_DUMP_FTELL)
1124     set(TCPDUMP_SOURCE_LIST_C ${TCPDUMP_SOURCE_LIST_C} missing/pcap_dump_ftell.c)
1125 endif(NOT HAVE_PCAP_DUMP_FTELL)
1126
1127 if(NOT HAVE_PCAP_LIST_DATALINKS)
1128     set(TCPDUMP_SOURCE_LIST_C ${TCPDUMP_SOURCE_LIST_C} missing/datalinks.c)
1129 endif(NOT HAVE_PCAP_LIST_DATALINKS)
1130
1131 if((NOT HAVE_PCAP_DATALINK_NAME_TO_VAL) OR (NOT HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION))
1132     set(TCPDUMP_SOURCE_LIST_C ${TCPDUMP_SOURCE_LIST_C} missing/dlnames.c)
1133 endif((NOT HAVE_PCAP_DATALINK_NAME_TO_VAL) OR (NOT HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION))
1134
1135 set(PROJECT_SOURCE_LIST_C ${NETDISSECT_SOURCE_LIST_C} ${TCPDUMP_SOURCE_LIST_C})
1136
1137 file(GLOB PROJECT_SOURCE_LIST_H
1138     *.h
1139 )
1140
1141 source_group("Source Files" FILES ${PROJECT_SOURCE_LIST_C})
1142 source_group("Header Files" FILES ${PROJECT_SOURCE_LIST_H})
1143
1144 ######################################
1145 # Register targets
1146 ######################################
1147
1148 add_executable(tcpdump ${TCPDUMP_SOURCE_LIST_C})
1149 if(NOT C_ADDITIONAL_FLAGS STREQUAL "")
1150     set_target_properties(tcpdump PROPERTIES COMPILE_FLAGS ${C_ADDITIONAL_FLAGS})
1151 endif()
1152 target_link_libraries(tcpdump netdissect ${TCPDUMP_LINK_LIBRARIES})
1153
1154 ######################################
1155 # Write out the config.h file
1156 ######################################
1157
1158 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/cmakeconfig.h.in ${CMAKE_CURRENT_BINARY_DIR}/config.h)
1159
1160 ######################################
1161 # Install tcpdump and man pages
1162 ######################################
1163
1164 #
1165 # "Define GNU standard installation directories", which actually
1166 # are also defined, to some degree, by autotools, and at least
1167 # some of which are general UN*X conventions.
1168 #
1169 include(GNUInstallDirs)
1170
1171 set(MAN1_EXPAND tcpdump.1.in)
1172
1173 if(WIN32)
1174     # XXX TODO where to install on Windows?
1175 else(WIN32)
1176     install(TARGETS tcpdump DESTINATION sbin)
1177 endif(WIN32)
1178
1179 # On UN*X, and on Windows when not using MSVC, process man pages and
1180 # arrange that they be installed.
1181 if(NOT MSVC)
1182     #
1183     # Man pages.
1184     #
1185     # For each section of the manual for which we have man pages
1186     # that require macro expansion, do the expansion.
1187     #
1188     set(MAN1 "")
1189     foreach(TEMPLATE_MANPAGE ${MAN1_EXPAND})
1190         string(REPLACE ".in" "" MANPAGE ${TEMPLATE_MANPAGE})
1191         configure_file(${CMAKE_SOURCE_DIR}/${TEMPLATE_MANPAGE} ${CMAKE_CURRENT_BINARY_DIR}/${MANPAGE} @ONLY)
1192         set(MAN1 ${MAN1} ${CMAKE_CURRENT_BINARY_DIR}/${MANPAGE})
1193     endforeach(TEMPLATE_MANPAGE)
1194     install(FILES ${MAN1} DESTINATION ${CMAKE_INSTALL_MANDIR}/man1)
1195 endif(NOT MSVC)
1196
1197 # uninstall target
1198 configure_file(
1199     "${CMAKE_CURRENT_SOURCE_DIR}/cmake_uninstall.cmake.in"
1200     "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
1201     IMMEDIATE @ONLY)
1202
1203 add_custom_target(uninstall
1204     COMMAND ${CMAKE_COMMAND} -P ${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake)
1205
1206 #
1207 # Tcpdump tests
1208 #
1209 add_custom_target(check
1210     COMMAND ./TESTrun.sh
1211     WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/tests)