The Tcpdump Group git mirrors - tcpdump/blob - configure.in

   1 dnl Copyright (c) 1994, 1995, 1996, 1997
   2 dnl     The Regents of the University of California.  All rights reserved.
   3 dnl
   4 dnl Process this file with autoconf to produce a configure script.
   5 dnl
   6
   7 #
   8 # See
   9 #
  10 #       http://ftp.gnu.org/gnu/config/README
  11 #
  12 # for the URLs to use to fetch new versions of config.guess and
  13 # config.sub.
  14 #
  15
  16 AC_PREREQ(2.64)
  17 AC_INIT(tcpdump, m4_esyscmd_s([cat VERSION]))
  18 AC_CONFIG_SRCDIR(tcpdump.c)
  19
  20 AC_CANONICAL_HOST
  21
  22 AC_LBL_C_INIT_BEFORE_CC(V_INCLS)
  23 AC_PROG_CC
  24 AC_LBL_C_INIT(V_CCOPT, V_INCLS)
  25 AC_LBL_C_INLINE
  26 AC_C___ATTRIBUTE__
  27 if test "$ac_cv___attribute__" = "yes"; then
  28         AC_C___ATTRIBUTE___UNUSED
  29         AC_C___ATTRIBUTE___FALLTHROUGH
  30 fi
  31
  32 AC_CHECK_HEADERS(fcntl.h rpc/rpc.h rpc/rpcent.h netdnet/dnetdb.h)
  33 AC_CHECK_HEADERS(net/pfvar.h, , , [#include <sys/types.h>
  34 #include <sys/socket.h>
  35 #include <net/if.h>])
  36 if test "$ac_cv_header_net_pfvar_h" = yes; then
  37         AC_CHECK_HEADERS(net/if_pflog.h, , , [#include <sys/types.h>
  38         #include <sys/socket.h>
  39         #include <net/if.h>
  40         #include <net/pfvar.h>])
  41         if test "$ac_cv_header_net_if_pflog_h" = yes; then
  42                 LOCALSRC="print-pflog.c $LOCALSRC"
  43         fi
  44 fi
  45 AC_CHECK_HEADERS(netinet/if_ether.h, , , [#include <sys/types.h>
  46 #include <sys/socket.h>])
  47 if test "$ac_cv_header_netinet_if_ether_h" != yes; then
  48         #
  49         # The simple test didn't work.
  50         # Do we need to include <net/if.h> first?
  51         # Unset ac_cv_header_netinet_if_ether_h so we don't
  52         # treat the previous failure as a cached value and
  53         # suppress the next test.
  54         #
  55         AC_MSG_NOTICE([Rechecking with some additional includes])
  56         unset ac_cv_header_netinet_if_ether_h
  57         AC_CHECK_HEADERS(netinet/if_ether.h, , , [#include <sys/types.h>
  58 #include <sys/socket.h>
  59 #include <netinet/in.h>
  60 struct mbuf;
  61 struct rtentry;
  62 #include <net/if.h>])
  63 fi
  64
  65 case "$host_os" in
  66
  67 darwin*)
  68         AC_ARG_ENABLE(universal,
  69         AC_HELP_STRING([--disable-universal],[don't build universal on OS X]))
  70         if test "$enable_universal" != "no"; then
  71                 case "$host_os" in
  72
  73                 darwin9.*)
  74                         #
  75                         # Leopard.  Build for x86 and 32-bit PowerPC, with
  76                         # x86 first.  (That's what Apple does.)
  77                         #
  78                         V_CCOPT="$V_CCOPT -arch i386 -arch ppc"
  79                         LDFLAGS="$LDFLAGS -arch i386 -arch ppc"
  80                         ;;
  81
  82                 darwin10.*)
  83                         #
  84                         # Snow Leopard.  Build for x86-64 and x86, with
  85                         # x86-64 first.  (That's what Apple does.)
  86                         #
  87                         V_CCOPT="$V_CCOPT -arch x86_64 -arch i386"
  88                         LDFLAGS="$LDFLAGS -arch x86_64 -arch i386"
  89                         ;;
  90                 esac
  91         fi
  92         ;;
  93 esac
  94
  95
  96 AC_ARG_WITH(smi,
  97 [  --with-smi              link with libsmi (allows to load MIBs on the fly to decode SNMP packets. [default=yes]
  98   --without-smi           don't link with libsmi],,
  99    with_smi=yes)
 100
 101 if test "x$with_smi" != "xno" ; then
 102         AC_CHECK_HEADER(smi.h,
 103         [
 104                 #
 105                 # OK, we found smi.h.  Do we have libsmi with smiInit?
 106                 #
 107                 AC_CHECK_LIB(smi, smiInit,
 108                 [
 109                         #
 110                         # OK, we have libsmi with smiInit.  Can we use it?
 111                         #
 112                         AC_MSG_CHECKING([whether to enable libsmi])
 113                         savedlibs="$LIBS"
 114                         LIBS="-lsmi $LIBS"
 115                         AC_TRY_RUN(
 116                                 [
 117 /* libsmi available check */
 118 #include <smi.h>
 119 main()
 120 {
 121   int current, revision, age, n;
 122   const int required = 2;
 123   if (smiInit(""))
 124     exit(1);
 125   if (strcmp(SMI_LIBRARY_VERSION, smi_library_version))
 126     exit(2);
 127   n = sscanf(smi_library_version, "%d:%d:%d", &current, &revision, &age);
 128   if (n != 3)
 129     exit(3);
 130   if (required < current - age || required > current)
 131     exit(4);
 132   exit(0);
 133 }
 134                                 ],
 135                                 [
 136                                         AC_MSG_RESULT(yes)
 137                                         AC_DEFINE(USE_LIBSMI, 1,
 138                                             [Define if you enable support for libsmi])
 139                                 ],
 140                                 [
 141                                         dnl autoconf documentation says that
 142                                         dnl $? contains the exit value.
 143                                         dnl reality is that it does not.
 144                                         dnl We leave this in just in case
 145                                         dnl autoconf ever comes back to
 146                                         dnl match the documentation.
 147                                         case $? in
 148                                           1) AC_MSG_RESULT(no - smiInit failed) ;;
 149                                           2) AC_MSG_RESULT(no - header/library version mismatch) ;;
 150                                           3) AC_MSG_RESULT(no - can't determine library version) ;;
 151                                           4) AC_MSG_RESULT(no - too old) ;;
 152                                           *) AC_MSG_RESULT(no) ;;
 153                                         esac
 154                                         LIBS="$savedlibs"
 155                                 ],
 156                                 [
 157                                         AC_MSG_RESULT(not when cross-compiling)
 158                                         LIBS="$savedlibs"
 159                                 ]
 160                         )
 161                 ])
 162         ])
 163 fi
 164
 165 AC_MSG_CHECKING([whether to enable the possibly-buggy SMB printer])
 166 AC_ARG_ENABLE(smb,
 167 [  --enable-smb            enable possibly-buggy SMB printer [default=yes]
 168   --disable-smb           disable possibly-buggy SMB printer],,
 169    enableval=yes)
 170 case "$enableval" in
 171 yes)    AC_MSG_RESULT(yes)
 172         AC_WARN([The SMB printer may have exploitable buffer overflows!!!])
 173         AC_DEFINE(ENABLE_SMB, 1,
 174             [define if you want to build the possibly-buggy SMB printer])
 175         LOCALSRC="print-smb.c smbutil.c $LOCALSRC"
 176         ;;
 177 *)      AC_MSG_RESULT(no)
 178         ;;
 179 esac
 180
 181 AC_ARG_WITH(user, [  --with-user=USERNAME    drop privileges by default to USERNAME])
 182 AC_MSG_CHECKING([whether to drop root privileges by default])
 183 if test ! -z "$with_user" ; then
 184        AC_DEFINE_UNQUOTED(WITH_USER, "$withval",
 185            [define if should drop privileges by default])
 186        AC_MSG_RESULT(to \"$withval\")
 187 else
 188        AC_MSG_RESULT(no)
 189 fi
 190
 191 AC_ARG_WITH(chroot, [  --with-chroot=DIRECTORY when dropping privileges, chroot to DIRECTORY])
 192 AC_MSG_CHECKING([whether to chroot])
 193 if test ! -z "$with_chroot" && test "$with_chroot" != "no" ; then
 194        AC_DEFINE_UNQUOTED(WITH_CHROOT, "$withval",
 195            [define if should chroot when dropping privileges])
 196        AC_MSG_RESULT(to \"$withval\")
 197 else
 198        AC_MSG_RESULT(no)
 199 fi
 200
 201 AC_ARG_WITH(sandbox-capsicum,
 202         AS_HELP_STRING([--with-sandbox-capsicum],
 203                        [use Capsicum security functions @<:@default=yes, if available@:>@]))
 204 #
 205 # Check whether various functions are available.  If any are, set
 206 # ac_lbl_capsicum_function_seen to yes; if any are not, set
 207 # ac_lbl_capsicum_function_not_seen to yes.
 208 #
 209 # We don't check cap_rights_init(), as it's a macro, wrapping another
 210 # function, in at least some versions of FreeBSD, and AC_CHECK_FUNCS()
 211 # doesn't handle that.
 212 #
 213 # All of the ones we check for must be available in order to enable
 214 # capsicum sandboxing.
 215 #
 216 # XXX - do we need to check for all of them, or are there some that, if
 217 # present, imply others are present?
 218 #
 219 if test ! -z "$with_sandbox-capsicum" && test "$with_sandbox-capsicum" != "no" ; then
 220         AC_CHECK_FUNCS(cap_enter cap_rights_limit cap_ioctls_limit openat,
 221             ac_lbl_capsicum_function_seen=yes,
 222             ac_lbl_capsicum_function_not_seen=yes)
 223         AC_CHECK_LIB(casper, cap_init, LIBS="$LIBS -lcasper")
 224         AC_CHECK_LIB(cap_dns, cap_gethostbyaddr, LIBS="$LIBS -lcap_dns")
 225 fi
 226 AC_MSG_CHECKING([whether to sandbox using capsicum])
 227 if test "x$ac_lbl_capsicum_function_seen" = "xyes" -a "x$ac_lbl_capsicum_function_not_seen" != "xyes"; then
 228         AC_DEFINE(HAVE_CAPSICUM, 1, [capsicum support available])
 229         AC_MSG_RESULT(yes)
 230 else
 231         AC_MSG_RESULT(no)
 232 fi
 233 AC_MSG_CHECKING([whether to sandbox using Casper library])
 234 if test "x$ac_cv_lib_casper_cap_init" = "xyes" -a "x$ac_cv_lib_cap_dns_cap_gethostbyaddr" = "xyes"; then
 235         AC_DEFINE(HAVE_CASPER, 1, [Casper support available])
 236         AC_MSG_RESULT(yes)
 237 else
 238         AC_MSG_RESULT(no)
 239 fi
 240
 241 #
 242 # We must check this before checking whether to check the OS's IPv6,
 243 # support because, on some platforms (such as SunOS 5.x), the test
 244 # program requires the extra networking libraries.
 245 #
 246 AC_LBL_LIBRARY_NET
 247
 248 #
 249 # Check whether AF_INET6 and struct in6_addr are defined.
 250 # If they aren't both defined, we don't have sufficient OS
 251 # support for IPv6, so we don't look for IPv6 support libraries,
 252 # and we define AF_INET6 and struct in6_addr ourselves.
 253 #
 254 AC_MSG_CHECKING([whether the operating system supports IPv6])
 255 AC_COMPILE_IFELSE(
 256     [
 257       AC_LANG_SOURCE(
 258         [[
 259 /* AF_INET6 available check */
 260 #include <sys/types.h>
 261 #include <sys/socket.h>
 262 #include <netinet/in.h>
 263 #ifdef AF_INET6
 264 void
 265 foo(struct in6_addr *addr)
 266 {
 267  memset(addr, 0, sizeof (struct in6_addr));
 268 }
 269 #else
 270 #error "AF_INET6 not defined"
 271 #endif
 272         ]])
 273     ],
 274     [
 275         AC_MSG_RESULT(yes)
 276         AC_DEFINE(HAVE_OS_IPV6_SUPPORT, 1,
 277             [define if the OS provides AF_INET6 and struct in6_addr])
 278         ipv6=yes
 279     ],
 280     [
 281         AC_MSG_RESULT(no)
 282         ipv6=no
 283     ]
 284 )
 285
 286 ipv6type=unknown
 287 ipv6lib=none
 288 ipv6trylibc=no
 289
 290 if test "$ipv6" = "yes"; then
 291         AC_MSG_CHECKING([ipv6 stack type])
 292         for i in inria kame linux-glibc linux-libinet6 toshiba v6d zeta; do
 293                 case $i in
 294                 inria)
 295                         dnl http://www.kame.net/
 296                         AC_EGREP_CPP(yes,
 297 [#include <netinet/in.h>
 298 #ifdef IPV6_INRIA_VERSION
 299 yes
 300 #endif],
 301                                 [ipv6type=$i])
 302                         ;;
 303                 kame)
 304                         dnl http://www.kame.net/
 305                         AC_EGREP_CPP(yes,
 306 [#include <netinet/in.h>
 307 #ifdef __KAME__
 308 yes
 309 #endif],
 310                                 [ipv6type=$i;
 311                                 ipv6lib=inet6;
 312                                 ipv6libdir=/usr/local/v6/lib;
 313                                 ipv6trylibc=yes])
 314                         ;;
 315                 linux-glibc)
 316                         dnl http://www.v6.linux.or.jp/
 317                         AC_EGREP_CPP(yes,
 318 [#include <features.h>
 319 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 320 yes
 321 #endif],
 322                                 [ipv6type=$i])
 323                         ;;
 324                 linux-libinet6)
 325                         dnl http://www.v6.linux.or.jp/
 326                         dnl
 327                         dnl This also matches Solaris 8 and Tru64 UNIX 5.1,
 328                         dnl and possibly other versions of those OSes
 329                         dnl
 330                         if test -d /usr/inet6 -o -f /usr/include/netinet/ip6.h; then
 331                                 ipv6type=$i
 332                                 ipv6lib=inet6
 333                                 ipv6libdir=/usr/inet6/lib
 334                                 ipv6trylibc=yes;
 335                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 336                         fi
 337                         ;;
 338                 toshiba)
 339                         AC_EGREP_CPP(yes,
 340 [#include <sys/param.h>
 341 #ifdef _TOSHIBA_INET6
 342 yes
 343 #endif],
 344                                 [ipv6type=$i;
 345                                 ipv6lib=inet6;
 346                                 ipv6libdir=/usr/local/v6/lib])
 347                         ;;
 348                 v6d)
 349                         AC_EGREP_CPP(yes,
 350 [#include </usr/local/v6/include/sys/v6config.h>
 351 #ifdef __V6D__
 352 yes
 353 #endif],
 354                                 [ipv6type=$i;
 355                                 ipv6lib=v6;
 356                                 ipv6libdir=/usr/local/v6/lib;
 357                                 CFLAGS="-I/usr/local/v6/include $CFLAGS"])
 358                         ;;
 359                 zeta)
 360                         AC_EGREP_CPP(yes,
 361 [#include <sys/param.h>
 362 #ifdef _ZETA_MINAMI_INET6
 363 yes
 364 #endif],
 365                                 [ipv6type=$i;
 366                                 ipv6lib=inet6;
 367                                 ipv6libdir=/usr/local/v6/lib])
 368                         ;;
 369                 esac
 370                 if test "$ipv6type" != "unknown"; then
 371                         break
 372                 fi
 373         done
 374         AC_MSG_RESULT($ipv6type)
 375 fi
 376
 377 if test "$ipv6" = "yes" -a "$ipv6lib" != "none"; then
 378         if test -d $ipv6libdir -a -f $ipv6libdir/lib$ipv6lib.a; then
 379                 LIBS="-L$ipv6libdir -l$ipv6lib $LIBS"
 380                 echo "You have $ipv6lib library, using it"
 381         else
 382                 if test "$ipv6trylibc" = "yes"; then
 383                         echo "You do not have $ipv6lib library, using libc"
 384                 else
 385                         echo 'Fatal: no $ipv6lib library found.  cannot continue.'
 386                         echo "You need to fetch lib$ipv6lib.a from appropriate"
 387                         echo 'ipv6 kit and compile beforehand.'
 388                         exit 1
 389                 fi
 390         fi
 391 fi
 392
 393 AC_CACHE_CHECK([for dnet_htoa declaration in netdnet/dnetdb.h],
 394 [td_cv_decl_netdnet_dnetdb_h_dnet_htoa],
 395 [AC_EGREP_HEADER(dnet_htoa, netdnet/dnetdb.h,
 396         td_cv_decl_netdnet_dnetdb_h_dnet_htoa=yes,
 397         td_cv_decl_netdnet_dnetdb_h_dnet_htoa=no)])
 398 if test "$td_cv_decl_netdnet_dnetdb_h_dnet_htoa" = yes; then
 399         AC_DEFINE(HAVE_NETDNET_DNETDB_H_DNET_HTOA, 1,
 400             [define if you have a dnet_htoa declaration in <netdnet/dnetdb.h>])
 401 fi
 402
 403 AC_REPLACE_FUNCS(vfprintf strlcat strlcpy strdup strsep getservent getopt_long)
 404 AC_CHECK_FUNCS(fork vfork strftime)
 405 AC_CHECK_FUNCS(setlinebuf alarm)
 406
 407 needsnprintf=no
 408 AC_CHECK_FUNCS(vsnprintf snprintf,,
 409         [needsnprintf=yes])
 410 if test $needsnprintf = yes; then
 411         AC_LIBOBJ(snprintf)
 412 fi
 413
 414 AC_SEARCH_LIBS(dnet_htoa, dnet,
 415     AC_DEFINE(HAVE_DNET_HTOA, 1, [define if you have the dnet_htoa function]))
 416
 417 AC_CHECK_LIB(rpc, main)         dnl It's unclear why we might need -lrpc
 418
 419 dnl Some platforms may need -lnsl for getrpcbynumber.
 420 AC_SEARCH_LIBS(getrpcbynumber, nsl,
 421     AC_DEFINE(HAVE_GETRPCBYNUMBER, 1, [define if you have getrpcbynumber()]))
 422
 423 AC_LBL_LIBPCAP(V_PCAPDEP, V_INCLS)
 424
 425 #
 426 # Check for these after AC_LBL_LIBPCAP, so we link with the appropriate
 427 # libraries (e.g., "-lsocket -lnsl" on Solaris).
 428 #
 429 # You are in a twisty little maze of UN*Xes, all different.
 430 # Some might not have ether_ntohost().
 431 # Some might have it, but not declare it in any header file.
 432 # Some might have it, but declare it in <netinet/if_ether.h>.
 433 # Some might have it, but declare it in <netinet/ether.h>
 434 # (And some might have it but document it as something declared in
 435 # <netinet/ethernet.h>, although <netinet/if_ether.h> appears to work.)
 436 #
 437 # Before you is a C compiler.
 438 #
 439 AC_CHECK_FUNCS(ether_ntohost, [
 440     AC_CACHE_CHECK(for buggy ether_ntohost, ac_cv_buggy_ether_ntohost, [
 441         AC_TRY_RUN([
 442                 #include <netdb.h>
 443                 #include <sys/types.h>
 444                 #include <sys/param.h>
 445                 #include <sys/socket.h>
 446
 447                 int
 448                 main(int argc, char **argv)
 449                 {
 450                         u_char ea[6] = { 0xff, 0xff, 0xff, 0xff, 0xff };
 451                         char name[MAXHOSTNAMELEN];
 452
 453                         ether_ntohost(name, (struct ether_addr *)ea);
 454                         exit(0);
 455                 }
 456         ], [ac_cv_buggy_ether_ntohost=no],
 457            [ac_cv_buggy_ether_ntohost=yes],
 458            [ac_cv_buggy_ether_ntohost="not while cross-compiling"])])
 459     if test "$ac_cv_buggy_ether_ntohost" = "no"; then
 460         AC_DEFINE(USE_ETHER_NTOHOST, 1,
 461             [define if you have ether_ntohost() and it works])
 462     fi
 463 ])
 464 if test "$ac_cv_func_ether_ntohost" = yes -a \
 465     "$ac_cv_buggy_ether_ntohost" = "no"; then
 466         #
 467         # OK, we have ether_ntohost().  Do we have <netinet/if_ether.h>?
 468         #
 469         if test "$ac_cv_header_netinet_if_ether_h" = yes; then
 470                 #
 471                 # Yes.  Does it declare ether_ntohost()?
 472                 #
 473                 AC_CHECK_DECL(ether_ntohost,
 474                     [
 475                         AC_DEFINE(NETINET_IF_ETHER_H_DECLARES_ETHER_NTOHOST,,
 476                             [Define to 1 if netinet/if_ether.h declares `ether_ntohost'])
 477                     ],,
 478                     [
 479 #include <sys/types.h>
 480 #include <sys/socket.h>
 481 #include <netinet/in.h>
 482 #include <arpa/inet.h>
 483 struct mbuf;
 484 struct rtentry;
 485 #include <net/if.h>
 486 #include <netinet/if_ether.h>
 487                     ])
 488         fi
 489         #
 490         # Did that succeed?
 491         #
 492         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 493                 #
 494                 # No, how about <netinet/ether.h>, as on Linux?
 495                 #
 496                 AC_CHECK_HEADERS(netinet/ether.h)
 497                 if test "$ac_cv_header_netinet_ether_h" = yes; then
 498                         #
 499                         # We have it - does it declare ether_ntohost()?
 500                         # Unset ac_cv_have_decl_ether_ntohost so we don't
 501                         # treat the previous failure as a cached value and
 502                         # suppress the next test.
 503                         #
 504                         unset ac_cv_have_decl_ether_ntohost
 505                         AC_CHECK_DECL(ether_ntohost,
 506                             [
 507                                 AC_DEFINE(NETINET_ETHER_H_DECLARES_ETHER_NTOHOST,,
 508                                     [Define to 1 if netinet/ether.h declares `ether_ntohost'])
 509                             ],,
 510                             [
 511 #include <netinet/ether.h>
 512                             ])
 513                 fi
 514         fi
 515         #
 516         # Is ether_ntohost() declared?
 517         #
 518         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 519                 #
 520                 # No, we'll have to declare it ourselves.
 521                 # Do we have "struct ether_addr"?
 522                 #
 523                 AC_CHECK_TYPES(struct ether_addr,,,
 524                     [
 525 #include <sys/types.h>
 526 #include <sys/socket.h>
 527 #include <netinet/in.h>
 528 #include <arpa/inet.h>
 529 struct mbuf;
 530 struct rtentry;
 531 #include <net/if.h>
 532 #include <netinet/if_ether.h>
 533                     ])
 534                 AC_DEFINE(HAVE_DECL_ETHER_NTOHOST, 0,
 535                     [Define to 1 if you have the declaration of `ether_ntohost', and to 0 if you
 536 don't.])
 537         else
 538                 AC_DEFINE(HAVE_DECL_ETHER_NTOHOST, 1,
 539                     [Define to 1 if you have the declaration of `ether_ntohost', and to 0 if you
 540 don't.])
 541         fi
 542 fi
 543
 544 # libdlpi is needed for Solaris 11 and later.
 545 AC_CHECK_LIB(dlpi, dlpi_walk, LIBS="$LIBS -ldlpi" LDFLAGS="-L/lib $LDFLAGS", ,-L/lib)
 546
 547 dnl
 548 dnl Check for "pcap_list_datalinks()", "pcap_set_datalink()",
 549 dnl and "pcap_datalink_name_to_val()", and use substitute versions
 550 dnl if they're not present.
 551 dnl
 552 AC_CHECK_FUNC(pcap_list_datalinks,
 553         [
 554             AC_DEFINE(HAVE_PCAP_LIST_DATALINKS, 1,
 555                 [define if libpcap has pcap_list_datalinks()])
 556             AC_CHECK_FUNCS(pcap_free_datalinks)
 557         ],
 558         [
 559             AC_LIBOBJ(datalinks)
 560         ])
 561 AC_CHECK_FUNCS(pcap_set_datalink)
 562 AC_CHECK_FUNC(pcap_datalink_name_to_val,
 563         [
 564             AC_DEFINE(HAVE_PCAP_DATALINK_NAME_TO_VAL, 1,
 565                 [define if libpcap has pcap_datalink_name_to_val()])
 566             AC_CHECK_FUNC(pcap_datalink_val_to_description,
 567                 AC_DEFINE(HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION, 1,
 568                     [define if libpcap has pcap_datalink_val_to_description()]),
 569                 [
 570                     AC_LIBOBJ(dlnames)
 571                 ])
 572         ],
 573         [
 574             AC_LIBOBJ(dlnames)
 575         ])
 576
 577 dnl
 578 dnl Check for "pcap_breakloop()"; you can't substitute for it if
 579 dnl it's absent (it has hooks into the live capture routines),
 580 dnl so just define the HAVE_ value if it's there.
 581 dnl
 582 AC_CHECK_FUNCS(pcap_breakloop)
 583
 584 dnl
 585 dnl Check for "pcap_dump_ftell()" and use a substitute version
 586 dnl if it's not present.
 587 dnl
 588 AC_CHECK_FUNC(pcap_dump_ftell,
 589         AC_DEFINE(HAVE_PCAP_DUMP_FTELL, 1,
 590             [define if libpcap has pcap_dump_ftell()]),
 591         [
 592             AC_LIBOBJ(pcap_dump_ftell)
 593         ])
 594
 595 #
 596 # Do we have the new open API?  Check for pcap_create, and assume that,
 597 # if we do, we also have pcap_activate() and the other new routines
 598 # introduced in libpcap 1.0.0.
 599 #
 600 AC_CHECK_FUNCS(pcap_create)
 601 if test $ac_cv_func_pcap_create = "yes" ; then
 602         #
 603         # OK, do we have pcap_set_tstamp_type?  If so, assume we have
 604         # pcap_list_tstamp_types and pcap_free_tstamp_types as well.
 605         #
 606         AC_CHECK_FUNCS(pcap_set_tstamp_type)
 607         #
 608         # And do we have pcap_set_tstamp_precision?  If so, we assume
 609         # we also have pcap_open_offline_with_tstamp_precision.
 610         #
 611         AC_CHECK_FUNCS(pcap_set_tstamp_precision)
 612 fi
 613
 614 #
 615 # Check for a miscellaneous collection of functions which we use
 616 # if we have them.
 617 #
 618 AC_CHECK_FUNCS(pcap_findalldevs)
 619 if test $ac_cv_func_pcap_findalldevs = "yes" ; then
 620 dnl Check for Mac OS X, which may ship pcap.h from 0.6 but libpcap may
 621 dnl be 0.8; this means that lib has pcap_findalldevs but header doesn't
 622 dnl have pcap_if_t.
 623     savedcppflags="$CPPFLAGS"
 624     CPPFLAGS="$CPPFLAGS $V_INCLS"
 625     AC_CHECK_TYPES(pcap_if_t, , , [#include <pcap.h>])
 626     CPPFLAGS="$savedcppflags"
 627 fi
 628 AC_CHECK_FUNCS(pcap_dump_flush pcap_lib_version)
 629 if test $ac_cv_func_pcap_lib_version = "no" ; then
 630     AC_MSG_CHECKING(whether pcap_version is defined by libpcap)
 631     AC_TRY_LINK([],
 632        [
 633         extern char pcap_version[];
 634
 635         return (int)pcap_version;
 636        ],
 637        ac_lbl_cv_pcap_version_defined=yes,
 638        ac_lbl_cv_pcap_version_defined=no)
 639     if test "$ac_lbl_cv_pcap_version_defined" = yes ; then
 640         AC_MSG_RESULT(yes)
 641         AC_DEFINE(HAVE_PCAP_VERSION, 1, [define if libpcap has pcap_version])
 642     else
 643         AC_MSG_RESULT(no)
 644     fi
 645 fi
 646 AC_CHECK_FUNCS(pcap_setdirection pcap_set_immediate_mode pcap_dump_ftell64)
 647 AC_CHECK_FUNCS(pcap_open pcap_findalldevs_ex)
 648
 649 #
 650 # Check for special debugging functions
 651 #
 652 AC_CHECK_FUNCS(pcap_set_parser_debug)
 653 if test "$ac_cv_func_pcap_set_parser_debug" = "no" ; then
 654         #
 655         # OK, we don't have pcap_set_parser_debug() to set the libpcap
 656         # filter expression parser debug flag; can we directly set the
 657         # flag?
 658         AC_MSG_CHECKING(whether pcap_debug is defined by libpcap)
 659         AC_TRY_LINK([],
 660            [
 661                 extern int pcap_debug;
 662
 663                 return pcap_debug;
 664            ],
 665            ac_lbl_cv_pcap_debug_defined=yes,
 666            ac_lbl_cv_pcap_debug_defined=no)
 667         if test "$ac_lbl_cv_pcap_debug_defined" = yes ; then
 668                 AC_MSG_RESULT(yes)
 669                 AC_DEFINE(HAVE_PCAP_DEBUG, 1, [define if libpcap has pcap_debug])
 670         else
 671                 AC_MSG_RESULT(no)
 672                 #
 673                 # OK, what about "yydebug"?
 674                 #
 675                 AC_MSG_CHECKING(whether yydebug is defined by libpcap)
 676                 AC_TRY_LINK([],
 677                    [
 678                         extern int yydebug;
 679
 680                         return yydebug;
 681                    ],
 682                    ac_lbl_cv_yydebug_defined=yes,
 683                    ac_lbl_cv_yydebug_defined=no)
 684                 if test "$ac_lbl_cv_yydebug_defined" = yes ; then
 685                         AC_MSG_RESULT(yes)
 686                         AC_DEFINE(HAVE_YYDEBUG, 1, [define if libpcap has yydebug])
 687                 else
 688                         AC_MSG_RESULT(no)
 689                 fi
 690         fi
 691 fi
 692 AC_CHECK_FUNCS(pcap_set_optimizer_debug)
 693 AC_REPLACE_FUNCS(bpf_dump)      dnl moved to libpcap in 0.6
 694
 695 V_GROUP=0
 696 if test -f /etc/group -a ! -z "`grep '^wheel:' /etc/group`" ; then
 697         V_GROUP=wheel
 698 fi
 699 #
 700 # Assume V7/BSD convention for man pages (file formats in section 5,
 701 # miscellaneous info in section 7).
 702 #
 703 MAN_FILE_FORMATS=5
 704 MAN_MISC_INFO=7
 705 case "$host_os" in
 706
 707 aix*)
 708         dnl Workaround to enable certain features
 709         AC_DEFINE(_SUN,1,[define on AIX to get certain functions])
 710         ;;
 711
 712 hpux*)
 713         #
 714         # Use System V conventions for man pages.
 715         #
 716         MAN_FILE_FORMATS=4
 717         MAN_MISC_INFO=5
 718         ;;
 719
 720 irix*)
 721         V_GROUP=sys
 722
 723         #
 724         # Use System V conventions for man pages.
 725         #
 726         MAN_FILE_FORMATS=4
 727         MAN_MISC_INFO=5
 728         ;;
 729
 730 osf*)
 731         V_GROUP=system
 732
 733         #
 734         # Use System V conventions for man pages.
 735         #
 736         MAN_FILE_FORMATS=4
 737         MAN_MISC_INFO=5
 738         ;;
 739
 740 solaris*)
 741         V_GROUP=sys
 742
 743         #
 744         # Use System V conventions for man pages.
 745         #
 746         MAN_FILE_FORMATS=4
 747         MAN_MISC_INFO=5
 748         ;;
 749 esac
 750
 751 if test -f /dev/bpf0 ; then
 752         V_GROUP=bpf
 753 fi
 754
 755 #
 756 # Make sure we have a definition for C99's uintptr_t (regardless of
 757 # whether the environment is a C99 environment or not).
 758 #
 759 AC_TYPE_UINTPTR_T
 760
 761 #
 762 # Check whether we have pcap/pcap-inttypes.h.
 763 # If we do, we use that to get the C99 types defined.
 764 #
 765 savedcppflags="$CPPFLAGS"
 766 CPPFLAGS="$CPPFLAGS $V_INCLS"
 767 AC_CHECK_HEADERS(pcap/pcap-inttypes.h)
 768 CPPFLAGS="$savedcppflags"
 769
 770 #
 771 # Define the old BSD specified-width types in terms of the C99 types;
 772 # we may need them with libpcap include files.
 773 #
 774 AC_CHECK_TYPE([u_int8_t], ,
 775         [AC_DEFINE([u_int8_t], [uint8_t],
 776         [Define to `uint8_t' if u_int8_t not defined.])],
 777         [AC_INCLUDES_DEFAULT
 778 #include <sys/types.h>
 779 ])
 780 AC_CHECK_TYPE([u_int16_t], ,
 781         [AC_DEFINE([u_int16_t], [uint16_t],
 782         [Define to `uint16_t' if u_int16_t not defined.])],
 783         [AC_INCLUDES_DEFAULT
 784 #include <sys/types.h>
 785 ])
 786 AC_CHECK_TYPE([u_int32_t], ,
 787         [AC_DEFINE([u_int32_t], [uint32_t],
 788         [Define to `uint32_t' if u_int32_t not defined.])],
 789         [AC_INCLUDES_DEFAULT
 790 #include <sys/types.h>
 791 ])
 792 AC_CHECK_TYPE([u_int64_t], ,
 793         [AC_DEFINE([u_int64_t], [uint64_t],
 794         [Define to `uint64_t' if u_int64_t not defined.])],
 795         [AC_INCLUDES_DEFAULT
 796 #include <sys/types.h>
 797 ])
 798
 799 #
 800 # Check for some headers introduced in later versions of libpcap
 801 # and used by some printers.
 802 #
 803 # Those headers might use the {u_}intN_t types, so we must do this
 804 # after we check for what's needed to get them defined.
 805 #
 806 savedcppflags="$CPPFLAGS"
 807 CPPFLAGS="$CPPFLAGS $V_INCLS"
 808 AC_CHECK_HEADERS(pcap/bluetooth.h,,,[#include "netdissect-stdinc.h"])
 809 AC_CHECK_HEADERS(pcap/nflog.h,,,[#include "netdissect-stdinc.h"])
 810 AC_CHECK_HEADERS(pcap/usb.h,,,[#include "netdissect-stdinc.h"])
 811 CPPFLAGS="$savedcppflags"
 812
 813 AC_PROG_RANLIB
 814 AC_CHECK_TOOL([AR], [ar])
 815
 816 AC_LBL_DEVEL(V_CCOPT)
 817
 818 # Check for OpenSSL/libressl libcrypto
 819 AC_MSG_CHECKING(whether to use OpenSSL/libressl libcrypto)
 820 # Specify location for both includes and libraries.
 821 want_libcrypto=ifavailable
 822 AC_ARG_WITH(crypto,
 823     AS_HELP_STRING([--with-crypto]@<:@=DIR@:>@,
 824                    [use OpenSSL/libressl libcrypto (located in directory DIR, if specified) @<:@default=yes, if available@:>@]),
 825 [
 826         if test $withval = no
 827         then
 828                 # User doesn't want to link with libcrypto.
 829                 want_libcrypto=no
 830                 AC_MSG_RESULT(no)
 831         elif test $withval = yes
 832         then
 833                 # User wants to link with libcrypto but hasn't specified
 834                 # a directory.
 835                 want_libcrypto=yes
 836                 AC_MSG_RESULT(yes)
 837         else
 838                 # User wants to link with libcrypto and has specified
 839                 # a directory, so use the provided value.
 840                 want_libcrypto=yes
 841                 libcrypto_root=$withval
 842                 AC_MSG_RESULT([yes, using the version installed in $withval])
 843
 844                 #
 845                 # Put the subdirectories of the libcrypto root directory
 846                 # at the front of the header and library search path.
 847                 #
 848                 CFLAGS="-I$withval/include $CFLAGS"
 849                 LIBS="-L$withval/lib $LIBS"
 850         fi
 851 ],[
 852         #
 853         # Use libcrypto if it's present, otherwise don't; no directory
 854         # was specified.
 855         #
 856         want_libcrypto=ifavailable
 857         AC_MSG_RESULT([yes, if available])
 858 ])
 859 if test "$want_libcrypto" != "no"; then
 860         #
 861         # Don't check for libcrypto unless we have its headers;
 862         # Apple, bless their pointy little heads, apparently ship
 863         # libcrypto as a library, but not the header files, in
 864         # El Capitan, probably because they don't want you writing
 865         # nasty portable code that could run on other UN*Xes, they
 866         # want you writing code that uses their Shiny New Crypto
 867         # Library and that only runs on OS X.
 868         #
 869         AC_CHECK_HEADER(openssl/crypto.h,
 870         [
 871                 AC_CHECK_LIB(crypto, DES_cbc_encrypt)
 872                 if test "$ac_cv_lib_crypto_DES_cbc_encrypt" = "yes"; then
 873                         AC_CHECK_HEADERS(openssl/evp.h)
 874                         #
 875                         # OK, then:
 876                         #
 877                         # 1) do we have EVP_CIPHER_CTX_new?
 878                         # If so, we use it to allocate an
 879                         # EVP_CIPHER_CTX, as EVP_CIPHER_CTX may be
 880                         # opaque; otherwise, we allocate it ourselves.
 881                         #
 882                         # 2) do we have EVP_CipherInit_ex()?
 883                         # If so, we use it, because we need to be
 884                         # able to make two "initialize the cipher"
 885                         # calls, one with the cipher and key, and
 886                         # one with the IV, and, as of OpenSSL 1.1,
 887                         # You Can't Do That with EVP_CipherInit(),
 888                         # because a call to EVP_CipherInit() will
 889                         # unconditionally clear the context, and
 890                         # if you don't supply a cipher, it'll
 891                         # clear the cipher, rendering the context
 892                         # unusable and causing a crash.
 893                         #
 894                         AC_CHECK_FUNCS(EVP_CIPHER_CTX_new EVP_CipherInit_ex)
 895                 fi
 896         ])
 897 fi
 898
 899 # Check for libcap-ng
 900 AC_MSG_CHECKING(whether to use libcap-ng)
 901 # Specify location for both includes and libraries.
 902 want_libcap_ng=ifavailable
 903 AC_ARG_WITH(cap_ng,
 904     AS_HELP_STRING([--with-cap-ng],
 905                    [use libcap-ng @<:@default=yes, if available@:>@]),
 906 [
 907         if test $withval = no
 908         then
 909                 want_libcap_ng=no
 910                 AC_MSG_RESULT(no)
 911         elif test $withval = yes
 912         then
 913                 want_libcap_ng=yes
 914                 AC_MSG_RESULT(yes)
 915         fi
 916 ],[
 917         #
 918         # Use libcap-ng if it's present, otherwise don't.
 919         #
 920         want_libcap_ng=ifavailable
 921         AC_MSG_RESULT([yes, if available])
 922 ])
 923 if test "$want_libcap_ng" != "no"; then
 924         AC_CHECK_LIB(cap-ng, capng_change_id)
 925         AC_CHECK_HEADERS(cap-ng.h)
 926 fi
 927
 928 dnl
 929 dnl set additional include path if necessary
 930 if test "$missing_includes" = "yes"; then
 931         CPPFLAGS="$CPPFLAGS -I$srcdir/missing"
 932         V_INCLS="$V_INCLS -I$srcdir/missing"
 933 fi
 934
 935 AC_SUBST(V_CCOPT)
 936 AC_SUBST(V_DEFS)
 937 AC_SUBST(V_GROUP)
 938 AC_SUBST(V_INCLS)
 939 AC_SUBST(V_PCAPDEP)
 940 AC_SUBST(LOCALSRC)
 941 AC_SUBST(MAN_FILE_FORMATS)
 942 AC_SUBST(MAN_MISC_INFO)
 943
 944 AC_PROG_INSTALL
 945
 946 AC_CONFIG_HEADER(config.h)
 947
 948 AC_OUTPUT_COMMANDS([if test -f .devel; then
 949         echo timestamp > stamp-h
 950         cat Makefile-devel-adds >> Makefile
 951         make depend
 952 fi])
 953 AC_OUTPUT(Makefile tcpdump.1)
 954 exit 0