The Tcpdump Group git mirrors - tcpdump/blob - configure.in

   1 dnl Copyright (c) 1994, 1995, 1996, 1997
   2 dnl     The Regents of the University of California.  All rights reserved.
   3 dnl
   4 dnl Process this file with autoconf to produce a configure script.
   5 dnl
   6
   7 #
   8 # See
   9 #
  10 #       http://ftp.gnu.org/gnu/config/README
  11 #
  12 # for the URLs to use to fetch new versions of config.guess and
  13 # config.sub.
  14 #
  15
  16 AC_PREREQ(2.61)
  17 AC_INIT(tcpdump.c)
  18
  19 AC_CANONICAL_HOST
  20
  21 AC_LBL_C_INIT_BEFORE_CC(V_INCLS)
  22 AC_PROG_CC
  23 AC_LBL_C_INIT(V_CCOPT, V_INCLS)
  24 AC_LBL_C_INLINE
  25 AC_C___ATTRIBUTE__
  26 if test "$ac_cv___attribute__" = "yes"; then
  27         AC_C___ATTRIBUTE___UNUSED
  28         AC_C___ATTRIBUTE___NORETURN_FUNCTION_POINTER
  29         AC_C___ATTRIBUTE___FORMAT
  30         if test "$ac_cv___attribute___format" = "yes"; then
  31                 AC_C___ATTRIBUTE___FORMAT_FUNCTION_POINTER
  32         fi
  33 fi
  34
  35 AC_CHECK_HEADERS(fcntl.h rpc/rpc.h rpc/rpcent.h netdnet/dnetdb.h)
  36 AC_CHECK_HEADERS(net/pfvar.h, , , [#include <sys/types.h>
  37 #include <sys/socket.h>
  38 #include <net/if.h>])
  39 if test "$ac_cv_header_net_pfvar_h" = yes; then
  40         LOCALSRC="print-pflog.c $LOCALSRC"
  41 fi
  42 AC_CHECK_HEADERS(netinet/if_ether.h, , , [#include <sys/types.h>
  43 #include <sys/socket.h>])
  44 if test "$ac_cv_header_netinet_if_ether_h" != yes; then
  45         #
  46         # The simple test didn't work.
  47         # Do we need to include <net/if.h> first?
  48         # Unset ac_cv_header_netinet_if_ether_h so we don't
  49         # treat the previous failure as a cached value and
  50         # suppress the next test.
  51         #
  52         AC_MSG_NOTICE([Rechecking with some additional includes])
  53         unset ac_cv_header_netinet_if_ether_h
  54         AC_CHECK_HEADERS(netinet/if_ether.h, , , [#include <sys/types.h>
  55 #include <sys/socket.h>
  56 #include <netinet/in.h>
  57 struct mbuf;
  58 struct rtentry;
  59 #include <net/if.h>])
  60 fi
  61
  62 AC_HEADER_TIME
  63
  64 case "$host_os" in
  65
  66 darwin*)
  67         AC_ARG_ENABLE(universal,
  68         AC_HELP_STRING([--disable-universal],[don't build universal on OS X]))
  69         if test "$enable_universal" != "no"; then
  70                 case "$host_os" in
  71
  72                 darwin9.*)
  73                         #
  74                         # Leopard.  Build for x86 and 32-bit PowerPC, with
  75                         # x86 first.  (That's what Apple does.)
  76                         #
  77                         V_CCOPT="$V_CCOPT -arch i386 -arch ppc"
  78                         LDFLAGS="$LDFLAGS -arch i386 -arch ppc"
  79                         ;;
  80
  81                 darwin10.*)
  82                         #
  83                         # Snow Leopard.  Build for x86-64 and x86, with
  84                         # x86-64 first.  (That's what Apple does.)
  85                         #
  86                         V_CCOPT="$V_CCOPT -arch x86_64 -arch i386"
  87                         LDFLAGS="$LDFLAGS -arch x86_64 -arch i386"
  88                         ;;
  89                 esac
  90         fi
  91         ;;
  92 esac
  93
  94
  95 AC_ARG_WITH(smi,
  96 [  --with-smi              link with libsmi (allows to load MIBs on the fly to decode SNMP packets. [default=yes]
  97   --without-smi           don't link with libsmi],,
  98    with_smi=yes)
  99
 100 if test "x$with_smi" != "xno" ; then
 101 AC_CHECK_HEADERS(smi.h)
 102 AC_CHECK_LIB(smi, smiInit)
 103 if test "$ac_cv_header_smi_h" = yes -a "$ac_cv_lib_smi_smiInit" = yes
 104 then
 105 AC_MSG_CHECKING([whether to enable libsmi])
 106         AC_TRY_RUN([ /* libsmi available check */
 107 #include <smi.h>
 108 main()
 109 {
 110   int current, revision, age, n;
 111   const int required = 2;
 112   if (smiInit(""))
 113     exit(1);
 114   if (strcmp(SMI_LIBRARY_VERSION, smi_library_version))
 115     exit(2);
 116   n = sscanf(smi_library_version, "%d:%d:%d", &current, &revision, &age);
 117   if (n != 3)
 118     exit(3);
 119   if (required < current - age || required > current)
 120     exit(4);
 121   exit(0);
 122 }
 123 ],
 124 [ AC_MSG_RESULT(yes)
 125   AC_DEFINE(LIBSMI, 1, [Define if you enable support for libsmi])
 126   libsmi=yes],
 127 dnl autoconf documentation says that $? contains the exit value.
 128 dnl reality is that it does not.  We leave this in just in case
 129 dnl autoconf ever comes back to match the documentation.
 130 [ case $? in
 131   1) AC_MSG_RESULT(no - smiInit failed) ;;
 132   2) AC_MSG_RESULT(no - header/library version mismatch) ;;
 133   3) AC_MSG_RESULT(no - can't determine library version) ;;
 134   4) AC_MSG_RESULT(no - too old) ;;
 135   *) AC_MSG_RESULT(no) ;;
 136   esac
 137   libsmi=no],
 138 [ AC_MSG_RESULT(not when cross-compiling)
 139   libsmi=no]
 140 )
 141 fi
 142 fi
 143
 144 AC_MSG_CHECKING([whether to enable the possibly-buggy SMB printer])
 145 AC_ARG_ENABLE(smb,
 146 [  --enable-smb            enable possibly-buggy SMB printer [default=yes]
 147   --disable-smb           disable possibly-buggy SMB printer],,
 148    enableval=yes)
 149 case "$enableval" in
 150 yes)    AC_MSG_RESULT(yes)
 151         AC_WARN([The SMB printer may have exploitable buffer overflows!!!])
 152         AC_DEFINE(TCPDUMP_DO_SMB, 1,
 153             [define if you want to build the possibly-buggy SMB printer])
 154         LOCALSRC="print-smb.c smbutil.c $LOCALSRC"
 155         ;;
 156 *)      AC_MSG_RESULT(no)
 157         ;;
 158 esac
 159
 160 AC_ARG_WITH(user, [  --with-user=USERNAME    drop privileges by default to USERNAME])
 161 AC_MSG_CHECKING([whether to drop root privileges by default])
 162 if test ! -z "$with_user" ; then
 163        AC_DEFINE_UNQUOTED(WITH_USER, "$withval",
 164            [define if should drop privileges by default])
 165        AC_MSG_RESULT(to \"$withval\")
 166 else
 167        AC_MSG_RESULT(no)
 168 fi
 169
 170 AC_ARG_WITH(chroot, [  --with-chroot=DIRECTORY when dropping privileges, chroot to DIRECTORY])
 171 AC_MSG_CHECKING([whether to chroot])
 172 if test ! -z "$with_chroot" && test "$with_chroot" != "no" ; then
 173        AC_DEFINE_UNQUOTED(WITH_CHROOT, "$withval",
 174            [define if should chroot when dropping privileges])
 175        AC_MSG_RESULT(to \"$withval\")
 176 else
 177        AC_MSG_RESULT(no)
 178 fi
 179
 180 AC_ARG_WITH(sandbox-capsicum, [ --with-sandbox-capsicum ])
 181 #
 182 # Check whether various functions are available.  If any are, set
 183 # ac_lbl_capsicum_function_seen to yes; if any are not, set
 184 # ac_lbl_capsicum_function_not_seen to yes.
 185 #
 186 # All of them must be available in order to enable capsicum sandboxing.
 187 #
 188 if test ! -z "$with_sandbox-capsicum" && test "$with_sandbox-capsicum" != "no" ; then
 189         AC_CHECK_FUNCS(cap_enter cap_rights_init cap_rights_limit cap_ioctls_limit openat,
 190             ac_lbl_capsicum_function_seen=yes,
 191             ac_lbl_capsicum_function_not_seen=yes)
 192 fi
 193 AC_MSG_CHECKING([whether to sandbox using capsicum])
 194 if test "x$ac_lbl_capsicum_function_seen" = "xyes" -a "x$ac_lbl_capsicum_function_not_seen" != "xyes"; then
 195         AC_DEFINE(HAVE_CAPSICUM, 1, [capsicum support available])
 196         AC_MSG_RESULT(yes)
 197 else
 198         AC_MSG_RESULT(no)
 199 fi
 200
 201 #
 202 # We must check this before checking whether to enable IPv6, because,
 203 # on some platforms (such as SunOS 5.x), the test program requires
 204 # the extra networking libraries.
 205 #
 206 AC_LBL_LIBRARY_NET
 207
 208 AC_MSG_CHECKING([whether to enable ipv6])
 209 AC_ARG_ENABLE(ipv6,
 210 [  --enable-ipv6           enable ipv6 (with ipv4) support
 211   --disable-ipv6          disable ipv6 support],
 212 [ case "$enableval" in
 213 yes)   AC_MSG_RESULT(yes)
 214        LOCALSRC="print-ip6.c print-ip6opts.c print-mobility.c print-ripng.c print-icmp6.c print-frag6.c print-rt6.c print-ospf6.c print-dhcp6.c print-babel.c $LOCALSRC"
 215        AC_DEFINE(INET6, 1, [Define if you enable IPv6 support])
 216        ipv6=yes
 217        ;;
 218 *)
 219        AC_MSG_RESULT(no)
 220        ipv6=no
 221        ;;
 222   esac ],
 223
 224   AC_COMPILE_IFELSE(
 225     [
 226       AC_LANG_SOURCE(
 227         [[/* AF_INET6 available check */
 228 #include <sys/types.h>
 229 #include <sys/socket.h>
 230 #include <netinet/in.h>
 231 #ifdef AF_INET6
 232 void
 233 foo(struct in6_addr *addr)
 234 {
 235  memset(addr, 0, sizeof (struct in6_addr));
 236 }
 237 #else
 238 #error "AF_INET6 not defined"
 239 #endif
 240         ]])
 241     ],
 242 [ AC_MSG_RESULT(yes)
 243   LOCALSRC="print-ip6.c print-ip6opts.c print-mobility.c print-ripng.c print-icmp6.c print-frag6.c print-rt6.c print-ospf6.c print-dhcp6.c print-babel.c $LOCALSRC"
 244   AC_DEFINE(INET6, 1, [Define if you enable IPv6 support])
 245   ipv6=yes],
 246 [ AC_MSG_RESULT(no)
 247   ipv6=no],
 248 [ AC_MSG_RESULT(no)
 249   ipv6=no]
 250 ))
 251
 252 ipv6type=unknown
 253 ipv6lib=none
 254 ipv6trylibc=no
 255
 256 if test "$ipv6" = "yes"; then
 257         AC_MSG_CHECKING([ipv6 stack type])
 258         for i in inria kame linux-glibc linux-libinet6 toshiba v6d zeta; do
 259                 case $i in
 260                 inria)
 261                         dnl http://www.kame.net/
 262                         AC_EGREP_CPP(yes,
 263 [#include <netinet/in.h>
 264 #ifdef IPV6_INRIA_VERSION
 265 yes
 266 #endif],
 267                                 [ipv6type=$i;
 268                                 CFLAGS="-DINET6 $CFLAGS"])
 269                         ;;
 270                 kame)
 271                         dnl http://www.kame.net/
 272                         AC_EGREP_CPP(yes,
 273 [#include <netinet/in.h>
 274 #ifdef __KAME__
 275 yes
 276 #endif],
 277                                 [ipv6type=$i;
 278                                 ipv6lib=inet6;
 279                                 ipv6libdir=/usr/local/v6/lib;
 280                                 ipv6trylibc=yes;
 281                                 CFLAGS="-DINET6 $CFLAGS"])
 282                         ;;
 283                 linux-glibc)
 284                         dnl http://www.v6.linux.or.jp/
 285                         AC_EGREP_CPP(yes,
 286 [#include <features.h>
 287 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 288 yes
 289 #endif],
 290                                 [ipv6type=$i;
 291                                 CFLAGS="-DINET6 $CFLAGS"])
 292                         ;;
 293                 linux-libinet6)
 294                         dnl http://www.v6.linux.or.jp/
 295                         dnl
 296                         dnl This also matches Solaris 8 and Tru64 UNIX 5.1,
 297                         dnl and possibly other versions of those OSes
 298                         dnl
 299                         if test -d /usr/inet6 -o -f /usr/include/netinet/ip6.h; then
 300                                 ipv6type=$i
 301                                 ipv6lib=inet6
 302                                 ipv6libdir=/usr/inet6/lib
 303                                 ipv6trylibc=yes;
 304                                 CFLAGS="-DINET6 -I/usr/inet6/include $CFLAGS"
 305                         fi
 306                         ;;
 307                 toshiba)
 308                         AC_EGREP_CPP(yes,
 309 [#include <sys/param.h>
 310 #ifdef _TOSHIBA_INET6
 311 yes
 312 #endif],
 313                                 [ipv6type=$i;
 314                                 ipv6lib=inet6;
 315                                 ipv6libdir=/usr/local/v6/lib;
 316                                 CFLAGS="-DINET6 $CFLAGS"])
 317                         ;;
 318                 v6d)
 319                         AC_EGREP_CPP(yes,
 320 [#include </usr/local/v6/include/sys/v6config.h>
 321 #ifdef __V6D__
 322 yes
 323 #endif],
 324                                 [ipv6type=$i;
 325                                 ipv6lib=v6;
 326                                 ipv6libdir=/usr/local/v6/lib;
 327                                 CFLAGS="-I/usr/local/v6/include $CFLAGS"])
 328                         ;;
 329                 zeta)
 330                         AC_EGREP_CPP(yes,
 331 [#include <sys/param.h>
 332 #ifdef _ZETA_MINAMI_INET6
 333 yes
 334 #endif],
 335                                 [ipv6type=$i;
 336                                 ipv6lib=inet6;
 337                                 ipv6libdir=/usr/local/v6/lib;
 338                                 CFLAGS="-DINET6 $CFLAGS"])
 339                         ;;
 340                 esac
 341                 if test "$ipv6type" != "unknown"; then
 342                         break
 343                 fi
 344         done
 345         AC_MSG_RESULT($ipv6type)
 346 fi
 347
 348 if test "$ipv6" = "yes" -a "$ipv6lib" != "none"; then
 349         if test -d $ipv6libdir -a -f $ipv6libdir/lib$ipv6lib.a; then
 350                 LIBS="-L$ipv6libdir -l$ipv6lib $LIBS"
 351                 echo "You have $ipv6lib library, using it"
 352         else
 353                 if test "$ipv6trylibc" = "yes"; then
 354                         echo "You do not have $ipv6lib library, using libc"
 355                 else
 356                         echo 'Fatal: no $ipv6lib library found.  cannot continue.'
 357                         echo "You need to fetch lib$ipv6lib.a from appropriate"
 358                         echo 'ipv6 kit and compile beforehand.'
 359                         exit 1
 360                 fi
 361         fi
 362 fi
 363
 364
 365 if test "$ipv6" = "yes"; then
 366         #
 367         # XXX - on Tru64 UNIX 5.1, there is no "getaddrinfo()"
 368         # function in libc; there are "ngetaddrinfo()" and
 369         # "ogetaddrinfo()" functions, and <netdb.h> #defines
 370         # "getaddrinfo" to be either "ngetaddrinfo" or
 371         # "ogetaddrinfo", depending on whether _SOCKADDR_LEN
 372         # or _XOPEN_SOURCE_EXTENDED are defined or not.
 373         #
 374         # So this test doesn't work on Tru64 5.1, and possibly
 375         # on other 5.x releases.  This causes the configure
 376         # script to become confused, and results in libpcap
 377         # being unbuildable.
 378         #
 379         AC_SEARCH_LIBS(getaddrinfo, socket, [dnl
 380         AC_MSG_CHECKING(getaddrinfo bug)
 381         AC_CACHE_VAL(td_cv_buggygetaddrinfo, [AC_TRY_RUN([
 382 #include <sys/types.h>
 383 #include <netdb.h>
 384 #include <string.h>
 385 #include <sys/socket.h>
 386 #include <netinet/in.h>
 387
 388 main()
 389 {
 390   int passive, gaierr, inet4 = 0, inet6 = 0;
 391   struct addrinfo hints, *ai, *aitop;
 392   char straddr[INET6_ADDRSTRLEN], strport[16];
 393
 394   for (passive = 0; passive <= 1; passive++) {
 395     memset(&hints, 0, sizeof(hints));
 396     hints.ai_family = AF_UNSPEC;
 397     hints.ai_flags = passive ? AI_PASSIVE : 0;
 398     hints.ai_socktype = SOCK_STREAM;
 399     hints.ai_protocol = IPPROTO_TCP;
 400     if ((gaierr = getaddrinfo(NULL, "54321", &hints, &aitop)) != 0) {
 401       (void)gai_strerror(gaierr);
 402       goto bad;
 403     }
 404     for (ai = aitop; ai; ai = ai->ai_next) {
 405       if (ai->ai_addr == NULL ||
 406           ai->ai_addrlen == 0 ||
 407           getnameinfo(ai->ai_addr, ai->ai_addrlen,
 408                       straddr, sizeof(straddr), strport, sizeof(strport),
 409                       NI_NUMERICHOST|NI_NUMERICSERV) != 0) {
 410         goto bad;
 411       }
 412       switch (ai->ai_family) {
 413       case AF_INET:
 414         if (strcmp(strport, "54321") != 0) {
 415           goto bad;
 416         }
 417         if (passive) {
 418           if (strcmp(straddr, "0.0.0.0") != 0) {
 419             goto bad;
 420           }
 421         } else {
 422           if (strcmp(straddr, "127.0.0.1") != 0) {
 423             goto bad;
 424           }
 425         }
 426         inet4++;
 427         break;
 428       case AF_INET6:
 429         if (strcmp(strport, "54321") != 0) {
 430           goto bad;
 431         }
 432         if (passive) {
 433           if (strcmp(straddr, "::") != 0) {
 434             goto bad;
 435           }
 436         } else {
 437           if (strcmp(straddr, "::1") != 0) {
 438             goto bad;
 439           }
 440         }
 441         inet6++;
 442         break;
 443       case AF_UNSPEC:
 444         goto bad;
 445         break;
 446 #ifdef AF_UNIX
 447       case AF_UNIX:
 448 #else
 449 #ifdef AF_LOCAL
 450       case AF_LOCAL:
 451 #endif
 452 #endif
 453       default:
 454         /* another family support? */
 455         break;
 456       }
 457     }
 458   }
 459
 460   /* supported family should be 2, unsupported family should be 0 */
 461   if (!(inet4 == 0 || inet4 == 2))
 462     goto bad;
 463   if (!(inet6 == 0 || inet6 == 2))
 464     goto bad;
 465
 466   if (aitop)
 467     freeaddrinfo(aitop);
 468   exit(0);
 469
 470  bad:
 471   if (aitop)
 472     freeaddrinfo(aitop);
 473   exit(1);
 474 }
 475 ],
 476         td_cv_buggygetaddrinfo=no,
 477         td_cv_buggygetaddrinfo=yes,
 478         td_cv_buggygetaddrinfo=yes)])
 479         if test "$td_cv_buggygetaddrinfo" = no; then
 480                 AC_MSG_RESULT(good)
 481         else
 482                 AC_MSG_RESULT(buggy)
 483         fi
 484
 485         if test "$td_cv_buggygetaddrinfo" = "yes"; then
 486                 #
 487                 # XXX - it doesn't appear that "ipv6type" can ever be
 488                 # set to "linux".  Should this be testing for
 489                 # "linux-glibc", or for that *or* "linux-libinet6"?
 490                 # If the latter, note that "linux-libinet6" is also
 491                 # the type given to some non-Linux OSes.
 492                 #
 493                 if test "$ipv6type" != "linux"; then
 494                         echo 'Fatal: You must get working getaddrinfo() function.'
 495                         echo '       or you can specify "--disable-ipv6"'.
 496                         exit 1
 497                 else
 498                         echo 'Warning: getaddrinfo() implementation on your system seems be buggy.'
 499                         echo '         Better upgrade your system library to newest version'
 500                         echo '         of GNU C library (aka glibc).'
 501                 fi
 502         fi
 503         ])
 504         AC_REPLACE_FUNCS(getnameinfo)
 505 fi
 506
 507 AC_CACHE_CHECK([for dnet_htoa declaration in netdnet/dnetdb.h],
 508 [td_cv_decl_netdnet_dnetdb_h_dnet_htoa],
 509 [AC_EGREP_HEADER(dnet_htoa, netdnet/dnetdb.h,
 510         td_cv_decl_netdnet_dnetdb_h_dnet_htoa=yes,
 511         td_cv_decl_netdnet_dnetdb_h_dnet_htoa=no)])
 512 if test "$td_cv_decl_netdnet_dnetdb_h_dnet_htoa" = yes; then
 513         AC_DEFINE(HAVE_NETDNET_DNETDB_H_DNET_HTOA, 1,
 514             [define if you have a dnet_htoa declaration in <netdnet/dnetdb.h>])
 515 fi
 516
 517 dnl
 518 dnl Checks for addrinfo structure
 519 AC_STRUCT_ADDRINFO(ac_cv_addrinfo)
 520 if test "$ac_cv_addrinfo" = no; then
 521         missing_includes=yes
 522 fi
 523
 524 dnl
 525 dnl Checks for NI_MAXSERV
 526 AC_NI_MAXSERV(ac_cv_maxserv)
 527 if test "$ac_cv_maxserv" = no; then
 528         missing_includes=yes
 529 fi
 530
 531 dnl
 532 dnl Checks for NI_NAMEREQD
 533 AC_NI_NAMEREQD(ac_cv_namereqd)
 534 if test "$ac_cv_namereqd" = no; then
 535         missing_includes=yes
 536 fi
 537
 538 AC_REPLACE_FUNCS(vfprintf strcasecmp strlcat strlcpy strdup strsep getopt_long)
 539 AC_CHECK_FUNCS(fork vfork strftime)
 540 AC_CHECK_FUNCS(setlinebuf alarm)
 541
 542 needsnprintf=no
 543 AC_CHECK_FUNCS(vsnprintf snprintf,,
 544         [needsnprintf=yes])
 545 if test $needsnprintf = yes; then
 546         AC_LIBOBJ(snprintf)
 547 fi
 548
 549 AC_LBL_TYPE_SIGNAL
 550
 551 AC_SEARCH_LIBS(dnet_htoa, dnet,
 552     AC_DEFINE(HAVE_DNET_HTOA, 1, [define if you have the dnet_htoa function]))
 553
 554 AC_CHECK_LIB(rpc, main)         dnl It's unclear why we might need -lrpc
 555
 556 dnl Some platforms may need -lnsl for getrpcbynumber.
 557 AC_SEARCH_LIBS(getrpcbynumber, nsl,
 558     AC_DEFINE(HAVE_GETRPCBYNUMBER, 1, [define if you have getrpcbynumber()]))
 559
 560 dnl AC_CHECK_LIB(z, uncompress)
 561 dnl AC_CHECK_HEADERS(zlib.h)
 562
 563 AC_LBL_LIBPCAP(V_PCAPDEP, V_INCLS)
 564
 565 #
 566 # Check for these after AC_LBL_LIBPCAP, so we link with the appropriate
 567 # libraries (e.g., "-lsocket -lnsl" on Solaris).
 568 #
 569 # We don't use AC_REPLACE_FUNCS because that uses AC_CHECK_FUNCS which
 570 # use AC_CHECK_FUNC which doesn't let us specify the right #includes
 571 # to make this work on BSD/OS 4.x.  BSD/OS 4.x ships with the BIND8
 572 # resolver, and the way it defines inet_{ntop,pton} is rather strange;
 573 # it does not ship with a libc symbol "inet_ntop()", it ships with
 574 # "_inet_ntop()", and has a #define macro in one of the system headers
 575 # to rename it.
 576 #
 577 dnl AC_TRY_COMPILE(inet_ntop inet_pton inet_aton)
 578 AC_MSG_CHECKING(for inet_ntop)
 579 AC_TRY_LINK([#include <sys/types.h>
 580 #include <sys/socket.h>
 581 #include <netinet/in.h>
 582 #include <arpa/inet.h>], [char src[4], dst[128];
 583 inet_ntop(AF_INET, src, dst, sizeof(dst));],
 584         [AC_MSG_RESULT(yes)], [AC_MSG_RESULT(no)
 585         AC_LIBOBJ(inet_ntop)])
 586 AC_MSG_CHECKING(for inet_pton)
 587 AC_TRY_LINK([#include <sys/types.h>
 588 #include <sys/socket.h>
 589 #include <netinet/in.h>
 590 #include <arpa/inet.h>], [char src[128], dst[4];
 591 inet_pton(AF_INET, src, dst);],
 592         [AC_MSG_RESULT(yes)], [AC_MSG_RESULT(no)
 593         AC_LIBOBJ(inet_pton)])
 594 AC_MSG_CHECKING(for inet_aton)
 595 AC_TRY_LINK([#include <sys/types.h>
 596 #include <netinet/in.h>
 597 #include <arpa/inet.h>], [char src[128];
 598 struct in_addr dst;
 599 inet_aton(src, &dst);],
 600         [AC_MSG_RESULT(yes)], [AC_MSG_RESULT(no)
 601         AC_LIBOBJ(inet_aton)])
 602
 603 #
 604 # Check for these after AC_LBL_LIBPCAP, for the same reason.
 605 #
 606 # You are in a twisty little maze of UN*Xes, all different.
 607 # Some might not have ether_ntohost().
 608 # Some might have it, but not declare it in any header file.
 609 # Some might have it, but declare it in <netinet/if_ether.h>.
 610 # Some might have it, but declare it in <netinet/ether.h>
 611 # (And some might have it but document it as something declared in
 612 # <netinet/ethernet.h>, although <netinet/if_ether.h> appears to work.)
 613 #
 614 # Before you is a C compiler.
 615 #
 616 AC_CHECK_FUNCS(ether_ntohost, [
 617     AC_CACHE_CHECK(for buggy ether_ntohost, ac_cv_buggy_ether_ntohost, [
 618         AC_TRY_RUN([
 619                 #include <netdb.h>
 620                 #include <sys/types.h>
 621                 #include <sys/param.h>
 622                 #include <sys/socket.h>
 623
 624                 int
 625                 main(int argc, char **argv)
 626                 {
 627                         u_char ea[6] = { 0xff, 0xff, 0xff, 0xff, 0xff };
 628                         char name[MAXHOSTNAMELEN];
 629
 630                         ether_ntohost(name, (struct ether_addr *)ea);
 631                         exit(0);
 632                 }
 633         ], [ac_cv_buggy_ether_ntohost=no],
 634            [ac_cv_buggy_ether_ntohost=yes],
 635            [ac_cv_buggy_ether_ntohost="not while cross-compiling"])])
 636     if test "$ac_cv_buggy_ether_ntohost" = "no"; then
 637         AC_DEFINE(USE_ETHER_NTOHOST, 1,
 638             [define if you have ether_ntohost() and it works])
 639     fi
 640 ])
 641 if test "$ac_cv_func_ether_ntohost" = yes -a \
 642     "$ac_cv_buggy_ether_ntohost" = "no"; then
 643         #
 644         # OK, we have ether_ntohost().  Do we have <netinet/if_ether.h>?
 645         #
 646         if test "$ac_cv_header_netinet_if_ether_h" = yes; then
 647                 #
 648                 # Yes.  Does it declare ether_ntohost()?
 649                 #
 650                 AC_CHECK_DECL(ether_ntohost,
 651                     [
 652                         AC_DEFINE(NETINET_IF_ETHER_H_DECLARES_ETHER_NTOHOST,,
 653                             [Define to 1 if netinet/if_ether.h declares `ether_ntohost'])
 654                     ],,
 655                     [
 656 #include <sys/types.h>
 657 #include <sys/socket.h>
 658 #include <netinet/in.h>
 659 #include <arpa/inet.h>
 660 struct mbuf;
 661 struct rtentry;
 662 #include <net/if.h>
 663 #include <netinet/if_ether.h>
 664                     ])
 665         fi
 666         #
 667         # Did that succeed?
 668         #
 669         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 670                 #
 671                 # No, how about <netinet/ether.h>, as on Linux?
 672                 #
 673                 AC_CHECK_HEADERS(netinet/ether.h)
 674                 if test "$ac_cv_header_netinet_ether_h" = yes; then
 675                         #
 676                         # We have it - does it declare ether_ntohost()?
 677                         # Unset ac_cv_have_decl_ether_ntohost so we don't
 678                         # treat the previous failure as a cached value and
 679                         # suppress the next test.
 680                         #
 681                         unset ac_cv_have_decl_ether_ntohost
 682                         AC_CHECK_DECL(ether_ntohost,
 683                             [
 684                                 AC_DEFINE(NETINET_ETHER_H_DECLARES_ETHER_NTOHOST,,
 685                                     [Define to 1 if netinet/ether.h declares `ether_ntohost'])
 686                             ],,
 687                             [
 688 #include <netinet/ether.h>
 689                             ])
 690                 fi
 691         fi
 692         #
 693         # Is ether_ntohost() declared?
 694         #
 695         if test "$ac_cv_have_decl_ether_ntohost" != yes; then
 696                 #
 697                 # No, we'll have to declare it ourselves.
 698                 # Do we have "struct ether_addr"?
 699                 #
 700                 AC_CHECK_TYPES(struct ether_addr,,,
 701                     [
 702 #include <sys/types.h>
 703 #include <sys/socket.h>
 704 #include <netinet/in.h>
 705 #include <arpa/inet.h>
 706 struct mbuf;
 707 struct rtentry;
 708 #include <net/if.h>
 709 #include <netinet/if_ether.h>
 710                     ])
 711                 AC_DEFINE(HAVE_DECL_ETHER_NTOHOST, 0,
 712                     [Define to 1 if you have the declaration of `ether_ntohost', and to 0 if you
 713 don't.])
 714         else
 715                 AC_DEFINE(HAVE_DECL_ETHER_NTOHOST, 1,
 716                     [Define to 1 if you have the declaration of `ether_ntohost', and to 0 if you
 717 don't.])
 718         fi
 719 fi
 720
 721 # libdlpi is needed for Solaris 11 and later.
 722 AC_CHECK_LIB(dlpi, dlpi_walk, LIBS="$LIBS -ldlpi" LDFLAGS="-L/lib $LDFLAGS", ,-L/lib)
 723
 724 dnl portability macros for getaddrinfo/getnameinfo
 725 dnl
 726 dnl Check for sa_len
 727 AC_CHECK_SA_LEN(ac_cv_sockaddr_has_sa_len)
 728 if test "$ac_cv_sockaddr_has_sa_len" = no; then
 729         missing_includes=yes
 730 fi
 731
 732 #
 733 # Do we have the new open API?  Check for pcap_create, and assume that,
 734 # if we do, we also have pcap_activate() and the other new routines
 735 # introduced in libpcap 1.0.0.
 736 #
 737 AC_CHECK_FUNCS(pcap_create)
 738 if test $ac_cv_func_pcap_create = "yes" ; then
 739         #
 740         # OK, do we have pcap_set_tstamp_type?  If so, assume we have
 741         # pcap_list_tstamp_types and pcap_free_tstamp_types as well.
 742         #
 743         AC_CHECK_FUNCS(pcap_set_tstamp_type)
 744         #
 745         # And do we have pcap_set_tstamp_precision?  If so, we assume
 746         # we also have pcap_open_offline_with_tstamp_precision.
 747         #
 748         AC_CHECK_FUNCS(pcap_set_tstamp_precision)
 749 fi
 750
 751 AC_CHECK_FUNCS(pcap_findalldevs pcap_dump_flush pcap_lib_version pcap_setdirection)
 752 if test $ac_cv_func_pcap_findalldevs = "yes" ; then
 753 dnl Check for Mac OS X, which may ship pcap.h from 0.6 but libpcap may
 754 dnl be 0.8; this means that lib has pcap_findalldevs but header doesn't
 755 dnl have pcap_if_t.
 756     savedcppflags="$CPPFLAGS"
 757     CPPFLAGS="$CPPFLAGS $V_INCLS"
 758     AC_CHECK_TYPES(pcap_if_t, , , [#include <pcap.h>])
 759     CPPFLAGS="$savedcppflags"
 760 fi
 761
 762 if test $ac_cv_func_pcap_lib_version = "no" ; then
 763     AC_MSG_CHECKING(whether pcap_version is defined by libpcap)
 764     AC_TRY_LINK([],
 765        [
 766         extern char pcap_version[];
 767
 768         return (int)pcap_version;
 769        ],
 770        ac_lbl_cv_pcap_version_defined=yes,
 771        ac_lbl_cv_pcap_version_defined=no)
 772     if test "$ac_lbl_cv_pcap_version_defined" = yes ; then
 773         AC_MSG_RESULT(yes)
 774         AC_DEFINE(HAVE_PCAP_VERSION, 1, [define if libpcap has pcap_version])
 775     else
 776         AC_MSG_RESULT(no)
 777     fi
 778 fi
 779 AC_MSG_CHECKING(whether pcap_debug is defined by libpcap)
 780 AC_TRY_LINK([],
 781    [
 782         extern int pcap_debug;
 783
 784         return pcap_debug;
 785    ],
 786    ac_lbl_cv_pcap_debug_defined=yes,
 787    ac_lbl_cv_pcap_debug_defined=no)
 788 if test "$ac_lbl_cv_pcap_debug_defined" = yes ; then
 789         AC_MSG_RESULT(yes)
 790         AC_DEFINE(HAVE_PCAP_DEBUG, 1, [define if libpcap has pcap_debug])
 791 else
 792         AC_MSG_RESULT(no)
 793         #
 794         # OK, what about "yydebug"?
 795         #
 796         AC_MSG_CHECKING(whether yydebug is defined by libpcap)
 797         AC_TRY_LINK([],
 798            [
 799                 extern int yydebug;
 800
 801                 return yydebug;
 802            ],
 803            ac_lbl_cv_yydebug_defined=yes,
 804            ac_lbl_cv_yydebug_defined=no)
 805         if test "$ac_lbl_cv_yydebug_defined" = yes ; then
 806                 AC_MSG_RESULT(yes)
 807                 AC_DEFINE(HAVE_YYDEBUG, 1, [define if libpcap has yydebug])
 808         else
 809                 AC_MSG_RESULT(no)
 810         fi
 811 fi
 812 AC_REPLACE_FUNCS(bpf_dump)      dnl moved to libpcap in 0.6
 813
 814 V_GROUP=0
 815 if test -f /etc/group -a ! -z "`grep '^wheel:' /etc/group`" ; then
 816         V_GROUP=wheel
 817 fi
 818 #
 819 # Assume V7/BSD convention for man pages (file formats in section 5,
 820 # miscellaneous info in section 7).
 821 #
 822 MAN_FILE_FORMATS=5
 823 MAN_MISC_INFO=7
 824 case "$host_os" in
 825
 826 aix*)
 827         dnl Workaround to enable certain features
 828         AC_DEFINE(_SUN,1,[define on AIX to get certain functions])
 829         ;;
 830
 831 hpux*)
 832         #
 833         # Use System V conventions for man pages.
 834         #
 835         MAN_FILE_FORMATS=4
 836         MAN_MISC_INFO=5
 837         ;;
 838
 839 irix*)
 840         V_GROUP=sys
 841
 842         #
 843         # Use System V conventions for man pages.
 844         #
 845         MAN_FILE_FORMATS=4
 846         MAN_MISC_INFO=5
 847         ;;
 848
 849 osf*)
 850         V_GROUP=system
 851
 852         #
 853         # Use System V conventions for man pages.
 854         #
 855         MAN_FILE_FORMATS=4
 856         MAN_MISC_INFO=5
 857         ;;
 858
 859 solaris*)
 860         V_GROUP=sys
 861
 862         #
 863         # Use System V conventions for man pages.
 864         #
 865         MAN_FILE_FORMATS=4
 866         MAN_MISC_INFO=5
 867         ;;
 868 esac
 869
 870 if test -f /dev/bpf0 ; then
 871         V_GROUP=bpf
 872 fi
 873
 874 #
 875 # Make sure we have definitions for all the C99 specified-width types
 876 # (regardless of whether the environment is a C99 environment or not).
 877 #
 878 AC_TYPE_INT8_T
 879 AC_TYPE_INT16_T
 880 AC_TYPE_INT32_T
 881 AC_TYPE_INT64_T
 882 AC_TYPE_UINT8_T
 883 AC_TYPE_UINT16_T
 884 AC_TYPE_UINT32_T
 885 AC_TYPE_UINT64_T
 886
 887 #
 888 # Define the old BSD specified-width types in terms of the C99 types;
 889 # we may need them with libpcap include files.
 890 #
 891 AC_CHECK_TYPE([u_int8_t], ,
 892         [AC_DEFINE([u_int8_t], [uint8_t],
 893         [Define to `uint8_t' if u_int8_t not defined.])],
 894         [AC_INCLUDES_DEFAULT
 895 #include <sys/types.h>
 896 ])
 897 AC_CHECK_TYPE([u_int16_t], ,
 898         [AC_DEFINE([u_int16_t], [uint16_t],
 899         [Define to `uint16_t' if u_int16_t not defined.])],
 900         [AC_INCLUDES_DEFAULT
 901 #include <sys/types.h>
 902 ])
 903 AC_CHECK_TYPE([u_int32_t], ,
 904         [AC_DEFINE([u_int32_t], [uint32_t],
 905         [Define to `uint32_t' if u_int32_t not defined.])],
 906         [AC_INCLUDES_DEFAULT
 907 #include <sys/types.h>
 908 ])
 909 AC_CHECK_TYPE([u_int64_t], ,
 910         [AC_DEFINE([u_int64_t], [uint64_t],
 911         [Define to `uint64_t' if u_int64_t not defined.])],
 912         [AC_INCLUDES_DEFAULT
 913 #include <sys/types.h>
 914 ])
 915
 916 #
 917 # Check for <inttypes.h>
 918 #
 919 AC_CHECK_HEADERS(inttypes.h,
 920   [
 921     #
 922     # OK, we have inttypes.h, but does it define all the PRI[doxu]64 macros?
 923     # Some systems have an inttypes.h that doesn't define all of them.
 924     #
 925     AC_MSG_CHECKING([[whether inttypes.h defines the PRI[doxu]64 macros]])
 926     AC_COMPILE_IFELSE(
 927       [
 928         AC_LANG_SOURCE(
 929           [[
 930             #include <inttypes.h>
 931             #include <stdio.h>
 932             #include <sys/types.h>
 933
 934             main()
 935             {
 936               printf("%" PRId64 "\n", (uint64_t)1);
 937               printf("%" PRIo64 "\n", (uint64_t)1);
 938               printf("%" PRIx64 "\n", (uint64_t)1);
 939               printf("%" PRIu64 "\n", (uint64_t)1);
 940             }
 941           ]])
 942       ],
 943       [
 944         AC_MSG_RESULT(yes)
 945         ac_lbl_inttypes_h_defines_formats=yes
 946       ],
 947       [
 948         AC_MSG_RESULT(no)
 949         ac_lbl_inttypes_h_defines_formats=no
 950       ])
 951   ],
 952   [
 953     #
 954     # We don't have inttypes.h, so it obviously can't define those
 955     # macros.
 956     #
 957     ac_lbl_inttypes_h_defines_formats=no
 958   ])
 959 if test "$ac_lbl_inttypes_h_defines_formats" = no; then
 960   AC_LBL_CHECK_64BIT_FORMAT(l,
 961     [
 962       AC_LBL_CHECK_64BIT_FORMAT(ll,
 963         [
 964           AC_LBL_CHECK_64BIT_FORMAT(L,
 965             [
 966               AC_LBL_CHECK_64BIT_FORMAT(q,
 967                 [
 968                   AC_MSG_ERROR([neither %llx nor %Lx nor %qx worked on a 64-bit integer])
 969                 ])
 970             ])
 971         ])
 972     ])
 973 fi
 974
 975 #
 976 # Check for some headers introduced in later versions of libpcap
 977 # and used by some printers.
 978 #
 979 # Those headers use the {u_}intN_t types, so we must do this after
 980 # we check for what's needed to get them defined.
 981 #
 982 savedcppflags="$CPPFLAGS"
 983 CPPFLAGS="$CPPFLAGS $V_INCLS"
 984 AC_CHECK_HEADERS(pcap/bluetooth.h,,,[#include "tcpdump-stdinc.h"])
 985 AC_CHECK_HEADERS(pcap/nflog.h,,,[#include "tcpdump-stdinc.h"])
 986 AC_CHECK_HEADERS(pcap/usb.h,,,[#include "tcpdump-stdinc.h"])
 987 CPPFLAGS="$savedcppflags"
 988
 989 AC_PROG_RANLIB
 990 AC_CHECK_TOOL([AR], [ar])
 991
 992 AC_LBL_DEVEL(V_CCOPT)
 993
 994 AC_LBL_SOCKADDR_SA_LEN
 995
 996 AC_LBL_UNALIGNED_ACCESS
 997
 998 AC_VAR_H_ERRNO
 999
1000 # Check for OpenSSL libcrypto
1001 AC_MSG_CHECKING(whether to use OpenSSL libcrypto)
1002 # Specify location for both includes and libraries.
1003 want_libcrypto=ifavailable
1004 AC_ARG_WITH(crypto,
1005     AS_HELP_STRING([--with-crypto],
1006                    [use OpenSSL libcrypto @<:@default=yes, if available@:>@]),
1007 [
1008         if test $withval = no
1009         then
1010                 want_libcrypto=no
1011                 AC_MSG_RESULT(no)
1012         elif test $withval = yes
1013         then
1014                 want_libcrypto=yes
1015                 AC_MSG_RESULT(yes)
1016         fi
1017 ],[
1018         #
1019         # Use libcrypto if it's present, otherwise don't.
1020         #
1021         want_libcrypto=ifavailable
1022         AC_MSG_RESULT([yes, if available])
1023 ])
1024 if test "$want_libcrypto" != "no"; then
1025         AC_CHECK_LIB(crypto, DES_cbc_encrypt)
1026         AC_CHECK_HEADERS(openssl/evp.h)
1027 fi
1028
1029 dnl
1030 dnl set additional include path if necessary
1031 if test "$missing_includes" = "yes"; then
1032         CPPFLAGS="$CPPFLAGS -I$srcdir/missing"
1033         V_INCLS="$V_INCLS -I$srcdir/missing"
1034 fi
1035
1036 AC_SUBST(V_CCOPT)
1037 AC_SUBST(V_DEFS)
1038 AC_SUBST(V_GROUP)
1039 AC_SUBST(V_INCLS)
1040 AC_SUBST(V_PCAPDEP)
1041 AC_SUBST(LOCALSRC)
1042 AC_SUBST(MAN_FILE_FORMATS)
1043 AC_SUBST(MAN_MISC_INFO)
1044
1045 AC_PROG_INSTALL
1046
1047 AC_CONFIG_HEADER(config.h)
1048
1049 AC_OUTPUT_COMMANDS([if test -f .devel; then
1050         echo timestamp > stamp-h
1051         cat Makefile-devel-adds >> Makefile
1052         make depend
1053 fi])
1054 AC_OUTPUT(Makefile tcpdump.1)
1055 exit 0