The Tcpdump Group git mirrors - tcpdump/blob - aclocal.m4

   1 dnl Copyright (c) 1995, 1996, 1997, 1998
   2 dnl     The Regents of the University of California.  All rights reserved.
   3 dnl
   4 dnl Redistribution and use in source and binary forms, with or without
   5 dnl modification, are permitted provided that: (1) source code distributions
   6 dnl retain the above copyright notice and this paragraph in its entirety, (2)
   7 dnl distributions including binary code include the above copyright notice and
   8 dnl this paragraph in its entirety in the documentation or other materials
   9 dnl provided with the distribution, and (3) all advertising materials mentioning
  10 dnl features or use of this software display the following acknowledgement:
  11 dnl ``This product includes software developed by the University of California,
  12 dnl Lawrence Berkeley Laboratory and its contributors.'' Neither the name of
  13 dnl the University nor the names of its contributors may be used to endorse
  14 dnl or promote products derived from this software without specific prior
  15 dnl written permission.
  16 dnl THIS SOFTWARE IS PROVIDED ``AS IS'' AND WITHOUT ANY EXPRESS OR IMPLIED
  17 dnl WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED WARRANTIES OF
  18 dnl MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE.
  19 dnl
  20 dnl LBL autoconf macros
  21 dnl
  22
  23 dnl
  24 dnl Do whatever AC_LBL_C_INIT work is necessary before using AC_PROG_CC.
  25 dnl
  26 dnl It appears that newer versions of autoconf (2.64 and later) will,
  27 dnl if you use AC_TRY_COMPILE in a macro, stick AC_PROG_CC at the
  28 dnl beginning of the macro, even if the macro itself calls AC_PROG_CC.
  29 dnl See the "Prerequisite Macros" and "Expanded Before Required" sections
  30 dnl in the Autoconf documentation.
  31 dnl
  32 dnl This causes a steaming heap of fail in our case, as we were, in
  33 dnl AC_LBL_C_INIT, doing the tests we now do in AC_LBL_C_INIT_BEFORE_CC,
  34 dnl calling AC_PROG_CC, and then doing the tests we now do in
  35 dnl AC_LBL_C_INIT.  Now, we run AC_LBL_C_INIT_BEFORE_CC, AC_PROG_CC,
  36 dnl and AC_LBL_C_INIT at the top level.
  37 dnl
  38 AC_DEFUN(AC_LBL_C_INIT_BEFORE_CC,
  39 [
  40     AC_BEFORE([$0], [AC_LBL_C_INIT])
  41     AC_BEFORE([$0], [AC_PROG_CC])
  42     AC_BEFORE([$0], [AC_LBL_FIXINCLUDES])
  43     AC_BEFORE([$0], [AC_LBL_DEVEL])
  44     AC_ARG_WITH(gcc, [  --without-gcc           don't use gcc])
  45     $1=""
  46     if test "${srcdir}" != "." ; then
  47             $1="-I$srcdir"
  48     fi
  49     if test "${CFLAGS+set}" = set; then
  50             LBL_CFLAGS="$CFLAGS"
  51     fi
  52     if test -z "$CC" ; then
  53             case "$host_os" in
  54
  55             bsdi*)
  56                     AC_CHECK_PROG(SHLICC2, shlicc2, yes, no)
  57                     if test $SHLICC2 = yes ; then
  58                             CC=shlicc2
  59                             export CC
  60                     fi
  61                     ;;
  62             esac
  63     fi
  64     if test -z "$CC" -a "$with_gcc" = no ; then
  65             CC=cc
  66             export CC
  67     fi
  68 ])
  69
  70 dnl
  71 dnl Determine which compiler we're using (cc or gcc)
  72 dnl If using gcc, determine the version number
  73 dnl If using cc:
  74 dnl     require that it support ansi prototypes
  75 dnl     use -O (AC_PROG_CC will use -g -O2 on gcc, so we don't need to
  76 dnl     do that ourselves for gcc)
  77 dnl     add -g flags, as appropriate
  78 dnl     explicitly specify /usr/local/include
  79 dnl
  80 dnl NOTE WELL: with newer versions of autoconf, "gcc" means any compiler
  81 dnl that defines __GNUC__, which means clang, for example, counts as "gcc".
  82 dnl
  83 dnl usage:
  84 dnl
  85 dnl     AC_LBL_C_INIT(copt, incls)
  86 dnl
  87 dnl results:
  88 dnl
  89 dnl     $1 (copt set)
  90 dnl     $2 (incls set)
  91 dnl     CC
  92 dnl     LDFLAGS
  93 dnl     LBL_CFLAGS
  94 dnl
  95 AC_DEFUN(AC_LBL_C_INIT,
  96 [
  97     AC_BEFORE([$0], [AC_LBL_FIXINCLUDES])
  98     AC_BEFORE([$0], [AC_LBL_DEVEL])
  99     AC_BEFORE([$0], [AC_LBL_SHLIBS_INIT])
 100     if test "$GCC" = yes ; then
 101             #
 102             # -Werror forces warnings to be errors.
 103             #
 104             ac_lbl_cc_force_warning_errors=-Werror
 105     else
 106             $2="$$2 -I/usr/local/include"
 107             LDFLAGS="$LDFLAGS -L/usr/local/lib"
 108
 109             case "$host_os" in
 110
 111             darwin*)
 112                     #
 113                     # This is assumed either to be GCC or clang, both
 114                     # of which use -Werror to force warnings to be errors.
 115                     #
 116                     ac_lbl_cc_force_warning_errors=-Werror
 117                     ;;
 118
 119             hpux*)
 120                     #
 121                     # HP C, which is what we presume we're using, doesn't
 122                     # exit with a non-zero exit status if we hand it an
 123                     # invalid -W flag, can't be forced to do so even with
 124                     # +We, and doesn't handle GCC-style -W flags, so we
 125                     # don't want to try using GCC-style -W flags.
 126                     #
 127                     ac_lbl_cc_dont_try_gcc_dashW=yes
 128                     ;;
 129
 130             irix*)
 131                     #
 132                     # MIPS C, which is what we presume we're using, doesn't
 133                     # necessarily exit with a non-zero exit status if we
 134                     # hand it an invalid -W flag, can't be forced to do
 135                     # so, and doesn't handle GCC-style -W flags, so we
 136                     # don't want to try using GCC-style -W flags.
 137                     #
 138                     ac_lbl_cc_dont_try_gcc_dashW=yes
 139                     #
 140                     # It also, apparently, defaults to "char" being
 141                     # unsigned, unlike most other C implementations;
 142                     # I suppose we could say "signed char" whenever
 143                     # we want to guarantee a signed "char", but let's
 144                     # just force signed chars.
 145                     #
 146                     # -xansi is normally the default, but the
 147                     # configure script was setting it; perhaps -cckr
 148                     # was the default in the Old Days.  (Then again,
 149                     # that would probably be for backwards compatibility
 150                     # in the days when ANSI C was Shiny and New, i.e.
 151                     # 1989 and the early '90's, so maybe we can just
 152                     # drop support for those compilers.)
 153                     #
 154                     # -g is equivalent to -g2, which turns off
 155                     # optimization; we choose -g3, which generates
 156                     # debugging information but doesn't turn off
 157                     # optimization (even if the optimization would
 158                     # cause inaccuracies in debugging).
 159                     #
 160                     $1="$$1 -xansi -signed -g3"
 161                     ;;
 162
 163             osf*)
 164                     #
 165                     # Presumed to be DEC OSF/1, Digital UNIX, or
 166                     # Tru64 UNIX.
 167                     #
 168                     # The DEC C compiler, which is what we presume we're
 169                     # using, doesn't exit with a non-zero exit status if we
 170                     # hand it an invalid -W flag, can't be forced to do
 171                     # so, and doesn't handle GCC-style -W flags, so we
 172                     # don't want to try using GCC-style -W flags.
 173                     #
 174                     ac_lbl_cc_dont_try_gcc_dashW=yes
 175                     #
 176                     # -g is equivalent to -g2, which turns off
 177                     # optimization; we choose -g3, which generates
 178                     # debugging information but doesn't turn off
 179                     # optimization (even if the optimization would
 180                     # cause inaccuracies in debugging).
 181                     #
 182                     $1="$$1 -g3"
 183                     ;;
 184
 185             solaris*)
 186                     #
 187                     # Assumed to be Sun C, which requires -errwarn to force
 188                     # warnings to be treated as errors.
 189                     #
 190                     ac_lbl_cc_force_warning_errors=-errwarn
 191                     ;;
 192
 193             ultrix*)
 194                     AC_MSG_CHECKING(that Ultrix $CC hacks const in prototypes)
 195                     AC_CACHE_VAL(ac_cv_lbl_cc_const_proto,
 196                         AC_TRY_COMPILE(
 197                             [#include <sys/types.h>],
 198                             [struct a { int b; };
 199                             void c(const struct a *)],
 200                             ac_cv_lbl_cc_const_proto=yes,
 201                             ac_cv_lbl_cc_const_proto=no))
 202                     AC_MSG_RESULT($ac_cv_lbl_cc_const_proto)
 203                     if test $ac_cv_lbl_cc_const_proto = no ; then
 204                             AC_DEFINE(const,[],
 205                                 [to handle Ultrix compilers that don't support const in prototypes])
 206                     fi
 207                     ;;
 208             esac
 209             $1="$$1 -O"
 210     fi
 211 ])
 212
 213 dnl
 214 dnl Check whether, if you pass an unknown warning option to the
 215 dnl compiler, it fails or just prints a warning message and succeeds.
 216 dnl Set ac_lbl_unknown_warning_option_error to the appropriate flag
 217 dnl to force an error if it would otherwise just print a warning message
 218 dnl and succeed.
 219 dnl
 220 AC_DEFUN(AC_LBL_CHECK_UNKNOWN_WARNING_OPTION_ERROR,
 221     [
 222         AC_MSG_CHECKING([whether the compiler fails when given an unknown warning option])
 223         save_CFLAGS="$CFLAGS"
 224         CFLAGS="$CFLAGS -Wxyzzy-this-will-never-succeed-xyzzy"
 225         AC_TRY_COMPILE(
 226             [],
 227             [return 0],
 228             [
 229                 AC_MSG_RESULT([no])
 230                 #
 231                 # We're assuming this is clang, where
 232                 # -Werror=unknown-warning-option is the appropriate
 233                 # option to force the compiler to fail.
 234                 #
 235                 ac_lbl_unknown_warning_option_error="-Werror=unknown-warning-option"
 236             ],
 237             [
 238                 AC_MSG_RESULT([yes])
 239             ])
 240         CFLAGS="$save_CFLAGS"
 241     ])
 242
 243 dnl
 244 dnl Check whether the compiler option specified as the second argument
 245 dnl is supported by the compiler and, if so, add it to the macro
 246 dnl specified as the first argument
 247 dnl
 248 AC_DEFUN(AC_LBL_CHECK_COMPILER_OPT,
 249     [
 250         AC_MSG_CHECKING([whether the compiler supports the $2 option])
 251         save_CFLAGS="$CFLAGS"
 252         if expr "x$2" : "x-W.*" >/dev/null
 253         then
 254             CFLAGS="$CFLAGS $ac_lbl_unknown_warning_option_error $2"
 255         elif expr "x$2" : "x-f.*" >/dev/null
 256         then
 257             CFLAGS="$CFLAGS -Werror $2"
 258         elif expr "x$2" : "x-m.*" >/dev/null
 259         then
 260             CFLAGS="$CFLAGS -Werror $2"
 261         else
 262             CFLAGS="$CFLAGS $2"
 263         fi
 264         AC_TRY_COMPILE(
 265             [],
 266             [return 0],
 267             [
 268                 AC_MSG_RESULT([yes])
 269                 CFLAGS="$save_CFLAGS"
 270                 $1="$$1 $2"
 271             ],
 272             [
 273                 AC_MSG_RESULT([no])
 274                 CFLAGS="$save_CFLAGS"
 275             ])
 276     ])
 277
 278 dnl
 279 dnl Check whether the compiler supports an option to generate
 280 dnl Makefile-style dependency lines
 281 dnl
 282 dnl GCC uses -M for this.  Non-GCC compilers that support this
 283 dnl use a variety of flags, including but not limited to -M.
 284 dnl
 285 dnl We test whether the flag in question is supported, as older
 286 dnl versions of compilers might not support it.
 287 dnl
 288 dnl We don't try all the possible flags, just in case some flag means
 289 dnl "generate dependencies" on one compiler but means something else
 290 dnl on another compiler.
 291 dnl
 292 dnl Most compilers that support this send the output to the standard
 293 dnl output by default.  IBM's XLC, however, supports -M but sends
 294 dnl the output to {sourcefile-basename}.u, and AIX has no /dev/stdout
 295 dnl to work around that, so we don't bother with XLC.
 296 dnl
 297 AC_DEFUN(AC_LBL_CHECK_DEPENDENCY_GENERATION_OPT,
 298     [
 299         AC_MSG_CHECKING([whether the compiler supports generating dependencies])
 300         if test "$GCC" = yes ; then
 301                 #
 302                 # GCC, or a compiler deemed to be GCC by AC_PROG_CC (even
 303                 # though it's not); we assume that, in this case, the flag
 304                 # would be -M.
 305                 #
 306                 ac_lbl_dependency_flag="-M"
 307         else
 308                 #
 309                 # Not GCC or a compiler deemed to be GCC; what platform is
 310                 # this?  (We're assuming that if the compiler isn't GCC
 311                 # it's the compiler from the vendor of the OS; that won't
 312                 # necessarily be true for x86 platforms, where it might be
 313                 # the Intel C compiler.)
 314                 #
 315                 case "$host_os" in
 316
 317                 irix*|osf*|darwin*)
 318                         #
 319                         # MIPS C for IRIX, DEC C, and clang all use -M.
 320                         #
 321                         ac_lbl_dependency_flag="-M"
 322                         ;;
 323
 324                 solaris*)
 325                         #
 326                         # Sun C uses -xM.
 327                         #
 328                         ac_lbl_dependency_flag="-xM"
 329                         ;;
 330
 331                 hpux*)
 332                         #
 333                         # HP's older C compilers don't support this.
 334                         # HP's newer C compilers support this with
 335                         # either +M or +Make; the older compilers
 336                         # interpret +M as something completely
 337                         # different, so we use +Make so we don't
 338                         # think it works with the older compilers.
 339                         #
 340                         ac_lbl_dependency_flag="+Make"
 341                         ;;
 342
 343                 *)
 344                         #
 345                         # Not one of the above; assume no support for
 346                         # generating dependencies.
 347                         #
 348                         ac_lbl_dependency_flag=""
 349                         ;;
 350                 esac
 351         fi
 352
 353         #
 354         # Is ac_lbl_dependency_flag defined and, if so, does the compiler
 355         # complain about it?
 356         #
 357         # Note: clang doesn't seem to exit with an error status when handed
 358         # an unknown non-warning error, even if you pass it
 359         # -Werror=unknown-warning-option.  However, it always supports
 360         # -M, so the fact that this test always succeeds with clang
 361         # isn't an issue.
 362         #
 363         if test ! -z "$ac_lbl_dependency_flag"; then
 364                 AC_LANG_CONFTEST(
 365                     [AC_LANG_SOURCE([[int main(void) { return 0; }]])])
 366                 if AC_RUN_LOG([eval "$CC $ac_lbl_dependency_flag conftest.c >/dev/null 2>&1"]); then
 367                         AC_MSG_RESULT([yes, with $ac_lbl_dependency_flag])
 368                         DEPENDENCY_CFLAG="$ac_lbl_dependency_flag"
 369                         MKDEP='${srcdir}/mkdep'
 370                 else
 371                         AC_MSG_RESULT([no])
 372                         #
 373                         # We can't run mkdep, so have "make depend" do
 374                         # nothing.
 375                         #
 376                         MKDEP=:
 377                 fi
 378                 rm -rf conftest*
 379         else
 380                 AC_MSG_RESULT([no])
 381                 #
 382                 # We can't run mkdep, so have "make depend" do
 383                 # nothing.
 384                 #
 385                 MKDEP=:
 386         fi
 387         AC_SUBST(DEPENDENCY_CFLAG)
 388         AC_SUBST(MKDEP)
 389     ])
 390
 391 #
 392 # Try compiling a sample of the type of code that appears in
 393 # gencode.c with "inline", "__inline__", and "__inline".
 394 #
 395 # Autoconf's AC_C_INLINE, at least in autoconf 2.13, isn't good enough,
 396 # as it just tests whether a function returning "int" can be inlined;
 397 # at least some versions of HP's C compiler can inline that, but can't
 398 # inline a function that returns a struct pointer.
 399 #
 400 # Make sure we use the V_CCOPT flags, because some of those might
 401 # disable inlining.
 402 #
 403 AC_DEFUN(AC_LBL_C_INLINE,
 404     [AC_MSG_CHECKING(for inline)
 405     save_CFLAGS="$CFLAGS"
 406     CFLAGS="$V_CCOPT"
 407     AC_CACHE_VAL(ac_cv_lbl_inline, [
 408         ac_cv_lbl_inline=""
 409         ac_lbl_cc_inline=no
 410         for ac_lbl_inline in inline __inline__ __inline
 411         do
 412             AC_TRY_COMPILE(
 413                 [#define inline $ac_lbl_inline
 414                 static inline struct iltest *foo(void);
 415                 struct iltest {
 416                     int iltest1;
 417                     int iltest2;
 418                 };
 419
 420                 static inline struct iltest *
 421                 foo()
 422                 {
 423                     static struct iltest xxx;
 424
 425                     return &xxx;
 426                 }],,ac_lbl_cc_inline=yes,)
 427             if test "$ac_lbl_cc_inline" = yes ; then
 428                 break;
 429             fi
 430         done
 431         if test "$ac_lbl_cc_inline" = yes ; then
 432             ac_cv_lbl_inline=$ac_lbl_inline
 433         fi])
 434     CFLAGS="$save_CFLAGS"
 435     if test ! -z "$ac_cv_lbl_inline" ; then
 436         AC_MSG_RESULT($ac_cv_lbl_inline)
 437     else
 438         AC_MSG_RESULT(no)
 439     fi
 440     AC_DEFINE_UNQUOTED(inline, $ac_cv_lbl_inline, [Define as token for inline if inlining supported])])
 441
 442 dnl
 443 dnl Use pfopen.c if available and pfopen() not in standard libraries
 444 dnl Require libpcap
 445 dnl Look for libpcap in directories under ..; those are local versions.
 446 dnl Look for an installed libpcap if there is no local version or if
 447 dnl the user said not to look for a local version.
 448 dnl
 449 dnl usage:
 450 dnl
 451 dnl     AC_LBL_LIBPCAP(pcapdep, incls)
 452 dnl
 453 dnl results:
 454 dnl
 455 dnl     $1 (pcapdep set)
 456 dnl     $2 (incls appended)
 457 dnl     LIBS
 458 dnl     LBL_LIBS
 459 dnl
 460 AC_DEFUN(AC_LBL_LIBPCAP,
 461     [AC_REQUIRE([AC_LBL_LIBRARY_NET])
 462     dnl
 463     dnl save a copy before locating libpcap.a
 464     dnl
 465     LBL_LIBS="$LIBS"
 466     pfopen=/usr/examples/packetfilter/pfopen.c
 467     if test -f $pfopen ; then
 468         AC_CHECK_FUNCS(pfopen)
 469         if test $ac_cv_func_pfopen = "no" ; then
 470             AC_MSG_RESULT(Using $pfopen)
 471             LIBS="$LIBS $pfopen"
 472         fi
 473     fi
 474     libpcap=FAIL
 475     AC_ARG_WITH([system-libpcap],
 476         [AS_HELP_STRING([--with-system-libpcap], [don't use local pcap library])],
 477         [
 478             #
 479             # Don't look for a local libpcap.
 480             #
 481             using_local_libpcap=no
 482         ],
 483         [
 484             #
 485             # Look for a local pcap library.
 486             #
 487             AC_MSG_CHECKING(for local pcap library)
 488             lastdir=FAIL
 489             places=`ls $srcdir/.. | sed -e 's,/$,,' -e "s,^,$srcdir/../," | \
 490                 egrep '/libpcap-[[0-9]]+\.[[0-9]]+(\.[[0-9]]*)?([[ab]][[0-9]]*|-PRE-GIT)?$'`
 491             places2=`ls .. | sed -e 's,/$,,' -e "s,^,../," | \
 492                 egrep '/libpcap-[[0-9]]+\.[[0-9]]+(\.[[0-9]]*)?([[ab]][[0-9]]*|-PRE-GIT)?$'`
 493             for dir in $places $srcdir/../libpcap ../libpcap $srcdir/libpcap $places2 ; do
 494                 basedir=`echo $dir | sed -e 's/[[ab]][[0-9]]*$//' | \
 495                     sed -e 's/-PRE-GIT$//' `
 496                 if test $lastdir = $basedir ; then
 497                     dnl skip alphas when an actual release is present
 498                     continue;
 499                 fi
 500                 lastdir=$dir
 501                 if test -r $dir/libpcap.a ; then
 502                     libpcap=$dir/libpcap.a
 503                     local_pcap_dir=$dir
 504                     dnl continue and select the last one that exists
 505                 fi
 506             done
 507             if test $libpcap = FAIL ; then
 508                 #
 509                 # We didn't find a local libpcap.
 510                 #
 511                 AC_MSG_RESULT(not found)
 512                 using_local_libpcap=no;
 513             else
 514                 #
 515                 # We found a local libpcap.
 516                 #
 517                 AC_MSG_RESULT($libpcap)
 518                 using_local_libpcap=yes
 519             fi
 520         ])
 521
 522     if test $using_local_libpcap = no ; then
 523         #
 524         # We didn't find a local libpcap.
 525         # Look for an installed pkg-config.
 526         #
 527         AC_PATH_TOOL(PKG_CONFIG, pkg-config)
 528         if test -n "$PKG_CONFIG" ; then
 529             #
 530             # We have it.  Are there .pc files for libpcap?
 531             #
 532             # --exists was introduced in pkg-config 0.4.0; that
 533             # dates back to late 2000, so we won't worry about
 534             # earlier releases that lack it.
 535             #
 536             AC_MSG_CHECKING(whether there are .pc files for libpcap)
 537             if "$PKG_CONFIG" libpcap --exists ; then
 538                 #
 539                 # Yes, so we can use pkg-config to get configuration
 540                 # information for libpcap.
 541                 #
 542                 AC_MSG_RESULT(yes)
 543                 pkg_config_usable=yes
 544             else
 545                 #
 546                 # No, so we can't use pkg-config to get configuration
 547                 # information for libpcap.
 548                 #
 549                 AC_MSG_RESULT(no)
 550                 pkg_config_usable=no
 551             fi
 552         else
 553             #
 554             # We don't have it, so we obviously can't use it.
 555             #
 556             pkg_config_usable=no
 557         fi
 558         if test "$pkg_config_usable" = "yes" ; then
 559             #
 560             # Found both - use pkg-config to get the include flags for
 561             # libpcap and the flags to link with libpcap.
 562             #
 563             # Please read section 11.6 "Shell Substitutions"
 564             # in the autoconf manual before doing anything
 565             # to this that involves quoting.  Especially note
 566             # the statement "There is just no portable way to use
 567             # double-quoted strings inside double-quoted back-quoted
 568             # expressions (pfew!)."
 569             #
 570             cflags=`"$PKG_CONFIG" libpcap --cflags`
 571             $2="$cflags $$2"
 572             libpcap=`"$PKG_CONFIG" libpcap --libs`
 573         else
 574             #
 575             # No pkg-config
 576             # Look for an installed pcap-config.
 577             #
 578             AC_PATH_TOOL(PCAP_CONFIG, pcap-config)
 579             if test -n "$PCAP_CONFIG" ; then
 580                 #
 581                 # Found - use it to get the include flags for
 582                 # libpcap and the flags to link with libpcap.
 583                 #
 584                 # Please read section 11.6 "Shell Substitutions"
 585                 # in the autoconf manual before doing anything
 586                 # to this that involves quoting.  Especially note
 587                 # the statement "There is just no portable way to use
 588                 # double-quoted strings inside double-quoted back-quoted
 589                 # expressions (pfew!)."
 590                 #
 591                 cflags=`"$PCAP_CONFIG" --cflags`
 592                 $2="$cflags $$2"
 593                 libpcap=`"$PCAP_CONFIG" --libs`
 594             else
 595                 #
 596                 # Not found; look for an installed pcap.
 597                 #
 598                 AC_CHECK_LIB(pcap, main, libpcap="-lpcap")
 599                 if test $libpcap = FAIL ; then
 600                     AC_MSG_ERROR(see the INSTALL doc for more info)
 601                 fi
 602                 dnl
 603                 dnl Some versions of Red Hat Linux put "pcap.h" in
 604                 dnl "/usr/include/pcap"; had the LBL folks done so,
 605                 dnl that would have been a good idea, but for
 606                 dnl the Red Hat folks to do so just breaks source
 607                 dnl compatibility with other systems.
 608                 dnl
 609                 dnl We work around this by assuming that, as we didn't
 610                 dnl find a local libpcap, libpcap is in /usr/lib or
 611                 dnl /usr/local/lib and that the corresponding header
 612                 dnl file is under one of those directories; if we don't
 613                 dnl find it in either of those directories, we check to
 614                 dnl see if it's in a "pcap" subdirectory of them and,
 615                 dnl if so, add that subdirectory to the "-I" list.
 616                 dnl
 617                 dnl (We now also put pcap.h in /usr/include/pcap, but we
 618                 dnl leave behind a /usr/include/pcap.h that includes it,
 619                 dnl so you can still just include <pcap.h>.)
 620                 dnl
 621                 AC_MSG_CHECKING(for extraneous pcap header directories)
 622                 if test \( ! -r /usr/local/include/pcap.h \) -a \
 623                         \( ! -r /usr/include/pcap.h \); then
 624                     if test -r /usr/local/include/pcap/pcap.h; then
 625                         d="/usr/local/include/pcap"
 626                     elif test -r /usr/include/pcap/pcap.h; then
 627                         d="/usr/include/pcap"
 628                     fi
 629                 fi
 630                 if test -z "$d" ; then
 631                     AC_MSG_RESULT(not found)
 632                 else
 633                     $2="-I$d $$2"
 634                     AC_MSG_RESULT(found -- -I$d added)
 635                 fi
 636             fi
 637         fi
 638     else
 639         #
 640         # We found a local libpcap.  Add it to the dependencies for
 641         # tcpdump.
 642         #
 643         $1=$libpcap
 644
 645         #
 646         # Look for its pcap-config script.
 647         #
 648         AC_PATH_PROG(PCAP_CONFIG, pcap-config,, $local_pcap_dir)
 649
 650         if test -n "$PCAP_CONFIG"; then
 651             #
 652             # We don't want its --cflags or --libs output, because
 653             # those presume it's installed.  For the C compiler flags,
 654             # we add the source directory for the local libpcap, so
 655             # we pick up its header files.
 656             #
 657             # We do, however, want its additional libraries, as required
 658             # when linking statically, because it makes calls to
 659             # routines in those libraries, so we'll need to link with
 660             # them, because we'll be linking statically with it.
 661             #
 662             $2="-I$local_pcap_dir $$2"
 663             additional_libs=`"$PCAP_CONFIG" --static --additional-libs`
 664             libpcap="$libpcap $additional_libs"
 665         else
 666             #
 667             # It doesn't have a pcap-config script.
 668             # Make sure it has a pcap.h file.
 669             #
 670             places=`ls $srcdir/.. | sed -e 's,/$,,' -e "s,^,$srcdir/../," | \
 671                 egrep '/libpcap-[[0-9]]*.[[0-9]]*(.[[0-9]]*)?([[ab]][[0-9]]*)?$'`
 672             places2=`ls .. | sed -e 's,/$,,' -e "s,^,../," | \
 673                 egrep '/libpcap-[[0-9]]*.[[0-9]]*(.[[0-9]]*)?([[ab]][[0-9]]*)?$'`
 674             pcapH=FAIL
 675             if test -r $local_pcap_dir/pcap.h; then
 676                 pcapH=$local_pcap_dir
 677             else
 678                 for dir in $places $srcdir/../libpcap ../libpcap $srcdir/libpcap $places2 ; do
 679                     if test -r $dir/pcap.h ; then
 680                         pcapH=$dir
 681                     fi
 682                 done
 683             fi
 684
 685             if test $pcapH = FAIL ; then
 686                 AC_MSG_ERROR(cannot find pcap.h: see INSTALL)
 687             fi
 688
 689             #
 690             # Force the compiler to look for header files in the
 691             # directory containing pcap.h.
 692             #
 693             $2="-I$pcapH $$2"
 694         fi
 695     fi
 696
 697     if test -z "$PKG_CONFIG" -a -z "$PCAP_CONFIG"; then
 698         #
 699         # We don't have pkg-config or pcap-config; find out any additional
 700         # link flags we need.  (If we have pkg-config or pcap-config, we
 701         # assume it tells us what we need.)
 702         #
 703         case "$host_os" in
 704
 705         aix*)
 706             #
 707             # If libpcap is DLPI-based, we have to use /lib/pse.exp if
 708             # present, as we use the STREAMS routines.
 709             #
 710             # (XXX - true only if we're linking with a static libpcap?)
 711             #
 712             pseexe="/lib/pse.exp"
 713             AC_MSG_CHECKING(for $pseexe)
 714             if test -f $pseexe ; then
 715                 AC_MSG_RESULT(yes)
 716                 LIBS="$LIBS -I:$pseexe"
 717             fi
 718
 719             #
 720             # If libpcap is BPF-based, we need "-lodm" and "-lcfg", as
 721             # we use them to load the BPF module.
 722             #
 723             # (XXX - true only if we're linking with a static libpcap?)
 724             #
 725             LIBS="$LIBS -lodm -lcfg"
 726             ;;
 727
 728         solaris*)
 729             # libdlpi is needed for Solaris 11 and later.
 730             AC_CHECK_LIB(dlpi, dlpi_walk, LIBS="$LIBS -ldlpi" LDFLAGS="-L/lib $LDFLAGS", ,-L/lib)
 731             ;;
 732         esac
 733     fi
 734
 735     LIBS="$libpcap $LIBS"
 736
 737     dnl
 738     dnl Check for "pcap_loop()", to make sure we found a working
 739     dnl libpcap and have all the right other libraries with which
 740     dnl to link.  (Otherwise, the checks below will fail, not
 741     dnl because the routines are missing from the library, but
 742     dnl because we aren't linking properly with libpcap, and
 743     dnl that will cause confusing errors at build time.)
 744     dnl
 745     AC_CHECK_FUNC(pcap_loop,,
 746     [
 747         AC_MSG_ERROR(
 748 [This is a bug, please follow the guidelines in CONTRIBUTING and include the
 749 config.log file in your report.  If you have downloaded libpcap from
 750 tcpdump.org, and built it yourself, please also include the config.log
 751 file from the libpcap source directory, the Makefile from the libpcap
 752 source directory, and the output of the make process for libpcap, as
 753 this could be a problem with the libpcap that was built, and we will
 754 not be able to determine why this is happening, and thus will not be
 755 able to fix it, without that information, as we have not been able to
 756 reproduce this problem ourselves.])
 757     ])
 758 ])
 759
 760 dnl
 761 dnl If using gcc, make sure we have ANSI ioctl definitions
 762 dnl
 763 dnl usage:
 764 dnl
 765 dnl     AC_LBL_FIXINCLUDES
 766 dnl
 767 AC_DEFUN(AC_LBL_FIXINCLUDES,
 768     [if test "$GCC" = yes ; then
 769             AC_MSG_CHECKING(for ANSI ioctl definitions)
 770             AC_CACHE_VAL(ac_cv_lbl_gcc_fixincludes,
 771                 AC_TRY_COMPILE(
 772                     [/*
 773                      * This generates a "duplicate case value" when fixincludes
 774                      * has not be run.
 775                      */
 776 #               include <sys/types.h>
 777 #               include <sys/time.h>
 778 #               include <sys/ioctl.h>
 779 #               ifdef HAVE_SYS_IOCCOM_H
 780 #               include <sys/ioccom.h>
 781 #               endif],
 782                     [switch (0) {
 783                     case _IO('A', 1):;
 784                     case _IO('B', 1):;
 785                     }],
 786                     ac_cv_lbl_gcc_fixincludes=yes,
 787                     ac_cv_lbl_gcc_fixincludes=no))
 788             AC_MSG_RESULT($ac_cv_lbl_gcc_fixincludes)
 789             if test $ac_cv_lbl_gcc_fixincludes = no ; then
 790                     # Don't cache failure
 791                     unset ac_cv_lbl_gcc_fixincludes
 792                     AC_MSG_ERROR(see the INSTALL for more info)
 793             fi
 794     fi])
 795
 796 dnl
 797 dnl Checks to see if union wait is used with WEXITSTATUS()
 798 dnl
 799 dnl usage:
 800 dnl
 801 dnl     AC_LBL_UNION_WAIT
 802 dnl
 803 dnl results:
 804 dnl
 805 dnl     DECLWAITSTATUS (defined)
 806 dnl
 807 AC_DEFUN(AC_LBL_UNION_WAIT,
 808     [AC_MSG_CHECKING(if union wait is used)
 809     AC_CACHE_VAL(ac_cv_lbl_union_wait,
 810         AC_TRY_COMPILE([
 811 #       include <sys/types.h>
 812 #       include <sys/wait.h>],
 813             [int status;
 814             u_int i = WEXITSTATUS(status);
 815             u_int j = waitpid(0, &status, 0);],
 816             ac_cv_lbl_union_wait=no,
 817             ac_cv_lbl_union_wait=yes))
 818     AC_MSG_RESULT($ac_cv_lbl_union_wait)
 819     if test $ac_cv_lbl_union_wait = yes ; then
 820             AC_DEFINE(DECLWAITSTATUS,union wait,[type for wait])
 821     else
 822             AC_DEFINE(DECLWAITSTATUS,int,[type for wait])
 823     fi])
 824
 825 dnl
 826 dnl Checks to see if -R is used
 827 dnl
 828 dnl usage:
 829 dnl
 830 dnl     AC_LBL_HAVE_RUN_PATH
 831 dnl
 832 dnl results:
 833 dnl
 834 dnl     ac_cv_lbl_have_run_path (yes or no)
 835 dnl
 836 AC_DEFUN(AC_LBL_HAVE_RUN_PATH,
 837     [AC_MSG_CHECKING(for ${CC-cc} -R)
 838     AC_CACHE_VAL(ac_cv_lbl_have_run_path,
 839         [echo 'main(){}' > conftest.c
 840         ${CC-cc} -o conftest conftest.c -R/a1/b2/c3 >conftest.out 2>&1
 841         if test ! -s conftest.out ; then
 842                 ac_cv_lbl_have_run_path=yes
 843         else
 844                 ac_cv_lbl_have_run_path=no
 845         fi
 846         rm -f -r conftest*])
 847     AC_MSG_RESULT($ac_cv_lbl_have_run_path)
 848     ])
 849
 850 dnl
 851 dnl Check whether a given format can be used to print 64-bit integers
 852 dnl
 853 AC_DEFUN(AC_LBL_CHECK_64BIT_FORMAT,
 854   [
 855     AC_MSG_CHECKING([whether %$1x can be used to format 64-bit integers])
 856     AC_RUN_IFELSE(
 857       [
 858         AC_LANG_SOURCE(
 859           [[
 860 #           ifdef HAVE_INTTYPES_H
 861             #include <inttypes.h>
 862 #           endif
 863             #include <stdio.h>
 864             #include <sys/types.h>
 865
 866             main()
 867             {
 868               uint64_t t = 1;
 869               char strbuf[16+1];
 870               sprintf(strbuf, "%016$1x", t << 32);
 871               if (strcmp(strbuf, "0000000100000000") == 0)
 872                 exit(0);
 873               else
 874                 exit(1);
 875             }
 876           ]])
 877       ],
 878       [
 879         AC_DEFINE(PRId64, "$1d", [define if the platform doesn't define PRId64])
 880         AC_DEFINE(PRIo64, "$1o", [define if the platform doesn't define PRIo64])
 881         AC_DEFINE(PRIx64, "$1x", [define if the platform doesn't define PRIu64])
 882         AC_DEFINE(PRIu64, "$1u", [define if the platform doesn't define PRIx64])
 883         AC_MSG_RESULT(yes)
 884       ],
 885       [
 886         AC_MSG_RESULT(no)
 887         $2
 888       ])
 889   ])
 890
 891 dnl
 892 dnl If the file .devel exists:
 893 dnl     Add some warning flags if the compiler supports them
 894 dnl     If an os prototype include exists, symlink os-proto.h to it
 895 dnl
 896 dnl usage:
 897 dnl
 898 dnl     AC_LBL_DEVEL(copt)
 899 dnl
 900 dnl results:
 901 dnl
 902 dnl     $1 (copt appended)
 903 dnl     HAVE_OS_PROTO_H (defined)
 904 dnl     os-proto.h (symlinked)
 905 dnl
 906 AC_DEFUN(AC_LBL_DEVEL,
 907     [rm -f os-proto.h
 908     if test "${LBL_CFLAGS+set}" = set; then
 909             $1="$$1 ${LBL_CFLAGS}"
 910     fi
 911     if test -f .devel ; then
 912             #
 913             # Skip all the warning option stuff on some compilers.
 914             #
 915             if test "$ac_lbl_cc_dont_try_gcc_dashW" != yes; then
 916                     AC_LBL_CHECK_UNKNOWN_WARNING_OPTION_ERROR()
 917                     AC_LBL_CHECK_COMPILER_OPT($1, -W)
 918                     AC_LBL_CHECK_COMPILER_OPT($1, -Wall)
 919                     AC_LBL_CHECK_COMPILER_OPT($1, -Wassign-enum)
 920                     AC_LBL_CHECK_COMPILER_OPT($1, -Wcast-qual)
 921                     AC_LBL_CHECK_COMPILER_OPT($1, -Wmissing-prototypes)
 922                     AC_LBL_CHECK_COMPILER_OPT($1, -Wold-style-definition)
 923                     AC_LBL_CHECK_COMPILER_OPT($1, -Wpedantic)
 924                     AC_LBL_CHECK_COMPILER_OPT($1, -Wpointer-arith)
 925                     AC_LBL_CHECK_COMPILER_OPT($1, -Wpointer-sign)
 926                     AC_LBL_CHECK_COMPILER_OPT($1, -Wshadow)
 927                     AC_LBL_CHECK_COMPILER_OPT($1, -Wsign-compare)
 928                     AC_LBL_CHECK_COMPILER_OPT($1, -Wstrict-prototypes)
 929                     AC_LBL_CHECK_COMPILER_OPT($1, -Wunreachable-code-return)
 930                     AC_LBL_CHECK_COMPILER_OPT($1, -Wused-but-marked-unused)
 931                     AC_LBL_CHECK_COMPILER_OPT($1, -Wwrite-strings)
 932             fi
 933             AC_LBL_CHECK_DEPENDENCY_GENERATION_OPT()
 934             #
 935             # We used to set -n32 for IRIX 6 when not using GCC (presumed
 936             # to mean that we're using MIPS C or MIPSpro C); it specified
 937             # the "new" faster 32-bit ABI, introduced in IRIX 6.2.  I'm
 938             # not sure why that would be something to do *only* with a
 939             # .devel file; why should the ABI for which we produce code
 940             # depend on .devel?
 941             #
 942             os=`echo $host_os | sed -e 's/\([[0-9]][[0-9]]*\)[[^0-9]].*$/\1/'`
 943             name="lbl/os-$os.h"
 944             if test -f $name ; then
 945                     ln -s $name os-proto.h
 946                     AC_DEFINE(HAVE_OS_PROTO_H, 1,
 947                         [if there's an os_proto.h for this platform, to use additional prototypes])
 948             else
 949                     AC_MSG_WARN(can't find $name)
 950             fi
 951     fi])
 952
 953 dnl
 954 dnl Improved version of AC_CHECK_LIB
 955 dnl
 956 dnl Thanks to John Hawkinson (jhawk@mit.edu)
 957 dnl
 958 dnl usage:
 959 dnl
 960 dnl     AC_LBL_CHECK_LIB(LIBRARY, FUNCTION [, ACTION-IF-FOUND [,
 961 dnl         ACTION-IF-NOT-FOUND [, OTHER-LIBRARIES]]])
 962 dnl
 963 dnl results:
 964 dnl
 965 dnl     LIBS
 966 dnl
 967 dnl XXX - "AC_LBL_LIBRARY_NET" was redone to use "AC_SEARCH_LIBS"
 968 dnl rather than "AC_LBL_CHECK_LIB", so this isn't used any more.
 969 dnl We keep it around for reference purposes in case it's ever
 970 dnl useful in the future.
 971 dnl
 972
 973 define(AC_LBL_CHECK_LIB,
 974 [AC_MSG_CHECKING([for $2 in -l$1])
 975 dnl Use a cache variable name containing the library, function
 976 dnl name, and extra libraries to link with, because the test really is
 977 dnl for library $1 defining function $2, when linked with potinal
 978 dnl library $5, not just for library $1.  Separate tests with the same
 979 dnl $1 and different $2's or $5's may have different results.
 980 ac_lib_var=`echo $1['_']$2['_']$5 | sed 'y%./+- %__p__%'`
 981 AC_CACHE_VAL(ac_cv_lbl_lib_$ac_lib_var,
 982 [ac_save_LIBS="$LIBS"
 983 LIBS="-l$1 $5 $LIBS"
 984 AC_TRY_LINK(dnl
 985 ifelse([$2], [main], , dnl Avoid conflicting decl of main.
 986 [/* Override any gcc2 internal prototype to avoid an error.  */
 987 ]ifelse(AC_LANG, CPLUSPLUS, [#ifdef __cplusplus
 988 extern "C"
 989 #endif
 990 ])dnl
 991 [/* We use char because int might match the return type of a gcc2
 992     builtin and then its argument prototype would still apply.  */
 993 char $2();
 994 ]),
 995             [$2()],
 996             eval "ac_cv_lbl_lib_$ac_lib_var=yes",
 997             eval "ac_cv_lbl_lib_$ac_lib_var=no")
 998 LIBS="$ac_save_LIBS"
 999 ])dnl
1000 if eval "test \"`echo '$ac_cv_lbl_lib_'$ac_lib_var`\" = yes"; then
1001   AC_MSG_RESULT(yes)
1002   ifelse([$3], ,
1003 [changequote(, )dnl
1004   ac_tr_lib=HAVE_LIB`echo $1 | sed -e 's/[^a-zA-Z0-9_]/_/g' \
1005     -e 'y/abcdefghijklmnopqrstuvwxyz/ABCDEFGHIJKLMNOPQRSTUVWXYZ/'`
1006 changequote([, ])dnl
1007   AC_DEFINE_UNQUOTED($ac_tr_lib)
1008   LIBS="-l$1 $LIBS"
1009 ], [$3])
1010 else
1011   AC_MSG_RESULT(no)
1012 ifelse([$4], , , [$4
1013 ])dnl
1014 fi
1015 ])
1016
1017 dnl
1018 dnl AC_LBL_LIBRARY_NET
1019 dnl
1020 dnl This test is for network applications that need socket() and
1021 dnl gethostbyname() -ish functions.  Under Solaris, those applications
1022 dnl need to link with "-lsocket -lnsl".  Under IRIX, they need to link
1023 dnl with "-lnsl" but should *not* link with "-lsocket" because
1024 dnl libsocket.a breaks a number of things (for instance:
1025 dnl gethostbyname() under IRIX 5.2, and snoop sockets under most
1026 dnl versions of IRIX).
1027 dnl
1028 dnl Unfortunately, many application developers are not aware of this,
1029 dnl and mistakenly write tests that cause -lsocket to be used under
1030 dnl IRIX.  It is also easy to write tests that cause -lnsl to be used
1031 dnl under operating systems where neither are necessary (or useful),
1032 dnl such as SunOS 4.1.4, which uses -lnsl for TLI.
1033 dnl
1034 dnl This test exists so that every application developer does not test
1035 dnl this in a different, and subtly broken fashion.
1036
1037 dnl It has been argued that this test should be broken up into two
1038 dnl separate tests, one for the resolver libraries, and one for the
1039 dnl libraries necessary for using Sockets API. Unfortunately, the two
1040 dnl are carefully intertwined and allowing the autoconf user to use
1041 dnl them independently potentially results in unfortunate ordering
1042 dnl dependencies -- as such, such component macros would have to
1043 dnl carefully use indirection and be aware if the other components were
1044 dnl executed. Since other autoconf macros do not go to this trouble,
1045 dnl and almost no applications use sockets without the resolver, this
1046 dnl complexity has not been implemented.
1047 dnl
1048 dnl The check for libresolv is in case you are attempting to link
1049 dnl statically and happen to have a libresolv.a lying around (and no
1050 dnl libnsl.a).
1051 dnl
1052 AC_DEFUN(AC_LBL_LIBRARY_NET, [
1053     # Most operating systems have gethostbyname() in the default searched
1054     # libraries (i.e. libc):
1055     # Some OSes (eg. Solaris) place it in libnsl
1056     # Some strange OSes (SINIX) have it in libsocket:
1057     AC_SEARCH_LIBS(gethostbyname, nsl socket resolv)
1058     # Unfortunately libsocket sometimes depends on libnsl and
1059     # AC_SEARCH_LIBS isn't up to the task of handling dependencies like this.
1060     if test "$ac_cv_search_gethostbyname" = "no"
1061     then
1062         AC_CHECK_LIB(socket, gethostbyname,
1063                      LIBS="-lsocket -lnsl $LIBS", , -lnsl)
1064     fi
1065     AC_SEARCH_LIBS(socket, socket, ,
1066         AC_CHECK_LIB(socket, socket, LIBS="-lsocket -lnsl $LIBS", , -lnsl))
1067     # DLPI needs putmsg under HPUX so test for -lstr while we're at it
1068     AC_SEARCH_LIBS(putmsg, str)
1069     ])
1070
1071 dnl Copyright (c) 1999 WIDE Project. All rights reserved.
1072 dnl
1073 dnl Redistribution and use in source and binary forms, with or without
1074 dnl modification, are permitted provided that the following conditions
1075 dnl are met:
1076 dnl 1. Redistributions of source code must retain the above copyright
1077 dnl    notice, this list of conditions and the following disclaimer.
1078 dnl 2. Redistributions in binary form must reproduce the above copyright
1079 dnl    notice, this list of conditions and the following disclaimer in the
1080 dnl    documentation and/or other materials provided with the distribution.
1081 dnl 3. Neither the name of the project nor the names of its contributors
1082 dnl    may be used to endorse or promote products derived from this software
1083 dnl    without specific prior written permission.
1084 dnl
1085 dnl THIS SOFTWARE IS PROVIDED BY THE PROJECT AND CONTRIBUTORS ``AS IS'' AND
1086 dnl ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
1087 dnl IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
1088 dnl ARE DISCLAIMED.  IN NO EVENT SHALL THE PROJECT OR CONTRIBUTORS BE LIABLE
1089 dnl FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
1090 dnl DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
1091 dnl OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
1092 dnl HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
1093 dnl LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
1094 dnl OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
1095 dnl SUCH DAMAGE.
1096
1097 AC_DEFUN(AC_LBL_SSLEAY,
1098     [
1099         #
1100         # Find the last component of $libdir; it's not necessarily
1101         # "lib" - it might be "lib64" on, for example, x86-64
1102         # Linux systems.
1103         #
1104         # We assume the directory in which we're looking for
1105         # libcrypto has a subdirectory with that as its name.
1106         #
1107         tmplib=`echo "$libdir" | sed 's,.*/,,'`
1108
1109         #
1110         # XXX - is there a better way to check if a given library is
1111         # in a given directory than checking each of the possible
1112         # shared library suffixes?
1113         #
1114         # Are there any other suffixes we need to look for?  Do we
1115         # have to worry about ".so.{version}"?
1116         #
1117         # Or should we just look for "libcrypto.*"?
1118         #
1119         if test -d "$1/$tmplib" -a \( -f "$1/$tmplib/libcrypto.a" -o \
1120                                     -f "$1/$tmplib/libcrypto.so" -o \
1121                                     -f "$1/$tmplib/libcrypto.sl" -o \
1122                                     -f "$1/$tmplib/libcrypto.dylib" \); then
1123                 ac_cv_ssleay_path="$1"
1124         fi
1125
1126         #
1127         # Make sure we have the headers as well.
1128         #
1129         if test -d "$1/include/openssl" -a -f "$1/include/openssl/des.h"; then
1130                 incdir="-I$1/include"
1131         fi
1132 ])